lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 //===----------------------------------------------------------------------===//
  55 // Selection DAG Type Profile definitions.
  56 //
  57 // These use the constraints defined above to describe the type requirements of
  58 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  59 // add their own if needed.
  60 //
  61
  62 // SDTypeProfile - This profile describes the type requirements of a Selection
  63 // DAG node.
  64 class SDTypeProfile<int numresults, int numoperands,
  65                     list<SDTypeConstraint> constraints> {
  66   int NumResults = numresults;
  67   int NumOperands = numoperands;
  68   list<SDTypeConstraint> Constraints = constraints;
  69 }
  70
  71 // Builtin profiles.
  72 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  73 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  74 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  75 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  76 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  77   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  78 ]>;
  79 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  80   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  81 ]>;
  82 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  83   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  84 ]>;
  85 def SDTFPTernaryOp : SDTypeProfile<1, 3, [      // fmadd, fnmsub, etc.
  86   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
  87 ]>;
  88 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
  89   SDTCisSameAs<0, 1>, SDTCisInt<0>
  90 ]>;
  91 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
  92   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
  93 ]>;
  94 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
  95   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
  96 ]>;
  97 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
  98   SDTCisSameAs<0, 1>, SDTCisFP<0>
  99 ]>;
 100 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 101   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 102 ]>;
 103 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 104   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 105 ]>;
 106 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 107   SDTCisFP<0>, SDTCisInt<1>
 108 ]>;
 109 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 110   SDTCisInt<0>, SDTCisFP<1>
 111 ]>;
 112 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 113   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 114   SDTCisVTSmallerThanOp<2, 1>
 115 ]>;
 116
 117 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 118   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 119 ]>;
 120
 121 def SDTSelect : SDTypeProfile<1, 3, [ // select
 122   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 123 ]>;
 124
 125 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 126   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 127   SDTCisVT<5, OtherVT>
 128 ]>;
 129
 130 def SDTBr : SDTypeProfile<0, 1, [ // br
 131   SDTCisVT<0, OtherVT>
 132 ]>;
 133
 134 def SDTRet : SDTypeProfile<0, 0, []>; // ret
 135
 136 def SDTReadPort : SDTypeProfile<1, 1, [ // readport
 137   SDTCisInt<0>, SDTCisInt<1>
 138 ]>;
 139
 140 def SDTWritePort : SDTypeProfile<0, 2, [ // writeport
 141   SDTCisInt<0>, SDTCisInt<1>
 142 ]>;
 143
 144 def SDTLoad : SDTypeProfile<1, 1, [ // load
 145   SDTCisPtrTy<1>
 146 ]>;
 147
 148 def SDTStore : SDTypeProfile<0, 2, [ // store
 149   SDTCisPtrTy<1>
 150 ]>;
 151
 152 def SDTExtLoad : SDTypeProfile<1, 3, [  // extload
 153   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 154 ]>;
 155 def SDTIntExtLoad : SDTypeProfile<1, 3, [  // sextload, zextload
 156   SDTCisInt<0>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 157 ]>;
 158 def SDTTruncStore : SDTypeProfile<0, 4, [  // truncstore
 159   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 160 ]>;
 161
 162
 163 //===----------------------------------------------------------------------===//
 164 // Selection DAG Node Properties.
 165 //
 166 // Note: These are hard coded into tblgen.
 167 //
 168 class SDNodeProperty;
 169 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 170 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 171 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 172
 173 //===----------------------------------------------------------------------===//
 174 // Selection DAG Node definitions.
 175 //
 176 class SDNode<string opcode, SDTypeProfile typeprof,
 177              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 178   string Opcode  = opcode;
 179   string SDClass = sdclass;
 180   list<SDNodeProperty> Properties = props;
 181   SDTypeProfile TypeProfile = typeprof;
 182 }
 183
 184 def set;
 185 def node;
 186 def srcvalue;
 187
 188 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 189 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 190 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 191 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 192 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 193 def globaladdr : SDNode<"ISD::GlobalAddress",         SDTPtrLeaf, [],
 194                         "GlobalAddressSDNode">;
 195 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress",  SDTPtrLeaf, [],
 196                          "GlobalAddressSDNode">;
 197 def constpool   : SDNode<"ISD::ConstantPool",         SDTPtrLeaf, [],
 198                          "ConstantPoolSDNode">;
 199 def tconstpool  : SDNode<"ISD::TargetConstantPool",   SDTPtrLeaf, [],
 200                          "ConstantPoolSDNode">;
 201 def frameindex  : SDNode<"ISD::FrameIndex",           SDTPtrLeaf, [],
 202                          "FrameIndexSDNode">;
 203 def tframeindex : SDNode<"ISD::TargetFrameIndex",     SDTPtrLeaf, [],
 204                          "FrameIndexSDNode">;
 205 def externalsym : SDNode<"ISD::ExternalSymbol",       SDTPtrLeaf, [],
 206                          "ExternalSymbolSDNode">;
 207 def texternalsym: SDNode<"ISD::TargetExternalSymbol", SDTPtrLeaf, [],
 208                          "ExternalSymbolSDNode">;
 209
 210 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 211                         [SDNPCommutative, SDNPAssociative]>;
 212 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 213 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 214                         [SDNPCommutative, SDNPAssociative]>;
 215 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 216 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 217 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 218 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 219 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 220 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 221 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 222 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 223 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 224 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 225                         [SDNPCommutative, SDNPAssociative]>;
 226 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 227                         [SDNPCommutative, SDNPAssociative]>;
 228 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 229                         [SDNPCommutative, SDNPAssociative]>;
 230
 231 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 232 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 233 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 234 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 235 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 236 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 237 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 238 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 239
 240 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 241 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 242 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 243 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 244 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 245 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 246 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 247 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 248 def fsin       : SDNode<"ISD::FSIN"       , SDTFPUnaryOp>;
 249 def fcos       : SDNode<"ISD::FCOS"       , SDTFPUnaryOp>;
 250
 251 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 252 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 253
 254 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 255 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 256 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 257 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 258
 259 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 260 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 261 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 262
 263 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 264 def ret        : SDNode<"ISD::RET"        , SDTRet,    [SDNPHasChain]>;
 265
 266 def readport   : SDNode<"ISD::READPORT"   , SDTReadPort,  [SDNPHasChain]>;
 267 def writeport  : SDNode<"ISD::WRITEPORT"  , SDTWritePort, [SDNPHasChain]>;
 268
 269 def load       : SDNode<"ISD::LOAD"       , SDTLoad,  [SDNPHasChain]>;
 270 def store      : SDNode<"ISD::STORE"      , SDTStore, [SDNPHasChain]>;
 271
 272 // Do not use sextld and zextld directly. Use sextload and zextload (see
 273 // below) which pass in a dummy srcvalue node which tblgen will skip over.
 274 def sextld     : SDNode<"ISD::SEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 275 def zextld     : SDNode<"ISD::ZEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 276 def extld      : SDNode<"ISD::EXTLOAD"    , SDTExtLoad,    [SDNPHasChain]>;
 277 def truncst    : SDNode<"ISD::TRUNCSTORE" , SDTTruncStore, [SDNPHasChain]>;
 278
 279 //===----------------------------------------------------------------------===//
 280 // Selection DAG Condition Codes
 281
 282 class CondCode; // ISD::CondCode enums
 283 def SETOEQ : CondCode; def SETOGT : CondCode;
 284 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 285 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 286 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 287 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 288
 289 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 290 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 291
 292
 293 //===----------------------------------------------------------------------===//
 294 // Selection DAG Node Transformation Functions.
 295 //
 296 // This mechanism allows targets to manipulate nodes in the output DAG once a
 297 // match has been formed.  This is typically used to manipulate immediate
 298 // values.
 299 //
 300 class SDNodeXForm<SDNode opc, code xformFunction> {
 301   SDNode Opcode = opc;
 302   code XFormFunction = xformFunction;
 303 }
 304
 305 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 306
 307
 308 //===----------------------------------------------------------------------===//
 309 // Selection DAG Pattern Fragments.
 310 //
 311 // Pattern fragments are reusable chunks of dags that match specific things.
 312 // They can take arguments and have C++ predicates that control whether they
 313 // match.  They are intended to make the patterns for common instructions more
 314 // compact and readable.
 315 //
 316
 317 /// PatFrag - Represents a pattern fragment.  This can match something on the
 318 /// DAG, frame a single node to multiply nested other fragments.
 319 ///
 320 class PatFrag<dag ops, dag frag, code pred = [{}],
 321               SDNodeXForm xform = NOOP_SDNodeXForm> {
 322   dag Operands = ops;
 323   dag Fragment = frag;
 324   code Predicate = pred;
 325   SDNodeXForm OperandTransform = xform;
 326 }
 327
 328 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 329 // to define immediates and other common things concisely.
 330 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 331  : PatFrag<(ops), frag, pred, xform>;
 332
 333 // Leaf fragments.
 334
 335 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 336
 337 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 338 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 339
 340 // Other helper fragments.
 341
 342 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 343 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 344
 345 // extending load & truncstore fragments.
 346 def sextload      : PatFrag<(ops node:$ptr, node:$vt),
 347                             (sextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 348 def zextload      : PatFrag<(ops node:$ptr, node:$vt),
 349                             (zextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 350 def extload       : PatFrag<(ops node:$ptr, node:$vt),
 351                             (extld node:$ptr, srcvalue:$dummy, node:$vt)>;
 352 def truncstore    : PatFrag<(ops node:$val, node:$ptr, node:$vt),
 353                             (truncst node:$val, node:$ptr, srcvalue:$dummy,
 354                             node:$vt)>;
 355
 356 // setcc convenience fragments.
 357 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 358                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 359 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 360                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 361 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 362                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 363 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 364                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 365 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 366                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 367 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 368                      (setcc node:$lhs, node:$rhs, SETONE)>;
 369 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 370                      (setcc node:$lhs, node:$rhs, SETO)>;
 371 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 372                      (setcc node:$lhs, node:$rhs, SETUO)>;
 373 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 374                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 375 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 376                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 377 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 378                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 379 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 380                      (setcc node:$lhs, node:$rhs, SETULT)>;
 381 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 382                      (setcc node:$lhs, node:$rhs, SETULE)>;
 383 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 384                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 385 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 386                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 387 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 388                      (setcc node:$lhs, node:$rhs, SETGT)>;
 389 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 390                      (setcc node:$lhs, node:$rhs, SETGE)>;
 391 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 392                      (setcc node:$lhs, node:$rhs, SETLT)>;
 393 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 394                      (setcc node:$lhs, node:$rhs, SETLE)>;
 395 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 396                      (setcc node:$lhs, node:$rhs, SETNE)>;
 397
 398 //===----------------------------------------------------------------------===//
 399 // Selection DAG Pattern Support.
 400 //
 401 // Patterns are what are actually matched against the target-flavored
 402 // instruction selection DAG.  Instructions defined by the target implicitly
 403 // define patterns in most cases, but patterns can also be explicitly added when
 404 // an operation is defined by a sequence of instructions (e.g. loading a large
 405 // immediate value on RISC targets that do not support immediates as large as
 406 // their GPRs).
 407 //
 408
 409 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 410   dag             PatternToMatch = patternToMatch;
 411   list<dag>       ResultInstrs   = resultInstrs;
 412   list<Predicate> Predicates     = [];  // See class Instruction in Target.td.
 413 }
 414
 415 // Pat - A simple (but common) form of a pattern, which produces a simple result
 416 // not needing a full list.
 417 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 418
 419 //===----------------------------------------------------------------------===//
 420 // Complex pattern definitions.
 421 //
 422 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 423 // in C++. NumOperands is the number of operands returned by the select function;
 424 // SelectFunc is the name of the function used to pattern match the max. pattern;
 425 // RootNodes are the list of possible root nodes of the sub-dags to match.
 426 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 427 //
 428 class ComplexPattern<ValueType ty, int numops, string fn, list<SDNode> roots = []> {
 429   ValueType Ty = ty;
 430   int NumOperands = numops;
 431   string SelectFunc = fn;
 432   list<SDNode> RootNodes = roots;
 433 }
 434
 435 //===----------------------------------------------------------------------===//
 436 // Dwarf support.
 437 //
 438 def SDT_dwarf_loc : SDTypeProfile<0, 3,
 439                                     [SDTCisInt<0>, SDTCisInt<1>, SDTCisInt<2>]>;
 440 def dwarf_loc  : SDNode<"ISD::DEBUG_LOC", SDT_dwarf_loc,[SDNPHasChain]>;
 441
 442
 443