lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 /// SDTCisIntVectorOfSameSize - This indicates that ThisOp and OtherOp are
  55 /// vector types, and that ThisOp is the result of
  56 /// MVT::getIntVectorWithNumElements with the number of elements that ThisOp
  57 /// has.
  58 class SDTCisIntVectorOfSameSize<int ThisOp, int OtherOp>
  59   : SDTypeConstraint<ThisOp> {
  60   int OtherOpNum = OtherOp;
  61 }
  62
  63 //===----------------------------------------------------------------------===//
  64 // Selection DAG Type Profile definitions.
  65 //
  66 // These use the constraints defined above to describe the type requirements of
  67 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  68 // add their own if needed.
  69 //
  70
  71 // SDTypeProfile - This profile describes the type requirements of a Selection
  72 // DAG node.
  73 class SDTypeProfile<int numresults, int numoperands,
  74                     list<SDTypeConstraint> constraints> {
  75   int NumResults = numresults;
  76   int NumOperands = numoperands;
  77   list<SDTypeConstraint> Constraints = constraints;
  78 }
  79
  80 // Builtin profiles.
  81 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  82 def SDTFPLeaf : SDTypeProfile<1, 0, [SDTCisFP<0>]>;       // for 'fpimm'.
  83 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  84 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  85 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  86 def SDTUnaryOp  : SDTypeProfile<1, 1, []>; // bitconvert
  87
  88 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  89   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  90 ]>;
  91 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  92   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  93 ]>;
  94 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  95   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  96 ]>;
  97 def SDTFPSignOp : SDTypeProfile<1, 2, [      // fcopysign.
  98   SDTCisSameAs<0, 1>, SDTCisFP<0>, SDTCisFP<2>
  99 ]>;
 100 def SDTFPTernaryOp : SDTypeProfile<1, 3, [      // fmadd, fnmsub, etc.
 101   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
 102 ]>;
 103 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
 104   SDTCisSameAs<0, 1>, SDTCisInt<0>
 105 ]>;
 106 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
 107   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
 108 ]>;
 109 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
 110   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
 111 ]>;
 112 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
 113   SDTCisSameAs<0, 1>, SDTCisFP<0>
 114 ]>;
 115 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 116   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 117 ]>;
 118 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 119   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 120 ]>;
 121 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 122   SDTCisFP<0>, SDTCisInt<1>
 123 ]>;
 124 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 125   SDTCisInt<0>, SDTCisFP<1>
 126 ]>;
 127 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 128   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 129   SDTCisVTSmallerThanOp<2, 1>
 130 ]>;
 131
 132 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 133   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 134 ]>;
 135
 136 def SDTSelect : SDTypeProfile<1, 3, [ // select
 137   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 138 ]>;
 139
 140 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 141   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 142   SDTCisVT<5, OtherVT>
 143 ]>;
 144
 145 def SDTBr : SDTypeProfile<0, 1, [ // br
 146   SDTCisVT<0, OtherVT>
 147 ]>;
 148
 149 def SDTBrcond : SDTypeProfile<0, 2, [ // brcond
 150   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 151 ]>;
 152
 153 def SDTBrind : SDTypeProfile<0, 1, [ // brind
 154   SDTCisPtrTy<0>
 155 ]>;
 156
 157 def SDTRet : SDTypeProfile<0, 0, []>; // ret
 158
 159 def SDTLoad : SDTypeProfile<1, 1, [ // load
 160   SDTCisPtrTy<1>
 161 ]>;
 162
 163 def SDTStore : SDTypeProfile<0, 2, [ // store
 164   SDTCisPtrTy<1>
 165 ]>;
 166
 167 def SDTIStore : SDTypeProfile<1, 3, [ // indexed store
 168   SDTCisSameAs<0, 2>, SDTCisPtrTy<0>, SDTCisPtrTy<3>
 169 ]>;
 170
 171 def SDTVecShuffle : SDTypeProfile<1, 3, [
 172   SDTCisSameAs<0, 1>, SDTCisSameAs<1, 2>, SDTCisIntVectorOfSameSize<3, 0>
 173 ]>;
 174
 175 //===----------------------------------------------------------------------===//
 176 // Selection DAG Node Properties.
 177 //
 178 // Note: These are hard coded into tblgen.
 179 //
 180 class SDNodeProperty;
 181 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 182 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 183 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 184 def SDNPOutFlag     : SDNodeProperty;   // Write a flag result
 185 def SDNPInFlag      : SDNodeProperty;   // Read a flag operand
 186 def SDNPOptInFlag   : SDNodeProperty;   // Optionally read a flag operand
 187
 188 //===----------------------------------------------------------------------===//
 189 // Selection DAG Node definitions.
 190 //
 191 class SDNode<string opcode, SDTypeProfile typeprof,
 192              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 193   string Opcode  = opcode;
 194   string SDClass = sdclass;
 195   list<SDNodeProperty> Properties = props;
 196   SDTypeProfile TypeProfile = typeprof;
 197 }
 198
 199 def set;
 200 def node;
 201 def srcvalue;
 202
 203 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 204 def fpimm      : SDNode<"ISD::TargetConstantFP",
 205                          SDTFPLeaf, [], "ConstantFPSDNode">;
 206 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 207 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 208 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 209 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 210 def globaladdr : SDNode<"ISD::GlobalAddress",         SDTPtrLeaf, [],
 211                         "GlobalAddressSDNode">;
 212 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress",  SDTPtrLeaf, [],
 213                          "GlobalAddressSDNode">;
 214 def globaltlsaddr : SDNode<"ISD::GlobalTLSAddress",         SDTPtrLeaf, [],
 215                           "GlobalAddressSDNode">;
 216 def tglobaltlsaddr : SDNode<"ISD::TargetGlobalTLSAddress",  SDTPtrLeaf, [],
 217                            "GlobalAddressSDNode">;
 218 def constpool   : SDNode<"ISD::ConstantPool",         SDTPtrLeaf, [],
 219                          "ConstantPoolSDNode">;
 220 def tconstpool  : SDNode<"ISD::TargetConstantPool",   SDTPtrLeaf, [],
 221                          "ConstantPoolSDNode">;
 222 def jumptable   : SDNode<"ISD::JumpTable",            SDTPtrLeaf, [],
 223                          "JumpTableSDNode">;
 224 def tjumptable  : SDNode<"ISD::TargetJumpTable",      SDTPtrLeaf, [],
 225                          "JumpTableSDNode">;
 226 def frameindex  : SDNode<"ISD::FrameIndex",           SDTPtrLeaf, [],
 227                          "FrameIndexSDNode">;
 228 def tframeindex : SDNode<"ISD::TargetFrameIndex",     SDTPtrLeaf, [],
 229                          "FrameIndexSDNode">;
 230 def externalsym : SDNode<"ISD::ExternalSymbol",       SDTPtrLeaf, [],
 231                          "ExternalSymbolSDNode">;
 232 def texternalsym: SDNode<"ISD::TargetExternalSymbol", SDTPtrLeaf, [],
 233                          "ExternalSymbolSDNode">;
 234
 235 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 236                         [SDNPCommutative, SDNPAssociative]>;
 237 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 238 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 239                         [SDNPCommutative, SDNPAssociative]>;
 240 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 241 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 242 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 243 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 244 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 245 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 246 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 247 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 248 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 249 def rotl       : SDNode<"ISD::ROTL"      , SDTIntShiftOp>;
 250 def rotr       : SDNode<"ISD::ROTR"      , SDTIntShiftOp>;
 251 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 252                         [SDNPCommutative, SDNPAssociative]>;
 253 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 254                         [SDNPCommutative, SDNPAssociative]>;
 255 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 256                         [SDNPCommutative, SDNPAssociative]>;
 257 def addc       : SDNode<"ISD::ADDC"      , SDTIntBinOp,
 258                         [SDNPCommutative, SDNPOutFlag]>;
 259 def adde       : SDNode<"ISD::ADDE"      , SDTIntBinOp,
 260                         [SDNPCommutative, SDNPOutFlag, SDNPInFlag]>;
 261 def subc       : SDNode<"ISD::SUBC"      , SDTIntBinOp,
 262                         [SDNPOutFlag]>;
 263 def sube       : SDNode<"ISD::SUBE"      , SDTIntBinOp,
 264                         [SDNPOutFlag, SDNPInFlag]>;
 265
 266 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 267 def bswap      : SDNode<"ISD::BSWAP"      , SDTIntUnaryOp>;
 268 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 269 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 270 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 271 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 272 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 273 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 274 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 275 def bitconvert : SDNode<"ISD::BIT_CONVERT", SDTUnaryOp>;
 276
 277 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 278 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 279 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 280 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 281 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 282 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 283 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 284 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 285 def fsin       : SDNode<"ISD::FSIN"       , SDTFPUnaryOp>;
 286 def fcos       : SDNode<"ISD::FCOS"       , SDTFPUnaryOp>;
 287
 288 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 289 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 290 def fcopysign  : SDNode<"ISD::FCOPYSIGN"  , SDTFPSignOp>;
 291
 292 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 293 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 294 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 295 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 296
 297 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 298 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 299 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 300
 301 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrcond, [SDNPHasChain]>;
 302 def brind      : SDNode<"ISD::BRIND"      , SDTBrind,  [SDNPHasChain]>;
 303 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 304 def ret        : SDNode<"ISD::RET"        , SDTRet,    [SDNPHasChain]>;
 305
 306 // Do not use ld, st directly. Use load, extload, sextload, zextload, store,
 307 // and truncst (see below).
 308 def ld         : SDNode<"ISD::LOAD"       , SDTLoad,  [SDNPHasChain]>;
 309 def st         : SDNode<"ISD::STORE"      , SDTStore, [SDNPHasChain]>;
 310 def ist        : SDNode<"ISD::STORE"      , SDTIStore, [SDNPHasChain]>;
 311
 312 def vector_shuffle : SDNode<"ISD::VECTOR_SHUFFLE", SDTVecShuffle, []>;
 313 def build_vector : SDNode<"ISD::BUILD_VECTOR", SDTypeProfile<1, 0, []>, []>;
 314 def scalar_to_vector : SDNode<"ISD::SCALAR_TO_VECTOR", SDTypeProfile<1, 1, []>,
 315                               []>;
 316 def vector_extract : SDNode<"ISD::EXTRACT_VECTOR_ELT",
 317     SDTypeProfile<1, 2, [SDTCisPtrTy<2>]>, []>;
 318 def vector_insert : SDNode<"ISD::INSERT_VECTOR_ELT",
 319     SDTypeProfile<1, 3, [SDTCisSameAs<0, 1>, SDTCisPtrTy<3>]>, []>;
 320
 321 def extract_subreg : SDNode<"ISD::EXTRACT_SUBREG",
 322     SDTypeProfile<1, 2, []>>;
 323 def insert_subreg : SDNode<"ISD::INSERT_SUBREG",
 324     SDTypeProfile<1, 3, []>>;
 325
 326 // Nodes for intrinsics, you should use the intrinsic itself and let tblgen use
 327 // these internally.  Don't reference these directly.
 328 def intrinsic_void : SDNode<"ISD::INTRINSIC_VOID",
 329                             SDTypeProfile<0, -1, [SDTCisPtrTy<0>]>,
 330                             [SDNPHasChain]>;
 331 def intrinsic_w_chain : SDNode<"ISD::INTRINSIC_W_CHAIN",
 332                                SDTypeProfile<1, -1, [SDTCisPtrTy<1>]>,
 333                                [SDNPHasChain]>;
 334 def intrinsic_wo_chain : SDNode<"ISD::INTRINSIC_WO_CHAIN",
 335                                 SDTypeProfile<1, -1, [SDTCisPtrTy<1>]>, []>;
 336
 337
 338 //===----------------------------------------------------------------------===//
 339 // Selection DAG Condition Codes
 340
 341 class CondCode; // ISD::CondCode enums
 342 def SETOEQ : CondCode; def SETOGT : CondCode;
 343 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 344 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 345 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 346 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 347
 348 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 349 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 350
 351
 352 //===----------------------------------------------------------------------===//
 353 // Selection DAG Node Transformation Functions.
 354 //
 355 // This mechanism allows targets to manipulate nodes in the output DAG once a
 356 // match has been formed.  This is typically used to manipulate immediate
 357 // values.
 358 //
 359 class SDNodeXForm<SDNode opc, code xformFunction> {
 360   SDNode Opcode = opc;
 361   code XFormFunction = xformFunction;
 362 }
 363
 364 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 365
 366
 367 //===----------------------------------------------------------------------===//
 368 // Selection DAG Pattern Fragments.
 369 //
 370 // Pattern fragments are reusable chunks of dags that match specific things.
 371 // They can take arguments and have C++ predicates that control whether they
 372 // match.  They are intended to make the patterns for common instructions more
 373 // compact and readable.
 374 //
 375
 376 /// PatFrag - Represents a pattern fragment.  This can match something on the
 377 /// DAG, frame a single node to multiply nested other fragments.
 378 ///
 379 class PatFrag<dag ops, dag frag, code pred = [{}],
 380               SDNodeXForm xform = NOOP_SDNodeXForm> {
 381   dag Operands = ops;
 382   dag Fragment = frag;
 383   code Predicate = pred;
 384   SDNodeXForm OperandTransform = xform;
 385 }
 386
 387 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 388 // to define immediates and other common things concisely.
 389 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 390  : PatFrag<(ops), frag, pred, xform>;
 391
 392 // Leaf fragments.
 393
 394 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 395 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 396
 397 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 398 def immAllOnesV: PatLeaf<(build_vector), [{
 399   return ISD::isBuildVectorAllOnes(N);
 400 }]>;
 401 def immAllZerosV: PatLeaf<(build_vector), [{
 402   return ISD::isBuildVectorAllZeros(N);
 403 }]>;
 404
 405 def immAllOnesV_bc: PatLeaf<(bitconvert), [{
 406   return ISD::isBuildVectorAllOnes(N);
 407 }]>;
 408
 409
 410 // Other helper fragments.
 411 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 412 def vnot : PatFrag<(ops node:$in), (xor node:$in, immAllOnesV)>;
 413 def vnot_conv : PatFrag<(ops node:$in), (xor node:$in, immAllOnesV_bc)>;
 414 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 415
 416 // load fragments.
 417 def load : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 418   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 419     return LD->getExtensionType() == ISD::NON_EXTLOAD &&
 420            LD->getAddressingMode() == ISD::UNINDEXED;
 421   return false;
 422 }]>;
 423
 424 // extending load fragments.
 425 def extloadi1  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 426   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 427     return LD->getExtensionType() == ISD::EXTLOAD &&
 428            LD->getAddressingMode() == ISD::UNINDEXED &&
 429            LD->getLoadedVT() == MVT::i1;
 430   return false;
 431 }]>;
 432 def extloadi8  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 433   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 434     return LD->getExtensionType() == ISD::EXTLOAD &&
 435            LD->getAddressingMode() == ISD::UNINDEXED &&
 436            LD->getLoadedVT() == MVT::i8;
 437   return false;
 438 }]>;
 439 def extloadi16 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 440   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 441     return LD->getExtensionType() == ISD::EXTLOAD &&
 442            LD->getAddressingMode() == ISD::UNINDEXED &&
 443            LD->getLoadedVT() == MVT::i16;
 444   return false;
 445 }]>;
 446 def extloadi32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 447   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 448     return LD->getExtensionType() == ISD::EXTLOAD &&
 449            LD->getAddressingMode() == ISD::UNINDEXED &&
 450            LD->getLoadedVT() == MVT::i32;
 451   return false;
 452 }]>;
 453 def extloadf32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 454   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 455     return LD->getExtensionType() == ISD::EXTLOAD &&
 456            LD->getAddressingMode() == ISD::UNINDEXED &&
 457            LD->getLoadedVT() == MVT::f32;
 458   return false;
 459 }]>;
 460
 461 def sextloadi1  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 462   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 463     return LD->getExtensionType() == ISD::SEXTLOAD &&
 464            LD->getAddressingMode() == ISD::UNINDEXED &&
 465            LD->getLoadedVT() == MVT::i1;
 466   return false;
 467 }]>;
 468 def sextloadi8  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 469   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 470     return LD->getExtensionType() == ISD::SEXTLOAD &&
 471            LD->getAddressingMode() == ISD::UNINDEXED &&
 472            LD->getLoadedVT() == MVT::i8;
 473   return false;
 474 }]>;
 475 def sextloadi16 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 476   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 477     return LD->getExtensionType() == ISD::SEXTLOAD &&
 478            LD->getAddressingMode() == ISD::UNINDEXED &&
 479            LD->getLoadedVT() == MVT::i16;
 480   return false;
 481 }]>;
 482 def sextloadi32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 483   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 484     return LD->getExtensionType() == ISD::SEXTLOAD &&
 485            LD->getAddressingMode() == ISD::UNINDEXED &&
 486            LD->getLoadedVT() == MVT::i32;
 487   return false;
 488 }]>;
 489
 490 def zextloadi1  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 491   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 492     return LD->getExtensionType() == ISD::ZEXTLOAD &&
 493            LD->getAddressingMode() == ISD::UNINDEXED &&
 494            LD->getLoadedVT() == MVT::i1;
 495   return false;
 496 }]>;
 497 def zextloadi8  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 498   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 499     return LD->getExtensionType() == ISD::ZEXTLOAD &&
 500            LD->getAddressingMode() == ISD::UNINDEXED &&
 501            LD->getLoadedVT() == MVT::i8;
 502   return false;
 503 }]>;
 504 def zextloadi16 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 505   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 506     return LD->getExtensionType() == ISD::ZEXTLOAD &&
 507            LD->getAddressingMode() == ISD::UNINDEXED &&
 508            LD->getLoadedVT() == MVT::i16;
 509   return false;
 510 }]>;
 511 def zextloadi32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 512   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 513     return LD->getExtensionType() == ISD::ZEXTLOAD &&
 514            LD->getAddressingMode() == ISD::UNINDEXED &&
 515            LD->getLoadedVT() == MVT::i32;
 516   return false;
 517 }]>;
 518
 519 // store fragments.
 520 def store : PatFrag<(ops node:$val, node:$ptr),
 521                     (st node:$val, node:$ptr), [{
 522   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 523     return !ST->isTruncatingStore() &&
 524            ST->getAddressingMode() == ISD::UNINDEXED;
 525   return false;
 526 }]>;
 527
 528 // truncstore fragments.
 529 def truncstorei1 : PatFrag<(ops node:$val, node:$ptr),
 530                            (st node:$val, node:$ptr), [{
 531   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 532     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::i1 &&
 533            ST->getAddressingMode() == ISD::UNINDEXED;
 534   return false;
 535 }]>;
 536 def truncstorei8 : PatFrag<(ops node:$val, node:$ptr),
 537                            (st node:$val, node:$ptr), [{
 538   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 539     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::i8 &&
 540            ST->getAddressingMode() == ISD::UNINDEXED;
 541   return false;
 542 }]>;
 543 def truncstorei16 : PatFrag<(ops node:$val, node:$ptr),
 544                             (st node:$val, node:$ptr), [{
 545   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 546     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::i16 &&
 547            ST->getAddressingMode() == ISD::UNINDEXED;
 548   return false;
 549 }]>;
 550 def truncstorei32 : PatFrag<(ops node:$val, node:$ptr),
 551                             (st node:$val, node:$ptr), [{
 552   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 553     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::i32 &&
 554            ST->getAddressingMode() == ISD::UNINDEXED;
 555   return false;
 556 }]>;
 557 def truncstoref32 : PatFrag<(ops node:$val, node:$ptr),
 558                             (st node:$val, node:$ptr), [{
 559   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 560     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::f32 &&
 561            ST->getAddressingMode() == ISD::UNINDEXED;
 562   return false;
 563 }]>;
 564
 565 // indexed store fragments.
 566 def pre_store : PatFrag<(ops node:$val, node:$base, node:$offset),
 567                         (ist node:$val, node:$base, node:$offset), [{
 568   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 569     ISD::MemIndexedMode AM = ST->getAddressingMode();
 570     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 571            !ST->isTruncatingStore();
 572   }
 573   return false;
 574 }]>;
 575
 576 def pre_truncsti1 : PatFrag<(ops node:$val, node:$base, node:$offset),
 577                             (ist node:$val, node:$base, node:$offset), [{
 578   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 579     ISD::MemIndexedMode AM = ST->getAddressingMode();
 580     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 581            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i1;
 582   }
 583   return false;
 584 }]>;
 585 def pre_truncsti8 : PatFrag<(ops node:$val, node:$base, node:$offset),
 586                             (ist node:$val, node:$base, node:$offset), [{
 587   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 588     ISD::MemIndexedMode AM = ST->getAddressingMode();
 589     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 590            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i8;
 591   }
 592   return false;
 593 }]>;
 594 def pre_truncsti16 : PatFrag<(ops node:$val, node:$base, node:$offset),
 595                              (ist node:$val, node:$base, node:$offset), [{
 596   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 597     ISD::MemIndexedMode AM = ST->getAddressingMode();
 598     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 599            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i16;
 600   }
 601   return false;
 602 }]>;
 603 def pre_truncsti32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 604                              (ist node:$val, node:$base, node:$offset), [{
 605   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 606     ISD::MemIndexedMode AM = ST->getAddressingMode();
 607     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 608            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i32;
 609   }
 610   return false;
 611 }]>;
 612 def pre_truncstf32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 613                              (ist node:$val, node:$base, node:$offset), [{
 614   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 615     ISD::MemIndexedMode AM = ST->getAddressingMode();
 616     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 617            ST->isTruncatingStore() && ST->getStoredVT() == MVT::f32;
 618   }
 619   return false;
 620 }]>;
 621
 622 def post_store : PatFrag<(ops node:$val, node:$ptr, node:$offset),
 623                          (ist node:$val, node:$ptr, node:$offset), [{
 624   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 625     ISD::MemIndexedMode AM = ST->getAddressingMode();
 626     return !ST->isTruncatingStore() &&
 627             (AM == ISD::POST_INC || AM == ISD::POST_DEC);
 628   }
 629   return false;
 630 }]>;
 631
 632 def post_truncsti1 : PatFrag<(ops node:$val, node:$base, node:$offset),
 633                              (ist node:$val, node:$base, node:$offset), [{
 634   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 635     ISD::MemIndexedMode AM = ST->getAddressingMode();
 636     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 637            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i1;
 638   }
 639   return false;
 640 }]>;
 641 def post_truncsti8 : PatFrag<(ops node:$val, node:$base, node:$offset),
 642                              (ist node:$val, node:$base, node:$offset), [{
 643   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 644     ISD::MemIndexedMode AM = ST->getAddressingMode();
 645     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 646            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i8;
 647   }
 648   return false;
 649 }]>;
 650 def post_truncsti16 : PatFrag<(ops node:$val, node:$base, node:$offset),
 651                               (ist node:$val, node:$base, node:$offset), [{
 652   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 653     ISD::MemIndexedMode AM = ST->getAddressingMode();
 654     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 655            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i16;
 656   }
 657   return false;
 658 }]>;
 659 def post_truncsti32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 660                               (ist node:$val, node:$base, node:$offset), [{
 661   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 662     ISD::MemIndexedMode AM = ST->getAddressingMode();
 663     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 664            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i32;
 665   }
 666   return false;
 667 }]>;
 668 def post_truncstf32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 669                               (ist node:$val, node:$base, node:$offset), [{
 670   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 671     ISD::MemIndexedMode AM = ST->getAddressingMode();
 672     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 673            ST->isTruncatingStore() && ST->getStoredVT() == MVT::f32;
 674   }
 675   return false;
 676 }]>;
 677
 678 // setcc convenience fragments.
 679 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 680                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 681 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 682                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 683 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 684                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 685 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 686                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 687 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 688                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 689 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 690                      (setcc node:$lhs, node:$rhs, SETONE)>;
 691 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 692                      (setcc node:$lhs, node:$rhs, SETO)>;
 693 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 694                      (setcc node:$lhs, node:$rhs, SETUO)>;
 695 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 696                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 697 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 698                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 699 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 700                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 701 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 702                      (setcc node:$lhs, node:$rhs, SETULT)>;
 703 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 704                      (setcc node:$lhs, node:$rhs, SETULE)>;
 705 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 706                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 707 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 708                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 709 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 710                      (setcc node:$lhs, node:$rhs, SETGT)>;
 711 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 712                      (setcc node:$lhs, node:$rhs, SETGE)>;
 713 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 714                      (setcc node:$lhs, node:$rhs, SETLT)>;
 715 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 716                      (setcc node:$lhs, node:$rhs, SETLE)>;
 717 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 718                      (setcc node:$lhs, node:$rhs, SETNE)>;
 719
 720 //===----------------------------------------------------------------------===//
 721 // Selection DAG Pattern Support.
 722 //
 723 // Patterns are what are actually matched against the target-flavored
 724 // instruction selection DAG.  Instructions defined by the target implicitly
 725 // define patterns in most cases, but patterns can also be explicitly added when
 726 // an operation is defined by a sequence of instructions (e.g. loading a large
 727 // immediate value on RISC targets that do not support immediates as large as
 728 // their GPRs).
 729 //
 730
 731 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 732   dag             PatternToMatch  = patternToMatch;
 733   list<dag>       ResultInstrs    = resultInstrs;
 734   list<Predicate> Predicates      = [];  // See class Instruction in Target.td.
 735   int             AddedComplexity = 0;  // See class Instruction in Target.td.
 736 }
 737
 738 // Pat - A simple (but common) form of a pattern, which produces a simple result
 739 // not needing a full list.
 740 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 741
 742 //===----------------------------------------------------------------------===//
 743 // Complex pattern definitions.
 744 //
 745 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 746 // in C++. NumOperands is the number of operands returned by the select function;
 747 // SelectFunc is the name of the function used to pattern match the max. pattern;
 748 // RootNodes are the list of possible root nodes of the sub-dags to match.
 749 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 750 //
 751 class ComplexPattern<ValueType ty, int numops, string fn,
 752                      list<SDNode> roots = [], list<SDNodeProperty> props = []> {
 753   ValueType Ty = ty;
 754   int NumOperands = numops;
 755   string SelectFunc = fn;
 756   list<SDNode> RootNodes = roots;
 757   list<SDNodeProperty> Properties = props;
 758 }
 759
 760 //===----------------------------------------------------------------------===//
 761 // Dwarf support.
 762 //
 763 def SDT_dwarf_loc : SDTypeProfile<0, 3,
 764                       [SDTCisInt<0>, SDTCisInt<1>, SDTCisInt<2>]>;
 765 def dwarf_loc : SDNode<"ISD::DEBUG_LOC", SDT_dwarf_loc,[SDNPHasChain]>;
 766
 767
 768