lib/Target/PowerPC/PPCInstrInfo.td

   1 //===- PPCInstrInfo.td - The PowerPC Instruction Set -------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the subset of the 32-bit PowerPC instruction set, as used
  11 // by the PowerPC instruction selector.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 include "PPCInstrFormats.td"
  16
  17 //===----------------------------------------------------------------------===//
  18 // PowerPC specific type constraints.
  19 //
  20 def SDT_PPCstfiwx : SDTypeProfile<0, 2, [ // stfiwx
  21   SDTCisVT<0, f64>, SDTCisPtrTy<1>
  22 ]>;
  23 def SDT_PPCShiftOp : SDTypeProfile<1, 2, [   // PPCshl, PPCsra, PPCsrl
  24   SDTCisVT<0, i32>, SDTCisVT<1, i32>, SDTCisVT<2, i32>
  25 ]>;
  26 def SDT_PPCCallSeq : SDTypeProfile<0, 1, [ SDTCisVT<0, i32> ]>;
  27
  28 def SDT_PPCvperm   : SDTypeProfile<1, 3, [
  29   SDTCisVT<3, v16i8>, SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>
  30 ]>;
  31
  32 def SDT_PPCvcmp : SDTypeProfile<1, 3, [
  33   SDTCisSameAs<0, 1>, SDTCisSameAs<1, 2>, SDTCisVT<3, i32>
  34 ]>;
  35
  36 def SDT_PPCcondbr : SDTypeProfile<0, 3, [
  37   SDTCisVT<1, i32>, SDTCisVT<2, OtherVT>
  38 ]>;
  39
  40 //===----------------------------------------------------------------------===//
  41 // PowerPC specific DAG Nodes.
  42 //
  43
  44 def PPCfcfid  : SDNode<"PPCISD::FCFID" , SDTFPUnaryOp, []>;
  45 def PPCfctidz : SDNode<"PPCISD::FCTIDZ", SDTFPUnaryOp, []>;
  46 def PPCfctiwz : SDNode<"PPCISD::FCTIWZ", SDTFPUnaryOp, []>;
  47 def PPCstfiwx : SDNode<"PPCISD::STFIWX", SDT_PPCstfiwx, [SDNPHasChain]>;
  48
  49 def PPCfsel   : SDNode<"PPCISD::FSEL",
  50    // Type constraint for fsel.
  51    SDTypeProfile<1, 3, [SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>,
  52                         SDTCisFP<0>, SDTCisVT<1, f64>]>, []>;
  53
  54 def PPChi       : SDNode<"PPCISD::Hi", SDTIntBinOp, []>;
  55 def PPClo       : SDNode<"PPCISD::Lo", SDTIntBinOp, []>;
  56 def PPCvmaddfp  : SDNode<"PPCISD::VMADDFP", SDTFPTernaryOp, []>;
  57 def PPCvnmsubfp : SDNode<"PPCISD::VNMSUBFP", SDTFPTernaryOp, []>;
  58
  59 def PPCvperm    : SDNode<"PPCISD::VPERM", SDT_PPCvperm, []>;
  60
  61 // These nodes represent the 32-bit PPC shifts that operate on 6-bit shift
  62 // amounts.  These nodes are generated by the multi-precision shift code.
  63 def PPCsrl        : SDNode<"PPCISD::SRL"       , SDT_PPCShiftOp>;
  64 def PPCsra        : SDNode<"PPCISD::SRA"       , SDT_PPCShiftOp>;
  65 def PPCshl        : SDNode<"PPCISD::SHL"       , SDT_PPCShiftOp>;
  66
  67 def PPCextsw_32   : SDNode<"PPCISD::EXTSW_32"  , SDTIntUnaryOp>;
  68 def PPCstd_32     : SDNode<"PPCISD::STD_32"    , SDTStore, [SDNPHasChain]>;
  69
  70 // These are target-independent nodes, but have target-specific formats.
  71 def callseq_start : SDNode<"ISD::CALLSEQ_START", SDT_PPCCallSeq,[SDNPHasChain]>;
  72 def callseq_end   : SDNode<"ISD::CALLSEQ_END",   SDT_PPCCallSeq,[SDNPHasChain]>;
  73
  74 def SDT_PPCCall   : SDTypeProfile<0, -1, [SDTCisVT<0, i32>]>;
  75 def PPCcall       : SDNode<"PPCISD::CALL", SDT_PPCCall,
  76                            [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  77 def PPCmtctr      : SDNode<"PPCISD::MTCTR", SDT_PPCCall,
  78                            [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  79 def PPCbctrl      : SDNode<"PPCISD::BCTRL", SDTRet,
  80                            [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  81
  82 def retflag       : SDNode<"PPCISD::RET_FLAG", SDTRet,
  83                            [SDNPHasChain, SDNPOptInFlag]>;
  84
  85 def PPCvcmp       : SDNode<"PPCISD::VCMP" , SDT_PPCvcmp, []>;
  86 def PPCvcmp_o     : SDNode<"PPCISD::VCMPo", SDT_PPCvcmp, [SDNPOutFlag]>;
  87
  88 def PPCcondbranch : SDNode<"PPCISD::COND_BRANCH", SDT_PPCcondbr,
  89                            [SDNPHasChain, SDNPOptInFlag]>;
  90
  91 //===----------------------------------------------------------------------===//
  92 // PowerPC specific transformation functions and pattern fragments.
  93 //
  94
  95 def SHL32 : SDNodeXForm<imm, [{
  96   // Transformation function: 31 - imm
  97   return getI32Imm(31 - N->getValue());
  98 }]>;
  99
 100 def SHL64 : SDNodeXForm<imm, [{
 101   // Transformation function: 63 - imm
 102   return getI32Imm(63 - N->getValue());
 103 }]>;
 104
 105 def SRL32 : SDNodeXForm<imm, [{
 106   // Transformation function: 32 - imm
 107   return N->getValue() ? getI32Imm(32 - N->getValue()) : getI32Imm(0);
 108 }]>;
 109
 110 def SRL64 : SDNodeXForm<imm, [{
 111   // Transformation function: 64 - imm
 112   return N->getValue() ? getI32Imm(64 - N->getValue()) : getI32Imm(0);
 113 }]>;
 114
 115 def LO16 : SDNodeXForm<imm, [{
 116   // Transformation function: get the low 16 bits.
 117   return getI32Imm((unsigned short)N->getValue());
 118 }]>;
 119
 120 def HI16 : SDNodeXForm<imm, [{
 121   // Transformation function: shift the immediate value down into the low bits.
 122   return getI32Imm((unsigned)N->getValue() >> 16);
 123 }]>;
 124
 125 def HA16 : SDNodeXForm<imm, [{
 126   // Transformation function: shift the immediate value down into the low bits.
 127   signed int Val = N->getValue();
 128   return getI32Imm((Val - (signed short)Val) >> 16);
 129 }]>;
 130
 131
 132 def immSExt16  : PatLeaf<(imm), [{
 133   // immSExt16 predicate - True if the immediate fits in a 16-bit sign extended
 134   // field.  Used by instructions like 'addi'.
 135   return (int)N->getValue() == (short)N->getValue();
 136 }]>;
 137 def immZExt16  : PatLeaf<(imm), [{
 138   // immZExt16 predicate - True if the immediate fits in a 16-bit zero extended
 139   // field.  Used by instructions like 'ori'.
 140   return (unsigned)N->getValue() == (unsigned short)N->getValue();
 141 }], LO16>;
 142
 143 def imm16Shifted : PatLeaf<(imm), [{
 144   // imm16Shifted predicate - True if only bits in the top 16-bits of the
 145   // immediate are set.  Used by instructions like 'addis'.
 146   return ((unsigned)N->getValue() & 0xFFFF0000U) == (unsigned)N->getValue();
 147 }], HI16>;
 148
 149
 150 //===----------------------------------------------------------------------===//
 151 // PowerPC Flag Definitions.
 152
 153 class isPPC64 { bit PPC64 = 1; }
 154 class isVMX   { bit VMX = 1; }
 155 class isDOT   {
 156   list<Register> Defs = [CR0];
 157   bit RC  = 1;
 158 }
 159
 160
 161
 162 //===----------------------------------------------------------------------===//
 163 // PowerPC Operand Definitions.
 164
 165 def s5imm   : Operand<i32> {
 166   let PrintMethod = "printS5ImmOperand";
 167 }
 168 def u5imm   : Operand<i32> {
 169   let PrintMethod = "printU5ImmOperand";
 170 }
 171 def u6imm   : Operand<i32> {
 172   let PrintMethod = "printU6ImmOperand";
 173 }
 174 def s16imm  : Operand<i32> {
 175   let PrintMethod = "printS16ImmOperand";
 176 }
 177 def u16imm  : Operand<i32> {
 178   let PrintMethod = "printU16ImmOperand";
 179 }
 180 def s16immX4  : Operand<i32> {   // Multiply imm by 4 before printing.
 181   let PrintMethod = "printS16X4ImmOperand";
 182 }
 183 def target : Operand<OtherVT> {
 184   let PrintMethod = "printBranchOperand";
 185 }
 186 def calltarget : Operand<i32> {
 187   let PrintMethod = "printCallOperand";
 188 }
 189 def aaddr : Operand<i32> {
 190   let PrintMethod = "printAbsAddrOperand";
 191 }
 192 def piclabel: Operand<i32> {
 193   let PrintMethod = "printPICLabel";
 194 }
 195 def symbolHi: Operand<i32> {
 196   let PrintMethod = "printSymbolHi";
 197 }
 198 def symbolLo: Operand<i32> {
 199   let PrintMethod = "printSymbolLo";
 200 }
 201 def crbitm: Operand<i8> {
 202   let PrintMethod = "printcrbitm";
 203 }
 204 // Address operands
 205 def memri : Operand<i32> {
 206   let PrintMethod = "printMemRegImm";
 207   let NumMIOperands = 2;
 208   let MIOperandInfo = (ops i32imm, GPRC);
 209 }
 210 def memrr : Operand<i32> {
 211   let PrintMethod = "printMemRegReg";
 212   let NumMIOperands = 2;
 213   let MIOperandInfo = (ops GPRC, GPRC);
 214 }
 215 def memrix : Operand<i32> {   // memri where the imm is shifted 2 bits.
 216   let PrintMethod = "printMemRegImmShifted";
 217   let NumMIOperands = 2;
 218   let MIOperandInfo = (ops i32imm, GPRC);
 219 }
 220
 221 // Define PowerPC specific addressing mode.
 222 def iaddr  : ComplexPattern<i32, 2, "SelectAddrImm",    []>;
 223 def xaddr  : ComplexPattern<i32, 2, "SelectAddrIdx",    []>;
 224 def xoaddr : ComplexPattern<i32, 2, "SelectAddrIdxOnly",[]>;
 225 def ixaddr : ComplexPattern<i32, 2, "SelectAddrImmShift", []>; // "std"
 226
 227 //===----------------------------------------------------------------------===//
 228 // PowerPC Instruction Predicate Definitions.
 229 def FPContractions : Predicate<"!NoExcessFPPrecision">;
 230
 231 //===----------------------------------------------------------------------===//
 232 // PowerPC Instruction Definitions.
 233
 234 // Pseudo-instructions:
 235
 236 let hasCtrlDep = 1 in {
 237 def ADJCALLSTACKDOWN : Pseudo<(ops u16imm:$amt),
 238                               "; ADJCALLSTACKDOWN",
 239                               [(callseq_start imm:$amt)]>;
 240 def ADJCALLSTACKUP   : Pseudo<(ops u16imm:$amt),
 241                               "; ADJCALLSTACKUP",
 242                               [(callseq_end imm:$amt)]>;
 243
 244 def UPDATE_VRSAVE    : Pseudo<(ops GPRC:$rD, GPRC:$rS),
 245                               "UPDATE_VRSAVE $rD, $rS", []>;
 246 }
 247 def IMPLICIT_DEF_GPR : Pseudo<(ops GPRC:$rD), "; $rD = IMPLICIT_DEF_GPRC",
 248                               [(set GPRC:$rD, (undef))]>;
 249 def IMPLICIT_DEF_F8  : Pseudo<(ops F8RC:$rD), "; $rD = IMPLICIT_DEF_F8",
 250                               [(set F8RC:$rD, (undef))]>;
 251 def IMPLICIT_DEF_F4  : Pseudo<(ops F4RC:$rD), "; $rD = IMPLICIT_DEF_F4",
 252                               [(set F4RC:$rD, (undef))]>;
 253
 254 // SELECT_CC_* - Used to implement the SELECT_CC DAG operation.  Expanded by the
 255 // scheduler into a branch sequence.
 256 let usesCustomDAGSchedInserter = 1,    // Expanded by the scheduler.
 257     PPC970_Single = 1 in {
 258   def SELECT_CC_Int : Pseudo<(ops GPRC:$dst, CRRC:$cond, GPRC:$T, GPRC:$F,
 259                               i32imm:$BROPC), "; SELECT_CC PSEUDO!", []>;
 260   def SELECT_CC_F4  : Pseudo<(ops F4RC:$dst, CRRC:$cond, F4RC:$T, F4RC:$F,
 261                               i32imm:$BROPC), "; SELECT_CC PSEUDO!", []>;
 262   def SELECT_CC_F8  : Pseudo<(ops F8RC:$dst, CRRC:$cond, F8RC:$T, F8RC:$F,
 263                               i32imm:$BROPC), "; SELECT_CC PSEUDO!", []>;
 264   def SELECT_CC_VRRC: Pseudo<(ops VRRC:$dst, CRRC:$cond, VRRC:$T, VRRC:$F,
 265                               i32imm:$BROPC), "; SELECT_CC PSEUDO!", []>;
 266 }
 267
 268 let isTerminator = 1, noResults = 1, PPC970_Unit = 7 in {
 269   let isReturn = 1 in
 270     def BLR : XLForm_2_ext<19, 16, 20, 0, 0, (ops), "blr", BrB, [(retflag)]>;
 271   def BCTR : XLForm_2_ext<19, 528, 20, 0, 0, (ops), "bctr", BrB, []>;
 272 }
 273
 274 let Defs = [LR] in
 275   def MovePCtoLR : Pseudo<(ops piclabel:$label), "bl $label", []>,
 276                    PPC970_Unit_BRU;
 277
 278 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1,
 279     noResults = 1, PPC970_Unit = 7 in {
 280   def COND_BRANCH : Pseudo<(ops CRRC:$crS, u16imm:$opc, target:$dst),
 281                            "; COND_BRANCH $crS, $opc, $dst",
 282                            [(PPCcondbranch CRRC:$crS, imm:$opc, bb:$dst)]>;
 283   def B   : IForm<18, 0, 0, (ops target:$dst),
 284                   "b $dst", BrB,
 285                   [(br bb:$dst)]>;
 286
 287   def BLT : BForm<16, 0, 0, 12, 0, (ops CRRC:$crS, target:$block),
 288                   "blt $crS, $block", BrB>;
 289   def BLE : BForm<16, 0, 0, 4,  1, (ops CRRC:$crS, target:$block),
 290                   "ble $crS, $block", BrB>;
 291   def BEQ : BForm<16, 0, 0, 12, 2, (ops CRRC:$crS, target:$block),
 292                   "beq $crS, $block", BrB>;
 293   def BGE : BForm<16, 0, 0, 4,  0, (ops CRRC:$crS, target:$block),
 294                   "bge $crS, $block", BrB>;
 295   def BGT : BForm<16, 0, 0, 12, 1, (ops CRRC:$crS, target:$block),
 296                   "bgt $crS, $block", BrB>;
 297   def BNE : BForm<16, 0, 0, 4,  2, (ops CRRC:$crS, target:$block),
 298                   "bne $crS, $block", BrB>;
 299   def BUN : BForm<16, 0, 0, 12, 3, (ops CRRC:$crS, target:$block),
 300                   "bun $crS, $block", BrB>;
 301   def BNU : BForm<16, 0, 0, 4,  3, (ops CRRC:$crS, target:$block),
 302                   "bnu $crS, $block", BrB>;
 303 }
 304
 305 let isCall = 1, noResults = 1, PPC970_Unit = 7,
 306   // All calls clobber the non-callee saved registers...
 307   Defs = [R0,R2,R3,R4,R5,R6,R7,R8,R9,R10,R11,R12,
 308           F0,F1,F2,F3,F4,F5,F6,F7,F8,F9,F10,F11,F12,F13,
 309           V0,V1,V2,V3,V4,V5,V6,V7,V8,V9,V10,V11,V12,V13,V14,V15,V16,V17,V18,V19,
 310           LR,CTR,
 311           CR0,CR1,CR5,CR6,CR7] in {
 312   // Convenient aliases for call instructions
 313   def BL  : IForm<18, 0, 1, (ops calltarget:$func, variable_ops),
 314                             "bl $func", BrB, []>;  // See Pat patterns below.
 315   def BLA : IForm<18, 1, 1, (ops aaddr:$func, variable_ops),
 316                             "bla $func", BrB, [(PPCcall imm:$func)]>;
 317   def BCTRL : XLForm_2_ext<19, 528, 20, 0, 1, (ops variable_ops), "bctrl", BrB,
 318                            [(PPCbctrl)]>;
 319 }
 320
 321 // DCB* instructions.
 322 def DCBZ : DCB_Form<1014, 0, (ops memrr:$dst),
 323                     "dcbz $dst", LdStDCBF, [(int_ppc_dcbz xoaddr:$dst)]>,
 324                     PPC970_DGroup_Single;
 325 def DCBZL : DCB_Form<1014, 1, (ops memrr:$dst),
 326                      "dcbzl $dst", LdStDCBF, [(int_ppc_dcbzl xoaddr:$dst)]>,
 327                      PPC970_DGroup_Single;
 328
 329 // D-Form instructions.  Most instructions that perform an operation on a
 330 // register and an immediate are of this type.
 331 //
 332 let isLoad = 1, PPC970_Unit = 2 in {
 333 def LBZ : DForm_1<34, (ops GPRC:$rD, memri:$src),
 334                   "lbz $rD, $src", LdStGeneral,
 335                   [(set GPRC:$rD, (zextload iaddr:$src, i8))]>;
 336 def LHA : DForm_1<42, (ops GPRC:$rD, memri:$src),
 337                   "lha $rD, $src", LdStLHA,
 338                   [(set GPRC:$rD, (sextload iaddr:$src, i16))]>,
 339                   PPC970_DGroup_Cracked;
 340 def LHZ : DForm_1<40, (ops GPRC:$rD, memri:$src),
 341                   "lhz $rD, $src", LdStGeneral,
 342                   [(set GPRC:$rD, (zextload iaddr:$src, i16))]>;
 343 def LWZ : DForm_1<32, (ops GPRC:$rD, memri:$src),
 344                   "lwz $rD, $src", LdStGeneral,
 345                   [(set GPRC:$rD, (load iaddr:$src))]>;
 346 def LWZU : DForm_1<35, (ops GPRC:$rD, s16imm:$disp, GPRC:$rA),
 347                    "lwzu $rD, $disp($rA)", LdStGeneral,
 348                    []>;
 349 }
 350 let PPC970_Unit = 1 in {  // FXU Operations.
 351 def ADDI   : DForm_2<14, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 352                      "addi $rD, $rA, $imm", IntGeneral,
 353                      [(set GPRC:$rD, (add GPRC:$rA, immSExt16:$imm))]>;
 354 def ADDIC  : DForm_2<12, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 355                      "addic $rD, $rA, $imm", IntGeneral,
 356                      [(set GPRC:$rD, (addc GPRC:$rA, immSExt16:$imm))]>,
 357                      PPC970_DGroup_Cracked;
 358 def ADDICo : DForm_2<13, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 359                      "addic. $rD, $rA, $imm", IntGeneral,
 360                      []>;
 361 def ADDIS  : DForm_2<15, (ops GPRC:$rD, GPRC:$rA, symbolHi:$imm),
 362                      "addis $rD, $rA, $imm", IntGeneral,
 363                      [(set GPRC:$rD, (add GPRC:$rA, imm16Shifted:$imm))]>;
 364 def LA     : DForm_2<14, (ops GPRC:$rD, GPRC:$rA, symbolLo:$sym),
 365                      "la $rD, $sym($rA)", IntGeneral,
 366                      [(set GPRC:$rD, (add GPRC:$rA,
 367                                           (PPClo tglobaladdr:$sym, 0)))]>;
 368 def MULLI  : DForm_2< 7, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 369                      "mulli $rD, $rA, $imm", IntMulLI,
 370                      [(set GPRC:$rD, (mul GPRC:$rA, immSExt16:$imm))]>;
 371 def SUBFIC : DForm_2< 8, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 372                      "subfic $rD, $rA, $imm", IntGeneral,
 373                      [(set GPRC:$rD, (subc immSExt16:$imm, GPRC:$rA))]>;
 374 def LI  : DForm_2_r0<14, (ops GPRC:$rD, symbolLo:$imm),
 375                      "li $rD, $imm", IntGeneral,
 376                      [(set GPRC:$rD, immSExt16:$imm)]>;
 377 def LIS : DForm_2_r0<15, (ops GPRC:$rD, symbolHi:$imm),
 378                      "lis $rD, $imm", IntGeneral,
 379                      [(set GPRC:$rD, imm16Shifted:$imm)]>;
 380 }
 381 let isStore = 1, noResults = 1, PPC970_Unit = 2 in {
 382 def STB  : DForm_3<38, (ops GPRC:$rS, memri:$src),
 383                    "stb $rS, $src", LdStGeneral,
 384                    [(truncstore GPRC:$rS, iaddr:$src, i8)]>;
 385 def STH  : DForm_3<44, (ops GPRC:$rS, memri:$src),
 386                    "sth $rS, $src", LdStGeneral,
 387                    [(truncstore GPRC:$rS, iaddr:$src, i16)]>;
 388 def STW  : DForm_3<36, (ops GPRC:$rS, memri:$src),
 389                    "stw $rS, $src", LdStGeneral,
 390                    [(store GPRC:$rS, iaddr:$src)]>;
 391 def STWU : DForm_3<37, (ops GPRC:$rS, s16imm:$disp, GPRC:$rA),
 392                    "stwu $rS, $disp($rA)", LdStGeneral,
 393                    []>;
 394 }
 395 let PPC970_Unit = 1 in {  // FXU Operations.
 396 def ANDIo : DForm_4<28, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 397                     "andi. $dst, $src1, $src2", IntGeneral,
 398                     [(set GPRC:$dst, (and GPRC:$src1, immZExt16:$src2))]>,
 399                     isDOT;
 400 def ANDISo : DForm_4<29, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 401                     "andis. $dst, $src1, $src2", IntGeneral,
 402                     [(set GPRC:$dst, (and GPRC:$src1, imm16Shifted:$src2))]>,
 403                     isDOT;
 404 def ORI   : DForm_4<24, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 405                     "ori $dst, $src1, $src2", IntGeneral,
 406                     [(set GPRC:$dst, (or GPRC:$src1, immZExt16:$src2))]>;
 407 def ORIS  : DForm_4<25, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 408                     "oris $dst, $src1, $src2", IntGeneral,
 409                     [(set GPRC:$dst, (or GPRC:$src1, imm16Shifted:$src2))]>;
 410 def XORI  : DForm_4<26, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 411                     "xori $dst, $src1, $src2", IntGeneral,
 412                     [(set GPRC:$dst, (xor GPRC:$src1, immZExt16:$src2))]>;
 413 def XORIS : DForm_4<27, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 414                     "xoris $dst, $src1, $src2", IntGeneral,
 415                     [(set GPRC:$dst, (xor GPRC:$src1, imm16Shifted:$src2))]>;
 416 def NOP   : DForm_4_zero<24, (ops), "nop", IntGeneral,
 417                          []>;
 418 def CMPI  : DForm_5<11, (ops CRRC:$crD, i1imm:$L, GPRC:$rA, s16imm:$imm),
 419                     "cmpi $crD, $L, $rA, $imm", IntCompare>;
 420 def CMPWI : DForm_5_ext<11, (ops CRRC:$crD, GPRC:$rA, s16imm:$imm),
 421                         "cmpwi $crD, $rA, $imm", IntCompare>;
 422 def CMPLI  : DForm_6<10, (ops CRRC:$dst, i1imm:$size, GPRC:$src1, u16imm:$src2),
 423                      "cmpli $dst, $size, $src1, $src2", IntCompare>;
 424 def CMPLWI : DForm_6_ext<10, (ops CRRC:$dst, GPRC:$src1, u16imm:$src2),
 425                          "cmplwi $dst, $src1, $src2", IntCompare>;
 426 }
 427 let isLoad = 1, PPC970_Unit = 2 in {
 428 def LFS : DForm_8<48, (ops F4RC:$rD, memri:$src),
 429                   "lfs $rD, $src", LdStLFDU,
 430                   [(set F4RC:$rD, (load iaddr:$src))]>;
 431 def LFD : DForm_8<50, (ops F8RC:$rD, memri:$src),
 432                   "lfd $rD, $src", LdStLFD,
 433                   [(set F8RC:$rD, (load iaddr:$src))]>;
 434 }
 435 let isStore = 1, noResults = 1, PPC970_Unit = 2 in {
 436 def STFS : DForm_9<52, (ops F4RC:$rS, memri:$dst),
 437                    "stfs $rS, $dst", LdStUX,
 438                    [(store F4RC:$rS, iaddr:$dst)]>;
 439 def STFD : DForm_9<54, (ops F8RC:$rS, memri:$dst),
 440                    "stfd $rS, $dst", LdStUX,
 441                    [(store F8RC:$rS, iaddr:$dst)]>;
 442 }
 443
 444 // X-Form instructions.  Most instructions that perform an operation on a
 445 // register and another register are of this type.
 446 //
 447 let isLoad = 1, PPC970_Unit = 2 in {
 448 def LBZX : XForm_1<31,  87, (ops GPRC:$rD, memrr:$src),
 449                    "lbzx $rD, $src", LdStGeneral,
 450                    [(set GPRC:$rD, (zextload xaddr:$src, i8))]>;
 451 def LHAX : XForm_1<31, 343, (ops GPRC:$rD, memrr:$src),
 452                    "lhax $rD, $src", LdStLHA,
 453                    [(set GPRC:$rD, (sextload xaddr:$src, i16))]>,
 454                    PPC970_DGroup_Cracked;
 455 def LHZX : XForm_1<31, 279, (ops GPRC:$rD, memrr:$src),
 456                    "lhzx $rD, $src", LdStGeneral,
 457                    [(set GPRC:$rD, (zextload xaddr:$src, i16))]>;
 458 def LWZX : XForm_1<31,  23, (ops GPRC:$rD, memrr:$src),
 459                    "lwzx $rD, $src", LdStGeneral,
 460                    [(set GPRC:$rD, (load xaddr:$src))]>;
 461 }
 462
 463 let PPC970_Unit = 1 in {  // FXU Operations.
 464 def NAND : XForm_6<31, 476, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 465                    "nand $rA, $rS, $rB", IntGeneral,
 466                    [(set GPRC:$rA, (not (and GPRC:$rS, GPRC:$rB)))]>;
 467 def AND  : XForm_6<31,  28, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 468                    "and $rA, $rS, $rB", IntGeneral,
 469                    [(set GPRC:$rA, (and GPRC:$rS, GPRC:$rB))]>;
 470 def ANDo : XForm_6<31,  28, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 471                    "and. $rA, $rS, $rB", IntGeneral,
 472                    []>, isDOT;
 473 def ANDC : XForm_6<31,  60, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 474                    "andc $rA, $rS, $rB", IntGeneral,
 475                    [(set GPRC:$rA, (and GPRC:$rS, (not GPRC:$rB)))]>;
 476 def OR4  : XForm_6<31, 444, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 477                    "or $rA, $rS, $rB", IntGeneral,
 478                    [(set GPRC:$rA, (or GPRC:$rS, GPRC:$rB))]>;
 479 def NOR  : XForm_6<31, 124, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 480                    "nor $rA, $rS, $rB", IntGeneral,
 481                    [(set GPRC:$rA, (not (or GPRC:$rS, GPRC:$rB)))]>;
 482 def ORo  : XForm_6<31, 444, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 483                    "or. $rA, $rS, $rB", IntGeneral,
 484                    []>, isDOT;
 485 def ORC  : XForm_6<31, 412, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 486                    "orc $rA, $rS, $rB", IntGeneral,
 487                    [(set GPRC:$rA, (or GPRC:$rS, (not GPRC:$rB)))]>;
 488 def EQV  : XForm_6<31, 284, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 489                    "eqv $rA, $rS, $rB", IntGeneral,
 490                    [(set GPRC:$rA, (not (xor GPRC:$rS, GPRC:$rB)))]>;
 491 def XOR  : XForm_6<31, 316, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 492                    "xor $rA, $rS, $rB", IntGeneral,
 493                    [(set GPRC:$rA, (xor GPRC:$rS, GPRC:$rB))]>;
 494 def SLW  : XForm_6<31,  24, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 495                    "slw $rA, $rS, $rB", IntGeneral,
 496                    [(set GPRC:$rA, (PPCshl GPRC:$rS, GPRC:$rB))]>;
 497 def SRW  : XForm_6<31, 536, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 498                    "srw $rA, $rS, $rB", IntGeneral,
 499                    [(set GPRC:$rA, (PPCsrl GPRC:$rS, GPRC:$rB))]>;
 500 def SRAW : XForm_6<31, 792, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 501                    "sraw $rA, $rS, $rB", IntShift,
 502                    [(set GPRC:$rA, (PPCsra GPRC:$rS, GPRC:$rB))]>;
 503 }
 504 let isStore = 1, noResults = 1, PPC970_Unit = 2 in {
 505 def STBX  : XForm_8<31, 215, (ops GPRC:$rS, memrr:$dst),
 506                    "stbx $rS, $dst", LdStGeneral,
 507                    [(truncstore GPRC:$rS, xaddr:$dst, i8)]>,
 508                    PPC970_DGroup_Cracked;
 509 def STHX  : XForm_8<31, 407, (ops GPRC:$rS, memrr:$dst),
 510                    "sthx $rS, $dst", LdStGeneral,
 511                    [(truncstore GPRC:$rS, xaddr:$dst, i16)]>,
 512                    PPC970_DGroup_Cracked;
 513 def STWX  : XForm_8<31, 151, (ops GPRC:$rS, memrr:$dst),
 514                    "stwx $rS, $dst", LdStGeneral,
 515                    [(store GPRC:$rS, xaddr:$dst)]>,
 516                    PPC970_DGroup_Cracked;
 517 def STWUX : XForm_8<31, 183, (ops GPRC:$rS, GPRC:$rA, GPRC:$rB),
 518                    "stwux $rS, $rA, $rB", LdStGeneral,
 519                    []>;
 520 }
 521 let PPC970_Unit = 1 in {  // FXU Operations.
 522 def SRAWI : XForm_10<31, 824, (ops GPRC:$rA, GPRC:$rS, u5imm:$SH),
 523                      "srawi $rA, $rS, $SH", IntShift,
 524                      [(set GPRC:$rA, (sra GPRC:$rS, (i32 imm:$SH)))]>;
 525 def CNTLZW : XForm_11<31,  26, (ops GPRC:$rA, GPRC:$rS),
 526                       "cntlzw $rA, $rS", IntGeneral,
 527                       [(set GPRC:$rA, (ctlz GPRC:$rS))]>;
 528 def EXTSB  : XForm_11<31, 954, (ops GPRC:$rA, GPRC:$rS),
 529                       "extsb $rA, $rS", IntGeneral,
 530                       [(set GPRC:$rA, (sext_inreg GPRC:$rS, i8))]>;
 531 def EXTSH  : XForm_11<31, 922, (ops GPRC:$rA, GPRC:$rS),
 532                       "extsh $rA, $rS", IntGeneral,
 533                       [(set GPRC:$rA, (sext_inreg GPRC:$rS, i16))]>;
 534
 535 def CMP    : XForm_16<31, 0, (ops CRRC:$crD, i1imm:$long, GPRC:$rA, GPRC:$rB),
 536                       "cmp $crD, $long, $rA, $rB", IntCompare>;
 537 def CMPL   : XForm_16<31, 32, (ops CRRC:$crD, i1imm:$long, GPRC:$rA, GPRC:$rB),
 538                       "cmpl $crD, $long, $rA, $rB", IntCompare>;
 539 def CMPW   : XForm_16_ext<31, 0, (ops CRRC:$crD, GPRC:$rA, GPRC:$rB),
 540                           "cmpw $crD, $rA, $rB", IntCompare>;
 541 def CMPLW  : XForm_16_ext<31, 32, (ops CRRC:$crD, GPRC:$rA, GPRC:$rB),
 542                           "cmplw $crD, $rA, $rB", IntCompare>;
 543 }
 544 let PPC970_Unit = 3 in {  // FPU Operations.
 545 //def FCMPO  : XForm_17<63, 32, (ops CRRC:$crD, FPRC:$fA, FPRC:$fB),
 546 //                      "fcmpo $crD, $fA, $fB", FPCompare>;
 547 def FCMPUS : XForm_17<63, 0, (ops CRRC:$crD, F4RC:$fA, F4RC:$fB),
 548                       "fcmpu $crD, $fA, $fB", FPCompare>;
 549 def FCMPUD : XForm_17<63, 0, (ops CRRC:$crD, F8RC:$fA, F8RC:$fB),
 550                       "fcmpu $crD, $fA, $fB", FPCompare>;
 551 }
 552 let isLoad = 1, PPC970_Unit = 2 in {
 553 def LFSX   : XForm_25<31, 535, (ops F4RC:$frD, memrr:$src),
 554                       "lfsx $frD, $src", LdStLFDU,
 555                       [(set F4RC:$frD, (load xaddr:$src))]>;
 556 def LFDX   : XForm_25<31, 599, (ops F8RC:$frD, memrr:$src),
 557                       "lfdx $frD, $src", LdStLFDU,
 558                       [(set F8RC:$frD, (load xaddr:$src))]>;
 559 }
 560 let PPC970_Unit = 3 in {  // FPU Operations.
 561 def FCTIWZ : XForm_26<63, 15, (ops F8RC:$frD, F8RC:$frB),
 562                       "fctiwz $frD, $frB", FPGeneral,
 563                       [(set F8RC:$frD, (PPCfctiwz F8RC:$frB))]>;
 564 def FRSP   : XForm_26<63, 12, (ops F4RC:$frD, F8RC:$frB),
 565                       "frsp $frD, $frB", FPGeneral,
 566                       [(set F4RC:$frD, (fround F8RC:$frB))]>;
 567 def FSQRT  : XForm_26<63, 22, (ops F8RC:$frD, F8RC:$frB),
 568                       "fsqrt $frD, $frB", FPSqrt,
 569                       [(set F8RC:$frD, (fsqrt F8RC:$frB))]>;
 570 def FSQRTS : XForm_26<59, 22, (ops F4RC:$frD, F4RC:$frB),
 571                       "fsqrts $frD, $frB", FPSqrt,
 572                       [(set F4RC:$frD, (fsqrt F4RC:$frB))]>;
 573 }
 574
 575 /// FMR is split into 3 versions, one for 4/8 byte FP, and one for extending.
 576 ///
 577 /// Note that these are defined as pseudo-ops on the PPC970 because they are
 578 /// often coalesced away and we don't want the dispatch group builder to think
 579 /// that they will fill slots (which could cause the load of a LSU reject to
 580 /// sneak into a d-group with a store).
 581 def FMRS   : XForm_26<63, 72, (ops F4RC:$frD, F4RC:$frB),
 582                       "fmr $frD, $frB", FPGeneral,
 583                       []>,  // (set F4RC:$frD, F4RC:$frB)
 584                       PPC970_Unit_Pseudo;
 585 def FMRD   : XForm_26<63, 72, (ops F8RC:$frD, F8RC:$frB),
 586                       "fmr $frD, $frB", FPGeneral,
 587                       []>,  // (set F8RC:$frD, F8RC:$frB)
 588                       PPC970_Unit_Pseudo;
 589 def FMRSD  : XForm_26<63, 72, (ops F8RC:$frD, F4RC:$frB),
 590                       "fmr $frD, $frB", FPGeneral,
 591                       [(set F8RC:$frD, (fextend F4RC:$frB))]>,
 592                       PPC970_Unit_Pseudo;
 593
 594 let PPC970_Unit = 3 in {  // FPU Operations.
 595 // These are artificially split into two different forms, for 4/8 byte FP.
 596 def FABSS  : XForm_26<63, 264, (ops F4RC:$frD, F4RC:$frB),
 597                       "fabs $frD, $frB", FPGeneral,
 598                       [(set F4RC:$frD, (fabs F4RC:$frB))]>;
 599 def FABSD  : XForm_26<63, 264, (ops F8RC:$frD, F8RC:$frB),
 600                       "fabs $frD, $frB", FPGeneral,
 601                       [(set F8RC:$frD, (fabs F8RC:$frB))]>;
 602 def FNABSS : XForm_26<63, 136, (ops F4RC:$frD, F4RC:$frB),
 603                       "fnabs $frD, $frB", FPGeneral,
 604                       [(set F4RC:$frD, (fneg (fabs F4RC:$frB)))]>;
 605 def FNABSD : XForm_26<63, 136, (ops F8RC:$frD, F8RC:$frB),
 606                       "fnabs $frD, $frB", FPGeneral,
 607                       [(set F8RC:$frD, (fneg (fabs F8RC:$frB)))]>;
 608 def FNEGS  : XForm_26<63, 40, (ops F4RC:$frD, F4RC:$frB),
 609                       "fneg $frD, $frB", FPGeneral,
 610                       [(set F4RC:$frD, (fneg F4RC:$frB))]>;
 611 def FNEGD  : XForm_26<63, 40, (ops F8RC:$frD, F8RC:$frB),
 612                       "fneg $frD, $frB", FPGeneral,
 613                       [(set F8RC:$frD, (fneg F8RC:$frB))]>;
 614 }
 615
 616 let isStore = 1, noResults = 1, PPC970_Unit = 2 in {
 617 def STFIWX: XForm_28<31, 983, (ops F8RC:$frS, memrr:$dst),
 618                      "stfiwx $frS, $dst", LdStUX,
 619                      [(PPCstfiwx F8RC:$frS, xoaddr:$dst)]>;
 620 def STFSX : XForm_28<31, 663, (ops F4RC:$frS, memrr:$dst),
 621                      "stfsx $frS, $dst", LdStUX,
 622                      [(store F4RC:$frS, xaddr:$dst)]>;
 623 def STFDX : XForm_28<31, 727, (ops F8RC:$frS, memrr:$dst),
 624                      "stfdx $frS, $dst", LdStUX,
 625                      [(store F8RC:$frS, xaddr:$dst)]>;
 626 }
 627
 628 // XL-Form instructions.  condition register logical ops.
 629 //
 630 def MCRF   : XLForm_3<19, 0, (ops CRRC:$BF, CRRC:$BFA),
 631                       "mcrf $BF, $BFA", BrMCR>,
 632              PPC970_DGroup_First, PPC970_Unit_CRU;
 633
 634 // XFX-Form instructions.  Instructions that deal with SPRs.
 635 //
 636 def MFCTR : XFXForm_1_ext<31, 339, 9, (ops GPRC:$rT), "mfctr $rT", SprMFSPR>,
 637             PPC970_DGroup_First, PPC970_Unit_FXU;
 638 let Pattern = [(PPCmtctr GPRC:$rS)] in {
 639 def MTCTR : XFXForm_7_ext<31, 467, 9, (ops GPRC:$rS), "mtctr $rS", SprMTSPR>,
 640             PPC970_DGroup_First, PPC970_Unit_FXU;
 641 }
 642
 643 def MTLR  : XFXForm_7_ext<31, 467, 8, (ops GPRC:$rS), "mtlr $rS", SprMTSPR>,
 644             PPC970_DGroup_First, PPC970_Unit_FXU;
 645 def MFLR  : XFXForm_1_ext<31, 339, 8, (ops GPRC:$rT), "mflr $rT", SprMFSPR>,
 646             PPC970_DGroup_First, PPC970_Unit_FXU;
 647
 648 // Move to/from VRSAVE: despite being a SPR, the VRSAVE register is renamed like
 649 // a GPR on the PPC970.  As such, copies in and out have the same performance
 650 // characteristics as an OR instruction.
 651 def MTVRSAVE : XFXForm_7_ext<31, 467, 256, (ops GPRC:$rS),
 652                              "mtspr 256, $rS", IntGeneral>,
 653                PPC970_DGroup_Single, PPC970_Unit_FXU;
 654 def MFVRSAVE : XFXForm_1_ext<31, 339, 256, (ops GPRC:$rT),
 655                              "mfspr $rT, 256", IntGeneral>,
 656                PPC970_DGroup_First, PPC970_Unit_FXU;
 657
 658 def MTCRF : XFXForm_5<31, 144, (ops crbitm:$FXM, GPRC:$rS),
 659                       "mtcrf $FXM, $rS", BrMCRX>,
 660             PPC970_MicroCode, PPC970_Unit_CRU;
 661 def MFCR  : XFXForm_3<31, 19, (ops GPRC:$rT), "mfcr $rT", SprMFCR>,
 662             PPC970_MicroCode, PPC970_Unit_CRU;
 663 def MFOCRF: XFXForm_5a<31, 19, (ops GPRC:$rT, crbitm:$FXM),
 664                        "mfcr $rT, $FXM", SprMFCR>,
 665             PPC970_DGroup_First, PPC970_Unit_CRU;
 666
 667 let PPC970_Unit = 1 in {  // FXU Operations.
 668
 669 // XO-Form instructions.  Arithmetic instructions that can set overflow bit
 670 //
 671 def ADD4  : XOForm_1<31, 266, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 672                      "add $rT, $rA, $rB", IntGeneral,
 673                      [(set GPRC:$rT, (add GPRC:$rA, GPRC:$rB))]>;
 674 def ADDC  : XOForm_1<31, 10, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 675                      "addc $rT, $rA, $rB", IntGeneral,
 676                      [(set GPRC:$rT, (addc GPRC:$rA, GPRC:$rB))]>,
 677                      PPC970_DGroup_Cracked;
 678 def ADDE  : XOForm_1<31, 138, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 679                      "adde $rT, $rA, $rB", IntGeneral,
 680                      [(set GPRC:$rT, (adde GPRC:$rA, GPRC:$rB))]>;
 681 def DIVW  : XOForm_1<31, 491, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 682                      "divw $rT, $rA, $rB", IntDivW,
 683                      [(set GPRC:$rT, (sdiv GPRC:$rA, GPRC:$rB))]>,
 684                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
 685 def DIVWU : XOForm_1<31, 459, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 686                      "divwu $rT, $rA, $rB", IntDivW,
 687                      [(set GPRC:$rT, (udiv GPRC:$rA, GPRC:$rB))]>,
 688                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
 689 def MULHW : XOForm_1<31, 75, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 690                      "mulhw $rT, $rA, $rB", IntMulHW,
 691                      [(set GPRC:$rT, (mulhs GPRC:$rA, GPRC:$rB))]>;
 692 def MULHWU : XOForm_1<31, 11, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 693                      "mulhwu $rT, $rA, $rB", IntMulHWU,
 694                      [(set GPRC:$rT, (mulhu GPRC:$rA, GPRC:$rB))]>;
 695 def MULLW : XOForm_1<31, 235, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 696                      "mullw $rT, $rA, $rB", IntMulHW,
 697                      [(set GPRC:$rT, (mul GPRC:$rA, GPRC:$rB))]>;
 698 def SUBF  : XOForm_1<31, 40, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 699                      "subf $rT, $rA, $rB", IntGeneral,
 700                      [(set GPRC:$rT, (sub GPRC:$rB, GPRC:$rA))]>;
 701 def SUBFC : XOForm_1<31, 8, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 702                      "subfc $rT, $rA, $rB", IntGeneral,
 703                      [(set GPRC:$rT, (subc GPRC:$rB, GPRC:$rA))]>,
 704                      PPC970_DGroup_Cracked;
 705 def SUBFE : XOForm_1<31, 136, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 706                      "subfe $rT, $rA, $rB", IntGeneral,
 707                      [(set GPRC:$rT, (sube GPRC:$rB, GPRC:$rA))]>;
 708 def ADDME  : XOForm_3<31, 234, 0, (ops GPRC:$rT, GPRC:$rA),
 709                       "addme $rT, $rA", IntGeneral,
 710                       [(set GPRC:$rT, (adde GPRC:$rA, immAllOnes))]>;
 711 def ADDZE  : XOForm_3<31, 202, 0, (ops GPRC:$rT, GPRC:$rA),
 712                       "addze $rT, $rA", IntGeneral,
 713                       [(set GPRC:$rT, (adde GPRC:$rA, 0))]>;
 714 def NEG    : XOForm_3<31, 104, 0, (ops GPRC:$rT, GPRC:$rA),
 715                       "neg $rT, $rA", IntGeneral,
 716                       [(set GPRC:$rT, (ineg GPRC:$rA))]>;
 717 def SUBFME : XOForm_3<31, 232, 0, (ops GPRC:$rT, GPRC:$rA),
 718                       "subfme $rT, $rA", IntGeneral,
 719                       [(set GPRC:$rT, (sube immAllOnes, GPRC:$rA))]>;
 720 def SUBFZE : XOForm_3<31, 200, 0, (ops GPRC:$rT, GPRC:$rA),
 721                       "subfze $rT, $rA", IntGeneral,
 722                       [(set GPRC:$rT, (sube 0, GPRC:$rA))]>;
 723 }
 724
 725 // A-Form instructions.  Most of the instructions executed in the FPU are of
 726 // this type.
 727 //
 728 let PPC970_Unit = 3 in {  // FPU Operations.
 729 def FMADD : AForm_1<63, 29,
 730                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
 731                     "fmadd $FRT, $FRA, $FRC, $FRB", FPFused,
 732                     [(set F8RC:$FRT, (fadd (fmul F8RC:$FRA, F8RC:$FRC),
 733                                            F8RC:$FRB))]>,
 734                     Requires<[FPContractions]>;
 735 def FMADDS : AForm_1<59, 29,
 736                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRC, F4RC:$FRB),
 737                     "fmadds $FRT, $FRA, $FRC, $FRB", FPGeneral,
 738                     [(set F4RC:$FRT, (fadd (fmul F4RC:$FRA, F4RC:$FRC),
 739                                            F4RC:$FRB))]>,
 740                     Requires<[FPContractions]>;
 741 def FMSUB : AForm_1<63, 28,
 742                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
 743                     "fmsub $FRT, $FRA, $FRC, $FRB", FPFused,
 744                     [(set F8RC:$FRT, (fsub (fmul F8RC:$FRA, F8RC:$FRC),
 745                                            F8RC:$FRB))]>,
 746                     Requires<[FPContractions]>;
 747 def FMSUBS : AForm_1<59, 28,
 748                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRC, F4RC:$FRB),
 749                     "fmsubs $FRT, $FRA, $FRC, $FRB", FPGeneral,
 750                     [(set F4RC:$FRT, (fsub (fmul F4RC:$FRA, F4RC:$FRC),
 751                                            F4RC:$FRB))]>,
 752                     Requires<[FPContractions]>;
 753 def FNMADD : AForm_1<63, 31,
 754                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
 755                     "fnmadd $FRT, $FRA, $FRC, $FRB", FPFused,
 756                     [(set F8RC:$FRT, (fneg (fadd (fmul F8RC:$FRA, F8RC:$FRC),
 757                                                  F8RC:$FRB)))]>,
 758                     Requires<[FPContractions]>;
 759 def FNMADDS : AForm_1<59, 31,
 760                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRC, F4RC:$FRB),
 761                     "fnmadds $FRT, $FRA, $FRC, $FRB", FPGeneral,
 762                     [(set F4RC:$FRT, (fneg (fadd (fmul F4RC:$FRA, F4RC:$FRC),
 763                                                  F4RC:$FRB)))]>,
 764                     Requires<[FPContractions]>;
 765 def FNMSUB : AForm_1<63, 30,
 766                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
 767                     "fnmsub $FRT, $FRA, $FRC, $FRB", FPFused,
 768                     [(set F8RC:$FRT, (fneg (fsub (fmul F8RC:$FRA, F8RC:$FRC),
 769                                                  F8RC:$FRB)))]>,
 770                     Requires<[FPContractions]>;
 771 def FNMSUBS : AForm_1<59, 30,
 772                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRC, F4RC:$FRB),
 773                     "fnmsubs $FRT, $FRA, $FRC, $FRB", FPGeneral,
 774                     [(set F4RC:$FRT, (fneg (fsub (fmul F4RC:$FRA, F4RC:$FRC),
 775                                                  F4RC:$FRB)))]>,
 776                     Requires<[FPContractions]>;
 777 // FSEL is artificially split into 4 and 8-byte forms for the result.  To avoid
 778 // having 4 of these, force the comparison to always be an 8-byte double (code
 779 // should use an FMRSD if the input comparison value really wants to be a float)
 780 // and 4/8 byte forms for the result and operand type..
 781 def FSELD : AForm_1<63, 23,
 782                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
 783                     "fsel $FRT, $FRA, $FRC, $FRB", FPGeneral,
 784                     [(set F8RC:$FRT, (PPCfsel F8RC:$FRA,F8RC:$FRC,F8RC:$FRB))]>;
 785 def FSELS : AForm_1<63, 23,
 786                      (ops F4RC:$FRT, F8RC:$FRA, F4RC:$FRC, F4RC:$FRB),
 787                      "fsel $FRT, $FRA, $FRC, $FRB", FPGeneral,
 788                     [(set F4RC:$FRT, (PPCfsel F8RC:$FRA,F4RC:$FRC,F4RC:$FRB))]>;
 789 def FADD  : AForm_2<63, 21,
 790                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRB),
 791                     "fadd $FRT, $FRA, $FRB", FPGeneral,
 792                     [(set F8RC:$FRT, (fadd F8RC:$FRA, F8RC:$FRB))]>;
 793 def FADDS : AForm_2<59, 21,
 794                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRB),
 795                     "fadds $FRT, $FRA, $FRB", FPGeneral,
 796                     [(set F4RC:$FRT, (fadd F4RC:$FRA, F4RC:$FRB))]>;
 797 def FDIV  : AForm_2<63, 18,
 798                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRB),
 799                     "fdiv $FRT, $FRA, $FRB", FPDivD,
 800                     [(set F8RC:$FRT, (fdiv F8RC:$FRA, F8RC:$FRB))]>;
 801 def FDIVS : AForm_2<59, 18,
 802                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRB),
 803                     "fdivs $FRT, $FRA, $FRB", FPDivS,
 804                     [(set F4RC:$FRT, (fdiv F4RC:$FRA, F4RC:$FRB))]>;
 805 def FMUL  : AForm_3<63, 25,
 806                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRB),
 807                     "fmul $FRT, $FRA, $FRB", FPFused,
 808                     [(set F8RC:$FRT, (fmul F8RC:$FRA, F8RC:$FRB))]>;
 809 def FMULS : AForm_3<59, 25,
 810                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRB),
 811                     "fmuls $FRT, $FRA, $FRB", FPGeneral,
 812                     [(set F4RC:$FRT, (fmul F4RC:$FRA, F4RC:$FRB))]>;
 813 def FSUB  : AForm_2<63, 20,
 814                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRB),
 815                     "fsub $FRT, $FRA, $FRB", FPGeneral,
 816                     [(set F8RC:$FRT, (fsub F8RC:$FRA, F8RC:$FRB))]>;
 817 def FSUBS : AForm_2<59, 20,
 818                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRB),
 819                     "fsubs $FRT, $FRA, $FRB", FPGeneral,
 820                     [(set F4RC:$FRT, (fsub F4RC:$FRA, F4RC:$FRB))]>;
 821 }
 822
 823 let PPC970_Unit = 1 in {  // FXU Operations.
 824 // M-Form instructions.  rotate and mask instructions.
 825 //
 826 let isTwoAddress = 1, isCommutable = 1 in {
 827 // RLWIMI can be commuted if the rotate amount is zero.
 828 def RLWIMI : MForm_2<20,
 829                      (ops GPRC:$rA, GPRC:$rSi, GPRC:$rS, u5imm:$SH, u5imm:$MB,
 830                       u5imm:$ME), "rlwimi $rA, $rS, $SH, $MB, $ME", IntRotate,
 831                       []>, PPC970_DGroup_Cracked;
 832 }
 833 def RLWINM : MForm_2<21,
 834                      (ops GPRC:$rA, GPRC:$rS, u5imm:$SH, u5imm:$MB, u5imm:$ME),
 835                      "rlwinm $rA, $rS, $SH, $MB, $ME", IntGeneral,
 836                      []>;
 837 def RLWINMo : MForm_2<21,
 838                      (ops GPRC:$rA, GPRC:$rS, u5imm:$SH, u5imm:$MB, u5imm:$ME),
 839                      "rlwinm. $rA, $rS, $SH, $MB, $ME", IntGeneral,
 840                      []>, isDOT, PPC970_DGroup_Cracked;
 841 def RLWNM  : MForm_2<23,
 842                      (ops GPRC:$rA, GPRC:$rS, GPRC:$rB, u5imm:$MB, u5imm:$ME),
 843                      "rlwnm $rA, $rS, $rB, $MB, $ME", IntGeneral,
 844                      []>;
 845 }
 846
 847
 848 //===----------------------------------------------------------------------===//
 849 // DWARF Pseudo Instructions
 850 //
 851
 852 def DWARF_LOC        : Pseudo<(ops i32imm:$line, i32imm:$col, i32imm:$file),
 853                               "; .loc $file, $line, $col",
 854                       [(dwarf_loc (i32 imm:$line), (i32 imm:$col),
 855                                   (i32 imm:$file))]>;
 856
 857 def DWARF_LABEL      : Pseudo<(ops i32imm:$id),
 858                               "\nLdebug_loc$id:",
 859                       [(dwarf_label (i32 imm:$id))]>;
 860
 861 //===----------------------------------------------------------------------===//
 862 // PowerPC Instruction Patterns
 863 //
 864
 865 // Arbitrary immediate support.  Implement in terms of LIS/ORI.
 866 def : Pat<(i32 imm:$imm),
 867           (ORI (LIS (HI16 imm:$imm)), (LO16 imm:$imm))>;
 868
 869 // Implement the 'not' operation with the NOR instruction.
 870 def NOT : Pat<(not GPRC:$in),
 871               (NOR GPRC:$in, GPRC:$in)>;
 872
 873 // ADD an arbitrary immediate.
 874 def : Pat<(add GPRC:$in, imm:$imm),
 875           (ADDIS (ADDI GPRC:$in, (LO16 imm:$imm)), (HA16 imm:$imm))>;
 876 // OR an arbitrary immediate.
 877 def : Pat<(or GPRC:$in, imm:$imm),
 878           (ORIS (ORI GPRC:$in, (LO16 imm:$imm)), (HI16 imm:$imm))>;
 879 // XOR an arbitrary immediate.
 880 def : Pat<(xor GPRC:$in, imm:$imm),
 881           (XORIS (XORI GPRC:$in, (LO16 imm:$imm)), (HI16 imm:$imm))>;
 882 // SUBFIC
 883 def : Pat<(sub  immSExt16:$imm, GPRC:$in),
 884           (SUBFIC GPRC:$in, imm:$imm)>;
 885
 886 // Return void support.
 887 def : Pat<(ret), (BLR)>;
 888
 889 // SHL/SRL
 890 def : Pat<(shl GPRC:$in, (i32 imm:$imm)),
 891           (RLWINM GPRC:$in, imm:$imm, 0, (SHL32 imm:$imm))>;
 892 def : Pat<(srl GPRC:$in, (i32 imm:$imm)),
 893           (RLWINM GPRC:$in, (SRL32 imm:$imm), imm:$imm, 31)>;
 894
 895 // ROTL
 896 def : Pat<(rotl GPRC:$in, GPRC:$sh),
 897           (RLWNM GPRC:$in, GPRC:$sh, 0, 31)>;
 898 def : Pat<(rotl GPRC:$in, (i32 imm:$imm)),
 899           (RLWINM GPRC:$in, imm:$imm, 0, 31)>;
 900
 901 // Calls
 902 def : Pat<(PPCcall tglobaladdr:$dst),
 903           (BL tglobaladdr:$dst)>;
 904 def : Pat<(PPCcall texternalsym:$dst),
 905           (BL texternalsym:$dst)>;
 906
 907 // Hi and Lo for Darwin Global Addresses.
 908 def : Pat<(PPChi tglobaladdr:$in, 0), (LIS tglobaladdr:$in)>;
 909 def : Pat<(PPClo tglobaladdr:$in, 0), (LI tglobaladdr:$in)>;
 910 def : Pat<(PPChi tconstpool:$in, 0), (LIS tconstpool:$in)>;
 911 def : Pat<(PPClo tconstpool:$in, 0), (LI tconstpool:$in)>;
 912 def : Pat<(PPChi tjumptable:$in, 0), (LIS tjumptable:$in)>;
 913 def : Pat<(PPClo tjumptable:$in, 0), (LI tjumptable:$in)>;
 914 def : Pat<(add GPRC:$in, (PPChi tglobaladdr:$g, 0)),
 915           (ADDIS GPRC:$in, tglobaladdr:$g)>;
 916 def : Pat<(add GPRC:$in, (PPChi tconstpool:$g, 0)),
 917           (ADDIS GPRC:$in, tconstpool:$g)>;
 918 def : Pat<(add GPRC:$in, (PPChi tjumptable:$g, 0)),
 919           (ADDIS GPRC:$in, tjumptable:$g)>;
 920
 921 // Fused negative multiply subtract, alternate pattern
 922 def : Pat<(fsub F8RC:$B, (fmul F8RC:$A, F8RC:$C)),
 923           (FNMSUB F8RC:$A, F8RC:$C, F8RC:$B)>,
 924           Requires<[FPContractions]>;
 925 def : Pat<(fsub F4RC:$B, (fmul F4RC:$A, F4RC:$C)),
 926           (FNMSUBS F4RC:$A, F4RC:$C, F4RC:$B)>,
 927           Requires<[FPContractions]>;
 928
 929 // Standard shifts.  These are represented separately from the real shifts above
 930 // so that we can distinguish between shifts that allow 5-bit and 6-bit shift
 931 // amounts.
 932 def : Pat<(sra GPRC:$rS, GPRC:$rB),
 933           (SRAW GPRC:$rS, GPRC:$rB)>;
 934 def : Pat<(srl GPRC:$rS, GPRC:$rB),
 935           (SRW GPRC:$rS, GPRC:$rB)>;
 936 def : Pat<(shl GPRC:$rS, GPRC:$rB),
 937           (SLW GPRC:$rS, GPRC:$rB)>;
 938
 939 def : Pat<(i32 (zextload iaddr:$src, i1)),
 940           (LBZ iaddr:$src)>;
 941 def : Pat<(i32 (zextload xaddr:$src, i1)),
 942           (LBZX xaddr:$src)>;
 943 def : Pat<(i32 (extload iaddr:$src, i1)),
 944           (LBZ iaddr:$src)>;
 945 def : Pat<(i32 (extload xaddr:$src, i1)),
 946           (LBZX xaddr:$src)>;
 947 def : Pat<(i32 (extload iaddr:$src, i8)),
 948           (LBZ iaddr:$src)>;
 949 def : Pat<(i32 (extload xaddr:$src, i8)),
 950           (LBZX xaddr:$src)>;
 951 def : Pat<(i32 (extload iaddr:$src, i16)),
 952           (LHZ iaddr:$src)>;
 953 def : Pat<(i32 (extload xaddr:$src, i16)),
 954           (LHZX xaddr:$src)>;
 955 def : Pat<(f64 (extload iaddr:$src, f32)),
 956           (FMRSD (LFS iaddr:$src))>;
 957 def : Pat<(f64 (extload xaddr:$src, f32)),
 958           (FMRSD (LFSX xaddr:$src))>;
 959
 960
 961 include "PPCInstrAltivec.td"
 962 include "PPCInstr64Bit.td"