lib/Target/PowerPC/PPCInstrFormats.td

   1 //===- PowerPCInstrFormats.td - PowerPC Instruction Formats --*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 //
  12 // PowerPC instruction formats
  13
  14 class I<bits<6> opcode, dag OOL, dag IOL, string asmstr, InstrItinClass itin>
  15         : Instruction {
  16   field bits<32> Inst;
  17   field bits<32> SoftFail = 0;
  18   let Size = 4;
  19
  20   bit PPC64 = 0;  // Default value, override with isPPC64
  21
  22   let Namespace = "PPC";
  23   let Inst{0-5} = opcode;
  24   let OutOperandList = OOL;
  25   let InOperandList = IOL;
  26   let AsmString = asmstr;
  27   let Itinerary = itin;
  28
  29   bits<1> PPC970_First = 0;
  30   bits<1> PPC970_Single = 0;
  31   bits<1> PPC970_Cracked = 0;
  32   bits<3> PPC970_Unit = 0;
  33
  34   /// These fields correspond to the fields in PPCInstrInfo.h.  Any changes to
  35   /// these must be reflected there!  See comments there for what these are.
  36   let TSFlags{0}   = PPC970_First;
  37   let TSFlags{1}   = PPC970_Single;
  38   let TSFlags{2}   = PPC970_Cracked;
  39   let TSFlags{5-3} = PPC970_Unit;
  40
  41   // Fields used for relation models.
  42   string BaseName = "";
  43
  44   // For cases where multiple instruction definitions really represent the
  45   // same underlying instruction but with one definition for 64-bit arguments
  46   // and one for 32-bit arguments, this bit breaks the degeneracy between
  47   // the two forms and allows TableGen to generate mapping tables.
  48   bit Interpretation64Bit = 0;
  49 }
  50
  51 class PPC970_DGroup_First   { bits<1> PPC970_First = 1;  }
  52 class PPC970_DGroup_Single  { bits<1> PPC970_Single = 1; }
  53 class PPC970_DGroup_Cracked { bits<1> PPC970_Cracked = 1; }
  54 class PPC970_MicroCode;
  55
  56 class PPC970_Unit_Pseudo   { bits<3> PPC970_Unit = 0;   }
  57 class PPC970_Unit_FXU      { bits<3> PPC970_Unit = 1;   }
  58 class PPC970_Unit_LSU      { bits<3> PPC970_Unit = 2;   }
  59 class PPC970_Unit_FPU      { bits<3> PPC970_Unit = 3;   }
  60 class PPC970_Unit_CRU      { bits<3> PPC970_Unit = 4;   }
  61 class PPC970_Unit_VALU     { bits<3> PPC970_Unit = 5;   }
  62 class PPC970_Unit_VPERM    { bits<3> PPC970_Unit = 6;   }
  63 class PPC970_Unit_BRU      { bits<3> PPC970_Unit = 7;   }
  64
  65 // Two joined instructions; used to emit two adjacent instructions as one.
  66 // The itinerary from the first instruction is used for scheduling and
  67 // classification.
  68 class I2<bits<6> opcode1, bits<6> opcode2, dag OOL, dag IOL, string asmstr,
  69          InstrItinClass itin>
  70         : Instruction {
  71   field bits<64> Inst;
  72   field bits<64> SoftFail = 0;
  73   let Size = 8;
  74
  75   bit PPC64 = 0;  // Default value, override with isPPC64
  76
  77   let Namespace = "PPC";
  78   let Inst{0-5} = opcode1;
  79   let Inst{32-37} = opcode2;
  80   let OutOperandList = OOL;
  81   let InOperandList = IOL;
  82   let AsmString = asmstr;
  83   let Itinerary = itin;
  84
  85   bits<1> PPC970_First = 0;
  86   bits<1> PPC970_Single = 0;
  87   bits<1> PPC970_Cracked = 0;
  88   bits<3> PPC970_Unit = 0;
  89
  90   /// These fields correspond to the fields in PPCInstrInfo.h.  Any changes to
  91   /// these must be reflected there!  See comments there for what these are.
  92   let TSFlags{0}   = PPC970_First;
  93   let TSFlags{1}   = PPC970_Single;
  94   let TSFlags{2}   = PPC970_Cracked;
  95   let TSFlags{5-3} = PPC970_Unit;
  96
  97   // Fields used for relation models.
  98   string BaseName = "";
  99   bit Interpretation64Bit = 0;
 100 }
 101
 102 // 1.7.1 I-Form
 103 class IForm<bits<6> opcode, bit aa, bit lk, dag OOL, dag IOL, string asmstr,
 104             InstrItinClass itin, list<dag> pattern>
 105          : I<opcode, OOL, IOL, asmstr, itin> {
 106   let Pattern = pattern;
 107   bits<24> LI;
 108
 109   let Inst{6-29}  = LI;
 110   let Inst{30}    = aa;
 111   let Inst{31}    = lk;
 112 }
 113
 114 // 1.7.2 B-Form
 115 class BForm<bits<6> opcode, bit aa, bit lk, dag OOL, dag IOL, string asmstr>
 116   : I<opcode, OOL, IOL, asmstr, IIC_BrB> {
 117   bits<7> BIBO;  // 2 bits of BI and 5 bits of BO.
 118   bits<3>  CR;
 119   bits<14> BD;
 120
 121   bits<5> BI;
 122   let BI{0-1} = BIBO{5-6};
 123   let BI{2-4} = CR{0-2};
 124
 125   let Inst{6-10}  = BIBO{4-0};
 126   let Inst{11-15} = BI;
 127   let Inst{16-29} = BD;
 128   let Inst{30}    = aa;
 129   let Inst{31}    = lk;
 130 }
 131
 132 class BForm_1<bits<6> opcode, bits<5> bo, bit aa, bit lk, dag OOL, dag IOL,
 133              string asmstr>
 134   : BForm<opcode, aa, lk, OOL, IOL, asmstr> {
 135   let BIBO{4-0} = bo;
 136   let BIBO{6-5} = 0;
 137   let CR = 0;
 138 }
 139
 140 class BForm_2<bits<6> opcode, bits<5> bo, bits<5> bi, bit aa, bit lk,
 141               dag OOL, dag IOL, string asmstr>
 142   : I<opcode, OOL, IOL, asmstr, IIC_BrB> {
 143   bits<14> BD;
 144
 145   let Inst{6-10}  = bo;
 146   let Inst{11-15} = bi;
 147   let Inst{16-29} = BD;
 148   let Inst{30}    = aa;
 149   let Inst{31}    = lk;
 150 }
 151
 152 class BForm_3<bits<6> opcode, bit aa, bit lk,
 153               dag OOL, dag IOL, string asmstr>
 154   : I<opcode, OOL, IOL, asmstr, IIC_BrB> {
 155   bits<5> BO;
 156   bits<5> BI;
 157   bits<14> BD;
 158
 159   let Inst{6-10}  = BO;
 160   let Inst{11-15} = BI;
 161   let Inst{16-29} = BD;
 162   let Inst{30}    = aa;
 163   let Inst{31}    = lk;
 164 }
 165
 166 class BForm_4<bits<6> opcode, bits<5> bo, bit aa, bit lk,
 167               dag OOL, dag IOL, string asmstr>
 168   : I<opcode, OOL, IOL, asmstr, IIC_BrB> {
 169   bits<5> BI;
 170   bits<14> BD;
 171
 172   let Inst{6-10}  = bo;
 173   let Inst{11-15} = BI;
 174   let Inst{16-29} = BD;
 175   let Inst{30}    = aa;
 176   let Inst{31}    = lk;
 177 }
 178
 179 // 1.7.3 SC-Form
 180 class SCForm<bits<6> opcode, bits<1> xo,
 181                      dag OOL, dag IOL, string asmstr, InstrItinClass itin,
 182                      list<dag> pattern>
 183   : I<opcode, OOL, IOL, asmstr, itin> {
 184   bits<7>  LEV;
 185
 186   let Pattern = pattern;
 187
 188   let Inst{20-26} = LEV;
 189   let Inst{30}    = xo;
 190 }
 191
 192 // 1.7.4 D-Form
 193 class DForm_base<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 194                  InstrItinClass itin, list<dag> pattern>
 195   : I<opcode, OOL, IOL, asmstr, itin> {
 196   bits<5>  A;
 197   bits<5>  B;
 198   bits<16> C;
 199
 200   let Pattern = pattern;
 201
 202   let Inst{6-10}  = A;
 203   let Inst{11-15} = B;
 204   let Inst{16-31} = C;
 205 }
 206
 207 class DForm_1<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 208               InstrItinClass itin, list<dag> pattern>
 209   : I<opcode, OOL, IOL, asmstr, itin> {
 210   bits<5>  A;
 211   bits<21> Addr;
 212
 213   let Pattern = pattern;
 214
 215   let Inst{6-10}  = A;
 216   let Inst{11-15} = Addr{20-16}; // Base Reg
 217   let Inst{16-31} = Addr{15-0};  // Displacement
 218 }
 219
 220 class DForm_1a<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 221                InstrItinClass itin, list<dag> pattern>
 222   : I<opcode, OOL, IOL, asmstr, itin> {
 223   bits<5>  A;
 224   bits<16> C;
 225   bits<5>  B;
 226
 227   let Pattern = pattern;
 228
 229   let Inst{6-10}  = A;
 230   let Inst{11-15} = B;
 231   let Inst{16-31} = C;
 232 }
 233
 234
 235 class DForm_2<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 236               InstrItinClass itin, list<dag> pattern>
 237   : DForm_base<opcode, OOL, IOL, asmstr, itin, pattern> {
 238
 239   // Even though ADDICo does not really have an RC bit, provide
 240   // the declaration of one here so that isDOT has something to set.
 241   bit RC = 0;
 242 }
 243
 244 class DForm_2_r0<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 245                  InstrItinClass itin, list<dag> pattern>
 246   : I<opcode, OOL, IOL, asmstr, itin> {
 247   bits<5>  A;
 248   bits<16> B;
 249
 250   let Pattern = pattern;
 251
 252   let Inst{6-10}  = A;
 253   let Inst{11-15} = 0;
 254   let Inst{16-31} = B;
 255 }
 256
 257 class DForm_4<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 258               InstrItinClass itin, list<dag> pattern>
 259   : I<opcode, OOL, IOL, asmstr, itin> {
 260   bits<5>  B;
 261   bits<5>  A;
 262   bits<16> C;
 263
 264   let Pattern = pattern;
 265
 266   let Inst{6-10}  = A;
 267   let Inst{11-15} = B;
 268   let Inst{16-31} = C;
 269 }
 270
 271 class DForm_4_zero<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 272                    InstrItinClass itin, list<dag> pattern>
 273   : DForm_1<opcode, OOL, IOL, asmstr, itin, pattern> {
 274   let A = 0;
 275   let Addr = 0;
 276 }
 277
 278 class DForm_4_fixedreg_zero<bits<6> opcode, bits<5> R, dag OOL, dag IOL,
 279                             string asmstr, InstrItinClass itin,
 280                             list<dag> pattern>
 281   : DForm_4<opcode, OOL, IOL, asmstr, itin, pattern> {
 282   let A = R;
 283   let B = R;
 284   let C = 0;
 285 }
 286
 287 class IForm_and_DForm_1<bits<6> opcode1, bit aa, bit lk, bits<6> opcode2,
 288             dag OOL, dag IOL, string asmstr,
 289             InstrItinClass itin, list<dag> pattern>
 290          : I2<opcode1, opcode2, OOL, IOL, asmstr, itin> {
 291   bits<5>  A;
 292   bits<21> Addr;
 293
 294   let Pattern = pattern;
 295   bits<24> LI;
 296
 297   let Inst{6-29}  = LI;
 298   let Inst{30}    = aa;
 299   let Inst{31}    = lk;
 300
 301   let Inst{38-42}  = A;
 302   let Inst{43-47} = Addr{20-16}; // Base Reg
 303   let Inst{48-63} = Addr{15-0};  // Displacement
 304 }
 305
 306 // This is used to emit BL8+NOP.
 307 class IForm_and_DForm_4_zero<bits<6> opcode1, bit aa, bit lk, bits<6> opcode2,
 308             dag OOL, dag IOL, string asmstr,
 309             InstrItinClass itin, list<dag> pattern>
 310          :  IForm_and_DForm_1<opcode1, aa, lk, opcode2,
 311                               OOL, IOL, asmstr, itin, pattern> {
 312   let A = 0;
 313   let Addr = 0;
 314 }
 315
 316 class DForm_5<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 317               InstrItinClass itin>
 318   : I<opcode, OOL, IOL, asmstr, itin> {
 319   bits<3>  BF;
 320   bits<1>  L;
 321   bits<5>  RA;
 322   bits<16> I;
 323
 324   let Inst{6-8}   = BF;
 325   let Inst{9}     = 0;
 326   let Inst{10}    = L;
 327   let Inst{11-15} = RA;
 328   let Inst{16-31} = I;
 329 }
 330
 331 class DForm_5_ext<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 332                   InstrItinClass itin>
 333   : DForm_5<opcode, OOL, IOL, asmstr, itin> {
 334   let L = PPC64;
 335 }
 336
 337 class DForm_6<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 338               InstrItinClass itin>
 339   : DForm_5<opcode, OOL, IOL, asmstr, itin>;
 340
 341 class DForm_6_ext<bits<6> opcode, dag OOL, dag IOL, string asmstr,
 342                   InstrItinClass itin>
 343   : DForm_6<opcode, OOL, IOL, asmstr, itin> {
 344   let L = PPC64;
 345 }
 346
 347
 348 // 1.7.5 DS-Form
 349 class DSForm_1<bits<6> opcode, bits<2> xo, dag OOL, dag IOL, string asmstr,
 350                InstrItinClass itin, list<dag> pattern>
 351          : I<opcode, OOL, IOL, asmstr, itin> {
 352   bits<5>  RST;
 353   bits<19> DS_RA;
 354
 355   let Pattern = pattern;
 356
 357   let Inst{6-10}  = RST;
 358   let Inst{11-15} = DS_RA{18-14};  // Register #
 359   let Inst{16-29} = DS_RA{13-0};   // Displacement.
 360   let Inst{30-31} = xo;
 361 }
 362
 363
 364 // 1.7.6 X-Form
 365 class XForm_base_r3xo<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 366                       InstrItinClass itin, list<dag> pattern>
 367   : I<opcode, OOL, IOL, asmstr, itin> {
 368   bits<5> RST;
 369   bits<5> A;
 370   bits<5> B;
 371
 372   let Pattern = pattern;
 373
 374   bit RC = 0;    // set by isDOT
 375
 376   let Inst{6-10}  = RST;
 377   let Inst{11-15} = A;
 378   let Inst{16-20} = B;
 379   let Inst{21-30} = xo;
 380   let Inst{31}    = RC;
 381 }
 382
 383 // This is the same as XForm_base_r3xo, but the first two operands are swapped
 384 // when code is emitted.
 385 class XForm_base_r3xo_swapped
 386         <bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 387         InstrItinClass itin>
 388   : I<opcode, OOL, IOL, asmstr, itin> {
 389   bits<5> A;
 390   bits<5> RST;
 391   bits<5> B;
 392
 393   bit RC = 0;    // set by isDOT
 394
 395   let Inst{6-10}  = RST;
 396   let Inst{11-15} = A;
 397   let Inst{16-20} = B;
 398   let Inst{21-30} = xo;
 399   let Inst{31}    = RC;
 400 }
 401
 402
 403 class XForm_1<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 404               InstrItinClass itin, list<dag> pattern>
 405   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern>;
 406
 407 class XForm_1a<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 408               InstrItinClass itin, list<dag> pattern>
 409   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 410   let RST = 0;
 411 }
 412
 413 class XForm_rs<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 414               InstrItinClass itin, list<dag> pattern>
 415   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 416   let A = 0;
 417   let B = 0;
 418 }
 419
 420 class XForm_6<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 421               InstrItinClass itin, list<dag> pattern>
 422   : XForm_base_r3xo_swapped<opcode, xo, OOL, IOL, asmstr, itin> {
 423   let Pattern = pattern;
 424 }
 425
 426 class XForm_8<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 427               InstrItinClass itin, list<dag> pattern>
 428   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern>;
 429
 430 class XForm_10<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 431                InstrItinClass itin, list<dag> pattern>
 432   : XForm_base_r3xo_swapped<opcode, xo, OOL, IOL, asmstr, itin> {
 433     let Pattern = pattern;
 434 }
 435
 436 class XForm_11<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 437                InstrItinClass itin, list<dag> pattern>
 438   : XForm_base_r3xo_swapped<opcode, xo, OOL, IOL, asmstr, itin> {
 439   let B = 0;
 440   let Pattern = pattern;
 441 }
 442
 443 class XForm_16<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 444                InstrItinClass itin>
 445          : I<opcode, OOL, IOL, asmstr, itin> {
 446   bits<3> BF;
 447   bits<1> L;
 448   bits<5> RA;
 449   bits<5> RB;
 450
 451   let Inst{6-8}   = BF;
 452   let Inst{9}     = 0;
 453   let Inst{10}    = L;
 454   let Inst{11-15} = RA;
 455   let Inst{16-20} = RB;
 456   let Inst{21-30} = xo;
 457   let Inst{31}    = 0;
 458 }
 459
 460 class XForm_sr<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 461                 InstrItinClass itin>
 462          : I<opcode, OOL, IOL, asmstr, itin> {
 463   bits<5> RS;
 464   bits<4> SR;
 465
 466   let Inst{6-10} = RS;
 467   let Inst{12-15} = SR;
 468   let Inst{21-30} = xo;
 469 }
 470
 471 class XForm_mbar<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 472                 InstrItinClass itin>
 473          : I<opcode, OOL, IOL, asmstr, itin> {
 474   bits<5> MO;
 475
 476   let Inst{6-10} = MO;
 477   let Inst{21-30} = xo;
 478 }
 479
 480 class XForm_srin<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 481                 InstrItinClass itin>
 482          : I<opcode, OOL, IOL, asmstr, itin> {
 483   bits<5> RS;
 484   bits<5> RB;
 485
 486   let Inst{6-10} = RS;
 487   let Inst{16-20} = RB;
 488   let Inst{21-30} = xo;
 489 }
 490
 491 class XForm_mtmsr<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 492                 InstrItinClass itin>
 493          : I<opcode, OOL, IOL, asmstr, itin> {
 494   bits<5> RS;
 495   bits<1> L;
 496
 497   let Inst{6-10} = RS;
 498   let Inst{15} = L;
 499   let Inst{21-30} = xo;
 500 }
 501
 502 class XForm_16_ext<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 503                    InstrItinClass itin>
 504   : XForm_16<opcode, xo, OOL, IOL, asmstr, itin> {
 505   let L = PPC64;
 506 }
 507
 508 class XForm_17<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 509                InstrItinClass itin>
 510          : I<opcode, OOL, IOL, asmstr, itin> {
 511   bits<3> BF;
 512   bits<5> FRA;
 513   bits<5> FRB;
 514
 515   let Inst{6-8}   = BF;
 516   let Inst{9-10}  = 0;
 517   let Inst{11-15} = FRA;
 518   let Inst{16-20} = FRB;
 519   let Inst{21-30} = xo;
 520   let Inst{31}    = 0;
 521 }
 522
 523 class XForm_24<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 524                InstrItinClass itin, list<dag> pattern>
 525   : I<opcode, OOL, IOL, asmstr, itin> {
 526   let Pattern = pattern;
 527   let Inst{6-10}  = 31;
 528   let Inst{11-15} = 0;
 529   let Inst{16-20} = 0;
 530   let Inst{21-30} = xo;
 531   let Inst{31}    = 0;
 532 }
 533
 534 class XForm_24_sync<bits<6> opcode, bits<10> xo, dag OOL, dag IOL,
 535                string asmstr, InstrItinClass itin, list<dag> pattern>
 536   : I<opcode, OOL, IOL, asmstr, itin> {
 537   bits<2> L;
 538
 539   let Pattern = pattern;
 540   let Inst{6-8}   = 0;
 541   let Inst{9-10}  = L;
 542   let Inst{11-15} = 0;
 543   let Inst{16-20} = 0;
 544   let Inst{21-30} = xo;
 545   let Inst{31}    = 0;
 546 }
 547
 548 class XForm_24_eieio<bits<6> opcode, bits<10> xo, dag OOL, dag IOL,
 549                string asmstr, InstrItinClass itin, list<dag> pattern>
 550   : XForm_24_sync<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 551   let L = 0;
 552 }
 553
 554 class XForm_25<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 555                InstrItinClass itin, list<dag> pattern>
 556   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 557 }
 558
 559 class XForm_26<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 560                InstrItinClass itin, list<dag> pattern>
 561   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 562   let A = 0;
 563 }
 564
 565 class XForm_28<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 566                InstrItinClass itin, list<dag> pattern>
 567   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 568 }
 569
 570 // This is used for MFFS, MTFSB0, MTFSB1.  42 is arbitrary; this series of
 571 // numbers presumably relates to some document, but I haven't found it.
 572 class XForm_42<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 573               InstrItinClass itin, list<dag> pattern>
 574   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 575   let Pattern = pattern;
 576
 577   bit RC = 0;    // set by isDOT
 578
 579   let Inst{6-10}  = RST;
 580   let Inst{11-20} = 0;
 581   let Inst{21-30} = xo;
 582   let Inst{31}    = RC;
 583 }
 584 class XForm_43<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 585               InstrItinClass itin, list<dag> pattern>
 586   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 587   let Pattern = pattern;
 588   bits<5> FM;
 589
 590   bit RC = 0;    // set by isDOT
 591
 592   let Inst{6-10}  = FM;
 593   let Inst{11-20} = 0;
 594   let Inst{21-30} = xo;
 595   let Inst{31}    = RC;
 596 }
 597
 598 class XForm_0<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 599               InstrItinClass itin, list<dag> pattern>
 600   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 601   let RST = 0;
 602   let A = 0;
 603   let B = 0;
 604 }
 605
 606 class XForm_16b<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 607               InstrItinClass itin, list<dag> pattern>
 608   : XForm_base_r3xo<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
 609   let RST = 0;
 610   let A = 0;
 611 }
 612
 613 // XX*-Form (VSX)
 614 class XX1Form<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 615               InstrItinClass itin, list<dag> pattern>
 616   : I<opcode, OOL, IOL, asmstr, itin> {
 617   bits<6> XT;
 618   bits<5> A;
 619   bits<5> B;
 620
 621   let Pattern = pattern;
 622
 623   let Inst{6-10}  = XT{4-0};
 624   let Inst{11-15} = A;
 625   let Inst{16-20} = B;
 626   let Inst{21-30} = xo;
 627   let Inst{31}    = XT{5};
 628 }
 629
 630 class XX2Form<bits<6> opcode, bits<9> xo, dag OOL, dag IOL, string asmstr,
 631               InstrItinClass itin, list<dag> pattern>
 632   : I<opcode, OOL, IOL, asmstr, itin> {
 633   bits<6> XT;
 634   bits<6> XB;
 635
 636   let Pattern = pattern;
 637
 638   let Inst{6-10}  = XT{4-0};
 639   let Inst{11-15} = 0;
 640   let Inst{16-20} = XB{4-0};
 641   let Inst{21-29} = xo;
 642   let Inst{30}    = XB{5};
 643   let Inst{31}    = XT{5};
 644 }
 645
 646 class XX2Form_1<bits<6> opcode, bits<9> xo, dag OOL, dag IOL, string asmstr,
 647                 InstrItinClass itin, list<dag> pattern>
 648   : I<opcode, OOL, IOL, asmstr, itin> {
 649   bits<3> CR;
 650   bits<6> XB;
 651
 652   let Pattern = pattern;
 653
 654   let Inst{6-8}   = CR;
 655   let Inst{9-15}  = 0;
 656   let Inst{16-20} = XB{4-0};
 657   let Inst{21-29} = xo;
 658   let Inst{30}    = XB{5};
 659   let Inst{31}    = 0;
 660 }
 661
 662 class XX2Form_2<bits<6> opcode, bits<9> xo, dag OOL, dag IOL, string asmstr,
 663                 InstrItinClass itin, list<dag> pattern>
 664   : I<opcode, OOL, IOL, asmstr, itin> {
 665   bits<6> XT;
 666   bits<6> XB;
 667   bits<2> D;
 668
 669   let Pattern = pattern;
 670
 671   let Inst{6-10}  = XT{4-0};
 672   let Inst{11-13} = 0;
 673   let Inst{14-15} = D;
 674   let Inst{16-20} = XB{4-0};
 675   let Inst{21-29} = xo;
 676   let Inst{30}    = XB{5};
 677   let Inst{31}    = XT{5};
 678 }
 679
 680 class XX3Form<bits<6> opcode, bits<8> xo, dag OOL, dag IOL, string asmstr,
 681               InstrItinClass itin, list<dag> pattern>
 682   : I<opcode, OOL, IOL, asmstr, itin> {
 683   bits<6> XT;
 684   bits<6> XA;
 685   bits<6> XB;
 686
 687   let Pattern = pattern;
 688
 689   let Inst{6-10}  = XT{4-0};
 690   let Inst{11-15} = XA{4-0};
 691   let Inst{16-20} = XB{4-0};
 692   let Inst{21-28} = xo;
 693   let Inst{29}    = XA{5};
 694   let Inst{30}    = XB{5};
 695   let Inst{31}    = XT{5};
 696 }
 697
 698 class XX3Form_1<bits<6> opcode, bits<8> xo, dag OOL, dag IOL, string asmstr,
 699                 InstrItinClass itin, list<dag> pattern>
 700   : I<opcode, OOL, IOL, asmstr, itin> {
 701   bits<3> CR;
 702   bits<6> XA;
 703   bits<6> XB;
 704
 705   let Pattern = pattern;
 706
 707   let Inst{6-8}   = CR;
 708   let Inst{9-10}  = 0;
 709   let Inst{11-15} = XA{4-0};
 710   let Inst{16-20} = XB{4-0};
 711   let Inst{21-28} = xo;
 712   let Inst{29}    = XA{5};
 713   let Inst{30}    = XB{5};
 714   let Inst{31}    = 0;
 715 }
 716
 717 class XX3Form_2<bits<6> opcode, bits<5> xo, dag OOL, dag IOL, string asmstr,
 718                 InstrItinClass itin, list<dag> pattern>
 719   : I<opcode, OOL, IOL, asmstr, itin> {
 720   bits<6> XT;
 721   bits<6> XA;
 722   bits<6> XB;
 723   bits<2> D;
 724
 725   let Pattern = pattern;
 726
 727   let Inst{6-10}  = XT{4-0};
 728   let Inst{11-15} = XA{4-0};
 729   let Inst{16-20} = XB{4-0};
 730   let Inst{21}    = 0;
 731   let Inst{22-23} = D;
 732   let Inst{24-28} = xo;
 733   let Inst{29}    = XA{5};
 734   let Inst{30}    = XB{5};
 735   let Inst{31}    = XT{5};
 736 }
 737
 738 class XX3Form_Rc<bits<6> opcode, bits<7> xo, dag OOL, dag IOL, string asmstr,
 739               InstrItinClass itin, list<dag> pattern>
 740   : I<opcode, OOL, IOL, asmstr, itin> {
 741   bits<6> XT;
 742   bits<6> XA;
 743   bits<6> XB;
 744
 745   let Pattern = pattern;
 746
 747   bit RC = 0;    // set by isDOT
 748
 749   let Inst{6-10}  = XT{4-0};
 750   let Inst{11-15} = XA{4-0};
 751   let Inst{16-20} = XB{4-0};
 752   let Inst{21}    = RC;
 753   let Inst{22-28} = xo;
 754   let Inst{29}    = XA{5};
 755   let Inst{30}    = XB{5};
 756   let Inst{31}    = XT{5};
 757 }
 758
 759 class XX4Form<bits<6> opcode, bits<2> xo, dag OOL, dag IOL, string asmstr,
 760               InstrItinClass itin, list<dag> pattern>
 761   : I<opcode, OOL, IOL, asmstr, itin> {
 762   bits<6> XT;
 763   bits<6> XA;
 764   bits<6> XB;
 765   bits<6> XC;
 766
 767   let Pattern = pattern;
 768
 769   let Inst{6-10}  = XT{4-0};
 770   let Inst{11-15} = XA{4-0};
 771   let Inst{16-20} = XB{4-0};
 772   let Inst{21-25} = XC{4-0};
 773   let Inst{26-27} = xo;
 774   let Inst{28}    = XC{5};
 775   let Inst{29}    = XA{5};
 776   let Inst{30}    = XB{5};
 777   let Inst{31}    = XT{5};
 778 }
 779
 780 // DCB_Form - Form X instruction, used for dcb* instructions.
 781 class DCB_Form<bits<10> xo, bits<5> immfield, dag OOL, dag IOL, string asmstr,
 782                       InstrItinClass itin, list<dag> pattern>
 783   : I<31, OOL, IOL, asmstr, itin> {
 784   bits<5> A;
 785   bits<5> B;
 786
 787   let Pattern = pattern;
 788
 789   let Inst{6-10}  = immfield;
 790   let Inst{11-15} = A;
 791   let Inst{16-20} = B;
 792   let Inst{21-30} = xo;
 793   let Inst{31}    = 0;
 794 }
 795
 796
 797 // DSS_Form - Form X instruction, used for altivec dss* instructions.
 798 class DSS_Form<bits<10> xo, dag OOL, dag IOL, string asmstr,
 799                       InstrItinClass itin, list<dag> pattern>
 800   : I<31, OOL, IOL, asmstr, itin> {
 801   bits<1> T;
 802   bits<2> STRM;
 803   bits<5> A;
 804   bits<5> B;
 805
 806   let Pattern = pattern;
 807
 808   let Inst{6}     = T;
 809   let Inst{7-8}   = 0;
 810   let Inst{9-10}  = STRM;
 811   let Inst{11-15} = A;
 812   let Inst{16-20} = B;
 813   let Inst{21-30} = xo;
 814   let Inst{31}    = 0;
 815 }
 816
 817 // 1.7.7 XL-Form
 818 class XLForm_1<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 819                InstrItinClass itin, list<dag> pattern>
 820     : I<opcode, OOL, IOL, asmstr, itin> {
 821   bits<5> CRD;
 822   bits<5> CRA;
 823   bits<5> CRB;
 824
 825   let Pattern = pattern;
 826
 827   let Inst{6-10}  = CRD;
 828   let Inst{11-15} = CRA;
 829   let Inst{16-20} = CRB;
 830   let Inst{21-30} = xo;
 831   let Inst{31}    = 0;
 832 }
 833
 834 class XLForm_1_ext<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 835                InstrItinClass itin, list<dag> pattern>
 836     : I<opcode, OOL, IOL, asmstr, itin> {
 837   bits<5> CRD;
 838
 839   let Pattern = pattern;
 840
 841   let Inst{6-10}  = CRD;
 842   let Inst{11-15} = CRD;
 843   let Inst{16-20} = CRD;
 844   let Inst{21-30} = xo;
 845   let Inst{31}    = 0;
 846 }
 847
 848 class XLForm_2<bits<6> opcode, bits<10> xo, bit lk, dag OOL, dag IOL, string asmstr,
 849                InstrItinClass itin, list<dag> pattern>
 850     : I<opcode, OOL, IOL, asmstr, itin> {
 851   bits<5> BO;
 852   bits<5> BI;
 853   bits<2> BH;
 854
 855   let Pattern = pattern;
 856
 857   let Inst{6-10}  = BO;
 858   let Inst{11-15} = BI;
 859   let Inst{16-18} = 0;
 860   let Inst{19-20} = BH;
 861   let Inst{21-30} = xo;
 862   let Inst{31}    = lk;
 863 }
 864
 865 class XLForm_2_br<bits<6> opcode, bits<10> xo, bit lk,
 866                   dag OOL, dag IOL, string asmstr, InstrItinClass itin, list<dag> pattern>
 867   : XLForm_2<opcode, xo, lk, OOL, IOL, asmstr, itin, pattern> {
 868   bits<7> BIBO;  // 2 bits of BI and 5 bits of BO.
 869   bits<3>  CR;
 870
 871   let BO = BIBO{4-0};
 872   let BI{0-1} = BIBO{5-6};
 873   let BI{2-4} = CR{0-2};
 874   let BH = 0;
 875 }
 876
 877 class XLForm_2_br2<bits<6> opcode, bits<10> xo, bits<5> bo, bit lk,
 878                    dag OOL, dag IOL, string asmstr, InstrItinClass itin, list<dag> pattern>
 879   : XLForm_2<opcode, xo, lk, OOL, IOL, asmstr, itin, pattern> {
 880   let BO = bo;
 881   let BH = 0;
 882 }
 883
 884 class XLForm_2_ext<bits<6> opcode, bits<10> xo, bits<5> bo,  bits<5> bi, bit lk,
 885                   dag OOL, dag IOL, string asmstr, InstrItinClass itin, list<dag> pattern>
 886   : XLForm_2<opcode, xo, lk, OOL, IOL, asmstr, itin, pattern> {
 887   let BO = bo;
 888   let BI = bi;
 889   let BH = 0;
 890 }
 891
 892 class XLForm_3<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 893                InstrItinClass itin>
 894          : I<opcode, OOL, IOL, asmstr, itin> {
 895   bits<3> BF;
 896   bits<3> BFA;
 897
 898   let Inst{6-8}   = BF;
 899   let Inst{9-10}  = 0;
 900   let Inst{11-13} = BFA;
 901   let Inst{14-15} = 0;
 902   let Inst{16-20} = 0;
 903   let Inst{21-30} = xo;
 904   let Inst{31}    = 0;
 905 }
 906
 907 // 1.7.8 XFX-Form
 908 class XFXForm_1<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 909                 InstrItinClass itin>
 910          : I<opcode, OOL, IOL, asmstr, itin> {
 911   bits<5>  RT;
 912   bits<10> SPR;
 913
 914   let Inst{6-10}  = RT;
 915   let Inst{11}    = SPR{4};
 916   let Inst{12}    = SPR{3};
 917   let Inst{13}    = SPR{2};
 918   let Inst{14}    = SPR{1};
 919   let Inst{15}    = SPR{0};
 920   let Inst{16}    = SPR{9};
 921   let Inst{17}    = SPR{8};
 922   let Inst{18}    = SPR{7};
 923   let Inst{19}    = SPR{6};
 924   let Inst{20}    = SPR{5};
 925   let Inst{21-30} = xo;
 926   let Inst{31}    = 0;
 927 }
 928
 929 class XFXForm_1_ext<bits<6> opcode, bits<10> xo, bits<10> spr,
 930                    dag OOL, dag IOL, string asmstr, InstrItinClass itin>
 931   : XFXForm_1<opcode, xo, OOL, IOL, asmstr, itin> {
 932   let SPR = spr;
 933 }
 934
 935 class XFXForm_3<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 936                 InstrItinClass itin>
 937          : I<opcode, OOL, IOL, asmstr, itin> {
 938   bits<5>  RT;
 939
 940   let Inst{6-10}  = RT;
 941   let Inst{11-20} = 0;
 942   let Inst{21-30} = xo;
 943   let Inst{31}    = 0;
 944 }
 945
 946 class XFXForm_5<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 947                 InstrItinClass itin>
 948   : I<opcode, OOL, IOL, asmstr, itin> {
 949   bits<8>  FXM;
 950   bits<5>  rS;
 951
 952   let Inst{6-10}  = rS;
 953   let Inst{11}    = 0;
 954   let Inst{12-19} = FXM;
 955   let Inst{20}    = 0;
 956   let Inst{21-30} = xo;
 957   let Inst{31}    = 0;
 958 }
 959
 960 class XFXForm_5a<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 961                  InstrItinClass itin>
 962   : I<opcode, OOL, IOL, asmstr, itin> {
 963   bits<5>  ST;
 964   bits<8>  FXM;
 965
 966   let Inst{6-10}  = ST;
 967   let Inst{11}    = 1;
 968   let Inst{12-19} = FXM;
 969   let Inst{20}    = 0;
 970   let Inst{21-30} = xo;
 971   let Inst{31}    = 0;
 972 }
 973
 974 class XFXForm_7<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 975                 InstrItinClass itin>
 976   : XFXForm_1<opcode, xo, OOL, IOL, asmstr, itin>;
 977
 978 class XFXForm_7_ext<bits<6> opcode, bits<10> xo, bits<10> spr,
 979                     dag OOL, dag IOL, string asmstr, InstrItinClass itin>
 980   : XFXForm_7<opcode, xo, OOL, IOL, asmstr, itin> {
 981   let SPR = spr;
 982 }
 983
 984 // XFL-Form - MTFSF
 985 // This is probably 1.7.9, but I don't have the reference that uses this
 986 // numbering scheme...
 987 class XFLForm<bits<6> opcode, bits<10> xo, dag OOL, dag IOL, string asmstr,
 988               InstrItinClass itin, list<dag>pattern>
 989   : I<opcode, OOL, IOL, asmstr, itin> {
 990   bits<8> FM;
 991   bits<5> rT;
 992
 993   bit RC = 0;    // set by isDOT
 994   let Pattern = pattern;
 995
 996   let Inst{6} = 0;
 997   let Inst{7-14}  = FM;
 998   let Inst{15} = 0;
 999   let Inst{16-20} = rT;
1000   let Inst{21-30} = xo;
1001   let Inst{31}    = RC;
1002 }
1003
1004 // 1.7.10 XS-Form - SRADI.
1005 class XSForm_1<bits<6> opcode, bits<9> xo, dag OOL, dag IOL, string asmstr,
1006                InstrItinClass itin, list<dag> pattern>
1007          : I<opcode, OOL, IOL, asmstr, itin> {
1008   bits<5> A;
1009   bits<5> RS;
1010   bits<6> SH;
1011
1012   bit RC = 0;    // set by isDOT
1013   let Pattern = pattern;
1014
1015   let Inst{6-10}  = RS;
1016   let Inst{11-15} = A;
1017   let Inst{16-20} = SH{4,3,2,1,0};
1018   let Inst{21-29} = xo;
1019   let Inst{30}    = SH{5};
1020   let Inst{31}    = RC;
1021 }
1022
1023 // 1.7.11 XO-Form
1024 class XOForm_1<bits<6> opcode, bits<9> xo, bit oe, dag OOL, dag IOL, string asmstr,
1025                InstrItinClass itin, list<dag> pattern>
1026          : I<opcode, OOL, IOL, asmstr, itin> {
1027   bits<5> RT;
1028   bits<5> RA;
1029   bits<5> RB;
1030
1031   let Pattern = pattern;
1032
1033   bit RC = 0;    // set by isDOT
1034
1035   let Inst{6-10}  = RT;
1036   let Inst{11-15} = RA;
1037   let Inst{16-20} = RB;
1038   let Inst{21}    = oe;
1039   let Inst{22-30} = xo;
1040   let Inst{31}    = RC;
1041 }
1042
1043 class XOForm_3<bits<6> opcode, bits<9> xo, bit oe,
1044                dag OOL, dag IOL, string asmstr, InstrItinClass itin, list<dag> pattern>
1045   : XOForm_1<opcode, xo, oe, OOL, IOL, asmstr, itin, pattern> {
1046   let RB = 0;
1047 }
1048
1049 // 1.7.12 A-Form
1050 class AForm_1<bits<6> opcode, bits<5> xo, dag OOL, dag IOL, string asmstr,
1051               InstrItinClass itin, list<dag> pattern>
1052          : I<opcode, OOL, IOL, asmstr, itin> {
1053   bits<5> FRT;
1054   bits<5> FRA;
1055   bits<5> FRC;
1056   bits<5> FRB;
1057
1058   let Pattern = pattern;
1059
1060   bit RC = 0;    // set by isDOT
1061
1062   let Inst{6-10}  = FRT;
1063   let Inst{11-15} = FRA;
1064   let Inst{16-20} = FRB;
1065   let Inst{21-25} = FRC;
1066   let Inst{26-30} = xo;
1067   let Inst{31}    = RC;
1068 }
1069
1070 class AForm_2<bits<6> opcode, bits<5> xo, dag OOL, dag IOL, string asmstr,
1071               InstrItinClass itin, list<dag> pattern>
1072   : AForm_1<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
1073   let FRC = 0;
1074 }
1075
1076 class AForm_3<bits<6> opcode, bits<5> xo, dag OOL, dag IOL, string asmstr,
1077               InstrItinClass itin, list<dag> pattern>
1078   : AForm_1<opcode, xo, OOL, IOL, asmstr, itin, pattern> {
1079   let FRB = 0;
1080 }
1081
1082 class AForm_4<bits<6> opcode, bits<5> xo, dag OOL, dag IOL, string asmstr,
1083               InstrItinClass itin, list<dag> pattern>
1084          : I<opcode, OOL, IOL, asmstr, itin> {
1085   bits<5> RT;
1086   bits<5> RA;
1087   bits<5> RB;
1088   bits<5> COND;
1089
1090   let Pattern = pattern;
1091
1092   let Inst{6-10}  = RT;
1093   let Inst{11-15} = RA;
1094   let Inst{16-20} = RB;
1095   let Inst{21-25} = COND;
1096   let Inst{26-30} = xo;
1097   let Inst{31}    = 0;
1098 }
1099
1100 // 1.7.13 M-Form
1101 class MForm_1<bits<6> opcode, dag OOL, dag IOL, string asmstr,
1102               InstrItinClass itin, list<dag> pattern>
1103     : I<opcode, OOL, IOL, asmstr, itin> {
1104   bits<5> RA;
1105   bits<5> RS;
1106   bits<5> RB;
1107   bits<5> MB;
1108   bits<5> ME;
1109
1110   let Pattern = pattern;
1111
1112   bit RC = 0;    // set by isDOT
1113
1114   let Inst{6-10}  = RS;
1115   let Inst{11-15} = RA;
1116   let Inst{16-20} = RB;
1117   let Inst{21-25} = MB;
1118   let Inst{26-30} = ME;
1119   let Inst{31}    = RC;
1120 }
1121
1122 class MForm_2<bits<6> opcode, dag OOL, dag IOL, string asmstr,
1123               InstrItinClass itin, list<dag> pattern>
1124   : MForm_1<opcode, OOL, IOL, asmstr, itin, pattern> {
1125 }
1126
1127 // 1.7.14 MD-Form
1128 class MDForm_1<bits<6> opcode, bits<3> xo, dag OOL, dag IOL, string asmstr,
1129                InstrItinClass itin, list<dag> pattern>
1130     : I<opcode, OOL, IOL, asmstr, itin> {
1131   bits<5> RA;
1132   bits<5> RS;
1133   bits<6> SH;
1134   bits<6> MBE;
1135
1136   let Pattern = pattern;
1137
1138   bit RC = 0;    // set by isDOT
1139
1140   let Inst{6-10}  = RS;
1141   let Inst{11-15} = RA;
1142   let Inst{16-20} = SH{4,3,2,1,0};
1143   let Inst{21-26} = MBE{4,3,2,1,0,5};
1144   let Inst{27-29} = xo;
1145   let Inst{30}    = SH{5};
1146   let Inst{31}    = RC;
1147 }
1148
1149 class MDSForm_1<bits<6> opcode, bits<4> xo, dag OOL, dag IOL, string asmstr,
1150                 InstrItinClass itin, list<dag> pattern>
1151     : I<opcode, OOL, IOL, asmstr, itin> {
1152   bits<5> RA;
1153   bits<5> RS;
1154   bits<5> RB;
1155   bits<6> MBE;
1156
1157   let Pattern = pattern;
1158
1159   bit RC = 0;    // set by isDOT
1160
1161   let Inst{6-10}  = RS;
1162   let Inst{11-15} = RA;
1163   let Inst{16-20} = RB;
1164   let Inst{21-26} = MBE{4,3,2,1,0,5};
1165   let Inst{27-30} = xo;
1166   let Inst{31}    = RC;
1167 }
1168
1169
1170 // E-1 VA-Form
1171
1172 // VAForm_1 - DACB ordering.
1173 class VAForm_1<bits<6> xo, dag OOL, dag IOL, string asmstr,
1174                InstrItinClass itin, list<dag> pattern>
1175     : I<4, OOL, IOL, asmstr, itin> {
1176   bits<5> VD;
1177   bits<5> VA;
1178   bits<5> VC;
1179   bits<5> VB;
1180
1181   let Pattern = pattern;
1182
1183   let Inst{6-10}  = VD;
1184   let Inst{11-15} = VA;
1185   let Inst{16-20} = VB;
1186   let Inst{21-25} = VC;
1187   let Inst{26-31} = xo;
1188 }
1189
1190 // VAForm_1a - DABC ordering.
1191 class VAForm_1a<bits<6> xo, dag OOL, dag IOL, string asmstr,
1192                 InstrItinClass itin, list<dag> pattern>
1193     : I<4, OOL, IOL, asmstr, itin> {
1194   bits<5> VD;
1195   bits<5> VA;
1196   bits<5> VB;
1197   bits<5> VC;
1198
1199   let Pattern = pattern;
1200
1201   let Inst{6-10}  = VD;
1202   let Inst{11-15} = VA;
1203   let Inst{16-20} = VB;
1204   let Inst{21-25} = VC;
1205   let Inst{26-31} = xo;
1206 }
1207
1208 class VAForm_2<bits<6> xo, dag OOL, dag IOL, string asmstr,
1209                InstrItinClass itin, list<dag> pattern>
1210     : I<4, OOL, IOL, asmstr, itin> {
1211   bits<5> VD;
1212   bits<5> VA;
1213   bits<5> VB;
1214   bits<4> SH;
1215
1216   let Pattern = pattern;
1217
1218   let Inst{6-10}  = VD;
1219   let Inst{11-15} = VA;
1220   let Inst{16-20} = VB;
1221   let Inst{21}    = 0;
1222   let Inst{22-25} = SH;
1223   let Inst{26-31} = xo;
1224 }
1225
1226 // E-2 VX-Form
1227 class VXForm_1<bits<11> xo, dag OOL, dag IOL, string asmstr,
1228                InstrItinClass itin, list<dag> pattern>
1229     : I<4, OOL, IOL, asmstr, itin> {
1230   bits<5> VD;
1231   bits<5> VA;
1232   bits<5> VB;
1233
1234   let Pattern = pattern;
1235
1236   let Inst{6-10}  = VD;
1237   let Inst{11-15} = VA;
1238   let Inst{16-20} = VB;
1239   let Inst{21-31} = xo;
1240 }
1241
1242 class VXForm_setzero<bits<11> xo, dag OOL, dag IOL, string asmstr,
1243                InstrItinClass itin, list<dag> pattern>
1244     : VXForm_1<xo, OOL, IOL, asmstr, itin, pattern> {
1245   let VA = VD;
1246   let VB = VD;
1247 }
1248
1249
1250 class VXForm_2<bits<11> xo, dag OOL, dag IOL, string asmstr,
1251                InstrItinClass itin, list<dag> pattern>
1252     : I<4, OOL, IOL, asmstr, itin> {
1253   bits<5> VD;
1254   bits<5> VB;
1255
1256   let Pattern = pattern;
1257
1258   let Inst{6-10}  = VD;
1259   let Inst{11-15} = 0;
1260   let Inst{16-20} = VB;
1261   let Inst{21-31} = xo;
1262 }
1263
1264 class VXForm_3<bits<11> xo, dag OOL, dag IOL, string asmstr,
1265                InstrItinClass itin, list<dag> pattern>
1266     : I<4, OOL, IOL, asmstr, itin> {
1267   bits<5> VD;
1268   bits<5> IMM;
1269
1270   let Pattern = pattern;
1271
1272   let Inst{6-10}  = VD;
1273   let Inst{11-15} = IMM;
1274   let Inst{16-20} = 0;
1275   let Inst{21-31} = xo;
1276 }
1277
1278 /// VXForm_4 - VX instructions with "VD,0,0" register fields, like mfvscr.
1279 class VXForm_4<bits<11> xo, dag OOL, dag IOL, string asmstr,
1280                InstrItinClass itin, list<dag> pattern>
1281     : I<4, OOL, IOL, asmstr, itin> {
1282   bits<5> VD;
1283
1284   let Pattern = pattern;
1285
1286   let Inst{6-10}  = VD;
1287   let Inst{11-15} = 0;
1288   let Inst{16-20} = 0;
1289   let Inst{21-31} = xo;
1290 }
1291
1292 /// VXForm_5 - VX instructions with "0,0,VB" register fields, like mtvscr.
1293 class VXForm_5<bits<11> xo, dag OOL, dag IOL, string asmstr,
1294                InstrItinClass itin, list<dag> pattern>
1295     : I<4, OOL, IOL, asmstr, itin> {
1296   bits<5> VB;
1297
1298   let Pattern = pattern;
1299
1300   let Inst{6-10}  = 0;
1301   let Inst{11-15} = 0;
1302   let Inst{16-20} = VB;
1303   let Inst{21-31} = xo;
1304 }
1305
1306 // E-4 VXR-Form
1307 class VXRForm_1<bits<10> xo, dag OOL, dag IOL, string asmstr,
1308                InstrItinClass itin, list<dag> pattern>
1309     : I<4, OOL, IOL, asmstr, itin> {
1310   bits<5> VD;
1311   bits<5> VA;
1312   bits<5> VB;
1313   bit RC = 0;
1314
1315   let Pattern = pattern;
1316
1317   let Inst{6-10}  = VD;
1318   let Inst{11-15} = VA;
1319   let Inst{16-20} = VB;
1320   let Inst{21}    = RC;
1321   let Inst{22-31} = xo;
1322 }
1323
1324 //===----------------------------------------------------------------------===//
1325 class Pseudo<dag OOL, dag IOL, string asmstr, list<dag> pattern>
1326     : I<0, OOL, IOL, asmstr, NoItinerary> {
1327   let isCodeGenOnly = 1;
1328   let PPC64 = 0;
1329   let Pattern = pattern;
1330   let Inst{31-0} = 0;
1331 }