lib/Target/X86/X86InstrExtension.td

   1 //===- X86InstrExtension.td - Sign and Zero Extensions -----*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the sign and zero extension operations.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 let neverHasSideEffects = 1 in {
  15   let Defs = [AX], Uses = [AL] in
  16   def CBW : I<0x98, RawFrm, (outs), (ins),
  17               "{cbtw|cbw}", []>, OpSize;   // AX = signext(AL)
  18   let Defs = [EAX], Uses = [AX] in
  19   def CWDE : I<0x98, RawFrm, (outs), (ins),
  20               "{cwtl|cwde}", []>;   // EAX = signext(AX)
  21
  22   let Defs = [AX,DX], Uses = [AX] in
  23   def CWD : I<0x99, RawFrm, (outs), (ins),
  24               "{cwtd|cwd}", []>, OpSize; // DX:AX = signext(AX)
  25   let Defs = [EAX,EDX], Uses = [EAX] in
  26   def CDQ : I<0x99, RawFrm, (outs), (ins),
  27               "{cltd|cdq}", []>; // EDX:EAX = signext(EAX)
  28
  29
  30   let Defs = [RAX], Uses = [EAX] in
  31   def CDQE : RI<0x98, RawFrm, (outs), (ins),
  32                "{cltq|cdqe}", []>;     // RAX = signext(EAX)
  33
  34   let Defs = [RAX,RDX], Uses = [RAX] in
  35   def CQO  : RI<0x99, RawFrm, (outs), (ins),
  36                 "{cqto|cqo}", []>; // RDX:RAX = signext(RAX)
  37 }
  38
  39
  40 // Sign/Zero extenders
  41 // Use movsbl intead of movsbw; we don't care about the high 16 bits
  42 // of the register here. This has a smaller encoding and avoids a
  43 // partial-register update.  Actual movsbw included for the disassembler.
  44 def MOVSX16rr8W : I<0xBE, MRMSrcReg, (outs GR16:$dst), (ins GR8:$src),
  45                     "movs{bw|x}\t{$src, $dst|$dst, $src}", []>, TB, OpSize;
  46 def MOVSX16rm8W : I<0xBE, MRMSrcMem, (outs GR16:$dst), (ins i8mem:$src),
  47                     "movs{bw|x}\t{$src, $dst|$dst, $src}", []>, TB, OpSize;
  48 def MOVSX16rr8 : I<0xBE, MRMSrcReg, (outs GR16:$dst), (ins GR8 :$src),
  49                    "", [(set GR16:$dst, (sext GR8:$src))]>, TB;
  50 def MOVSX16rm8 : I<0xBE, MRMSrcMem, (outs GR16:$dst), (ins i8mem :$src),
  51                    "", [(set GR16:$dst, (sextloadi16i8 addr:$src))]>, TB;
  52 def MOVSX32rr8 : I<0xBE, MRMSrcReg, (outs GR32:$dst), (ins GR8 :$src),
  53                    "movs{bl|x}\t{$src, $dst|$dst, $src}",
  54                    [(set GR32:$dst, (sext GR8:$src))]>, TB;
  55 def MOVSX32rm8 : I<0xBE, MRMSrcMem, (outs GR32:$dst), (ins i8mem :$src),
  56                    "movs{bl|x}\t{$src, $dst|$dst, $src}",
  57                    [(set GR32:$dst, (sextloadi32i8 addr:$src))]>, TB;
  58 def MOVSX32rr16: I<0xBF, MRMSrcReg, (outs GR32:$dst), (ins GR16:$src),
  59                    "movs{wl|x}\t{$src, $dst|$dst, $src}",
  60                    [(set GR32:$dst, (sext GR16:$src))]>, TB;
  61 def MOVSX32rm16: I<0xBF, MRMSrcMem, (outs GR32:$dst), (ins i16mem:$src),
  62                    "movs{wl|x}\t{$src, $dst|$dst, $src}",
  63                    [(set GR32:$dst, (sextloadi32i16 addr:$src))]>, TB;
  64
  65 // Use movzbl intead of movzbw; we don't care about the high 16 bits
  66 // of the register here. This has a smaller encoding and avoids a
  67 // partial-register update.  Actual movzbw included for the disassembler.
  68 def MOVZX16rr8W : I<0xB6, MRMSrcReg, (outs GR16:$dst), (ins GR8:$src),
  69                     "movz{bw|x}\t{$src, $dst|$dst, $src}", []>, TB, OpSize;
  70 def MOVZX16rm8W : I<0xB6, MRMSrcMem, (outs GR16:$dst), (ins i8mem:$src),
  71                     "movz{bw|x}\t{$src, $dst|$dst, $src}", []>, TB, OpSize;
  72 def MOVZX16rr8 : I<0xB6, MRMSrcReg, (outs GR16:$dst), (ins GR8 :$src),
  73                    "", [(set GR16:$dst, (zext GR8:$src))]>, TB;
  74 def MOVZX16rm8 : I<0xB6, MRMSrcMem, (outs GR16:$dst), (ins i8mem :$src),
  75                    "", [(set GR16:$dst, (zextloadi16i8 addr:$src))]>, TB;
  76 def MOVZX32rr8 : I<0xB6, MRMSrcReg, (outs GR32:$dst), (ins GR8 :$src),
  77                    "movz{bl|x}\t{$src, $dst|$dst, $src}",
  78                    [(set GR32:$dst, (zext GR8:$src))]>, TB;
  79 def MOVZX32rm8 : I<0xB6, MRMSrcMem, (outs GR32:$dst), (ins i8mem :$src),
  80                    "movz{bl|x}\t{$src, $dst|$dst, $src}",
  81                    [(set GR32:$dst, (zextloadi32i8 addr:$src))]>, TB;
  82 def MOVZX32rr16: I<0xB7, MRMSrcReg, (outs GR32:$dst), (ins GR16:$src),
  83                    "movz{wl|x}\t{$src, $dst|$dst, $src}",
  84                    [(set GR32:$dst, (zext GR16:$src))]>, TB;
  85 def MOVZX32rm16: I<0xB7, MRMSrcMem, (outs GR32:$dst), (ins i16mem:$src),
  86                    "movz{wl|x}\t{$src, $dst|$dst, $src}",
  87                    [(set GR32:$dst, (zextloadi32i16 addr:$src))]>, TB;
  88
  89 // These are the same as the regular MOVZX32rr8 and MOVZX32rm8
  90 // except that they use GR32_NOREX for the output operand register class
  91 // instead of GR32. This allows them to operate on h registers on x86-64.
  92 def MOVZX32_NOREXrr8 : I<0xB6, MRMSrcReg,
  93                          (outs GR32_NOREX:$dst), (ins GR8:$src),
  94                          "movz{bl|x}\t{$src, $dst|$dst, $src}  # NOREX",
  95                          []>, TB;
  96 let mayLoad = 1 in
  97 def MOVZX32_NOREXrm8 : I<0xB6, MRMSrcMem,
  98                          (outs GR32_NOREX:$dst), (ins i8mem:$src),
  99                          "movz{bl|x}\t{$src, $dst|$dst, $src}  # NOREX",
 100                          []>, TB;
 101
 102 // MOVSX64rr8 always has a REX prefix and it has an 8-bit register
 103 // operand, which makes it a rare instruction with an 8-bit register
 104 // operand that can never access an h register. If support for h registers
 105 // were generalized, this would require a special register class.
 106 def MOVSX64rr8 : RI<0xBE, MRMSrcReg, (outs GR64:$dst), (ins GR8 :$src),
 107                     "movs{bq|x}\t{$src, $dst|$dst, $src}",
 108                     [(set GR64:$dst, (sext GR8:$src))]>, TB;
 109 def MOVSX64rm8 : RI<0xBE, MRMSrcMem, (outs GR64:$dst), (ins i8mem :$src),
 110                     "movs{bq|x}\t{$src, $dst|$dst, $src}",
 111                     [(set GR64:$dst, (sextloadi64i8 addr:$src))]>, TB;
 112 def MOVSX64rr16: RI<0xBF, MRMSrcReg, (outs GR64:$dst), (ins GR16:$src),
 113                     "movs{wq|x}\t{$src, $dst|$dst, $src}",
 114                     [(set GR64:$dst, (sext GR16:$src))]>, TB;
 115 def MOVSX64rm16: RI<0xBF, MRMSrcMem, (outs GR64:$dst), (ins i16mem:$src),
 116                     "movs{wq|x}\t{$src, $dst|$dst, $src}",
 117                     [(set GR64:$dst, (sextloadi64i16 addr:$src))]>, TB;
 118 def MOVSX64rr32: RI<0x63, MRMSrcReg, (outs GR64:$dst), (ins GR32:$src),
 119                     "movs{lq|xd}\t{$src, $dst|$dst, $src}",
 120                     [(set GR64:$dst, (sext GR32:$src))]>;
 121 def MOVSX64rm32: RI<0x63, MRMSrcMem, (outs GR64:$dst), (ins i32mem:$src),
 122                     "movs{lq|xd}\t{$src, $dst|$dst, $src}",
 123                     [(set GR64:$dst, (sextloadi64i32 addr:$src))]>;
 124
 125 // movzbq and movzwq encodings for the disassembler
 126 def MOVZX64rr8_Q : RI<0xB6, MRMSrcReg, (outs GR64:$dst), (ins GR8:$src),
 127                        "movz{bq|x}\t{$src, $dst|$dst, $src}", []>, TB;
 128 def MOVZX64rm8_Q : RI<0xB6, MRMSrcMem, (outs GR64:$dst), (ins i8mem:$src),
 129                        "movz{bq|x}\t{$src, $dst|$dst, $src}", []>, TB;
 130 def MOVZX64rr16_Q : RI<0xB7, MRMSrcReg, (outs GR64:$dst), (ins GR16:$src),
 131                        "movz{wq|x}\t{$src, $dst|$dst, $src}", []>, TB;
 132 def MOVZX64rm16_Q : RI<0xB7, MRMSrcMem, (outs GR64:$dst), (ins i16mem:$src),
 133                        "movz{wq|x}\t{$src, $dst|$dst, $src}", []>, TB;
 134
 135 // Use movzbl instead of movzbq when the destination is a register; it's
 136 // equivalent due to implicit zero-extending, and it has a smaller encoding.
 137 def MOVZX64rr8 : I<0xB6, MRMSrcReg, (outs GR64:$dst), (ins GR8 :$src),
 138                    "", [(set GR64:$dst, (zext GR8:$src))]>, TB;
 139 def MOVZX64rm8 : I<0xB6, MRMSrcMem, (outs GR64:$dst), (ins i8mem :$src),
 140                    "", [(set GR64:$dst, (zextloadi64i8 addr:$src))]>, TB;
 141 // Use movzwl instead of movzwq when the destination is a register; it's
 142 // equivalent due to implicit zero-extending, and it has a smaller encoding.
 143 def MOVZX64rr16: I<0xB7, MRMSrcReg, (outs GR64:$dst), (ins GR16:$src),
 144                    "", [(set GR64:$dst, (zext GR16:$src))]>, TB;
 145 def MOVZX64rm16: I<0xB7, MRMSrcMem, (outs GR64:$dst), (ins i16mem:$src),
 146                    "", [(set GR64:$dst, (zextloadi64i16 addr:$src))]>, TB;
 147
 148 // There's no movzlq instruction, but movl can be used for this purpose, using
 149 // implicit zero-extension. The preferred way to do 32-bit-to-64-bit zero
 150 // extension on x86-64 is to use a SUBREG_TO_REG to utilize implicit
 151 // zero-extension, however this isn't possible when the 32-bit value is
 152 // defined by a truncate or is copied from something where the high bits aren't
 153 // necessarily all zero. In such cases, we fall back to these explicit zext
 154 // instructions.
 155 def MOVZX64rr32 : I<0x89, MRMDestReg, (outs GR64:$dst), (ins GR32:$src),
 156                     "", [(set GR64:$dst, (zext GR32:$src))]>;
 157 def MOVZX64rm32 : I<0x8B, MRMSrcMem, (outs GR64:$dst), (ins i32mem:$src),
 158                     "", [(set GR64:$dst, (zextloadi64i32 addr:$src))]>;
 159
 160
 161
 162