lib/Target/X86/X86InstrFPStack.td

   1 //==- X86InstrFPStack.td - Describe the X86 Instruction Set --*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 x87 FPU instruction set, defining the
  11 // instructions, and properties of the instructions which are needed for code
  12 // generation, machine code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // FPStack specific DAG Nodes.
  18 //===----------------------------------------------------------------------===//
  19
  20 def SDTX86FpGet2    : SDTypeProfile<2, 0, [SDTCisVT<0, f80>,
  21                                            SDTCisVT<1, f80>]>;
  22 def SDTX86Fld       : SDTypeProfile<1, 2, [SDTCisFP<0>,
  23                                            SDTCisPtrTy<1>,
  24                                            SDTCisVT<2, OtherVT>]>;
  25 def SDTX86Fst       : SDTypeProfile<0, 3, [SDTCisFP<0>,
  26                                            SDTCisPtrTy<1>,
  27                                            SDTCisVT<2, OtherVT>]>;
  28 def SDTX86Fild      : SDTypeProfile<1, 2, [SDTCisFP<0>, SDTCisPtrTy<1>,
  29                                            SDTCisVT<2, OtherVT>]>;
  30 def SDTX86FpToIMem  : SDTypeProfile<0, 2, [SDTCisFP<0>, SDTCisPtrTy<1>]>;
  31
  32 def SDTX86CwdStore  : SDTypeProfile<0, 1, [SDTCisPtrTy<0>]>;
  33
  34 def X86fld          : SDNode<"X86ISD::FLD", SDTX86Fld,
  35                              [SDNPHasChain, SDNPMayLoad]>;
  36 def X86fst          : SDNode<"X86ISD::FST", SDTX86Fst,
  37                              [SDNPHasChain, SDNPInFlag, SDNPMayStore]>;
  38 def X86fild         : SDNode<"X86ISD::FILD", SDTX86Fild,
  39                              [SDNPHasChain, SDNPMayLoad]>;
  40 def X86fildflag     : SDNode<"X86ISD::FILD_FLAG", SDTX86Fild,
  41                              [SDNPHasChain, SDNPOutFlag, SDNPMayLoad]>;
  42 def X86fp_to_i16mem : SDNode<"X86ISD::FP_TO_INT16_IN_MEM", SDTX86FpToIMem,
  43                              [SDNPHasChain, SDNPMayStore]>;
  44 def X86fp_to_i32mem : SDNode<"X86ISD::FP_TO_INT32_IN_MEM", SDTX86FpToIMem,
  45                              [SDNPHasChain, SDNPMayStore]>;
  46 def X86fp_to_i64mem : SDNode<"X86ISD::FP_TO_INT64_IN_MEM", SDTX86FpToIMem,
  47                              [SDNPHasChain, SDNPMayStore]>;
  48 def X86fp_cwd_get16 : SDNode<"X86ISD::FNSTCW16m",          SDTX86CwdStore,
  49                              [SDNPHasChain, SDNPMayStore, SDNPSideEffect]>;
  50
  51 //===----------------------------------------------------------------------===//
  52 // FPStack pattern fragments
  53 //===----------------------------------------------------------------------===//
  54
  55 def fpimm0 : PatLeaf<(fpimm), [{
  56   return N->isExactlyValue(+0.0);
  57 }]>;
  58
  59 def fpimmneg0 : PatLeaf<(fpimm), [{
  60   return N->isExactlyValue(-0.0);
  61 }]>;
  62
  63 def fpimm1 : PatLeaf<(fpimm), [{
  64   return N->isExactlyValue(+1.0);
  65 }]>;
  66
  67 def fpimmneg1 : PatLeaf<(fpimm), [{
  68   return N->isExactlyValue(-1.0);
  69 }]>;
  70
  71 // Some 'special' instructions
  72 let usesCustomInserter = 1 in {  // Expanded after instruction selection.
  73   def FP32_TO_INT16_IN_MEM : I<0, Pseudo,
  74                               (outs), (ins i16mem:$dst, RFP32:$src),
  75                               "##FP32_TO_INT16_IN_MEM PSEUDO!",
  76                               [(X86fp_to_i16mem RFP32:$src, addr:$dst)]>;
  77   def FP32_TO_INT32_IN_MEM : I<0, Pseudo,
  78                               (outs), (ins i32mem:$dst, RFP32:$src),
  79                               "##FP32_TO_INT32_IN_MEM PSEUDO!",
  80                               [(X86fp_to_i32mem RFP32:$src, addr:$dst)]>;
  81   def FP32_TO_INT64_IN_MEM : I<0, Pseudo,
  82                               (outs), (ins i64mem:$dst, RFP32:$src),
  83                               "##FP32_TO_INT64_IN_MEM PSEUDO!",
  84                               [(X86fp_to_i64mem RFP32:$src, addr:$dst)]>;
  85   def FP64_TO_INT16_IN_MEM : I<0, Pseudo,
  86                               (outs), (ins i16mem:$dst, RFP64:$src),
  87                               "##FP64_TO_INT16_IN_MEM PSEUDO!",
  88                               [(X86fp_to_i16mem RFP64:$src, addr:$dst)]>;
  89   def FP64_TO_INT32_IN_MEM : I<0, Pseudo,
  90                               (outs), (ins i32mem:$dst, RFP64:$src),
  91                               "##FP64_TO_INT32_IN_MEM PSEUDO!",
  92                               [(X86fp_to_i32mem RFP64:$src, addr:$dst)]>;
  93   def FP64_TO_INT64_IN_MEM : I<0, Pseudo,
  94                               (outs), (ins i64mem:$dst, RFP64:$src),
  95                               "##FP64_TO_INT64_IN_MEM PSEUDO!",
  96                               [(X86fp_to_i64mem RFP64:$src, addr:$dst)]>;
  97   def FP80_TO_INT16_IN_MEM : I<0, Pseudo,
  98                               (outs), (ins i16mem:$dst, RFP80:$src),
  99                               "##FP80_TO_INT16_IN_MEM PSEUDO!",
 100                               [(X86fp_to_i16mem RFP80:$src, addr:$dst)]>;
 101   def FP80_TO_INT32_IN_MEM : I<0, Pseudo,
 102                               (outs), (ins i32mem:$dst, RFP80:$src),
 103                               "##FP80_TO_INT32_IN_MEM PSEUDO!",
 104                               [(X86fp_to_i32mem RFP80:$src, addr:$dst)]>;
 105   def FP80_TO_INT64_IN_MEM : I<0, Pseudo,
 106                               (outs), (ins i64mem:$dst, RFP80:$src),
 107                               "##FP80_TO_INT64_IN_MEM PSEUDO!",
 108                               [(X86fp_to_i64mem RFP80:$src, addr:$dst)]>;
 109 }
 110
 111 let isTerminator = 1 in
 112   let Defs = [FP0, FP1, FP2, FP3, FP4, FP5, FP6] in
 113     def FP_REG_KILL  : I<0, Pseudo, (outs), (ins), "##FP_REG_KILL", []>;
 114
 115 // All FP Stack operations are represented with four instructions here.  The
 116 // first three instructions, generated by the instruction selector, use "RFP32"
 117 // "RFP64" or "RFP80" registers: traditional register files to reference 32-bit,
 118 // 64-bit or 80-bit floating point values.  These sizes apply to the values,
 119 // not the registers, which are always 80 bits; RFP32, RFP64 and RFP80 can be
 120 // copied to each other without losing information.  These instructions are all
 121 // pseudo instructions and use the "_Fp" suffix.
 122 // In some cases there are additional variants with a mixture of different
 123 // register sizes.
 124 // The second instruction is defined with FPI, which is the actual instruction
 125 // emitted by the assembler.  These use "RST" registers, although frequently
 126 // the actual register(s) used are implicit.  These are always 80 bits.
 127 // The FP stackifier pass converts one to the other after register allocation
 128 // occurs.
 129 //
 130 // Note that the FpI instruction should have instruction selection info (e.g.
 131 // a pattern) and the FPI instruction should have emission info (e.g. opcode
 132 // encoding and asm printing info).
 133
 134 // Pseudo Instructions for FP stack return values.
 135 def FpGET_ST0_32 : FpI_<(outs RFP32:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 136 def FpGET_ST0_64 : FpI_<(outs RFP64:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 137 def FpGET_ST0_80 : FpI_<(outs RFP80:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 138
 139 // FpGET_ST1* should only be issued *after* an FpGET_ST0* has been issued when
 140 // there are two values live out on the stack from a call or inlineasm.  This
 141 // magic is handled by the stackifier.  It is not valid to emit FpGET_ST1* and
 142 // then FpGET_ST0*.  In addition, it is invalid for any FP-using operations to
 143 // occur between them.
 144 def FpGET_ST1_32 : FpI_<(outs RFP32:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 145 def FpGET_ST1_64 : FpI_<(outs RFP64:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 146 def FpGET_ST1_80 : FpI_<(outs RFP80:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 147
 148 let Defs = [ST0] in {
 149 def FpSET_ST0_32 : FpI_<(outs), (ins RFP32:$src), SpecialFP, []>; // ST(0) = FPR
 150 def FpSET_ST0_64 : FpI_<(outs), (ins RFP64:$src), SpecialFP, []>; // ST(0) = FPR
 151 def FpSET_ST0_80 : FpI_<(outs), (ins RFP80:$src), SpecialFP, []>; // ST(0) = FPR
 152 }
 153
 154 let Defs = [ST1] in {
 155 def FpSET_ST1_32 : FpI_<(outs), (ins RFP32:$src), SpecialFP, []>; // ST(1) = FPR
 156 def FpSET_ST1_64 : FpI_<(outs), (ins RFP64:$src), SpecialFP, []>; // ST(1) = FPR
 157 def FpSET_ST1_80 : FpI_<(outs), (ins RFP80:$src), SpecialFP, []>; // ST(1) = FPR
 158 }
 159
 160 // FpIf32, FpIf64 - Floating Point Psuedo Instruction template.
 161 // f32 instructions can use SSE1 and are predicated on FPStackf32 == !SSE1.
 162 // f64 instructions can use SSE2 and are predicated on FPStackf64 == !SSE2.
 163 // f80 instructions cannot use SSE and use neither of these.
 164 class FpIf32<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 165   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf32]>;
 166 class FpIf64<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 167   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf64]>;
 168
 169 // Register copies.  Just copies, the shortening ones do not truncate.
 170 let neverHasSideEffects = 1 in {
 171   def MOV_Fp3232 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src), SpecialFP, []>;
 172   def MOV_Fp3264 : FpIf32<(outs RFP64:$dst), (ins RFP32:$src), SpecialFP, []>;
 173   def MOV_Fp6432 : FpIf32<(outs RFP32:$dst), (ins RFP64:$src), SpecialFP, []>;
 174   def MOV_Fp6464 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src), SpecialFP, []>;
 175   def MOV_Fp8032 : FpIf32<(outs RFP32:$dst), (ins RFP80:$src), SpecialFP, []>;
 176   def MOV_Fp3280 : FpIf32<(outs RFP80:$dst), (ins RFP32:$src), SpecialFP, []>;
 177   def MOV_Fp8064 : FpIf64<(outs RFP64:$dst), (ins RFP80:$src), SpecialFP, []>;
 178   def MOV_Fp6480 : FpIf64<(outs RFP80:$dst), (ins RFP64:$src), SpecialFP, []>;
 179   def MOV_Fp8080 : FpI_  <(outs RFP80:$dst), (ins RFP80:$src), SpecialFP, []>;
 180 }
 181
 182 // Factoring for arithmetic.
 183 multiclass FPBinary_rr<SDNode OpNode> {
 184 // Register op register -> register
 185 // These are separated out because they have no reversed form.
 186 def _Fp32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2), TwoArgFP,
 187                 [(set RFP32:$dst, (OpNode RFP32:$src1, RFP32:$src2))]>;
 188 def _Fp64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2), TwoArgFP,
 189                 [(set RFP64:$dst, (OpNode RFP64:$src1, RFP64:$src2))]>;
 190 def _Fp80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2), TwoArgFP,
 191                 [(set RFP80:$dst, (OpNode RFP80:$src1, RFP80:$src2))]>;
 192 }
 193 // The FopST0 series are not included here because of the irregularities
 194 // in where the 'r' goes in assembly output.
 195 // These instructions cannot address 80-bit memory.
 196 multiclass FPBinary<SDNode OpNode, Format fp, string asmstring> {
 197 // ST(0) = ST(0) + [mem]
 198 def _Fp32m  : FpIf32<(outs RFP32:$dst),
 199                      (ins RFP32:$src1, f32mem:$src2), OneArgFPRW,
 200                   [(set RFP32:$dst,
 201                     (OpNode RFP32:$src1, (loadf32 addr:$src2)))]>;
 202 def _Fp64m  : FpIf64<(outs RFP64:$dst),
 203                      (ins RFP64:$src1, f64mem:$src2), OneArgFPRW,
 204                   [(set RFP64:$dst,
 205                     (OpNode RFP64:$src1, (loadf64 addr:$src2)))]>;
 206 def _Fp64m32: FpIf64<(outs RFP64:$dst),
 207                      (ins RFP64:$src1, f32mem:$src2), OneArgFPRW,
 208                   [(set RFP64:$dst,
 209                     (OpNode RFP64:$src1, (f64 (extloadf32 addr:$src2))))]>;
 210 def _Fp80m32: FpI_<(outs RFP80:$dst),
 211                    (ins RFP80:$src1, f32mem:$src2), OneArgFPRW,
 212                   [(set RFP80:$dst,
 213                     (OpNode RFP80:$src1, (f80 (extloadf32 addr:$src2))))]>;
 214 def _Fp80m64: FpI_<(outs RFP80:$dst),
 215                    (ins RFP80:$src1, f64mem:$src2), OneArgFPRW,
 216                   [(set RFP80:$dst,
 217                     (OpNode RFP80:$src1, (f80 (extloadf64 addr:$src2))))]>;
 218 def _F32m  : FPI<0xD8, fp, (outs), (ins f32mem:$src),
 219                  !strconcat("f", !strconcat(asmstring, "{s}\t$src"))> {
 220   let mayLoad = 1;
 221 }
 222 def _F64m  : FPI<0xDC, fp, (outs), (ins f64mem:$src),
 223                  !strconcat("f", !strconcat(asmstring, "{l}\t$src"))> {
 224   let mayLoad = 1;
 225 }
 226 // ST(0) = ST(0) + [memint]
 227 def _FpI16m32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, i16mem:$src2),
 228                        OneArgFPRW,
 229                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 230                                        (X86fild addr:$src2, i16)))]>;
 231 def _FpI32m32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, i32mem:$src2),
 232                        OneArgFPRW,
 233                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 234                                        (X86fild addr:$src2, i32)))]>;
 235 def _FpI16m64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, i16mem:$src2),
 236                        OneArgFPRW,
 237                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 238                                        (X86fild addr:$src2, i16)))]>;
 239 def _FpI32m64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, i32mem:$src2),
 240                        OneArgFPRW,
 241                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 242                                        (X86fild addr:$src2, i32)))]>;
 243 def _FpI16m80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, i16mem:$src2),
 244                        OneArgFPRW,
 245                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 246                                        (X86fild addr:$src2, i16)))]>;
 247 def _FpI32m80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, i32mem:$src2),
 248                        OneArgFPRW,
 249                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 250                                        (X86fild addr:$src2, i32)))]>;
 251 def _FI16m  : FPI<0xDE, fp, (outs), (ins i16mem:$src),
 252                   !strconcat("fi", !strconcat(asmstring, "{s}\t$src"))> {
 253   let mayLoad = 1;
 254 }
 255 def _FI32m  : FPI<0xDA, fp, (outs), (ins i32mem:$src),
 256                   !strconcat("fi", !strconcat(asmstring, "{l}\t$src"))> {
 257   let mayLoad = 1;
 258 }
 259 }
 260
 261 defm ADD : FPBinary_rr<fadd>;
 262 defm SUB : FPBinary_rr<fsub>;
 263 defm MUL : FPBinary_rr<fmul>;
 264 defm DIV : FPBinary_rr<fdiv>;
 265 defm ADD : FPBinary<fadd, MRM0m, "add">;
 266 defm SUB : FPBinary<fsub, MRM4m, "sub">;
 267 defm SUBR: FPBinary<fsub ,MRM5m, "subr">;
 268 defm MUL : FPBinary<fmul, MRM1m, "mul">;
 269 defm DIV : FPBinary<fdiv, MRM6m, "div">;
 270 defm DIVR: FPBinary<fdiv, MRM7m, "divr">;
 271
 272 class FPST0rInst<bits<8> o, string asm>
 273   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, D8;
 274 class FPrST0Inst<bits<8> o, string asm>
 275   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DC;
 276 class FPrST0PInst<bits<8> o, string asm>
 277   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DE;
 278
 279 // NOTE: GAS and apparently all other AT&T style assemblers have a broken notion
 280 // of some of the 'reverse' forms of the fsub and fdiv instructions.  As such,
 281 // we have to put some 'r's in and take them out of weird places.
 282 def ADD_FST0r   : FPST0rInst <0xC0, "fadd\t$op">;
 283 def ADD_FrST0   : FPrST0Inst <0xC0, "fadd\t{%st(0), $op|$op, %ST(0)}">;
 284 def ADD_FPrST0  : FPrST0PInst<0xC0, "faddp\t$op">;
 285 def SUBR_FST0r  : FPST0rInst <0xE8, "fsubr\t$op">;
 286 def SUB_FrST0   : FPrST0Inst <0xE8, "fsub{r}\t{%st(0), $op|$op, %ST(0)}">;
 287 def SUB_FPrST0  : FPrST0PInst<0xE8, "fsub{r}p\t$op">;
 288 def SUB_FST0r   : FPST0rInst <0xE0, "fsub\t$op">;
 289 def SUBR_FrST0  : FPrST0Inst <0xE0, "fsub{|r}\t{%st(0), $op|$op, %ST(0)}">;
 290 def SUBR_FPrST0 : FPrST0PInst<0xE0, "fsub{|r}p\t$op">;
 291 def MUL_FST0r   : FPST0rInst <0xC8, "fmul\t$op">;
 292 def MUL_FrST0   : FPrST0Inst <0xC8, "fmul\t{%st(0), $op|$op, %ST(0)}">;
 293 def MUL_FPrST0  : FPrST0PInst<0xC8, "fmulp\t$op">;
 294 def DIVR_FST0r  : FPST0rInst <0xF8, "fdivr\t$op">;
 295 def DIV_FrST0   : FPrST0Inst <0xF8, "fdiv{r}\t{%st(0), $op|$op, %ST(0)}">;
 296 def DIV_FPrST0  : FPrST0PInst<0xF8, "fdiv{r}p\t$op">;
 297 def DIV_FST0r   : FPST0rInst <0xF0, "fdiv\t$op">;
 298 def DIVR_FrST0  : FPrST0Inst <0xF0, "fdiv{|r}\t{%st(0), $op|$op, %ST(0)}">;
 299 def DIVR_FPrST0 : FPrST0PInst<0xF0, "fdiv{|r}p\t$op">;
 300
 301 def COM_FST0r   : FPST0rInst <0xD0, "fcom\t$op">;
 302 def COMP_FST0r  : FPST0rInst <0xD8, "fcomp\t$op">;
 303
 304 // Unary operations.
 305 multiclass FPUnary<SDNode OpNode, bits<8> opcode, string asmstring> {
 306 def _Fp32  : FpIf32<(outs RFP32:$dst), (ins RFP32:$src), OneArgFPRW,
 307                  [(set RFP32:$dst, (OpNode RFP32:$src))]>;
 308 def _Fp64  : FpIf64<(outs RFP64:$dst), (ins RFP64:$src), OneArgFPRW,
 309                  [(set RFP64:$dst, (OpNode RFP64:$src))]>;
 310 def _Fp80  : FpI_<(outs RFP80:$dst), (ins RFP80:$src), OneArgFPRW,
 311                  [(set RFP80:$dst, (OpNode RFP80:$src))]>;
 312 def _F     : FPI<opcode, RawFrm, (outs), (ins), asmstring>, D9;
 313 }
 314
 315 defm CHS : FPUnary<fneg, 0xE0, "fchs">;
 316 defm ABS : FPUnary<fabs, 0xE1, "fabs">;
 317 defm SQRT: FPUnary<fsqrt,0xFA, "fsqrt">;
 318 defm SIN : FPUnary<fsin, 0xFE, "fsin">;
 319 defm COS : FPUnary<fcos, 0xFF, "fcos">;
 320
 321 let neverHasSideEffects = 1 in {
 322 def TST_Fp32  : FpIf32<(outs), (ins RFP32:$src), OneArgFP, []>;
 323 def TST_Fp64  : FpIf64<(outs), (ins RFP64:$src), OneArgFP, []>;
 324 def TST_Fp80  : FpI_<(outs), (ins RFP80:$src), OneArgFP, []>;
 325 }
 326 def TST_F  : FPI<0xE4, RawFrm, (outs), (ins), "ftst">, D9;
 327
 328 // Versions of FP instructions that take a single memory operand.  Added for the
 329 //   disassembler; remove as they are included with patterns elsewhere.
 330 def FCOM32m  : FPI<0xD8, MRM2m, (outs), (ins f32mem:$src), "fcom{l}\t$src">;
 331 def FCOMP32m : FPI<0xD8, MRM3m, (outs), (ins f32mem:$src), "fcomp{l}\t$src">;
 332
 333 def FLDENVm  : FPI<0xD9, MRM4m, (outs), (ins f32mem:$src), "fldenv\t$src">;
 334 def FSTENVm  : FPI<0xD9, MRM6m, (outs f32mem:$dst), (ins), "fnstenv\t$dst">;
 335
 336 def FICOM32m : FPI<0xDA, MRM2m, (outs), (ins i32mem:$src), "ficom{l}\t$src">;
 337 def FICOMP32m: FPI<0xDA, MRM3m, (outs), (ins i32mem:$src), "ficomp{l}\t$src">;
 338
 339 def FCOM64m  : FPI<0xDC, MRM2m, (outs), (ins f64mem:$src), "fcom{ll}\t$src">;
 340 def FCOMP64m : FPI<0xDC, MRM3m, (outs), (ins f64mem:$src), "fcomp{ll}\t$src">;
 341
 342 def FRSTORm  : FPI<0xDD, MRM4m, (outs f32mem:$dst), (ins), "frstor\t$dst">;
 343 def FSAVEm   : FPI<0xDD, MRM6m, (outs f32mem:$dst), (ins), "fnsave\t$dst">;
 344 def FNSTSWm  : FPI<0xDD, MRM7m, (outs f32mem:$dst), (ins), "fnstsw\t$dst">;
 345
 346 def FICOM16m : FPI<0xDE, MRM2m, (outs), (ins i16mem:$src), "ficom{w}\t$src">;
 347 def FICOMP16m: FPI<0xDE, MRM3m, (outs), (ins i16mem:$src), "ficomp{w}\t$src">;
 348
 349 def FBLDm    : FPI<0xDF, MRM4m, (outs), (ins f32mem:$src), "fbld\t$src">;
 350 def FBSTPm   : FPI<0xDF, MRM6m, (outs f32mem:$dst), (ins), "fbstp\t$dst">;
 351
 352 // Floating point cmovs.
 353 class FpIf32CMov<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 354   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf32, HasCMov]>;
 355 class FpIf64CMov<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 356   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf64, HasCMov]>;
 357
 358 multiclass FPCMov<PatLeaf cc> {
 359   def _Fp32  : FpIf32CMov<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2),
 360                        CondMovFP,
 361                      [(set RFP32:$dst, (X86cmov RFP32:$src1, RFP32:$src2,
 362                                         cc, EFLAGS))]>;
 363   def _Fp64  : FpIf64CMov<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2),
 364                        CondMovFP,
 365                      [(set RFP64:$dst, (X86cmov RFP64:$src1, RFP64:$src2,
 366                                         cc, EFLAGS))]>;
 367   def _Fp80  : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2),
 368                      CondMovFP,
 369                      [(set RFP80:$dst, (X86cmov RFP80:$src1, RFP80:$src2,
 370                                         cc, EFLAGS))]>,
 371                                         Requires<[HasCMov]>;
 372 }
 373
 374 let Uses = [EFLAGS], isTwoAddress = 1 in {
 375 defm CMOVB  : FPCMov<X86_COND_B>;
 376 defm CMOVBE : FPCMov<X86_COND_BE>;
 377 defm CMOVE  : FPCMov<X86_COND_E>;
 378 defm CMOVP  : FPCMov<X86_COND_P>;
 379 defm CMOVNB : FPCMov<X86_COND_AE>;
 380 defm CMOVNBE: FPCMov<X86_COND_A>;
 381 defm CMOVNE : FPCMov<X86_COND_NE>;
 382 defm CMOVNP : FPCMov<X86_COND_NP>;
 383 }
 384
 385 let Predicates = [HasCMov] in {
 386 // These are not factored because there's no clean way to pass DA/DB.
 387 def CMOVB_F  : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 388                   "fcmovb\t{$op, %st(0)|%ST(0), $op}">, DA;
 389 def CMOVBE_F : FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 390                   "fcmovbe\t{$op, %st(0)|%ST(0), $op}">, DA;
 391 def CMOVE_F  : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 392                   "fcmove\t{$op, %st(0)|%ST(0), $op}">, DA;
 393 def CMOVP_F  : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 394                   "fcmovu\t {$op, %st(0)|%ST(0), $op}">, DA;
 395 def CMOVNB_F : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 396                   "fcmovnb\t{$op, %st(0)|%ST(0), $op}">, DB;
 397 def CMOVNBE_F: FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 398                   "fcmovnbe\t{$op, %st(0)|%ST(0), $op}">, DB;
 399 def CMOVNE_F : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 400                   "fcmovne\t{$op, %st(0)|%ST(0), $op}">, DB;
 401 def CMOVNP_F : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 402                   "fcmovnu\t{$op, %st(0)|%ST(0), $op}">, DB;
 403 } // Predicates = [HasCMov]
 404
 405 // Floating point loads & stores.
 406 let canFoldAsLoad = 1 in {
 407 def LD_Fp32m   : FpIf32<(outs RFP32:$dst), (ins f32mem:$src), ZeroArgFP,
 408                   [(set RFP32:$dst, (loadf32 addr:$src))]>;
 409 let isReMaterializable = 1 in
 410   def LD_Fp64m : FpIf64<(outs RFP64:$dst), (ins f64mem:$src), ZeroArgFP,
 411                   [(set RFP64:$dst, (loadf64 addr:$src))]>;
 412 def LD_Fp80m   : FpI_<(outs RFP80:$dst), (ins f80mem:$src), ZeroArgFP,
 413                   [(set RFP80:$dst, (loadf80 addr:$src))]>;
 414 }
 415 def LD_Fp32m64 : FpIf64<(outs RFP64:$dst), (ins f32mem:$src), ZeroArgFP,
 416                   [(set RFP64:$dst, (f64 (extloadf32 addr:$src)))]>;
 417 def LD_Fp64m80 : FpI_<(outs RFP80:$dst), (ins f64mem:$src), ZeroArgFP,
 418                   [(set RFP80:$dst, (f80 (extloadf64 addr:$src)))]>;
 419 def LD_Fp32m80 : FpI_<(outs RFP80:$dst), (ins f32mem:$src), ZeroArgFP,
 420                   [(set RFP80:$dst, (f80 (extloadf32 addr:$src)))]>;
 421 def ILD_Fp16m32: FpIf32<(outs RFP32:$dst), (ins i16mem:$src), ZeroArgFP,
 422                   [(set RFP32:$dst, (X86fild addr:$src, i16))]>;
 423 def ILD_Fp32m32: FpIf32<(outs RFP32:$dst), (ins i32mem:$src), ZeroArgFP,
 424                   [(set RFP32:$dst, (X86fild addr:$src, i32))]>;
 425 def ILD_Fp64m32: FpIf32<(outs RFP32:$dst), (ins i64mem:$src), ZeroArgFP,
 426                   [(set RFP32:$dst, (X86fild addr:$src, i64))]>;
 427 def ILD_Fp16m64: FpIf64<(outs RFP64:$dst), (ins i16mem:$src), ZeroArgFP,
 428                   [(set RFP64:$dst, (X86fild addr:$src, i16))]>;
 429 def ILD_Fp32m64: FpIf64<(outs RFP64:$dst), (ins i32mem:$src), ZeroArgFP,
 430                   [(set RFP64:$dst, (X86fild addr:$src, i32))]>;
 431 def ILD_Fp64m64: FpIf64<(outs RFP64:$dst), (ins i64mem:$src), ZeroArgFP,
 432                   [(set RFP64:$dst, (X86fild addr:$src, i64))]>;
 433 def ILD_Fp16m80: FpI_<(outs RFP80:$dst), (ins i16mem:$src), ZeroArgFP,
 434                   [(set RFP80:$dst, (X86fild addr:$src, i16))]>;
 435 def ILD_Fp32m80: FpI_<(outs RFP80:$dst), (ins i32mem:$src), ZeroArgFP,
 436                   [(set RFP80:$dst, (X86fild addr:$src, i32))]>;
 437 def ILD_Fp64m80: FpI_<(outs RFP80:$dst), (ins i64mem:$src), ZeroArgFP,
 438                   [(set RFP80:$dst, (X86fild addr:$src, i64))]>;
 439
 440 def ST_Fp32m   : FpIf32<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP,
 441                   [(store RFP32:$src, addr:$op)]>;
 442 def ST_Fp64m32 : FpIf64<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP,
 443                   [(truncstoref32 RFP64:$src, addr:$op)]>;
 444 def ST_Fp64m   : FpIf64<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP,
 445                   [(store RFP64:$src, addr:$op)]>;
 446 def ST_Fp80m32 : FpI_<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP,
 447                   [(truncstoref32 RFP80:$src, addr:$op)]>;
 448 def ST_Fp80m64 : FpI_<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP,
 449                   [(truncstoref64 RFP80:$src, addr:$op)]>;
 450 // FST does not support 80-bit memory target; FSTP must be used.
 451
 452 let mayStore = 1, neverHasSideEffects = 1 in {
 453 def ST_FpP32m    : FpIf32<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP, []>;
 454 def ST_FpP64m32  : FpIf64<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP, []>;
 455 def ST_FpP64m    : FpIf64<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP, []>;
 456 def ST_FpP80m32  : FpI_<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP, []>;
 457 def ST_FpP80m64  : FpI_<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP, []>;
 458 }
 459 def ST_FpP80m    : FpI_<(outs), (ins f80mem:$op, RFP80:$src), OneArgFP,
 460                     [(store RFP80:$src, addr:$op)]>;
 461 let mayStore = 1, neverHasSideEffects = 1 in {
 462 def IST_Fp16m32  : FpIf32<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP, []>;
 463 def IST_Fp32m32  : FpIf32<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP, []>;
 464 def IST_Fp64m32  : FpIf32<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP, []>;
 465 def IST_Fp16m64  : FpIf64<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP, []>;
 466 def IST_Fp32m64  : FpIf64<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP, []>;
 467 def IST_Fp64m64  : FpIf64<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP, []>;
 468 def IST_Fp16m80  : FpI_<(outs), (ins i16mem:$op, RFP80:$src), OneArgFP, []>;
 469 def IST_Fp32m80  : FpI_<(outs), (ins i32mem:$op, RFP80:$src), OneArgFP, []>;
 470 def IST_Fp64m80  : FpI_<(outs), (ins i64mem:$op, RFP80:$src), OneArgFP, []>;
 471 }
 472
 473 let mayLoad = 1 in {
 474 def LD_F32m   : FPI<0xD9, MRM0m, (outs), (ins f32mem:$src), "fld{s}\t$src">;
 475 def LD_F64m   : FPI<0xDD, MRM0m, (outs), (ins f64mem:$src), "fld{l}\t$src">;
 476 def LD_F80m   : FPI<0xDB, MRM5m, (outs), (ins f80mem:$src), "fld{t}\t$src">;
 477 def ILD_F16m  : FPI<0xDF, MRM0m, (outs), (ins i16mem:$src), "fild{s}\t$src">;
 478 def ILD_F32m  : FPI<0xDB, MRM0m, (outs), (ins i32mem:$src), "fild{l}\t$src">;
 479 def ILD_F64m  : FPI<0xDF, MRM5m, (outs), (ins i64mem:$src), "fild{ll}\t$src">;
 480 }
 481 let mayStore = 1 in {
 482 def ST_F32m   : FPI<0xD9, MRM2m, (outs), (ins f32mem:$dst), "fst{s}\t$dst">;
 483 def ST_F64m   : FPI<0xDD, MRM2m, (outs), (ins f64mem:$dst), "fst{l}\t$dst">;
 484 def ST_FP32m  : FPI<0xD9, MRM3m, (outs), (ins f32mem:$dst), "fstp{s}\t$dst">;
 485 def ST_FP64m  : FPI<0xDD, MRM3m, (outs), (ins f64mem:$dst), "fstp{l}\t$dst">;
 486 def ST_FP80m  : FPI<0xDB, MRM7m, (outs), (ins f80mem:$dst), "fstp{t}\t$dst">;
 487 def IST_F16m  : FPI<0xDF, MRM2m, (outs), (ins i16mem:$dst), "fist{s}\t$dst">;
 488 def IST_F32m  : FPI<0xDB, MRM2m, (outs), (ins i32mem:$dst), "fist{l}\t$dst">;
 489 def IST_FP16m : FPI<0xDF, MRM3m, (outs), (ins i16mem:$dst), "fistp{s}\t$dst">;
 490 def IST_FP32m : FPI<0xDB, MRM3m, (outs), (ins i32mem:$dst), "fistp{l}\t$dst">;
 491 def IST_FP64m : FPI<0xDF, MRM7m, (outs), (ins i64mem:$dst), "fistp{ll}\t$dst">;
 492 }
 493
 494 // FISTTP requires SSE3 even though it's a FPStack op.
 495 def ISTT_Fp16m32 : FpI_<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP,
 496                     [(X86fp_to_i16mem RFP32:$src, addr:$op)]>,
 497                     Requires<[HasSSE3]>;
 498 def ISTT_Fp32m32 : FpI_<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP,
 499                     [(X86fp_to_i32mem RFP32:$src, addr:$op)]>,
 500                     Requires<[HasSSE3]>;
 501 def ISTT_Fp64m32 : FpI_<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP,
 502                     [(X86fp_to_i64mem RFP32:$src, addr:$op)]>,
 503                     Requires<[HasSSE3]>;
 504 def ISTT_Fp16m64 : FpI_<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP,
 505                     [(X86fp_to_i16mem RFP64:$src, addr:$op)]>,
 506                     Requires<[HasSSE3]>;
 507 def ISTT_Fp32m64 : FpI_<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP,
 508                     [(X86fp_to_i32mem RFP64:$src, addr:$op)]>,
 509                     Requires<[HasSSE3]>;
 510 def ISTT_Fp64m64 : FpI_<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP,
 511                     [(X86fp_to_i64mem RFP64:$src, addr:$op)]>,
 512                     Requires<[HasSSE3]>;
 513 def ISTT_Fp16m80 : FpI_<(outs), (ins i16mem:$op, RFP80:$src), OneArgFP,
 514                     [(X86fp_to_i16mem RFP80:$src, addr:$op)]>,
 515                     Requires<[HasSSE3]>;
 516 def ISTT_Fp32m80 : FpI_<(outs), (ins i32mem:$op, RFP80:$src), OneArgFP,
 517                     [(X86fp_to_i32mem RFP80:$src, addr:$op)]>,
 518                     Requires<[HasSSE3]>;
 519 def ISTT_Fp64m80 : FpI_<(outs), (ins i64mem:$op, RFP80:$src), OneArgFP,
 520                     [(X86fp_to_i64mem RFP80:$src, addr:$op)]>,
 521                     Requires<[HasSSE3]>;
 522
 523 let mayStore = 1 in {
 524 def ISTT_FP16m : FPI<0xDF, MRM1m, (outs), (ins i16mem:$dst), "fisttp{s}\t$dst">;
 525 def ISTT_FP32m : FPI<0xDB, MRM1m, (outs), (ins i32mem:$dst), "fisttp{l}\t$dst">;
 526 def ISTT_FP64m : FPI<0xDD, MRM1m, (outs), (ins i64mem:$dst),
 527   "fisttp{ll}\t$dst">;
 528 }
 529
 530 // FP Stack manipulation instructions.
 531 def LD_Frr   : FPI<0xC0, AddRegFrm, (outs), (ins RST:$op), "fld\t$op">, D9;
 532 def ST_Frr   : FPI<0xD0, AddRegFrm, (outs), (ins RST:$op), "fst\t$op">, DD;
 533 def ST_FPrr  : FPI<0xD8, AddRegFrm, (outs), (ins RST:$op), "fstp\t$op">, DD;
 534 def XCH_F    : FPI<0xC8, AddRegFrm, (outs), (ins RST:$op), "fxch\t$op">, D9;
 535
 536 // Floating point constant loads.
 537 let isReMaterializable = 1 in {
 538 def LD_Fp032 : FpIf32<(outs RFP32:$dst), (ins), ZeroArgFP,
 539                 [(set RFP32:$dst, fpimm0)]>;
 540 def LD_Fp132 : FpIf32<(outs RFP32:$dst), (ins), ZeroArgFP,
 541                 [(set RFP32:$dst, fpimm1)]>;
 542 def LD_Fp064 : FpIf64<(outs RFP64:$dst), (ins), ZeroArgFP,
 543                 [(set RFP64:$dst, fpimm0)]>;
 544 def LD_Fp164 : FpIf64<(outs RFP64:$dst), (ins), ZeroArgFP,
 545                 [(set RFP64:$dst, fpimm1)]>;
 546 def LD_Fp080 : FpI_<(outs RFP80:$dst), (ins), ZeroArgFP,
 547                 [(set RFP80:$dst, fpimm0)]>;
 548 def LD_Fp180 : FpI_<(outs RFP80:$dst), (ins), ZeroArgFP,
 549                 [(set RFP80:$dst, fpimm1)]>;
 550 }
 551
 552 def LD_F0 : FPI<0xEE, RawFrm, (outs), (ins), "fldz">, D9;
 553 def LD_F1 : FPI<0xE8, RawFrm, (outs), (ins), "fld1">, D9;
 554
 555
 556 // Floating point compares.
 557 let Defs = [EFLAGS] in {
 558 def UCOM_Fpr32 : FpIf32<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 559                         []>;  // FPSW = cmp ST(0) with ST(i)
 560 def UCOM_Fpr64 : FpIf64<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 561                         []>;  // FPSW = cmp ST(0) with ST(i)
 562 def UCOM_Fpr80 : FpI_  <(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 563                         []>;  // FPSW = cmp ST(0) with ST(i)
 564
 565 def UCOM_FpIr32: FpIf32<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 566                   [(X86cmp RFP32:$lhs, RFP32:$rhs),
 567                    (implicit EFLAGS)]>; // CC = ST(0) cmp ST(i)
 568 def UCOM_FpIr64: FpIf64<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 569                   [(X86cmp RFP64:$lhs, RFP64:$rhs),
 570                    (implicit EFLAGS)]>; // CC = ST(0) cmp ST(i)
 571 def UCOM_FpIr80: FpI_<(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 572                   [(X86cmp RFP80:$lhs, RFP80:$rhs),
 573                    (implicit EFLAGS)]>; // CC = ST(0) cmp ST(i)
 574 }
 575
 576 let Defs = [EFLAGS], Uses = [ST0] in {
 577 def UCOM_Fr    : FPI<0xE0, AddRegFrm,    // FPSW = cmp ST(0) with ST(i)
 578                     (outs), (ins RST:$reg),
 579                     "fucom\t$reg">, DD;
 580 def UCOM_FPr   : FPI<0xE8, AddRegFrm,    // FPSW = cmp ST(0) with ST(i), pop
 581                     (outs), (ins RST:$reg),
 582                     "fucomp\t$reg">, DD;
 583 def UCOM_FPPr  : FPI<0xE9, RawFrm,       // cmp ST(0) with ST(1), pop, pop
 584                     (outs), (ins),
 585                     "fucompp">, DA;
 586
 587 def UCOM_FIr   : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i)
 588                     (outs), (ins RST:$reg),
 589                     "fucomi\t{$reg, %st(0)|%ST(0), $reg}">, DB;
 590 def UCOM_FIPr  : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i), pop
 591                     (outs), (ins RST:$reg),
 592                     "fucomip\t{$reg, %st(0)|%ST(0), $reg}">, DF;
 593 }
 594
 595 def COM_FIr : FPI<0xF0, AddRegFrm, (outs), (ins RST:$reg),
 596                   "fcomi\t{$reg, %st(0)|%ST(0), $reg}">, DB;
 597 def COM_FIPr : FPI<0xF0, AddRegFrm, (outs), (ins RST:$reg),
 598                    "fcomip\t{$reg, %st(0)|%ST(0), $reg}">, DF;
 599
 600 // Floating point flag ops.
 601 let Defs = [AX] in
 602 def FNSTSW8r  : I<0xE0, RawFrm,                  // AX = fp flags
 603                   (outs), (ins), "fnstsw %ax", []>, DF;
 604
 605 def FNSTCW16m : I<0xD9, MRM7m,                   // [mem16] = X87 control world
 606                   (outs), (ins i16mem:$dst), "fnstcw\t$dst",
 607                   [(X86fp_cwd_get16 addr:$dst)]>;
 608
 609 let mayLoad = 1 in
 610 def FLDCW16m  : I<0xD9, MRM5m,                   // X87 control world = [mem16]
 611                   (outs), (ins i16mem:$dst), "fldcw\t$dst", []>;
 612
 613 // Register free
 614
 615 def FFREE : FPI<0xC0, AddRegFrm, (outs), (ins RST:$reg),
 616                 "ffree\t$reg">, DD;
 617
 618 // Clear exceptions
 619
 620 def FNCLEX : I<0xE2, RawFrm, (outs), (ins), "fnclex", []>, DB;
 621
 622 // Operandless floating-point instructions for the disassembler
 623
 624 def FNOP : I<0xD0, RawFrm, (outs), (ins), "fnop", []>, D9;
 625 def FXAM : I<0xE5, RawFrm, (outs), (ins), "fxam", []>, D9;
 626 def FLDL2T : I<0xE9, RawFrm, (outs), (ins), "fldl2t", []>, D9;
 627 def FLDL2E : I<0xEA, RawFrm, (outs), (ins), "fldl2e", []>, D9;
 628 def FLDPI : I<0xEB, RawFrm, (outs), (ins), "fldpi", []>, D9;
 629 def FLDLG2 : I<0xEC, RawFrm, (outs), (ins), "fldlg2", []>, D9;
 630 def FLDLN2 : I<0xED, RawFrm, (outs), (ins), "fldln2", []>, D9;
 631 def F2XM1 : I<0xF0, RawFrm, (outs), (ins), "f2xm1", []>, D9;
 632 def FYL2X : I<0xF1, RawFrm, (outs), (ins), "fyl2x", []>, D9;
 633 def FPTAN : I<0xF2, RawFrm, (outs), (ins), "fptan", []>, D9;
 634 def FPATAN : I<0xF3, RawFrm, (outs), (ins), "fpatan", []>, D9;
 635 def FXTRACT : I<0xF4, RawFrm, (outs), (ins), "fxtract", []>, D9;
 636 def FPREM1 : I<0xF5, RawFrm, (outs), (ins), "fprem1", []>, D9;
 637 def FDECSTP : I<0xF6, RawFrm, (outs), (ins), "fdecstp", []>, D9;
 638 def FINCSTP : I<0xF7, RawFrm, (outs), (ins), "fincstp", []>, D9;
 639 def FPREM : I<0xF8, RawFrm, (outs), (ins), "fprem", []>, D9;
 640 def FYL2XP1 : I<0xF9, RawFrm, (outs), (ins), "fyl2xp1", []>, D9;
 641 def FSINCOS : I<0xFB, RawFrm, (outs), (ins), "fsincos", []>, D9;
 642 def FRNDINT : I<0xFC, RawFrm, (outs), (ins), "frndint", []>, D9;
 643 def FSCALE : I<0xFD, RawFrm, (outs), (ins), "fscale", []>, D9;
 644 def FCOMPP : I<0xD9, RawFrm, (outs), (ins), "fcompp", []>, DE;
 645
 646 def FXSAVE : I<0xAE, MRM0m, (outs opaque512mem:$dst), (ins),
 647                "fxsave\t$dst", []>, TB;
 648 def FXRSTOR : I<0xAE, MRM1m, (outs), (ins opaque512mem:$src),
 649                 "fxrstor\t$src", []>, TB;
 650
 651 //===----------------------------------------------------------------------===//
 652 // Non-Instruction Patterns
 653 //===----------------------------------------------------------------------===//
 654
 655 // Required for RET of f32 / f64 / f80 values.
 656 def : Pat<(X86fld addr:$src, f32), (LD_Fp32m addr:$src)>;
 657 def : Pat<(X86fld addr:$src, f64), (LD_Fp64m addr:$src)>;
 658 def : Pat<(X86fld addr:$src, f80), (LD_Fp80m addr:$src)>;
 659
 660 // Required for CALL which return f32 / f64 / f80 values.
 661 def : Pat<(X86fst RFP32:$src, addr:$op, f32), (ST_Fp32m addr:$op, RFP32:$src)>;
 662 def : Pat<(X86fst RFP64:$src, addr:$op, f32), (ST_Fp64m32 addr:$op,
 663                                                           RFP64:$src)>;
 664 def : Pat<(X86fst RFP64:$src, addr:$op, f64), (ST_Fp64m addr:$op, RFP64:$src)>;
 665 def : Pat<(X86fst RFP80:$src, addr:$op, f32), (ST_Fp80m32 addr:$op,
 666                                                           RFP80:$src)>;
 667 def : Pat<(X86fst RFP80:$src, addr:$op, f64), (ST_Fp80m64 addr:$op,
 668                                                           RFP80:$src)>;
 669 def : Pat<(X86fst RFP80:$src, addr:$op, f80), (ST_FpP80m addr:$op,
 670                                                          RFP80:$src)>;
 671
 672 // Floating point constant -0.0 and -1.0
 673 def : Pat<(f32 fpimmneg0), (CHS_Fp32 (LD_Fp032))>, Requires<[FPStackf32]>;
 674 def : Pat<(f32 fpimmneg1), (CHS_Fp32 (LD_Fp132))>, Requires<[FPStackf32]>;
 675 def : Pat<(f64 fpimmneg0), (CHS_Fp64 (LD_Fp064))>, Requires<[FPStackf64]>;
 676 def : Pat<(f64 fpimmneg1), (CHS_Fp64 (LD_Fp164))>, Requires<[FPStackf64]>;
 677 def : Pat<(f80 fpimmneg0), (CHS_Fp80 (LD_Fp080))>;
 678 def : Pat<(f80 fpimmneg1), (CHS_Fp80 (LD_Fp180))>;
 679
 680 // Used to conv. i64 to f64 since there isn't a SSE version.
 681 def : Pat<(X86fildflag addr:$src, i64), (ILD_Fp64m64 addr:$src)>;
 682
 683 // FP extensions map onto simple pseudo-value conversions if they are to/from
 684 // the FP stack.
 685 def : Pat<(f64 (fextend RFP32:$src)), (MOV_Fp3264 RFP32:$src)>,
 686           Requires<[FPStackf32]>;
 687 def : Pat<(f80 (fextend RFP32:$src)), (MOV_Fp3280 RFP32:$src)>,
 688            Requires<[FPStackf32]>;
 689 def : Pat<(f80 (fextend RFP64:$src)), (MOV_Fp6480 RFP64:$src)>,
 690            Requires<[FPStackf64]>;
 691
 692 // FP truncations map onto simple pseudo-value conversions if they are to/from
 693 // the FP stack.  We have validated that only value-preserving truncations make
 694 // it through isel.
 695 def : Pat<(f32 (fround RFP64:$src)), (MOV_Fp6432 RFP64:$src)>,
 696           Requires<[FPStackf32]>;
 697 def : Pat<(f32 (fround RFP80:$src)), (MOV_Fp8032 RFP80:$src)>,
 698            Requires<[FPStackf32]>;
 699 def : Pat<(f64 (fround RFP80:$src)), (MOV_Fp8064 RFP80:$src)>,
 700            Requires<[FPStackf64]>;