lib/Target/PowerPC/PPCInstrFormats.td

   1 //===- PowerPCInstrFormats.td - PowerPC Instruction Formats --*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 //
  12 // PowerPC instruction formats
  13
  14 class I<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin>
  15         : Instruction {
  16   field bits<32> Inst;
  17
  18   bit PPC64 = 0;  // Default value, override with isPPC64
  19   bit VMX = 0;    // Default value, override with isVMX
  20
  21   let Name = "";
  22   let Namespace = "PPC";
  23   let Inst{0-5} = opcode;
  24   let OperandList = OL;
  25   let AsmString = asmstr;
  26   let Itinerary = itin;
  27
  28   /// These fields correspond to the fields in PPCInstrInfo.h.  Any changes to
  29   /// these must be reflected there!  See comments there for what these are.
  30   bits<1> PPC970_First = 0;
  31   bits<1> PPC970_Single = 0;
  32   bits<1> PPC970_Cracked = 0;
  33   bits<3> PPC970_Unit = 0;
  34 }
  35
  36 class PPC970_DGroup_First   { bits<1> PPC970_First = 1;  }
  37 class PPC970_DGroup_Single  { bits<1> PPC970_Single = 1; }
  38 class PPC970_DGroup_Cracked { bits<1> PPC970_Cracked = 1; }
  39 class PPC970_MicroCode;
  40
  41 class PPC970_Unit_Pseudo   { bits<3> PPC970_Unit = 0;   }
  42 class PPC970_Unit_FXU      { bits<3> PPC970_Unit = 1;   }
  43 class PPC970_Unit_LSU      { bits<3> PPC970_Unit = 2;   }
  44 class PPC970_Unit_FPU      { bits<3> PPC970_Unit = 3;   }
  45 class PPC970_Unit_CRU      { bits<3> PPC970_Unit = 4;   }
  46 class PPC970_Unit_VALU     { bits<3> PPC970_Unit = 5;   }
  47 class PPC970_Unit_VPERM    { bits<3> PPC970_Unit = 6;   }
  48 class PPC970_Unit_BRU      { bits<3> PPC970_Unit = 7;   }
  49
  50
  51 // 1.7.1 I-Form
  52 class IForm<bits<6> opcode, bit aa, bit lk, dag OL, string asmstr,
  53             InstrItinClass itin, list<dag> pattern>
  54          : I<opcode, OL, asmstr, itin> {
  55   let Pattern = pattern;
  56   bits<24> LI;
  57
  58   let Inst{6-29}  = LI;
  59   let Inst{30}    = aa;
  60   let Inst{31}    = lk;
  61 }
  62
  63 // 1.7.2 B-Form
  64 class BForm<bits<6> opcode, bit aa, bit lk, bits<5> bo, bits<2> bicode, dag OL,
  65             string asmstr, InstrItinClass itin>
  66   : I<opcode, OL, asmstr, itin> {
  67   bits<3>  CR;
  68   bits<14> BD;
  69
  70   let Inst{6-10}  = bo;
  71   let Inst{11-13} = CR;
  72   let Inst{14-15} = bicode;
  73   let Inst{16-29} = BD;
  74   let Inst{30}    = aa;
  75   let Inst{31}    = lk;
  76 }
  77
  78 // 1.7.4 D-Form
  79 class DForm_base<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
  80                  list<dag> pattern>
  81   : I<opcode, OL, asmstr, itin> {
  82   bits<5>  A;
  83   bits<5>  B;
  84   bits<16> C;
  85
  86   let Pattern = pattern;
  87
  88   let Inst{6-10}  = A;
  89   let Inst{11-15} = B;
  90   let Inst{16-31} = C;
  91 }
  92
  93 class DForm_1<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
  94               list<dag> pattern>
  95   : I<opcode, OL, asmstr, itin> {
  96   bits<5>  A;
  97   bits<16> C;
  98   bits<5>  B;
  99
 100   let Pattern = pattern;
 101
 102   let Inst{6-10}  = A;
 103   let Inst{11-15} = B;
 104   let Inst{16-31} = C;
 105 }
 106
 107 class DForm_2<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
 108               list<dag> pattern>
 109   : DForm_base<opcode, OL, asmstr, itin, pattern>;
 110
 111 class DForm_2_r0<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
 112                  list<dag> pattern>
 113   : I<opcode, OL, asmstr, itin> {
 114   bits<5>  A;
 115   bits<16> B;
 116
 117   let Pattern = pattern;
 118
 119   let Inst{6-10}  = A;
 120   let Inst{11-15} = 0;
 121   let Inst{16-31} = B;
 122 }
 123
 124 // Currently we make the use/def reg distinction in ISel, not tablegen
 125 class DForm_3<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
 126               list<dag> pattern>
 127   : DForm_1<opcode, OL, asmstr, itin, pattern>;
 128
 129 class DForm_4<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
 130               list<dag> pattern>
 131   : I<opcode, OL, asmstr, itin> {
 132   bits<5>  B;
 133   bits<5>  A;
 134   bits<16> C;
 135
 136   let Pattern = pattern;
 137
 138   let Inst{6-10}  = A;
 139   let Inst{11-15} = B;
 140   let Inst{16-31} = C;
 141 }
 142
 143 class DForm_4_zero<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
 144                    list<dag> pattern>
 145   : DForm_1<opcode, OL, asmstr, itin, pattern> {
 146   let A = 0;
 147   let B = 0;
 148   let C = 0;
 149 }
 150
 151 class DForm_5<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin>
 152   : I<opcode, OL, asmstr, itin> {
 153   bits<3>  BF;
 154   bits<1>  L;
 155   bits<5>  RA;
 156   bits<16> I;
 157
 158   let Inst{6-8}   = BF;
 159   let Inst{9}     = 0;
 160   let Inst{10}    = L;
 161   let Inst{11-15} = RA;
 162   let Inst{16-31} = I;
 163 }
 164
 165 class DForm_5_ext<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin>
 166   : DForm_5<opcode, OL, asmstr, itin> {
 167   let L = PPC64;
 168 }
 169
 170 class DForm_6<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin>
 171   : DForm_5<opcode, OL, asmstr, itin>;
 172
 173 class DForm_6_ext<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin>
 174   : DForm_6<opcode, OL, asmstr, itin> {
 175   let L = PPC64;
 176 }
 177
 178 class DForm_8<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
 179               list<dag> pattern>
 180   : DForm_1<opcode, OL, asmstr, itin, pattern> {
 181 }
 182
 183 class DForm_9<bits<6> opcode, dag OL, string asmstr, InstrItinClass itin,
 184               list<dag> pattern>
 185   : DForm_1<opcode, OL, asmstr, itin, pattern> {
 186 }
 187
 188 // 1.7.5 DS-Form
 189 class DSForm_1<bits<6> opcode, bits<2> xo, dag OL, string asmstr,
 190                InstrItinClass itin, list<dag> pattern>
 191          : I<opcode, OL, asmstr, itin> {
 192   bits<5>  RST;
 193   bits<14> DS;
 194   bits<5>  RA;
 195
 196   let Pattern = pattern;
 197
 198   let Inst{6-10}  = RST;
 199   let Inst{11-15} = RA;
 200   let Inst{16-29} = DS;
 201   let Inst{30-31} = xo;
 202 }
 203
 204 class DSForm_2<bits<6> opcode, bits<2> xo, dag OL, string asmstr,
 205                InstrItinClass itin, list<dag> pattern>
 206   : DSForm_1<opcode, xo, OL, asmstr, itin, pattern>;
 207
 208 // 1.7.6 X-Form
 209 class XForm_base_r3xo<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 210                       InstrItinClass itin, list<dag> pattern>
 211   : I<opcode, OL, asmstr, itin> {
 212   bits<5> RST;
 213   bits<5> A;
 214   bits<5> B;
 215
 216   let Pattern = pattern;
 217
 218   bit RC = 0;    // set by isDOT
 219
 220   let Inst{6-10}  = RST;
 221   let Inst{11-15} = A;
 222   let Inst{16-20} = B;
 223   let Inst{21-30} = xo;
 224   let Inst{31}    = RC;
 225 }
 226
 227 // This is the same as XForm_base_r3xo, but the first two operands are swapped
 228 // when code is emitted.
 229 class XForm_base_r3xo_swapped
 230         <bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 231         InstrItinClass itin>
 232   : I<opcode, OL, asmstr, itin> {
 233   bits<5> A;
 234   bits<5> RST;
 235   bits<5> B;
 236
 237   bit RC = 0;    // set by isDOT
 238
 239   let Inst{6-10}  = RST;
 240   let Inst{11-15} = A;
 241   let Inst{16-20} = B;
 242   let Inst{21-30} = xo;
 243   let Inst{31}    = RC;
 244 }
 245
 246
 247 class XForm_1<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 248               InstrItinClass itin, list<dag> pattern>
 249   : XForm_base_r3xo<opcode, xo, OL, asmstr, itin, pattern>;
 250
 251 class XForm_6<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 252               InstrItinClass itin, list<dag> pattern>
 253   : XForm_base_r3xo_swapped<opcode, xo, OL, asmstr, itin> {
 254   let Pattern = pattern;
 255 }
 256
 257 class XForm_8<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 258               InstrItinClass itin, list<dag> pattern>
 259   : XForm_base_r3xo<opcode, xo, OL, asmstr, itin, pattern>;
 260
 261 class XForm_10<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 262                InstrItinClass itin, list<dag> pattern>
 263   : XForm_base_r3xo_swapped<opcode, xo, OL, asmstr, itin> {
 264     let Pattern = pattern;
 265 }
 266
 267 class XForm_11<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 268                InstrItinClass itin, list<dag> pattern>
 269   : XForm_base_r3xo_swapped<opcode, xo, OL, asmstr, itin> {
 270   let B = 0;
 271   let Pattern = pattern;
 272 }
 273
 274 class XForm_16<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 275                InstrItinClass itin>
 276          : I<opcode, OL, asmstr, itin> {
 277   bits<3> BF;
 278   bits<1> L;
 279   bits<5> RA;
 280   bits<5> RB;
 281
 282   let Inst{6-8}   = BF;
 283   let Inst{9}     = 0;
 284   let Inst{10}    = L;
 285   let Inst{11-15} = RA;
 286   let Inst{16-20} = RB;
 287   let Inst{21-30} = xo;
 288   let Inst{31}    = 0;
 289 }
 290
 291 class XForm_16_ext<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 292                    InstrItinClass itin>
 293   : XForm_16<opcode, xo, OL, asmstr, itin> {
 294   let L = PPC64;
 295 }
 296
 297 class XForm_17<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 298                InstrItinClass itin>
 299          : I<opcode, OL, asmstr, itin> {
 300   bits<3> BF;
 301   bits<5> FRA;
 302   bits<5> FRB;
 303
 304   let Inst{6-8}   = BF;
 305   let Inst{9-10}  = 0;
 306   let Inst{11-15} = FRA;
 307   let Inst{16-20} = FRB;
 308   let Inst{21-30} = xo;
 309   let Inst{31}    = 0;
 310 }
 311
 312 class XForm_25<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 313                InstrItinClass itin, list<dag> pattern>
 314   : XForm_base_r3xo<opcode, xo, OL, asmstr, itin, pattern> {
 315 }
 316
 317 class XForm_26<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 318                InstrItinClass itin, list<dag> pattern>
 319   : XForm_base_r3xo<opcode, xo, OL, asmstr, itin, pattern> {
 320   let A = 0;
 321 }
 322
 323 class XForm_28<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 324                InstrItinClass itin, list<dag> pattern>
 325   : XForm_base_r3xo<opcode, xo, OL, asmstr, itin, pattern> {
 326 }
 327
 328 // DCB_Form - Form X instruction, used for dcb* instructions.
 329 class DCB_Form<bits<10> xo, bits<5> immfield, dag OL, string asmstr,
 330                       InstrItinClass itin, list<dag> pattern>
 331   : I<31, OL, asmstr, itin> {
 332   bits<5> A;
 333   bits<5> B;
 334
 335   let Pattern = pattern;
 336
 337   let Inst{6-10}  = immfield;
 338   let Inst{11-15} = A;
 339   let Inst{16-20} = B;
 340   let Inst{21-30} = xo;
 341   let Inst{31}    = 0;
 342 }
 343
 344
 345 // DSS_Form - Form X instruction, used for altivec dss* instructions.
 346 class DSS_Form<bits<10> xo, dag OL, string asmstr,
 347                       InstrItinClass itin, list<dag> pattern>
 348   : I<31, OL, asmstr, itin> {
 349   bits<1> T;
 350   bits<2> STRM;
 351   bits<5> A;
 352   bits<5> B;
 353
 354   let Pattern = pattern;
 355
 356   let Inst{6}     = T;
 357   let Inst{7-8}   = 0;
 358   let Inst{9-10}  = STRM;
 359   let Inst{11-15} = A;
 360   let Inst{16-20} = B;
 361   let Inst{21-30} = xo;
 362   let Inst{31}    = 0;
 363 }
 364
 365 // 1.7.7 XL-Form
 366 class XLForm_1<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 367                InstrItinClass itin>
 368     : I<opcode, OL, asmstr, itin> {
 369   bits<3> CRD;
 370   bits<2> CRDb;
 371   bits<3> CRA;
 372   bits<2> CRAb;
 373   bits<3> CRB;
 374   bits<2> CRBb;
 375
 376   let Inst{6-8}   = CRD;
 377   let Inst{9-10}  = CRDb;
 378   let Inst{11-13} = CRA;
 379   let Inst{14-15} = CRAb;
 380   let Inst{16-18} = CRB;
 381   let Inst{19-20} = CRBb;
 382   let Inst{21-30} = xo;
 383   let Inst{31}    = 0;
 384 }
 385
 386 class XLForm_2<bits<6> opcode, bits<10> xo, bit lk, dag OL, string asmstr,
 387                InstrItinClass itin, list<dag> pattern>
 388     : I<opcode, OL, asmstr, itin> {
 389   bits<5> BO;
 390   bits<5> BI;
 391   bits<2> BH;
 392
 393   let Pattern = pattern;
 394
 395   let Inst{6-10}  = BO;
 396   let Inst{11-15} = BI;
 397   let Inst{16-18} = 0;
 398   let Inst{19-20} = BH;
 399   let Inst{21-30} = xo;
 400   let Inst{31}    = lk;
 401 }
 402
 403 class XLForm_2_ext<bits<6> opcode, bits<10> xo, bits<5> bo,  bits<5> bi, bit lk,
 404                   dag OL, string asmstr, InstrItinClass itin, list<dag> pattern>
 405   : XLForm_2<opcode, xo, lk, OL, asmstr, itin, pattern> {
 406   let BO = bo;
 407   let BI = bi;
 408   let BH = 0;
 409 }
 410
 411 class XLForm_3<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 412                InstrItinClass itin>
 413          : I<opcode, OL, asmstr, itin> {
 414   bits<3> BF;
 415   bits<3> BFA;
 416
 417   let Inst{6-8}   = BF;
 418   let Inst{9-10}  = 0;
 419   let Inst{11-13} = BFA;
 420   let Inst{14-15} = 0;
 421   let Inst{16-20} = 0;
 422   let Inst{21-30} = xo;
 423   let Inst{31}    = 0;
 424 }
 425
 426 // 1.7.8 XFX-Form
 427 class XFXForm_1<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 428                 InstrItinClass itin>
 429          : I<opcode, OL, asmstr, itin> {
 430   bits<5>  RT;
 431   bits<10> SPR;
 432
 433   let Inst{6-10}  = RT;
 434   let Inst{11}    = SPR{4};
 435   let Inst{12}    = SPR{3};
 436   let Inst{13}    = SPR{2};
 437   let Inst{14}    = SPR{1};
 438   let Inst{15}    = SPR{0};
 439   let Inst{16}    = SPR{9};
 440   let Inst{17}    = SPR{8};
 441   let Inst{18}    = SPR{7};
 442   let Inst{19}    = SPR{6};
 443   let Inst{20}    = SPR{5};
 444   let Inst{21-30} = xo;
 445   let Inst{31}    = 0;
 446 }
 447
 448 class XFXForm_1_ext<bits<6> opcode, bits<10> xo, bits<10> spr,
 449                    dag OL, string asmstr, InstrItinClass itin>
 450   : XFXForm_1<opcode, xo, OL, asmstr, itin> {
 451   let SPR = spr;
 452 }
 453
 454 class XFXForm_3<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 455                 InstrItinClass itin>
 456          : I<opcode, OL, asmstr, itin> {
 457   bits<5>  RT;
 458
 459   let Inst{6-10}  = RT;
 460   let Inst{11-20} = 0;
 461   let Inst{21-30} = xo;
 462   let Inst{31}    = 0;
 463 }
 464
 465 class XFXForm_5<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 466                 InstrItinClass itin>
 467   : I<opcode, OL, asmstr, itin> {
 468   bits<8>  FXM;
 469   bits<5>  ST;
 470
 471   let Inst{6-10}  = ST;
 472   let Inst{11}    = 0;
 473   let Inst{12-19} = FXM;
 474   let Inst{20}    = 0;
 475   let Inst{21-30} = xo;
 476   let Inst{31}    = 0;
 477 }
 478
 479 class XFXForm_5a<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 480                  InstrItinClass itin>
 481   : I<opcode, OL, asmstr, itin> {
 482   bits<5>  ST;
 483   bits<8>  FXM;
 484
 485   let Inst{6-10}  = ST;
 486   let Inst{11}    = 1;
 487   let Inst{12-19} = FXM;
 488   let Inst{20}    = 0;
 489   let Inst{21-30} = xo;
 490   let Inst{31}    = 0;
 491 }
 492
 493 class XFXForm_7<bits<6> opcode, bits<10> xo, dag OL, string asmstr,
 494                 InstrItinClass itin>
 495   : XFXForm_1<opcode, xo, OL, asmstr, itin>;
 496
 497 class XFXForm_7_ext<bits<6> opcode, bits<10> xo, bits<10> spr,
 498                     dag OL, string asmstr, InstrItinClass itin>
 499   : XFXForm_7<opcode, xo, OL, asmstr, itin> {
 500   let SPR = spr;
 501 }
 502
 503 // 1.7.10 XS-Form
 504 class XSForm_1<bits<6> opcode, bits<9> xo, dag OL, string asmstr,
 505                InstrItinClass itin>
 506          : I<opcode, OL, asmstr, itin> {
 507   bits<5> RS;
 508   bits<5> A;
 509   bits<6> SH;
 510
 511   bit RC = 0;    // set by isDOT
 512
 513   let Inst{6-10}  = RS;
 514   let Inst{11-15} = A;
 515   let Inst{16-20} = SH{1-5};
 516   let Inst{21-29} = xo;
 517   let Inst{30}    = SH{0};
 518   let Inst{31}    = RC;
 519 }
 520
 521 // 1.7.11 XO-Form
 522 class XOForm_1<bits<6> opcode, bits<9> xo, bit oe, dag OL, string asmstr,
 523                InstrItinClass itin, list<dag> pattern>
 524          : I<opcode, OL, asmstr, itin> {
 525   bits<5> RT;
 526   bits<5> RA;
 527   bits<5> RB;
 528
 529   let Pattern = pattern;
 530
 531   bit RC = 0;    // set by isDOT
 532
 533   let Inst{6-10}  = RT;
 534   let Inst{11-15} = RA;
 535   let Inst{16-20} = RB;
 536   let Inst{21}    = oe;
 537   let Inst{22-30} = xo;
 538   let Inst{31}    = RC;
 539 }
 540
 541 class XOForm_3<bits<6> opcode, bits<9> xo, bit oe,
 542                dag OL, string asmstr, InstrItinClass itin, list<dag> pattern>
 543   : XOForm_1<opcode, xo, oe, OL, asmstr, itin, pattern> {
 544   let RB = 0;
 545 }
 546
 547 // 1.7.12 A-Form
 548 class AForm_1<bits<6> opcode, bits<5> xo, dag OL, string asmstr,
 549               InstrItinClass itin, list<dag> pattern>
 550          : I<opcode, OL, asmstr, itin> {
 551   bits<5> FRT;
 552   bits<5> FRA;
 553   bits<5> FRC;
 554   bits<5> FRB;
 555
 556   let Pattern = pattern;
 557
 558   bit RC = 0;    // set by isDOT
 559
 560   let Inst{6-10}  = FRT;
 561   let Inst{11-15} = FRA;
 562   let Inst{16-20} = FRB;
 563   let Inst{21-25} = FRC;
 564   let Inst{26-30} = xo;
 565   let Inst{31}    = RC;
 566 }
 567
 568 class AForm_2<bits<6> opcode, bits<5> xo, dag OL, string asmstr,
 569               InstrItinClass itin, list<dag> pattern>
 570   : AForm_1<opcode, xo, OL, asmstr, itin, pattern> {
 571   let FRC = 0;
 572 }
 573
 574 class AForm_3<bits<6> opcode, bits<5> xo, dag OL, string asmstr,
 575               InstrItinClass itin, list<dag> pattern>
 576   : AForm_1<opcode, xo, OL, asmstr, itin, pattern> {
 577   let FRB = 0;
 578 }
 579
 580 // 1.7.13 M-Form
 581 class MForm_1<bits<6> opcode, dag OL, string asmstr,
 582               InstrItinClass itin, list<dag> pattern>
 583     : I<opcode, OL, asmstr, itin> {
 584   bits<5> RA;
 585   bits<5> RS;
 586   bits<5> RB;
 587   bits<5> MB;
 588   bits<5> ME;
 589
 590   let Pattern = pattern;
 591
 592   bit RC = 0;    // set by isDOT
 593
 594   let Inst{6-10}  = RS;
 595   let Inst{11-15} = RA;
 596   let Inst{16-20} = RB;
 597   let Inst{21-25} = MB;
 598   let Inst{26-30} = ME;
 599   let Inst{31}    = RC;
 600 }
 601
 602 class MForm_2<bits<6> opcode, dag OL, string asmstr,
 603               InstrItinClass itin, list<dag> pattern>
 604   : MForm_1<opcode, OL, asmstr, itin, pattern> {
 605 }
 606
 607 // 1.7.14 MD-Form
 608 class MDForm_1<bits<6> opcode, bits<3> xo, dag OL, string asmstr,
 609                InstrItinClass itin, list<dag> pattern>
 610     : I<opcode, OL, asmstr, itin> {
 611   bits<5> RS;
 612   bits<5> RA;
 613   bits<6> SH;
 614   bits<6> MBE;
 615
 616   let Pattern = pattern;
 617
 618   bit RC = 0;    // set by isDOT
 619
 620   let Inst{6-10}  = RS;
 621   let Inst{11-15} = RA;
 622   let Inst{16-20} = SH{1-5};
 623   let Inst{21-26} = MBE;
 624   let Inst{27-29} = xo;
 625   let Inst{30}    = SH{0};
 626   let Inst{31}    = RC;
 627 }
 628
 629
 630
 631 // E-1 VA-Form
 632
 633 // VAForm_1 - DACB ordering.
 634 class VAForm_1<bits<6> xo, dag OL, string asmstr,
 635                InstrItinClass itin, list<dag> pattern>
 636     : I<4, OL, asmstr, itin> {
 637   bits<5> VD;
 638   bits<5> VA;
 639   bits<5> VC;
 640   bits<5> VB;
 641
 642   let Pattern = pattern;
 643
 644   let Inst{6-10}  = VD;
 645   let Inst{11-15} = VA;
 646   let Inst{16-20} = VB;
 647   let Inst{21-25} = VC;
 648   let Inst{26-31} = xo;
 649 }
 650
 651 // VAForm_1a - DABC ordering.
 652 class VAForm_1a<bits<6> xo, dag OL, string asmstr,
 653                 InstrItinClass itin, list<dag> pattern>
 654     : I<4, OL, asmstr, itin> {
 655   bits<5> VD;
 656   bits<5> VA;
 657   bits<5> VB;
 658   bits<5> VC;
 659
 660   let Pattern = pattern;
 661
 662   let Inst{6-10}  = VD;
 663   let Inst{11-15} = VA;
 664   let Inst{16-20} = VB;
 665   let Inst{21-25} = VC;
 666   let Inst{26-31} = xo;
 667 }
 668
 669 class VAForm_2<bits<6> xo, dag OL, string asmstr,
 670                InstrItinClass itin, list<dag> pattern>
 671     : I<4, OL, asmstr, itin> {
 672   bits<5> VD;
 673   bits<5> VA;
 674   bits<5> VB;
 675   bits<4> SH;
 676
 677   let Pattern = pattern;
 678
 679   let Inst{6-10}  = VD;
 680   let Inst{11-15} = VA;
 681   let Inst{16-20} = VB;
 682   let Inst{21}    = 0;
 683   let Inst{22-25} = SH;
 684   let Inst{26-31} = xo;
 685 }
 686
 687 // E-2 VX-Form
 688 class VXForm_1<bits<11> xo, dag OL, string asmstr,
 689                InstrItinClass itin, list<dag> pattern>
 690     : I<4, OL, asmstr, itin> {
 691   bits<5> VD;
 692   bits<5> VA;
 693   bits<5> VB;
 694
 695   let Pattern = pattern;
 696
 697   let Inst{6-10}  = VD;
 698   let Inst{11-15} = VA;
 699   let Inst{16-20} = VB;
 700   let Inst{21-31} = xo;
 701 }
 702
 703 class VXForm_setzero<bits<11> xo, dag OL, string asmstr,
 704                InstrItinClass itin, list<dag> pattern>
 705     : VXForm_1<xo, OL, asmstr, itin, pattern> {
 706   let VA = VD;
 707   let VB = VD;
 708 }
 709
 710
 711 class VXForm_2<bits<11> xo, dag OL, string asmstr,
 712                InstrItinClass itin, list<dag> pattern>
 713     : I<4, OL, asmstr, itin> {
 714   bits<5> VD;
 715   bits<5> VB;
 716
 717   let Pattern = pattern;
 718
 719   let Inst{6-10}  = VD;
 720   let Inst{11-15} = 0;
 721   let Inst{16-20} = VB;
 722   let Inst{21-31} = xo;
 723 }
 724
 725 class VXForm_3<bits<11> xo, dag OL, string asmstr,
 726                InstrItinClass itin, list<dag> pattern>
 727     : I<4, OL, asmstr, itin> {
 728   bits<5> VD;
 729   bits<5> IMM;
 730
 731   let Pattern = pattern;
 732
 733   let Inst{6-10}  = VD;
 734   let Inst{11-15} = IMM;
 735   let Inst{16-20} = 0;
 736   let Inst{21-31} = xo;
 737 }
 738
 739 /// VXForm_4 - VX instructions with "VD,0,0" register fields, like mfvscr.
 740 class VXForm_4<bits<11> xo, dag OL, string asmstr,
 741                InstrItinClass itin, list<dag> pattern>
 742     : I<4, OL, asmstr, itin> {
 743   bits<5> VD;
 744
 745   let Pattern = pattern;
 746
 747   let Inst{6-10}  = VD;
 748   let Inst{11-15} = 0;
 749   let Inst{16-20} = 0;
 750   let Inst{21-31} = xo;
 751 }
 752
 753 /// VXForm_5 - VX instructions with "0,0,VB" register fields, like mtvscr.
 754 class VXForm_5<bits<11> xo, dag OL, string asmstr,
 755                InstrItinClass itin, list<dag> pattern>
 756     : I<4, OL, asmstr, itin> {
 757   bits<5> VB;
 758
 759   let Pattern = pattern;
 760
 761   let Inst{6-10}  = 0;
 762   let Inst{11-15} = 0;
 763   let Inst{16-20} = VB;
 764   let Inst{21-31} = xo;
 765 }
 766
 767 // E-4 VXR-Form
 768 class VXRForm_1<bits<10> xo, dag OL, string asmstr,
 769                InstrItinClass itin, list<dag> pattern>
 770     : I<4, OL, asmstr, itin> {
 771   bits<5> VD;
 772   bits<5> VA;
 773   bits<5> VB;
 774   bit RC = 0;
 775
 776   let Pattern = pattern;
 777
 778   let Inst{6-10}  = VD;
 779   let Inst{11-15} = VA;
 780   let Inst{16-20} = VB;
 781   let Inst{21}    = RC;
 782   let Inst{22-31} = xo;
 783 }
 784
 785 //===----------------------------------------------------------------------===//
 786 class Pseudo<dag OL, string asmstr, list<dag> pattern>
 787     : I<0, OL, asmstr, NoItinerary> {
 788   let PPC64 = 0;
 789   let VMX = 0;
 790   let Pattern = pattern;
 791   let Inst{31-0} = 0;
 792 }