lib/Target/R600/CaymanInstructions.td

   1 //===-- CaymanInstructions.td - CM Instruction defs  -------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // TableGen definitions for instructions which are available only on Cayman
  11 // family GPUs.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 def isCayman : Predicate<"Subtarget.hasCaymanISA()">;
  16
  17 //===----------------------------------------------------------------------===//
  18 // Cayman Instructions
  19 //===----------------------------------------------------------------------===//
  20
  21 let Predicates = [isCayman] in {
  22
  23 def MULADD_INT24_cm : R600_3OP <0x08, "MULADD_INT24",
  24   [(set i32:$dst, (AMDGPUmad_i24 i32:$src0, i32:$src1, i32:$src2))], VecALU
  25 >;
  26 def MUL_INT24_cm : R600_2OP <0x5B, "MUL_INT24",
  27   [(set i32:$dst, (AMDGPUmul_i24 i32:$src0, i32:$src1))], VecALU
  28 >;
  29
  30 def : IMad24Pat<MULADD_INT24_cm>;
  31
  32 let isVector = 1 in {
  33
  34 def RECIP_IEEE_cm : RECIP_IEEE_Common<0x86>;
  35
  36 def MULLO_INT_cm : MULLO_INT_Common<0x8F>;
  37 def MULHI_INT_cm : MULHI_INT_Common<0x90>;
  38 def MULLO_UINT_cm : MULLO_UINT_Common<0x91>;
  39 def MULHI_UINT_cm : MULHI_UINT_Common<0x92>;
  40 def RECIPSQRT_CLAMPED_cm : RECIPSQRT_CLAMPED_Common<0x87>;
  41 def EXP_IEEE_cm : EXP_IEEE_Common<0x81>;
  42 def LOG_IEEE_cm : LOG_IEEE_Common<0x83>;
  43 def RECIP_CLAMPED_cm : RECIP_CLAMPED_Common<0x84>;
  44 def RECIPSQRT_IEEE_cm : RECIPSQRT_IEEE_Common<0x89>;
  45 def SIN_cm : SIN_Common<0x8D>;
  46 def COS_cm : COS_Common<0x8E>;
  47 } // End isVector = 1
  48
  49 def : POW_Common <LOG_IEEE_cm, EXP_IEEE_cm, MUL>;
  50
  51 defm DIV_cm : DIV_Common<RECIP_IEEE_cm>;
  52
  53 // RECIP_UINT emulation for Cayman
  54 // The multiplication scales from [0,1] to the unsigned integer range
  55 def : Pat <
  56   (AMDGPUurecip i32:$src0),
  57   (FLT_TO_UINT_eg (MUL_IEEE (RECIP_IEEE_cm (UINT_TO_FLT_eg $src0)),
  58                             (MOV_IMM_I32 CONST.FP_UINT_MAX_PLUS_1)))
  59 >;
  60
  61   def CF_END_CM : CF_CLAUSE_EG<32, (ins), "CF_END"> {
  62     let ADDR = 0;
  63     let POP_COUNT = 0;
  64     let COUNT = 0;
  65   }
  66
  67
  68 def : Pat<(fsqrt f32:$src), (MUL R600_Reg32:$src, (RECIPSQRT_CLAMPED_cm $src))>;
  69
  70 class RAT_STORE_DWORD <RegisterClass rc, ValueType vt, bits<4> mask> :
  71   CF_MEM_RAT_CACHELESS <0x14, 0, mask,
  72                         (ins rc:$rw_gpr, R600_TReg32_X:$index_gpr),
  73                         "STORE_DWORD $rw_gpr, $index_gpr",
  74                         [(global_store vt:$rw_gpr, i32:$index_gpr)]> {
  75   let eop = 0; // This bit is not used on Cayman.
  76 }
  77
  78 def RAT_STORE_DWORD32 : RAT_STORE_DWORD <R600_TReg32_X, i32, 0x1>;
  79 def RAT_STORE_DWORD64 : RAT_STORE_DWORD <R600_Reg64, v2i32, 0x3>;
  80 def RAT_STORE_DWORD128 : RAT_STORE_DWORD <R600_Reg128, v4i32, 0xf>;
  81
  82 class VTX_READ_cm <string name, bits<8> buffer_id, dag outs, list<dag> pattern>
  83     : VTX_WORD0_cm, VTX_READ<name, buffer_id, outs, pattern> {
  84
  85   // Static fields
  86   let VC_INST = 0;
  87   let FETCH_TYPE = 2;
  88   let FETCH_WHOLE_QUAD = 0;
  89   let BUFFER_ID = buffer_id;
  90   let SRC_REL = 0;
  91   // XXX: We can infer this field based on the SRC_GPR.  This would allow us
  92   // to store vertex addresses in any channel, not just X.
  93   let SRC_SEL_X = 0;
  94   let SRC_SEL_Y = 0;
  95   let STRUCTURED_READ = 0;
  96   let LDS_REQ = 0;
  97   let COALESCED_READ = 0;
  98
  99   let Inst{31-0} = Word0;
 100 }
 101
 102 class VTX_READ_8_cm <bits<8> buffer_id, list<dag> pattern>
 103     : VTX_READ_cm <"VTX_READ_8 $dst_gpr, $src_gpr", buffer_id,
 104                    (outs R600_TReg32_X:$dst_gpr), pattern> {
 105
 106   let DST_SEL_X = 0;
 107   let DST_SEL_Y = 7;   // Masked
 108   let DST_SEL_Z = 7;   // Masked
 109   let DST_SEL_W = 7;   // Masked
 110   let DATA_FORMAT = 1; // FMT_8
 111 }
 112
 113 class VTX_READ_16_cm <bits<8> buffer_id, list<dag> pattern>
 114     : VTX_READ_cm <"VTX_READ_16 $dst_gpr, $src_gpr", buffer_id,
 115                    (outs R600_TReg32_X:$dst_gpr), pattern> {
 116   let DST_SEL_X = 0;
 117   let DST_SEL_Y = 7;   // Masked
 118   let DST_SEL_Z = 7;   // Masked
 119   let DST_SEL_W = 7;   // Masked
 120   let DATA_FORMAT = 5; // FMT_16
 121
 122 }
 123
 124 class VTX_READ_32_cm <bits<8> buffer_id, list<dag> pattern>
 125     : VTX_READ_cm <"VTX_READ_32 $dst_gpr, $src_gpr", buffer_id,
 126                    (outs R600_TReg32_X:$dst_gpr), pattern> {
 127
 128   let DST_SEL_X        = 0;
 129   let DST_SEL_Y        = 7;   // Masked
 130   let DST_SEL_Z        = 7;   // Masked
 131   let DST_SEL_W        = 7;   // Masked
 132   let DATA_FORMAT      = 0xD; // COLOR_32
 133
 134   // This is not really necessary, but there were some GPU hangs that appeared
 135   // to be caused by ALU instructions in the next instruction group that wrote
 136   // to the $src_gpr registers of the VTX_READ.
 137   // e.g.
 138   // %T3_X<def> = VTX_READ_PARAM_32_eg %T2_X<kill>, 24
 139   // %T2_X<def> = MOV %ZERO
 140   //Adding this constraint prevents this from happening.
 141   let Constraints = "$src_gpr.ptr = $dst_gpr";
 142 }
 143
 144 class VTX_READ_64_cm <bits<8> buffer_id, list<dag> pattern>
 145     : VTX_READ_cm <"VTX_READ_64 $dst_gpr, $src_gpr", buffer_id,
 146                    (outs R600_Reg64:$dst_gpr), pattern> {
 147
 148   let DST_SEL_X        = 0;
 149   let DST_SEL_Y        = 1;
 150   let DST_SEL_Z        = 7;
 151   let DST_SEL_W        = 7;
 152   let DATA_FORMAT      = 0x1D; // COLOR_32_32
 153 }
 154
 155 class VTX_READ_128_cm <bits<8> buffer_id, list<dag> pattern>
 156     : VTX_READ_cm <"VTX_READ_128 $dst_gpr.XYZW, $src_gpr", buffer_id,
 157                    (outs R600_Reg128:$dst_gpr), pattern> {
 158
 159   let DST_SEL_X        =  0;
 160   let DST_SEL_Y        =  1;
 161   let DST_SEL_Z        =  2;
 162   let DST_SEL_W        =  3;
 163   let DATA_FORMAT      =  0x22; // COLOR_32_32_32_32
 164
 165   // XXX: Need to force VTX_READ_128 instructions to write to the same register
 166   // that holds its buffer address to avoid potential hangs.  We can't use
 167   // the same constraint as VTX_READ_32_eg, because the $src_gpr.ptr and $dst
 168   // registers are different sizes.
 169 }
 170
 171 //===----------------------------------------------------------------------===//
 172 // VTX Read from parameter memory space
 173 //===----------------------------------------------------------------------===//
 174 def VTX_READ_PARAM_8_cm : VTX_READ_8_cm <0,
 175   [(set i32:$dst_gpr, (load_param_exti8 ADDRVTX_READ:$src_gpr))]
 176 >;
 177
 178 def VTX_READ_PARAM_16_cm : VTX_READ_16_cm <0,
 179   [(set i32:$dst_gpr, (load_param_exti16 ADDRVTX_READ:$src_gpr))]
 180 >;
 181
 182 def VTX_READ_PARAM_32_cm : VTX_READ_32_cm <0,
 183   [(set i32:$dst_gpr, (load_param ADDRVTX_READ:$src_gpr))]
 184 >;
 185
 186 def VTX_READ_PARAM_64_cm : VTX_READ_64_cm <0,
 187   [(set v2i32:$dst_gpr, (load_param ADDRVTX_READ:$src_gpr))]
 188 >;
 189
 190 def VTX_READ_PARAM_128_cm : VTX_READ_128_cm <0,
 191   [(set v4i32:$dst_gpr, (load_param ADDRVTX_READ:$src_gpr))]
 192 >;
 193
 194 //===----------------------------------------------------------------------===//
 195 // VTX Read from global memory space
 196 //===----------------------------------------------------------------------===//
 197
 198 // 8-bit reads
 199 def VTX_READ_GLOBAL_8_cm : VTX_READ_8_cm <1,
 200   [(set i32:$dst_gpr, (az_extloadi8_global ADDRVTX_READ:$src_gpr))]
 201 >;
 202
 203 def VTX_READ_GLOBAL_16_cm : VTX_READ_16_cm <1,
 204   [(set i32:$dst_gpr, (az_extloadi16_global ADDRVTX_READ:$src_gpr))]
 205 >;
 206
 207 // 32-bit reads
 208 def VTX_READ_GLOBAL_32_cm : VTX_READ_32_cm <1,
 209   [(set i32:$dst_gpr, (global_load ADDRVTX_READ:$src_gpr))]
 210 >;
 211
 212 // 64-bit reads
 213 def VTX_READ_GLOBAL_64_cm : VTX_READ_64_cm <1,
 214   [(set v2i32:$dst_gpr, (global_load ADDRVTX_READ:$src_gpr))]
 215 >;
 216
 217 // 128-bit reads
 218 def VTX_READ_GLOBAL_128_cm : VTX_READ_128_cm <1,
 219   [(set v4i32:$dst_gpr, (global_load ADDRVTX_READ:$src_gpr))]
 220 >;
 221
 222 } // End isCayman
 223