lib/Target/R600/AMDGPUInstructions.td

   1 //===-- AMDGPUInstructions.td - Common instruction defs ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file contains instruction defs that are common to all hw codegen
  11 // targets.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 class AMDGPUInst <dag outs, dag ins, string asm, list<dag> pattern> : Instruction {
  16   field bit isRegisterLoad = 0;
  17   field bit isRegisterStore = 0;
  18
  19   let Namespace = "AMDGPU";
  20   let OutOperandList = outs;
  21   let InOperandList = ins;
  22   let AsmString = asm;
  23   let Pattern = pattern;
  24   let Itinerary = NullALU;
  25
  26   let TSFlags{63} = isRegisterLoad;
  27   let TSFlags{62} = isRegisterStore;
  28 }
  29
  30 class AMDGPUShaderInst <dag outs, dag ins, string asm, list<dag> pattern>
  31     : AMDGPUInst<outs, ins, asm, pattern> {
  32
  33   field bits<32> Inst = 0xffffffff;
  34
  35 }
  36
  37 def InstFlag : OperandWithDefaultOps <i32, (ops (i32 0))>;
  38 def ADDRIndirect : ComplexPattern<iPTR, 2, "SelectADDRIndirect", [], []>;
  39
  40 def u32imm : Operand<i32> {
  41   let PrintMethod = "printU32ImmOperand";
  42 }
  43
  44 def u16imm : Operand<i16> {
  45   let PrintMethod = "printU16ImmOperand";
  46 }
  47
  48 def u8imm : Operand<i8> {
  49   let PrintMethod = "printU8ImmOperand";
  50 }
  51
  52 //===----------------------------------------------------------------------===//
  53 // PatLeafs for floating-point comparisons
  54 //===----------------------------------------------------------------------===//
  55
  56 def COND_OEQ : PatLeaf <
  57   (cond),
  58   [{return N->get() == ISD::SETOEQ || N->get() == ISD::SETEQ;}]
  59 >;
  60
  61 def COND_OGT : PatLeaf <
  62   (cond),
  63   [{return N->get() == ISD::SETOGT || N->get() == ISD::SETGT;}]
  64 >;
  65
  66 def COND_OGE : PatLeaf <
  67   (cond),
  68   [{return N->get() == ISD::SETOGE || N->get() == ISD::SETGE;}]
  69 >;
  70
  71 def COND_OLT : PatLeaf <
  72   (cond),
  73   [{return N->get() == ISD::SETOLT || N->get() == ISD::SETLT;}]
  74 >;
  75
  76 def COND_OLE : PatLeaf <
  77   (cond),
  78   [{return N->get() == ISD::SETOLE || N->get() == ISD::SETLE;}]
  79 >;
  80
  81 def COND_UNE : PatLeaf <
  82   (cond),
  83   [{return N->get() == ISD::SETUNE || N->get() == ISD::SETNE;}]
  84 >;
  85
  86 def COND_O : PatLeaf <(cond), [{return N->get() == ISD::SETO;}]>;
  87 def COND_UO : PatLeaf <(cond), [{return N->get() == ISD::SETUO;}]>;
  88
  89 //===----------------------------------------------------------------------===//
  90 // PatLeafs for unsigned comparisons
  91 //===----------------------------------------------------------------------===//
  92
  93 def COND_UGT : PatLeaf <(cond), [{return N->get() == ISD::SETUGT;}]>;
  94 def COND_UGE : PatLeaf <(cond), [{return N->get() == ISD::SETUGE;}]>;
  95 def COND_ULT : PatLeaf <(cond), [{return N->get() == ISD::SETULT;}]>;
  96 def COND_ULE : PatLeaf <(cond), [{return N->get() == ISD::SETULE;}]>;
  97
  98 //===----------------------------------------------------------------------===//
  99 // PatLeafs for signed comparisons
 100 //===----------------------------------------------------------------------===//
 101
 102 def COND_SGT : PatLeaf <(cond), [{return N->get() == ISD::SETGT;}]>;
 103 def COND_SGE : PatLeaf <(cond), [{return N->get() == ISD::SETGE;}]>;
 104 def COND_SLT : PatLeaf <(cond), [{return N->get() == ISD::SETLT;}]>;
 105 def COND_SLE : PatLeaf <(cond), [{return N->get() == ISD::SETLE;}]>;
 106
 107 //===----------------------------------------------------------------------===//
 108 // PatLeafs for integer equality
 109 //===----------------------------------------------------------------------===//
 110
 111 def COND_EQ : PatLeaf <
 112   (cond),
 113   [{return N->get() == ISD::SETEQ || N->get() == ISD::SETUEQ;}]
 114 >;
 115
 116 def COND_NE : PatLeaf <
 117   (cond),
 118   [{return N->get() == ISD::SETNE || N->get() == ISD::SETUNE;}]
 119 >;
 120
 121 def COND_NULL : PatLeaf <
 122   (cond),
 123   [{return false;}]
 124 >;
 125
 126 //===----------------------------------------------------------------------===//
 127 // Load/Store Pattern Fragments
 128 //===----------------------------------------------------------------------===//
 129
 130 def az_extload : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 131   LoadSDNode *L = cast<LoadSDNode>(N);
 132   return L->getExtensionType() == ISD::ZEXTLOAD ||
 133          L->getExtensionType() == ISD::EXTLOAD;
 134 }]>;
 135
 136 def az_extloadi8 : PatFrag<(ops node:$ptr), (az_extload node:$ptr), [{
 137   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
 138 }]>;
 139
 140 def az_extloadi8_global : PatFrag<(ops node:$ptr), (az_extloadi8 node:$ptr), [{
 141     return isGlobalLoad(dyn_cast<LoadSDNode>(N));
 142 }]>;
 143
 144 def sextloadi8_global : PatFrag<(ops node:$ptr), (sextloadi8 node:$ptr), [{
 145     return isGlobalLoad(dyn_cast<LoadSDNode>(N));
 146 }]>;
 147
 148 def az_extloadi8_constant : PatFrag<(ops node:$ptr), (az_extloadi8 node:$ptr), [{
 149     return isConstantLoad(dyn_cast<LoadSDNode>(N), -1);
 150 }]>;
 151
 152 def sextloadi8_constant : PatFrag<(ops node:$ptr), (sextloadi8 node:$ptr), [{
 153     return isConstantLoad(dyn_cast<LoadSDNode>(N), -1);
 154 }]>;
 155
 156 def az_extloadi8_local : PatFrag<(ops node:$ptr), (az_extloadi8 node:$ptr), [{
 157     return isLocalLoad(dyn_cast<LoadSDNode>(N));
 158 }]>;
 159
 160 def sextloadi8_local : PatFrag<(ops node:$ptr), (sextloadi8 node:$ptr), [{
 161     return isLocalLoad(dyn_cast<LoadSDNode>(N));
 162 }]>;
 163
 164 def az_extloadi16 : PatFrag<(ops node:$ptr), (az_extload node:$ptr), [{
 165   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
 166 }]>;
 167
 168 def az_extloadi16_global : PatFrag<(ops node:$ptr), (az_extloadi16 node:$ptr), [{
 169     return isGlobalLoad(dyn_cast<LoadSDNode>(N));
 170 }]>;
 171
 172 def sextloadi16_global : PatFrag<(ops node:$ptr), (sextloadi16 node:$ptr), [{
 173     return isGlobalLoad(dyn_cast<LoadSDNode>(N));
 174 }]>;
 175
 176 def az_extloadi16_constant : PatFrag<(ops node:$ptr), (az_extloadi16 node:$ptr), [{
 177     return isConstantLoad(dyn_cast<LoadSDNode>(N), -1);
 178 }]>;
 179
 180 def sextloadi16_constant : PatFrag<(ops node:$ptr), (sextloadi16 node:$ptr), [{
 181     return isConstantLoad(dyn_cast<LoadSDNode>(N), -1);
 182 }]>;
 183
 184 def az_extloadi16_local : PatFrag<(ops node:$ptr), (az_extloadi16 node:$ptr), [{
 185     return isLocalLoad(dyn_cast<LoadSDNode>(N));
 186 }]>;
 187
 188 def sextloadi16_local : PatFrag<(ops node:$ptr), (sextloadi16 node:$ptr), [{
 189     return isLocalLoad(dyn_cast<LoadSDNode>(N));
 190 }]>;
 191
 192 def az_extloadi32 : PatFrag<(ops node:$ptr), (az_extload node:$ptr), [{
 193   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
 194 }]>;
 195
 196 def az_extloadi32_global : PatFrag<(ops node:$ptr),
 197                                    (az_extloadi32 node:$ptr), [{
 198   return isGlobalLoad(dyn_cast<LoadSDNode>(N));
 199 }]>;
 200
 201 def az_extloadi32_constant : PatFrag<(ops node:$ptr),
 202                                      (az_extloadi32 node:$ptr), [{
 203   return isConstantLoad(dyn_cast<LoadSDNode>(N), -1);
 204 }]>;
 205
 206 def truncstorei8_global : PatFrag<(ops node:$val, node:$ptr),
 207                                   (truncstorei8 node:$val, node:$ptr), [{
 208   return isGlobalStore(dyn_cast<StoreSDNode>(N));
 209 }]>;
 210
 211 def truncstorei16_global : PatFrag<(ops node:$val, node:$ptr),
 212                                   (truncstorei16 node:$val, node:$ptr), [{
 213   return isGlobalStore(dyn_cast<StoreSDNode>(N));
 214 }]>;
 215
 216 def local_store : PatFrag<(ops node:$val, node:$ptr),
 217                              (store node:$val, node:$ptr), [{
 218   return isLocalStore(dyn_cast<StoreSDNode>(N));
 219 }]>;
 220
 221 def truncstorei8_local : PatFrag<(ops node:$val, node:$ptr),
 222                                   (truncstorei8 node:$val, node:$ptr), [{
 223   return isLocalStore(dyn_cast<StoreSDNode>(N));
 224 }]>;
 225
 226 def truncstorei16_local : PatFrag<(ops node:$val, node:$ptr),
 227                                   (truncstorei16 node:$val, node:$ptr), [{
 228   return isLocalStore(dyn_cast<StoreSDNode>(N));
 229 }]>;
 230
 231 def local_load : PatFrag<(ops node:$ptr), (load node:$ptr), [{
 232     return isLocalLoad(dyn_cast<LoadSDNode>(N));
 233 }]>;
 234
 235
 236 class local_binary_atomic_op<SDNode atomic_op> :
 237   PatFrag<(ops node:$ptr, node:$value),
 238     (atomic_op node:$ptr, node:$value), [{
 239   return cast<MemSDNode>(N)->getAddressSpace() == AMDGPUAS::LOCAL_ADDRESS;
 240 }]>;
 241
 242
 243 def atomic_swap_local : local_binary_atomic_op<atomic_swap>;
 244 def atomic_load_add_local : local_binary_atomic_op<atomic_load_add>;
 245 def atomic_load_sub_local : local_binary_atomic_op<atomic_load_sub>;
 246 def atomic_load_and_local : local_binary_atomic_op<atomic_load_and>;
 247 def atomic_load_or_local : local_binary_atomic_op<atomic_load_or>;
 248 def atomic_load_xor_local : local_binary_atomic_op<atomic_load_xor>;
 249 def atomic_load_nand_local : local_binary_atomic_op<atomic_load_nand>;
 250 def atomic_load_min_local : local_binary_atomic_op<atomic_load_min>;
 251 def atomic_load_max_local : local_binary_atomic_op<atomic_load_max>;
 252 def atomic_load_umin_local : local_binary_atomic_op<atomic_load_umin>;
 253 def atomic_load_umax_local : local_binary_atomic_op<atomic_load_umax>;
 254
 255 def mskor_global : PatFrag<(ops node:$val, node:$ptr),
 256                             (AMDGPUstore_mskor node:$val, node:$ptr), [{
 257   return dyn_cast<MemSDNode>(N)->getAddressSpace() == AMDGPUAS::GLOBAL_ADDRESS;
 258 }]>;
 259
 260 def atomic_cmp_swap_32_local :
 261   PatFrag<(ops node:$ptr, node:$cmp, node:$swap),
 262           (atomic_cmp_swap node:$ptr, node:$cmp, node:$swap), [{
 263   AtomicSDNode *AN = cast<AtomicSDNode>(N);
 264   return AN->getMemoryVT() == MVT::i32 &&
 265          AN->getAddressSpace() == AMDGPUAS::LOCAL_ADDRESS;
 266 }]>;
 267
 268
 269 class Constants {
 270 int TWO_PI = 0x40c90fdb;
 271 int PI = 0x40490fdb;
 272 int TWO_PI_INV = 0x3e22f983;
 273 int FP_UINT_MAX_PLUS_1 = 0x4f800000;    // 1 << 32 in floating point encoding
 274 int FP32_NEG_ONE = 0xbf800000;
 275 int FP32_ONE = 0x3f800000;
 276 }
 277 def CONST : Constants;
 278
 279 def FP_ZERO : PatLeaf <
 280   (fpimm),
 281   [{return N->getValueAPF().isZero();}]
 282 >;
 283
 284 def FP_ONE : PatLeaf <
 285   (fpimm),
 286   [{return N->isExactlyValue(1.0);}]
 287 >;
 288
 289 let isCodeGenOnly = 1, isPseudo = 1 in {
 290
 291 let usesCustomInserter = 1  in {
 292
 293 class CLAMP <RegisterClass rc> : AMDGPUShaderInst <
 294   (outs rc:$dst),
 295   (ins rc:$src0),
 296   "CLAMP $dst, $src0",
 297   [(set f32:$dst, (int_AMDIL_clamp f32:$src0, (f32 FP_ZERO), (f32 FP_ONE)))]
 298 >;
 299
 300 class FABS <RegisterClass rc> : AMDGPUShaderInst <
 301   (outs rc:$dst),
 302   (ins rc:$src0),
 303   "FABS $dst, $src0",
 304   [(set f32:$dst, (fabs f32:$src0))]
 305 >;
 306
 307 class FNEG <RegisterClass rc> : AMDGPUShaderInst <
 308   (outs rc:$dst),
 309   (ins rc:$src0),
 310   "FNEG $dst, $src0",
 311   [(set f32:$dst, (fneg f32:$src0))]
 312 >;
 313
 314 } // usesCustomInserter = 1
 315
 316 multiclass RegisterLoadStore <RegisterClass dstClass, Operand addrClass,
 317                     ComplexPattern addrPat> {
 318 let UseNamedOperandTable = 1 in {
 319
 320   def RegisterLoad : AMDGPUShaderInst <
 321     (outs dstClass:$dst),
 322     (ins addrClass:$addr, i32imm:$chan),
 323     "RegisterLoad $dst, $addr",
 324     [(set i32:$dst, (AMDGPUregister_load addrPat:$addr, (i32 timm:$chan)))]
 325   > {
 326     let isRegisterLoad = 1;
 327   }
 328
 329   def RegisterStore : AMDGPUShaderInst <
 330     (outs),
 331     (ins dstClass:$val, addrClass:$addr, i32imm:$chan),
 332     "RegisterStore $val, $addr",
 333     [(AMDGPUregister_store i32:$val, addrPat:$addr, (i32 timm:$chan))]
 334   > {
 335     let isRegisterStore = 1;
 336   }
 337 }
 338 }
 339
 340 } // End isCodeGenOnly = 1, isPseudo = 1
 341
 342 /* Generic helper patterns for intrinsics */
 343 /* -------------------------------------- */
 344
 345 class POW_Common <AMDGPUInst log_ieee, AMDGPUInst exp_ieee, AMDGPUInst mul>
 346   : Pat <
 347   (fpow f32:$src0, f32:$src1),
 348   (exp_ieee (mul f32:$src1, (log_ieee f32:$src0)))
 349 >;
 350
 351 /* Other helper patterns */
 352 /* --------------------- */
 353
 354 /* Extract element pattern */
 355 class Extract_Element <ValueType sub_type, ValueType vec_type, int sub_idx,
 356                        SubRegIndex sub_reg>
 357   : Pat<
 358   (sub_type (vector_extract vec_type:$src, sub_idx)),
 359   (EXTRACT_SUBREG $src, sub_reg)
 360 >;
 361
 362 /* Insert element pattern */
 363 class Insert_Element <ValueType elem_type, ValueType vec_type,
 364                       int sub_idx, SubRegIndex sub_reg>
 365   : Pat <
 366   (vector_insert vec_type:$vec, elem_type:$elem, sub_idx),
 367   (INSERT_SUBREG $vec, $elem, sub_reg)
 368 >;
 369
 370 // XXX: Convert to new syntax and use COPY_TO_REG, once the DFAPacketizer
 371 // can handle COPY instructions.
 372 // bitconvert pattern
 373 class BitConvert <ValueType dt, ValueType st, RegisterClass rc> : Pat <
 374   (dt (bitconvert (st rc:$src0))),
 375   (dt rc:$src0)
 376 >;
 377
 378 // XXX: Convert to new syntax and use COPY_TO_REG, once the DFAPacketizer
 379 // can handle COPY instructions.
 380 class DwordAddrPat<ValueType vt, RegisterClass rc> : Pat <
 381   (vt (AMDGPUdwordaddr (vt rc:$addr))),
 382   (vt rc:$addr)
 383 >;
 384
 385 // BFI_INT patterns
 386
 387 multiclass BFIPatterns <Instruction BFI_INT, Instruction LoadImm32> {
 388
 389   // Definition from ISA doc:
 390   // (y & x) | (z & ~x)
 391   def : Pat <
 392     (or (and i32:$y, i32:$x), (and i32:$z, (not i32:$x))),
 393     (BFI_INT $x, $y, $z)
 394   >;
 395
 396   // SHA-256 Ch function
 397   // z ^ (x & (y ^ z))
 398   def : Pat <
 399     (xor i32:$z, (and i32:$x, (xor i32:$y, i32:$z))),
 400     (BFI_INT $x, $y, $z)
 401   >;
 402
 403   def : Pat <
 404     (fcopysign f32:$src0, f32:$src1),
 405     (BFI_INT (LoadImm32 0x7fffffff), $src0, $src1)
 406   >;
 407
 408   def : Pat <
 409     (f64 (fcopysign f64:$src0, f64:$src1)),
 410       (INSERT_SUBREG (INSERT_SUBREG (f64 (IMPLICIT_DEF)),
 411       (i32 (EXTRACT_SUBREG $src0, sub0)), sub0),
 412       (BFI_INT (LoadImm32 0x7fffffff),
 413                (i32 (EXTRACT_SUBREG $src0, sub1)),
 414                (i32 (EXTRACT_SUBREG $src1, sub1))), sub1)
 415   >;
 416 }
 417
 418 // SHA-256 Ma patterns
 419
 420 // ((x & z) | (y & (x | z))) -> BFI_INT (XOR x, y), z, y
 421 class SHA256MaPattern <Instruction BFI_INT, Instruction XOR> : Pat <
 422   (or (and i32:$x, i32:$z), (and i32:$y, (or i32:$x, i32:$z))),
 423   (BFI_INT (XOR i32:$x, i32:$y), i32:$z, i32:$y)
 424 >;
 425
 426 // Bitfield extract patterns
 427
 428 /*
 429
 430 XXX: The BFE pattern is not working correctly because the XForm is not being
 431 applied.
 432
 433 def legalshift32 : ImmLeaf <i32, [{return Imm >=0 && Imm < 32;}]>;
 434 def bfemask : PatLeaf <(imm), [{return isMask_32(N->getZExtValue());}],
 435                             SDNodeXForm<imm, [{ return CurDAG->getTargetConstant(CountTrailingOnes_32(N->getZExtValue()), MVT::i32);}]>>;
 436
 437 class BFEPattern <Instruction BFE> : Pat <
 438   (and (srl i32:$x, legalshift32:$y), bfemask:$z),
 439   (BFE $x, $y, $z)
 440 >;
 441
 442 */
 443
 444 // rotr pattern
 445 class ROTRPattern <Instruction BIT_ALIGN> : Pat <
 446   (rotr i32:$src0, i32:$src1),
 447   (BIT_ALIGN $src0, $src0, $src1)
 448 >;
 449
 450 // 24-bit arithmetic patterns
 451 def umul24 : PatFrag <(ops node:$x, node:$y), (mul node:$x, node:$y)>;
 452
 453 /*
 454 class UMUL24Pattern <Instruction UMUL24> : Pat <
 455   (mul U24:$x, U24:$y),
 456   (UMUL24 $x, $y)
 457 >;
 458 */
 459
 460 class IMad24Pat<Instruction Inst> : Pat <
 461   (add (AMDGPUmul_i24 i32:$src0, i32:$src1), i32:$src2),
 462   (Inst $src0, $src1, $src2)
 463 >;
 464
 465 class UMad24Pat<Instruction Inst> : Pat <
 466   (add (AMDGPUmul_u24 i32:$src0, i32:$src1), i32:$src2),
 467   (Inst $src0, $src1, $src2)
 468 >;
 469
 470 multiclass Expand24IBitOps<Instruction MulInst, Instruction AddInst> {
 471   def _expand_imad24 : Pat <
 472     (AMDGPUmad_i24 i32:$src0, i32:$src1, i32:$src2),
 473     (AddInst (MulInst $src0, $src1), $src2)
 474   >;
 475
 476   def _expand_imul24 : Pat <
 477     (AMDGPUmul_i24 i32:$src0, i32:$src1),
 478     (MulInst $src0, $src1)
 479   >;
 480 }
 481
 482 multiclass Expand24UBitOps<Instruction MulInst, Instruction AddInst> {
 483   def _expand_umad24 : Pat <
 484     (AMDGPUmad_u24 i32:$src0, i32:$src1, i32:$src2),
 485     (AddInst (MulInst $src0, $src1), $src2)
 486   >;
 487
 488   def _expand_umul24 : Pat <
 489     (AMDGPUmul_u24 i32:$src0, i32:$src1),
 490     (MulInst $src0, $src1)
 491   >;
 492 }
 493
 494 include "R600Instructions.td"
 495 include "R700Instructions.td"
 496 include "EvergreenInstructions.td"
 497 include "CaymanInstructions.td"
 498
 499 include "SIInstrInfo.td"
 500