lib/Target/Sparc/SparcInstr64Bit.td

   1 //===-- SparcInstr64Bit.td - 64-bit instructions for Sparc Target ---------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file contains instruction definitions and patterns needed for 64-bit
  11 // code generation on SPARC v9.
  12 //
  13 // Some SPARC v9 instructions are defined in SparcInstrInfo.td because they can
  14 // also be used in 32-bit code running on a SPARC v9 CPU.
  15 //
  16 //===----------------------------------------------------------------------===//
  17
  18 let Predicates = [Is64Bit] in {
  19 // The same integer registers are used for i32 and i64 values.
  20 // When registers hold i32 values, the high bits are don't care.
  21 // This give us free trunc and anyext.
  22 def : Pat<(i64 (anyext i32:$val)), (COPY_TO_REGCLASS $val, I64Regs)>;
  23 def : Pat<(i32 (trunc i64:$val)), (COPY_TO_REGCLASS $val, IntRegs)>;
  24
  25 } // Predicates = [Is64Bit]
  26
  27
  28 //===----------------------------------------------------------------------===//
  29 // 64-bit Shift Instructions.
  30 //===----------------------------------------------------------------------===//
  31 //
  32 // The 32-bit shift instructions are still available. The left shift srl
  33 // instructions shift all 64 bits, but it only accepts a 5-bit shift amount.
  34 //
  35 // The srl instructions only shift the low 32 bits and clear the high 32 bits.
  36 // Finally, sra shifts the low 32 bits and sign-extends to 64 bits.
  37
  38 let Predicates = [Is64Bit] in {
  39
  40 def : Pat<(i64 (zext i32:$val)), (SRLri $val, 0)>;
  41 def : Pat<(i64 (sext i32:$val)), (SRAri $val, 0)>;
  42
  43 def : Pat<(i64 (and i64:$val, 0xffffffff)), (SRLri $val, 0)>;
  44 def : Pat<(i64 (sext_inreg i64:$val, i32)), (SRAri $val, 0)>;
  45
  46 defm SLLX : F3_S<"sllx", 0b100101, 1, shl, i64, I64Regs>;
  47 defm SRLX : F3_S<"srlx", 0b100110, 1, srl, i64, I64Regs>;
  48 defm SRAX : F3_S<"srax", 0b100111, 1, sra, i64, I64Regs>;
  49
  50 } // Predicates = [Is64Bit]
  51
  52
  53 //===----------------------------------------------------------------------===//
  54 // 64-bit Immediates.
  55 //===----------------------------------------------------------------------===//
  56 //
  57 // All 32-bit immediates can be materialized with sethi+or, but 64-bit
  58 // immediates may require more code. There may be a point where it is
  59 // preferable to use a constant pool load instead, depending on the
  60 // microarchitecture.
  61
  62 // Single-instruction patterns.
  63
  64 // The ALU instructions want their simm13 operands as i32 immediates.
  65 def as_i32imm : SDNodeXForm<imm, [{
  66   return CurDAG->getTargetConstant(N->getSExtValue(), MVT::i32);
  67 }]>;
  68 def : Pat<(i64 simm13:$val), (ORri (i64 G0), (as_i32imm $val))>;
  69 def : Pat<(i64 SETHIimm:$val), (SETHIi (HI22 $val))>;
  70
  71 // Double-instruction patterns.
  72
  73 // All unsigned i32 immediates can be handled by sethi+or.
  74 def uimm32 : PatLeaf<(imm), [{ return isUInt<32>(N->getZExtValue()); }]>;
  75 def : Pat<(i64 uimm32:$val), (ORri (SETHIi (HI22 $val)), (LO10 $val))>,
  76       Requires<[Is64Bit]>;
  77
  78 // All negative i33 immediates can be handled by sethi+xor.
  79 def nimm33 : PatLeaf<(imm), [{
  80   int64_t Imm = N->getSExtValue();
  81   return Imm < 0 && isInt<33>(Imm);
  82 }]>;
  83 // Bits 10-31 inverted. Same as assembler's %hix.
  84 def HIX22 : SDNodeXForm<imm, [{
  85   uint64_t Val = (~N->getZExtValue() >> 10) & ((1u << 22) - 1);
  86   return CurDAG->getTargetConstant(Val, MVT::i32);
  87 }]>;
  88 // Bits 0-9 with ones in bits 10-31. Same as assembler's %lox.
  89 def LOX10 : SDNodeXForm<imm, [{
  90   return CurDAG->getTargetConstant(~(~N->getZExtValue() & 0x3ff), MVT::i32);
  91 }]>;
  92 def : Pat<(i64 nimm33:$val), (XORri (SETHIi (HIX22 $val)), (LOX10 $val))>,
  93       Requires<[Is64Bit]>;
  94
  95 // More possible patterns:
  96 //
  97 //   (sllx sethi, n)
  98 //   (sllx simm13, n)
  99 //
 100 // 3 instrs:
 101 //
 102 //   (xor (sllx sethi), simm13)
 103 //   (sllx (xor sethi, simm13))
 104 //
 105 // 4 instrs:
 106 //
 107 //   (or sethi, (sllx sethi))
 108 //   (xnor sethi, (sllx sethi))
 109 //
 110 // 5 instrs:
 111 //
 112 //   (or (sllx sethi), (or sethi, simm13))
 113 //   (xnor (sllx sethi), (or sethi, simm13))
 114 //   (or (sllx sethi), (sllx sethi))
 115 //   (xnor (sllx sethi), (sllx sethi))
 116 //
 117 // Worst case is 6 instrs:
 118 //
 119 //   (or (sllx (or sethi, simmm13)), (or sethi, simm13))
 120
 121 // Bits 42-63, same as assembler's %hh.
 122 def HH22 : SDNodeXForm<imm, [{
 123   uint64_t Val = (N->getZExtValue() >> 42) & ((1u << 22) - 1);
 124   return CurDAG->getTargetConstant(Val, MVT::i32);
 125 }]>;
 126 // Bits 32-41, same as assembler's %hm.
 127 def HM10 : SDNodeXForm<imm, [{
 128   uint64_t Val = (N->getZExtValue() >> 32) & ((1u << 10) - 1);
 129   return CurDAG->getTargetConstant(Val, MVT::i32);
 130 }]>;
 131 def : Pat<(i64 imm:$val),
 132           (ORrr (SLLXri (ORri (SETHIi (HH22 $val)), (HM10 $val)), (i32 32)),
 133                 (ORri (SETHIi (HI22 $val)), (LO10 $val)))>,
 134       Requires<[Is64Bit]>;
 135
 136
 137 //===----------------------------------------------------------------------===//
 138 // 64-bit Integer Arithmetic and Logic.
 139 //===----------------------------------------------------------------------===//
 140
 141 let Predicates = [Is64Bit] in {
 142
 143 // Register-register instructions.
 144 let isCodeGenOnly = 1 in {
 145 defm ANDX    : F3_12<"and", 0b000001, and, I64Regs, i64, i64imm>;
 146 defm ORX     : F3_12<"or",  0b000010, or,  I64Regs, i64, i64imm>;
 147 defm XORX    : F3_12<"xor", 0b000011, xor, I64Regs, i64, i64imm>;
 148
 149 def ANDXNrr  : F3_1<2, 0b000101,
 150                  (outs I64Regs:$dst), (ins I64Regs:$b, I64Regs:$c),
 151                  "andn $b, $c, $dst",
 152                  [(set i64:$dst, (and i64:$b, (not i64:$c)))]>;
 153 def ORXNrr   : F3_1<2, 0b000110,
 154                  (outs I64Regs:$dst), (ins I64Regs:$b, I64Regs:$c),
 155                  "orn $b, $c, $dst",
 156                  [(set i64:$dst, (or i64:$b, (not i64:$c)))]>;
 157 def XNORXrr  : F3_1<2, 0b000111,
 158                    (outs I64Regs:$dst), (ins I64Regs:$b, I64Regs:$c),
 159                    "xnor $b, $c, $dst",
 160                    [(set i64:$dst, (not (xor i64:$b, i64:$c)))]>;
 161
 162 defm ADDX    : F3_12<"add", 0b000000, add, I64Regs, i64, i64imm>;
 163 defm SUBX    : F3_12<"sub", 0b000100, sub, I64Regs, i64, i64imm>;
 164
 165 def TLS_ADDXrr : F3_1<2, 0b000000, (outs I64Regs:$rd),
 166                    (ins I64Regs:$rs1, I64Regs:$rs2, TLSSym:$sym),
 167                    "add $rs1, $rs2, $rd, $sym",
 168                    [(set i64:$rd,
 169                        (tlsadd i64:$rs1, i64:$rs2, tglobaltlsaddr:$sym))]>;
 170
 171 // "LEA" form of add
 172 def LEAX_ADDri : F3_2<2, 0b000000,
 173                      (outs I64Regs:$dst), (ins MEMri:$addr),
 174                      "add ${addr:arith}, $dst",
 175                      [(set iPTR:$dst, ADDRri:$addr)]>;
 176 }
 177
 178 def : Pat<(SPcmpicc i64:$a, i64:$b), (CMPrr $a, $b)>;
 179 def : Pat<(SPcmpicc i64:$a, (i64 simm13:$b)), (CMPri $a, (as_i32imm $b))>;
 180 def : Pat<(ctpop i64:$src), (POPCrr $src)>;
 181
 182 } // Predicates = [Is64Bit]
 183
 184
 185 //===----------------------------------------------------------------------===//
 186 // 64-bit Integer Multiply and Divide.
 187 //===----------------------------------------------------------------------===//
 188
 189 let Predicates = [Is64Bit] in {
 190
 191 def MULXrr : F3_1<2, 0b001001,
 192                   (outs I64Regs:$rd), (ins I64Regs:$rs1, I64Regs:$rs2),
 193                   "mulx $rs1, $rs2, $rd",
 194                   [(set i64:$rd, (mul i64:$rs1, i64:$rs2))]>;
 195 def MULXri : F3_2<2, 0b001001,
 196                   (outs IntRegs:$rd), (ins IntRegs:$rs1, i64imm:$i),
 197                   "mulx $rs1, $i, $rd",
 198                   [(set i64:$rd, (mul i64:$rs1, (i64 simm13:$i)))]>;
 199
 200 // Division can trap.
 201 let hasSideEffects = 1 in {
 202 def SDIVXrr : F3_1<2, 0b101101,
 203                    (outs I64Regs:$rd), (ins I64Regs:$rs1, I64Regs:$rs2),
 204                    "sdivx $rs1, $rs2, $rd",
 205                    [(set i64:$rd, (sdiv i64:$rs1, i64:$rs2))]>;
 206 def SDIVXri : F3_2<2, 0b101101,
 207                    (outs IntRegs:$rd), (ins IntRegs:$rs1, i64imm:$i),
 208                    "sdivx $rs1, $i, $rd",
 209                    [(set i64:$rd, (sdiv i64:$rs1, (i64 simm13:$i)))]>;
 210
 211 def UDIVXrr : F3_1<2, 0b001101,
 212                    (outs I64Regs:$rd), (ins I64Regs:$rs1, I64Regs:$rs2),
 213                    "udivx $rs1, $rs2, $rd",
 214                    [(set i64:$rd, (udiv i64:$rs1, i64:$rs2))]>;
 215 def UDIVXri : F3_2<2, 0b001101,
 216                    (outs IntRegs:$rd), (ins IntRegs:$rs1, i64imm:$i),
 217                    "udivx $rs1, $i, $rd",
 218                    [(set i64:$rd, (udiv i64:$rs1, (i64 simm13:$i)))]>;
 219 } // hasSideEffects = 1
 220
 221 } // Predicates = [Is64Bit]
 222
 223
 224 //===----------------------------------------------------------------------===//
 225 // 64-bit Loads and Stores.
 226 //===----------------------------------------------------------------------===//
 227 //
 228 // All the 32-bit loads and stores are available. The extending loads are sign
 229 // or zero-extending to 64 bits. The LDrr and LDri instructions load 32 bits
 230 // zero-extended to i64. Their mnemonic is lduw in SPARC v9 (Load Unsigned
 231 // Word).
 232 //
 233 // SPARC v9 adds 64-bit loads as well as a sign-extending ldsw i32 loads.
 234
 235 let Predicates = [Is64Bit] in {
 236
 237 // 64-bit loads.
 238 def LDXrr  : F3_1<3, 0b001011,
 239                   (outs I64Regs:$dst), (ins MEMrr:$addr),
 240                   "ldx [$addr], $dst",
 241                   [(set i64:$dst, (load ADDRrr:$addr))]>;
 242 def LDXri  : F3_2<3, 0b001011,
 243                   (outs I64Regs:$dst), (ins MEMri:$addr),
 244                   "ldx [$addr], $dst",
 245                   [(set i64:$dst, (load ADDRri:$addr))]>;
 246 let mayLoad = 1, isCodeGenOnly = 1, isAsmParserOnly = 1 in
 247   def TLS_LDXrr : F3_1<3, 0b001011,
 248                        (outs IntRegs:$dst), (ins MEMrr:$addr, TLSSym:$sym),
 249                        "ldx [$addr], $dst, $sym",
 250                        [(set i64:$dst,
 251                            (tlsld ADDRrr:$addr, tglobaltlsaddr:$sym))]>;
 252
 253 // Extending loads to i64.
 254 def : Pat<(i64 (zextloadi1 ADDRrr:$addr)), (LDUBrr ADDRrr:$addr)>;
 255 def : Pat<(i64 (zextloadi1 ADDRri:$addr)), (LDUBri ADDRri:$addr)>;
 256 def : Pat<(i64 (extloadi1 ADDRrr:$addr)), (LDUBrr ADDRrr:$addr)>;
 257 def : Pat<(i64 (extloadi1 ADDRri:$addr)), (LDUBri ADDRri:$addr)>;
 258
 259 def : Pat<(i64 (zextloadi8 ADDRrr:$addr)), (LDUBrr ADDRrr:$addr)>;
 260 def : Pat<(i64 (zextloadi8 ADDRri:$addr)), (LDUBri ADDRri:$addr)>;
 261 def : Pat<(i64 (extloadi8 ADDRrr:$addr)),  (LDUBrr ADDRrr:$addr)>;
 262 def : Pat<(i64 (extloadi8 ADDRri:$addr)),  (LDUBri ADDRri:$addr)>;
 263 def : Pat<(i64 (sextloadi8 ADDRrr:$addr)), (LDSBrr ADDRrr:$addr)>;
 264 def : Pat<(i64 (sextloadi8 ADDRri:$addr)), (LDSBri ADDRri:$addr)>;
 265
 266 def : Pat<(i64 (zextloadi16 ADDRrr:$addr)), (LDUHrr ADDRrr:$addr)>;
 267 def : Pat<(i64 (zextloadi16 ADDRri:$addr)), (LDUHri ADDRri:$addr)>;
 268 def : Pat<(i64 (extloadi16 ADDRrr:$addr)),  (LDUHrr ADDRrr:$addr)>;
 269 def : Pat<(i64 (extloadi16 ADDRri:$addr)),  (LDUHri ADDRri:$addr)>;
 270 def : Pat<(i64 (sextloadi16 ADDRrr:$addr)), (LDSHrr ADDRrr:$addr)>;
 271 def : Pat<(i64 (sextloadi16 ADDRri:$addr)), (LDSHri ADDRri:$addr)>;
 272
 273 def : Pat<(i64 (zextloadi32 ADDRrr:$addr)), (LDrr ADDRrr:$addr)>;
 274 def : Pat<(i64 (zextloadi32 ADDRri:$addr)), (LDri ADDRri:$addr)>;
 275 def : Pat<(i64 (extloadi32 ADDRrr:$addr)),  (LDrr ADDRrr:$addr)>;
 276 def : Pat<(i64 (extloadi32 ADDRri:$addr)),  (LDri ADDRri:$addr)>;
 277
 278 // Sign-extending load of i32 into i64 is a new SPARC v9 instruction.
 279 def LDSWrr : F3_1<3, 0b001000,
 280                  (outs I64Regs:$dst), (ins MEMrr:$addr),
 281                  "ldsw [$addr], $dst",
 282                  [(set i64:$dst, (sextloadi32 ADDRrr:$addr))]>;
 283 def LDSWri : F3_2<3, 0b001000,
 284                  (outs I64Regs:$dst), (ins MEMri:$addr),
 285                  "ldsw [$addr], $dst",
 286                  [(set i64:$dst, (sextloadi32 ADDRri:$addr))]>;
 287
 288 // 64-bit stores.
 289 def STXrr  : F3_1<3, 0b001110,
 290                  (outs), (ins MEMrr:$addr, I64Regs:$rd),
 291                  "stx $rd, [$addr]",
 292                  [(store i64:$rd, ADDRrr:$addr)]>;
 293 def STXri  : F3_2<3, 0b001110,
 294                  (outs), (ins MEMri:$addr, I64Regs:$rd),
 295                  "stx $rd, [$addr]",
 296                  [(store i64:$rd, ADDRri:$addr)]>;
 297
 298 // Truncating stores from i64 are identical to the i32 stores.
 299 def : Pat<(truncstorei8  i64:$src, ADDRrr:$addr), (STBrr ADDRrr:$addr, $src)>;
 300 def : Pat<(truncstorei8  i64:$src, ADDRri:$addr), (STBri ADDRri:$addr, $src)>;
 301 def : Pat<(truncstorei16 i64:$src, ADDRrr:$addr), (STHrr ADDRrr:$addr, $src)>;
 302 def : Pat<(truncstorei16 i64:$src, ADDRri:$addr), (STHri ADDRri:$addr, $src)>;
 303 def : Pat<(truncstorei32 i64:$src, ADDRrr:$addr), (STrr  ADDRrr:$addr, $src)>;
 304 def : Pat<(truncstorei32 i64:$src, ADDRri:$addr), (STri  ADDRri:$addr, $src)>;
 305
 306 // store 0, addr -> store %g0, addr
 307 def : Pat<(store (i64 0), ADDRrr:$dst), (STXrr ADDRrr:$dst, (i64 G0))>;
 308 def : Pat<(store (i64 0), ADDRri:$dst), (STXri ADDRri:$dst, (i64 G0))>;
 309
 310 } // Predicates = [Is64Bit]
 311
 312
 313 //===----------------------------------------------------------------------===//
 314 // 64-bit Conditionals.
 315 //===----------------------------------------------------------------------===//
 316
 317 // Conditional branch class on %xcc:
 318 class XBranchSP<dag ins, string asmstr, list<dag> pattern>
 319   : F2_3<0b001, 0b10, (outs), ins, asmstr, pattern> {
 320   let isBranch = 1;
 321   let isTerminator = 1;
 322   let hasDelaySlot = 1;
 323 }
 324
 325 //
 326 // Flag-setting instructions like subcc and addcc set both icc and xcc flags.
 327 // The icc flags correspond to the 32-bit result, and the xcc are for the
 328 // full 64-bit result.
 329 //
 330 // We reuse CMPICC SDNodes for compares, but use new BRXCC branch nodes for
 331 // 64-bit compares. See LowerBR_CC.
 332
 333 let Predicates = [Is64Bit] in {
 334
 335 let Uses = [ICC] in
 336 def BPXCC : XBranchSP<(ins brtarget:$imm19, CCOp:$cond),
 337                      "b$cond %xcc, $imm19",
 338                      [(SPbrxcc bb:$imm19, imm:$cond)]>;
 339
 340 // Conditional moves on %xcc.
 341 let Uses = [ICC], Constraints = "$f = $rd" in {
 342 let cc = 0b110 in {
 343 def MOVXCCrr : F4_1<0b101100, (outs IntRegs:$rd),
 344                       (ins IntRegs:$rs2, IntRegs:$f, CCOp:$cond),
 345                       "mov$cond %xcc, $rs2, $rd",
 346                       [(set i32:$rd,
 347                        (SPselectxcc i32:$rs2, i32:$f, imm:$cond))]>;
 348 def MOVXCCri : F4_2<0b101100, (outs IntRegs:$rd),
 349                       (ins i32imm:$simm11, IntRegs:$f, CCOp:$cond),
 350                       "mov$cond %xcc, $simm11, $rd",
 351                       [(set i32:$rd,
 352                        (SPselectxcc simm11:$simm11, i32:$f, imm:$cond))]>;
 353 } // cc
 354
 355 let opf_cc = 0b110 in {
 356 def FMOVS_XCC : F4_3<0b110101, 0b000001, (outs FPRegs:$rd),
 357                       (ins FPRegs:$rs2, FPRegs:$f, CCOp:$cond),
 358                       "fmovs$cond %xcc, $rs2, $rd",
 359                       [(set f32:$rd,
 360                        (SPselectxcc f32:$rs2, f32:$f, imm:$cond))]>;
 361 def FMOVD_XCC : F4_3<0b110101, 0b000010, (outs DFPRegs:$rd),
 362                       (ins DFPRegs:$rs2, DFPRegs:$f, CCOp:$cond),
 363                       "fmovd$cond %xcc, $rs2, $rd",
 364                       [(set f64:$rd,
 365                        (SPselectxcc f64:$rs2, f64:$f, imm:$cond))]>;
 366 def FMOVQ_XCC : F4_3<0b110101, 0b000011, (outs QFPRegs:$rd),
 367                       (ins QFPRegs:$rs2, QFPRegs:$f, CCOp:$cond),
 368                       "fmovq$cond %xcc, $rs2, $rd",
 369                       [(set f128:$rd,
 370                        (SPselectxcc f128:$rs2, f128:$f, imm:$cond))]>;
 371 } // opf_cc
 372 } // Uses, Constraints
 373
 374 //===----------------------------------------------------------------------===//
 375 // 64-bit Floating Point Conversions.
 376 //===----------------------------------------------------------------------===//
 377
 378 let Predicates = [Is64Bit] in {
 379
 380 def FXTOS : F3_3u<2, 0b110100, 0b010000100,
 381                  (outs FPRegs:$dst), (ins DFPRegs:$src),
 382                  "fxtos $src, $dst",
 383                  [(set FPRegs:$dst, (SPxtof DFPRegs:$src))]>;
 384 def FXTOD : F3_3u<2, 0b110100, 0b010001000,
 385                  (outs DFPRegs:$dst), (ins DFPRegs:$src),
 386                  "fxtod $src, $dst",
 387                  [(set DFPRegs:$dst, (SPxtof DFPRegs:$src))]>;
 388 def FXTOQ : F3_3u<2, 0b110100, 0b010001100,
 389                  (outs QFPRegs:$dst), (ins DFPRegs:$src),
 390                  "fxtoq $src, $dst",
 391                  [(set QFPRegs:$dst, (SPxtof DFPRegs:$src))]>,
 392                  Requires<[HasHardQuad]>;
 393
 394 def FSTOX : F3_3u<2, 0b110100, 0b010000001,
 395                  (outs DFPRegs:$dst), (ins FPRegs:$src),
 396                  "fstox $src, $dst",
 397                  [(set DFPRegs:$dst, (SPftox FPRegs:$src))]>;
 398 def FDTOX : F3_3u<2, 0b110100, 0b010000010,
 399                  (outs DFPRegs:$dst), (ins DFPRegs:$src),
 400                  "fdtox $src, $dst",
 401                  [(set DFPRegs:$dst, (SPftox DFPRegs:$src))]>;
 402 def FQTOX : F3_3u<2, 0b110100, 0b010000011,
 403                  (outs DFPRegs:$dst), (ins QFPRegs:$src),
 404                  "fqtox $src, $dst",
 405                  [(set DFPRegs:$dst, (SPftox QFPRegs:$src))]>,
 406                  Requires<[HasHardQuad]>;
 407
 408 } // Predicates = [Is64Bit]
 409
 410 def : Pat<(SPselectxcc i64:$t, i64:$f, imm:$cond),
 411           (MOVXCCrr $t, $f, imm:$cond)>;
 412 def : Pat<(SPselectxcc (i64 simm11:$t), i64:$f, imm:$cond),
 413           (MOVXCCri (as_i32imm $t), $f, imm:$cond)>;
 414
 415 def : Pat<(SPselecticc i64:$t, i64:$f, imm:$cond),
 416           (MOVICCrr $t, $f, imm:$cond)>;
 417 def : Pat<(SPselecticc (i64 simm11:$t), i64:$f, imm:$cond),
 418           (MOVICCri (as_i32imm $t), $f, imm:$cond)>;
 419
 420 def : Pat<(SPselectfcc i64:$t, i64:$f, imm:$cond),
 421           (MOVFCCrr $t, $f, imm:$cond)>;
 422 def : Pat<(SPselectfcc (i64 simm11:$t), i64:$f, imm:$cond),
 423           (MOVFCCri (as_i32imm $t), $f, imm:$cond)>;
 424
 425 } // Predicates = [Is64Bit]
 426
 427
 428 // 64 bit SETHI
 429 let Predicates = [Is64Bit], isCodeGenOnly = 1 in {
 430 def SETHIXi : F2_1<0b100,
 431                    (outs IntRegs:$rd), (ins i64imm:$imm22),
 432                    "sethi $imm22, $rd",
 433                    [(set i64:$rd, SETHIimm:$imm22)]>;
 434 }
 435
 436 // ATOMICS.
 437 let Predicates = [Is64Bit], Constraints = "$swap = $rd" in {
 438   def CASXrr: F3_1<3, 0b111110,
 439                 (outs I64Regs:$rd), (ins I64Regs:$rs1, I64Regs:$rs2,
 440                                      I64Regs:$swap),
 441                  "casx [$rs1], $rs2, $rd",
 442                  [(set i64:$rd,
 443                      (atomic_cmp_swap i64:$rs1, i64:$rs2, i64:$swap))]>;
 444
 445 } // Predicates = [Is64Bit], Constraints = ...
 446
 447 let Predicates = [Is64Bit] in {
 448
 449 def : Pat<(atomic_fence imm, imm), (MEMBARi 0xf)>;
 450
 451 // atomic_load_64 addr -> load addr
 452 def : Pat<(i64 (atomic_load ADDRrr:$src)), (LDXrr ADDRrr:$src)>;
 453 def : Pat<(i64 (atomic_load ADDRri:$src)), (LDXri ADDRri:$src)>;
 454
 455 // atomic_store_64 val, addr -> store val, addr
 456 def : Pat<(atomic_store ADDRrr:$dst, i64:$val), (STXrr ADDRrr:$dst, $val)>;
 457 def : Pat<(atomic_store ADDRri:$dst, i64:$val), (STXri ADDRri:$dst, $val)>;
 458
 459 } // Predicates = [Is64Bit]
 460
 461 // Global addresses, constant pool entries
 462 let Predicates = [Is64Bit] in {
 463
 464 def : Pat<(SPhi tglobaladdr:$in), (SETHIi tglobaladdr:$in)>;
 465 def : Pat<(SPlo tglobaladdr:$in), (ORXri (i64 G0), tglobaladdr:$in)>;
 466 def : Pat<(SPhi tconstpool:$in), (SETHIi tconstpool:$in)>;
 467 def : Pat<(SPlo tconstpool:$in), (ORXri (i64 G0), tconstpool:$in)>;
 468
 469 // GlobalTLS addresses
 470 def : Pat<(SPhi tglobaltlsaddr:$in), (SETHIi tglobaltlsaddr:$in)>;
 471 def : Pat<(SPlo tglobaltlsaddr:$in), (ORXri (i64 G0), tglobaltlsaddr:$in)>;
 472 def : Pat<(add (SPhi tglobaltlsaddr:$in1), (SPlo tglobaltlsaddr:$in2)),
 473           (ADDXri (SETHIXi tglobaltlsaddr:$in1), (tglobaltlsaddr:$in2))>;
 474 def : Pat<(xor (SPhi tglobaltlsaddr:$in1), (SPlo tglobaltlsaddr:$in2)),
 475           (XORXri  (SETHIXi tglobaltlsaddr:$in1), (tglobaltlsaddr:$in2))>;
 476
 477 // Blockaddress
 478 def : Pat<(SPhi tblockaddress:$in), (SETHIi tblockaddress:$in)>;
 479 def : Pat<(SPlo tblockaddress:$in), (ORXri (i64 G0), tblockaddress:$in)>;
 480
 481 // Add reg, lo.  This is used when taking the addr of a global/constpool entry.
 482 def : Pat<(add iPTR:$r, (SPlo tglobaladdr:$in)), (ADDXri $r, tglobaladdr:$in)>;
 483 def : Pat<(add iPTR:$r, (SPlo tconstpool:$in)),  (ADDXri $r, tconstpool:$in)>;
 484 def : Pat<(add iPTR:$r, (SPlo tblockaddress:$in)),
 485                         (ADDXri $r, tblockaddress:$in)>;
 486 }