lib/Target/PowerPC/PPCInstrFormats.td

   1 //===- PowerPCInstrFormats.td - PowerPC Instruction Formats --*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 //
  12 // PowerPC instruction formats
  13
  14 class I<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin>
  15         : Instruction {
  16   field bits<32> Inst;
  17
  18   bit PPC64 = 0;  // Default value, override with isPPC64
  19
  20   let Name = "";
  21   let Namespace = "PPC";
  22   let Inst{0-5} = opcode;
  23   let OperandList = OL;
  24   let AsmString = asmstr;
  25   let Itinerary = itin;
  26
  27   /// These fields correspond to the fields in PPCInstrInfo.h.  Any changes to
  28   /// these must be reflected there!  See comments there for what these are.
  29   bits<1> PPC970_First = 0;
  30   bits<1> PPC970_Single = 0;
  31   bits<1> PPC970_Cracked = 0;
  32   bits<3> PPC970_Unit = 0;
  33 }
  34
  35 class PPC970_DGroup_First   { bits<1> PPC970_First = 1;  }
  36 class PPC970_DGroup_Single  { bits<1> PPC970_Single = 1; }
  37 class PPC970_DGroup_Cracked { bits<1> PPC970_Cracked = 1; }
  38 class PPC970_MicroCode;
  39
  40 class PPC970_Unit_Pseudo   { bits<3> PPC970_Unit = 0;   }
  41 class PPC970_Unit_FXU      { bits<3> PPC970_Unit = 1;   }
  42 class PPC970_Unit_LSU      { bits<3> PPC970_Unit = 2;   }
  43 class PPC970_Unit_FPU      { bits<3> PPC970_Unit = 3;   }
  44 class PPC970_Unit_CRU      { bits<3> PPC970_Unit = 4;   }
  45 class PPC970_Unit_VALU     { bits<3> PPC970_Unit = 5;   }
  46 class PPC970_Unit_VPERM    { bits<3> PPC970_Unit = 6;   }
  47 class PPC970_Unit_BRU      { bits<3> PPC970_Unit = 7;   }
  48
  49
  50 // 1.7.1 I-Form
  51 class IForm<bits<6> opcode, bit aa, bit lk, dag OL, string asmstr,
  52             InstrItinClass itin, list<dag> pattern>
  53          : I<opcode, OL, asmstr, itin> {
  54   let Pattern = pattern;
  55   bits<24> LI;
  56
  57   let Inst{6-29}  = LI;
  58   let Inst{30}    = aa;
  59   let Inst{31}    = lk;
  60 }
  61
  62 // 1.7.2 B-Form
  63 class BForm<bits<6> opcode, bit aa, bit lk, dag OL, string asmstr>
  64   : I<opcode, OL, asmstr, BrB> {
  65   bits<7> BIBO;  // 2 bits of BI and 5 bits of BO.
  66   bits<3>  CR;
  67   bits<14> BD;
  68
  69   bits<5> BI;
  70   let BI{0-1} = BIBO{5-6};
  71   let BI{2-4} = CR{0-2};
  72
  73   let Inst{6-10}  = BIBO{4-0};
  74   let Inst{11-15} = BI;
  75   let Inst{16-29} = BD;
  76   let Inst{30}    = aa;
  77   let Inst{31}    = lk;
  78 }
  79
  80
  81 // 1.7.4 D-Form
  82 class DForm_base<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
  83                  list<dag> pattern>
  84   : I<opcode, OL, asmstr, itin> {
  85   bits<5>  A;
  86   bits<5>  B;
  87   bits<16> C;
  88
  89   let Pattern = pattern;
  90
  91   let Inst{6-10}  = A;
  92   let Inst{11-15} = B;
  93   let Inst{16-31} = C;
  94 }
  95
  96 class DForm_1<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
  97               list<dag> pattern>
  98   : I<opcode, OL, asmstr, itin> {
  99   bits<5>  A;
 100   bits<16> C;
 101   bits<5>  B;
 102
 103   let Pattern = pattern;
 104
 105   let Inst{6-10}  = A;
 106   let Inst{11-15} = B;
 107   let Inst{16-31} = C;
 108 }
 109
 110 class DForm_2<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
 111               list<dag> pattern>
 112   : DForm_base<opcode, OL, asmstr, itin, pattern>;
 113
 114 class DForm_2_r0<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
 115                  list<dag> pattern>
 116   : I<opcode, OL, asmstr, itin> {
 117   bits<5>  A;
 118   bits<16> B;
 119
 120   let Pattern = pattern;
 121
 122   let Inst{6-10}  = A;
 123   let Inst{11-15} = 0;
 124   let Inst{16-31} = B;
 125 }
 126
 127 class DForm_4<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
 128               list<dag> pattern>
 129   : I<opcode, OL, asmstr, itin> {
 130   bits<5>  B;
 131   bits<5>  A;
 132   bits<16> C;
 133
 134   let Pattern = pattern;
 135
 136   let Inst{6-10}  = A;
 137   let Inst{11-15} = B;
 138   let Inst{16-31} = C;
 139 }
 140
 141 class DForm_4_zero<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
 142                    list<dag> pattern>
 143   : DForm_1<opcode, OL, asmstr, itin, pattern> {
 144   let A = 0;
 145   let B = 0;
 146   let C = 0;
 147 }
 148
 149 class DForm_5<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin>
 150   : I<opcode, OL, asmstr, itin> {
 151   bits<3>  BF;
 152   bits<1>  L;
 153   bits<5>  RA;
 154   bits<16> I;
 155
 156   let Inst{6-8}   = BF;
 157   let Inst{9}     = 0;
 158   let Inst{10}    = L;
 159   let Inst{11-15} = RA;
 160   let Inst{16-31} = I;
 161 }
 162
 163 class DForm_5_ext<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin>
 164   : DForm_5<opcode, OL, asmstr, itin> {
 165   let L = PPC64;
 166 }
 167
 168 class DForm_6<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin>
 169   : DForm_5<opcode, OL, asmstr, itin>;
 170
 171 class DForm_6_ext<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin>
 172   : DForm_6<opcode, OL, asmstr, itin> {
 173   let L = PPC64;
 174 }
 175
 176
 177 // 1.7.5 DS-Form
 178 class DSForm_1<bits<6> opcode, bits<2> xo, dag OL, string asmstr,
 179                InstrItinClass itin, list<dag> pattern>
 180          : I<opcode, OL, asmstr, itin> {
 181   bits<5>  RST;
 182   bits<14> DS;
 183   bits<5>  RA;
 184
 185   let Pattern = pattern;
 186
 187   let Inst{6-10}  = RST;
 188   let Inst{11-15} = RA;
 189   let Inst{16-29} = DS;
 190   let Inst{30-31} = xo;
 191 }
 192
 193 // 1.7.6 X-Form
 194 class XForm_base_r3xo<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 195                       InstrItinClass itin, list<dag> pattern>
 196   : I<opcode, OL, asmstr, itin> {
 197   bits<5> RST;
 198   bits<5> A;
 199   bits<5> B;
 200
 201   let Pattern = pattern;
 202
 203   bit RC = 0;    // set by isDOT
 204
 205   let Inst{6-10}  = RST;
 206   let Inst{11-15} = A;
 207   let Inst{16-20} = B;
 208   let Inst{21-30} = xo;
 209   let Inst{31}    = RC;
 210 }
 211
 212 // This is the same as XForm_base_r3xo, but the first two operands are swapped
 213 // when code is emitted.
 214 class XForm_base_r3xo_swapped
 215         <bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 216         InstrItinClass itin>
 217   : I<opcode, OL, asmstr, itin> {
 218   bits<5> A;
 219   bits<5> RST;
 220   bits<5> B;
 221
 222   bit RC = 0;    // set by isDOT
 223
 224   let Inst{6-10}  = RST;
 225   let Inst{11-15} = A;
 226   let Inst{16-20} = B;
 227   let Inst{21-30} = xo;
 228   let Inst{31}    = RC;
 229 }
 230
 231
 232 class XForm_1<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 233               InstrItinClass itin, list<dag> pattern>
 234   : XForm_base_r3xo<opcode, xo, OL, asmstr, itin, pattern>;
 235
 236 class XForm_6<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 237               InstrItinClass itin, list<dag> pattern>
 238   : XForm_base_r3xo_swapped<opcode, xo, OL, asmstr, itin> {
 239   let Pattern = pattern;
 240 }
 241
 242 class XForm_8<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 243               InstrItinClass itin, list<dag> pattern>
 244   : XForm_base_r3xo<opcode, xo, OL, asmstr, itin, pattern>;
 245
 246 class XForm_10<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 247                InstrItinClass itin, list<dag> pattern>
 248   : XForm_base_r3xo_swapped<opcode, xo, OL, asmstr, itin> {
 249     let Pattern = pattern;
 250 }
 251
 252 class XForm_11<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 253                InstrItinClass itin, list<dag> pattern>
 254   : XForm_base_r3xo_swapped<opcode, xo, OL, asmstr, itin> {
 255   let B = 0;
 256   let Pattern = pattern;
 257 }
 258
 259 class XForm_16<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 260                InstrItinClass itin>
 261          : I<opcode, OL, asmstr, itin> {
 262   bits<3> BF;
 263   bits<1> L;
 264   bits<5> RA;
 265   bits<5> RB;
 266
 267   let Inst{6-8}   = BF;
 268   let Inst{9}     = 0;
 269   let Inst{10}    = L;
 270   let Inst{11-15} = RA;
 271   let Inst{16-20} = RB;
 272   let Inst{21-30} = xo;
 273   let Inst{31}    = 0;
 274 }
 275
 276 class XForm_16_ext<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 277                    InstrItinClass itin>
 278   : XForm_16<opcode, xo, OL, asmstr, itin> {
 279   let L = PPC64;
 280 }
 281
 282 class XForm_17<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 283                InstrItinClass itin>
 284          : I<opcode, OL, asmstr, itin> {
 285   bits<3> BF;
 286   bits<5> FRA;
 287   bits<5> FRB;
 288
 289   let Inst{6-8}   = BF;
 290   let Inst{9-10}  = 0;
 291   let Inst{11-15} = FRA;
 292   let Inst{16-20} = FRB;
 293   let Inst{21-30} = xo;
 294   let Inst{31}    = 0;
 295 }
 296
 297 class XForm_25<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 298                InstrItinClass itin, list<dag> pattern>
 299   : XForm_base_r3xo<opcode, xo, OL, asmstr, itin, pattern> {
 300 }
 301
 302 class XForm_26<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 303                InstrItinClass itin, list<dag> pattern>
 304   : XForm_base_r3xo<opcode, xo, OL, asmstr, itin, pattern> {
 305   let A = 0;
 306 }
 307
 308 class XForm_28<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 309                InstrItinClass itin, list<dag> pattern>
 310   : XForm_base_r3xo<opcode, xo, OL, asmstr, itin, pattern> {
 311 }
 312
 313 // DCB_Form - Form X instruction, used for dcb* instructions.
 314 class DCB_Form<bits<10> xo, bits<5> immfield, dag OL, string asmstr,
 315                       InstrItinClass itin, list<dag> pattern>
 316   : I<31, OL, asmstr, itin> {
 317   bits<5> A;
 318   bits<5> B;
 319
 320   let Pattern = pattern;
 321
 322   let Inst{6-10}  = immfield;
 323   let Inst{11-15} = A;
 324   let Inst{16-20} = B;
 325   let Inst{21-30} = xo;
 326   let Inst{31}    = 0;
 327 }
 328
 329
 330 // DSS_Form - Form X instruction, used for altivec dss* instructions.
 331 class DSS_Form<bits<10> xo, dag OL, string asmstr,
 332                       InstrItinClass itin, list<dag> pattern>
 333   : I<31, OL, asmstr, itin> {
 334   bits<1> T;
 335   bits<2> STRM;
 336   bits<5> A;
 337   bits<5> B;
 338
 339   let Pattern = pattern;
 340
 341   let Inst{6}     = T;
 342   let Inst{7-8}   = 0;
 343   let Inst{9-10}  = STRM;
 344   let Inst{11-15} = A;
 345   let Inst{16-20} = B;
 346   let Inst{21-30} = xo;
 347   let Inst{31}    = 0;
 348 }
 349
 350 // 1.7.7 XL-Form
 351 class XLForm_1<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 352                InstrItinClass itin>
 353     : I<opcode, OL, asmstr, itin> {
 354   bits<3> CRD;
 355   bits<2> CRDb;
 356   bits<3> CRA;
 357   bits<2> CRAb;
 358   bits<3> CRB;
 359   bits<2> CRBb;
 360
 361   let Inst{6-8}   = CRD;
 362   let Inst{9-10}  = CRDb;
 363   let Inst{11-13} = CRA;
 364   let Inst{14-15} = CRAb;
 365   let Inst{16-18} = CRB;
 366   let Inst{19-20} = CRBb;
 367   let Inst{21-30} = xo;
 368   let Inst{31}    = 0;
 369 }
 370
 371 class XLForm_2<bits<6> opcode, bits<10> xo, bit lk, dag OL, string asmstr,
 372                InstrItinClass itin, list<dag> pattern>
 373     : I<opcode, OL, asmstr, itin> {
 374   bits<5> BO;
 375   bits<5> BI;
 376   bits<2> BH;
 377
 378   let Pattern = pattern;
 379
 380   let Inst{6-10}  = BO;
 381   let Inst{11-15} = BI;
 382   let Inst{16-18} = 0;
 383   let Inst{19-20} = BH;
 384   let Inst{21-30} = xo;
 385   let Inst{31}    = lk;
 386 }
 387
 388 class XLForm_2_br<bits<6> opcode, bits<10> xo, bit lk,
 389                   dag OL, string asmstr, InstrItinClass itin, list<dag> pattern>
 390   : XLForm_2<opcode, xo, lk, OL, asmstr, itin, pattern> {
 391   bits<7> BIBO;  // 2 bits of BI and 5 bits of BO.
 392   bits<3>  CR;
 393
 394   let BO = BIBO{2-6};
 395   let BI{0-1} = BIBO{0-1};
 396   let BI{2-4} = CR;
 397   let BH = 0;
 398 }
 399
 400
 401 class XLForm_2_ext<bits<6> opcode, bits<10> xo, bits<5> bo,  bits<5> bi, bit lk,
 402                   dag OL, string asmstr, InstrItinClass itin, list<dag> pattern>
 403   : XLForm_2<opcode, xo, lk, OL, asmstr, itin, pattern> {
 404   let BO = bo;
 405   let BI = bi;
 406   let BH = 0;
 407 }
 408
 409 class XLForm_3<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 410                InstrItinClass itin>
 411          : I<opcode, OL, asmstr, itin> {
 412   bits<3> BF;
 413   bits<3> BFA;
 414
 415   let Inst{6-8}   = BF;
 416   let Inst{9-10}  = 0;
 417   let Inst{11-13} = BFA;
 418   let Inst{14-15} = 0;
 419   let Inst{16-20} = 0;
 420   let Inst{21-30} = xo;
 421   let Inst{31}    = 0;
 422 }
 423
 424 // 1.7.8 XFX-Form
 425 class XFXForm_1<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 426                 InstrItinClass itin>
 427          : I<opcode, OL, asmstr, itin> {
 428   bits<5>  RT;
 429   bits<10> SPR;
 430
 431   let Inst{6-10}  = RT;
 432   let Inst{11}    = SPR{4};
 433   let Inst{12}    = SPR{3};
 434   let Inst{13}    = SPR{2};
 435   let Inst{14}    = SPR{1};
 436   let Inst{15}    = SPR{0};
 437   let Inst{16}    = SPR{9};
 438   let Inst{17}    = SPR{8};
 439   let Inst{18}    = SPR{7};
 440   let Inst{19}    = SPR{6};
 441   let Inst{20}    = SPR{5};
 442   let Inst{21-30} = xo;
 443   let Inst{31}    = 0;
 444 }
 445
 446 class XFXForm_1_ext<bits<6> opcode, bits<10> xo, bits<10> spr,
 447                    dag OL, string asmstr, InstrItinClass itin>
 448   : XFXForm_1<opcode, xo, OL, asmstr, itin> {
 449   let SPR = spr;
 450 }
 451
 452 class XFXForm_3<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 453                 InstrItinClass itin>
 454          : I<opcode, OL, asmstr, itin> {
 455   bits<5>  RT;
 456
 457   let Inst{6-10}  = RT;
 458   let Inst{11-20} = 0;
 459   let Inst{21-30} = xo;
 460   let Inst{31}    = 0;
 461 }
 462
 463 class XFXForm_5<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 464                 InstrItinClass itin>
 465   : I<opcode, OL, asmstr, itin> {
 466   bits<8>  FXM;
 467   bits<5>  ST;
 468
 469   let Inst{6-10}  = ST;
 470   let Inst{11}    = 0;
 471   let Inst{12-19} = FXM;
 472   let Inst{20}    = 0;
 473   let Inst{21-30} = xo;
 474   let Inst{31}    = 0;
 475 }
 476
 477 class XFXForm_5a<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 478                  InstrItinClass itin>
 479   : I<opcode, OL, asmstr, itin> {
 480   bits<5>  ST;
 481   bits<8>  FXM;
 482
 483   let Inst{6-10}  = ST;
 484   let Inst{11}    = 1;
 485   let Inst{12-19} = FXM;
 486   let Inst{20}    = 0;
 487   let Inst{21-30} = xo;
 488   let Inst{31}    = 0;
 489 }
 490
 491 class XFXForm_7<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 492                 InstrItinClass itin>
 493   : XFXForm_1<opcode, xo, OL, asmstr, itin>;
 494
 495 class XFXForm_7_ext<bits<6> opcode, bits<10> xo, bits<10> spr,
 496                     dag OL, string asmstr, InstrItinClass itin>
 497   : XFXForm_7<opcode, xo, OL, asmstr, itin> {
 498   let SPR = spr;
 499 }
 500
 501 // 1.7.10 XS-Form - SRADI.
 502 class XSForm_1<bits<6> opcode, bits<9> xo, dag OL, string asmstr,
 503                InstrItinClass itin, list<dag> pattern>
 504          : I<opcode, OL, asmstr, itin> {
 505   bits<5> RS;
 506   bits<5> A;
 507   bits<6> SH;
 508
 509   bit RC = 0;    // set by isDOT
 510   let Pattern = pattern;
 511
 512   let Inst{6-10}  = RS;
 513   let Inst{11-15} = A;
 514   let Inst{16-20} = SH{4,3,2,1,0};
 515   let Inst{21-29} = xo;
 516   let Inst{30}    = SH{5};
 517   let Inst{31}    = RC;
 518 }
 519
 520 // 1.7.11 XO-Form
 521 class XOForm_1<bits<6> opcode, bits<9> xo, bit oe, dag OL, string asmstr,
 522                InstrItinClass itin, list<dag> pattern>
 523          : I<opcode, OL, asmstr, itin> {
 524   bits<5> RT;
 525   bits<5> RA;
 526   bits<5> RB;
 527
 528   let Pattern = pattern;
 529
 530   bit RC = 0;    // set by isDOT
 531
 532   let Inst{6-10}  = RT;
 533   let Inst{11-15} = RA;
 534   let Inst{16-20} = RB;
 535   let Inst{21}    = oe;
 536   let Inst{22-30} = xo;
 537   let Inst{31}    = RC;
 538 }
 539
 540 class XOForm_3<bits<6> opcode, bits<9> xo, bit oe,
 541                dag OL, string asmstr, InstrItinClass itin, list<dag> pattern>
 542   : XOForm_1<opcode, xo, oe, OL, asmstr, itin, pattern> {
 543   let RB = 0;
 544 }
 545
 546 // 1.7.12 A-Form
 547 class AForm_1<bits<6> opcode, bits<5> xo, dag OL, string asmstr,
 548               InstrItinClass itin, list<dag> pattern>
 549          : I<opcode, OL, asmstr, itin> {
 550   bits<5> FRT;
 551   bits<5> FRA;
 552   bits<5> FRC;
 553   bits<5> FRB;
 554
 555   let Pattern = pattern;
 556
 557   bit RC = 0;    // set by isDOT
 558
 559   let Inst{6-10}  = FRT;
 560   let Inst{11-15} = FRA;
 561   let Inst{16-20} = FRB;
 562   let Inst{21-25} = FRC;
 563   let Inst{26-30} = xo;
 564   let Inst{31}    = RC;
 565 }
 566
 567 class AForm_2<bits<6> opcode, bits<5> xo, dag OL, string asmstr,
 568               InstrItinClass itin, list<dag> pattern>
 569   : AForm_1<opcode, xo, OL, asmstr, itin, pattern> {
 570   let FRC = 0;
 571 }
 572
 573 class AForm_3<bits<6> opcode, bits<5> xo, dag OL, string asmstr,
 574               InstrItinClass itin, list<dag> pattern>
 575   : AForm_1<opcode, xo, OL, asmstr, itin, pattern> {
 576   let FRB = 0;
 577 }
 578
 579 // 1.7.13 M-Form
 580 class MForm_1<bits<6> opcode, dag OL, string asmstr,
 581               InstrItinClass itin, list<dag> pattern>
 582     : I<opcode, OL, asmstr, itin> {
 583   bits<5> RA;
 584   bits<5> RS;
 585   bits<5> RB;
 586   bits<5> MB;
 587   bits<5> ME;
 588
 589   let Pattern = pattern;
 590
 591   bit RC = 0;    // set by isDOT
 592
 593   let Inst{6-10}  = RS;
 594   let Inst{11-15} = RA;
 595   let Inst{16-20} = RB;
 596   let Inst{21-25} = MB;
 597   let Inst{26-30} = ME;
 598   let Inst{31}    = RC;
 599 }
 600
 601 class MForm_2<bits<6> opcode, dag OL, string asmstr,
 602               InstrItinClass itin, list<dag> pattern>
 603   : MForm_1<opcode, OL, asmstr, itin, pattern> {
 604 }
 605
 606 // 1.7.14 MD-Form
 607 class MDForm_1<bits<6> opcode, bits<3> xo, dag OL, string asmstr,
 608                InstrItinClass itin, list<dag> pattern>
 609     : I<opcode, OL, asmstr, itin> {
 610   bits<5> RA;
 611   bits<5> RS;
 612   bits<6> SH;
 613   bits<6> MBE;
 614
 615   let Pattern = pattern;
 616
 617   bit RC = 0;    // set by isDOT
 618
 619   let Inst{6-10}  = RS;
 620   let Inst{11-15} = RA;
 621   let Inst{16-20} = SH{4,3,2,1,0};
 622   let Inst{21-26} = MBE{4,3,2,1,0,5};
 623   let Inst{27-29} = xo;
 624   let Inst{30}    = SH{5};
 625   let Inst{31}    = RC;
 626 }
 627
 628
 629
 630 // E-1 VA-Form
 631
 632 // VAForm_1 - DACB ordering.
 633 class VAForm_1<bits<6> xo, dag OL, string asmstr,
 634                InstrItinClass itin, list<dag> pattern>
 635     : I<4, OL, asmstr, itin> {
 636   bits<5> VD;
 637   bits<5> VA;
 638   bits<5> VC;
 639   bits<5> VB;
 640
 641   let Pattern = pattern;
 642
 643   let Inst{6-10}  = VD;
 644   let Inst{11-15} = VA;
 645   let Inst{16-20} = VB;
 646   let Inst{21-25} = VC;
 647   let Inst{26-31} = xo;
 648 }
 649
 650 // VAForm_1a - DABC ordering.
 651 class VAForm_1a<bits<6> xo, dag OL, string asmstr,
 652                 InstrItinClass itin, list<dag> pattern>
 653     : I<4, OL, asmstr, itin> {
 654   bits<5> VD;
 655   bits<5> VA;
 656   bits<5> VB;
 657   bits<5> VC;
 658
 659   let Pattern = pattern;
 660
 661   let Inst{6-10}  = VD;
 662   let Inst{11-15} = VA;
 663   let Inst{16-20} = VB;
 664   let Inst{21-25} = VC;
 665   let Inst{26-31} = xo;
 666 }
 667
 668 class VAForm_2<bits<6> xo, dag OL, string asmstr,
 669                InstrItinClass itin, list<dag> pattern>
 670     : I<4, OL, asmstr, itin> {
 671   bits<5> VD;
 672   bits<5> VA;
 673   bits<5> VB;
 674   bits<4> SH;
 675
 676   let Pattern = pattern;
 677
 678   let Inst{6-10}  = VD;
 679   let Inst{11-15} = VA;
 680   let Inst{16-20} = VB;
 681   let Inst{21}    = 0;
 682   let Inst{22-25} = SH;
 683   let Inst{26-31} = xo;
 684 }
 685
 686 // E-2 VX-Form
 687 class VXForm_1<bits<11> xo, dag OL, string asmstr,
 688                InstrItinClass itin, list<dag> pattern>
 689     : I<4, OL, asmstr, itin> {
 690   bits<5> VD;
 691   bits<5> VA;
 692   bits<5> VB;
 693
 694   let Pattern = pattern;
 695
 696   let Inst{6-10}  = VD;
 697   let Inst{11-15} = VA;
 698   let Inst{16-20} = VB;
 699   let Inst{21-31} = xo;
 700 }
 701
 702 class VXForm_setzero<bits<11> xo, dag OL, string asmstr,
 703                InstrItinClass itin, list<dag> pattern>
 704     : VXForm_1<xo, OL, asmstr, itin, pattern> {
 705   let VA = VD;
 706   let VB = VD;
 707 }
 708
 709
 710 class VXForm_2<bits<11> xo, dag OL, string asmstr,
 711                InstrItinClass itin, list<dag> pattern>
 712     : I<4, OL, asmstr, itin> {
 713   bits<5> VD;
 714   bits<5> VB;
 715
 716   let Pattern = pattern;
 717
 718   let Inst{6-10}  = VD;
 719   let Inst{11-15} = 0;
 720   let Inst{16-20} = VB;
 721   let Inst{21-31} = xo;
 722 }
 723
 724 class VXForm_3<bits<11> xo, dag OL, string asmstr,
 725                InstrItinClass itin, list<dag> pattern>
 726     : I<4, OL, asmstr, itin> {
 727   bits<5> VD;
 728   bits<5> IMM;
 729
 730   let Pattern = pattern;
 731
 732   let Inst{6-10}  = VD;
 733   let Inst{11-15} = IMM;
 734   let Inst{16-20} = 0;
 735   let Inst{21-31} = xo;
 736 }
 737
 738 /// VXForm_4 - VX instructions with "VD,0,0" register fields, like mfvscr.
 739 class VXForm_4<bits<11> xo, dag OL, string asmstr,
 740                InstrItinClass itin, list<dag> pattern>
 741     : I<4, OL, asmstr, itin> {
 742   bits<5> VD;
 743
 744   let Pattern = pattern;
 745
 746   let Inst{6-10}  = VD;
 747   let Inst{11-15} = 0;
 748   let Inst{16-20} = 0;
 749   let Inst{21-31} = xo;
 750 }
 751
 752 /// VXForm_5 - VX instructions with "0,0,VB" register fields, like mtvscr.
 753 class VXForm_5<bits<11> xo, dag OL, string asmstr,
 754                InstrItinClass itin, list<dag> pattern>
 755     : I<4, OL, asmstr, itin> {
 756   bits<5> VB;
 757
 758   let Pattern = pattern;
 759
 760   let Inst{6-10}  = 0;
 761   let Inst{11-15} = 0;
 762   let Inst{16-20} = VB;
 763   let Inst{21-31} = xo;
 764 }
 765
 766 // E-4 VXR-Form
 767 class VXRForm_1<bits<10> xo, dag OL, string asmstr,
 768                InstrItinClass itin, list<dag> pattern>
 769     : I<4, OL, asmstr, itin> {
 770   bits<5> VD;
 771   bits<5> VA;
 772   bits<5> VB;
 773   bit RC = 0;
 774
 775   let Pattern = pattern;
 776
 777   let Inst{6-10}  = VD;
 778   let Inst{11-15} = VA;
 779   let Inst{16-20} = VB;
 780   let Inst{21}    = RC;
 781   let Inst{22-31} = xo;
 782 }
 783
 784 //===----------------------------------------------------------------------===//
 785 class Pseudo<dag OL, string asmstr, list<dag> pattern>
 786     : I<0, OL, asmstr, NoItinerary> {
 787   let PPC64 = 0;
 788   let Pattern = pattern;
 789   let Inst{31-0} = 0;
 790 }