lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 /// SDTCisIntVectorOfSameSize - This indicates that ThisOp and OtherOp are
  55 /// packed vector types, and that ThisOp is the result of
  56 /// MVT::getIntVectorWithNumElements with the number of elements that ThisOp
  57 /// has.
  58 class SDTCisIntVectorOfSameSize<int ThisOp, int OtherOp>
  59   : SDTypeConstraint<ThisOp> {
  60   int OtherOpNum = OtherOp;
  61 }
  62
  63 //===----------------------------------------------------------------------===//
  64 // Selection DAG Type Profile definitions.
  65 //
  66 // These use the constraints defined above to describe the type requirements of
  67 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  68 // add their own if needed.
  69 //
  70
  71 // SDTypeProfile - This profile describes the type requirements of a Selection
  72 // DAG node.
  73 class SDTypeProfile<int numresults, int numoperands,
  74                     list<SDTypeConstraint> constraints> {
  75   int NumResults = numresults;
  76   int NumOperands = numoperands;
  77   list<SDTypeConstraint> Constraints = constraints;
  78 }
  79
  80 // Builtin profiles.
  81 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  82 def SDTFPLeaf : SDTypeProfile<1, 0, [SDTCisFP<0>]>;       // for 'fpimm'.
  83 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  84 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  85 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  86 def SDTUnaryOp  : SDTypeProfile<1, 1, []>; // bitconvert
  87
  88 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  89   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  90 ]>;
  91 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  92   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  93 ]>;
  94 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  95   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  96 ]>;
  97 def SDTFPSignOp : SDTypeProfile<1, 2, [      // fcopysign.
  98   SDTCisSameAs<0, 1>, SDTCisFP<0>, SDTCisFP<2>
  99 ]>;
 100 def SDTFPTernaryOp : SDTypeProfile<1, 3, [      // fmadd, fnmsub, etc.
 101   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
 102 ]>;
 103 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
 104   SDTCisSameAs<0, 1>, SDTCisInt<0>
 105 ]>;
 106 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
 107   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
 108 ]>;
 109 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
 110   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
 111 ]>;
 112 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
 113   SDTCisSameAs<0, 1>, SDTCisFP<0>
 114 ]>;
 115 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 116   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 117 ]>;
 118 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 119   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 120 ]>;
 121 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 122   SDTCisFP<0>, SDTCisInt<1>
 123 ]>;
 124 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 125   SDTCisInt<0>, SDTCisFP<1>
 126 ]>;
 127 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 128   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 129   SDTCisVTSmallerThanOp<2, 1>
 130 ]>;
 131
 132 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 133   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 134 ]>;
 135
 136 def SDTSelect : SDTypeProfile<1, 3, [ // select
 137   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 138 ]>;
 139
 140 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 141   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 142   SDTCisVT<5, OtherVT>
 143 ]>;
 144
 145 def SDTBr : SDTypeProfile<0, 1, [ // br
 146   SDTCisVT<0, OtherVT>
 147 ]>;
 148
 149 def SDTBrcond : SDTypeProfile<0, 2, [ // brcond
 150   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 151 ]>;
 152
 153 def SDTRet : SDTypeProfile<0, 0, []>; // ret
 154
 155 def SDTLoad : SDTypeProfile<1, 1, [ // load
 156   SDTCisPtrTy<1>
 157 ]>;
 158
 159 def SDTStore : SDTypeProfile<0, 2, [ // store
 160   SDTCisPtrTy<1>
 161 ]>;
 162
 163 def SDTExtLoad : SDTypeProfile<1, 3, [  // extload
 164   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 165 ]>;
 166 def SDTIntExtLoad : SDTypeProfile<1, 3, [  // sextload, zextload
 167   SDTCisInt<0>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 168 ]>;
 169 def SDTTruncStore : SDTypeProfile<0, 4, [  // truncstore
 170   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 171 ]>;
 172
 173 def SDTVecShuffle : SDTypeProfile<1, 3, [
 174   SDTCisSameAs<0, 1>, SDTCisSameAs<1, 2>, SDTCisIntVectorOfSameSize<3, 0>
 175 ]>;
 176
 177 //===----------------------------------------------------------------------===//
 178 // Selection DAG Node Properties.
 179 //
 180 // Note: These are hard coded into tblgen.
 181 //
 182 class SDNodeProperty;
 183 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 184 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 185 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 186 def SDNPOutFlag     : SDNodeProperty;   // Write a flag result
 187 def SDNPInFlag      : SDNodeProperty;   // Read a flag operand
 188 def SDNPOptInFlag   : SDNodeProperty;   // Optionally read a flag operand
 189
 190 //===----------------------------------------------------------------------===//
 191 // Selection DAG Node definitions.
 192 //
 193 class SDNode<string opcode, SDTypeProfile typeprof,
 194              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 195   string Opcode  = opcode;
 196   string SDClass = sdclass;
 197   list<SDNodeProperty> Properties = props;
 198   SDTypeProfile TypeProfile = typeprof;
 199 }
 200
 201 def set;
 202 def node;
 203 def srcvalue;
 204
 205 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 206 def fpimm      : SDNode<"ISD::TargetConstantFP",
 207                          SDTFPLeaf, [], "ConstantFPSDNode">;
 208 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 209 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 210 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 211 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 212 def globaladdr : SDNode<"ISD::GlobalAddress",         SDTPtrLeaf, [],
 213                         "GlobalAddressSDNode">;
 214 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress",  SDTPtrLeaf, [],
 215                          "GlobalAddressSDNode">;
 216 def constpool   : SDNode<"ISD::ConstantPool",         SDTPtrLeaf, [],
 217                          "ConstantPoolSDNode">;
 218 def tconstpool  : SDNode<"ISD::TargetConstantPool",   SDTPtrLeaf, [],
 219                          "ConstantPoolSDNode">;
 220 def frameindex  : SDNode<"ISD::FrameIndex",           SDTPtrLeaf, [],
 221                          "FrameIndexSDNode">;
 222 def tframeindex : SDNode<"ISD::TargetFrameIndex",     SDTPtrLeaf, [],
 223                          "FrameIndexSDNode">;
 224 def externalsym : SDNode<"ISD::ExternalSymbol",       SDTPtrLeaf, [],
 225                          "ExternalSymbolSDNode">;
 226 def texternalsym: SDNode<"ISD::TargetExternalSymbol", SDTPtrLeaf, [],
 227                          "ExternalSymbolSDNode">;
 228
 229 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 230                         [SDNPCommutative, SDNPAssociative]>;
 231 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 232 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 233                         [SDNPCommutative, SDNPAssociative]>;
 234 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 235 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 236 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 237 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 238 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 239 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 240 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 241 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 242 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 243 def rotl       : SDNode<"ISD::ROTL"      , SDTIntShiftOp>;
 244 def rotr       : SDNode<"ISD::ROTR"      , SDTIntShiftOp>;
 245 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 246                         [SDNPCommutative, SDNPAssociative]>;
 247 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 248                         [SDNPCommutative, SDNPAssociative]>;
 249 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 250                         [SDNPCommutative, SDNPAssociative]>;
 251 def addc       : SDNode<"ISD::ADDC"      , SDTIntBinOp,
 252                         [SDNPCommutative, SDNPOutFlag]>;
 253 def adde       : SDNode<"ISD::ADDE"      , SDTIntBinOp,
 254                         [SDNPCommutative, SDNPOutFlag, SDNPInFlag]>;
 255 def subc       : SDNode<"ISD::SUBC"      , SDTIntBinOp,
 256                         [SDNPOutFlag]>;
 257 def sube       : SDNode<"ISD::SUBE"      , SDTIntBinOp,
 258                         [SDNPOutFlag, SDNPInFlag]>;
 259
 260 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 261 def bswap      : SDNode<"ISD::BSWAP"      , SDTIntUnaryOp>;
 262 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 263 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 264 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 265 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 266 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 267 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 268 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 269 def bitconvert : SDNode<"ISD::BIT_CONVERT", SDTUnaryOp>;
 270
 271 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 272 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 273 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 274 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 275 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 276 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 277 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 278 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 279 def fsin       : SDNode<"ISD::FSIN"       , SDTFPUnaryOp>;
 280 def fcos       : SDNode<"ISD::FCOS"       , SDTFPUnaryOp>;
 281
 282 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 283 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 284 def fcopysign  : SDNode<"ISD::FCOPYSIGN"  , SDTFPSignOp>;
 285
 286 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 287 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 288 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 289 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 290
 291 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 292 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 293 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 294
 295 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrcond, [SDNPHasChain]>;
 296 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 297 def ret        : SDNode<"ISD::RET"        , SDTRet,    [SDNPHasChain]>;
 298
 299 def load       : SDNode<"ISD::LOAD"       , SDTLoad,  [SDNPHasChain]>;
 300 def store      : SDNode<"ISD::STORE"      , SDTStore, [SDNPHasChain]>;
 301
 302 // Do not use sextld and zextld directly. Use sextload and zextload (see
 303 // below) which pass in a dummy srcvalue node which tblgen will skip over.
 304 def sextld     : SDNode<"ISD::SEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 305 def zextld     : SDNode<"ISD::ZEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 306 def extld      : SDNode<"ISD::EXTLOAD"    , SDTExtLoad,    [SDNPHasChain]>;
 307 def truncst    : SDNode<"ISD::TRUNCSTORE" , SDTTruncStore, [SDNPHasChain]>;
 308
 309 def vector_shuffle : SDNode<"ISD::VECTOR_SHUFFLE", SDTVecShuffle, []>;
 310
 311
 312 //===----------------------------------------------------------------------===//
 313 // Selection DAG Condition Codes
 314
 315 class CondCode; // ISD::CondCode enums
 316 def SETOEQ : CondCode; def SETOGT : CondCode;
 317 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 318 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 319 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 320 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 321
 322 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 323 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 324
 325
 326 //===----------------------------------------------------------------------===//
 327 // Selection DAG Node Transformation Functions.
 328 //
 329 // This mechanism allows targets to manipulate nodes in the output DAG once a
 330 // match has been formed.  This is typically used to manipulate immediate
 331 // values.
 332 //
 333 class SDNodeXForm<SDNode opc, code xformFunction> {
 334   SDNode Opcode = opc;
 335   code XFormFunction = xformFunction;
 336 }
 337
 338 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 339
 340
 341 //===----------------------------------------------------------------------===//
 342 // Selection DAG Pattern Fragments.
 343 //
 344 // Pattern fragments are reusable chunks of dags that match specific things.
 345 // They can take arguments and have C++ predicates that control whether they
 346 // match.  They are intended to make the patterns for common instructions more
 347 // compact and readable.
 348 //
 349
 350 /// PatFrag - Represents a pattern fragment.  This can match something on the
 351 /// DAG, frame a single node to multiply nested other fragments.
 352 ///
 353 class PatFrag<dag ops, dag frag, code pred = [{}],
 354               SDNodeXForm xform = NOOP_SDNodeXForm> {
 355   dag Operands = ops;
 356   dag Fragment = frag;
 357   code Predicate = pred;
 358   SDNodeXForm OperandTransform = xform;
 359 }
 360
 361 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 362 // to define immediates and other common things concisely.
 363 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 364  : PatFrag<(ops), frag, pred, xform>;
 365
 366 // Leaf fragments.
 367
 368 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 369 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 370 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 371
 372 // Other helper fragments.
 373
 374 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 375 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 376
 377 // extending load & truncstore fragments.
 378 def sextload      : PatFrag<(ops node:$ptr, node:$vt),
 379                             (sextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 380 def zextload      : PatFrag<(ops node:$ptr, node:$vt),
 381                             (zextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 382 def extload       : PatFrag<(ops node:$ptr, node:$vt),
 383                             (extld node:$ptr, srcvalue:$dummy, node:$vt)>;
 384 def truncstore    : PatFrag<(ops node:$val, node:$ptr, node:$vt),
 385                             (truncst node:$val, node:$ptr, srcvalue:$dummy,
 386                             node:$vt)>;
 387
 388 // setcc convenience fragments.
 389 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 390                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 391 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 392                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 393 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 394                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 395 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 396                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 397 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 398                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 399 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 400                      (setcc node:$lhs, node:$rhs, SETONE)>;
 401 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 402                      (setcc node:$lhs, node:$rhs, SETO)>;
 403 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 404                      (setcc node:$lhs, node:$rhs, SETUO)>;
 405 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 406                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 407 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 408                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 409 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 410                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 411 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 412                      (setcc node:$lhs, node:$rhs, SETULT)>;
 413 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 414                      (setcc node:$lhs, node:$rhs, SETULE)>;
 415 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 416                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 417 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 418                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 419 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 420                      (setcc node:$lhs, node:$rhs, SETGT)>;
 421 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 422                      (setcc node:$lhs, node:$rhs, SETGE)>;
 423 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 424                      (setcc node:$lhs, node:$rhs, SETLT)>;
 425 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 426                      (setcc node:$lhs, node:$rhs, SETLE)>;
 427 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 428                      (setcc node:$lhs, node:$rhs, SETNE)>;
 429
 430 //===----------------------------------------------------------------------===//
 431 // Selection DAG Pattern Support.
 432 //
 433 // Patterns are what are actually matched against the target-flavored
 434 // instruction selection DAG.  Instructions defined by the target implicitly
 435 // define patterns in most cases, but patterns can also be explicitly added when
 436 // an operation is defined by a sequence of instructions (e.g. loading a large
 437 // immediate value on RISC targets that do not support immediates as large as
 438 // their GPRs).
 439 //
 440
 441 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 442   dag             PatternToMatch = patternToMatch;
 443   list<dag>       ResultInstrs   = resultInstrs;
 444   list<Predicate> Predicates     = [];  // See class Instruction in Target.td.
 445 }
 446
 447 // Pat - A simple (but common) form of a pattern, which produces a simple result
 448 // not needing a full list.
 449 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 450
 451 //===----------------------------------------------------------------------===//
 452 // Complex pattern definitions.
 453 //
 454 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 455 // in C++. NumOperands is the number of operands returned by the select function;
 456 // SelectFunc is the name of the function used to pattern match the max. pattern;
 457 // RootNodes are the list of possible root nodes of the sub-dags to match.
 458 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 459 //
 460 class ComplexPattern<ValueType ty, int numops, string fn, list<SDNode> roots = []> {
 461   ValueType Ty = ty;
 462   int NumOperands = numops;
 463   string SelectFunc = fn;
 464   list<SDNode> RootNodes = roots;
 465 }
 466
 467 //===----------------------------------------------------------------------===//
 468 // Dwarf support.
 469 //
 470 def SDT_dwarf_loc : SDTypeProfile<0, 3,
 471                       [SDTCisInt<0>, SDTCisInt<1>, SDTCisInt<2>]>;
 472 def dwarf_loc : SDNode<"ISD::DEBUG_LOC", SDT_dwarf_loc,[SDNPHasChain]>;
 473
 474 def SDT_dwarf_label : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
 475 def dwarf_label : SDNode<"ISD::DEBUG_LABEL", SDT_dwarf_label,[SDNPHasChain]>;
 476
 477
 478