lib/Target/SystemZ/SystemZOperands.td

   1 //===-- SystemZOperands.td - SystemZ instruction operands ----*- tblgen-*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // Class definitions
  12 //===----------------------------------------------------------------------===//
  13
  14 class ImmediateAsmOperand<string name>
  15   : AsmOperandClass {
  16   let Name = name;
  17   let RenderMethod = "addImmOperands";
  18 }
  19
  20 // Constructs both a DAG pattern and instruction operand for an immediate
  21 // of type VT.  PRED returns true if a node is acceptable and XFORM returns
  22 // the operand value associated with the node.  ASMOP is the name of the
  23 // associated asm operand, and also forms the basis of the asm print method.
  24 class Immediate<ValueType vt, code pred, SDNodeXForm xform, string asmop>
  25   : PatLeaf<(vt imm), pred, xform>, Operand<vt> {
  26   let PrintMethod = "print"##asmop##"Operand";
  27   let DecoderMethod = "decode"##asmop##"Operand";
  28   let ParserMatchClass = !cast<AsmOperandClass>(asmop);
  29 }
  30
  31 // Constructs an asm operand for a PC-relative address.  SIZE says how
  32 // many bits there are.
  33 class PCRelAsmOperand<string size> : ImmediateAsmOperand<"PCRel"##size> {
  34   let PredicateMethod = "isImm";
  35   let ParserMethod = "parsePCRel"##size;
  36 }
  37
  38 // Constructs an operand for a PC-relative address with address type VT.
  39 // ASMOP is the associated asm operand.
  40 class PCRelOperand<ValueType vt, AsmOperandClass asmop> : Operand<vt> {
  41   let PrintMethod = "printPCRelOperand";
  42   let ParserMatchClass = asmop;
  43 }
  44
  45 // Constructs both a DAG pattern and instruction operand for a PC-relative
  46 // address with address size VT.  SELF is the name of the operand and
  47 // ASMOP is the associated asm operand.
  48 class PCRelAddress<ValueType vt, string self, AsmOperandClass asmop>
  49   : ComplexPattern<vt, 1, "selectPCRelAddress", [z_pcrel_wrapper]>,
  50     PCRelOperand<vt, asmop> {
  51   let MIOperandInfo = (ops !cast<Operand>(self));
  52 }
  53
  54 // Constructs an AsmOperandClass for addressing mode FORMAT, treating the
  55 // registers as having BITSIZE bits and displacements as having DISPSIZE bits.
  56 // LENGTH is "LenN" for addresses with an N-bit length field, otherwise it
  57 // is "".
  58 class AddressAsmOperand<string format, string bitsize, string dispsize,
  59                         string length = "">
  60   : AsmOperandClass {
  61   let Name = format##bitsize##"Disp"##dispsize##length;
  62   let ParserMethod = "parse"##format##bitsize;
  63   let RenderMethod = "add"##format##"Operands";
  64 }
  65
  66 // Constructs both a DAG pattern and instruction operand for an addressing mode.
  67 // FORMAT, BITSIZE, DISPSIZE and LENGTH are the parameters to an associated
  68 // AddressAsmOperand.  OPERANDS is a list of NUMOPS individual operands
  69 // (base register, displacement, etc.).  SELTYPE is the type of the memory
  70 // operand for selection purposes; sometimes we want different selection
  71 // choices for the same underlying addressing mode.  SUFFIX is similarly
  72 // a suffix appended to the displacement for selection purposes;
  73 // e.g. we want to reject small 20-bit displacements if a 12-bit form
  74 // also exists, but we want to accept them otherwise.
  75 class AddressingMode<string seltype, string bitsize, string dispsize,
  76                      string suffix, string length, int numops, string format,
  77                      dag operands>
  78   : ComplexPattern<!cast<ValueType>("i"##bitsize), numops,
  79                    "select"##seltype##dispsize##suffix##length,
  80                    [add, sub, or, frameindex, z_adjdynalloc]>,
  81     Operand<!cast<ValueType>("i"##bitsize)> {
  82   let PrintMethod = "print"##format##"Operand";
  83   let EncoderMethod = "get"##format##dispsize##length##"Encoding";
  84   let DecoderMethod =
  85     "decode"##format##bitsize##"Disp"##dispsize##length##"Operand";
  86   let MIOperandInfo = operands;
  87   let ParserMatchClass =
  88     !cast<AddressAsmOperand>(format##bitsize##"Disp"##dispsize##length);
  89 }
  90
  91 // An addressing mode with a base and displacement but no index.
  92 class BDMode<string type, string bitsize, string dispsize, string suffix>
  93   : AddressingMode<type, bitsize, dispsize, suffix, "", 2, "BDAddr",
  94                    (ops !cast<RegisterOperand>("ADDR"##bitsize),
  95                         !cast<Immediate>("disp"##dispsize##"imm"##bitsize))>;
  96
  97 // An addressing mode with a base, displacement and index.
  98 class BDXMode<string type, string bitsize, string dispsize, string suffix>
  99   : AddressingMode<type, bitsize, dispsize, suffix, "", 3, "BDXAddr",
 100                    (ops !cast<RegisterOperand>("ADDR"##bitsize),
 101                         !cast<Immediate>("disp"##dispsize##"imm"##bitsize),
 102                         !cast<RegisterOperand>("ADDR"##bitsize))>;
 103
 104 // A BDMode paired with an immediate length operand of LENSIZE bits.
 105 class BDLMode<string type, string bitsize, string dispsize, string suffix,
 106               string lensize>
 107   : AddressingMode<type, bitsize, dispsize, suffix, "Len"##lensize, 3,
 108                    "BDLAddr",
 109                    (ops !cast<RegisterOperand>("ADDR"##bitsize),
 110                         !cast<Immediate>("disp"##dispsize##"imm"##bitsize),
 111                         !cast<Immediate>("imm"##bitsize))>;
 112
 113 //===----------------------------------------------------------------------===//
 114 // Extracting immediate operands from nodes
 115 // These all create MVT::i64 nodes to ensure the value is not sign-extended
 116 // when converted from an SDNode to a MachineOperand later on.
 117 //===----------------------------------------------------------------------===//
 118
 119 // Bits 0-15 (counting from the lsb).
 120 def LL16 : SDNodeXForm<imm, [{
 121   uint64_t Value = N->getZExtValue() & 0x000000000000FFFFULL;
 122   return CurDAG->getTargetConstant(Value, MVT::i64);
 123 }]>;
 124
 125 // Bits 16-31 (counting from the lsb).
 126 def LH16 : SDNodeXForm<imm, [{
 127   uint64_t Value = (N->getZExtValue() & 0x00000000FFFF0000ULL) >> 16;
 128   return CurDAG->getTargetConstant(Value, MVT::i64);
 129 }]>;
 130
 131 // Bits 32-47 (counting from the lsb).
 132 def HL16 : SDNodeXForm<imm, [{
 133   uint64_t Value = (N->getZExtValue() & 0x0000FFFF00000000ULL) >> 32;
 134   return CurDAG->getTargetConstant(Value, MVT::i64);
 135 }]>;
 136
 137 // Bits 48-63 (counting from the lsb).
 138 def HH16 : SDNodeXForm<imm, [{
 139   uint64_t Value = (N->getZExtValue() & 0xFFFF000000000000ULL) >> 48;
 140   return CurDAG->getTargetConstant(Value, MVT::i64);
 141 }]>;
 142
 143 // Low 32 bits.
 144 def LF32 : SDNodeXForm<imm, [{
 145   uint64_t Value = N->getZExtValue() & 0x00000000FFFFFFFFULL;
 146   return CurDAG->getTargetConstant(Value, MVT::i64);
 147 }]>;
 148
 149 // High 32 bits.
 150 def HF32 : SDNodeXForm<imm, [{
 151   uint64_t Value = N->getZExtValue() >> 32;
 152   return CurDAG->getTargetConstant(Value, MVT::i64);
 153 }]>;
 154
 155 // Truncate an immediate to a 8-bit signed quantity.
 156 def SIMM8 : SDNodeXForm<imm, [{
 157   return CurDAG->getTargetConstant(int8_t(N->getZExtValue()), MVT::i64);
 158 }]>;
 159
 160 // Truncate an immediate to a 8-bit unsigned quantity.
 161 def UIMM8 : SDNodeXForm<imm, [{
 162   return CurDAG->getTargetConstant(uint8_t(N->getZExtValue()), MVT::i64);
 163 }]>;
 164
 165 // Truncate an immediate to a 16-bit signed quantity.
 166 def SIMM16 : SDNodeXForm<imm, [{
 167   return CurDAG->getTargetConstant(int16_t(N->getZExtValue()), MVT::i64);
 168 }]>;
 169
 170 // Truncate an immediate to a 16-bit unsigned quantity.
 171 def UIMM16 : SDNodeXForm<imm, [{
 172   return CurDAG->getTargetConstant(uint16_t(N->getZExtValue()), MVT::i64);
 173 }]>;
 174
 175 // Truncate an immediate to a 32-bit signed quantity.
 176 def SIMM32 : SDNodeXForm<imm, [{
 177   return CurDAG->getTargetConstant(int32_t(N->getZExtValue()), MVT::i64);
 178 }]>;
 179
 180 // Truncate an immediate to a 32-bit unsigned quantity.
 181 def UIMM32 : SDNodeXForm<imm, [{
 182   return CurDAG->getTargetConstant(uint32_t(N->getZExtValue()), MVT::i64);
 183 }]>;
 184
 185 // Negate and then truncate an immediate to a 32-bit unsigned quantity.
 186 def NEGIMM32 : SDNodeXForm<imm, [{
 187   return CurDAG->getTargetConstant(uint32_t(-N->getZExtValue()), MVT::i64);
 188 }]>;
 189
 190 //===----------------------------------------------------------------------===//
 191 // Immediate asm operands.
 192 //===----------------------------------------------------------------------===//
 193
 194 def U4Imm  : ImmediateAsmOperand<"U4Imm">;
 195 def U6Imm  : ImmediateAsmOperand<"U6Imm">;
 196 def S8Imm  : ImmediateAsmOperand<"S8Imm">;
 197 def U8Imm  : ImmediateAsmOperand<"U8Imm">;
 198 def S16Imm : ImmediateAsmOperand<"S16Imm">;
 199 def U16Imm : ImmediateAsmOperand<"U16Imm">;
 200 def S32Imm : ImmediateAsmOperand<"S32Imm">;
 201 def U32Imm : ImmediateAsmOperand<"U32Imm">;
 202
 203 //===----------------------------------------------------------------------===//
 204 // 8-bit immediates
 205 //===----------------------------------------------------------------------===//
 206
 207 def uimm8zx4 : Immediate<i8, [{
 208   return isUInt<4>(N->getZExtValue());
 209 }], NOOP_SDNodeXForm, "U4Imm">;
 210
 211 def uimm8zx6 : Immediate<i8, [{
 212   return isUInt<6>(N->getZExtValue());
 213 }], NOOP_SDNodeXForm, "U6Imm">;
 214
 215 def simm8    : Immediate<i8, [{}], SIMM8, "S8Imm">;
 216 def uimm8    : Immediate<i8, [{}], UIMM8, "U8Imm">;
 217
 218 //===----------------------------------------------------------------------===//
 219 // i32 immediates
 220 //===----------------------------------------------------------------------===//
 221
 222 // Immediates for the lower and upper 16 bits of an i32, with the other
 223 // bits of the i32 being zero.
 224 def imm32ll16 : Immediate<i32, [{
 225   return SystemZ::isImmLL(N->getZExtValue());
 226 }], LL16, "U16Imm">;
 227
 228 def imm32lh16 : Immediate<i32, [{
 229   return SystemZ::isImmLH(N->getZExtValue());
 230 }], LH16, "U16Imm">;
 231
 232 // Immediates for the lower and upper 16 bits of an i32, with the other
 233 // bits of the i32 being one.
 234 def imm32ll16c : Immediate<i32, [{
 235   return SystemZ::isImmLL(uint32_t(~N->getZExtValue()));
 236 }], LL16, "U16Imm">;
 237
 238 def imm32lh16c : Immediate<i32, [{
 239   return SystemZ::isImmLH(uint32_t(~N->getZExtValue()));
 240 }], LH16, "U16Imm">;
 241
 242 // Short immediates
 243 def imm32sx8 : Immediate<i32, [{
 244   return isInt<8>(N->getSExtValue());
 245 }], SIMM8, "S8Imm">;
 246
 247 def imm32zx8 : Immediate<i32, [{
 248   return isUInt<8>(N->getZExtValue());
 249 }], UIMM8, "U8Imm">;
 250
 251 def imm32zx8trunc : Immediate<i32, [{}], UIMM8, "U8Imm">;
 252
 253 def imm32sx16 : Immediate<i32, [{
 254   return isInt<16>(N->getSExtValue());
 255 }], SIMM16, "S16Imm">;
 256
 257 def imm32zx16 : Immediate<i32, [{
 258   return isUInt<16>(N->getZExtValue());
 259 }], UIMM16, "U16Imm">;
 260
 261 def imm32sx16trunc : Immediate<i32, [{}], SIMM16, "S16Imm">;
 262
 263 // Full 32-bit immediates.  we need both signed and unsigned versions
 264 // because the assembler is picky.  E.g. AFI requires signed operands
 265 // while NILF requires unsigned ones.
 266 def simm32 : Immediate<i32, [{}], SIMM32, "S32Imm">;
 267 def uimm32 : Immediate<i32, [{}], UIMM32, "U32Imm">;
 268
 269 def imm32 : ImmLeaf<i32, [{}]>;
 270
 271 //===----------------------------------------------------------------------===//
 272 // 64-bit immediates
 273 //===----------------------------------------------------------------------===//
 274
 275 // Immediates for 16-bit chunks of an i64, with the other bits of the
 276 // i32 being zero.
 277 def imm64ll16 : Immediate<i64, [{
 278   return SystemZ::isImmLL(N->getZExtValue());
 279 }], LL16, "U16Imm">;
 280
 281 def imm64lh16 : Immediate<i64, [{
 282   return SystemZ::isImmLH(N->getZExtValue());
 283 }], LH16, "U16Imm">;
 284
 285 def imm64hl16 : Immediate<i64, [{
 286   return SystemZ::isImmHL(N->getZExtValue());
 287 }], HL16, "U16Imm">;
 288
 289 def imm64hh16 : Immediate<i64, [{
 290   return SystemZ::isImmHH(N->getZExtValue());
 291 }], HH16, "U16Imm">;
 292
 293 // Immediates for 16-bit chunks of an i64, with the other bits of the
 294 // i32 being one.
 295 def imm64ll16c : Immediate<i64, [{
 296   return SystemZ::isImmLL(uint64_t(~N->getZExtValue()));
 297 }], LL16, "U16Imm">;
 298
 299 def imm64lh16c : Immediate<i64, [{
 300   return SystemZ::isImmLH(uint64_t(~N->getZExtValue()));
 301 }], LH16, "U16Imm">;
 302
 303 def imm64hl16c : Immediate<i64, [{
 304   return SystemZ::isImmHL(uint64_t(~N->getZExtValue()));
 305 }], HL16, "U16Imm">;
 306
 307 def imm64hh16c : Immediate<i64, [{
 308   return SystemZ::isImmHH(uint64_t(~N->getZExtValue()));
 309 }], HH16, "U16Imm">;
 310
 311 // Immediates for the lower and upper 32 bits of an i64, with the other
 312 // bits of the i32 being zero.
 313 def imm64lf32 : Immediate<i64, [{
 314   return SystemZ::isImmLF(N->getZExtValue());
 315 }], LF32, "U32Imm">;
 316
 317 def imm64hf32 : Immediate<i64, [{
 318   return SystemZ::isImmHF(N->getZExtValue());
 319 }], HF32, "U32Imm">;
 320
 321 // Immediates for the lower and upper 32 bits of an i64, with the other
 322 // bits of the i32 being one.
 323 def imm64lf32c : Immediate<i64, [{
 324   return SystemZ::isImmLF(uint64_t(~N->getZExtValue()));
 325 }], LF32, "U32Imm">;
 326
 327 def imm64hf32c : Immediate<i64, [{
 328   return SystemZ::isImmHF(uint64_t(~N->getZExtValue()));
 329 }], HF32, "U32Imm">;
 330
 331 // Short immediates.
 332 def imm64sx8 : Immediate<i64, [{
 333   return isInt<8>(N->getSExtValue());
 334 }], SIMM8, "S8Imm">;
 335
 336 def imm64zx8 : Immediate<i64, [{
 337   return isUInt<8>(N->getSExtValue());
 338 }], UIMM8, "U8Imm">;
 339
 340 def imm64sx16 : Immediate<i64, [{
 341   return isInt<16>(N->getSExtValue());
 342 }], SIMM16, "S16Imm">;
 343
 344 def imm64zx16 : Immediate<i64, [{
 345   return isUInt<16>(N->getZExtValue());
 346 }], UIMM16, "U16Imm">;
 347
 348 def imm64sx32 : Immediate<i64, [{
 349   return isInt<32>(N->getSExtValue());
 350 }], SIMM32, "S32Imm">;
 351
 352 def imm64zx32 : Immediate<i64, [{
 353   return isUInt<32>(N->getZExtValue());
 354 }], UIMM32, "U32Imm">;
 355
 356 def imm64zx32n : Immediate<i64, [{
 357   return isUInt<32>(-N->getSExtValue());
 358 }], NEGIMM32, "U32Imm">;
 359
 360 def imm64 : ImmLeaf<i64, [{}]>, Operand<i64>;
 361
 362 //===----------------------------------------------------------------------===//
 363 // Floating-point immediates
 364 //===----------------------------------------------------------------------===//
 365
 366 // Floating-point zero.
 367 def fpimm0 : PatLeaf<(fpimm), [{ return N->isExactlyValue(+0.0); }]>;
 368
 369 // Floating point negative zero.
 370 def fpimmneg0 : PatLeaf<(fpimm), [{ return N->isExactlyValue(-0.0); }]>;
 371
 372 //===----------------------------------------------------------------------===//
 373 // Symbolic address operands
 374 //===----------------------------------------------------------------------===//
 375
 376 // PC-relative asm operands.
 377 def PCRel16 : PCRelAsmOperand<"16">;
 378 def PCRel32 : PCRelAsmOperand<"32">;
 379
 380 // PC-relative offsets of a basic block.  The offset is sign-extended
 381 // and multiplied by 2.
 382 def brtarget16 : PCRelOperand<OtherVT, PCRel16> {
 383   let EncoderMethod = "getPC16DBLEncoding";
 384   let DecoderMethod = "decodePC16DBLOperand";
 385 }
 386 def brtarget32 : PCRelOperand<OtherVT, PCRel32> {
 387   let EncoderMethod = "getPC32DBLEncoding";
 388   let DecoderMethod = "decodePC32DBLOperand";
 389 }
 390
 391 // A PC-relative offset of a global value.  The offset is sign-extended
 392 // and multiplied by 2.
 393 def pcrel32 : PCRelAddress<i64, "pcrel32", PCRel32> {
 394   let EncoderMethod = "getPC32DBLEncoding";
 395   let DecoderMethod = "decodePC32DBLOperand";
 396 }
 397
 398 // A PC-relative offset of a global value when the value is used as a
 399 // call target.  The offset is sign-extended and multiplied by 2.
 400 def pcrel16call : PCRelAddress<i64, "pcrel16call", PCRel16> {
 401   let PrintMethod = "printCallOperand";
 402   let EncoderMethod = "getPLT16DBLEncoding";
 403   let DecoderMethod = "decodePC16DBLOperand";
 404 }
 405 def pcrel32call : PCRelAddress<i64, "pcrel32call", PCRel32> {
 406   let PrintMethod = "printCallOperand";
 407   let EncoderMethod = "getPLT32DBLEncoding";
 408   let DecoderMethod = "decodePC32DBLOperand";
 409 }
 410
 411 //===----------------------------------------------------------------------===//
 412 // Addressing modes
 413 //===----------------------------------------------------------------------===//
 414
 415 // 12-bit displacement operands.
 416 def disp12imm32 : Operand<i32>;
 417 def disp12imm64 : Operand<i64>;
 418
 419 // 20-bit displacement operands.
 420 def disp20imm32 : Operand<i32>;
 421 def disp20imm64 : Operand<i64>;
 422
 423 def BDAddr32Disp12      : AddressAsmOperand<"BDAddr",   "32", "12">;
 424 def BDAddr32Disp20      : AddressAsmOperand<"BDAddr",   "32", "20">;
 425 def BDAddr64Disp12      : AddressAsmOperand<"BDAddr",   "64", "12">;
 426 def BDAddr64Disp20      : AddressAsmOperand<"BDAddr",   "64", "20">;
 427 def BDXAddr64Disp12     : AddressAsmOperand<"BDXAddr",  "64", "12">;
 428 def BDXAddr64Disp20     : AddressAsmOperand<"BDXAddr",  "64", "20">;
 429 def BDLAddr64Disp12Len8 : AddressAsmOperand<"BDLAddr",  "64", "12", "Len8">;
 430
 431 // DAG patterns and operands for addressing modes.  Each mode has
 432 // the form <type><range><group>[<len>] where:
 433 //
 434 // <type> is one of:
 435 //   shift    : base + displacement (32-bit)
 436 //   bdaddr   : base + displacement
 437 //   mviaddr  : like bdaddr, but reject cases with a natural index
 438 //   bdxaddr  : base + displacement + index
 439 //   laaddr   : like bdxaddr, but used for Load Address operations
 440 //   dynalloc : base + displacement + index + ADJDYNALLOC
 441 //   bdladdr  : base + displacement with a length field
 442 //
 443 // <range> is one of:
 444 //   12       : the displacement is an unsigned 12-bit value
 445 //   20       : the displacement is a signed 20-bit value
 446 //
 447 // <group> is one of:
 448 //   pair     : used when there is an equivalent instruction with the opposite
 449 //              range value (12 or 20)
 450 //   only     : used when there is no equivalent instruction with the opposite
 451 //              range value
 452 //
 453 // <len> is one of:
 454 //
 455 //   <empty>  : there is no length field
 456 //   len8     : the length field is 8 bits, with a range of [1, 0x100].
 457 def shift12only       : BDMode <"BDAddr",   "32", "12", "Only">;
 458 def shift20only       : BDMode <"BDAddr",   "32", "20", "Only">;
 459 def bdaddr12only      : BDMode <"BDAddr",   "64", "12", "Only">;
 460 def bdaddr12pair      : BDMode <"BDAddr",   "64", "12", "Pair">;
 461 def bdaddr20only      : BDMode <"BDAddr",   "64", "20", "Only">;
 462 def bdaddr20pair      : BDMode <"BDAddr",   "64", "20", "Pair">;
 463 def mviaddr12pair     : BDMode <"MVIAddr",  "64", "12", "Pair">;
 464 def mviaddr20pair     : BDMode <"MVIAddr",  "64", "20", "Pair">;
 465 def bdxaddr12only     : BDXMode<"BDXAddr",  "64", "12", "Only">;
 466 def bdxaddr12pair     : BDXMode<"BDXAddr",  "64", "12", "Pair">;
 467 def bdxaddr20only     : BDXMode<"BDXAddr",  "64", "20", "Only">;
 468 def bdxaddr20only128  : BDXMode<"BDXAddr",  "64", "20", "Only128">;
 469 def bdxaddr20pair     : BDXMode<"BDXAddr",  "64", "20", "Pair">;
 470 def dynalloc12only    : BDXMode<"DynAlloc", "64", "12", "Only">;
 471 def laaddr12pair      : BDXMode<"LAAddr",   "64", "12", "Pair">;
 472 def laaddr20pair      : BDXMode<"LAAddr",   "64", "20", "Pair">;
 473 def bdladdr12onlylen8 : BDLMode<"BDLAddr",  "64", "12", "Only", "8">;
 474
 475 //===----------------------------------------------------------------------===//
 476 // Miscellaneous
 477 //===----------------------------------------------------------------------===//
 478
 479 // Access registers.  At present we just use them for accessing the thread
 480 // pointer, so we don't expose them as register to LLVM.
 481 def AccessReg : AsmOperandClass {
 482   let Name = "AccessReg";
 483   let ParserMethod = "parseAccessReg";
 484 }
 485 def access_reg : Immediate<i8, [{ return N->getZExtValue() < 16; }],
 486                            NOOP_SDNodeXForm, "AccessReg"> {
 487   let ParserMatchClass = AccessReg;
 488 }
 489
 490 // A 4-bit condition-code mask.
 491 def cond4 : PatLeaf<(i8 imm), [{ return (N->getZExtValue() < 16); }]>,
 492             Operand<i8> {
 493   let PrintMethod = "printCond4Operand";
 494 }