lib/Target/PowerPC/PPCInstrInfo.td

   1 //===- PowerPCInstrInfo.td - The PowerPC Instruction Set -----*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the subset of the 32-bit PowerPC instruction set, as used
  11 // by the PowerPC instruction selector.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 include "PowerPCInstrFormats.td"
  16
  17 //===----------------------------------------------------------------------===//
  18 // Selection DAG Type Constraint definitions.
  19 //
  20 // Note that the semantics of these constraints are hard coded into tblgen.  To
  21 // modify or add constraints, you have to hack tblgen.
  22 //
  23
  24 class SDTypeConstraint<int opnum> {
  25   int OperandNum = opnum;
  26 }
  27
  28 // SDTCisVT - The specified operand has exactly this VT.
  29 class SDTCisVT <int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  30   ValueType VT = vt;
  31 }
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP <int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 //===----------------------------------------------------------------------===//
  51 // Selection DAG Type Profile definitions.
  52 //
  53 // These use the constraints defined above to describe the type requirements of
  54 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  55 // add their own if needed.
  56 //
  57
  58 // SDTypeProfile - This profile describes the type requirements of a Selection
  59 // DAG node.
  60 class SDTypeProfile<int numresults, int numoperands,
  61                     list<SDTypeConstraint> constraints> {
  62   int NumResults = numresults;
  63   int NumOperands = numoperands;
  64   list<SDTypeConstraint> Constraints = constraints;
  65 }
  66
  67 // Builtin profiles.
  68 def SDTImm    : SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  69 def SDTVT     : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'
  70 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  71   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  72 ]>;
  73 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  74   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  75 ]>;
  76 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
  77   SDTCisSameAs<0, 1>, SDTCisInt<0>
  78 ]>;
  79 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
  80   SDTCisSameAs<0, 1>, SDTCisFP<0>
  81 ]>;
  82 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
  83   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
  84   SDTCisVTSmallerThanOp<2, 1>
  85 ]>;
  86
  87 //===----------------------------------------------------------------------===//
  88 // Selection DAG Node Properties.
  89 //
  90 // Note: These are hard coded into tblgen.
  91 //
  92 class SDNodeProperty;
  93 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
  94 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
  95
  96 //===----------------------------------------------------------------------===//
  97 // Selection DAG Node definitions.
  98 //
  99 class SDNode<string opcode, SDTypeProfile typeprof,
 100              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 101   string Opcode  = opcode;
 102   string SDClass = sdclass;
 103   list<SDNodeProperty> Properties = props;
 104   SDTypeProfile TypeProfile = typeprof;
 105 }
 106
 107 def set;
 108 def node;
 109
 110 def imm        : SDNode<"ISD::Constant"  , SDTImm     , [], "ConstantSDNode">;
 111 def vt         : SDNode<"ISD::VALUETYPE" , SDTVT      , [], "VTSDNode">;
 112 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 113                         [SDNPCommutative, SDNPAssociative]>;
 114 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 115 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 116                         [SDNPCommutative, SDNPAssociative]>;
 117 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 118 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 119 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 120 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 121 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 122 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 123 def srl        : SDNode<"ISD::SRL"       , SDTIntBinOp>;
 124 def sra        : SDNode<"ISD::SRA"       , SDTIntBinOp>;
 125 def shl        : SDNode<"ISD::SHL"       , SDTIntBinOp>;
 126 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 127                         [SDNPCommutative, SDNPAssociative]>;
 128 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 129                         [SDNPCommutative, SDNPAssociative]>;
 130 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 131                         [SDNPCommutative, SDNPAssociative]>;
 132 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 133 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 134 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 135 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 136 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 137 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 138 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 139 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 140
 141 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 142 def ctlz       : SDNode<"ISD::CTLZ"      , SDTIntUnaryOp>;
 143
 144 //===----------------------------------------------------------------------===//
 145 // Selection DAG Node Transformation Functions.
 146 //
 147 // This mechanism allows targets to manipulate nodes in the output DAG once a
 148 // match has been formed.  This is typically used to manipulate immediate
 149 // values.
 150 //
 151 class SDNodeXForm<SDNode opc, code xformFunction> {
 152   SDNode Opcode = opc;
 153   code XFormFunction = xformFunction;
 154 }
 155
 156 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 157
 158
 159 //===----------------------------------------------------------------------===//
 160 // Selection DAG Pattern Fragments.
 161 //
 162 // Pattern fragments are reusable chunks of dags that match specific things.
 163 // They can take arguments and have C++ predicates that control whether they
 164 // match.  They are intended to make the patterns for common instructions more
 165 // compact and readable.
 166 //
 167
 168 /// PatFrag - Represents a pattern fragment.  This can match something on the
 169 /// DAG, frame a single node to multiply nested other fragments.
 170 ///
 171 class PatFrag<dag ops, dag frag, code pred = [{}],
 172               SDNodeXForm xform = NOOP_SDNodeXForm> {
 173   dag Operands = ops;
 174   dag Fragment = frag;
 175   code Predicate = pred;
 176   SDNodeXForm OperandTransform = xform;
 177 }
 178
 179 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 180 // to define immediates and other common things concisely.
 181 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 182  : PatFrag<(ops), frag, pred, xform>;
 183
 184 // Leaf fragments.
 185
 186 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 187 def immZero    : PatLeaf<(imm), [{ return N->isNullValue();    }]>;
 188
 189 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 190 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 191
 192 // Other helper fragments.
 193
 194 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 195 def ineg : PatFrag<(ops node:$in), (sub immZero, node:$in)>;
 196
 197 //===----------------------------------------------------------------------===//
 198 // Selection DAG Pattern Support.
 199 //
 200 // Patterns are what are actually matched against the target-flavored
 201 // instruction selection DAG.  Instructions defined by the target implicitly
 202 // define patterns in most cases, but patterns can also be explicitly added when
 203 // an operation is defined by a sequence of instructions (e.g. loading a large
 204 // immediate value on RISC targets that do not support immediates as large as
 205 // their GPRs).
 206 //
 207
 208 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 209   dag       PatternToMatch = patternToMatch;
 210   list<dag> ResultInstrs   = resultInstrs;
 211 }
 212
 213 // Pat - A simple (but common) form of a pattern, which produces a simple result
 214 // not needing a full list.
 215 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 216
 217 //===----------------------------------------------------------------------===//
 218 // PowerPC specific transformation functions and pattern fragments.
 219 //
 220 def LO16 : SDNodeXForm<imm, [{
 221   // Transformation function: get the low 16 bits.
 222   return getI32Imm((unsigned short)N->getValue());
 223 }]>;
 224
 225 def HI16 : SDNodeXForm<imm, [{
 226   // Transformation function: shift the immediate value down into the low bits.
 227   return getI32Imm((unsigned)N->getValue() >> 16);
 228 }]>;
 229
 230 def HA16 : SDNodeXForm<imm, [{
 231   // Transformation function: shift the immediate value down into the low bits.
 232   signed int Val = N->getValue();
 233   return getI32Imm((Val - (signed short)Val) >> 16);
 234 }]>;
 235
 236
 237 def immSExt16  : PatLeaf<(imm), [{
 238   // immSExt16 predicate - True if the immediate fits in a 16-bit sign extended
 239   // field.  Used by instructions like 'addi'.
 240   return (int)N->getValue() == (short)N->getValue();
 241 }]>;
 242 def immZExt16  : PatLeaf<(imm), [{
 243   // immZExt16 predicate - True if the immediate fits in a 16-bit zero extended
 244   // field.  Used by instructions like 'ori'.
 245   return (unsigned)N->getValue() == (unsigned short)N->getValue();
 246 }], LO16>;
 247
 248 def imm16Shifted : PatLeaf<(imm), [{
 249   // imm16Shifted predicate - True if only bits in the top 16-bits of the
 250   // immediate are set.  Used by instructions like 'addis'.
 251   return ((unsigned)N->getValue() & 0xFFFF0000U) == (unsigned)N->getValue();
 252 }], HI16>;
 253
 254 /*
 255 // Example of a legalize expander: Only for PPC64.
 256 def : Expander<(set i64:$dst, (fp_to_sint f64:$src)),
 257                [(set f64:$tmp , (FCTIDZ f64:$src)),
 258                 (set i32:$tmpFI, (CreateNewFrameIndex 8, 8)),
 259                 (store f64:$tmp, i32:$tmpFI),
 260                 (set i64:$dst, (load i32:$tmpFI))],
 261                 Subtarget_PPC64>;
 262 */
 263
 264 //===----------------------------------------------------------------------===//
 265 // PowerPC Flag Definitions.
 266
 267 class isPPC64 { bit PPC64 = 1; }
 268 class isVMX   { bit VMX = 1; }
 269 class isDOT   {
 270   list<Register> Defs = [CR0];
 271   bit RC  = 1;
 272 }
 273
 274
 275
 276 //===----------------------------------------------------------------------===//
 277 // PowerPC Operand Definitions.
 278
 279 def u5imm   : Operand<i32> {
 280   let PrintMethod = "printU5ImmOperand";
 281 }
 282 def u6imm   : Operand<i32> {
 283   let PrintMethod = "printU6ImmOperand";
 284 }
 285 def s16imm  : Operand<i32> {
 286   let PrintMethod = "printS16ImmOperand";
 287 }
 288 def u16imm  : Operand<i32> {
 289   let PrintMethod = "printU16ImmOperand";
 290 }
 291 def target : Operand<i32> {
 292   let PrintMethod = "printBranchOperand";
 293 }
 294 def piclabel: Operand<i32> {
 295   let PrintMethod = "printPICLabel";
 296 }
 297 def symbolHi: Operand<i32> {
 298   let PrintMethod = "printSymbolHi";
 299 }
 300 def symbolLo: Operand<i32> {
 301   let PrintMethod = "printSymbolLo";
 302 }
 303 def crbitm: Operand<i8> {
 304   let PrintMethod = "printcrbitm";
 305 }
 306
 307
 308
 309 //===----------------------------------------------------------------------===//
 310 // PowerPC Instruction Definitions.
 311
 312 // Pseudo-instructions:
 313 def PHI : Pseudo<(ops variable_ops), "; PHI">;
 314
 315 let isLoad = 1 in {
 316 def ADJCALLSTACKDOWN : Pseudo<(ops u16imm:$amt), "; ADJCALLSTACKDOWN">;
 317 def ADJCALLSTACKUP : Pseudo<(ops u16imm:$amt), "; ADJCALLSTACKUP">;
 318 }
 319 def IMPLICIT_DEF_GPR : Pseudo<(ops GPRC:$rD), "; $rD = IMPLICIT_DEF_GPRC">;
 320 def IMPLICIT_DEF_FP  : Pseudo<(ops FPRC:$rD), "; %rD = IMPLICIT_DEF_FP">;
 321
 322 // SELECT_CC_* - Used to implement the SELECT_CC DAG operation.  Expanded by the
 323 // scheduler into a branch sequence.
 324 let usesCustomDAGSchedInserter = 1 in {  // Expanded by the scheduler.
 325   def SELECT_CC_Int : Pseudo<(ops GPRC:$dst, CRRC:$cond, GPRC:$T, GPRC:$F,
 326                               i32imm:$BROPC), "; SELECT_CC PSEUDO!">;
 327   def SELECT_CC_FP  : Pseudo<(ops FPRC:$dst, CRRC:$cond, FPRC:$T, FPRC:$F,
 328                               i32imm:$BROPC), "; SELECT_CC PSEUDO!">;
 329 }
 330
 331
 332 let isTerminator = 1 in {
 333   let isReturn = 1 in
 334     def BLR : XLForm_2_ext<19, 16, 20, 0, 0, (ops), "blr">;
 335   def BCTR : XLForm_2_ext<19, 528, 20, 0, 0, (ops), "bctr">;
 336 }
 337
 338 let Defs = [LR] in
 339   def MovePCtoLR : Pseudo<(ops piclabel:$label), "bl $label">;
 340
 341 let isBranch = 1, isTerminator = 1 in {
 342   def COND_BRANCH : Pseudo<(ops CRRC:$crS, u16imm:$opc,
 343                                 target:$true, target:$false),
 344                            "; COND_BRANCH">;
 345   def B   : IForm<18, 0, 0, (ops target:$func), "b $func">;
 346 //def BA  : IForm<18, 1, 0, (ops target:$func), "ba $func">;
 347   def BL  : IForm<18, 0, 1, (ops target:$func), "bl $func">;
 348 //def BLA : IForm<18, 1, 1, (ops target:$func), "bla $func">;
 349
 350   // FIXME: 4*CR# needs to be added to the BI field!
 351   // This will only work for CR0 as it stands now
 352   def BLT : BForm<16, 0, 0, 12, 0, (ops CRRC:$crS, target:$block),
 353                   "blt $crS, $block">;
 354   def BLE : BForm<16, 0, 0, 4,  1, (ops CRRC:$crS, target:$block),
 355                   "ble $crS, $block">;
 356   def BEQ : BForm<16, 0, 0, 12, 2, (ops CRRC:$crS, target:$block),
 357                   "beq $crS, $block">;
 358   def BGE : BForm<16, 0, 0, 4,  0, (ops CRRC:$crS, target:$block),
 359                   "bge $crS, $block">;
 360   def BGT : BForm<16, 0, 0, 12, 1, (ops CRRC:$crS, target:$block),
 361                   "bgt $crS, $block">;
 362   def BNE : BForm<16, 0, 0, 4,  2, (ops CRRC:$crS, target:$block),
 363                   "bne $crS, $block">;
 364 }
 365
 366 let isCall = 1,
 367   // All calls clobber the non-callee saved registers...
 368   Defs = [R0,R2,R3,R4,R5,R6,R7,R8,R9,R10,R11,R12,
 369           F0,F1,F2,F3,F4,F5,F6,F7,F8,F9,F10,F11,F12,F13,
 370           LR,CTR,
 371           CR0,CR1,CR5,CR6,CR7] in {
 372   // Convenient aliases for call instructions
 373   def CALLpcrel : IForm<18, 0, 1, (ops target:$func, variable_ops), "bl $func">;
 374   def CALLindirect : XLForm_2_ext<19, 528, 20, 0, 1,
 375                                   (ops variable_ops), "bctrl">;
 376 }
 377
 378 // D-Form instructions.  Most instructions that perform an operation on a
 379 // register and an immediate are of this type.
 380 //
 381 let isLoad = 1 in {
 382 def LBZ : DForm_1<34, (ops GPRC:$rD, symbolLo:$disp, GPRC:$rA),
 383                   "lbz $rD, $disp($rA)">;
 384 def LHA : DForm_1<42, (ops GPRC:$rD, symbolLo:$disp, GPRC:$rA),
 385                   "lha $rD, $disp($rA)">;
 386 def LHZ : DForm_1<40, (ops GPRC:$rD, symbolLo:$disp, GPRC:$rA),
 387                   "lhz $rD, $disp($rA)">;
 388 def LMW : DForm_1<46, (ops GPRC:$rD, s16imm:$disp, GPRC:$rA),
 389                   "lmw $rD, $disp($rA)">;
 390 def LWZ : DForm_1<32, (ops GPRC:$rD, symbolLo:$disp, GPRC:$rA),
 391                   "lwz $rD, $disp($rA)">;
 392 def LWZU : DForm_1<35, (ops GPRC:$rD, s16imm:$disp, GPRC:$rA),
 393                    "lwzu $rD, $disp($rA)">;
 394 }
 395 def ADDI   : DForm_2<14, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 396                      "addi $rD, $rA, $imm",
 397                      [(set GPRC:$rD, (add GPRC:$rA, immSExt16:$imm))]>;
 398 def ADDIC  : DForm_2<12, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 399                      "addic $rD, $rA, $imm",
 400                      []>;
 401 def ADDICo : DForm_2<13, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 402                      "addic. $rD, $rA, $imm",
 403                      []>;
 404 def ADDIS  : DForm_2<15, (ops GPRC:$rD, GPRC:$rA, symbolHi:$imm),
 405                      "addis $rD, $rA, $imm",
 406                      [(set GPRC:$rD, (add GPRC:$rA, imm16Shifted:$imm))]>;
 407 def LA     : DForm_2<14, (ops GPRC:$rD, GPRC:$rA, symbolLo:$sym),
 408                      "la $rD, $sym($rA)",
 409                      []>;
 410 def MULLI  : DForm_2< 7, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 411                      "mulli $rD, $rA, $imm",
 412                      [(set GPRC:$rD, (mul GPRC:$rA, immSExt16:$imm))]>;
 413 def SUBFIC : DForm_2< 8, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 414                      "subfic $rD, $rA, $imm",
 415                      [(set GPRC:$rD, (sub immSExt16:$imm, GPRC:$rA))]>;
 416 def LI  : DForm_2_r0<14, (ops GPRC:$rD, s16imm:$imm),
 417                      "li $rD, $imm",
 418                      [(set GPRC:$rD, immSExt16:$imm)]>;
 419 def LIS : DForm_2_r0<15, (ops GPRC:$rD, symbolHi:$imm),
 420                      "lis $rD, $imm",
 421                      [(set GPRC:$rD, imm16Shifted:$imm)]>;
 422 let isStore = 1 in {
 423 def STMW : DForm_3<47, (ops GPRC:$rS, s16imm:$disp, GPRC:$rA),
 424                    "stmw $rS, $disp($rA)">;
 425 def STB  : DForm_3<38, (ops GPRC:$rS, symbolLo:$disp, GPRC:$rA),
 426                    "stb $rS, $disp($rA)">;
 427 def STH  : DForm_3<44, (ops GPRC:$rS, symbolLo:$disp, GPRC:$rA),
 428                    "sth $rS, $disp($rA)">;
 429 def STW  : DForm_3<36, (ops GPRC:$rS, symbolLo:$disp, GPRC:$rA),
 430                    "stw $rS, $disp($rA)">;
 431 def STWU : DForm_3<37, (ops GPRC:$rS, s16imm:$disp, GPRC:$rA),
 432                    "stwu $rS, $disp($rA)">;
 433 }
 434 def ANDIo : DForm_4<28, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 435                     "andi. $dst, $src1, $src2",
 436                     []>, isDOT;
 437 def ANDISo : DForm_4<29, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 438                     "andis. $dst, $src1, $src2",
 439                     []>, isDOT;
 440 def ORI   : DForm_4<24, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 441                     "ori $dst, $src1, $src2",
 442                     [(set GPRC:$dst, (or GPRC:$src1, immZExt16:$src2))]>;
 443 def ORIS  : DForm_4<25, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 444                     "oris $dst, $src1, $src2",
 445                     [(set GPRC:$dst, (or GPRC:$src1, imm16Shifted:$src2))]>;
 446 def XORI  : DForm_4<26, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 447                     "xori $dst, $src1, $src2",
 448                     [(set GPRC:$dst, (xor GPRC:$src1, immZExt16:$src2))]>;
 449 def XORIS : DForm_4<27, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 450                     "xoris $dst, $src1, $src2",
 451                     [(set GPRC:$dst, (xor GPRC:$src1, imm16Shifted:$src2))]>;
 452 def NOP   : DForm_4_zero<24, (ops), "nop">;
 453 def CMPI  : DForm_5<11, (ops CRRC:$crD, i1imm:$L, GPRC:$rA, s16imm:$imm),
 454                     "cmpi $crD, $L, $rA, $imm">;
 455 def CMPWI : DForm_5_ext<11, (ops CRRC:$crD, GPRC:$rA, s16imm:$imm),
 456                         "cmpwi $crD, $rA, $imm">;
 457 def CMPDI : DForm_5_ext<11, (ops CRRC:$crD, GPRC:$rA, s16imm:$imm),
 458                         "cmpdi $crD, $rA, $imm">, isPPC64;
 459 def CMPLI  : DForm_6<10, (ops CRRC:$dst, i1imm:$size, GPRC:$src1, u16imm:$src2),
 460                      "cmpli $dst, $size, $src1, $src2">;
 461 def CMPLWI : DForm_6_ext<10, (ops CRRC:$dst, GPRC:$src1, u16imm:$src2),
 462                          "cmplwi $dst, $src1, $src2">;
 463 def CMPLDI : DForm_6_ext<10, (ops CRRC:$dst, GPRC:$src1, u16imm:$src2),
 464                          "cmpldi $dst, $src1, $src2">, isPPC64;
 465 let isLoad = 1 in {
 466 def LFS : DForm_8<48, (ops FPRC:$rD, symbolLo:$disp, GPRC:$rA),
 467                   "lfs $rD, $disp($rA)">;
 468 def LFD : DForm_8<50, (ops FPRC:$rD, symbolLo:$disp, GPRC:$rA),
 469                   "lfd $rD, $disp($rA)">;
 470 }
 471 let isStore = 1 in {
 472 def STFS : DForm_9<52, (ops FPRC:$rS, symbolLo:$disp, GPRC:$rA),
 473                    "stfs $rS, $disp($rA)">;
 474 def STFD : DForm_9<54, (ops FPRC:$rS, symbolLo:$disp, GPRC:$rA),
 475                    "stfd $rS, $disp($rA)">;
 476 }
 477
 478 // DS-Form instructions.  Load/Store instructions available in PPC-64
 479 //
 480 let isLoad = 1 in {
 481 def LWA  : DSForm_1<58, 2, (ops GPRC:$rT, s16imm:$DS, GPRC:$rA),
 482                     "lwa $rT, $DS($rA)">, isPPC64;
 483 def LD   : DSForm_2<58, 0, (ops GPRC:$rT, s16imm:$DS, GPRC:$rA),
 484                     "ld $rT, $DS($rA)">, isPPC64;
 485 }
 486 let isStore = 1 in {
 487 def STD  : DSForm_2<62, 0, (ops GPRC:$rT, s16imm:$DS, GPRC:$rA),
 488                     "std $rT, $DS($rA)">, isPPC64;
 489 def STDU : DSForm_2<62, 1, (ops GPRC:$rT, s16imm:$DS, GPRC:$rA),
 490                     "stdu $rT, $DS($rA)">, isPPC64;
 491 }
 492
 493 // X-Form instructions.  Most instructions that perform an operation on a
 494 // register and another register are of this type.
 495 //
 496 let isLoad = 1 in {
 497 def LBZX : XForm_1<31,  87, (ops GPRC:$dst, GPRC:$base, GPRC:$index),
 498                    "lbzx $dst, $base, $index">;
 499 def LHAX : XForm_1<31, 343, (ops GPRC:$dst, GPRC:$base, GPRC:$index),
 500                    "lhax $dst, $base, $index">;
 501 def LHZX : XForm_1<31, 279, (ops GPRC:$dst, GPRC:$base, GPRC:$index),
 502                    "lhzx $dst, $base, $index">;
 503 def LWAX : XForm_1<31, 341, (ops GPRC:$dst, GPRC:$base, GPRC:$index),
 504                    "lwax $dst, $base, $index">, isPPC64;
 505 def LWZX : XForm_1<31,  23, (ops GPRC:$dst, GPRC:$base, GPRC:$index),
 506                    "lwzx $dst, $base, $index">;
 507 def LDX  : XForm_1<31,  21, (ops GPRC:$dst, GPRC:$base, GPRC:$index),
 508                    "ldx $dst, $base, $index">, isPPC64;
 509 }
 510 def NAND : XForm_6<31, 476, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 511                    "nand $rA, $rS, $rB",
 512                    [(set GPRC:$rA, (not (and GPRC:$rS, GPRC:$rB)))]>;
 513 def AND  : XForm_6<31,  28, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 514                    "and $rA, $rS, $rB",
 515                    [(set GPRC:$rA, (and GPRC:$rS, GPRC:$rB))]>;
 516 def ANDo : XForm_6<31,  28, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 517                    "and. $rA, $rS, $rB",
 518                    []>, isDOT;
 519 def ANDC : XForm_6<31,  60, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 520                    "andc $rA, $rS, $rB",
 521                    [(set GPRC:$rA, (and GPRC:$rS, (not GPRC:$rB)))]>;
 522 def OR   : XForm_6<31, 444, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 523                    "or $rA, $rS, $rB",
 524                    [(set GPRC:$rA, (or GPRC:$rS, GPRC:$rB))]>;
 525 def NOR  : XForm_6<31, 124, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 526                    "nor $rA, $rS, $rB",
 527                    [(set GPRC:$rA, (not (or GPRC:$rS, GPRC:$rB)))]>;
 528 def ORo  : XForm_6<31, 444, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 529                    "or. $rA, $rS, $rB",
 530                    []>, isDOT;
 531 def ORC  : XForm_6<31, 412, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 532                    "orc $rA, $rS, $rB",
 533                    [(set GPRC:$rA, (or GPRC:$rS, (not GPRC:$rB)))]>;
 534 def EQV  : XForm_6<31, 284, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 535                    "eqv $rA, $rS, $rB",
 536                    [(set GPRC:$rA, (not (xor GPRC:$rS, GPRC:$rB)))]>;
 537 def XOR  : XForm_6<31, 316, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 538                    "xor $rA, $rS, $rB",
 539                    [(set GPRC:$rA, (xor GPRC:$rS, GPRC:$rB))]>;
 540 def SLD  : XForm_6<31,  27, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 541                    "sld $rA, $rS, $rB",
 542                    []>, isPPC64;
 543 def SLW  : XForm_6<31,  24, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 544                    "slw $rA, $rS, $rB",
 545                    [(set GPRC:$rA, (shl GPRC:$rS, GPRC:$rB))]>;
 546 def SRD  : XForm_6<31, 539, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 547                    "srd $rA, $rS, $rB",
 548                    []>, isPPC64;
 549 def SRW  : XForm_6<31, 536, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 550                    "srw $rA, $rS, $rB",
 551                    [(set GPRC:$rA, (srl GPRC:$rS, GPRC:$rB))]>;
 552 def SRAD : XForm_6<31, 794, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 553                    "srad $rA, $rS, $rB",
 554                    []>, isPPC64;
 555 def SRAW : XForm_6<31, 792, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 556                    "sraw $rA, $rS, $rB",
 557                    [(set GPRC:$rA, (sra GPRC:$rS, GPRC:$rB))]>;
 558 let isStore = 1 in {
 559 def STBX  : XForm_8<31, 215, (ops GPRC:$rS, GPRC:$rA, GPRC:$rB),
 560                    "stbx $rS, $rA, $rB">;
 561 def STHX  : XForm_8<31, 407, (ops GPRC:$rS, GPRC:$rA, GPRC:$rB),
 562                    "sthx $rS, $rA, $rB">;
 563 def STWX  : XForm_8<31, 151, (ops GPRC:$rS, GPRC:$rA, GPRC:$rB),
 564                    "stwx $rS, $rA, $rB">;
 565 def STWUX : XForm_8<31, 183, (ops GPRC:$rS, GPRC:$rA, GPRC:$rB),
 566                    "stwux $rS, $rA, $rB">;
 567 def STDX  : XForm_8<31, 149, (ops GPRC:$rS, GPRC:$rA, GPRC:$rB),
 568                    "stdx $rS, $rA, $rB">, isPPC64;
 569 def STDUX : XForm_8<31, 181, (ops GPRC:$rS, GPRC:$rA, GPRC:$rB),
 570                    "stdux $rS, $rA, $rB">, isPPC64;
 571 }
 572 def SRAWI : XForm_10<31, 824, (ops GPRC:$rA, GPRC:$rS, u5imm:$SH),
 573                      "srawi $rA, $rS, $SH",
 574                      [(set GPRC:$rA, (sra GPRC:$rS, imm:$SH))]>;
 575 def CNTLZW : XForm_11<31,  26, (ops GPRC:$rA, GPRC:$rS),
 576                       "cntlzw $rA, $rS",
 577                       [(set GPRC:$rA, (ctlz GPRC:$rS))]>;
 578 def EXTSB  : XForm_11<31, 954, (ops GPRC:$rA, GPRC:$rS),
 579                       "extsb $rA, $rS",
 580                       [(set GPRC:$rA, (sext_inreg GPRC:$rS, i8))]>;
 581 def EXTSH  : XForm_11<31, 922, (ops GPRC:$rA, GPRC:$rS),
 582                       "extsh $rA, $rS",
 583                       [(set GPRC:$rA, (sext_inreg GPRC:$rS, i16))]>;
 584 def EXTSW  : XForm_11<31, 986, (ops GPRC:$rA, GPRC:$rS),
 585                       "extsw $rA, $rS",
 586                       []>, isPPC64;
 587 def CMP    : XForm_16<31, 0, (ops CRRC:$crD, i1imm:$long, GPRC:$rA, GPRC:$rB),
 588                       "cmp $crD, $long, $rA, $rB">;
 589 def CMPL   : XForm_16<31, 32, (ops CRRC:$crD, i1imm:$long, GPRC:$rA, GPRC:$rB),
 590                       "cmpl $crD, $long, $rA, $rB">;
 591 def CMPW   : XForm_16_ext<31, 0, (ops CRRC:$crD, GPRC:$rA, GPRC:$rB),
 592                           "cmpw $crD, $rA, $rB">;
 593 def CMPD   : XForm_16_ext<31, 0, (ops CRRC:$crD, GPRC:$rA, GPRC:$rB),
 594                           "cmpd $crD, $rA, $rB">, isPPC64;
 595 def CMPLW  : XForm_16_ext<31, 32, (ops CRRC:$crD, GPRC:$rA, GPRC:$rB),
 596                           "cmplw $crD, $rA, $rB">;
 597 def CMPLD  : XForm_16_ext<31, 32, (ops CRRC:$crD, GPRC:$rA, GPRC:$rB),
 598                           "cmpld $crD, $rA, $rB">, isPPC64;
 599 def FCMPO  : XForm_17<63, 32, (ops CRRC:$crD, FPRC:$fA, FPRC:$fB),
 600                       "fcmpo $crD, $fA, $fB">;
 601 def FCMPU  : XForm_17<63, 0, (ops CRRC:$crD, FPRC:$fA, FPRC:$fB),
 602                       "fcmpu $crD, $fA, $fB">;
 603 let isLoad = 1 in {
 604 def LFSX   : XForm_25<31, 535, (ops FPRC:$dst, GPRC:$base, GPRC:$index),
 605                       "lfsx $dst, $base, $index">;
 606 def LFDX   : XForm_25<31, 599, (ops FPRC:$dst, GPRC:$base, GPRC:$index),
 607                       "lfdx $dst, $base, $index">;
 608 }
 609 def FCFID  : XForm_26<63, 846, (ops FPRC:$frD, FPRC:$frB),
 610                       "fcfid $frD, $frB",
 611                       []>, isPPC64;
 612 def FCTIDZ : XForm_26<63, 815, (ops FPRC:$frD, FPRC:$frB),
 613                       "fctidz $frD, $frB",
 614                       []>, isPPC64;
 615 def FCTIWZ : XForm_26<63, 15, (ops FPRC:$frD, FPRC:$frB),
 616                       "fctiwz $frD, $frB",
 617                       []>;
 618 def FABS   : XForm_26<63, 264, (ops FPRC:$frD, FPRC:$frB),
 619                       "fabs $frD, $frB",
 620                       [(set FPRC:$frD, (fabs FPRC:$frB))]>;
 621 def FMR    : XForm_26<63, 72, (ops FPRC:$frD, FPRC:$frB),
 622                       "fmr $frD, $frB",
 623                       []>;  // (set FPRC:$frD, FPRC:$frB)
 624 def FNABS  : XForm_26<63, 136, (ops FPRC:$frD, FPRC:$frB),
 625                       "fnabs $frD, $frB",
 626                       [(set FPRC:$frD, (fneg (fabs FPRC:$frB)))]>;
 627 def FNEG   : XForm_26<63, 40, (ops FPRC:$frD, FPRC:$frB),
 628                       "fneg $frD, $frB",
 629                       [(set FPRC:$frD, (fneg FPRC:$frB))]>;
 630 def FRSP   : XForm_26<63, 12, (ops FPRC:$frD, FPRC:$frB),
 631                       "frsp $frD, $frB",
 632                       []>;
 633 def FSQRT  : XForm_26<63, 22, (ops FPRC:$frD, FPRC:$frB),
 634                       "fsqrt $frD, $frB",
 635                       [(set FPRC:$frD, (fsqrt FPRC:$frB))]>;
 636 def FSQRTS : XForm_26<59, 22, (ops FPRC:$frD, FPRC:$frB),
 637                       "fsqrts $frD, $frB",
 638                       []>;
 639
 640 let isStore = 1 in {
 641 def STFSX : XForm_28<31, 663, (ops FPRC:$frS, GPRC:$rA, GPRC:$rB),
 642                      "stfsx $frS, $rA, $rB">;
 643 def STFDX : XForm_28<31, 727, (ops FPRC:$frS, GPRC:$rA, GPRC:$rB),
 644                      "stfdx $frS, $rA, $rB">;
 645 }
 646
 647 // XL-Form instructions.  condition register logical ops.
 648 //
 649 def MCRF   : XLForm_3<19, 0, (ops CRRC:$BF, CRRC:$BFA),
 650                       "mcrf $BF, $BFA">;
 651
 652 // XFX-Form instructions.  Instructions that deal with SPRs
 653 //
 654 // Note that although LR should be listed as `8' and CTR as `9' in the SPR
 655 // field, the manual lists the groups of bits as [5-9] = 0, [0-4] = 8 or 9
 656 // which means the SPR value needs to be multiplied by a factor of 32.
 657 def MFCTR : XFXForm_1_ext<31, 339, 288, (ops GPRC:$rT), "mfctr $rT">;
 658 def MFLR  : XFXForm_1_ext<31, 339, 256, (ops GPRC:$rT), "mflr $rT">;
 659 def MFCR  : XFXForm_3<31, 19, (ops GPRC:$rT), "mfcr $rT">;
 660 def MTCRF : XFXForm_5<31, 144, (ops crbitm:$FXM, GPRC:$rS),
 661                       "mtcrf $FXM, $rS">;
 662 def MFOCRF : XFXForm_5a<31, 19, (ops GPRC:$rT, crbitm:$FXM),
 663                         "mfcr $rT, $FXM">;
 664 def MTCTR : XFXForm_7_ext<31, 467, 288, (ops GPRC:$rS), "mtctr $rS">;
 665 def MTLR  : XFXForm_7_ext<31, 467, 256, (ops GPRC:$rS), "mtlr $rS">;
 666
 667 // XS-Form instructions.  Just 'sradi'
 668 //
 669 def SRADI  : XSForm_1<31, 413, (ops GPRC:$rA, GPRC:$rS, u6imm:$SH),
 670                       "sradi $rA, $rS, $SH">, isPPC64;
 671
 672 // XO-Form instructions.  Arithmetic instructions that can set overflow bit
 673 //
 674 def ADD   : XOForm_1<31, 266, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 675                      "add $rT, $rA, $rB",
 676                      [(set GPRC:$rT, (add GPRC:$rA, GPRC:$rB))]>;
 677 def ADDC  : XOForm_1<31, 10, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 678                      "addc $rT, $rA, $rB",
 679                      []>;
 680 def ADDE  : XOForm_1<31, 138, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 681                      "adde $rT, $rA, $rB",
 682                      []>;
 683 def DIVD  : XOForm_1<31, 489, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 684                      "divd $rT, $rA, $rB",
 685                      []>, isPPC64;
 686 def DIVDU : XOForm_1<31, 457, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 687                      "divdu $rT, $rA, $rB",
 688                      []>, isPPC64;
 689 def DIVW  : XOForm_1<31, 491, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 690                      "divw $rT, $rA, $rB",
 691                      [(set GPRC:$rT, (sdiv GPRC:$rA, GPRC:$rB))]>;
 692 def DIVWU : XOForm_1<31, 459, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 693                      "divwu $rT, $rA, $rB",
 694                      [(set GPRC:$rT, (udiv GPRC:$rA, GPRC:$rB))]>;
 695 def MULHW : XOForm_1<31, 75, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 696                      "mulhw $rT, $rA, $rB",
 697                      [(set GPRC:$rT, (mulhs GPRC:$rA, GPRC:$rB))]>;
 698 def MULHWU : XOForm_1<31, 11, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 699                      "mulhwu $rT, $rA, $rB",
 700                      [(set GPRC:$rT, (mulhu GPRC:$rA, GPRC:$rB))]>;
 701 def MULLD : XOForm_1<31, 233, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 702                      "mulld $rT, $rA, $rB",
 703                      []>, isPPC64;
 704 def MULLW : XOForm_1<31, 235, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 705                      "mullw $rT, $rA, $rB",
 706                      [(set GPRC:$rT, (mul GPRC:$rA, GPRC:$rB))]>;
 707 def SUBF  : XOForm_1<31, 40, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 708                      "subf $rT, $rA, $rB",
 709                      [(set GPRC:$rT, (sub GPRC:$rB, GPRC:$rA))]>;
 710 def SUBFC : XOForm_1<31, 8, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 711                      "subfc $rT, $rA, $rB",
 712                      []>;
 713 def SUBFE : XOForm_1<31, 136, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 714                      "subfe $rT, $rA, $rB",
 715                      []>;
 716 def ADDME  : XOForm_3<31, 234, 0, (ops GPRC:$rT, GPRC:$rA),
 717                       "addme $rT, $rA",
 718                       []>;
 719 def ADDZE  : XOForm_3<31, 202, 0, (ops GPRC:$rT, GPRC:$rA),
 720                       "addze $rT, $rA",
 721                       []>;
 722 def NEG    : XOForm_3<31, 104, 0, (ops GPRC:$rT, GPRC:$rA),
 723                       "neg $rT, $rA",
 724                       [(set GPRC:$rT, (ineg GPRC:$rA))]>;
 725 def SUBFZE : XOForm_3<31, 200, 0, (ops GPRC:$rT, GPRC:$rA),
 726                       "subfze $rT, $rA",
 727                       []>;
 728
 729 // A-Form instructions.  Most of the instructions executed in the FPU are of
 730 // this type.
 731 //
 732 def FMADD : AForm_1<63, 29,
 733                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRC, FPRC:$FRB),
 734                     "fmadd $FRT, $FRA, $FRC, $FRB",
 735                     [(set FPRC:$FRT, (fadd (fmul FPRC:$FRA, FPRC:$FRC),
 736                                            FPRC:$FRB))]>;
 737 def FMADDS : AForm_1<59, 29,
 738                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRC, FPRC:$FRB),
 739                     "fmadds $FRT, $FRA, $FRC, $FRB",
 740                     []>;
 741 def FMSUB : AForm_1<63, 28,
 742                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRC, FPRC:$FRB),
 743                     "fmsub $FRT, $FRA, $FRC, $FRB",
 744                     [(set FPRC:$FRT, (fsub (fmul FPRC:$FRA, FPRC:$FRC),
 745                                            FPRC:$FRB))]>;
 746 def FMSUBS : AForm_1<59, 28,
 747                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRC, FPRC:$FRB),
 748                     "fmsubs $FRT, $FRA, $FRC, $FRB",
 749                     []>;
 750 def FNMADD : AForm_1<63, 31,
 751                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRC, FPRC:$FRB),
 752                     "fnmadd $FRT, $FRA, $FRC, $FRB",
 753                     [(set FPRC:$FRT, (fneg (fadd (fmul FPRC:$FRA, FPRC:$FRC),
 754                                                  FPRC:$FRB)))]>;
 755 def FNMADDS : AForm_1<59, 31,
 756                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRC, FPRC:$FRB),
 757                     "fnmadds $FRT, $FRA, $FRC, $FRB",
 758                     []>;
 759 def FNMSUB : AForm_1<63, 30,
 760                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRC, FPRC:$FRB),
 761                     "fnmsub $FRT, $FRA, $FRC, $FRB",
 762                     [(set FPRC:$FRT, (fneg (fsub (fmul FPRC:$FRA, FPRC:$FRC),
 763                                                  FPRC:$FRB)))]>;
 764 def FNMSUBS : AForm_1<59, 30,
 765                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRC, FPRC:$FRB),
 766                     "fnmsubs $FRT, $FRA, $FRC, $FRB",
 767                     []>;
 768 def FSEL  : AForm_1<63, 23,
 769                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRC, FPRC:$FRB),
 770                     "fsel $FRT, $FRA, $FRC, $FRB",
 771                     []>;
 772 def FADD  : AForm_2<63, 21,
 773                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRB),
 774                     "fadd $FRT, $FRA, $FRB",
 775                     [(set FPRC:$FRT, (fadd FPRC:$FRA, FPRC:$FRB))]>;
 776 def FADDS : AForm_2<59, 21,
 777                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRB),
 778                     "fadds $FRT, $FRA, $FRB",
 779                     []>;
 780 def FDIV  : AForm_2<63, 18,
 781                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRB),
 782                     "fdiv $FRT, $FRA, $FRB",
 783                     [(set FPRC:$FRT, (fdiv FPRC:$FRA, FPRC:$FRB))]>;
 784 def FDIVS : AForm_2<59, 18,
 785                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRB),
 786                     "fdivs $FRT, $FRA, $FRB",
 787                     []>;
 788 def FMUL  : AForm_3<63, 25,
 789                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRB),
 790                     "fmul $FRT, $FRA, $FRB",
 791                     [(set FPRC:$FRT, (fmul FPRC:$FRA, FPRC:$FRB))]>;
 792 def FMULS : AForm_3<59, 25,
 793                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRB),
 794                     "fmuls $FRT, $FRA, $FRB",
 795                     []>;
 796 def FSUB  : AForm_2<63, 20,
 797                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRB),
 798                     "fsub $FRT, $FRA, $FRB",
 799                     [(set FPRC:$FRT, (fsub FPRC:$FRA, FPRC:$FRB))]>;
 800 def FSUBS : AForm_2<59, 20,
 801                     (ops FPRC:$FRT, FPRC:$FRA, FPRC:$FRB),
 802                     "fsubs $FRT, $FRA, $FRB",
 803                     []>;
 804
 805 // M-Form instructions.  rotate and mask instructions.
 806 //
 807 let isTwoAddress = 1, isCommutable = 1 in {
 808 // RLWIMI can be commuted if the rotate amount is zero.
 809 def RLWIMI : MForm_2<20,
 810                      (ops GPRC:$rA, GPRC:$rSi, GPRC:$rS, u5imm:$SH, u5imm:$MB,
 811                       u5imm:$ME), "rlwimi $rA, $rS, $SH, $MB, $ME">;
 812 }
 813 def RLWINM : MForm_2<21,
 814                      (ops GPRC:$rA, GPRC:$rS, u5imm:$SH, u5imm:$MB, u5imm:$ME),
 815                      "rlwinm $rA, $rS, $SH, $MB, $ME">;
 816 def RLWINMo : MForm_2<21,
 817                      (ops GPRC:$rA, GPRC:$rS, u5imm:$SH, u5imm:$MB, u5imm:$ME),
 818                      "rlwinm. $rA, $rS, $SH, $MB, $ME">, isDOT;
 819 def RLWNM  : MForm_2<23,
 820                      (ops GPRC:$rA, GPRC:$rS, GPRC:$rB, u5imm:$MB, u5imm:$ME),
 821                      "rlwnm $rA, $rS, $rB, $MB, $ME">;
 822
 823 // MD-Form instructions.  64 bit rotate instructions.
 824 //
 825 def RLDICL : MDForm_1<30, 0,
 826                       (ops GPRC:$rA, GPRC:$rS, u6imm:$SH, u6imm:$MB),
 827                       "rldicl $rA, $rS, $SH, $MB">, isPPC64;
 828 def RLDICR : MDForm_1<30, 1,
 829                       (ops GPRC:$rA, GPRC:$rS, u6imm:$SH, u6imm:$ME),
 830                       "rldicr $rA, $rS, $SH, $ME">, isPPC64;
 831
 832 //===----------------------------------------------------------------------===//
 833 // PowerPC Instruction Patterns
 834 //
 835
 836 // Arbitrary immediate support.  Implement in terms of LIS/ORI.
 837 def : Pat<(i32 imm:$imm),
 838           (ORI (LIS (HI16 imm:$imm)), (LO16 imm:$imm))>;
 839
 840 // Implement the 'not' operation with the NOR instruction.
 841 def NOT : Pat<(not GPRC:$in),
 842               (NOR GPRC:$in, GPRC:$in)>;
 843
 844 // ADD an arbitrary immediate.
 845 def : Pat<(add GPRC:$in, imm:$imm),
 846           (ADDIS (ADDI GPRC:$in, (LO16 imm:$imm)), (HA16 imm:$imm))>;
 847 // OR an arbitrary immediate.
 848 def : Pat<(or GPRC:$in, imm:$imm),
 849           (ORIS (ORI GPRC:$in, (LO16 imm:$imm)), (HI16 imm:$imm))>;
 850 // XOR an arbitrary immediate.
 851 def : Pat<(xor GPRC:$in, imm:$imm),
 852           (XORIS (XORI GPRC:$in, (LO16 imm:$imm)), (HI16 imm:$imm))>;
 853
 854
 855
 856 // Same as above, but using a temporary. FIXME: implement temporaries :)
 857 /*
 858 def : Pattern<(xor GPRC:$in, imm:$imm),
 859               [(set GPRC:$tmp, (XORI GPRC:$in, (LO16 imm:$imm))),
 860                (XORIS GPRC:$tmp, (HI16 imm:$imm))]>;
 861 */
 862
 863
 864 //===----------------------------------------------------------------------===//
 865 // PowerPCInstrInfo Definition
 866 //
 867 def PowerPCInstrInfo : InstrInfo {
 868   let PHIInst  = PHI;
 869
 870   let TSFlagsFields = [ "VMX", "PPC64" ];
 871   let TSFlagsShifts = [ 0, 1 ];
 872
 873   let isLittleEndianEncoding = 1;
 874 }
 875