lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 /// SDTCisIntVectorOfSameSize - This indicates that ThisOp and OtherOp are
  55 /// vector types, and that ThisOp is the result of
  56 /// MVT::getIntVectorWithNumElements with the number of elements that ThisOp
  57 /// has.
  58 class SDTCisIntVectorOfSameSize<int ThisOp, int OtherOp>
  59   : SDTypeConstraint<ThisOp> {
  60   int OtherOpNum = OtherOp;
  61 }
  62
  63 //===----------------------------------------------------------------------===//
  64 // Selection DAG Type Profile definitions.
  65 //
  66 // These use the constraints defined above to describe the type requirements of
  67 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  68 // add their own if needed.
  69 //
  70
  71 // SDTypeProfile - This profile describes the type requirements of a Selection
  72 // DAG node.
  73 class SDTypeProfile<int numresults, int numoperands,
  74                     list<SDTypeConstraint> constraints> {
  75   int NumResults = numresults;
  76   int NumOperands = numoperands;
  77   list<SDTypeConstraint> Constraints = constraints;
  78 }
  79
  80 // Builtin profiles.
  81 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  82 def SDTFPLeaf : SDTypeProfile<1, 0, [SDTCisFP<0>]>;       // for 'fpimm'.
  83 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  84 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  85 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  86 def SDTUnaryOp  : SDTypeProfile<1, 1, []>; // bitconvert
  87
  88 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  89   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  90 ]>;
  91 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  92   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  93 ]>;
  94 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  95   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  96 ]>;
  97 def SDTFPSignOp : SDTypeProfile<1, 2, [      // fcopysign.
  98   SDTCisSameAs<0, 1>, SDTCisFP<0>, SDTCisFP<2>
  99 ]>;
 100 def SDTFPTernaryOp : SDTypeProfile<1, 3, [      // fmadd, fnmsub, etc.
 101   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
 102 ]>;
 103 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
 104   SDTCisSameAs<0, 1>, SDTCisInt<0>
 105 ]>;
 106 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
 107   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
 108 ]>;
 109 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
 110   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
 111 ]>;
 112 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
 113   SDTCisSameAs<0, 1>, SDTCisFP<0>
 114 ]>;
 115 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 116   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 117 ]>;
 118 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 119   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 120 ]>;
 121 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 122   SDTCisFP<0>, SDTCisInt<1>
 123 ]>;
 124 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 125   SDTCisInt<0>, SDTCisFP<1>
 126 ]>;
 127 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 128   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 129   SDTCisVTSmallerThanOp<2, 1>
 130 ]>;
 131
 132 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 133   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 134 ]>;
 135
 136 def SDTSelect : SDTypeProfile<1, 3, [ // select
 137   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 138 ]>;
 139
 140 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 141   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 142   SDTCisVT<5, OtherVT>
 143 ]>;
 144
 145 def SDTBr : SDTypeProfile<0, 1, [ // br
 146   SDTCisVT<0, OtherVT>
 147 ]>;
 148
 149 def SDTBrcond : SDTypeProfile<0, 2, [ // brcond
 150   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 151 ]>;
 152
 153 def SDTBrind : SDTypeProfile<0, 1, [ // brind
 154   SDTCisPtrTy<0>
 155 ]>;
 156
 157 def SDTNone : SDTypeProfile<0, 0, []>; // ret, trap
 158
 159 def SDTLoad : SDTypeProfile<1, 1, [ // load
 160   SDTCisPtrTy<1>
 161 ]>;
 162
 163 def SDTStore : SDTypeProfile<0, 2, [ // store
 164   SDTCisPtrTy<1>
 165 ]>;
 166
 167 def SDTIStore : SDTypeProfile<1, 3, [ // indexed store
 168   SDTCisSameAs<0, 2>, SDTCisPtrTy<0>, SDTCisPtrTy<3>
 169 ]>;
 170
 171 def SDTVecShuffle : SDTypeProfile<1, 3, [
 172   SDTCisSameAs<0, 1>, SDTCisSameAs<1, 2>, SDTCisIntVectorOfSameSize<3, 0>
 173 ]>;
 174
 175 class SDCallSeqStart<list<SDTypeConstraint> constraints> :
 176         SDTypeProfile<0, 1, constraints>;
 177 class SDCallSeqEnd<list<SDTypeConstraint> constraints> :
 178         SDTypeProfile<0, 2, constraints>;
 179
 180 //===----------------------------------------------------------------------===//
 181 // Selection DAG Node Properties.
 182 //
 183 // Note: These are hard coded into tblgen.
 184 //
 185 class SDNodeProperty;
 186 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 187 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 188 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 189 def SDNPOutFlag     : SDNodeProperty;   // Write a flag result
 190 def SDNPInFlag      : SDNodeProperty;   // Read a flag operand
 191 def SDNPOptInFlag   : SDNodeProperty;   // Optionally read a flag operand
 192 def SDNPMayStore    : SDNodeProperty;   // May write to memory, sets 'mayStore'.
 193 def SDNPMayLoad     : SDNodeProperty;   // May read memory, sets 'mayLoad'.
 194 def SDNPSideEffect  : SDNodeProperty;   // Sets 'HasUnmodelledSideEffects'.
 195
 196 //===----------------------------------------------------------------------===//
 197 // Selection DAG Node definitions.
 198 //
 199 class SDNode<string opcode, SDTypeProfile typeprof,
 200              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 201   string Opcode  = opcode;
 202   string SDClass = sdclass;
 203   list<SDNodeProperty> Properties = props;
 204   SDTypeProfile TypeProfile = typeprof;
 205 }
 206
 207 def set;
 208 def implicit;
 209 def parallel;
 210 def node;
 211 def srcvalue;
 212
 213 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 214 def fpimm      : SDNode<"ISD::TargetConstantFP",
 215                          SDTFPLeaf, [], "ConstantFPSDNode">;
 216 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 217 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 218 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 219 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 220 def globaladdr : SDNode<"ISD::GlobalAddress",         SDTPtrLeaf, [],
 221                         "GlobalAddressSDNode">;
 222 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress",  SDTPtrLeaf, [],
 223                          "GlobalAddressSDNode">;
 224 def globaltlsaddr : SDNode<"ISD::GlobalTLSAddress",         SDTPtrLeaf, [],
 225                           "GlobalAddressSDNode">;
 226 def tglobaltlsaddr : SDNode<"ISD::TargetGlobalTLSAddress",  SDTPtrLeaf, [],
 227                            "GlobalAddressSDNode">;
 228 def constpool   : SDNode<"ISD::ConstantPool",         SDTPtrLeaf, [],
 229                          "ConstantPoolSDNode">;
 230 def tconstpool  : SDNode<"ISD::TargetConstantPool",   SDTPtrLeaf, [],
 231                          "ConstantPoolSDNode">;
 232 def jumptable   : SDNode<"ISD::JumpTable",            SDTPtrLeaf, [],
 233                          "JumpTableSDNode">;
 234 def tjumptable  : SDNode<"ISD::TargetJumpTable",      SDTPtrLeaf, [],
 235                          "JumpTableSDNode">;
 236 def frameindex  : SDNode<"ISD::FrameIndex",           SDTPtrLeaf, [],
 237                          "FrameIndexSDNode">;
 238 def tframeindex : SDNode<"ISD::TargetFrameIndex",     SDTPtrLeaf, [],
 239                          "FrameIndexSDNode">;
 240 def externalsym : SDNode<"ISD::ExternalSymbol",       SDTPtrLeaf, [],
 241                          "ExternalSymbolSDNode">;
 242 def texternalsym: SDNode<"ISD::TargetExternalSymbol", SDTPtrLeaf, [],
 243                          "ExternalSymbolSDNode">;
 244
 245 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 246                         [SDNPCommutative, SDNPAssociative]>;
 247 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 248 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 249                         [SDNPCommutative, SDNPAssociative]>;
 250 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 251 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 252 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 253 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 254 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 255 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 256 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 257 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 258 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 259 def rotl       : SDNode<"ISD::ROTL"      , SDTIntShiftOp>;
 260 def rotr       : SDNode<"ISD::ROTR"      , SDTIntShiftOp>;
 261 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 262                         [SDNPCommutative, SDNPAssociative]>;
 263 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 264                         [SDNPCommutative, SDNPAssociative]>;
 265 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 266                         [SDNPCommutative, SDNPAssociative]>;
 267 def addc       : SDNode<"ISD::ADDC"      , SDTIntBinOp,
 268                         [SDNPCommutative, SDNPOutFlag]>;
 269 def adde       : SDNode<"ISD::ADDE"      , SDTIntBinOp,
 270                         [SDNPCommutative, SDNPOutFlag, SDNPInFlag]>;
 271 def subc       : SDNode<"ISD::SUBC"      , SDTIntBinOp,
 272                         [SDNPOutFlag]>;
 273 def sube       : SDNode<"ISD::SUBE"      , SDTIntBinOp,
 274                         [SDNPOutFlag, SDNPInFlag]>;
 275
 276 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 277 def bswap      : SDNode<"ISD::BSWAP"      , SDTIntUnaryOp>;
 278 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 279 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 280 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 281 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 282 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 283 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 284 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 285 def bitconvert : SDNode<"ISD::BIT_CONVERT", SDTUnaryOp>;
 286
 287 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 288 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 289 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 290 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 291 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 292 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 293 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 294 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 295 def fsin       : SDNode<"ISD::FSIN"       , SDTFPUnaryOp>;
 296 def fcos       : SDNode<"ISD::FCOS"       , SDTFPUnaryOp>;
 297
 298 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 299 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 300 def fcopysign  : SDNode<"ISD::FCOPYSIGN"  , SDTFPSignOp>;
 301
 302 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 303 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 304 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 305 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 306
 307 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 308 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 309 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 310
 311 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrcond, [SDNPHasChain]>;
 312 def brind      : SDNode<"ISD::BRIND"      , SDTBrind,  [SDNPHasChain]>;
 313 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 314 def ret        : SDNode<"ISD::RET"        , SDTNone,   [SDNPHasChain]>;
 315 def trap       : SDNode<"ISD::TRAP"       , SDTNone,
 316                         [SDNPHasChain, SDNPSideEffect]>;
 317
 318 // Do not use ld, st directly. Use load, extload, sextload, zextload, store,
 319 // and truncst (see below).
 320 def ld         : SDNode<"ISD::LOAD"       , SDTLoad,
 321                         [SDNPHasChain, SDNPMayLoad]>;
 322 def st         : SDNode<"ISD::STORE"      , SDTStore,
 323                         [SDNPHasChain, SDNPMayStore]>;
 324 def ist        : SDNode<"ISD::STORE"      , SDTIStore,
 325                         [SDNPHasChain, SDNPMayStore]>;
 326
 327 def vector_shuffle : SDNode<"ISD::VECTOR_SHUFFLE", SDTVecShuffle, []>;
 328 def build_vector : SDNode<"ISD::BUILD_VECTOR", SDTypeProfile<1, 0, []>, []>;
 329 def scalar_to_vector : SDNode<"ISD::SCALAR_TO_VECTOR", SDTypeProfile<1, 1, []>,
 330                               []>;
 331 def vector_extract : SDNode<"ISD::EXTRACT_VECTOR_ELT",
 332     SDTypeProfile<1, 2, [SDTCisPtrTy<2>]>, []>;
 333 def vector_insert : SDNode<"ISD::INSERT_VECTOR_ELT",
 334     SDTypeProfile<1, 3, [SDTCisSameAs<0, 1>, SDTCisPtrTy<3>]>, []>;
 335
 336 def extract_subreg : SDNode<"ISD::EXTRACT_SUBREG",
 337     SDTypeProfile<1, 2, []>>;
 338 def insert_subreg : SDNode<"ISD::INSERT_SUBREG",
 339     SDTypeProfile<1, 3, []>>;
 340
 341 // Nodes for intrinsics, you should use the intrinsic itself and let tblgen use
 342 // these internally.  Don't reference these directly.
 343 def intrinsic_void : SDNode<"ISD::INTRINSIC_VOID",
 344                             SDTypeProfile<0, -1, [SDTCisPtrTy<0>]>,
 345                             [SDNPHasChain]>;
 346 def intrinsic_w_chain : SDNode<"ISD::INTRINSIC_W_CHAIN",
 347                                SDTypeProfile<1, -1, [SDTCisPtrTy<1>]>,
 348                                [SDNPHasChain]>;
 349 def intrinsic_wo_chain : SDNode<"ISD::INTRINSIC_WO_CHAIN",
 350                                 SDTypeProfile<1, -1, [SDTCisPtrTy<1>]>, []>;
 351
 352
 353 //===----------------------------------------------------------------------===//
 354 // Selection DAG Condition Codes
 355
 356 class CondCode; // ISD::CondCode enums
 357 def SETOEQ : CondCode; def SETOGT : CondCode;
 358 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 359 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 360 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 361 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 362
 363 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 364 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 365
 366
 367 //===----------------------------------------------------------------------===//
 368 // Selection DAG Node Transformation Functions.
 369 //
 370 // This mechanism allows targets to manipulate nodes in the output DAG once a
 371 // match has been formed.  This is typically used to manipulate immediate
 372 // values.
 373 //
 374 class SDNodeXForm<SDNode opc, code xformFunction> {
 375   SDNode Opcode = opc;
 376   code XFormFunction = xformFunction;
 377 }
 378
 379 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 380
 381
 382 //===----------------------------------------------------------------------===//
 383 // Selection DAG Pattern Fragments.
 384 //
 385 // Pattern fragments are reusable chunks of dags that match specific things.
 386 // They can take arguments and have C++ predicates that control whether they
 387 // match.  They are intended to make the patterns for common instructions more
 388 // compact and readable.
 389 //
 390
 391 /// PatFrag - Represents a pattern fragment.  This can match something on the
 392 /// DAG, frame a single node to multiply nested other fragments.
 393 ///
 394 class PatFrag<dag ops, dag frag, code pred = [{}],
 395               SDNodeXForm xform = NOOP_SDNodeXForm> {
 396   dag Operands = ops;
 397   dag Fragment = frag;
 398   code Predicate = pred;
 399   SDNodeXForm OperandTransform = xform;
 400 }
 401
 402 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 403 // to define immediates and other common things concisely.
 404 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 405  : PatFrag<(ops), frag, pred, xform>;
 406
 407 // Leaf fragments.
 408
 409 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 410 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 411
 412 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 413 def immAllOnesV: PatLeaf<(build_vector), [{
 414   return ISD::isBuildVectorAllOnes(N);
 415 }]>;
 416 def immAllOnesV_bc: PatLeaf<(bitconvert), [{
 417   return ISD::isBuildVectorAllOnes(N);
 418 }]>;
 419 def immAllZerosV: PatLeaf<(build_vector), [{
 420   return ISD::isBuildVectorAllZeros(N);
 421 }]>;
 422 def immAllZerosV_bc: PatLeaf<(bitconvert), [{
 423   return ISD::isBuildVectorAllZeros(N);
 424 }]>;
 425
 426
 427
 428 // Other helper fragments.
 429 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 430 def vnot : PatFrag<(ops node:$in), (xor node:$in, immAllOnesV)>;
 431 def vnot_conv : PatFrag<(ops node:$in), (xor node:$in, immAllOnesV_bc)>;
 432 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 433
 434 // load fragments.
 435 def load : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 436   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 437     return LD->getExtensionType() == ISD::NON_EXTLOAD &&
 438            LD->getAddressingMode() == ISD::UNINDEXED;
 439   return false;
 440 }]>;
 441
 442 // extending load fragments.
 443 def extloadi1  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 444   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 445     return LD->getExtensionType() == ISD::EXTLOAD &&
 446            LD->getAddressingMode() == ISD::UNINDEXED &&
 447            LD->getLoadedVT() == MVT::i1;
 448   return false;
 449 }]>;
 450 def extloadi8  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 451   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 452     return LD->getExtensionType() == ISD::EXTLOAD &&
 453            LD->getAddressingMode() == ISD::UNINDEXED &&
 454            LD->getLoadedVT() == MVT::i8;
 455   return false;
 456 }]>;
 457 def extloadi16 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 458   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 459     return LD->getExtensionType() == ISD::EXTLOAD &&
 460            LD->getAddressingMode() == ISD::UNINDEXED &&
 461            LD->getLoadedVT() == MVT::i16;
 462   return false;
 463 }]>;
 464 def extloadi32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 465   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 466     return LD->getExtensionType() == ISD::EXTLOAD &&
 467            LD->getAddressingMode() == ISD::UNINDEXED &&
 468            LD->getLoadedVT() == MVT::i32;
 469   return false;
 470 }]>;
 471 def extloadf32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 472   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 473     return LD->getExtensionType() == ISD::EXTLOAD &&
 474            LD->getAddressingMode() == ISD::UNINDEXED &&
 475            LD->getLoadedVT() == MVT::f32;
 476   return false;
 477 }]>;
 478 def extloadf64 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 479   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 480     return LD->getExtensionType() == ISD::EXTLOAD &&
 481            LD->getAddressingMode() == ISD::UNINDEXED &&
 482            LD->getLoadedVT() == MVT::f64;
 483   return false;
 484 }]>;
 485
 486 def sextloadi1  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 487   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 488     return LD->getExtensionType() == ISD::SEXTLOAD &&
 489            LD->getAddressingMode() == ISD::UNINDEXED &&
 490            LD->getLoadedVT() == MVT::i1;
 491   return false;
 492 }]>;
 493 def sextloadi8  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 494   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 495     return LD->getExtensionType() == ISD::SEXTLOAD &&
 496            LD->getAddressingMode() == ISD::UNINDEXED &&
 497            LD->getLoadedVT() == MVT::i8;
 498   return false;
 499 }]>;
 500 def sextloadi16 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 501   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 502     return LD->getExtensionType() == ISD::SEXTLOAD &&
 503            LD->getAddressingMode() == ISD::UNINDEXED &&
 504            LD->getLoadedVT() == MVT::i16;
 505   return false;
 506 }]>;
 507 def sextloadi32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 508   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 509     return LD->getExtensionType() == ISD::SEXTLOAD &&
 510            LD->getAddressingMode() == ISD::UNINDEXED &&
 511            LD->getLoadedVT() == MVT::i32;
 512   return false;
 513 }]>;
 514
 515 def zextloadi1  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 516   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 517     return LD->getExtensionType() == ISD::ZEXTLOAD &&
 518            LD->getAddressingMode() == ISD::UNINDEXED &&
 519            LD->getLoadedVT() == MVT::i1;
 520   return false;
 521 }]>;
 522 def zextloadi8  : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 523   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 524     return LD->getExtensionType() == ISD::ZEXTLOAD &&
 525            LD->getAddressingMode() == ISD::UNINDEXED &&
 526            LD->getLoadedVT() == MVT::i8;
 527   return false;
 528 }]>;
 529 def zextloadi16 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 530   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 531     return LD->getExtensionType() == ISD::ZEXTLOAD &&
 532            LD->getAddressingMode() == ISD::UNINDEXED &&
 533            LD->getLoadedVT() == MVT::i16;
 534   return false;
 535 }]>;
 536 def zextloadi32 : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 537   if (LoadSDNode *LD = dyn_cast<LoadSDNode>(N))
 538     return LD->getExtensionType() == ISD::ZEXTLOAD &&
 539            LD->getAddressingMode() == ISD::UNINDEXED &&
 540            LD->getLoadedVT() == MVT::i32;
 541   return false;
 542 }]>;
 543
 544 // store fragments.
 545 def store : PatFrag<(ops node:$val, node:$ptr),
 546                     (st node:$val, node:$ptr), [{
 547   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 548     return !ST->isTruncatingStore() &&
 549            ST->getAddressingMode() == ISD::UNINDEXED;
 550   return false;
 551 }]>;
 552
 553 // truncstore fragments.
 554 def truncstorei8 : PatFrag<(ops node:$val, node:$ptr),
 555                            (st node:$val, node:$ptr), [{
 556   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 557     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::i8 &&
 558            ST->getAddressingMode() == ISD::UNINDEXED;
 559   return false;
 560 }]>;
 561 def truncstorei16 : PatFrag<(ops node:$val, node:$ptr),
 562                             (st node:$val, node:$ptr), [{
 563   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 564     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::i16 &&
 565            ST->getAddressingMode() == ISD::UNINDEXED;
 566   return false;
 567 }]>;
 568 def truncstorei32 : PatFrag<(ops node:$val, node:$ptr),
 569                             (st node:$val, node:$ptr), [{
 570   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 571     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::i32 &&
 572            ST->getAddressingMode() == ISD::UNINDEXED;
 573   return false;
 574 }]>;
 575 def truncstoref32 : PatFrag<(ops node:$val, node:$ptr),
 576                             (st node:$val, node:$ptr), [{
 577   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 578     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::f32 &&
 579            ST->getAddressingMode() == ISD::UNINDEXED;
 580   return false;
 581 }]>;
 582 def truncstoref64 : PatFrag<(ops node:$val, node:$ptr),
 583                             (st node:$val, node:$ptr), [{
 584   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N))
 585     return ST->isTruncatingStore() && ST->getStoredVT() == MVT::f64 &&
 586            ST->getAddressingMode() == ISD::UNINDEXED;
 587   return false;
 588 }]>;
 589
 590 // indexed store fragments.
 591 def pre_store : PatFrag<(ops node:$val, node:$base, node:$offset),
 592                         (ist node:$val, node:$base, node:$offset), [{
 593   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 594     ISD::MemIndexedMode AM = ST->getAddressingMode();
 595     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 596            !ST->isTruncatingStore();
 597   }
 598   return false;
 599 }]>;
 600
 601 def pre_truncsti1 : PatFrag<(ops node:$val, node:$base, node:$offset),
 602                             (ist node:$val, node:$base, node:$offset), [{
 603   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 604     ISD::MemIndexedMode AM = ST->getAddressingMode();
 605     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 606            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i1;
 607   }
 608   return false;
 609 }]>;
 610 def pre_truncsti8 : PatFrag<(ops node:$val, node:$base, node:$offset),
 611                             (ist node:$val, node:$base, node:$offset), [{
 612   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 613     ISD::MemIndexedMode AM = ST->getAddressingMode();
 614     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 615            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i8;
 616   }
 617   return false;
 618 }]>;
 619 def pre_truncsti16 : PatFrag<(ops node:$val, node:$base, node:$offset),
 620                              (ist node:$val, node:$base, node:$offset), [{
 621   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 622     ISD::MemIndexedMode AM = ST->getAddressingMode();
 623     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 624            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i16;
 625   }
 626   return false;
 627 }]>;
 628 def pre_truncsti32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 629                              (ist node:$val, node:$base, node:$offset), [{
 630   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 631     ISD::MemIndexedMode AM = ST->getAddressingMode();
 632     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 633            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i32;
 634   }
 635   return false;
 636 }]>;
 637 def pre_truncstf32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 638                              (ist node:$val, node:$base, node:$offset), [{
 639   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 640     ISD::MemIndexedMode AM = ST->getAddressingMode();
 641     return (AM == ISD::PRE_INC || AM == ISD::PRE_DEC) &&
 642            ST->isTruncatingStore() && ST->getStoredVT() == MVT::f32;
 643   }
 644   return false;
 645 }]>;
 646
 647 def post_store : PatFrag<(ops node:$val, node:$ptr, node:$offset),
 648                          (ist node:$val, node:$ptr, node:$offset), [{
 649   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 650     ISD::MemIndexedMode AM = ST->getAddressingMode();
 651     return !ST->isTruncatingStore() &&
 652             (AM == ISD::POST_INC || AM == ISD::POST_DEC);
 653   }
 654   return false;
 655 }]>;
 656
 657 def post_truncsti1 : PatFrag<(ops node:$val, node:$base, node:$offset),
 658                              (ist node:$val, node:$base, node:$offset), [{
 659   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 660     ISD::MemIndexedMode AM = ST->getAddressingMode();
 661     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 662            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i1;
 663   }
 664   return false;
 665 }]>;
 666 def post_truncsti8 : PatFrag<(ops node:$val, node:$base, node:$offset),
 667                              (ist node:$val, node:$base, node:$offset), [{
 668   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 669     ISD::MemIndexedMode AM = ST->getAddressingMode();
 670     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 671            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i8;
 672   }
 673   return false;
 674 }]>;
 675 def post_truncsti16 : PatFrag<(ops node:$val, node:$base, node:$offset),
 676                               (ist node:$val, node:$base, node:$offset), [{
 677   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 678     ISD::MemIndexedMode AM = ST->getAddressingMode();
 679     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 680            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i16;
 681   }
 682   return false;
 683 }]>;
 684 def post_truncsti32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 685                               (ist node:$val, node:$base, node:$offset), [{
 686   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 687     ISD::MemIndexedMode AM = ST->getAddressingMode();
 688     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 689            ST->isTruncatingStore() && ST->getStoredVT() == MVT::i32;
 690   }
 691   return false;
 692 }]>;
 693 def post_truncstf32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 694                               (ist node:$val, node:$base, node:$offset), [{
 695   if (StoreSDNode *ST = dyn_cast<StoreSDNode>(N)) {
 696     ISD::MemIndexedMode AM = ST->getAddressingMode();
 697     return (AM == ISD::POST_INC || AM == ISD::POST_DEC) &&
 698            ST->isTruncatingStore() && ST->getStoredVT() == MVT::f32;
 699   }
 700   return false;
 701 }]>;
 702
 703 // setcc convenience fragments.
 704 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 705                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 706 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 707                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 708 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 709                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 710 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 711                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 712 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 713                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 714 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 715                      (setcc node:$lhs, node:$rhs, SETONE)>;
 716 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 717                      (setcc node:$lhs, node:$rhs, SETO)>;
 718 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 719                      (setcc node:$lhs, node:$rhs, SETUO)>;
 720 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 721                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 722 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 723                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 724 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 725                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 726 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 727                      (setcc node:$lhs, node:$rhs, SETULT)>;
 728 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 729                      (setcc node:$lhs, node:$rhs, SETULE)>;
 730 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 731                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 732 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 733                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 734 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 735                      (setcc node:$lhs, node:$rhs, SETGT)>;
 736 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 737                      (setcc node:$lhs, node:$rhs, SETGE)>;
 738 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 739                      (setcc node:$lhs, node:$rhs, SETLT)>;
 740 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 741                      (setcc node:$lhs, node:$rhs, SETLE)>;
 742 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 743                      (setcc node:$lhs, node:$rhs, SETNE)>;
 744
 745 //===----------------------------------------------------------------------===//
 746 // Selection DAG Pattern Support.
 747 //
 748 // Patterns are what are actually matched against the target-flavored
 749 // instruction selection DAG.  Instructions defined by the target implicitly
 750 // define patterns in most cases, but patterns can also be explicitly added when
 751 // an operation is defined by a sequence of instructions (e.g. loading a large
 752 // immediate value on RISC targets that do not support immediates as large as
 753 // their GPRs).
 754 //
 755
 756 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 757   dag             PatternToMatch  = patternToMatch;
 758   list<dag>       ResultInstrs    = resultInstrs;
 759   list<Predicate> Predicates      = [];  // See class Instruction in Target.td.
 760   int             AddedComplexity = 0;  // See class Instruction in Target.td.
 761 }
 762
 763 // Pat - A simple (but common) form of a pattern, which produces a simple result
 764 // not needing a full list.
 765 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 766
 767 //===----------------------------------------------------------------------===//
 768 // Complex pattern definitions.
 769 //
 770 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 771 // in C++. NumOperands is the number of operands returned by the select function;
 772 // SelectFunc is the name of the function used to pattern match the max. pattern;
 773 // RootNodes are the list of possible root nodes of the sub-dags to match.
 774 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 775 //
 776 class ComplexPattern<ValueType ty, int numops, string fn,
 777                      list<SDNode> roots = [], list<SDNodeProperty> props = []> {
 778   ValueType Ty = ty;
 779   int NumOperands = numops;
 780   string SelectFunc = fn;
 781   list<SDNode> RootNodes = roots;
 782   list<SDNodeProperty> Properties = props;
 783 }
 784
 785 //===----------------------------------------------------------------------===//
 786 // Dwarf support.
 787 //
 788 def SDT_dwarf_loc : SDTypeProfile<0, 3,
 789                       [SDTCisInt<0>, SDTCisInt<1>, SDTCisInt<2>]>;
 790 def dwarf_loc : SDNode<"ISD::DEBUG_LOC", SDT_dwarf_loc,[SDNPHasChain]>;
 791
 792
 793