lib/Target/SystemZ/SystemZOperators.td

   1 //===-- SystemZOperators.td - SystemZ-specific operators ------*- tblgen-*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // Type profiles
  12 //===----------------------------------------------------------------------===//
  13 def SDT_CallSeqStart        : SDCallSeqStart<[SDTCisVT<0, i64>]>;
  14 def SDT_CallSeqEnd          : SDCallSeqEnd<[SDTCisVT<0, i64>,
  15                                             SDTCisVT<1, i64>]>;
  16 def SDT_ZCall               : SDTypeProfile<0, -1, [SDTCisPtrTy<0>]>;
  17 def SDT_ZCmp                : SDTypeProfile<0, 2, [SDTCisSameAs<0, 1>]>;
  18 def SDT_ZICmp               : SDTypeProfile<0, 3,
  19                                             [SDTCisSameAs<0, 1>,
  20                                              SDTCisVT<2, i32>]>;
  21 def SDT_ZBRCCMask           : SDTypeProfile<0, 3,
  22                                             [SDTCisVT<0, i32>,
  23                                              SDTCisVT<1, i32>,
  24                                              SDTCisVT<2, OtherVT>]>;
  25 def SDT_ZSelectCCMask       : SDTypeProfile<1, 4,
  26                                             [SDTCisSameAs<0, 1>,
  27                                              SDTCisSameAs<1, 2>,
  28                                              SDTCisVT<3, i32>,
  29                                              SDTCisVT<4, i32>]>;
  30 def SDT_ZWrapPtr            : SDTypeProfile<1, 1,
  31                                             [SDTCisSameAs<0, 1>,
  32                                              SDTCisPtrTy<0>]>;
  33 def SDT_ZWrapOffset         : SDTypeProfile<1, 2,
  34                                             [SDTCisSameAs<0, 1>,
  35                                              SDTCisSameAs<0, 2>,
  36                                              SDTCisPtrTy<0>]>;
  37 def SDT_ZAdjDynAlloc        : SDTypeProfile<1, 0, [SDTCisVT<0, i64>]>;
  38 def SDT_ZExtractAccess      : SDTypeProfile<1, 1,
  39                                             [SDTCisVT<0, i32>,
  40                                              SDTCisVT<1, i32>]>;
  41 def SDT_ZGR128Binary32      : SDTypeProfile<1, 2,
  42                                             [SDTCisVT<0, untyped>,
  43                                              SDTCisVT<1, untyped>,
  44                                              SDTCisVT<2, i32>]>;
  45 def SDT_ZGR128Binary64      : SDTypeProfile<1, 2,
  46                                             [SDTCisVT<0, untyped>,
  47                                              SDTCisVT<1, untyped>,
  48                                              SDTCisVT<2, i64>]>;
  49 def SDT_ZAtomicLoadBinaryW  : SDTypeProfile<1, 5,
  50                                             [SDTCisVT<0, i32>,
  51                                              SDTCisPtrTy<1>,
  52                                              SDTCisVT<2, i32>,
  53                                              SDTCisVT<3, i32>,
  54                                              SDTCisVT<4, i32>,
  55                                              SDTCisVT<5, i32>]>;
  56 def SDT_ZAtomicCmpSwapW     : SDTypeProfile<1, 6,
  57                                             [SDTCisVT<0, i32>,
  58                                              SDTCisPtrTy<1>,
  59                                              SDTCisVT<2, i32>,
  60                                              SDTCisVT<3, i32>,
  61                                              SDTCisVT<4, i32>,
  62                                              SDTCisVT<5, i32>,
  63                                              SDTCisVT<6, i32>]>;
  64 def SDT_ZMemMemLength       : SDTypeProfile<0, 3,
  65                                             [SDTCisPtrTy<0>,
  66                                              SDTCisPtrTy<1>,
  67                                              SDTCisVT<2, i64>]>;
  68 def SDT_ZMemMemLoop         : SDTypeProfile<0, 4,
  69                                             [SDTCisPtrTy<0>,
  70                                              SDTCisPtrTy<1>,
  71                                              SDTCisVT<2, i64>,
  72                                              SDTCisVT<3, i64>]>;
  73 def SDT_ZString             : SDTypeProfile<1, 3,
  74                                             [SDTCisPtrTy<0>,
  75                                              SDTCisPtrTy<1>,
  76                                              SDTCisPtrTy<2>,
  77                                              SDTCisVT<3, i32>]>;
  78 def SDT_ZI32Intrinsic       : SDTypeProfile<1, 0, [SDTCisVT<0, i32>]>;
  79 def SDT_ZPrefetch           : SDTypeProfile<0, 2,
  80                                             [SDTCisVT<0, i32>,
  81                                              SDTCisPtrTy<1>]>;
  82 def SDT_ZTBegin             : SDTypeProfile<0, 2,
  83                                             [SDTCisPtrTy<0>,
  84                                              SDTCisVT<1, i32>]>;
  85 def SDT_ZInsertVectorElt    : SDTypeProfile<1, 3,
  86                                             [SDTCisVec<0>,
  87                                              SDTCisSameAs<0, 1>,
  88                                              SDTCisVT<3, i32>]>;
  89 def SDT_ZExtractVectorElt   : SDTypeProfile<1, 2,
  90                                             [SDTCisVec<1>,
  91                                              SDTCisVT<2, i32>]>;
  92 def SDT_ZReplicate          : SDTypeProfile<1, 1,
  93                                             [SDTCisVec<0>]>;
  94 def SDT_ZVecBinary          : SDTypeProfile<1, 2,
  95                                             [SDTCisVec<0>,
  96                                              SDTCisSameAs<0, 1>,
  97                                              SDTCisSameAs<0, 2>]>;
  98 def SDT_ZVecBinaryInt       : SDTypeProfile<1, 2,
  99                                             [SDTCisVec<0>,
 100                                              SDTCisSameAs<0, 1>,
 101                                              SDTCisVT<2, i32>]>;
 102 def SDT_ZVecBinaryConv      : SDTypeProfile<1, 2,
 103                                             [SDTCisVec<0>,
 104                                              SDTCisVec<1>,
 105                                              SDTCisSameAs<1, 2>]>;
 106 def SDT_ZRotateMask         : SDTypeProfile<1, 2,
 107                                             [SDTCisVec<0>,
 108                                              SDTCisVT<1, i32>,
 109                                              SDTCisVT<2, i32>]>;
 110 def SDT_ZJoinDwords         : SDTypeProfile<1, 2,
 111                                             [SDTCisVT<0, v2i64>,
 112                                              SDTCisVT<1, i64>,
 113                                              SDTCisVT<2, i64>]>;
 114 def SDT_ZVecTernary         : SDTypeProfile<1, 3,
 115                                             [SDTCisVec<0>,
 116                                              SDTCisSameAs<0, 1>,
 117                                              SDTCisSameAs<0, 2>,
 118                                              SDTCisSameAs<0, 3>]>;
 119 def SDT_ZVecTernaryInt      : SDTypeProfile<1, 3,
 120                                             [SDTCisVec<0>,
 121                                              SDTCisSameAs<0, 1>,
 122                                              SDTCisSameAs<0, 2>,
 123                                              SDTCisVT<3, i32>]>;
 124
 125 //===----------------------------------------------------------------------===//
 126 // Node definitions
 127 //===----------------------------------------------------------------------===//
 128
 129 // These are target-independent nodes, but have target-specific formats.
 130 def callseq_start       : SDNode<"ISD::CALLSEQ_START", SDT_CallSeqStart,
 131                                  [SDNPHasChain, SDNPSideEffect, SDNPOutGlue]>;
 132 def callseq_end         : SDNode<"ISD::CALLSEQ_END",   SDT_CallSeqEnd,
 133                                  [SDNPHasChain, SDNPSideEffect, SDNPOptInGlue,
 134                                   SDNPOutGlue]>;
 135 def global_offset_table : SDNode<"ISD::GLOBAL_OFFSET_TABLE", SDTPtrLeaf>;
 136
 137 // Nodes for SystemZISD::*.  See SystemZISelLowering.h for more details.
 138 def z_retflag           : SDNode<"SystemZISD::RET_FLAG", SDTNone,
 139                                  [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
 140 def z_call              : SDNode<"SystemZISD::CALL", SDT_ZCall,
 141                                  [SDNPHasChain, SDNPOutGlue, SDNPOptInGlue,
 142                                   SDNPVariadic]>;
 143 def z_sibcall           : SDNode<"SystemZISD::SIBCALL", SDT_ZCall,
 144                                  [SDNPHasChain, SDNPOutGlue, SDNPOptInGlue,
 145                                   SDNPVariadic]>;
 146 def z_tls_gdcall        : SDNode<"SystemZISD::TLS_GDCALL", SDT_ZCall,
 147                                  [SDNPHasChain, SDNPInGlue, SDNPOutGlue,
 148                                   SDNPVariadic]>;
 149 def z_tls_ldcall        : SDNode<"SystemZISD::TLS_LDCALL", SDT_ZCall,
 150                                  [SDNPHasChain, SDNPInGlue, SDNPOutGlue,
 151                                   SDNPVariadic]>;
 152 def z_pcrel_wrapper     : SDNode<"SystemZISD::PCREL_WRAPPER", SDT_ZWrapPtr, []>;
 153 def z_pcrel_offset      : SDNode<"SystemZISD::PCREL_OFFSET",
 154                                  SDT_ZWrapOffset, []>;
 155 def z_iabs              : SDNode<"SystemZISD::IABS", SDTIntUnaryOp, []>;
 156 def z_icmp              : SDNode<"SystemZISD::ICMP", SDT_ZICmp, [SDNPOutGlue]>;
 157 def z_fcmp              : SDNode<"SystemZISD::FCMP", SDT_ZCmp, [SDNPOutGlue]>;
 158 def z_tm                : SDNode<"SystemZISD::TM", SDT_ZICmp, [SDNPOutGlue]>;
 159 def z_br_ccmask         : SDNode<"SystemZISD::BR_CCMASK", SDT_ZBRCCMask,
 160                                  [SDNPHasChain, SDNPInGlue]>;
 161 def z_select_ccmask     : SDNode<"SystemZISD::SELECT_CCMASK", SDT_ZSelectCCMask,
 162                                  [SDNPInGlue]>;
 163 def z_adjdynalloc       : SDNode<"SystemZISD::ADJDYNALLOC", SDT_ZAdjDynAlloc>;
 164 def z_extract_access    : SDNode<"SystemZISD::EXTRACT_ACCESS",
 165                                  SDT_ZExtractAccess>;
 166 def z_popcnt            : SDNode<"SystemZISD::POPCNT", SDTIntUnaryOp>;
 167 def z_umul_lohi64       : SDNode<"SystemZISD::UMUL_LOHI64", SDT_ZGR128Binary64>;
 168 def z_sdivrem32         : SDNode<"SystemZISD::SDIVREM32", SDT_ZGR128Binary32>;
 169 def z_sdivrem64         : SDNode<"SystemZISD::SDIVREM64", SDT_ZGR128Binary64>;
 170 def z_udivrem32         : SDNode<"SystemZISD::UDIVREM32", SDT_ZGR128Binary32>;
 171 def z_udivrem64         : SDNode<"SystemZISD::UDIVREM64", SDT_ZGR128Binary64>;
 172
 173 def z_serialize         : SDNode<"SystemZISD::SERIALIZE", SDTNone,
 174                                  [SDNPHasChain, SDNPMayStore]>;
 175
 176 // Defined because the index is an i32 rather than a pointer.
 177 def z_vector_insert     : SDNode<"ISD::INSERT_VECTOR_ELT",
 178                                  SDT_ZInsertVectorElt>;
 179 def z_vector_extract    : SDNode<"ISD::EXTRACT_VECTOR_ELT",
 180                                  SDT_ZExtractVectorElt>;
 181 def z_byte_mask         : SDNode<"SystemZISD::BYTE_MASK", SDT_ZReplicate>;
 182 def z_rotate_mask       : SDNode<"SystemZISD::ROTATE_MASK", SDT_ZRotateMask>;
 183 def z_replicate         : SDNode<"SystemZISD::REPLICATE", SDT_ZReplicate>;
 184 def z_join_dwords       : SDNode<"SystemZISD::JOIN_DWORDS", SDT_ZJoinDwords>;
 185 def z_splat             : SDNode<"SystemZISD::SPLAT", SDT_ZVecBinaryInt>;
 186 def z_merge_high        : SDNode<"SystemZISD::MERGE_HIGH", SDT_ZVecBinary>;
 187 def z_merge_low         : SDNode<"SystemZISD::MERGE_LOW", SDT_ZVecBinary>;
 188 def z_shl_double        : SDNode<"SystemZISD::SHL_DOUBLE", SDT_ZVecTernaryInt>;
 189 def z_permute_dwords    : SDNode<"SystemZISD::PERMUTE_DWORDS",
 190                                  SDT_ZVecTernaryInt>;
 191 def z_permute           : SDNode<"SystemZISD::PERMUTE", SDT_ZVecTernary>;
 192 def z_pack              : SDNode<"SystemZISD::PACK", SDT_ZVecBinaryConv>;
 193 def z_vshl_by_scalar    : SDNode<"SystemZISD::VSHL_BY_SCALAR",
 194                                  SDT_ZVecBinaryInt>;
 195 def z_vsrl_by_scalar    : SDNode<"SystemZISD::VSRL_BY_SCALAR",
 196                                  SDT_ZVecBinaryInt>;
 197 def z_vsra_by_scalar    : SDNode<"SystemZISD::VSRA_BY_SCALAR",
 198                                  SDT_ZVecBinaryInt>;
 199 def z_vsum              : SDNode<"SystemZISD::VSUM", SDT_ZVecBinaryConv>;
 200 def z_vicmpe            : SDNode<"SystemZISD::VICMPE", SDT_ZVecBinary>;
 201 def z_vicmph            : SDNode<"SystemZISD::VICMPH", SDT_ZVecBinary>;
 202 def z_vicmphl           : SDNode<"SystemZISD::VICMPHL", SDT_ZVecBinary>;
 203 def z_vfcmpe            : SDNode<"SystemZISD::VFCMPE", SDT_ZVecBinaryConv>;
 204 def z_vfcmph            : SDNode<"SystemZISD::VFCMPH", SDT_ZVecBinaryConv>;
 205 def z_vfcmphe           : SDNode<"SystemZISD::VFCMPHE", SDT_ZVecBinaryConv>;
 206
 207 class AtomicWOp<string name, SDTypeProfile profile = SDT_ZAtomicLoadBinaryW>
 208   : SDNode<"SystemZISD::"##name, profile,
 209            [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 210
 211 def z_atomic_swapw      : AtomicWOp<"ATOMIC_SWAPW">;
 212 def z_atomic_loadw_add  : AtomicWOp<"ATOMIC_LOADW_ADD">;
 213 def z_atomic_loadw_sub  : AtomicWOp<"ATOMIC_LOADW_SUB">;
 214 def z_atomic_loadw_and  : AtomicWOp<"ATOMIC_LOADW_AND">;
 215 def z_atomic_loadw_or   : AtomicWOp<"ATOMIC_LOADW_OR">;
 216 def z_atomic_loadw_xor  : AtomicWOp<"ATOMIC_LOADW_XOR">;
 217 def z_atomic_loadw_nand : AtomicWOp<"ATOMIC_LOADW_NAND">;
 218 def z_atomic_loadw_min  : AtomicWOp<"ATOMIC_LOADW_MIN">;
 219 def z_atomic_loadw_max  : AtomicWOp<"ATOMIC_LOADW_MAX">;
 220 def z_atomic_loadw_umin : AtomicWOp<"ATOMIC_LOADW_UMIN">;
 221 def z_atomic_loadw_umax : AtomicWOp<"ATOMIC_LOADW_UMAX">;
 222 def z_atomic_cmp_swapw  : AtomicWOp<"ATOMIC_CMP_SWAPW", SDT_ZAtomicCmpSwapW>;
 223
 224 def z_mvc               : SDNode<"SystemZISD::MVC", SDT_ZMemMemLength,
 225                                  [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
 226 def z_mvc_loop          : SDNode<"SystemZISD::MVC_LOOP", SDT_ZMemMemLoop,
 227                                  [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
 228 def z_nc                : SDNode<"SystemZISD::NC", SDT_ZMemMemLength,
 229                                   [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
 230 def z_nc_loop           : SDNode<"SystemZISD::NC_LOOP", SDT_ZMemMemLoop,
 231                                   [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
 232 def z_oc                : SDNode<"SystemZISD::OC", SDT_ZMemMemLength,
 233                                   [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
 234 def z_oc_loop           : SDNode<"SystemZISD::OC_LOOP", SDT_ZMemMemLoop,
 235                                   [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
 236 def z_xc                : SDNode<"SystemZISD::XC", SDT_ZMemMemLength,
 237                                   [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
 238 def z_xc_loop           : SDNode<"SystemZISD::XC_LOOP", SDT_ZMemMemLoop,
 239                                   [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
 240 def z_clc               : SDNode<"SystemZISD::CLC", SDT_ZMemMemLength,
 241                                  [SDNPHasChain, SDNPOutGlue, SDNPMayLoad]>;
 242 def z_clc_loop          : SDNode<"SystemZISD::CLC_LOOP", SDT_ZMemMemLoop,
 243                                  [SDNPHasChain, SDNPOutGlue, SDNPMayLoad]>;
 244 def z_strcmp            : SDNode<"SystemZISD::STRCMP", SDT_ZString,
 245                                  [SDNPHasChain, SDNPOutGlue, SDNPMayLoad]>;
 246 def z_stpcpy            : SDNode<"SystemZISD::STPCPY", SDT_ZString,
 247                                  [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
 248 def z_search_string     : SDNode<"SystemZISD::SEARCH_STRING", SDT_ZString,
 249                                  [SDNPHasChain, SDNPOutGlue, SDNPMayLoad]>;
 250 def z_ipm               : SDNode<"SystemZISD::IPM", SDT_ZI32Intrinsic,
 251                                  [SDNPInGlue]>;
 252 def z_prefetch          : SDNode<"SystemZISD::PREFETCH", SDT_ZPrefetch,
 253                                  [SDNPHasChain, SDNPMayLoad, SDNPMayStore,
 254                                   SDNPMemOperand]>;
 255
 256 def z_tbegin            : SDNode<"SystemZISD::TBEGIN", SDT_ZTBegin,
 257                                  [SDNPHasChain, SDNPOutGlue, SDNPMayStore,
 258                                   SDNPSideEffect]>;
 259 def z_tbegin_nofloat    : SDNode<"SystemZISD::TBEGIN_NOFLOAT", SDT_ZTBegin,
 260                                  [SDNPHasChain, SDNPOutGlue, SDNPMayStore,
 261                                   SDNPSideEffect]>;
 262 def z_tend              : SDNode<"SystemZISD::TEND", SDTNone,
 263                                  [SDNPHasChain, SDNPOutGlue, SDNPSideEffect]>;
 264
 265 def z_vshl              : SDNode<"ISD::SHL", SDT_ZVecBinary>;
 266 def z_vsra              : SDNode<"ISD::SRA", SDT_ZVecBinary>;
 267 def z_vsrl              : SDNode<"ISD::SRL", SDT_ZVecBinary>;
 268
 269 //===----------------------------------------------------------------------===//
 270 // Pattern fragments
 271 //===----------------------------------------------------------------------===//
 272
 273 // Signed and unsigned comparisons.
 274 def z_scmp : PatFrag<(ops node:$a, node:$b), (z_icmp node:$a, node:$b, imm), [{
 275   unsigned Type = cast<ConstantSDNode>(N->getOperand(2))->getZExtValue();
 276   return Type != SystemZICMP::UnsignedOnly;
 277 }]>;
 278 def z_ucmp : PatFrag<(ops node:$a, node:$b), (z_icmp node:$a, node:$b, imm), [{
 279   unsigned Type = cast<ConstantSDNode>(N->getOperand(2))->getZExtValue();
 280   return Type != SystemZICMP::SignedOnly;
 281 }]>;
 282
 283 // Register- and memory-based TEST UNDER MASK.
 284 def z_tm_reg : PatFrag<(ops node:$a, node:$b), (z_tm node:$a, node:$b, imm)>;
 285 def z_tm_mem : PatFrag<(ops node:$a, node:$b), (z_tm node:$a, node:$b, 0)>;
 286
 287 // Register sign-extend operations.  Sub-32-bit values are represented as i32s.
 288 def sext8  : PatFrag<(ops node:$src), (sext_inreg node:$src, i8)>;
 289 def sext16 : PatFrag<(ops node:$src), (sext_inreg node:$src, i16)>;
 290 def sext32 : PatFrag<(ops node:$src), (sext (i32 node:$src))>;
 291
 292 // Match extensions of an i32 to an i64, followed by an in-register sign
 293 // extension from a sub-i32 value.
 294 def sext8dbl : PatFrag<(ops node:$src), (sext8 (anyext node:$src))>;
 295 def sext16dbl : PatFrag<(ops node:$src), (sext16 (anyext node:$src))>;
 296
 297 // Register zero-extend operations.  Sub-32-bit values are represented as i32s.
 298 def zext8  : PatFrag<(ops node:$src), (and node:$src, 0xff)>;
 299 def zext16 : PatFrag<(ops node:$src), (and node:$src, 0xffff)>;
 300 def zext32 : PatFrag<(ops node:$src), (zext (i32 node:$src))>;
 301
 302 // Match extensions of an i32 to an i64, followed by an AND of the low
 303 // i8 or i16 part.
 304 def zext8dbl : PatFrag<(ops node:$src), (zext8 (anyext node:$src))>;
 305 def zext16dbl : PatFrag<(ops node:$src), (zext16 (anyext node:$src))>;
 306
 307 // Typed floating-point loads.
 308 def loadf32 : PatFrag<(ops node:$src), (f32 (load node:$src))>;
 309 def loadf64 : PatFrag<(ops node:$src), (f64 (load node:$src))>;
 310
 311 // Extending loads in which the extension type can be signed.
 312 def asextload : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 313   unsigned Type = cast<LoadSDNode>(N)->getExtensionType();
 314   return Type == ISD::EXTLOAD || Type == ISD::SEXTLOAD;
 315 }]>;
 316 def asextloadi8 : PatFrag<(ops node:$ptr), (asextload node:$ptr), [{
 317   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
 318 }]>;
 319 def asextloadi16 : PatFrag<(ops node:$ptr), (asextload node:$ptr), [{
 320   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
 321 }]>;
 322 def asextloadi32 : PatFrag<(ops node:$ptr), (asextload node:$ptr), [{
 323   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
 324 }]>;
 325
 326 // Extending loads in which the extension type can be unsigned.
 327 def azextload : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 328   unsigned Type = cast<LoadSDNode>(N)->getExtensionType();
 329   return Type == ISD::EXTLOAD || Type == ISD::ZEXTLOAD;
 330 }]>;
 331 def azextloadi8 : PatFrag<(ops node:$ptr), (azextload node:$ptr), [{
 332   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
 333 }]>;
 334 def azextloadi16 : PatFrag<(ops node:$ptr), (azextload node:$ptr), [{
 335   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
 336 }]>;
 337 def azextloadi32 : PatFrag<(ops node:$ptr), (azextload node:$ptr), [{
 338   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
 339 }]>;
 340
 341 // Extending loads in which the extension type doesn't matter.
 342 def anyextload : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 343   return cast<LoadSDNode>(N)->getExtensionType() != ISD::NON_EXTLOAD;
 344 }]>;
 345 def anyextloadi8 : PatFrag<(ops node:$ptr), (anyextload node:$ptr), [{
 346   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
 347 }]>;
 348 def anyextloadi16 : PatFrag<(ops node:$ptr), (anyextload node:$ptr), [{
 349   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
 350 }]>;
 351 def anyextloadi32 : PatFrag<(ops node:$ptr), (anyextload node:$ptr), [{
 352   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
 353 }]>;
 354
 355 // Aligned loads.
 356 class AlignedLoad<SDPatternOperator load>
 357   : PatFrag<(ops node:$addr), (load node:$addr), [{
 358   auto *Load = cast<LoadSDNode>(N);
 359   return Load->getAlignment() >= Load->getMemoryVT().getStoreSize();
 360 }]>;
 361 def aligned_load         : AlignedLoad<load>;
 362 def aligned_asextloadi16 : AlignedLoad<asextloadi16>;
 363 def aligned_asextloadi32 : AlignedLoad<asextloadi32>;
 364 def aligned_azextloadi16 : AlignedLoad<azextloadi16>;
 365 def aligned_azextloadi32 : AlignedLoad<azextloadi32>;
 366
 367 // Aligned stores.
 368 class AlignedStore<SDPatternOperator store>
 369   : PatFrag<(ops node:$src, node:$addr), (store node:$src, node:$addr), [{
 370   auto *Store = cast<StoreSDNode>(N);
 371   return Store->getAlignment() >= Store->getMemoryVT().getStoreSize();
 372 }]>;
 373 def aligned_store         : AlignedStore<store>;
 374 def aligned_truncstorei16 : AlignedStore<truncstorei16>;
 375 def aligned_truncstorei32 : AlignedStore<truncstorei32>;
 376
 377 // Non-volatile loads.  Used for instructions that might access the storage
 378 // location multiple times.
 379 class NonvolatileLoad<SDPatternOperator load>
 380   : PatFrag<(ops node:$addr), (load node:$addr), [{
 381   auto *Load = cast<LoadSDNode>(N);
 382   return !Load->isVolatile();
 383 }]>;
 384 def nonvolatile_load          : NonvolatileLoad<load>;
 385 def nonvolatile_anyextloadi8  : NonvolatileLoad<anyextloadi8>;
 386 def nonvolatile_anyextloadi16 : NonvolatileLoad<anyextloadi16>;
 387 def nonvolatile_anyextloadi32 : NonvolatileLoad<anyextloadi32>;
 388
 389 // Non-volatile stores.
 390 class NonvolatileStore<SDPatternOperator store>
 391   : PatFrag<(ops node:$src, node:$addr), (store node:$src, node:$addr), [{
 392   auto *Store = cast<StoreSDNode>(N);
 393   return !Store->isVolatile();
 394 }]>;
 395 def nonvolatile_store         : NonvolatileStore<store>;
 396 def nonvolatile_truncstorei8  : NonvolatileStore<truncstorei8>;
 397 def nonvolatile_truncstorei16 : NonvolatileStore<truncstorei16>;
 398 def nonvolatile_truncstorei32 : NonvolatileStore<truncstorei32>;
 399
 400 // A store of a load that can be implemented using MVC.
 401 def mvc_store : PatFrag<(ops node:$value, node:$addr),
 402                         (unindexedstore node:$value, node:$addr),
 403                         [{ return storeLoadCanUseMVC(N); }]>;
 404
 405 // Binary read-modify-write operations on memory in which the other
 406 // operand is also memory and for which block operations like NC can
 407 // be used.  There are two patterns for each operator, depending on
 408 // which operand contains the "other" load.
 409 multiclass block_op<SDPatternOperator operator> {
 410   def "1" : PatFrag<(ops node:$value, node:$addr),
 411                     (unindexedstore (operator node:$value,
 412                                               (unindexedload node:$addr)),
 413                                     node:$addr),
 414                     [{ return storeLoadCanUseBlockBinary(N, 0); }]>;
 415   def "2" : PatFrag<(ops node:$value, node:$addr),
 416                     (unindexedstore (operator (unindexedload node:$addr),
 417                                               node:$value),
 418                                     node:$addr),
 419                     [{ return storeLoadCanUseBlockBinary(N, 1); }]>;
 420 }
 421 defm block_and : block_op<and>;
 422 defm block_or  : block_op<or>;
 423 defm block_xor : block_op<xor>;
 424
 425 // Insertions.
 426 def inserti8 : PatFrag<(ops node:$src1, node:$src2),
 427                        (or (and node:$src1, -256), node:$src2)>;
 428 def insertll : PatFrag<(ops node:$src1, node:$src2),
 429                        (or (and node:$src1, 0xffffffffffff0000), node:$src2)>;
 430 def insertlh : PatFrag<(ops node:$src1, node:$src2),
 431                        (or (and node:$src1, 0xffffffff0000ffff), node:$src2)>;
 432 def inserthl : PatFrag<(ops node:$src1, node:$src2),
 433                        (or (and node:$src1, 0xffff0000ffffffff), node:$src2)>;
 434 def inserthh : PatFrag<(ops node:$src1, node:$src2),
 435                        (or (and node:$src1, 0x0000ffffffffffff), node:$src2)>;
 436 def insertlf : PatFrag<(ops node:$src1, node:$src2),
 437                        (or (and node:$src1, 0xffffffff00000000), node:$src2)>;
 438 def inserthf : PatFrag<(ops node:$src1, node:$src2),
 439                        (or (and node:$src1, 0x00000000ffffffff), node:$src2)>;
 440
 441 // ORs that can be treated as insertions.
 442 def or_as_inserti8 : PatFrag<(ops node:$src1, node:$src2),
 443                              (or node:$src1, node:$src2), [{
 444   unsigned BitWidth = N->getValueType(0).getScalarType().getSizeInBits();
 445   return CurDAG->MaskedValueIsZero(N->getOperand(0),
 446                                    APInt::getLowBitsSet(BitWidth, 8));
 447 }]>;
 448
 449 // ORs that can be treated as reversed insertions.
 450 def or_as_revinserti8 : PatFrag<(ops node:$src1, node:$src2),
 451                                 (or node:$src1, node:$src2), [{
 452   unsigned BitWidth = N->getValueType(0).getScalarType().getSizeInBits();
 453   return CurDAG->MaskedValueIsZero(N->getOperand(1),
 454                                    APInt::getLowBitsSet(BitWidth, 8));
 455 }]>;
 456
 457 // Negative integer absolute.
 458 def z_inegabs : PatFrag<(ops node:$src), (ineg (z_iabs node:$src))>;
 459
 460 // Integer absolute, matching the canonical form generated by DAGCombiner.
 461 def z_iabs32 : PatFrag<(ops node:$src),
 462                        (xor (add node:$src, (sra node:$src, (i32 31))),
 463                             (sra node:$src, (i32 31)))>;
 464 def z_iabs64 : PatFrag<(ops node:$src),
 465                        (xor (add node:$src, (sra node:$src, (i32 63))),
 466                             (sra node:$src, (i32 63)))>;
 467 def z_inegabs32 : PatFrag<(ops node:$src), (ineg (z_iabs32 node:$src))>;
 468 def z_inegabs64 : PatFrag<(ops node:$src), (ineg (z_iabs64 node:$src))>;
 469
 470 // Integer multiply-and-add
 471 def z_muladd : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 472                        (add (mul node:$src1, node:$src2), node:$src3)>;
 473
 474 // Fused multiply-subtract, using the natural operand order.
 475 def fms : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 476                   (fma node:$src1, node:$src2, (fneg node:$src3))>;
 477
 478 // Fused multiply-add and multiply-subtract, but with the order of the
 479 // operands matching SystemZ's MA and MS instructions.
 480 def z_fma : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 481                     (fma node:$src2, node:$src3, node:$src1)>;
 482 def z_fms : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 483                     (fma node:$src2, node:$src3, (fneg node:$src1))>;
 484
 485 // Floating-point negative absolute.
 486 def fnabs : PatFrag<(ops node:$ptr), (fneg (fabs node:$ptr))>;
 487
 488 // Create a unary operator that loads from memory and then performs
 489 // the given operation on it.
 490 class loadu<SDPatternOperator operator, SDPatternOperator load = load>
 491   : PatFrag<(ops node:$addr), (operator (load node:$addr))>;
 492
 493 // Create a store operator that performs the given unary operation
 494 // on the value before storing it.
 495 class storeu<SDPatternOperator operator, SDPatternOperator store = store>
 496   : PatFrag<(ops node:$value, node:$addr),
 497             (store (operator node:$value), node:$addr)>;
 498
 499 // Vector representation of all-zeros and all-ones.
 500 def z_vzero : PatFrag<(ops), (bitconvert (v16i8 (z_byte_mask (i32 0))))>;
 501 def z_vones : PatFrag<(ops), (bitconvert (v16i8 (z_byte_mask (i32 65535))))>;
 502
 503 // Load a scalar and replicate it in all elements of a vector.
 504 class z_replicate_load<ValueType scalartype, SDPatternOperator load>
 505   : PatFrag<(ops node:$addr),
 506             (z_replicate (scalartype (load node:$addr)))>;
 507 def z_replicate_loadi8  : z_replicate_load<i32, anyextloadi8>;
 508 def z_replicate_loadi16 : z_replicate_load<i32, anyextloadi16>;
 509 def z_replicate_loadi32 : z_replicate_load<i32, load>;
 510 def z_replicate_loadi64 : z_replicate_load<i64, load>;
 511 def z_replicate_loadf64 : z_replicate_load<f64, load>;
 512
 513 // Load a scalar and insert it into a single element of a vector.
 514 class z_vle<ValueType scalartype, SDPatternOperator load>
 515   : PatFrag<(ops node:$vec, node:$addr, node:$index),
 516             (z_vector_insert node:$vec, (scalartype (load node:$addr)),
 517                              node:$index)>;
 518 def z_vlei8  : z_vle<i32, anyextloadi8>;
 519 def z_vlei16 : z_vle<i32, anyextloadi16>;
 520 def z_vlei32 : z_vle<i32, load>;
 521 def z_vlei64 : z_vle<i64, load>;
 522 def z_vlef64 : z_vle<f64, load>;
 523
 524 // Load a scalar and insert it into the low element of the high i64 of a
 525 // zeroed vector.
 526 class z_vllez<ValueType scalartype, SDPatternOperator load, int index>
 527   : PatFrag<(ops node:$addr),
 528             (z_vector_insert (z_vzero),
 529                              (scalartype (load node:$addr)), (i32 index))>;
 530 def z_vllezi8  : z_vllez<i32, anyextloadi8, 7>;
 531 def z_vllezi16 : z_vllez<i32, anyextloadi16, 3>;
 532 def z_vllezi32 : z_vllez<i32, load, 1>;
 533 def z_vllezi64 : PatFrag<(ops node:$addr),
 534                          (z_join_dwords (i64 (load node:$addr)), (i64 0))>;
 535 def z_vllezf64 : PatFrag<(ops node:$addr),
 536                          (z_merge_high
 537                           (scalar_to_vector (f64 (load node:$addr))),
 538                           (z_vzero))>;
 539
 540 // Store one element of a vector.
 541 class z_vste<ValueType scalartype, SDPatternOperator store>
 542   : PatFrag<(ops node:$vec, node:$addr, node:$index),
 543             (store (scalartype (z_vector_extract node:$vec, node:$index)),
 544                    node:$addr)>;
 545 def z_vstei8  : z_vste<i32, truncstorei8>;
 546 def z_vstei16 : z_vste<i32, truncstorei16>;
 547 def z_vstei32 : z_vste<i32, store>;
 548 def z_vstei64 : z_vste<i64, store>;
 549 def z_vstef64 : z_vste<f64, store>;
 550
 551 // Arithmetic negation on vectors.
 552 def z_vneg : PatFrag<(ops node:$x), (sub (z_vzero), node:$x)>;
 553
 554 // Bitwise negation on vectors.
 555 def z_vnot : PatFrag<(ops node:$x), (xor node:$x, (z_vones))>;
 556
 557 // Signed "integer greater than zero" on vectors.
 558 def z_vicmph_zero : PatFrag<(ops node:$x), (z_vicmph node:$x, (z_vzero))>;
 559
 560 // Signed "integer less than zero" on vectors.
 561 def z_vicmpl_zero : PatFrag<(ops node:$x), (z_vicmph (z_vzero), node:$x)>;
 562
 563 // Integer absolute on vectors.
 564 class z_viabs<int shift>
 565   : PatFrag<(ops node:$src),
 566             (xor (add node:$src, (z_vsra_by_scalar node:$src, (i32 shift))),
 567                  (z_vsra_by_scalar node:$src, (i32 shift)))>;
 568 def z_viabs8  : z_viabs<7>;
 569 def z_viabs16 : z_viabs<15>;
 570 def z_viabs32 : z_viabs<31>;
 571 def z_viabs64 : z_viabs<63>;
 572
 573 // Sign-extend the i64 elements of a vector.
 574 class z_vse<int shift>
 575   : PatFrag<(ops node:$src),
 576             (z_vsra_by_scalar (z_vshl_by_scalar node:$src, shift), shift)>;
 577 def z_vsei8  : z_vse<56>;
 578 def z_vsei16 : z_vse<48>;
 579 def z_vsei32 : z_vse<32>;
 580
 581 // ...and again with the extensions being done on individual i64 scalars.
 582 class z_vse_by_parts<SDPatternOperator operator, int index1, int index2>
 583   : PatFrag<(ops node:$src),
 584             (z_join_dwords
 585              (operator (z_vector_extract node:$src, index1)),
 586              (operator (z_vector_extract node:$src, index2)))>;
 587 def z_vsei8_by_parts  : z_vse_by_parts<sext8dbl, 7, 15>;
 588 def z_vsei16_by_parts : z_vse_by_parts<sext16dbl, 3, 7>;
 589 def z_vsei32_by_parts : z_vse_by_parts<sext32, 1, 3>;