lib/Target/PowerPC/PPCInstrInfo.td

   1 //===- PPCInstrInfo.td - The PowerPC Instruction Set -------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the subset of the 32-bit PowerPC instruction set, as used
  11 // by the PowerPC instruction selector.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 include "PPCInstrFormats.td"
  16
  17 //===----------------------------------------------------------------------===//
  18 // PowerPC specific type constraints.
  19 //
  20 def SDT_PPCstfiwx : SDTypeProfile<0, 2, [ // stfiwx
  21   SDTCisVT<0, f64>, SDTCisPtrTy<1>
  22 ]>;
  23 def SDT_PPCShiftOp : SDTypeProfile<1, 2, [   // PPCshl, PPCsra, PPCsrl
  24   SDTCisVT<0, i32>, SDTCisVT<1, i32>, SDTCisVT<2, i32>
  25 ]>;
  26 def SDT_PPCCallSeq : SDTypeProfile<0, 1, [ SDTCisVT<0, i32> ]>;
  27
  28 def SDT_PPCvperm   : SDTypeProfile<1, 3, [
  29   SDTCisVT<3, v16i8>, SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>
  30 ]>;
  31
  32 def SDT_PPCvcmp : SDTypeProfile<1, 3, [
  33   SDTCisSameAs<0, 1>, SDTCisSameAs<1, 2>, SDTCisVT<3, i32>
  34 ]>;
  35
  36 def SDT_PPCcondbr : SDTypeProfile<0, 3, [
  37   SDTCisVT<0, i32>, SDTCisVT<2, OtherVT>
  38 ]>;
  39
  40 def SDT_PPClbrx : SDTypeProfile<1, 3, [
  41   SDTCisVT<0, i32>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
  42 ]>;
  43 def SDT_PPCstbrx : SDTypeProfile<0, 4, [
  44   SDTCisVT<0, i32>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
  45 ]>;
  46
  47 //===----------------------------------------------------------------------===//
  48 // PowerPC specific DAG Nodes.
  49 //
  50
  51 def PPCfcfid  : SDNode<"PPCISD::FCFID" , SDTFPUnaryOp, []>;
  52 def PPCfctidz : SDNode<"PPCISD::FCTIDZ", SDTFPUnaryOp, []>;
  53 def PPCfctiwz : SDNode<"PPCISD::FCTIWZ", SDTFPUnaryOp, []>;
  54 def PPCstfiwx : SDNode<"PPCISD::STFIWX", SDT_PPCstfiwx, [SDNPHasChain]>;
  55
  56 def PPCfsel   : SDNode<"PPCISD::FSEL",
  57    // Type constraint for fsel.
  58    SDTypeProfile<1, 3, [SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>,
  59                         SDTCisFP<0>, SDTCisVT<1, f64>]>, []>;
  60
  61 def PPChi       : SDNode<"PPCISD::Hi", SDTIntBinOp, []>;
  62 def PPClo       : SDNode<"PPCISD::Lo", SDTIntBinOp, []>;
  63 def PPCvmaddfp  : SDNode<"PPCISD::VMADDFP", SDTFPTernaryOp, []>;
  64 def PPCvnmsubfp : SDNode<"PPCISD::VNMSUBFP", SDTFPTernaryOp, []>;
  65
  66 def PPCvperm    : SDNode<"PPCISD::VPERM", SDT_PPCvperm, []>;
  67
  68 // These nodes represent the 32-bit PPC shifts that operate on 6-bit shift
  69 // amounts.  These nodes are generated by the multi-precision shift code.
  70 def PPCsrl        : SDNode<"PPCISD::SRL"       , SDT_PPCShiftOp>;
  71 def PPCsra        : SDNode<"PPCISD::SRA"       , SDT_PPCShiftOp>;
  72 def PPCshl        : SDNode<"PPCISD::SHL"       , SDT_PPCShiftOp>;
  73
  74 def PPCextsw_32   : SDNode<"PPCISD::EXTSW_32"  , SDTIntUnaryOp>;
  75 def PPCstd_32     : SDNode<"PPCISD::STD_32"    , SDTStore, [SDNPHasChain]>;
  76
  77 // These are target-independent nodes, but have target-specific formats.
  78 def callseq_start : SDNode<"ISD::CALLSEQ_START", SDT_PPCCallSeq,
  79                            [SDNPHasChain, SDNPOutFlag]>;
  80 def callseq_end   : SDNode<"ISD::CALLSEQ_END",   SDT_PPCCallSeq,
  81                            [SDNPHasChain, SDNPOutFlag]>;
  82
  83 def SDT_PPCCall   : SDTypeProfile<0, -1, [SDTCisInt<0>]>;
  84 def PPCcall       : SDNode<"PPCISD::CALL", SDT_PPCCall,
  85                            [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  86 def PPCmtctr      : SDNode<"PPCISD::MTCTR", SDT_PPCCall,
  87                            [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  88 def PPCbctrl      : SDNode<"PPCISD::BCTRL", SDTRet,
  89                            [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  90
  91 def retflag       : SDNode<"PPCISD::RET_FLAG", SDTRet,
  92                            [SDNPHasChain, SDNPOptInFlag]>;
  93
  94 def PPCvcmp       : SDNode<"PPCISD::VCMP" , SDT_PPCvcmp, []>;
  95 def PPCvcmp_o     : SDNode<"PPCISD::VCMPo", SDT_PPCvcmp, [SDNPOutFlag]>;
  96
  97 def PPCcondbranch : SDNode<"PPCISD::COND_BRANCH", SDT_PPCcondbr,
  98                            [SDNPHasChain, SDNPOptInFlag]>;
  99
 100 def PPClbrx       : SDNode<"PPCISD::LBRX", SDT_PPClbrx, [SDNPHasChain]>;
 101 def PPCstbrx      : SDNode<"PPCISD::STBRX", SDT_PPCstbrx, [SDNPHasChain]>;
 102
 103 // Instructions to support dynamic alloca.
 104 def SDTDynOp  : SDTypeProfile<1, 2, []>;
 105 def PPCdynalloc   : SDNode<"PPCISD::DYNALLOC", SDTDynOp, [SDNPHasChain]>;
 106
 107 //===----------------------------------------------------------------------===//
 108 // PowerPC specific transformation functions and pattern fragments.
 109 //
 110
 111 def SHL32 : SDNodeXForm<imm, [{
 112   // Transformation function: 31 - imm
 113   return getI32Imm(31 - N->getValue());
 114 }]>;
 115
 116 def SRL32 : SDNodeXForm<imm, [{
 117   // Transformation function: 32 - imm
 118   return N->getValue() ? getI32Imm(32 - N->getValue()) : getI32Imm(0);
 119 }]>;
 120
 121 def LO16 : SDNodeXForm<imm, [{
 122   // Transformation function: get the low 16 bits.
 123   return getI32Imm((unsigned short)N->getValue());
 124 }]>;
 125
 126 def HI16 : SDNodeXForm<imm, [{
 127   // Transformation function: shift the immediate value down into the low bits.
 128   return getI32Imm((unsigned)N->getValue() >> 16);
 129 }]>;
 130
 131 def HA16 : SDNodeXForm<imm, [{
 132   // Transformation function: shift the immediate value down into the low bits.
 133   signed int Val = N->getValue();
 134   return getI32Imm((Val - (signed short)Val) >> 16);
 135 }]>;
 136 def MB : SDNodeXForm<imm, [{
 137   // Transformation function: get the start bit of a mask
 138   unsigned mb, me;
 139   (void)isRunOfOnes((unsigned)N->getValue(), mb, me);
 140   return getI32Imm(mb);
 141 }]>;
 142
 143 def ME : SDNodeXForm<imm, [{
 144   // Transformation function: get the end bit of a mask
 145   unsigned mb, me;
 146   (void)isRunOfOnes((unsigned)N->getValue(), mb, me);
 147   return getI32Imm(me);
 148 }]>;
 149 def maskimm32 : PatLeaf<(imm), [{
 150   // maskImm predicate - True if immediate is a run of ones.
 151   unsigned mb, me;
 152   if (N->getValueType(0) == MVT::i32)
 153     return isRunOfOnes((unsigned)N->getValue(), mb, me);
 154   else
 155     return false;
 156 }]>;
 157
 158 def immSExt16  : PatLeaf<(imm), [{
 159   // immSExt16 predicate - True if the immediate fits in a 16-bit sign extended
 160   // field.  Used by instructions like 'addi'.
 161   if (N->getValueType(0) == MVT::i32)
 162     return (int32_t)N->getValue() == (short)N->getValue();
 163   else
 164     return (int64_t)N->getValue() == (short)N->getValue();
 165 }]>;
 166 def immZExt16  : PatLeaf<(imm), [{
 167   // immZExt16 predicate - True if the immediate fits in a 16-bit zero extended
 168   // field.  Used by instructions like 'ori'.
 169   return (uint64_t)N->getValue() == (unsigned short)N->getValue();
 170 }], LO16>;
 171
 172 // imm16Shifted* - These match immediates where the low 16-bits are zero.  There
 173 // are two forms: imm16ShiftedSExt and imm16ShiftedZExt.  These two forms are
 174 // identical in 32-bit mode, but in 64-bit mode, they return true if the
 175 // immediate fits into a sign/zero extended 32-bit immediate (with the low bits
 176 // clear).
 177 def imm16ShiftedZExt : PatLeaf<(imm), [{
 178   // imm16ShiftedZExt predicate - True if only bits in the top 16-bits of the
 179   // immediate are set.  Used by instructions like 'xoris'.
 180   return (N->getValue() & ~uint64_t(0xFFFF0000)) == 0;
 181 }], HI16>;
 182
 183 def imm16ShiftedSExt : PatLeaf<(imm), [{
 184   // imm16ShiftedSExt predicate - True if only bits in the top 16-bits of the
 185   // immediate are set.  Used by instructions like 'addis'.  Identical to
 186   // imm16ShiftedZExt in 32-bit mode.
 187   if (N->getValue() & 0xFFFF) return false;
 188   if (N->getValueType(0) == MVT::i32)
 189     return true;
 190   // For 64-bit, make sure it is sext right.
 191   return N->getValue() == (uint64_t)(int)N->getValue();
 192 }], HI16>;
 193
 194
 195 //===----------------------------------------------------------------------===//
 196 // PowerPC Flag Definitions.
 197
 198 class isPPC64 { bit PPC64 = 1; }
 199 class isDOT   {
 200   list<Register> Defs = [CR0];
 201   bit RC  = 1;
 202 }
 203
 204 class RegConstraint<string C> {
 205   string Constraints = C;
 206 }
 207 class NoEncode<string E> {
 208   string DisableEncoding = E;
 209 }
 210
 211
 212 //===----------------------------------------------------------------------===//
 213 // PowerPC Operand Definitions.
 214
 215 def s5imm   : Operand<i32> {
 216   let PrintMethod = "printS5ImmOperand";
 217 }
 218 def u5imm   : Operand<i32> {
 219   let PrintMethod = "printU5ImmOperand";
 220 }
 221 def u6imm   : Operand<i32> {
 222   let PrintMethod = "printU6ImmOperand";
 223 }
 224 def s16imm  : Operand<i32> {
 225   let PrintMethod = "printS16ImmOperand";
 226 }
 227 def u16imm  : Operand<i32> {
 228   let PrintMethod = "printU16ImmOperand";
 229 }
 230 def s16immX4  : Operand<i32> {   // Multiply imm by 4 before printing.
 231   let PrintMethod = "printS16X4ImmOperand";
 232 }
 233 def target : Operand<OtherVT> {
 234   let PrintMethod = "printBranchOperand";
 235 }
 236 def calltarget : Operand<iPTR> {
 237   let PrintMethod = "printCallOperand";
 238 }
 239 def aaddr : Operand<iPTR> {
 240   let PrintMethod = "printAbsAddrOperand";
 241 }
 242 def piclabel: Operand<iPTR> {
 243   let PrintMethod = "printPICLabel";
 244 }
 245 def symbolHi: Operand<i32> {
 246   let PrintMethod = "printSymbolHi";
 247 }
 248 def symbolLo: Operand<i32> {
 249   let PrintMethod = "printSymbolLo";
 250 }
 251 def crbitm: Operand<i8> {
 252   let PrintMethod = "printcrbitm";
 253 }
 254 // Address operands
 255 def memri : Operand<iPTR> {
 256   let PrintMethod = "printMemRegImm";
 257   let MIOperandInfo = (ops i32imm:$imm, ptr_rc:$reg);
 258 }
 259 def memrr : Operand<iPTR> {
 260   let PrintMethod = "printMemRegReg";
 261   let MIOperandInfo = (ops ptr_rc, ptr_rc);
 262 }
 263 def memrix : Operand<iPTR> {   // memri where the imm is shifted 2 bits.
 264   let PrintMethod = "printMemRegImmShifted";
 265   let MIOperandInfo = (ops i32imm:$imm, ptr_rc:$reg);
 266 }
 267
 268 // PowerPC Predicate operand.  20 = (0<<5)|20 = always, CR0 is a dummy reg
 269 // that doesn't matter.
 270 def pred : PredicateOperand<(ops imm, CRRC), (ops (i32 20), CR0)> {
 271   let PrintMethod = "printPredicateOperand";
 272 }
 273
 274 // Define PowerPC specific addressing mode.
 275 def iaddr  : ComplexPattern<iPTR, 2, "SelectAddrImm",    [], []>;
 276 def xaddr  : ComplexPattern<iPTR, 2, "SelectAddrIdx",    [], []>;
 277 def xoaddr : ComplexPattern<iPTR, 2, "SelectAddrIdxOnly",[], []>;
 278 def ixaddr : ComplexPattern<iPTR, 2, "SelectAddrImmShift", [], []>; // "std"
 279
 280 /// This is just the offset part of iaddr, used for preinc.
 281 def iaddroff : ComplexPattern<iPTR, 1, "SelectAddrImmOffs", [], []>;
 282
 283 //===----------------------------------------------------------------------===//
 284 // PowerPC Instruction Predicate Definitions.
 285 def FPContractions : Predicate<"!NoExcessFPPrecision">;
 286
 287
 288 //===----------------------------------------------------------------------===//
 289 // PowerPC Instruction Definitions.
 290
 291 // Pseudo-instructions:
 292
 293 let hasCtrlDep = 1 in {
 294 def ADJCALLSTACKDOWN : Pseudo<(ops u16imm:$amt),
 295                               "${:comment} ADJCALLSTACKDOWN",
 296                               [(callseq_start imm:$amt)]>, Imp<[R1],[R1]>;
 297 def ADJCALLSTACKUP   : Pseudo<(ops u16imm:$amt),
 298                               "${:comment} ADJCALLSTACKUP",
 299                               [(callseq_end imm:$amt)]>, Imp<[R1],[R1]>;
 300
 301 def UPDATE_VRSAVE    : Pseudo<(ops GPRC:$rD, GPRC:$rS),
 302                               "UPDATE_VRSAVE $rD, $rS", []>;
 303 }
 304
 305 def DYNALLOC : Pseudo<(ops GPRC:$result, GPRC:$negsize, memri:$fpsi),
 306                        "${:comment} DYNALLOC $result, $negsize, $fpsi",
 307                        [(set GPRC:$result,
 308                              (PPCdynalloc GPRC:$negsize, iaddr:$fpsi))]>,
 309                         Imp<[R1],[R1]>;
 310
 311 def IMPLICIT_DEF_GPRC: Pseudo<(ops GPRC:$rD),"${:comment}IMPLICIT_DEF_GPRC $rD",
 312                               [(set GPRC:$rD, (undef))]>;
 313 def IMPLICIT_DEF_F8  : Pseudo<(ops F8RC:$rD), "${:comment} IMPLICIT_DEF_F8 $rD",
 314                               [(set F8RC:$rD, (undef))]>;
 315 def IMPLICIT_DEF_F4  : Pseudo<(ops F4RC:$rD), "${:comment} IMPLICIT_DEF_F4 $rD",
 316                               [(set F4RC:$rD, (undef))]>;
 317
 318 // SELECT_CC_* - Used to implement the SELECT_CC DAG operation.  Expanded by the
 319 // scheduler into a branch sequence.
 320 let usesCustomDAGSchedInserter = 1,    // Expanded by the scheduler.
 321     PPC970_Single = 1 in {
 322   def SELECT_CC_I4 : Pseudo<(ops GPRC:$dst, CRRC:$cond, GPRC:$T, GPRC:$F,
 323                               i32imm:$BROPC), "${:comment} SELECT_CC PSEUDO!",
 324                               []>;
 325   def SELECT_CC_I8 : Pseudo<(ops G8RC:$dst, CRRC:$cond, G8RC:$T, G8RC:$F,
 326                               i32imm:$BROPC), "${:comment} SELECT_CC PSEUDO!",
 327                               []>;
 328   def SELECT_CC_F4  : Pseudo<(ops F4RC:$dst, CRRC:$cond, F4RC:$T, F4RC:$F,
 329                               i32imm:$BROPC), "${:comment} SELECT_CC PSEUDO!",
 330                               []>;
 331   def SELECT_CC_F8  : Pseudo<(ops F8RC:$dst, CRRC:$cond, F8RC:$T, F8RC:$F,
 332                               i32imm:$BROPC), "${:comment} SELECT_CC PSEUDO!",
 333                               []>;
 334   def SELECT_CC_VRRC: Pseudo<(ops VRRC:$dst, CRRC:$cond, VRRC:$T, VRRC:$F,
 335                               i32imm:$BROPC), "${:comment} SELECT_CC PSEUDO!",
 336                               []>;
 337 }
 338
 339 let isTerminator = 1, isBarrier = 1, noResults = 1, PPC970_Unit = 7 in {
 340   let isReturn = 1 in
 341     def BLR : XLForm_2_br<19, 16, 0, (ops pred:$p),
 342                           "b${p:cc}lr ${p:reg}", BrB,
 343                           [(retflag)]>;
 344   def BCTR : XLForm_2_ext<19, 528, 20, 0, 0, (ops), "bctr", BrB, []>;
 345 }
 346
 347
 348
 349 let Defs = [LR] in
 350   def MovePCtoLR : Pseudo<(ops piclabel:$label), "bl $label", []>,
 351                    PPC970_Unit_BRU;
 352
 353 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1,
 354     noResults = 1, PPC970_Unit = 7 in {
 355   let isBarrier = 1 in {
 356   def B   : IForm<18, 0, 0, (ops target:$dst),
 357                   "b $dst", BrB,
 358                   [(br bb:$dst)]>;
 359   }
 360
 361   // BCC represents an arbitrary conditional branch on a predicate.
 362   // FIXME: should be able to write a pattern for PPCcondbranch, but can't use
 363   // a two-value operand where a dag node expects two operands. :(
 364   def BCC : Pseudo<(ops pred:$cond, target:$dst),
 365                    "b${cond:cc} ${cond:reg}, $dst",
 366                    [/*(PPCcondbranch CRRC:$crS, imm:$opc, bb:$dst)*/]>;
 367
 368   def BLT : BForm<16, 0, 0, 12, 0, (ops CRRC:$crS, target:$block),
 369                   "blt $crS, $block", BrB>;
 370   def BLE : BForm<16, 0, 0, 4,  1, (ops CRRC:$crS, target:$block),
 371                   "ble $crS, $block", BrB>;
 372   def BEQ : BForm<16, 0, 0, 12, 2, (ops CRRC:$crS, target:$block),
 373                   "beq $crS, $block", BrB>;
 374   def BGE : BForm<16, 0, 0, 4,  0, (ops CRRC:$crS, target:$block),
 375                   "bge $crS, $block", BrB>;
 376   def BGT : BForm<16, 0, 0, 12, 1, (ops CRRC:$crS, target:$block),
 377                   "bgt $crS, $block", BrB>;
 378   def BNE : BForm<16, 0, 0, 4,  2, (ops CRRC:$crS, target:$block),
 379                   "bne $crS, $block", BrB>;
 380   def BUN : BForm<16, 0, 0, 12, 3, (ops CRRC:$crS, target:$block),
 381                   "bun $crS, $block", BrB>;
 382   def BNU : BForm<16, 0, 0, 4,  3, (ops CRRC:$crS, target:$block),
 383                   "bnu $crS, $block", BrB>;
 384 }
 385
 386 let isCall = 1, noResults = 1, PPC970_Unit = 7,
 387   // All calls clobber the non-callee saved registers...
 388   Defs = [R0,R2,R3,R4,R5,R6,R7,R8,R9,R10,R11,R12,
 389           F0,F1,F2,F3,F4,F5,F6,F7,F8,F9,F10,F11,F12,F13,
 390           V0,V1,V2,V3,V4,V5,V6,V7,V8,V9,V10,V11,V12,V13,V14,V15,V16,V17,V18,V19,
 391           LR,CTR,
 392           CR0,CR1,CR5,CR6,CR7] in {
 393   // Convenient aliases for call instructions
 394   def BL  : IForm<18, 0, 1, (ops calltarget:$func, variable_ops),
 395                             "bl $func", BrB, []>;  // See Pat patterns below.
 396   def BLA : IForm<18, 1, 1, (ops aaddr:$func, variable_ops),
 397                             "bla $func", BrB, [(PPCcall (i32 imm:$func))]>;
 398   def BCTRL : XLForm_2_ext<19, 528, 20, 0, 1, (ops variable_ops), "bctrl", BrB,
 399                            [(PPCbctrl)]>;
 400 }
 401
 402 // DCB* instructions.
 403 def DCBA   : DCB_Form<758, 0, (ops memrr:$dst),
 404                       "dcba $dst", LdStDCBF, [(int_ppc_dcba xoaddr:$dst)]>,
 405                       PPC970_DGroup_Single;
 406 def DCBF   : DCB_Form<86, 0, (ops memrr:$dst),
 407                       "dcbf $dst", LdStDCBF, [(int_ppc_dcbf xoaddr:$dst)]>,
 408                       PPC970_DGroup_Single;
 409 def DCBI   : DCB_Form<470, 0, (ops memrr:$dst),
 410                       "dcbi $dst", LdStDCBF, [(int_ppc_dcbi xoaddr:$dst)]>,
 411                       PPC970_DGroup_Single;
 412 def DCBST  : DCB_Form<54, 0, (ops memrr:$dst),
 413                       "dcbst $dst", LdStDCBF, [(int_ppc_dcbst xoaddr:$dst)]>,
 414                       PPC970_DGroup_Single;
 415 def DCBT   : DCB_Form<278, 0, (ops memrr:$dst),
 416                       "dcbt $dst", LdStDCBF, [(int_ppc_dcbt xoaddr:$dst)]>,
 417                       PPC970_DGroup_Single;
 418 def DCBTST : DCB_Form<246, 0, (ops memrr:$dst),
 419                       "dcbtst $dst", LdStDCBF, [(int_ppc_dcbtst xoaddr:$dst)]>,
 420                       PPC970_DGroup_Single;
 421 def DCBZ   : DCB_Form<1014, 0, (ops memrr:$dst),
 422                       "dcbz $dst", LdStDCBF, [(int_ppc_dcbz xoaddr:$dst)]>,
 423                       PPC970_DGroup_Single;
 424 def DCBZL  : DCB_Form<1014, 1, (ops memrr:$dst),
 425                       "dcbzl $dst", LdStDCBF, [(int_ppc_dcbzl xoaddr:$dst)]>,
 426                       PPC970_DGroup_Single;
 427
 428 //===----------------------------------------------------------------------===//
 429 // PPC32 Load Instructions.
 430 //
 431
 432 // Unindexed (r+i) Loads.
 433 let isLoad = 1, PPC970_Unit = 2 in {
 434 def LBZ : DForm_1<34, (ops GPRC:$rD, memri:$src),
 435                   "lbz $rD, $src", LdStGeneral,
 436                   [(set GPRC:$rD, (zextloadi8 iaddr:$src))]>;
 437 def LHA : DForm_1<42, (ops GPRC:$rD, memri:$src),
 438                   "lha $rD, $src", LdStLHA,
 439                   [(set GPRC:$rD, (sextloadi16 iaddr:$src))]>,
 440                   PPC970_DGroup_Cracked;
 441 def LHZ : DForm_1<40, (ops GPRC:$rD, memri:$src),
 442                   "lhz $rD, $src", LdStGeneral,
 443                   [(set GPRC:$rD, (zextloadi16 iaddr:$src))]>;
 444 def LWZ : DForm_1<32, (ops GPRC:$rD, memri:$src),
 445                   "lwz $rD, $src", LdStGeneral,
 446                   [(set GPRC:$rD, (load iaddr:$src))]>;
 447
 448 def LFS : DForm_1<48, (ops F4RC:$rD, memri:$src),
 449                   "lfs $rD, $src", LdStLFDU,
 450                   [(set F4RC:$rD, (load iaddr:$src))]>;
 451 def LFD : DForm_1<50, (ops F8RC:$rD, memri:$src),
 452                   "lfd $rD, $src", LdStLFD,
 453                   [(set F8RC:$rD, (load iaddr:$src))]>;
 454
 455
 456 // Unindexed (r+i) Loads with Update (preinc).
 457 def LBZU : DForm_1<35, (ops GPRC:$rD, ptr_rc:$ea_result, memri:$addr),
 458                    "lbzu $rD, $addr", LdStGeneral,
 459                    []>, RegConstraint<"$addr.reg = $ea_result">,
 460                    NoEncode<"$ea_result">;
 461
 462 def LHAU : DForm_1<43, (ops GPRC:$rD, ptr_rc:$ea_result, memri:$addr),
 463                    "lhau $rD, $addr", LdStGeneral,
 464                    []>, RegConstraint<"$addr.reg = $ea_result">,
 465                    NoEncode<"$ea_result">;
 466
 467 def LHZU : DForm_1<41, (ops GPRC:$rD, ptr_rc:$ea_result, memri:$addr),
 468                    "lhzu $rD, $addr", LdStGeneral,
 469                    []>, RegConstraint<"$addr.reg = $ea_result">,
 470                    NoEncode<"$ea_result">;
 471
 472 def LWZU : DForm_1<33, (ops GPRC:$rD, ptr_rc:$ea_result, memri:$addr),
 473                    "lwzu $rD, $addr", LdStGeneral,
 474                    []>, RegConstraint<"$addr.reg = $ea_result">,
 475                    NoEncode<"$ea_result">;
 476
 477 def LFSU : DForm_1<49, (ops F4RC:$rD, ptr_rc:$ea_result, memri:$addr),
 478                   "lfs $rD, $addr", LdStLFDU,
 479                   []>, RegConstraint<"$addr.reg = $ea_result">,
 480                    NoEncode<"$ea_result">;
 481
 482 def LFDU : DForm_1<51, (ops F8RC:$rD, ptr_rc:$ea_result, memri:$addr),
 483                   "lfd $rD, $addr", LdStLFD,
 484                   []>, RegConstraint<"$addr.reg = $ea_result">,
 485                    NoEncode<"$ea_result">;
 486 }
 487
 488 // Indexed (r+r) Loads.
 489 //
 490 let isLoad = 1, PPC970_Unit = 2 in {
 491 def LBZX : XForm_1<31,  87, (ops GPRC:$rD, memrr:$src),
 492                    "lbzx $rD, $src", LdStGeneral,
 493                    [(set GPRC:$rD, (zextloadi8 xaddr:$src))]>;
 494 def LHAX : XForm_1<31, 343, (ops GPRC:$rD, memrr:$src),
 495                    "lhax $rD, $src", LdStLHA,
 496                    [(set GPRC:$rD, (sextloadi16 xaddr:$src))]>,
 497                    PPC970_DGroup_Cracked;
 498 def LHZX : XForm_1<31, 279, (ops GPRC:$rD, memrr:$src),
 499                    "lhzx $rD, $src", LdStGeneral,
 500                    [(set GPRC:$rD, (zextloadi16 xaddr:$src))]>;
 501 def LWZX : XForm_1<31,  23, (ops GPRC:$rD, memrr:$src),
 502                    "lwzx $rD, $src", LdStGeneral,
 503                    [(set GPRC:$rD, (load xaddr:$src))]>;
 504
 505
 506 def LHBRX : XForm_1<31, 790, (ops GPRC:$rD, memrr:$src),
 507                    "lhbrx $rD, $src", LdStGeneral,
 508                    [(set GPRC:$rD, (PPClbrx xoaddr:$src, srcvalue:$sv, i16))]>;
 509 def LWBRX : XForm_1<31,  534, (ops GPRC:$rD, memrr:$src),
 510                    "lwbrx $rD, $src", LdStGeneral,
 511                    [(set GPRC:$rD, (PPClbrx xoaddr:$src, srcvalue:$sv, i32))]>;
 512
 513 def LFSX   : XForm_25<31, 535, (ops F4RC:$frD, memrr:$src),
 514                       "lfsx $frD, $src", LdStLFDU,
 515                       [(set F4RC:$frD, (load xaddr:$src))]>;
 516 def LFDX   : XForm_25<31, 599, (ops F8RC:$frD, memrr:$src),
 517                       "lfdx $frD, $src", LdStLFDU,
 518                       [(set F8RC:$frD, (load xaddr:$src))]>;
 519 }
 520
 521 //===----------------------------------------------------------------------===//
 522 // PPC32 Store Instructions.
 523 //
 524
 525 // Unindexed (r+i) Stores.
 526 let isStore = 1, noResults = 1, PPC970_Unit = 2 in {
 527 def STB  : DForm_1<38, (ops GPRC:$rS, memri:$src),
 528                    "stb $rS, $src", LdStGeneral,
 529                    [(truncstorei8 GPRC:$rS, iaddr:$src)]>;
 530 def STH  : DForm_1<44, (ops GPRC:$rS, memri:$src),
 531                    "sth $rS, $src", LdStGeneral,
 532                    [(truncstorei16 GPRC:$rS, iaddr:$src)]>;
 533 def STW  : DForm_1<36, (ops GPRC:$rS, memri:$src),
 534                    "stw $rS, $src", LdStGeneral,
 535                    [(store GPRC:$rS, iaddr:$src)]>;
 536 def STFS : DForm_1<52, (ops F4RC:$rS, memri:$dst),
 537                    "stfs $rS, $dst", LdStUX,
 538                    [(store F4RC:$rS, iaddr:$dst)]>;
 539 def STFD : DForm_1<54, (ops F8RC:$rS, memri:$dst),
 540                    "stfd $rS, $dst", LdStUX,
 541                    [(store F8RC:$rS, iaddr:$dst)]>;
 542 }
 543
 544 // Unindexed (r+i) Stores with Update (preinc).
 545 let isStore = 1, PPC970_Unit = 2 in {
 546 def STBU  : DForm_1<39, (ops ptr_rc:$ea_res, GPRC:$rS,
 547                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 548                     "stbu $rS, $ptroff($ptrreg)", LdStGeneral,
 549                     [(set ptr_rc:$ea_res,
 550                           (pre_truncsti8 GPRC:$rS, ptr_rc:$ptrreg,
 551                                          iaddroff:$ptroff))]>,
 552                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 553 def STHU  : DForm_1<45, (ops ptr_rc:$ea_res, GPRC:$rS,
 554                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 555                     "sthu $rS, $ptroff($ptrreg)", LdStGeneral,
 556                     [(set ptr_rc:$ea_res,
 557                         (pre_truncsti16 GPRC:$rS, ptr_rc:$ptrreg,
 558                                         iaddroff:$ptroff))]>,
 559                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 560 def STWU  : DForm_1<37, (ops ptr_rc:$ea_res, GPRC:$rS,
 561                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 562                     "stwu $rS, $ptroff($ptrreg)", LdStGeneral,
 563                     [(set ptr_rc:$ea_res, (pre_store GPRC:$rS, ptr_rc:$ptrreg,
 564                                                      iaddroff:$ptroff))]>,
 565                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 566 def STFSU : DForm_1<37, (ops ptr_rc:$ea_res, F4RC:$rS,
 567                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 568                     "stfsu $rS, $ptroff($ptrreg)", LdStGeneral,
 569                     [(set ptr_rc:$ea_res, (pre_store F4RC:$rS,  ptr_rc:$ptrreg,
 570                                           iaddroff:$ptroff))]>,
 571                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 572 def STFDU : DForm_1<37, (ops ptr_rc:$ea_res, F8RC:$rS,
 573                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 574                     "stfdu $rS, $ptroff($ptrreg)", LdStGeneral,
 575                     [(set ptr_rc:$ea_res, (pre_store F8RC:$rS, ptr_rc:$ptrreg,
 576                                           iaddroff:$ptroff))]>,
 577                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 578 }
 579
 580
 581 // Indexed (r+r) Stores.
 582 //
 583 let isStore = 1, noResults = 1, PPC970_Unit = 2 in {
 584 def STBX  : XForm_8<31, 215, (ops GPRC:$rS, memrr:$dst),
 585                    "stbx $rS, $dst", LdStGeneral,
 586                    [(truncstorei8 GPRC:$rS, xaddr:$dst)]>,
 587                    PPC970_DGroup_Cracked;
 588 def STHX  : XForm_8<31, 407, (ops GPRC:$rS, memrr:$dst),
 589                    "sthx $rS, $dst", LdStGeneral,
 590                    [(truncstorei16 GPRC:$rS, xaddr:$dst)]>,
 591                    PPC970_DGroup_Cracked;
 592 def STWX  : XForm_8<31, 151, (ops GPRC:$rS, memrr:$dst),
 593                    "stwx $rS, $dst", LdStGeneral,
 594                    [(store GPRC:$rS, xaddr:$dst)]>,
 595                    PPC970_DGroup_Cracked;
 596 def STWUX : XForm_8<31, 183, (ops GPRC:$rS, GPRC:$rA, GPRC:$rB),
 597                    "stwux $rS, $rA, $rB", LdStGeneral,
 598                    []>;
 599 def STHBRX: XForm_8<31, 918, (ops GPRC:$rS, memrr:$dst),
 600                    "sthbrx $rS, $dst", LdStGeneral,
 601                    [(PPCstbrx GPRC:$rS, xoaddr:$dst, srcvalue:$dummy, i16)]>,
 602                    PPC970_DGroup_Cracked;
 603 def STWBRX: XForm_8<31, 662, (ops GPRC:$rS, memrr:$dst),
 604                    "stwbrx $rS, $dst", LdStGeneral,
 605                    [(PPCstbrx GPRC:$rS, xoaddr:$dst, srcvalue:$dummy, i32)]>,
 606                    PPC970_DGroup_Cracked;
 607
 608 def STFIWX: XForm_28<31, 983, (ops F8RC:$frS, memrr:$dst),
 609                      "stfiwx $frS, $dst", LdStUX,
 610                      [(PPCstfiwx F8RC:$frS, xoaddr:$dst)]>;
 611 def STFSX : XForm_28<31, 663, (ops F4RC:$frS, memrr:$dst),
 612                      "stfsx $frS, $dst", LdStUX,
 613                      [(store F4RC:$frS, xaddr:$dst)]>;
 614 def STFDX : XForm_28<31, 727, (ops F8RC:$frS, memrr:$dst),
 615                      "stfdx $frS, $dst", LdStUX,
 616                      [(store F8RC:$frS, xaddr:$dst)]>;
 617 }
 618
 619
 620 //===----------------------------------------------------------------------===//
 621 // PPC32 Arithmetic Instructions.
 622 //
 623
 624 let PPC970_Unit = 1 in {  // FXU Operations.
 625 def ADDI   : DForm_2<14, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 626                      "addi $rD, $rA, $imm", IntGeneral,
 627                      [(set GPRC:$rD, (add GPRC:$rA, immSExt16:$imm))]>;
 628 def ADDIC  : DForm_2<12, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 629                      "addic $rD, $rA, $imm", IntGeneral,
 630                      [(set GPRC:$rD, (addc GPRC:$rA, immSExt16:$imm))]>,
 631                      PPC970_DGroup_Cracked;
 632 def ADDICo : DForm_2<13, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 633                      "addic. $rD, $rA, $imm", IntGeneral,
 634                      []>;
 635 def ADDIS  : DForm_2<15, (ops GPRC:$rD, GPRC:$rA, symbolHi:$imm),
 636                      "addis $rD, $rA, $imm", IntGeneral,
 637                      [(set GPRC:$rD, (add GPRC:$rA, imm16ShiftedSExt:$imm))]>;
 638 def LA     : DForm_2<14, (ops GPRC:$rD, GPRC:$rA, symbolLo:$sym),
 639                      "la $rD, $sym($rA)", IntGeneral,
 640                      [(set GPRC:$rD, (add GPRC:$rA,
 641                                           (PPClo tglobaladdr:$sym, 0)))]>;
 642 def MULLI  : DForm_2< 7, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 643                      "mulli $rD, $rA, $imm", IntMulLI,
 644                      [(set GPRC:$rD, (mul GPRC:$rA, immSExt16:$imm))]>;
 645 def SUBFIC : DForm_2< 8, (ops GPRC:$rD, GPRC:$rA, s16imm:$imm),
 646                      "subfic $rD, $rA, $imm", IntGeneral,
 647                      [(set GPRC:$rD, (subc immSExt16:$imm, GPRC:$rA))]>;
 648 def LI  : DForm_2_r0<14, (ops GPRC:$rD, symbolLo:$imm),
 649                      "li $rD, $imm", IntGeneral,
 650                      [(set GPRC:$rD, immSExt16:$imm)]>;
 651 def LIS : DForm_2_r0<15, (ops GPRC:$rD, symbolHi:$imm),
 652                      "lis $rD, $imm", IntGeneral,
 653                      [(set GPRC:$rD, imm16ShiftedSExt:$imm)]>;
 654 }
 655
 656 let PPC970_Unit = 1 in {  // FXU Operations.
 657 def ANDIo : DForm_4<28, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 658                     "andi. $dst, $src1, $src2", IntGeneral,
 659                     [(set GPRC:$dst, (and GPRC:$src1, immZExt16:$src2))]>,
 660                     isDOT;
 661 def ANDISo : DForm_4<29, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 662                     "andis. $dst, $src1, $src2", IntGeneral,
 663                     [(set GPRC:$dst, (and GPRC:$src1,imm16ShiftedZExt:$src2))]>,
 664                     isDOT;
 665 def ORI   : DForm_4<24, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 666                     "ori $dst, $src1, $src2", IntGeneral,
 667                     [(set GPRC:$dst, (or GPRC:$src1, immZExt16:$src2))]>;
 668 def ORIS  : DForm_4<25, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 669                     "oris $dst, $src1, $src2", IntGeneral,
 670                     [(set GPRC:$dst, (or GPRC:$src1, imm16ShiftedZExt:$src2))]>;
 671 def XORI  : DForm_4<26, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 672                     "xori $dst, $src1, $src2", IntGeneral,
 673                     [(set GPRC:$dst, (xor GPRC:$src1, immZExt16:$src2))]>;
 674 def XORIS : DForm_4<27, (ops GPRC:$dst, GPRC:$src1, u16imm:$src2),
 675                     "xoris $dst, $src1, $src2", IntGeneral,
 676                     [(set GPRC:$dst, (xor GPRC:$src1,imm16ShiftedZExt:$src2))]>;
 677 def NOP   : DForm_4_zero<24, (ops), "nop", IntGeneral,
 678                          []>;
 679 def CMPWI : DForm_5_ext<11, (ops CRRC:$crD, GPRC:$rA, s16imm:$imm),
 680                         "cmpwi $crD, $rA, $imm", IntCompare>;
 681 def CMPLWI : DForm_6_ext<10, (ops CRRC:$dst, GPRC:$src1, u16imm:$src2),
 682                          "cmplwi $dst, $src1, $src2", IntCompare>;
 683 }
 684
 685
 686 let PPC970_Unit = 1 in {  // FXU Operations.
 687 def NAND : XForm_6<31, 476, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 688                    "nand $rA, $rS, $rB", IntGeneral,
 689                    [(set GPRC:$rA, (not (and GPRC:$rS, GPRC:$rB)))]>;
 690 def AND  : XForm_6<31,  28, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 691                    "and $rA, $rS, $rB", IntGeneral,
 692                    [(set GPRC:$rA, (and GPRC:$rS, GPRC:$rB))]>;
 693 def ANDC : XForm_6<31,  60, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 694                    "andc $rA, $rS, $rB", IntGeneral,
 695                    [(set GPRC:$rA, (and GPRC:$rS, (not GPRC:$rB)))]>;
 696 def OR   : XForm_6<31, 444, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 697                    "or $rA, $rS, $rB", IntGeneral,
 698                    [(set GPRC:$rA, (or GPRC:$rS, GPRC:$rB))]>;
 699 def NOR  : XForm_6<31, 124, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 700                    "nor $rA, $rS, $rB", IntGeneral,
 701                    [(set GPRC:$rA, (not (or GPRC:$rS, GPRC:$rB)))]>;
 702 def ORC  : XForm_6<31, 412, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 703                    "orc $rA, $rS, $rB", IntGeneral,
 704                    [(set GPRC:$rA, (or GPRC:$rS, (not GPRC:$rB)))]>;
 705 def EQV  : XForm_6<31, 284, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 706                    "eqv $rA, $rS, $rB", IntGeneral,
 707                    [(set GPRC:$rA, (not (xor GPRC:$rS, GPRC:$rB)))]>;
 708 def XOR  : XForm_6<31, 316, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 709                    "xor $rA, $rS, $rB", IntGeneral,
 710                    [(set GPRC:$rA, (xor GPRC:$rS, GPRC:$rB))]>;
 711 def SLW  : XForm_6<31,  24, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 712                    "slw $rA, $rS, $rB", IntGeneral,
 713                    [(set GPRC:$rA, (PPCshl GPRC:$rS, GPRC:$rB))]>;
 714 def SRW  : XForm_6<31, 536, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 715                    "srw $rA, $rS, $rB", IntGeneral,
 716                    [(set GPRC:$rA, (PPCsrl GPRC:$rS, GPRC:$rB))]>;
 717 def SRAW : XForm_6<31, 792, (ops GPRC:$rA, GPRC:$rS, GPRC:$rB),
 718                    "sraw $rA, $rS, $rB", IntShift,
 719                    [(set GPRC:$rA, (PPCsra GPRC:$rS, GPRC:$rB))]>;
 720 }
 721
 722 let PPC970_Unit = 1 in {  // FXU Operations.
 723 def SRAWI : XForm_10<31, 824, (ops GPRC:$rA, GPRC:$rS, u5imm:$SH),
 724                      "srawi $rA, $rS, $SH", IntShift,
 725                      [(set GPRC:$rA, (sra GPRC:$rS, (i32 imm:$SH)))]>;
 726 def CNTLZW : XForm_11<31,  26, (ops GPRC:$rA, GPRC:$rS),
 727                       "cntlzw $rA, $rS", IntGeneral,
 728                       [(set GPRC:$rA, (ctlz GPRC:$rS))]>;
 729 def EXTSB  : XForm_11<31, 954, (ops GPRC:$rA, GPRC:$rS),
 730                       "extsb $rA, $rS", IntGeneral,
 731                       [(set GPRC:$rA, (sext_inreg GPRC:$rS, i8))]>;
 732 def EXTSH  : XForm_11<31, 922, (ops GPRC:$rA, GPRC:$rS),
 733                       "extsh $rA, $rS", IntGeneral,
 734                       [(set GPRC:$rA, (sext_inreg GPRC:$rS, i16))]>;
 735
 736 def CMPW   : XForm_16_ext<31, 0, (ops CRRC:$crD, GPRC:$rA, GPRC:$rB),
 737                           "cmpw $crD, $rA, $rB", IntCompare>;
 738 def CMPLW  : XForm_16_ext<31, 32, (ops CRRC:$crD, GPRC:$rA, GPRC:$rB),
 739                           "cmplw $crD, $rA, $rB", IntCompare>;
 740 }
 741 let PPC970_Unit = 3 in {  // FPU Operations.
 742 //def FCMPO  : XForm_17<63, 32, (ops CRRC:$crD, FPRC:$fA, FPRC:$fB),
 743 //                      "fcmpo $crD, $fA, $fB", FPCompare>;
 744 def FCMPUS : XForm_17<63, 0, (ops CRRC:$crD, F4RC:$fA, F4RC:$fB),
 745                       "fcmpu $crD, $fA, $fB", FPCompare>;
 746 def FCMPUD : XForm_17<63, 0, (ops CRRC:$crD, F8RC:$fA, F8RC:$fB),
 747                       "fcmpu $crD, $fA, $fB", FPCompare>;
 748
 749 def FCTIWZ : XForm_26<63, 15, (ops F8RC:$frD, F8RC:$frB),
 750                       "fctiwz $frD, $frB", FPGeneral,
 751                       [(set F8RC:$frD, (PPCfctiwz F8RC:$frB))]>;
 752 def FRSP   : XForm_26<63, 12, (ops F4RC:$frD, F8RC:$frB),
 753                       "frsp $frD, $frB", FPGeneral,
 754                       [(set F4RC:$frD, (fround F8RC:$frB))]>;
 755 def FSQRT  : XForm_26<63, 22, (ops F8RC:$frD, F8RC:$frB),
 756                       "fsqrt $frD, $frB", FPSqrt,
 757                       [(set F8RC:$frD, (fsqrt F8RC:$frB))]>;
 758 def FSQRTS : XForm_26<59, 22, (ops F4RC:$frD, F4RC:$frB),
 759                       "fsqrts $frD, $frB", FPSqrt,
 760                       [(set F4RC:$frD, (fsqrt F4RC:$frB))]>;
 761 }
 762
 763 /// FMR is split into 3 versions, one for 4/8 byte FP, and one for extending.
 764 ///
 765 /// Note that these are defined as pseudo-ops on the PPC970 because they are
 766 /// often coalesced away and we don't want the dispatch group builder to think
 767 /// that they will fill slots (which could cause the load of a LSU reject to
 768 /// sneak into a d-group with a store).
 769 def FMRS   : XForm_26<63, 72, (ops F4RC:$frD, F4RC:$frB),
 770                       "fmr $frD, $frB", FPGeneral,
 771                       []>,  // (set F4RC:$frD, F4RC:$frB)
 772                       PPC970_Unit_Pseudo;
 773 def FMRD   : XForm_26<63, 72, (ops F8RC:$frD, F8RC:$frB),
 774                       "fmr $frD, $frB", FPGeneral,
 775                       []>,  // (set F8RC:$frD, F8RC:$frB)
 776                       PPC970_Unit_Pseudo;
 777 def FMRSD  : XForm_26<63, 72, (ops F8RC:$frD, F4RC:$frB),
 778                       "fmr $frD, $frB", FPGeneral,
 779                       [(set F8RC:$frD, (fextend F4RC:$frB))]>,
 780                       PPC970_Unit_Pseudo;
 781
 782 let PPC970_Unit = 3 in {  // FPU Operations.
 783 // These are artificially split into two different forms, for 4/8 byte FP.
 784 def FABSS  : XForm_26<63, 264, (ops F4RC:$frD, F4RC:$frB),
 785                       "fabs $frD, $frB", FPGeneral,
 786                       [(set F4RC:$frD, (fabs F4RC:$frB))]>;
 787 def FABSD  : XForm_26<63, 264, (ops F8RC:$frD, F8RC:$frB),
 788                       "fabs $frD, $frB", FPGeneral,
 789                       [(set F8RC:$frD, (fabs F8RC:$frB))]>;
 790 def FNABSS : XForm_26<63, 136, (ops F4RC:$frD, F4RC:$frB),
 791                       "fnabs $frD, $frB", FPGeneral,
 792                       [(set F4RC:$frD, (fneg (fabs F4RC:$frB)))]>;
 793 def FNABSD : XForm_26<63, 136, (ops F8RC:$frD, F8RC:$frB),
 794                       "fnabs $frD, $frB", FPGeneral,
 795                       [(set F8RC:$frD, (fneg (fabs F8RC:$frB)))]>;
 796 def FNEGS  : XForm_26<63, 40, (ops F4RC:$frD, F4RC:$frB),
 797                       "fneg $frD, $frB", FPGeneral,
 798                       [(set F4RC:$frD, (fneg F4RC:$frB))]>;
 799 def FNEGD  : XForm_26<63, 40, (ops F8RC:$frD, F8RC:$frB),
 800                       "fneg $frD, $frB", FPGeneral,
 801                       [(set F8RC:$frD, (fneg F8RC:$frB))]>;
 802 }
 803
 804
 805 // XL-Form instructions.  condition register logical ops.
 806 //
 807 def MCRF   : XLForm_3<19, 0, (ops CRRC:$BF, CRRC:$BFA),
 808                       "mcrf $BF, $BFA", BrMCR>,
 809              PPC970_DGroup_First, PPC970_Unit_CRU;
 810
 811 // XFX-Form instructions.  Instructions that deal with SPRs.
 812 //
 813 def MFCTR : XFXForm_1_ext<31, 339, 9, (ops GPRC:$rT), "mfctr $rT", SprMFSPR>,
 814             PPC970_DGroup_First, PPC970_Unit_FXU;
 815 let Pattern = [(PPCmtctr GPRC:$rS)] in {
 816 def MTCTR : XFXForm_7_ext<31, 467, 9, (ops GPRC:$rS), "mtctr $rS", SprMTSPR>,
 817             PPC970_DGroup_First, PPC970_Unit_FXU;
 818 }
 819
 820 def MTLR  : XFXForm_7_ext<31, 467, 8, (ops GPRC:$rS), "mtlr $rS", SprMTSPR>,
 821             PPC970_DGroup_First, PPC970_Unit_FXU;
 822 def MFLR  : XFXForm_1_ext<31, 339, 8, (ops GPRC:$rT), "mflr $rT", SprMFSPR>,
 823             PPC970_DGroup_First, PPC970_Unit_FXU;
 824
 825 // Move to/from VRSAVE: despite being a SPR, the VRSAVE register is renamed like
 826 // a GPR on the PPC970.  As such, copies in and out have the same performance
 827 // characteristics as an OR instruction.
 828 def MTVRSAVE : XFXForm_7_ext<31, 467, 256, (ops GPRC:$rS),
 829                              "mtspr 256, $rS", IntGeneral>,
 830                PPC970_DGroup_Single, PPC970_Unit_FXU;
 831 def MFVRSAVE : XFXForm_1_ext<31, 339, 256, (ops GPRC:$rT),
 832                              "mfspr $rT, 256", IntGeneral>,
 833                PPC970_DGroup_First, PPC970_Unit_FXU;
 834
 835 def MTCRF : XFXForm_5<31, 144, (ops crbitm:$FXM, GPRC:$rS),
 836                       "mtcrf $FXM, $rS", BrMCRX>,
 837             PPC970_MicroCode, PPC970_Unit_CRU;
 838 def MFCR  : XFXForm_3<31, 19, (ops GPRC:$rT), "mfcr $rT", SprMFCR>,
 839             PPC970_MicroCode, PPC970_Unit_CRU;
 840 def MFOCRF: XFXForm_5a<31, 19, (ops GPRC:$rT, crbitm:$FXM),
 841                        "mfcr $rT, $FXM", SprMFCR>,
 842             PPC970_DGroup_First, PPC970_Unit_CRU;
 843
 844 let PPC970_Unit = 1 in {  // FXU Operations.
 845
 846 // XO-Form instructions.  Arithmetic instructions that can set overflow bit
 847 //
 848 def ADD4  : XOForm_1<31, 266, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 849                      "add $rT, $rA, $rB", IntGeneral,
 850                      [(set GPRC:$rT, (add GPRC:$rA, GPRC:$rB))]>;
 851 def ADDC  : XOForm_1<31, 10, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 852                      "addc $rT, $rA, $rB", IntGeneral,
 853                      [(set GPRC:$rT, (addc GPRC:$rA, GPRC:$rB))]>,
 854                      PPC970_DGroup_Cracked;
 855 def ADDE  : XOForm_1<31, 138, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 856                      "adde $rT, $rA, $rB", IntGeneral,
 857                      [(set GPRC:$rT, (adde GPRC:$rA, GPRC:$rB))]>;
 858 def DIVW  : XOForm_1<31, 491, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 859                      "divw $rT, $rA, $rB", IntDivW,
 860                      [(set GPRC:$rT, (sdiv GPRC:$rA, GPRC:$rB))]>,
 861                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
 862 def DIVWU : XOForm_1<31, 459, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 863                      "divwu $rT, $rA, $rB", IntDivW,
 864                      [(set GPRC:$rT, (udiv GPRC:$rA, GPRC:$rB))]>,
 865                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
 866 def MULHW : XOForm_1<31, 75, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 867                      "mulhw $rT, $rA, $rB", IntMulHW,
 868                      [(set GPRC:$rT, (mulhs GPRC:$rA, GPRC:$rB))]>;
 869 def MULHWU : XOForm_1<31, 11, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 870                      "mulhwu $rT, $rA, $rB", IntMulHWU,
 871                      [(set GPRC:$rT, (mulhu GPRC:$rA, GPRC:$rB))]>;
 872 def MULLW : XOForm_1<31, 235, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 873                      "mullw $rT, $rA, $rB", IntMulHW,
 874                      [(set GPRC:$rT, (mul GPRC:$rA, GPRC:$rB))]>;
 875 def SUBF  : XOForm_1<31, 40, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 876                      "subf $rT, $rA, $rB", IntGeneral,
 877                      [(set GPRC:$rT, (sub GPRC:$rB, GPRC:$rA))]>;
 878 def SUBFC : XOForm_1<31, 8, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 879                      "subfc $rT, $rA, $rB", IntGeneral,
 880                      [(set GPRC:$rT, (subc GPRC:$rB, GPRC:$rA))]>,
 881                      PPC970_DGroup_Cracked;
 882 def SUBFE : XOForm_1<31, 136, 0, (ops GPRC:$rT, GPRC:$rA, GPRC:$rB),
 883                      "subfe $rT, $rA, $rB", IntGeneral,
 884                      [(set GPRC:$rT, (sube GPRC:$rB, GPRC:$rA))]>;
 885 def ADDME  : XOForm_3<31, 234, 0, (ops GPRC:$rT, GPRC:$rA),
 886                       "addme $rT, $rA", IntGeneral,
 887                       [(set GPRC:$rT, (adde GPRC:$rA, immAllOnes))]>;
 888 def ADDZE  : XOForm_3<31, 202, 0, (ops GPRC:$rT, GPRC:$rA),
 889                       "addze $rT, $rA", IntGeneral,
 890                       [(set GPRC:$rT, (adde GPRC:$rA, 0))]>;
 891 def NEG    : XOForm_3<31, 104, 0, (ops GPRC:$rT, GPRC:$rA),
 892                       "neg $rT, $rA", IntGeneral,
 893                       [(set GPRC:$rT, (ineg GPRC:$rA))]>;
 894 def SUBFME : XOForm_3<31, 232, 0, (ops GPRC:$rT, GPRC:$rA),
 895                       "subfme $rT, $rA", IntGeneral,
 896                       [(set GPRC:$rT, (sube immAllOnes, GPRC:$rA))]>;
 897 def SUBFZE : XOForm_3<31, 200, 0, (ops GPRC:$rT, GPRC:$rA),
 898                       "subfze $rT, $rA", IntGeneral,
 899                       [(set GPRC:$rT, (sube 0, GPRC:$rA))]>;
 900 }
 901
 902 // A-Form instructions.  Most of the instructions executed in the FPU are of
 903 // this type.
 904 //
 905 let PPC970_Unit = 3 in {  // FPU Operations.
 906 def FMADD : AForm_1<63, 29,
 907                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
 908                     "fmadd $FRT, $FRA, $FRC, $FRB", FPFused,
 909                     [(set F8RC:$FRT, (fadd (fmul F8RC:$FRA, F8RC:$FRC),
 910                                            F8RC:$FRB))]>,
 911                     Requires<[FPContractions]>;
 912 def FMADDS : AForm_1<59, 29,
 913                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRC, F4RC:$FRB),
 914                     "fmadds $FRT, $FRA, $FRC, $FRB", FPGeneral,
 915                     [(set F4RC:$FRT, (fadd (fmul F4RC:$FRA, F4RC:$FRC),
 916                                            F4RC:$FRB))]>,
 917                     Requires<[FPContractions]>;
 918 def FMSUB : AForm_1<63, 28,
 919                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
 920                     "fmsub $FRT, $FRA, $FRC, $FRB", FPFused,
 921                     [(set F8RC:$FRT, (fsub (fmul F8RC:$FRA, F8RC:$FRC),
 922                                            F8RC:$FRB))]>,
 923                     Requires<[FPContractions]>;
 924 def FMSUBS : AForm_1<59, 28,
 925                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRC, F4RC:$FRB),
 926                     "fmsubs $FRT, $FRA, $FRC, $FRB", FPGeneral,
 927                     [(set F4RC:$FRT, (fsub (fmul F4RC:$FRA, F4RC:$FRC),
 928                                            F4RC:$FRB))]>,
 929                     Requires<[FPContractions]>;
 930 def FNMADD : AForm_1<63, 31,
 931                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
 932                     "fnmadd $FRT, $FRA, $FRC, $FRB", FPFused,
 933                     [(set F8RC:$FRT, (fneg (fadd (fmul F8RC:$FRA, F8RC:$FRC),
 934                                                  F8RC:$FRB)))]>,
 935                     Requires<[FPContractions]>;
 936 def FNMADDS : AForm_1<59, 31,
 937                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRC, F4RC:$FRB),
 938                     "fnmadds $FRT, $FRA, $FRC, $FRB", FPGeneral,
 939                     [(set F4RC:$FRT, (fneg (fadd (fmul F4RC:$FRA, F4RC:$FRC),
 940                                                  F4RC:$FRB)))]>,
 941                     Requires<[FPContractions]>;
 942 def FNMSUB : AForm_1<63, 30,
 943                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
 944                     "fnmsub $FRT, $FRA, $FRC, $FRB", FPFused,
 945                     [(set F8RC:$FRT, (fneg (fsub (fmul F8RC:$FRA, F8RC:$FRC),
 946                                                  F8RC:$FRB)))]>,
 947                     Requires<[FPContractions]>;
 948 def FNMSUBS : AForm_1<59, 30,
 949                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRC, F4RC:$FRB),
 950                     "fnmsubs $FRT, $FRA, $FRC, $FRB", FPGeneral,
 951                     [(set F4RC:$FRT, (fneg (fsub (fmul F4RC:$FRA, F4RC:$FRC),
 952                                                  F4RC:$FRB)))]>,
 953                     Requires<[FPContractions]>;
 954 // FSEL is artificially split into 4 and 8-byte forms for the result.  To avoid
 955 // having 4 of these, force the comparison to always be an 8-byte double (code
 956 // should use an FMRSD if the input comparison value really wants to be a float)
 957 // and 4/8 byte forms for the result and operand type..
 958 def FSELD : AForm_1<63, 23,
 959                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
 960                     "fsel $FRT, $FRA, $FRC, $FRB", FPGeneral,
 961                     [(set F8RC:$FRT, (PPCfsel F8RC:$FRA,F8RC:$FRC,F8RC:$FRB))]>;
 962 def FSELS : AForm_1<63, 23,
 963                      (ops F4RC:$FRT, F8RC:$FRA, F4RC:$FRC, F4RC:$FRB),
 964                      "fsel $FRT, $FRA, $FRC, $FRB", FPGeneral,
 965                     [(set F4RC:$FRT, (PPCfsel F8RC:$FRA,F4RC:$FRC,F4RC:$FRB))]>;
 966 def FADD  : AForm_2<63, 21,
 967                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRB),
 968                     "fadd $FRT, $FRA, $FRB", FPGeneral,
 969                     [(set F8RC:$FRT, (fadd F8RC:$FRA, F8RC:$FRB))]>;
 970 def FADDS : AForm_2<59, 21,
 971                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRB),
 972                     "fadds $FRT, $FRA, $FRB", FPGeneral,
 973                     [(set F4RC:$FRT, (fadd F4RC:$FRA, F4RC:$FRB))]>;
 974 def FDIV  : AForm_2<63, 18,
 975                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRB),
 976                     "fdiv $FRT, $FRA, $FRB", FPDivD,
 977                     [(set F8RC:$FRT, (fdiv F8RC:$FRA, F8RC:$FRB))]>;
 978 def FDIVS : AForm_2<59, 18,
 979                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRB),
 980                     "fdivs $FRT, $FRA, $FRB", FPDivS,
 981                     [(set F4RC:$FRT, (fdiv F4RC:$FRA, F4RC:$FRB))]>;
 982 def FMUL  : AForm_3<63, 25,
 983                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRB),
 984                     "fmul $FRT, $FRA, $FRB", FPFused,
 985                     [(set F8RC:$FRT, (fmul F8RC:$FRA, F8RC:$FRB))]>;
 986 def FMULS : AForm_3<59, 25,
 987                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRB),
 988                     "fmuls $FRT, $FRA, $FRB", FPGeneral,
 989                     [(set F4RC:$FRT, (fmul F4RC:$FRA, F4RC:$FRB))]>;
 990 def FSUB  : AForm_2<63, 20,
 991                     (ops F8RC:$FRT, F8RC:$FRA, F8RC:$FRB),
 992                     "fsub $FRT, $FRA, $FRB", FPGeneral,
 993                     [(set F8RC:$FRT, (fsub F8RC:$FRA, F8RC:$FRB))]>;
 994 def FSUBS : AForm_2<59, 20,
 995                     (ops F4RC:$FRT, F4RC:$FRA, F4RC:$FRB),
 996                     "fsubs $FRT, $FRA, $FRB", FPGeneral,
 997                     [(set F4RC:$FRT, (fsub F4RC:$FRA, F4RC:$FRB))]>;
 998 }
 999
1000 let PPC970_Unit = 1 in {  // FXU Operations.
1001 // M-Form instructions.  rotate and mask instructions.
1002 //
1003 let isCommutable = 1 in {
1004 // RLWIMI can be commuted if the rotate amount is zero.
1005 def RLWIMI : MForm_2<20,
1006                      (ops GPRC:$rA, GPRC:$rSi, GPRC:$rS, u5imm:$SH, u5imm:$MB,
1007                       u5imm:$ME), "rlwimi $rA, $rS, $SH, $MB, $ME", IntRotate,
1008                       []>, PPC970_DGroup_Cracked, RegConstraint<"$rSi = $rA">,
1009                       NoEncode<"$rSi">;
1010 }
1011 def RLWINM : MForm_2<21,
1012                      (ops GPRC:$rA, GPRC:$rS, u5imm:$SH, u5imm:$MB, u5imm:$ME),
1013                      "rlwinm $rA, $rS, $SH, $MB, $ME", IntGeneral,
1014                      []>;
1015 def RLWINMo : MForm_2<21,
1016                      (ops GPRC:$rA, GPRC:$rS, u5imm:$SH, u5imm:$MB, u5imm:$ME),
1017                      "rlwinm. $rA, $rS, $SH, $MB, $ME", IntGeneral,
1018                      []>, isDOT, PPC970_DGroup_Cracked;
1019 def RLWNM  : MForm_2<23,
1020                      (ops GPRC:$rA, GPRC:$rS, GPRC:$rB, u5imm:$MB, u5imm:$ME),
1021                      "rlwnm $rA, $rS, $rB, $MB, $ME", IntGeneral,
1022                      []>;
1023 }
1024
1025
1026 //===----------------------------------------------------------------------===//
1027 // DWARF Pseudo Instructions
1028 //
1029
1030 def DWARF_LOC        : Pseudo<(ops i32imm:$line, i32imm:$col, i32imm:$file),
1031                               "${:comment} .loc $file, $line, $col",
1032                       [(dwarf_loc (i32 imm:$line), (i32 imm:$col),
1033                                   (i32 imm:$file))]>;
1034
1035 def DWARF_LABEL      : Pseudo<(ops i32imm:$id),
1036                               "\n${:private}debug_loc$id:",
1037                       [(dwarf_label (i32 imm:$id))]>;
1038
1039 //===----------------------------------------------------------------------===//
1040 // PowerPC Instruction Patterns
1041 //
1042
1043 // Arbitrary immediate support.  Implement in terms of LIS/ORI.
1044 def : Pat<(i32 imm:$imm),
1045           (ORI (LIS (HI16 imm:$imm)), (LO16 imm:$imm))>;
1046
1047 // Implement the 'not' operation with the NOR instruction.
1048 def NOT : Pat<(not GPRC:$in),
1049               (NOR GPRC:$in, GPRC:$in)>;
1050
1051 // ADD an arbitrary immediate.
1052 def : Pat<(add GPRC:$in, imm:$imm),
1053           (ADDIS (ADDI GPRC:$in, (LO16 imm:$imm)), (HA16 imm:$imm))>;
1054 // OR an arbitrary immediate.
1055 def : Pat<(or GPRC:$in, imm:$imm),
1056           (ORIS (ORI GPRC:$in, (LO16 imm:$imm)), (HI16 imm:$imm))>;
1057 // XOR an arbitrary immediate.
1058 def : Pat<(xor GPRC:$in, imm:$imm),
1059           (XORIS (XORI GPRC:$in, (LO16 imm:$imm)), (HI16 imm:$imm))>;
1060 // SUBFIC
1061 def : Pat<(sub  immSExt16:$imm, GPRC:$in),
1062           (SUBFIC GPRC:$in, imm:$imm)>;
1063
1064 // Return void support.
1065 def : Pat<(ret), (BLR)>;
1066
1067 // SHL/SRL
1068 def : Pat<(shl GPRC:$in, (i32 imm:$imm)),
1069           (RLWINM GPRC:$in, imm:$imm, 0, (SHL32 imm:$imm))>;
1070 def : Pat<(srl GPRC:$in, (i32 imm:$imm)),
1071           (RLWINM GPRC:$in, (SRL32 imm:$imm), imm:$imm, 31)>;
1072
1073 // ROTL
1074 def : Pat<(rotl GPRC:$in, GPRC:$sh),
1075           (RLWNM GPRC:$in, GPRC:$sh, 0, 31)>;
1076 def : Pat<(rotl GPRC:$in, (i32 imm:$imm)),
1077           (RLWINM GPRC:$in, imm:$imm, 0, 31)>;
1078
1079 // RLWNM
1080 def : Pat<(and (rotl GPRC:$in, GPRC:$sh), maskimm32:$imm),
1081           (RLWNM GPRC:$in, GPRC:$sh, (MB maskimm32:$imm), (ME maskimm32:$imm))>;
1082
1083 // Calls
1084 def : Pat<(PPCcall (i32 tglobaladdr:$dst)),
1085           (BL tglobaladdr:$dst)>;
1086 def : Pat<(PPCcall (i32 texternalsym:$dst)),
1087           (BL texternalsym:$dst)>;
1088
1089 // Hi and Lo for Darwin Global Addresses.
1090 def : Pat<(PPChi tglobaladdr:$in, 0), (LIS tglobaladdr:$in)>;
1091 def : Pat<(PPClo tglobaladdr:$in, 0), (LI tglobaladdr:$in)>;
1092 def : Pat<(PPChi tconstpool:$in, 0), (LIS tconstpool:$in)>;
1093 def : Pat<(PPClo tconstpool:$in, 0), (LI tconstpool:$in)>;
1094 def : Pat<(PPChi tjumptable:$in, 0), (LIS tjumptable:$in)>;
1095 def : Pat<(PPClo tjumptable:$in, 0), (LI tjumptable:$in)>;
1096 def : Pat<(add GPRC:$in, (PPChi tglobaladdr:$g, 0)),
1097           (ADDIS GPRC:$in, tglobaladdr:$g)>;
1098 def : Pat<(add GPRC:$in, (PPChi tconstpool:$g, 0)),
1099           (ADDIS GPRC:$in, tconstpool:$g)>;
1100 def : Pat<(add GPRC:$in, (PPChi tjumptable:$g, 0)),
1101           (ADDIS GPRC:$in, tjumptable:$g)>;
1102
1103 // Fused negative multiply subtract, alternate pattern
1104 def : Pat<(fsub F8RC:$B, (fmul F8RC:$A, F8RC:$C)),
1105           (FNMSUB F8RC:$A, F8RC:$C, F8RC:$B)>,
1106           Requires<[FPContractions]>;
1107 def : Pat<(fsub F4RC:$B, (fmul F4RC:$A, F4RC:$C)),
1108           (FNMSUBS F4RC:$A, F4RC:$C, F4RC:$B)>,
1109           Requires<[FPContractions]>;
1110
1111 // Standard shifts.  These are represented separately from the real shifts above
1112 // so that we can distinguish between shifts that allow 5-bit and 6-bit shift
1113 // amounts.
1114 def : Pat<(sra GPRC:$rS, GPRC:$rB),
1115           (SRAW GPRC:$rS, GPRC:$rB)>;
1116 def : Pat<(srl GPRC:$rS, GPRC:$rB),
1117           (SRW GPRC:$rS, GPRC:$rB)>;
1118 def : Pat<(shl GPRC:$rS, GPRC:$rB),
1119           (SLW GPRC:$rS, GPRC:$rB)>;
1120
1121 def : Pat<(zextloadi1 iaddr:$src),
1122           (LBZ iaddr:$src)>;
1123 def : Pat<(zextloadi1 xaddr:$src),
1124           (LBZX xaddr:$src)>;
1125 def : Pat<(extloadi1 iaddr:$src),
1126           (LBZ iaddr:$src)>;
1127 def : Pat<(extloadi1 xaddr:$src),
1128           (LBZX xaddr:$src)>;
1129 def : Pat<(extloadi8 iaddr:$src),
1130           (LBZ iaddr:$src)>;
1131 def : Pat<(extloadi8 xaddr:$src),
1132           (LBZX xaddr:$src)>;
1133 def : Pat<(extloadi16 iaddr:$src),
1134           (LHZ iaddr:$src)>;
1135 def : Pat<(extloadi16 xaddr:$src),
1136           (LHZX xaddr:$src)>;
1137 def : Pat<(extloadf32 iaddr:$src),
1138           (FMRSD (LFS iaddr:$src))>;
1139 def : Pat<(extloadf32 xaddr:$src),
1140           (FMRSD (LFSX xaddr:$src))>;
1141
1142 include "PPCInstrAltivec.td"
1143 include "PPCInstr64Bit.td"