lib/Target/X86/X86InstrFormats.td

   1 //===- X86InstrFormats.td - X86 Instruction Formats --------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // X86 Instruction Format Definitions.
  12 //
  13
  14 // Format specifies the encoding used by the instruction.  This is part of the
  15 // ad-hoc solution used to emit machine instruction encodings by our machine
  16 // code emitter.
  17 class Format<bits<6> val> {
  18   bits<6> Value = val;
  19 }
  20
  21 def Pseudo     : Format<0>; def RawFrm     : Format<1>;
  22 def AddRegFrm  : Format<2>; def MRMDestReg : Format<3>;
  23 def MRMDestMem : Format<4>; def MRMSrcReg  : Format<5>;
  24 def MRMSrcMem  : Format<6>;
  25 def MRM0r  : Format<16>; def MRM1r  : Format<17>; def MRM2r  : Format<18>;
  26 def MRM3r  : Format<19>; def MRM4r  : Format<20>; def MRM5r  : Format<21>;
  27 def MRM6r  : Format<22>; def MRM7r  : Format<23>;
  28 def MRM0m  : Format<24>; def MRM1m  : Format<25>; def MRM2m  : Format<26>;
  29 def MRM3m  : Format<27>; def MRM4m  : Format<28>; def MRM5m  : Format<29>;
  30 def MRM6m  : Format<30>; def MRM7m  : Format<31>;
  31 def MRMInitReg : Format<32>;
  32 def MRM_C1 : Format<33>;
  33 def MRM_C2 : Format<34>;
  34 def MRM_C3 : Format<35>;
  35 def MRM_C4 : Format<36>;
  36 def MRM_C8 : Format<37>;
  37 def MRM_C9 : Format<38>;
  38 def MRM_E8 : Format<39>;
  39 def MRM_F0 : Format<40>;
  40 def MRM_F8 : Format<41>;
  41 def MRM_F9 : Format<42>;
  42
  43 // ImmType - This specifies the immediate type used by an instruction. This is
  44 // part of the ad-hoc solution used to emit machine instruction encodings by our
  45 // machine code emitter.
  46 class ImmType<bits<3> val> {
  47   bits<3> Value = val;
  48 }
  49 def NoImm      : ImmType<0>;
  50 def Imm8       : ImmType<1>;
  51 def Imm8PCRel  : ImmType<2>;
  52 def Imm16      : ImmType<3>;
  53 def Imm32      : ImmType<4>;
  54 def Imm32PCRel : ImmType<5>;
  55 def Imm64      : ImmType<6>;
  56
  57 // FPFormat - This specifies what form this FP instruction has.  This is used by
  58 // the Floating-Point stackifier pass.
  59 class FPFormat<bits<3> val> {
  60   bits<3> Value = val;
  61 }
  62 def NotFP      : FPFormat<0>;
  63 def ZeroArgFP  : FPFormat<1>;
  64 def OneArgFP   : FPFormat<2>;
  65 def OneArgFPRW : FPFormat<3>;
  66 def TwoArgFP   : FPFormat<4>;
  67 def CompareFP  : FPFormat<5>;
  68 def CondMovFP  : FPFormat<6>;
  69 def SpecialFP  : FPFormat<7>;
  70
  71 // Class specifying the SSE execution domain, used by the SSEDomainFix pass.
  72 // Keep in sync with tables in X86InstrInfo.cpp.
  73 class Domain<bits<2> val> {
  74   bits<2> Value = val;
  75 }
  76 def GenericDomain   : Domain<0>;
  77 def SSEPackedSingle : Domain<1>;
  78 def SSEPackedDouble : Domain<2>;
  79 def SSEPackedInt    : Domain<3>;
  80
  81 // Prefix byte classes which are used to indicate to the ad-hoc machine code
  82 // emitter that various prefix bytes are required.
  83 class OpSize { bit hasOpSizePrefix = 1; }
  84 class AdSize { bit hasAdSizePrefix = 1; }
  85 class REX_W  { bit hasREX_WPrefix = 1; }
  86 class LOCK   { bit hasLockPrefix = 1; }
  87 class SegFS  { bits<2> SegOvrBits = 1; }
  88 class SegGS  { bits<2> SegOvrBits = 2; }
  89 class TB     { bits<4> Prefix = 1; }
  90 class REP    { bits<4> Prefix = 2; }
  91 class D8     { bits<4> Prefix = 3; }
  92 class D9     { bits<4> Prefix = 4; }
  93 class DA     { bits<4> Prefix = 5; }
  94 class DB     { bits<4> Prefix = 6; }
  95 class DC     { bits<4> Prefix = 7; }
  96 class DD     { bits<4> Prefix = 8; }
  97 class DE     { bits<4> Prefix = 9; }
  98 class DF     { bits<4> Prefix = 10; }
  99 class XD     { bits<4> Prefix = 11; }
 100 class XS     { bits<4> Prefix = 12; }
 101 class T8     { bits<4> Prefix = 13; }
 102 class TA     { bits<4> Prefix = 14; }
 103 class TF     { bits<4> Prefix = 15; }
 104 class VEX    { bit hasVEXPrefix = 1; }
 105 class VEX_4V : VEX { bit hasVEX_4VPrefix = 1; }
 106
 107 class X86Inst<bits<8> opcod, Format f, ImmType i, dag outs, dag ins,
 108               string AsmStr, Domain d = GenericDomain>
 109   : Instruction {
 110   let Namespace = "X86";
 111
 112   bits<8> Opcode = opcod;
 113   Format Form = f;
 114   bits<6> FormBits = Form.Value;
 115   ImmType ImmT = i;
 116
 117   dag OutOperandList = outs;
 118   dag InOperandList = ins;
 119   string AsmString = AsmStr;
 120
 121   //
 122   // Attributes specific to X86 instructions...
 123   //
 124   bit hasOpSizePrefix = 0;  // Does this inst have a 0x66 prefix?
 125   bit hasAdSizePrefix = 0;  // Does this inst have a 0x67 prefix?
 126
 127   bits<4> Prefix = 0;       // Which prefix byte does this inst have?
 128   bit hasREX_WPrefix  = 0;  // Does this inst requires the REX.W prefix?
 129   FPFormat FPForm = NotFP;  // What flavor of FP instruction is this?
 130   bit hasLockPrefix = 0;    // Does this inst have a 0xF0 prefix?
 131   bits<2> SegOvrBits = 0;   // Segment override prefix.
 132   Domain ExeDomain = d;
 133   bit hasVEXPrefix  = 0;    // Does this inst requires a VEX prefix?
 134   bit hasVEX_4VPrefix  = 0; // Does this inst requires the VEX.VVVV field?
 135
 136   // TSFlags layout should be kept in sync with X86InstrInfo.h.
 137   let TSFlags{5-0}   = FormBits;
 138   let TSFlags{6}     = hasOpSizePrefix;
 139   let TSFlags{7}     = hasAdSizePrefix;
 140   let TSFlags{11-8}  = Prefix;
 141   let TSFlags{12}    = hasREX_WPrefix;
 142   let TSFlags{15-13} = ImmT.Value;
 143   let TSFlags{18-16} = FPForm.Value;
 144   let TSFlags{19}    = hasLockPrefix;
 145   let TSFlags{21-20} = SegOvrBits;
 146   let TSFlags{23-22} = ExeDomain.Value;
 147   let TSFlags{31-24} = Opcode;
 148   let TSFlags{32}    = hasVEXPrefix;
 149   let TSFlags{33}    = hasVEX_4VPrefix;
 150 }
 151
 152 class I<bits<8> o, Format f, dag outs, dag ins, string asm,
 153         list<dag> pattern, Domain d = GenericDomain>
 154   : X86Inst<o, f, NoImm, outs, ins, asm, d> {
 155   let Pattern = pattern;
 156   let CodeSize = 3;
 157 }
 158 class Ii8 <bits<8> o, Format f, dag outs, dag ins, string asm,
 159            list<dag> pattern, Domain d = GenericDomain>
 160   : X86Inst<o, f, Imm8, outs, ins, asm, d> {
 161   let Pattern = pattern;
 162   let CodeSize = 3;
 163 }
 164 class Ii8PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 165                list<dag> pattern>
 166   : X86Inst<o, f, Imm8PCRel, outs, ins, asm> {
 167   let Pattern = pattern;
 168   let CodeSize = 3;
 169 }
 170 class Ii16<bits<8> o, Format f, dag outs, dag ins, string asm,
 171            list<dag> pattern>
 172   : X86Inst<o, f, Imm16, outs, ins, asm> {
 173   let Pattern = pattern;
 174   let CodeSize = 3;
 175 }
 176 class Ii32<bits<8> o, Format f, dag outs, dag ins, string asm,
 177            list<dag> pattern>
 178   : X86Inst<o, f, Imm32, outs, ins, asm> {
 179   let Pattern = pattern;
 180   let CodeSize = 3;
 181 }
 182
 183 class Ii32PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 184            list<dag> pattern>
 185   : X86Inst<o, f, Imm32PCRel, outs, ins, asm> {
 186   let Pattern = pattern;
 187   let CodeSize = 3;
 188 }
 189
 190 // FPStack Instruction Templates:
 191 // FPI - Floating Point Instruction template.
 192 class FPI<bits<8> o, Format F, dag outs, dag ins, string asm>
 193   : I<o, F, outs, ins, asm, []> {}
 194
 195 // FpI_ - Floating Point Psuedo Instruction template. Not Predicated.
 196 class FpI_<dag outs, dag ins, FPFormat fp, list<dag> pattern>
 197   : X86Inst<0, Pseudo, NoImm, outs, ins, ""> {
 198   let FPForm = fp;
 199   let Pattern = pattern;
 200 }
 201
 202 // Templates for instructions that use a 16- or 32-bit segmented address as
 203 //  their only operand: lcall (FAR CALL) and ljmp (FAR JMP)
 204 //
 205 //   Iseg16 - 16-bit segment selector, 16-bit offset
 206 //   Iseg32 - 16-bit segment selector, 32-bit offset
 207
 208 class Iseg16 <bits<8> o, Format f, dag outs, dag ins, string asm,
 209               list<dag> pattern> : X86Inst<o, f, NoImm, outs, ins, asm> {
 210   let Pattern = pattern;
 211   let CodeSize = 3;
 212 }
 213
 214 class Iseg32 <bits<8> o, Format f, dag outs, dag ins, string asm,
 215               list<dag> pattern> : X86Inst<o, f, NoImm, outs, ins, asm> {
 216   let Pattern = pattern;
 217   let CodeSize = 3;
 218 }
 219
 220 // SI - SSE 1 & 2 scalar instructions
 221 class SI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 222       : I<o, F, outs, ins, asm, pattern> {
 223   let Predicates = !if(hasVEXPrefix /* VEX_4V */,
 224             !if(!eq(Prefix, 11 /* XD */), [HasAVX, HasSSE2], [HasAVX, HasSSE1]),
 225             !if(!eq(Prefix, 12 /* XS */), [HasSSE1], [HasSSE2]));
 226
 227   // AVX instructions have a 'v' prefix in the mnemonic
 228   let AsmString = !if(hasVEXPrefix, !strconcat("v", asm), asm);
 229 }
 230
 231 // SIi8 - SSE 1 & 2 scalar instructions
 232 class SIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 233            list<dag> pattern>
 234       : Ii8<o, F, outs, ins, asm, pattern> {
 235   let Predicates = !if(hasVEXPrefix /* VEX_4V */,
 236             !if(!eq(Prefix, 11 /* XD */), [HasAVX, HasSSE2], [HasAVX, HasSSE1]),
 237             !if(!eq(Prefix, 12 /* XS */), [HasSSE1], [HasSSE2]));
 238
 239   // AVX instructions have a 'v' prefix in the mnemonic
 240   let AsmString = !if(hasVEXPrefix, !strconcat("v", asm), asm);
 241 }
 242
 243 // PI - SSE 1 & 2 packed instructions
 244 class PI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern,
 245          Domain d>
 246       : I<o, F, outs, ins, asm, pattern, d> {
 247   let Predicates = !if(hasVEXPrefix /* VEX_4V */,
 248         !if(hasOpSizePrefix /* OpSize */, [HasAVX, HasSSE2], [HasAVX, HasSSE1]),
 249         !if(hasOpSizePrefix /* OpSize */, [HasSSE2], [HasSSE1]));
 250
 251   // AVX instructions have a 'v' prefix in the mnemonic
 252   let AsmString = !if(hasVEXPrefix, !strconcat("v", asm), asm);
 253 }
 254
 255 // PIi8 - SSE 1 & 2 packed instructions with immediate
 256 class PIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 257            list<dag> pattern, Domain d>
 258       : Ii8<o, F, outs, ins, asm, pattern, d> {
 259   let Predicates = !if(hasVEX_4VPrefix /* VEX_4V */,
 260         !if(hasOpSizePrefix /* OpSize */, [HasAVX, HasSSE2], [HasAVX, HasSSE1]),
 261         !if(hasOpSizePrefix /* OpSize */, [HasSSE2], [HasSSE1]));
 262
 263   // AVX instructions have a 'v' prefix in the mnemonic
 264   let AsmString = !if(hasVEX_4VPrefix, !strconcat("v", asm), asm);
 265 }
 266
 267 // SSE1 Instruction Templates:
 268 //
 269 //   SSI   - SSE1 instructions with XS prefix.
 270 //   PSI   - SSE1 instructions with TB prefix.
 271 //   PSIi8 - SSE1 instructions with ImmT == Imm8 and TB prefix.
 272 //   VSSI  - SSE1 instructions with XS prefix in AVX form.
 273 //   VPSI  - SSE1 instructions with TB prefix in AVX form.
 274
 275 class SSI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 276       : I<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE1]>;
 277 class SSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 278             list<dag> pattern>
 279       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE1]>;
 280 class PSI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 281       : I<o, F, outs, ins, asm, pattern, SSEPackedSingle>, TB,
 282         Requires<[HasSSE1]>;
 283 class PSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 284             list<dag> pattern>
 285       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedSingle>, TB,
 286         Requires<[HasSSE1]>;
 287 class VSSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 288            list<dag> pattern>
 289       : I<o, F, outs, ins, !strconcat("v", asm), pattern>, XS,
 290         Requires<[HasAVX, HasSSE1]>;
 291 class VPSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 292            list<dag> pattern>
 293       : I<o, F, outs, ins, !strconcat("v", asm), pattern, SSEPackedSingle>,
 294         Requires<[HasAVX, HasSSE1]>;
 295
 296 // SSE2 Instruction Templates:
 297 //
 298 //   SDI    - SSE2 instructions with XD prefix.
 299 //   SDIi8  - SSE2 instructions with ImmT == Imm8 and XD prefix.
 300 //   SSDIi8 - SSE2 instructions with ImmT == Imm8 and XS prefix.
 301 //   PDI    - SSE2 instructions with TB and OpSize prefixes.
 302 //   PDIi8  - SSE2 instructions with ImmT == Imm8 and TB and OpSize prefixes.
 303 //   VSDI   - SSE2 instructions with XD prefix in AVX form.
 304 //   VPDI   - SSE2 instructions with TB and OpSize prefixes in AVX form.
 305
 306 class SDI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 307       : I<o, F, outs, ins, asm, pattern>, XD, Requires<[HasSSE2]>;
 308 class SDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 309             list<dag> pattern>
 310       : Ii8<o, F, outs, ins, asm, pattern>, XD, Requires<[HasSSE2]>;
 311 class SSDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 312              list<dag> pattern>
 313       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE2]>;
 314 class PDI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 315       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 316         Requires<[HasSSE2]>;
 317 class PDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 318             list<dag> pattern>
 319       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 320         Requires<[HasSSE2]>;
 321 class VSDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 322            list<dag> pattern>
 323       : I<o, F, outs, ins, !strconcat("v", asm), pattern>, XD,
 324         Requires<[HasAVX, HasSSE2]>;
 325 class VPDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 326            list<dag> pattern>
 327       : I<o, F, outs, ins, !strconcat("v", asm), pattern, SSEPackedDouble>,
 328         OpSize, Requires<[HasAVX, HasSSE2]>;
 329
 330 // SSE3 Instruction Templates:
 331 //
 332 //   S3I   - SSE3 instructions with TB and OpSize prefixes.
 333 //   S3SI  - SSE3 instructions with XS prefix.
 334 //   S3DI  - SSE3 instructions with XD prefix.
 335
 336 class S3SI<bits<8> o, Format F, dag outs, dag ins, string asm,
 337            list<dag> pattern>
 338       : I<o, F, outs, ins, asm, pattern, SSEPackedSingle>, XS,
 339         Requires<[HasSSE3]>;
 340 class S3DI<bits<8> o, Format F, dag outs, dag ins, string asm,
 341            list<dag> pattern>
 342       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, XD,
 343         Requires<[HasSSE3]>;
 344 class S3I<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 345       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 346         Requires<[HasSSE3]>;
 347
 348
 349 // SSSE3 Instruction Templates:
 350 //
 351 //   SS38I - SSSE3 instructions with T8 prefix.
 352 //   SS3AI - SSSE3 instructions with TA prefix.
 353 //
 354 // Note: SSSE3 instructions have 64-bit and 128-bit versions. The 64-bit version
 355 // uses the MMX registers. We put those instructions here because they better
 356 // fit into the SSSE3 instruction category rather than the MMX category.
 357
 358 class SS38I<bits<8> o, Format F, dag outs, dag ins, string asm,
 359             list<dag> pattern>
 360       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 361         Requires<[HasSSSE3]>;
 362 class SS3AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 363             list<dag> pattern>
 364       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 365         Requires<[HasSSSE3]>;
 366
 367 // SSE4.1 Instruction Templates:
 368 //
 369 //   SS48I - SSE 4.1 instructions with T8 prefix.
 370 //   SS41AIi8 - SSE 4.1 instructions with TA prefix and ImmT == Imm8.
 371 //
 372 class SS48I<bits<8> o, Format F, dag outs, dag ins, string asm,
 373             list<dag> pattern>
 374       : I<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 375         Requires<[HasSSE41]>;
 376 class SS4AIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 377             list<dag> pattern>
 378       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 379         Requires<[HasSSE41]>;
 380
 381 // SSE4.2 Instruction Templates:
 382 //
 383 //   SS428I - SSE 4.2 instructions with T8 prefix.
 384 class SS428I<bits<8> o, Format F, dag outs, dag ins, string asm,
 385              list<dag> pattern>
 386       : I<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 387         Requires<[HasSSE42]>;
 388
 389 //   SS42FI - SSE 4.2 instructions with TF prefix.
 390 class SS42FI<bits<8> o, Format F, dag outs, dag ins, string asm,
 391               list<dag> pattern>
 392       : I<o, F, outs, ins, asm, pattern>, TF, Requires<[HasSSE42]>;
 393
 394 //   SS42AI = SSE 4.2 instructions with TA prefix
 395 class SS42AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 396              list<dag> pattern>
 397       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 398         Requires<[HasSSE42]>;
 399
 400 // AES Instruction Templates:
 401 //
 402 // AES8I
 403 // These use the same encoding as the SSE4.2 T8 and TA encodings.
 404 class AES8I<bits<8> o, Format F, dag outs, dag ins, string asm,
 405             list<dag>pattern>
 406       : I<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 407         Requires<[HasAES]>;
 408
 409 class AESAI<bits<8> o, Format F, dag outs, dag ins, string asm,
 410             list<dag> pattern>
 411       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 412         Requires<[HasAES]>;
 413
 414 // X86-64 Instruction templates...
 415 //
 416
 417 class RI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 418       : I<o, F, outs, ins, asm, pattern>, REX_W;
 419 class RIi8 <bits<8> o, Format F, dag outs, dag ins, string asm,
 420             list<dag> pattern>
 421       : Ii8<o, F, outs, ins, asm, pattern>, REX_W;
 422 class RIi32 <bits<8> o, Format F, dag outs, dag ins, string asm,
 423              list<dag> pattern>
 424       : Ii32<o, F, outs, ins, asm, pattern>, REX_W;
 425
 426 class RIi64<bits<8> o, Format f, dag outs, dag ins, string asm,
 427             list<dag> pattern>
 428   : X86Inst<o, f, Imm64, outs, ins, asm>, REX_W {
 429   let Pattern = pattern;
 430   let CodeSize = 3;
 431 }
 432
 433 class RSSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 434            list<dag> pattern>
 435       : SSI<o, F, outs, ins, asm, pattern>, REX_W;
 436 class RSDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 437            list<dag> pattern>
 438       : SDI<o, F, outs, ins, asm, pattern>, REX_W;
 439 class RPDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 440            list<dag> pattern>
 441       : PDI<o, F, outs, ins, asm, pattern>, REX_W;
 442
 443 // MMX Instruction templates
 444 //
 445
 446 // MMXI   - MMX instructions with TB prefix.
 447 // MMXI64 - MMX instructions with TB prefix valid only in 64 bit mode.
 448 // MMX2I  - MMX / SSE2 instructions with TB and OpSize prefixes.
 449 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 450 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 451 // MMXID  - MMX instructions with XD prefix.
 452 // MMXIS  - MMX instructions with XS prefix.
 453 class MMXI<bits<8> o, Format F, dag outs, dag ins, string asm,
 454            list<dag> pattern>
 455       : I<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX]>;
 456 class MMXI64<bits<8> o, Format F, dag outs, dag ins, string asm,
 457              list<dag> pattern>
 458       : I<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX,In64BitMode]>;
 459 class MMXRI<bits<8> o, Format F, dag outs, dag ins, string asm,
 460             list<dag> pattern>
 461       : I<o, F, outs, ins, asm, pattern>, TB, REX_W, Requires<[HasMMX]>;
 462 class MMX2I<bits<8> o, Format F, dag outs, dag ins, string asm,
 463             list<dag> pattern>
 464       : I<o, F, outs, ins, asm, pattern>, TB, OpSize, Requires<[HasMMX]>;
 465 class MMXIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 466              list<dag> pattern>
 467       : Ii8<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX]>;
 468 class MMXID<bits<8> o, Format F, dag outs, dag ins, string asm,
 469             list<dag> pattern>
 470       : Ii8<o, F, outs, ins, asm, pattern>, XD, Requires<[HasMMX]>;
 471 class MMXIS<bits<8> o, Format F, dag outs, dag ins, string asm,
 472             list<dag> pattern>
 473       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasMMX]>;