lib/Target/WebAssembly/WebAssemblyInstrFormats.td

   1 // WebAssemblyInstrFormats.td - WebAssembly Instruction Formats -*- tblgen -*-//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 ///
  10 /// \file
  11 /// \brief WebAssembly instruction format definitions.
  12 ///
  13 //===----------------------------------------------------------------------===//
  14
  15 // WebAssembly Instruction Format.
  16 class WebAssemblyInst<string cstr> : Instruction {
  17   field bits<0> Inst; // Instruction encoding.
  18   let Namespace   = "WebAssembly";
  19   let Pattern     = [];
  20   let Constraints = cstr;
  21 }
  22
  23 // Normal instructions.
  24 class I<dag oops, dag iops, list<dag> pattern, string cstr = "">
  25     : WebAssemblyInst<cstr> {
  26   dag OutOperandList = oops;
  27   dag InOperandList  = iops;
  28   let Pattern        = pattern;
  29 }
  30
  31 // Unary and binary instructions, for the local types that WebAssembly supports.
  32 multiclass UnaryInt<SDNode node> {
  33   def _I32 : I<(outs I32:$dst), (ins I32:$src),
  34                [(set I32:$dst, (node I32:$src))]>;
  35   def _I64 : I<(outs I64:$dst), (ins I64:$src),
  36                [(set I64:$dst, (node I64:$src))]>;
  37 }
  38 multiclass BinaryInt<SDNode node> {
  39   def _I32 : I<(outs I32:$dst), (ins I32:$lhs, I32:$rhs),
  40                [(set I32:$dst, (node I32:$lhs, I32:$rhs))]>;
  41   def _I64 : I<(outs I64:$dst), (ins I64:$lhs, I64:$rhs),
  42                [(set I64:$dst, (node I64:$lhs, I64:$rhs))]>;
  43 }
  44 multiclass UnaryFP<SDNode node> {
  45   def _F32 : I<(outs F32:$dst), (ins F32:$src),
  46                [(set F32:$dst, (node F32:$src))]>;
  47   def _F64 : I<(outs F64:$dst), (ins F64:$src),
  48                [(set F64:$dst, (node F64:$src))]>;
  49 }
  50 multiclass BinaryFP<SDNode node> {
  51   def _F32 : I<(outs F32:$dst), (ins F32:$lhs, F32:$rhs),
  52                [(set F32:$dst, (node F32:$lhs, F32:$rhs))]>;
  53   def _F64 : I<(outs F64:$dst), (ins F64:$lhs, F64:$rhs),
  54                [(set F64:$dst, (node F64:$lhs, F64:$rhs))]>;
  55 }
  56 multiclass ComparisonInt<CondCode cond> {
  57   def _I32 : I<(outs I32:$dst), (ins I32:$lhs, I32:$rhs),
  58                [(set I32:$dst, (setcc I32:$lhs, I32:$rhs, cond))]>;
  59   def _I64 : I<(outs I32:$dst), (ins I64:$lhs, I64:$rhs),
  60                [(set I32:$dst, (setcc I64:$lhs, I64:$rhs, cond))]>;
  61 }
  62 multiclass ComparisonFP<CondCode cond> {
  63   def _F32 : I<(outs I32:$dst), (ins F32:$lhs, F32:$rhs),
  64                [(set I32:$dst, (setcc F32:$lhs, F32:$rhs, cond))]>;
  65   def _F64 : I<(outs I32:$dst), (ins F64:$lhs, F64:$rhs),
  66                [(set I32:$dst, (setcc F64:$lhs, F64:$rhs, cond))]>;
  67 }