lib/Target/PowerPC/PPCInstrAltivec.td

   1 //===- PPCInstrAltivec.td - The PowerPC Altivec Extension --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Altivec extension to the PowerPC instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Altivec transformation functions and pattern fragments.
  16 //
  17
  18 /// VPKUHUM_shuffle_mask/VPKUWUM_shuffle_mask - Return true if this is a valid
  19 /// shuffle mask for the VPKUHUM or VPKUWUM instructions.
  20 def VPKUHUM_shuffle_mask : PatLeaf<(build_vector), [{
  21   return PPC::isVPKUHUMShuffleMask(N);
  22 }]>;
  23 def VPKUWUM_shuffle_mask : PatLeaf<(build_vector), [{
  24   return PPC::isVPKUWUMShuffleMask(N);
  25 }]>;
  26
  27 def VMRGLB_shuffle_mask : PatLeaf<(build_vector), [{
  28   return PPC::isVMRGLShuffleMask(N, 1);
  29 }]>;
  30 def VMRGLH_shuffle_mask : PatLeaf<(build_vector), [{
  31   return PPC::isVMRGLShuffleMask(N, 2);
  32 }]>;
  33 def VMRGLW_shuffle_mask : PatLeaf<(build_vector), [{
  34   return PPC::isVMRGLShuffleMask(N, 4);
  35 }]>;
  36 def VMRGHB_shuffle_mask : PatLeaf<(build_vector), [{
  37   return PPC::isVMRGHShuffleMask(N, 1);
  38 }]>;
  39 def VMRGHH_shuffle_mask : PatLeaf<(build_vector), [{
  40   return PPC::isVMRGHShuffleMask(N, 2);
  41 }]>;
  42 def VMRGHW_shuffle_mask : PatLeaf<(build_vector), [{
  43   return PPC::isVMRGHShuffleMask(N, 4);
  44 }]>;
  45
  46
  47 def VSLDOI_get_imm : SDNodeXForm<build_vector, [{
  48   return getI32Imm(PPC::isVSLDOIShuffleMask(N));
  49 }]>;
  50 def VSLDOI_shuffle_mask :  PatLeaf<(build_vector), [{
  51   return PPC::isVSLDOIShuffleMask(N) != -1;
  52 }], VSLDOI_get_imm>;
  53
  54 /// VSLDOI_rotate* - These are used to match vsldoi(X,X), which is turned into
  55 /// vector_shuffle(X,undef,mask) by the dag combiner.
  56 def VSLDOI_rotate_get_imm : SDNodeXForm<build_vector, [{
  57   return getI32Imm(PPC::isVSLDOIRotateShuffleMask(N));
  58 }]>;
  59 def VSLDOI_rotate_shuffle_mask :  PatLeaf<(build_vector), [{
  60   return PPC::isVSLDOIRotateShuffleMask(N) != -1;
  61 }], VSLDOI_rotate_get_imm>;
  62
  63
  64 // VSPLT*_get_imm xform function: convert vector_shuffle mask to VSPLT* imm.
  65 def VSPLTB_get_imm : SDNodeXForm<build_vector, [{
  66   return getI32Imm(PPC::getVSPLTImmediate(N, 1));
  67 }]>;
  68 def VSPLTB_shuffle_mask : PatLeaf<(build_vector), [{
  69   return PPC::isSplatShuffleMask(N, 1);
  70 }], VSPLTB_get_imm>;
  71 def VSPLTH_get_imm : SDNodeXForm<build_vector, [{
  72   return getI32Imm(PPC::getVSPLTImmediate(N, 2));
  73 }]>;
  74 def VSPLTH_shuffle_mask : PatLeaf<(build_vector), [{
  75   return PPC::isSplatShuffleMask(N, 2);
  76 }], VSPLTH_get_imm>;
  77 def VSPLTW_get_imm : SDNodeXForm<build_vector, [{
  78   return getI32Imm(PPC::getVSPLTImmediate(N, 4));
  79 }]>;
  80 def VSPLTW_shuffle_mask : PatLeaf<(build_vector), [{
  81   return PPC::isSplatShuffleMask(N, 4);
  82 }], VSPLTW_get_imm>;
  83
  84
  85 // VSPLTISB_get_imm xform function: convert build_vector to VSPLTISB imm.
  86 def VSPLTISB_get_imm : SDNodeXForm<build_vector, [{
  87   char Val;
  88   PPC::isVecSplatImm(N, 1, &Val);
  89   return getI32Imm(Val);
  90 }]>;
  91 def vecspltisb : PatLeaf<(build_vector), [{
  92   return PPC::isVecSplatImm(N, 1);
  93 }], VSPLTISB_get_imm>;
  94
  95 // VSPLTISH_get_imm xform function: convert build_vector to VSPLTISH imm.
  96 def VSPLTISH_get_imm : SDNodeXForm<build_vector, [{
  97   char Val;
  98   PPC::isVecSplatImm(N, 2, &Val);
  99   return getI32Imm(Val);
 100 }]>;
 101 def vecspltish : PatLeaf<(build_vector), [{
 102   return PPC::isVecSplatImm(N, 2);
 103 }], VSPLTISH_get_imm>;
 104
 105 // VSPLTISW_get_imm xform function: convert build_vector to VSPLTISW imm.
 106 def VSPLTISW_get_imm : SDNodeXForm<build_vector, [{
 107   char Val;
 108   PPC::isVecSplatImm(N, 4, &Val);
 109   return getI32Imm(Val);
 110 }]>;
 111 def vecspltisw : PatLeaf<(build_vector), [{
 112   return PPC::isVecSplatImm(N, 4);
 113 }], VSPLTISW_get_imm>;
 114
 115 //===----------------------------------------------------------------------===//
 116 // Helpers for defining instructions that directly correspond to intrinsics.
 117
 118 // VA1a_Int - A VAForm_1a intrinsic definition.
 119 class VA1a_Int<bits<6> xo, string opc, Intrinsic IntID>
 120   : VAForm_1a<xo, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB, VRRC:$vC),
 121               !strconcat(opc, " $vD, $vA, $vB, $vC"), VecFP,
 122                        [(set VRRC:$vD, (IntID VRRC:$vA, VRRC:$vB, VRRC:$vC))]>;
 123
 124 // VX1_Int - A VXForm_1 intrinsic definition.
 125 class VX1_Int<bits<11> xo, string opc, Intrinsic IntID>
 126   : VXForm_1<xo, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 127              !strconcat(opc, " $vD, $vA, $vB"), VecFP,
 128              [(set VRRC:$vD, (IntID VRRC:$vA, VRRC:$vB))]>;
 129
 130 // VX2_Int - A VXForm_2 intrinsic definition.
 131 class VX2_Int<bits<11> xo, string opc, Intrinsic IntID>
 132   : VXForm_2<xo, (ops VRRC:$vD, VRRC:$vB),
 133              !strconcat(opc, " $vD, $vB"), VecFP,
 134              [(set VRRC:$vD, (IntID VRRC:$vB))]>;
 135
 136 //===----------------------------------------------------------------------===//
 137 // Instruction Definitions.
 138
 139 def IMPLICIT_DEF_VRRC : Pseudo<(ops VRRC:$rD), "; $rD = IMPLICIT_DEF_VRRC",
 140                                [(set VRRC:$rD, (v4f32 (undef)))]>;
 141
 142 let noResults = 1 in {
 143 def DSS   : DSS_Form<822, (ops u5imm:$A, u5imm:$STRM,u5imm:$ZERO1,u5imm:$ZERO2),
 144                      "dss $STRM, $A", LdStGeneral /*FIXME*/, []>;
 145 def DST   : DSS_Form<342, (ops u5imm:$T, u5imm:$STRM, GPRC:$rA, GPRC:$rB),
 146                      "dst $rA, $rB, $STRM, $T", LdStGeneral /*FIXME*/, []>;
 147 def DSTST : DSS_Form<374, (ops u5imm:$T, u5imm:$STRM, GPRC:$rA, GPRC:$rB),
 148                    "dstst $rA, $rB, $STRM, $T", LdStGeneral /*FIXME*/, []>;
 149 }
 150
 151 def MFVSCR : VXForm_4<1540, (ops VRRC:$vD),
 152                       "mfvcr $vD", LdStGeneral,
 153                       [(set VRRC:$vD, (int_ppc_altivec_mfvscr))]>;
 154 def MTVSCR : VXForm_5<1604, (ops VRRC:$vB),
 155                       "mtvcr $vB", LdStGeneral,
 156                       [(int_ppc_altivec_mtvscr VRRC:$vB)]>;
 157
 158 let isLoad = 1, PPC970_Unit = 2 in {  // Loads.
 159 def LVEBX: XForm_1<31,   7, (ops VRRC:$vD, memrr:$src),
 160                    "lvebx $vD, $src", LdStGeneral,
 161                    [(set VRRC:$vD, (int_ppc_altivec_lvebx xoaddr:$src))]>;
 162 def LVEHX: XForm_1<31,  39, (ops VRRC:$vD, memrr:$src),
 163                    "lvehx $vD, $src", LdStGeneral,
 164                    [(set VRRC:$vD, (int_ppc_altivec_lvehx xoaddr:$src))]>;
 165 def LVEWX: XForm_1<31,  71, (ops VRRC:$vD, memrr:$src),
 166                    "lvewx $vD, $src", LdStGeneral,
 167                    [(set VRRC:$vD, (int_ppc_altivec_lvewx xoaddr:$src))]>;
 168 def LVX  : XForm_1<31, 103, (ops VRRC:$vD, memrr:$src),
 169                    "lvx $vD, $src", LdStGeneral,
 170                    [(set VRRC:$vD, (int_ppc_altivec_lvx xoaddr:$src))]>;
 171 def LVXL : XForm_1<31, 359, (ops VRRC:$vD, memrr:$src),
 172                    "lvxl $vD, $src", LdStGeneral,
 173                    [(set VRRC:$vD, (int_ppc_altivec_lvxl xoaddr:$src))]>;
 174 }
 175
 176 def LVSL : XForm_1<31,   6, (ops VRRC:$vD, memrr:$src),
 177                    "lvsl $vD, $src", LdStGeneral,
 178                    [(set VRRC:$vD, (int_ppc_altivec_lvsl xoaddr:$src))]>,
 179                    PPC970_Unit_LSU;
 180 def LVSR : XForm_1<31,  38, (ops VRRC:$vD, memrr:$src),
 181                    "lvsr $vD, $src", LdStGeneral,
 182                    [(set VRRC:$vD, (int_ppc_altivec_lvsr xoaddr:$src))]>,
 183                    PPC970_Unit_LSU;
 184
 185 let isStore = 1, noResults = 1, PPC970_Unit = 2 in {   // Stores.
 186 def STVEBX: XForm_8<31, 135, (ops VRRC:$rS, memrr:$dst),
 187                    "stvebx $rS, $dst", LdStGeneral,
 188                    [(int_ppc_altivec_stvebx VRRC:$rS, xoaddr:$dst)]>;
 189 def STVEHX: XForm_8<31, 167, (ops VRRC:$rS, memrr:$dst),
 190                    "stvehx $rS, $dst", LdStGeneral,
 191                    [(int_ppc_altivec_stvehx VRRC:$rS, xoaddr:$dst)]>;
 192 def STVEWX: XForm_8<31, 199, (ops VRRC:$rS, memrr:$dst),
 193                    "stvewx $rS, $dst", LdStGeneral,
 194                    [(int_ppc_altivec_stvewx VRRC:$rS, xoaddr:$dst)]>;
 195 def STVX  : XForm_8<31, 231, (ops VRRC:$rS, memrr:$dst),
 196                    "stvx $rS, $dst", LdStGeneral,
 197                    [(int_ppc_altivec_stvx VRRC:$rS, xoaddr:$dst)]>;
 198 def STVXL : XForm_8<31, 487, (ops VRRC:$rS, memrr:$dst),
 199                    "stvxl $rS, $dst", LdStGeneral,
 200                    [(int_ppc_altivec_stvxl VRRC:$rS, xoaddr:$dst)]>;
 201 }
 202
 203 let PPC970_Unit = 5 in {  // VALU Operations.
 204 // VA-Form instructions.  3-input AltiVec ops.
 205 def VMADDFP : VAForm_1<46, (ops VRRC:$vD, VRRC:$vA, VRRC:$vC, VRRC:$vB),
 206                        "vmaddfp $vD, $vA, $vC, $vB", VecFP,
 207                        [(set VRRC:$vD, (fadd (fmul VRRC:$vA, VRRC:$vC),
 208                                              VRRC:$vB))]>,
 209                        Requires<[FPContractions]>;
 210 def VNMSUBFP: VAForm_1<47, (ops VRRC:$vD, VRRC:$vA, VRRC:$vC, VRRC:$vB),
 211                        "vnmsubfp $vD, $vA, $vC, $vB", VecFP,
 212                        [(set VRRC:$vD, (fneg (fsub (fmul VRRC:$vA, VRRC:$vC),
 213                                                    VRRC:$vB)))]>,
 214                        Requires<[FPContractions]>;
 215
 216 def VMHADDSHS  : VA1a_Int<32, "vmhaddshs",  int_ppc_altivec_vmhaddshs>;
 217 def VMHRADDSHS : VA1a_Int<33, "vmhraddshs", int_ppc_altivec_vmhraddshs>;
 218 def VMLADDUHM  : VA1a_Int<34, "vmladduhm",  int_ppc_altivec_vmladduhm>;
 219 def VPERM      : VA1a_Int<43, "vperm",      int_ppc_altivec_vperm>;
 220 def VSEL       : VA1a_Int<42, "vsel",       int_ppc_altivec_vsel>;
 221
 222 // Shuffles.
 223 def VSLDOI  : VAForm_2<44, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB, u5imm:$SH),
 224                        "vsldoi $vD, $vA, $vB, $SH", VecFP,
 225                        [(set VRRC:$vD,
 226                              (vector_shuffle (v16i8 VRRC:$vA), VRRC:$vB,
 227                                              VSLDOI_shuffle_mask:$SH))]>;
 228
 229 // VX-Form instructions.  AltiVec arithmetic ops.
 230 def VADDFP : VXForm_1<10, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 231                       "vaddfp $vD, $vA, $vB", VecFP,
 232                       [(set VRRC:$vD, (fadd VRRC:$vA, VRRC:$vB))]>;
 233
 234 def VADDUBM : VXForm_1<0, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 235                       "vaddubm $vD, $vA, $vB", VecGeneral,
 236                       [(set VRRC:$vD, (add (v16i8 VRRC:$vA), VRRC:$vB))]>;
 237 def VADDUHM : VXForm_1<64, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 238                       "vadduhm $vD, $vA, $vB", VecGeneral,
 239                       [(set VRRC:$vD, (add (v8i16 VRRC:$vA), VRRC:$vB))]>;
 240 def VADDUWM : VXForm_1<128, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 241                       "vadduwm $vD, $vA, $vB", VecGeneral,
 242                       [(set VRRC:$vD, (add (v4i32 VRRC:$vA), VRRC:$vB))]>;
 243
 244 def VADDCUW : VX1_Int<384, "vaddcuw", int_ppc_altivec_vaddcuw>;
 245 def VADDSBS : VX1_Int<768, "vaddsbs", int_ppc_altivec_vaddsbs>;
 246 def VADDSHS : VX1_Int<832, "vaddshs", int_ppc_altivec_vaddshs>;
 247 def VADDSWS : VX1_Int<896, "vaddsws", int_ppc_altivec_vaddsws>;
 248 def VADDUBS : VX1_Int<512, "vaddubs", int_ppc_altivec_vaddubs>;
 249 def VADDUHS : VX1_Int<576, "vadduhs", int_ppc_altivec_vadduhs>;
 250 def VADDUWS : VX1_Int<640, "vadduws", int_ppc_altivec_vadduws>;
 251
 252
 253 def VAND : VXForm_1<1028, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 254                     "vand $vD, $vA, $vB", VecFP,
 255                     [(set VRRC:$vD, (and (v4i32 VRRC:$vA), VRRC:$vB))]>;
 256 def VANDC : VXForm_1<1092, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 257                      "vandc $vD, $vA, $vB", VecFP,
 258                      [(set VRRC:$vD, (and (v4i32 VRRC:$vA), (vnot VRRC:$vB)))]>;
 259
 260 def VCFSX  : VXForm_1<842, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 261                       "vcfsx $vD, $vB, $UIMM", VecFP,
 262                       [(set VRRC:$vD,
 263                              (int_ppc_altivec_vcfsx VRRC:$vB, imm:$UIMM))]>;
 264 def VCFUX  : VXForm_1<778, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 265                       "vcfux $vD, $vB, $UIMM", VecFP,
 266                       [(set VRRC:$vD,
 267                              (int_ppc_altivec_vcfux VRRC:$vB, imm:$UIMM))]>;
 268 def VCTSXS : VXForm_1<970, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 269                       "vctsxs $vD, $vB, $UIMM", VecFP,
 270                       [(set VRRC:$vD,
 271                              (int_ppc_altivec_vctsxs VRRC:$vB, imm:$UIMM))]>;
 272 def VCTUXS : VXForm_1<906, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 273                       "vctuxs $vD, $vB, $UIMM", VecFP,
 274                       [(set VRRC:$vD,
 275                              (int_ppc_altivec_vctuxs VRRC:$vB, imm:$UIMM))]>;
 276 def VEXPTEFP : VX2_Int<394, "vexptefp", int_ppc_altivec_vexptefp>;
 277 def VLOGEFP  : VX2_Int<458, "vlogefp",  int_ppc_altivec_vlogefp>;
 278
 279 def VAVGSB : VX1_Int<1282, "vavgsb", int_ppc_altivec_vavgsb>;
 280 def VAVGSH : VX1_Int<1346, "vavgsh", int_ppc_altivec_vavgsh>;
 281 def VAVGSW : VX1_Int<1410, "vavgsw", int_ppc_altivec_vavgsw>;
 282 def VAVGUB : VX1_Int<1026, "vavgub", int_ppc_altivec_vavgub>;
 283 def VAVGUH : VX1_Int<1090, "vavguh", int_ppc_altivec_vavguh>;
 284 def VAVGUW : VX1_Int<1154, "vavguw", int_ppc_altivec_vavguw>;
 285
 286 def VMAXFP : VX1_Int<1034, "vmaxfp", int_ppc_altivec_vmaxfp>;
 287 def VMAXSB : VX1_Int< 258, "vmaxsb", int_ppc_altivec_vmaxsb>;
 288 def VMAXSH : VX1_Int< 322, "vmaxsh", int_ppc_altivec_vmaxsh>;
 289 def VMAXSW : VX1_Int< 386, "vmaxsw", int_ppc_altivec_vmaxsw>;
 290 def VMAXUB : VX1_Int<   2, "vmaxub", int_ppc_altivec_vmaxub>;
 291 def VMAXUH : VX1_Int<  66, "vmaxuh", int_ppc_altivec_vmaxuh>;
 292 def VMAXUW : VX1_Int< 130, "vmaxuw", int_ppc_altivec_vmaxuw>;
 293 def VMINFP : VX1_Int<1098, "vminfp", int_ppc_altivec_vminfp>;
 294 def VMINSB : VX1_Int< 770, "vminsb", int_ppc_altivec_vminsb>;
 295 def VMINSH : VX1_Int< 834, "vminsh", int_ppc_altivec_vminsh>;
 296 def VMINSW : VX1_Int< 896, "vminsw", int_ppc_altivec_vminsw>;
 297 def VMINUB : VX1_Int< 514, "vminub", int_ppc_altivec_vminub>;
 298 def VMINUH : VX1_Int< 578, "vminuh", int_ppc_altivec_vminuh>;
 299 def VMINUW : VX1_Int< 642, "vminuw", int_ppc_altivec_vminuw>;
 300
 301 def VMRGHB : VXForm_1< 12, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 302                       "vmrghb $vD, $vA, $vB", VecFP,
 303                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 304                                              VRRC:$vB, VMRGHB_shuffle_mask))]>;
 305 def VMRGHH : VXForm_1< 76, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 306                       "vmrghh $vD, $vA, $vB", VecFP,
 307                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 308                                              VRRC:$vB, VMRGHH_shuffle_mask))]>;
 309 def VMRGHW : VXForm_1<140, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 310                       "vmrghw $vD, $vA, $vB", VecFP,
 311                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 312                                              VRRC:$vB, VMRGHW_shuffle_mask))]>;
 313 def VMRGLB : VXForm_1<268, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 314                       "vmrglb $vD, $vA, $vB", VecFP,
 315                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 316                                              VRRC:$vB, VMRGLB_shuffle_mask))]>;
 317 def VMRGLH : VXForm_1<332, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 318                       "vmrglh $vD, $vA, $vB", VecFP,
 319                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 320                                              VRRC:$vB, VMRGLH_shuffle_mask))]>;
 321 def VMRGLW : VXForm_1<396, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 322                       "vmrglw $vD, $vA, $vB", VecFP,
 323                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 324                                              VRRC:$vB, VMRGLW_shuffle_mask))]>;
 325
 326 def VMSUMMBM : VA1a_Int<37, "vmsummbm", int_ppc_altivec_vmsummbm>;
 327 def VMSUMSHM : VA1a_Int<40, "vmsumshm", int_ppc_altivec_vmsumshm>;
 328 def VMSUMSHS : VA1a_Int<41, "vmsumshs", int_ppc_altivec_vmsumshs>;
 329 def VMSUMUBM : VA1a_Int<36, "vmsumubm", int_ppc_altivec_vmsumubm>;
 330 def VMSUMUHM : VA1a_Int<38, "vmsumuhm", int_ppc_altivec_vmsumuhm>;
 331 def VMSUMUHS : VA1a_Int<39, "vmsumuhs", int_ppc_altivec_vmsumuhs>;
 332
 333 def VMULESB : VX1_Int<776, "vmulesb", int_ppc_altivec_vmulesb>;
 334 def VMULESH : VX1_Int<840, "vmulesh", int_ppc_altivec_vmulesh>;
 335 def VMULEUB : VX1_Int<520, "vmuleub", int_ppc_altivec_vmuleub>;
 336 def VMULEUH : VX1_Int<584, "vmuleuh", int_ppc_altivec_vmuleuh>;
 337 def VMULOSB : VX1_Int<264, "vmulosb", int_ppc_altivec_vmulosb>;
 338 def VMULOSH : VX1_Int<328, "vmulosh", int_ppc_altivec_vmulosh>;
 339 def VMULOUB : VX1_Int<  8, "vmuloub", int_ppc_altivec_vmuloub>;
 340 def VMULOUH : VX1_Int< 72, "vmulouh", int_ppc_altivec_vmulouh>;
 341
 342 def VREFP     : VX2_Int<266, "vrefp",     int_ppc_altivec_vrefp>;
 343 def VRFIM     : VX2_Int<714, "vrfim",     int_ppc_altivec_vrfim>;
 344 def VRFIN     : VX2_Int<522, "vrfin",     int_ppc_altivec_vrfin>;
 345 def VRFIP     : VX2_Int<650, "vrfip",     int_ppc_altivec_vrfip>;
 346 def VRFIZ     : VX2_Int<586, "vrfiz",     int_ppc_altivec_vrfiz>;
 347 def VRSQRTEFP : VX2_Int<330, "vrsqrtefp", int_ppc_altivec_vrsqrtefp>;
 348
 349 def VSUBCUW : VX1_Int<74, "vsubcuw", int_ppc_altivec_vsubcuw>;
 350
 351 def VSUBFP  : VXForm_1<74, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 352                       "vsubfp $vD, $vA, $vB", VecGeneral,
 353                       [(set VRRC:$vD, (fsub VRRC:$vA, VRRC:$vB))]>;
 354 def VSUBUBM : VXForm_1<1024, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 355                       "vsububm $vD, $vA, $vB", VecGeneral,
 356                       [(set VRRC:$vD, (sub (v16i8 VRRC:$vA), VRRC:$vB))]>;
 357 def VSUBUHM : VXForm_1<1088, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 358                       "vsubuhm $vD, $vA, $vB", VecGeneral,
 359                       [(set VRRC:$vD, (sub (v8i16 VRRC:$vA), VRRC:$vB))]>;
 360 def VSUBUWM : VXForm_1<1152, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 361                       "vsubuwm $vD, $vA, $vB", VecGeneral,
 362                       [(set VRRC:$vD, (sub (v4i32 VRRC:$vA), VRRC:$vB))]>;
 363
 364 def VSUBSBS : VX1_Int<1792, "vsubsbs" , int_ppc_altivec_vsubsbs>;
 365 def VSUBSHS : VX1_Int<1856, "vsubshs" , int_ppc_altivec_vsubshs>;
 366 def VSUBSWS : VX1_Int<1920, "vsubsws" , int_ppc_altivec_vsubsws>;
 367 def VSUBUBS : VX1_Int<1536, "vsububs" , int_ppc_altivec_vsububs>;
 368 def VSUBUHS : VX1_Int<1600, "vsubuhs" , int_ppc_altivec_vsubuhs>;
 369 def VSUBUWS : VX1_Int<1664, "vsubuws" , int_ppc_altivec_vsubuws>;
 370 def VSUMSWS : VX1_Int<1928, "vsumsws" , int_ppc_altivec_vsumsws>;
 371 def VSUM2SWS: VX1_Int<1672, "vsum2sws", int_ppc_altivec_vsum2sws>;
 372 def VSUM4SBS: VX1_Int<1672, "vsum4sbs", int_ppc_altivec_vsum4sbs>;
 373 def VSUM4SHS: VX1_Int<1608, "vsum4shs", int_ppc_altivec_vsum4shs>;
 374 def VSUM4UBS: VX1_Int<1544, "vsum4ubs", int_ppc_altivec_vsum4ubs>;
 375
 376 def VNOR : VXForm_1<1284, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 377                     "vnor $vD, $vA, $vB", VecFP,
 378                     [(set VRRC:$vD, (vnot (or (v4i32 VRRC:$vA), VRRC:$vB)))]>;
 379 def VOR : VXForm_1<1156, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 380                       "vor $vD, $vA, $vB", VecFP,
 381                       [(set VRRC:$vD, (or (v4i32 VRRC:$vA), VRRC:$vB))]>;
 382 def VXOR : VXForm_1<1220, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 383                       "vxor $vD, $vA, $vB", VecFP,
 384                       [(set VRRC:$vD, (xor (v4i32 VRRC:$vA), VRRC:$vB))]>;
 385
 386 def VRLB   : VX1_Int<   4, "vrlb", int_ppc_altivec_vrlb>;
 387 def VRLH   : VX1_Int<  68, "vrlh", int_ppc_altivec_vrlh>;
 388 def VRLW   : VX1_Int< 132, "vrlw", int_ppc_altivec_vrlw>;
 389
 390 def VSL    : VX1_Int< 452, "vsl" , int_ppc_altivec_vsl >;
 391 def VSLO   : VX1_Int<1036, "vslo", int_ppc_altivec_vslo>;
 392 def VSLB   : VX1_Int< 260, "vslb", int_ppc_altivec_vslb>;
 393 def VSLH   : VX1_Int< 324, "vslh", int_ppc_altivec_vslh>;
 394 def VSLW   : VX1_Int< 388, "vslw", int_ppc_altivec_vslw>;
 395
 396 def VSPLTB : VXForm_1<524, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 397                       "vspltb $vD, $vB, $UIMM", VecPerm,
 398                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vB), (undef),
 399                                       VSPLTB_shuffle_mask:$UIMM))]>;
 400 def VSPLTH : VXForm_1<588, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 401                       "vsplth $vD, $vB, $UIMM", VecPerm,
 402                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vB), (undef),
 403                                       VSPLTH_shuffle_mask:$UIMM))]>;
 404 def VSPLTW : VXForm_1<652, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 405                       "vspltw $vD, $vB, $UIMM", VecPerm,
 406                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vB), (undef),
 407                                       VSPLTW_shuffle_mask:$UIMM))]>;
 408
 409 def VSR    : VX1_Int< 708, "vsr"  , int_ppc_altivec_vsr>;
 410 def VSRO   : VX1_Int<1100, "vsro" , int_ppc_altivec_vsro>;
 411 def VSRAB  : VX1_Int< 772, "vsrab", int_ppc_altivec_vsrab>;
 412 def VSRAH  : VX1_Int< 836, "vsrah", int_ppc_altivec_vsrah>;
 413 def VSRAW  : VX1_Int< 900, "vsraw", int_ppc_altivec_vsraw>;
 414 def VSRB   : VX1_Int< 516, "vsrb" , int_ppc_altivec_vsrb>;
 415 def VSRH   : VX1_Int< 580, "vsrh" , int_ppc_altivec_vsrh>;
 416 def VSRW   : VX1_Int< 644, "vsrw" , int_ppc_altivec_vsrw>;
 417
 418
 419 def VSPLTISB : VXForm_3<780, (ops VRRC:$vD, s5imm:$SIMM),
 420                        "vspltisb $vD, $SIMM", VecPerm,
 421                        [(set VRRC:$vD, (v4f32 vecspltisb:$SIMM))]>;
 422 def VSPLTISH : VXForm_3<844, (ops VRRC:$vD, s5imm:$SIMM),
 423                        "vspltish $vD, $SIMM", VecPerm,
 424                        [(set VRRC:$vD, (v4f32 vecspltish:$SIMM))]>;
 425 def VSPLTISW : VXForm_3<908, (ops VRRC:$vD, s5imm:$SIMM),
 426                        "vspltisw $vD, $SIMM", VecPerm,
 427                        [(set VRRC:$vD, (v4f32 vecspltisw:$SIMM))]>;
 428
 429 // Vector Pack.
 430 def VPKPX   : VX1_Int<782, "vpkpx", int_ppc_altivec_vpkpx>;
 431 def VPKSHSS : VX1_Int<398, "vpkshss", int_ppc_altivec_vpkshss>;
 432 def VPKSHUS : VX1_Int<270, "vpkshus", int_ppc_altivec_vpkshus>;
 433 def VPKSWSS : VX1_Int<462, "vpkswss", int_ppc_altivec_vpkswss>;
 434 def VPKSWUS : VX1_Int<334, "vpkswus", int_ppc_altivec_vpkswus>;
 435 def VPKUHUM : VXForm_1<14, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 436                        "vpkuhum $vD, $vA, $vB", VecFP,
 437                        [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 438                                              VRRC:$vB, VPKUHUM_shuffle_mask))]>;
 439 def VPKUHUS : VX1_Int<142, "vpkuhus", int_ppc_altivec_vpkuhus>;
 440 def VPKUWUM : VXForm_1<78, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 441                        "vpkuwum $vD, $vA, $vB", VecFP,
 442                        [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 443                                              VRRC:$vB, VPKUWUM_shuffle_mask))]>;
 444 def VPKUWUS : VX1_Int<206, "vpkuwus", int_ppc_altivec_vpkuwus>;
 445
 446 // Vector Unpack.
 447 def VUPKHPX : VX2_Int<846, "vupkhpx", int_ppc_altivec_vupkhpx>;
 448 def VUPKHSB : VX2_Int<526, "vupkhsb", int_ppc_altivec_vupkhsb>;
 449 def VUPKHSH : VX2_Int<590, "vupkhsh", int_ppc_altivec_vupkhsh>;
 450 def VUPKLPX : VX2_Int<974, "vupklpx", int_ppc_altivec_vupklpx>;
 451 def VUPKLSB : VX2_Int<654, "vupklsb", int_ppc_altivec_vupklsb>;
 452 def VUPKLSH : VX2_Int<718, "vupklsh", int_ppc_altivec_vupklsh>;
 453
 454
 455 // Altivec Comparisons.
 456
 457 class VCMP<bits<10> xo, string asmstr, ValueType Ty>
 458   : VXRForm_1<xo, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB), asmstr, VecFPCompare,
 459               [(set VRRC:$vD, (Ty (PPCvcmp VRRC:$vA, VRRC:$vB, xo)))]>;
 460 class VCMPo<bits<10> xo, string asmstr, ValueType Ty>
 461   : VXRForm_1<xo, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB), asmstr, VecFPCompare,
 462               [(set VRRC:$vD, (Ty (PPCvcmp_o VRRC:$vA, VRRC:$vB, xo)))]> {
 463   let Defs = [CR6];
 464   let RC = 1;
 465 }
 466
 467 // f32 element comparisons.0
 468 def VCMPBFP   : VCMP <966, "vcmpbfp $vD, $vA, $vB"  , v4f32>;
 469 def VCMPBFPo  : VCMPo<966, "vcmpbfp. $vD, $vA, $vB" , v4f32>;
 470 def VCMPEQFP  : VCMP <198, "vcmpeqfp $vD, $vA, $vB" , v4f32>;
 471 def VCMPEQFPo : VCMPo<198, "vcmpeqfp. $vD, $vA, $vB", v4f32>;
 472 def VCMPGEFP  : VCMP <454, "vcmpgefp $vD, $vA, $vB" , v4f32>;
 473 def VCMPGEFPo : VCMPo<454, "vcmpgefp. $vD, $vA, $vB", v4f32>;
 474 def VCMPGTFP  : VCMP <710, "vcmpgtfp $vD, $vA, $vB" , v4f32>;
 475 def VCMPGTFPo : VCMPo<710, "vcmpgtfp. $vD, $vA, $vB", v4f32>;
 476
 477 // i8 element comparisons.
 478 def VCMPEQUB  : VCMP <  6, "vcmpequb $vD, $vA, $vB" , v16i8>;
 479 def VCMPEQUBo : VCMPo<  6, "vcmpequb. $vD, $vA, $vB", v16i8>;
 480 def VCMPGTSB  : VCMP <774, "vcmpgtsb $vD, $vA, $vB" , v16i8>;
 481 def VCMPGTSBo : VCMPo<774, "vcmpgtsb. $vD, $vA, $vB", v16i8>;
 482 def VCMPGTUB  : VCMP <518, "vcmpgtub $vD, $vA, $vB" , v16i8>;
 483 def VCMPGTUBo : VCMPo<518, "vcmpgtub. $vD, $vA, $vB", v16i8>;
 484
 485 // i16 element comparisons.
 486 def VCMPEQUH  : VCMP < 70, "vcmpequh $vD, $vA, $vB" , v8i16>;
 487 def VCMPEQUHo : VCMPo< 70, "vcmpequh. $vD, $vA, $vB", v8i16>;
 488 def VCMPGTSH  : VCMP <838, "vcmpgtsh $vD, $vA, $vB" , v8i16>;
 489 def VCMPGTSHo : VCMPo<838, "vcmpgtsh. $vD, $vA, $vB", v8i16>;
 490 def VCMPGTUH  : VCMP <582, "vcmpgtuh $vD, $vA, $vB" , v8i16>;
 491 def VCMPGTUHo : VCMPo<582, "vcmpgtuh. $vD, $vA, $vB", v8i16>;
 492
 493 // i32 element comparisons.
 494 def VCMPEQUW  : VCMP <134, "vcmpequw $vD, $vA, $vB" , v4i32>;
 495 def VCMPEQUWo : VCMPo<134, "vcmpequw. $vD, $vA, $vB", v4i32>;
 496 def VCMPGTSW  : VCMP <902, "vcmpgtsw $vD, $vA, $vB" , v4i32>;
 497 def VCMPGTSWo : VCMPo<902, "vcmpgtsw. $vD, $vA, $vB", v4i32>;
 498 def VCMPGTUW  : VCMP <646, "vcmpgtuw $vD, $vA, $vB" , v4i32>;
 499 def VCMPGTUWo : VCMPo<646, "vcmpgtuw. $vD, $vA, $vB", v4i32>;
 500
 501 def V_SET0 : VXForm_setzero<1220, (ops VRRC:$vD),
 502                       "vxor $vD, $vD, $vD", VecFP,
 503                       [(set VRRC:$vD, (v4f32 immAllZerosV))]>;
 504 }
 505
 506 //===----------------------------------------------------------------------===//
 507 // Additional Altivec Patterns
 508 //
 509
 510 // DS* intrinsics.
 511 def : Pat<(int_ppc_altivec_dss imm:$STRM), (DSS 0, imm:$STRM, 0, 0)>;
 512 def : Pat<(int_ppc_altivec_dssall), (DSS 1, 0, 0, 0)>;
 513 def : Pat<(int_ppc_altivec_dst GPRC:$rA, GPRC:$rB, imm:$STRM),
 514           (DST 0, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 515 def : Pat<(int_ppc_altivec_dstt GPRC:$rA, GPRC:$rB, imm:$STRM),
 516           (DST 1, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 517 def : Pat<(int_ppc_altivec_dstst GPRC:$rA, GPRC:$rB, imm:$STRM),
 518           (DSTST 0, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 519 def : Pat<(int_ppc_altivec_dststt GPRC:$rA, GPRC:$rB, imm:$STRM),
 520           (DSTST 1, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 521
 522 // Undef/Zero.
 523 def : Pat<(v16i8 (undef)), (v16i8 (IMPLICIT_DEF_VRRC))>;
 524 def : Pat<(v8i16 (undef)), (v8i16 (IMPLICIT_DEF_VRRC))>;
 525 def : Pat<(v4i32 (undef)), (v4i32 (IMPLICIT_DEF_VRRC))>;
 526 def : Pat<(v16i8 immAllZerosV), (v16i8 (V_SET0))>;
 527 def : Pat<(v8i16 immAllZerosV), (v8i16 (V_SET0))>;
 528 def : Pat<(v4i32 immAllZerosV), (v4i32 (V_SET0))>;
 529
 530 // Loads.
 531 def : Pat<(v16i8 (load xoaddr:$src)), (v16i8 (LVX xoaddr:$src))>;
 532 def : Pat<(v8i16 (load xoaddr:$src)), (v8i16 (LVX xoaddr:$src))>;
 533 def : Pat<(v4i32 (load xoaddr:$src)), (v4i32 (LVX xoaddr:$src))>;
 534 def : Pat<(v4f32 (load xoaddr:$src)), (v4f32 (LVX xoaddr:$src))>;
 535
 536 // Stores.
 537 def : Pat<(store (v16i8 VRRC:$rS), xoaddr:$dst),
 538           (STVX (v16i8 VRRC:$rS), xoaddr:$dst)>;
 539 def : Pat<(store (v8i16 VRRC:$rS), xoaddr:$dst),
 540           (STVX (v8i16 VRRC:$rS), xoaddr:$dst)>;
 541 def : Pat<(store (v4i32 VRRC:$rS), xoaddr:$dst),
 542           (STVX (v4i32 VRRC:$rS), xoaddr:$dst)>;
 543 def : Pat<(store (v4f32 VRRC:$rS), xoaddr:$dst),
 544           (STVX (v4f32 VRRC:$rS), xoaddr:$dst)>;
 545
 546 // Bit conversions.
 547 def : Pat<(v16i8 (bitconvert (v8i16 VRRC:$src))), (v16i8 VRRC:$src)>;
 548 def : Pat<(v16i8 (bitconvert (v4i32 VRRC:$src))), (v16i8 VRRC:$src)>;
 549 def : Pat<(v16i8 (bitconvert (v4f32 VRRC:$src))), (v16i8 VRRC:$src)>;
 550
 551 def : Pat<(v8i16 (bitconvert (v16i8 VRRC:$src))), (v8i16 VRRC:$src)>;
 552 def : Pat<(v8i16 (bitconvert (v4i32 VRRC:$src))), (v8i16 VRRC:$src)>;
 553 def : Pat<(v8i16 (bitconvert (v4f32 VRRC:$src))), (v8i16 VRRC:$src)>;
 554
 555 def : Pat<(v4i32 (bitconvert (v16i8 VRRC:$src))), (v4i32 VRRC:$src)>;
 556 def : Pat<(v4i32 (bitconvert (v8i16 VRRC:$src))), (v4i32 VRRC:$src)>;
 557 def : Pat<(v4i32 (bitconvert (v4f32 VRRC:$src))), (v4i32 VRRC:$src)>;
 558
 559 def : Pat<(v4f32 (bitconvert (v16i8 VRRC:$src))), (v4f32 VRRC:$src)>;
 560 def : Pat<(v4f32 (bitconvert (v8i16 VRRC:$src))), (v4f32 VRRC:$src)>;
 561 def : Pat<(v4f32 (bitconvert (v4i32 VRRC:$src))), (v4f32 VRRC:$src)>;
 562
 563 // Shuffles.
 564
 565 // Match vsldoi(x,x)
 566 def:Pat<(vector_shuffle (v16i8 VRRC:$vA),undef, VSLDOI_rotate_shuffle_mask:$in),
 567         (VSLDOI VRRC:$vA, VRRC:$vA, VSLDOI_rotate_shuffle_mask:$in)>;
 568
 569 // Immediate vector formation with vsplti*.
 570 def : Pat<(v16i8 vecspltisb:$invec), (v16i8 (VSPLTISB vecspltisb:$invec))>;
 571 def : Pat<(v16i8 vecspltish:$invec), (v16i8 (VSPLTISH vecspltish:$invec))>;
 572 def : Pat<(v16i8 vecspltisw:$invec), (v16i8 (VSPLTISW vecspltisw:$invec))>;
 573
 574 def : Pat<(v8i16 vecspltisb:$invec), (v8i16 (VSPLTISB vecspltisb:$invec))>;
 575 def : Pat<(v8i16 vecspltish:$invec), (v8i16 (VSPLTISH vecspltish:$invec))>;
 576 def : Pat<(v8i16 vecspltisw:$invec), (v8i16 (VSPLTISW vecspltisw:$invec))>;
 577
 578 def : Pat<(v4i32 vecspltisb:$invec), (v4i32 (VSPLTISB vecspltisb:$invec))>;
 579 def : Pat<(v4i32 vecspltish:$invec), (v4i32 (VSPLTISH vecspltish:$invec))>;
 580 def : Pat<(v4i32 vecspltisw:$invec), (v4i32 (VSPLTISW vecspltisw:$invec))>;
 581
 582 // Logical Operations
 583 def : Pat<(v16i8 (vnot VRRC:$vA)), (v16i8 (VNOR VRRC:$vA, VRRC:$vA))>;
 584 def : Pat<(v8i16 (vnot VRRC:$vA)), (v8i16 (VNOR VRRC:$vA, VRRC:$vA))>;
 585 def : Pat<(v4i32 (vnot VRRC:$vA)), (v4i32 (VNOR VRRC:$vA, VRRC:$vA))>;
 586
 587 def : Pat<(v16i8 (and VRRC:$A, VRRC:$B)), (v16i8 (VAND VRRC:$A, VRRC:$B))>;
 588 def : Pat<(v8i16 (and VRRC:$A, VRRC:$B)), (v8i16 (VAND VRRC:$A, VRRC:$B))>;
 589 def : Pat<(v16i8 (or  VRRC:$A, VRRC:$B)), (v16i8 (VOR  VRRC:$A, VRRC:$B))>;
 590 def : Pat<(v8i16 (or  VRRC:$A, VRRC:$B)), (v8i16 (VOR  VRRC:$A, VRRC:$B))>;
 591 def : Pat<(v16i8 (xor VRRC:$A, VRRC:$B)), (v16i8 (VXOR VRRC:$A, VRRC:$B))>;
 592 def : Pat<(v8i16 (xor VRRC:$A, VRRC:$B)), (v8i16 (VXOR VRRC:$A, VRRC:$B))>;
 593 def : Pat<(v16i8 (vnot (or VRRC:$A, VRRC:$B))),(v16i8 (VNOR VRRC:$A, VRRC:$B))>;
 594 def : Pat<(v8i16 (vnot (or VRRC:$A, VRRC:$B))),(v8i16 (VNOR VRRC:$A, VRRC:$B))>;
 595 def : Pat<(v16i8 (and VRRC:$A, (vnot VRRC:$B))),
 596           (v16i8 (VANDC VRRC:$A, VRRC:$B))>;
 597 def : Pat<(v8i16 (and VRRC:$A, (vnot VRRC:$B))),
 598           (v8i16 (VANDC VRRC:$A, VRRC:$B))>;
 599
 600 def : Pat<(fmul VRRC:$vA, VRRC:$vB),
 601           (VMADDFP VRRC:$vA, VRRC:$vB, (V_SET0))>;
 602
 603 // Fused multiply add and multiply sub for packed float.  These are represented
 604 // separately from the real instructions above, for operations that must have
 605 // the additional precision, such as Newton-Rhapson (used by divide, sqrt)
 606 def : Pat<(PPCvmaddfp VRRC:$A, VRRC:$B, VRRC:$C),
 607           (VMADDFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 608 def : Pat<(PPCvnmsubfp VRRC:$A, VRRC:$B, VRRC:$C),
 609           (VNMSUBFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 610
 611 def : Pat<(int_ppc_altivec_vmaddfp VRRC:$A, VRRC:$B, VRRC:$C),
 612           (VMADDFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 613 def : Pat<(int_ppc_altivec_vnmsubfp VRRC:$A, VRRC:$B, VRRC:$C),
 614           (VNMSUBFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 615
 616 def : Pat<(PPCvperm (v16i8 VRRC:$vA), VRRC:$vB, VRRC:$vC),
 617           (v16i8 (VPERM VRRC:$vA, VRRC:$vB, VRRC:$vC))>;