lib/Target/PowerPC/PPCInstr64Bit.td

   1 //===-- PPCInstr64Bit.td - The PowerPC 64-bit Support ------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the PowerPC 64-bit instructions.  These patterns are used
  11 // both when in ppc64 mode and when in "use 64-bit extensions in 32-bit" mode.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // 64-bit operands.
  17 //
  18 def s16imm64 : Operand<i64> {
  19   let PrintMethod = "printS16ImmOperand";
  20 }
  21 def u16imm64 : Operand<i64> {
  22   let PrintMethod = "printU16ImmOperand";
  23 }
  24 def symbolHi64 : Operand<i64> {
  25   let PrintMethod = "printSymbolHi";
  26   let EncoderMethod = "getHA16Encoding";
  27 }
  28 def symbolLo64 : Operand<i64> {
  29   let PrintMethod = "printSymbolLo";
  30   let EncoderMethod = "getLO16Encoding";
  31 }
  32
  33 //===----------------------------------------------------------------------===//
  34 // 64-bit transformation functions.
  35 //
  36
  37 def SHL64 : SDNodeXForm<imm, [{
  38   // Transformation function: 63 - imm
  39   return getI32Imm(63 - N->getZExtValue());
  40 }]>;
  41
  42 def SRL64 : SDNodeXForm<imm, [{
  43   // Transformation function: 64 - imm
  44   return N->getZExtValue() ? getI32Imm(64 - N->getZExtValue()) : getI32Imm(0);
  45 }]>;
  46
  47 def HI32_48 : SDNodeXForm<imm, [{
  48   // Transformation function: shift the immediate value down into the low bits.
  49   return getI32Imm((unsigned short)(N->getZExtValue() >> 32));
  50 }]>;
  51
  52 def HI48_64 : SDNodeXForm<imm, [{
  53   // Transformation function: shift the immediate value down into the low bits.
  54   return getI32Imm((unsigned short)(N->getZExtValue() >> 48));
  55 }]>;
  56
  57
  58 //===----------------------------------------------------------------------===//
  59 // Calls.
  60 //
  61
  62 let Defs = [LR8] in
  63   def MovePCtoLR8 : Pseudo<(outs), (ins), "", []>,
  64                     PPC970_Unit_BRU;
  65
  66 // Darwin ABI Calls.
  67 let isCall = 1, PPC970_Unit = 7, Defs = [LR8] in {
  68   // Convenient aliases for call instructions
  69   let Uses = [RM] in {
  70     def BL8_Darwin  : IForm<18, 0, 1,
  71                             (outs), (ins calltarget:$func, variable_ops),
  72                             "bl $func", BrB, []>;  // See Pat patterns below.
  73     def BLA8_Darwin : IForm<18, 1, 1,
  74                           (outs), (ins aaddr:$func, variable_ops),
  75                           "bla $func", BrB, [(PPCcall_Darwin (i64 imm:$func))]>;
  76   }
  77   let Uses = [CTR8, RM] in {
  78     def BCTRL8_Darwin : XLForm_2_ext<19, 528, 20, 0, 1,
  79                                   (outs), (ins variable_ops),
  80                                   "bctrl", BrB,
  81                                   [(PPCbctrl_Darwin)]>, Requires<[In64BitMode]>;
  82   }
  83 }
  84
  85 // ELF 64 ABI Calls = Darwin ABI Calls
  86 // Used to define BL8_ELF and BLA8_ELF
  87 let isCall = 1, PPC970_Unit = 7, Defs = [LR8] in {
  88   // Convenient aliases for call instructions
  89   let Uses = [RM] in {
  90     def BL8_ELF  : IForm<18, 0, 1,
  91                          (outs), (ins calltarget:$func, variable_ops),
  92                          "bl $func", BrB, []>;  // See Pat patterns below.
  93
  94     let isCodeGenOnly = 1 in
  95     def BL8_NOP_ELF  : IForm_and_DForm_4_zero<18, 0, 1, 24,
  96                              (outs), (ins calltarget:$func, variable_ops),
  97                              "bl $func\n\tnop", BrB, []>;
  98
  99     def BLA8_ELF : IForm<18, 1, 1,
 100                          (outs), (ins aaddr:$func, variable_ops),
 101                          "bla $func", BrB, [(PPCcall_SVR4 (i64 imm:$func))]>;
 102
 103     let isCodeGenOnly = 1 in
 104     def BLA8_NOP_ELF : IForm_and_DForm_4_zero<18, 1, 1, 24,
 105                              (outs), (ins aaddr:$func, variable_ops),
 106                              "bla $func\n\tnop", BrB,
 107                              [(PPCcall_nop_SVR4 (i64 imm:$func))]>;
 108   }
 109   let Uses = [X11, CTR8, RM] in {
 110     def BCTRL8_ELF : XLForm_2_ext<19, 528, 20, 0, 1,
 111                                (outs), (ins variable_ops),
 112                                "bctrl", BrB,
 113                                [(PPCbctrl_SVR4)]>, Requires<[In64BitMode]>;
 114   }
 115 }
 116
 117
 118 // Calls
 119 def : Pat<(PPCcall_Darwin (i64 tglobaladdr:$dst)),
 120           (BL8_Darwin tglobaladdr:$dst)>;
 121 def : Pat<(PPCcall_Darwin (i64 texternalsym:$dst)),
 122           (BL8_Darwin texternalsym:$dst)>;
 123
 124 def : Pat<(PPCcall_SVR4 (i64 tglobaladdr:$dst)),
 125           (BL8_ELF tglobaladdr:$dst)>;
 126 def : Pat<(PPCcall_nop_SVR4 (i64 tglobaladdr:$dst)),
 127           (BL8_NOP_ELF tglobaladdr:$dst)>;
 128
 129 def : Pat<(PPCcall_SVR4 (i64 texternalsym:$dst)),
 130           (BL8_ELF texternalsym:$dst)>;
 131 def : Pat<(PPCcall_nop_SVR4 (i64 texternalsym:$dst)),
 132           (BL8_NOP_ELF texternalsym:$dst)>;
 133
 134 def : Pat<(PPCnop),
 135           (NOP)>;
 136
 137 // Atomic operations
 138 let usesCustomInserter = 1 in {
 139   let Defs = [CR0] in {
 140     def ATOMIC_LOAD_ADD_I64 : Pseudo<
 141       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "",
 142       [(set G8RC:$dst, (atomic_load_add_64 xoaddr:$ptr, G8RC:$incr))]>;
 143     def ATOMIC_LOAD_SUB_I64 : Pseudo<
 144       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "",
 145       [(set G8RC:$dst, (atomic_load_sub_64 xoaddr:$ptr, G8RC:$incr))]>;
 146     def ATOMIC_LOAD_OR_I64 : Pseudo<
 147       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "",
 148       [(set G8RC:$dst, (atomic_load_or_64 xoaddr:$ptr, G8RC:$incr))]>;
 149     def ATOMIC_LOAD_XOR_I64 : Pseudo<
 150       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "",
 151       [(set G8RC:$dst, (atomic_load_xor_64 xoaddr:$ptr, G8RC:$incr))]>;
 152     def ATOMIC_LOAD_AND_I64 : Pseudo<
 153       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "",
 154       [(set G8RC:$dst, (atomic_load_and_64 xoaddr:$ptr, G8RC:$incr))]>;
 155     def ATOMIC_LOAD_NAND_I64 : Pseudo<
 156       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "",
 157       [(set G8RC:$dst, (atomic_load_nand_64 xoaddr:$ptr, G8RC:$incr))]>;
 158
 159     def ATOMIC_CMP_SWAP_I64 : Pseudo<
 160       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$old, G8RC:$new), "",
 161       [(set G8RC:$dst,
 162                     (atomic_cmp_swap_64 xoaddr:$ptr, G8RC:$old, G8RC:$new))]>;
 163
 164     def ATOMIC_SWAP_I64 : Pseudo<
 165       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$new), "",
 166       [(set G8RC:$dst, (atomic_swap_64 xoaddr:$ptr, G8RC:$new))]>;
 167   }
 168 }
 169
 170 // Instructions to support atomic operations
 171 def LDARX : XForm_1<31,  84, (outs G8RC:$rD), (ins memrr:$ptr),
 172                    "ldarx $rD, $ptr", LdStLDARX,
 173                    [(set G8RC:$rD, (PPClarx xoaddr:$ptr))]>;
 174
 175 let Defs = [CR0] in
 176 def STDCX : XForm_1<31, 214, (outs), (ins G8RC:$rS, memrr:$dst),
 177                    "stdcx. $rS, $dst", LdStSTDCX,
 178                    [(PPCstcx G8RC:$rS, xoaddr:$dst)]>,
 179                    isDOT;
 180
 181 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
 182 def TCRETURNdi8 :Pseudo< (outs),
 183                         (ins calltarget:$dst, i32imm:$offset, variable_ops),
 184                  "#TC_RETURNd8 $dst $offset",
 185                  []>;
 186
 187 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
 188 def TCRETURNai8 :Pseudo<(outs), (ins aaddr:$func, i32imm:$offset, variable_ops),
 189                  "#TC_RETURNa8 $func $offset",
 190                  [(PPCtc_return (i64 imm:$func), imm:$offset)]>;
 191
 192 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
 193 def TCRETURNri8 : Pseudo<(outs), (ins CTRRC8:$dst, i32imm:$offset, variable_ops),
 194                  "#TC_RETURNr8 $dst $offset",
 195                  []>;
 196
 197
 198 let isTerminator = 1, isBarrier = 1, PPC970_Unit = 7, isBranch = 1,
 199     isIndirectBranch = 1, isCall = 1, Uses = [CTR8, RM] in {
 200   let isReturn = 1 in {
 201     def TAILBCTR8 : XLForm_2_ext<19, 528, 20, 0, 0, (outs), (ins), "bctr", BrB, []>,
 202         Requires<[In64BitMode]>;
 203   }
 204
 205   def BCTR8 : XLForm_2_ext<19, 528, 20, 0, 0, (outs), (ins), "bctr", BrB, []>,
 206       Requires<[In64BitMode]>;
 207 }
 208
 209
 210 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7,
 211     isBarrier = 1, isCall = 1, isReturn = 1, Uses = [RM] in
 212 def TAILB8   : IForm<18, 0, 0, (outs), (ins calltarget:$dst),
 213                   "b $dst", BrB,
 214                   []>;
 215
 216
 217 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7,
 218     isBarrier = 1, isCall = 1, isReturn = 1, Uses = [RM] in
 219 def TAILBA8   : IForm<18, 0, 0, (outs), (ins aaddr:$dst),
 220                   "ba $dst", BrB,
 221                   []>;
 222
 223 def : Pat<(PPCtc_return (i64 tglobaladdr:$dst),  imm:$imm),
 224           (TCRETURNdi8 tglobaladdr:$dst, imm:$imm)>;
 225
 226 def : Pat<(PPCtc_return (i64 texternalsym:$dst), imm:$imm),
 227           (TCRETURNdi8 texternalsym:$dst, imm:$imm)>;
 228
 229 def : Pat<(PPCtc_return CTRRC8:$dst, imm:$imm),
 230           (TCRETURNri8 CTRRC8:$dst, imm:$imm)>;
 231
 232 // 64-but CR instructions
 233 def MTCRF8 : XFXForm_5<31, 144, (outs crbitm:$FXM), (ins G8RC:$rS),
 234                       "mtcrf $FXM, $rS", BrMCRX>,
 235             PPC970_MicroCode, PPC970_Unit_CRU;
 236
 237 def MFCR8pseud: XFXForm_3<31, 19, (outs G8RC:$rT), (ins crbitm:$FXM),
 238                        "", SprMFCR>,
 239             PPC970_MicroCode, PPC970_Unit_CRU;
 240
 241 def MFCR8 : XFXForm_3<31, 19, (outs G8RC:$rT), (ins),
 242                      "mfcr $rT", SprMFCR>,
 243                      PPC970_MicroCode, PPC970_Unit_CRU;
 244
 245 //===----------------------------------------------------------------------===//
 246 // 64-bit SPR manipulation instrs.
 247
 248 let Uses = [CTR8] in {
 249 def MFCTR8 : XFXForm_1_ext<31, 339, 9, (outs G8RC:$rT), (ins),
 250                            "mfctr $rT", SprMFSPR>,
 251              PPC970_DGroup_First, PPC970_Unit_FXU;
 252 }
 253 let Pattern = [(PPCmtctr G8RC:$rS)], Defs = [CTR8] in {
 254 def MTCTR8 : XFXForm_7_ext<31, 467, 9, (outs), (ins G8RC:$rS),
 255                            "mtctr $rS", SprMTSPR>,
 256              PPC970_DGroup_First, PPC970_Unit_FXU;
 257 }
 258
 259 let Defs = [X1], Uses = [X1] in
 260 def DYNALLOC8 : Pseudo<(outs G8RC:$result), (ins G8RC:$negsize, memri:$fpsi),"",
 261                        [(set G8RC:$result,
 262                              (PPCdynalloc G8RC:$negsize, iaddr:$fpsi))]>;
 263
 264 let Defs = [LR8] in {
 265 def MTLR8  : XFXForm_7_ext<31, 467, 8, (outs), (ins G8RC:$rS),
 266                            "mtlr $rS", SprMTSPR>,
 267              PPC970_DGroup_First, PPC970_Unit_FXU;
 268 }
 269 let Uses = [LR8] in {
 270 def MFLR8  : XFXForm_1_ext<31, 339, 8, (outs G8RC:$rT), (ins),
 271                            "mflr $rT", SprMFSPR>,
 272              PPC970_DGroup_First, PPC970_Unit_FXU;
 273 }
 274
 275 //===----------------------------------------------------------------------===//
 276 // Fixed point instructions.
 277 //
 278
 279 let PPC970_Unit = 1 in {  // FXU Operations.
 280
 281 // Copies, extends, truncates.
 282 def OR4To8  : XForm_6<31, 444, (outs G8RC:$rA), (ins GPRC:$rS, GPRC:$rB),
 283                    "or $rA, $rS, $rB", IntGeneral,
 284                    []>;
 285 def OR8To4  : XForm_6<31, 444, (outs GPRC:$rA), (ins G8RC:$rS, G8RC:$rB),
 286                    "or $rA, $rS, $rB", IntGeneral,
 287                    []>;
 288
 289 def LI8  : DForm_2_r0<14, (outs G8RC:$rD), (ins symbolLo64:$imm),
 290                       "li $rD, $imm", IntGeneral,
 291                       [(set G8RC:$rD, immSExt16:$imm)]>;
 292 def LIS8 : DForm_2_r0<15, (outs G8RC:$rD), (ins symbolHi64:$imm),
 293                       "lis $rD, $imm", IntGeneral,
 294                       [(set G8RC:$rD, imm16ShiftedSExt:$imm)]>;
 295
 296 // Logical ops.
 297 def NAND8: XForm_6<31, 476, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 298                    "nand $rA, $rS, $rB", IntGeneral,
 299                    [(set G8RC:$rA, (not (and G8RC:$rS, G8RC:$rB)))]>;
 300 def AND8 : XForm_6<31,  28, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 301                    "and $rA, $rS, $rB", IntGeneral,
 302                    [(set G8RC:$rA, (and G8RC:$rS, G8RC:$rB))]>;
 303 def ANDC8: XForm_6<31,  60, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 304                    "andc $rA, $rS, $rB", IntGeneral,
 305                    [(set G8RC:$rA, (and G8RC:$rS, (not G8RC:$rB)))]>;
 306 def OR8  : XForm_6<31, 444, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 307                    "or $rA, $rS, $rB", IntGeneral,
 308                    [(set G8RC:$rA, (or G8RC:$rS, G8RC:$rB))]>;
 309 def NOR8 : XForm_6<31, 124, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 310                    "nor $rA, $rS, $rB", IntGeneral,
 311                    [(set G8RC:$rA, (not (or G8RC:$rS, G8RC:$rB)))]>;
 312 def ORC8 : XForm_6<31, 412, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 313                    "orc $rA, $rS, $rB", IntGeneral,
 314                    [(set G8RC:$rA, (or G8RC:$rS, (not G8RC:$rB)))]>;
 315 def EQV8 : XForm_6<31, 284, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 316                    "eqv $rA, $rS, $rB", IntGeneral,
 317                    [(set G8RC:$rA, (not (xor G8RC:$rS, G8RC:$rB)))]>;
 318 def XOR8 : XForm_6<31, 316, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 319                    "xor $rA, $rS, $rB", IntGeneral,
 320                    [(set G8RC:$rA, (xor G8RC:$rS, G8RC:$rB))]>;
 321
 322 // Logical ops with immediate.
 323 def ANDIo8  : DForm_4<28, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 324                       "andi. $dst, $src1, $src2", IntGeneral,
 325                       [(set G8RC:$dst, (and G8RC:$src1, immZExt16:$src2))]>,
 326                       isDOT;
 327 def ANDISo8 : DForm_4<29, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 328                      "andis. $dst, $src1, $src2", IntGeneral,
 329                     [(set G8RC:$dst, (and G8RC:$src1,imm16ShiftedZExt:$src2))]>,
 330                      isDOT;
 331 def ORI8    : DForm_4<24, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 332                       "ori $dst, $src1, $src2", IntGeneral,
 333                       [(set G8RC:$dst, (or G8RC:$src1, immZExt16:$src2))]>;
 334 def ORIS8   : DForm_4<25, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 335                       "oris $dst, $src1, $src2", IntGeneral,
 336                     [(set G8RC:$dst, (or G8RC:$src1, imm16ShiftedZExt:$src2))]>;
 337 def XORI8   : DForm_4<26, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 338                       "xori $dst, $src1, $src2", IntGeneral,
 339                       [(set G8RC:$dst, (xor G8RC:$src1, immZExt16:$src2))]>;
 340 def XORIS8  : DForm_4<27, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 341                       "xoris $dst, $src1, $src2", IntGeneral,
 342                    [(set G8RC:$dst, (xor G8RC:$src1, imm16ShiftedZExt:$src2))]>;
 343
 344 def ADD8  : XOForm_1<31, 266, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 345                      "add $rT, $rA, $rB", IntGeneral,
 346                      [(set G8RC:$rT, (add G8RC:$rA, G8RC:$rB))]>;
 347
 348 let Defs = [CARRY] in {
 349 def ADDC8 : XOForm_1<31, 10, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 350                      "addc $rT, $rA, $rB", IntGeneral,
 351                      [(set G8RC:$rT, (addc G8RC:$rA, G8RC:$rB))]>,
 352                      PPC970_DGroup_Cracked;
 353 def ADDIC8 : DForm_2<12, (outs G8RC:$rD), (ins G8RC:$rA, s16imm64:$imm),
 354                      "addic $rD, $rA, $imm", IntGeneral,
 355                      [(set G8RC:$rD, (addc G8RC:$rA, immSExt16:$imm))]>;
 356 }
 357 def ADDI8  : DForm_2<14, (outs G8RC:$rD), (ins G8RC:$rA, s16imm64:$imm),
 358                      "addi $rD, $rA, $imm", IntGeneral,
 359                      [(set G8RC:$rD, (add G8RC:$rA, immSExt16:$imm))]>;
 360 def ADDI8L  : DForm_2<14, (outs G8RC:$rD), (ins G8RC:$rA, symbolLo64:$imm),
 361                      "addi $rD, $rA, $imm", IntGeneral,
 362                      [(set G8RC:$rD, (add G8RC:$rA, immSExt16:$imm))]>;
 363 def ADDIS8 : DForm_2<15, (outs G8RC:$rD), (ins G8RC:$rA, symbolHi64:$imm),
 364                      "addis $rD, $rA, $imm", IntGeneral,
 365                      [(set G8RC:$rD, (add G8RC:$rA, imm16ShiftedSExt:$imm))]>;
 366
 367 let Defs = [CARRY] in {
 368 def SUBFIC8: DForm_2< 8, (outs G8RC:$rD), (ins G8RC:$rA, s16imm64:$imm),
 369                      "subfic $rD, $rA, $imm", IntGeneral,
 370                      [(set G8RC:$rD, (subc immSExt16:$imm, G8RC:$rA))]>;
 371 def SUBFC8 : XOForm_1<31, 8, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 372                       "subfc $rT, $rA, $rB", IntGeneral,
 373                       [(set G8RC:$rT, (subc G8RC:$rB, G8RC:$rA))]>,
 374                       PPC970_DGroup_Cracked;
 375 }
 376 def SUBF8 : XOForm_1<31, 40, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 377                      "subf $rT, $rA, $rB", IntGeneral,
 378                      [(set G8RC:$rT, (sub G8RC:$rB, G8RC:$rA))]>;
 379 def NEG8    : XOForm_3<31, 104, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 380                        "neg $rT, $rA", IntGeneral,
 381                        [(set G8RC:$rT, (ineg G8RC:$rA))]>;
 382 let Uses = [CARRY], Defs = [CARRY] in {
 383 def ADDE8   : XOForm_1<31, 138, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 384                        "adde $rT, $rA, $rB", IntGeneral,
 385                        [(set G8RC:$rT, (adde G8RC:$rA, G8RC:$rB))]>;
 386 def ADDME8  : XOForm_3<31, 234, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 387                        "addme $rT, $rA", IntGeneral,
 388                        [(set G8RC:$rT, (adde G8RC:$rA, -1))]>;
 389 def ADDZE8  : XOForm_3<31, 202, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 390                        "addze $rT, $rA", IntGeneral,
 391                        [(set G8RC:$rT, (adde G8RC:$rA, 0))]>;
 392 def SUBFE8  : XOForm_1<31, 136, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 393                        "subfe $rT, $rA, $rB", IntGeneral,
 394                        [(set G8RC:$rT, (sube G8RC:$rB, G8RC:$rA))]>;
 395 def SUBFME8 : XOForm_3<31, 232, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 396                        "subfme $rT, $rA", IntGeneral,
 397                        [(set G8RC:$rT, (sube -1, G8RC:$rA))]>;
 398 def SUBFZE8 : XOForm_3<31, 200, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 399                        "subfze $rT, $rA", IntGeneral,
 400                        [(set G8RC:$rT, (sube 0, G8RC:$rA))]>;
 401 }
 402
 403
 404 def MULHD : XOForm_1<31, 73, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 405                      "mulhd $rT, $rA, $rB", IntMulHW,
 406                      [(set G8RC:$rT, (mulhs G8RC:$rA, G8RC:$rB))]>;
 407 def MULHDU : XOForm_1<31, 9, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 408                      "mulhdu $rT, $rA, $rB", IntMulHWU,
 409                      [(set G8RC:$rT, (mulhu G8RC:$rA, G8RC:$rB))]>;
 410
 411 def CMPD   : XForm_16_ext<31, 0, (outs CRRC:$crD), (ins G8RC:$rA, G8RC:$rB),
 412                           "cmpd $crD, $rA, $rB", IntCompare>, isPPC64;
 413 def CMPLD  : XForm_16_ext<31, 32, (outs CRRC:$crD), (ins G8RC:$rA, G8RC:$rB),
 414                           "cmpld $crD, $rA, $rB", IntCompare>, isPPC64;
 415 def CMPDI  : DForm_5_ext<11, (outs CRRC:$crD), (ins G8RC:$rA, s16imm:$imm),
 416                          "cmpdi $crD, $rA, $imm", IntCompare>, isPPC64;
 417 def CMPLDI : DForm_6_ext<10, (outs CRRC:$dst), (ins G8RC:$src1, u16imm:$src2),
 418                          "cmpldi $dst, $src1, $src2", IntCompare>, isPPC64;
 419
 420 def SLD  : XForm_6<31,  27, (outs G8RC:$rA), (ins G8RC:$rS, GPRC:$rB),
 421                    "sld $rA, $rS, $rB", IntRotateD,
 422                    [(set G8RC:$rA, (PPCshl G8RC:$rS, GPRC:$rB))]>, isPPC64;
 423 def SRD  : XForm_6<31, 539, (outs G8RC:$rA), (ins G8RC:$rS, GPRC:$rB),
 424                    "srd $rA, $rS, $rB", IntRotateD,
 425                    [(set G8RC:$rA, (PPCsrl G8RC:$rS, GPRC:$rB))]>, isPPC64;
 426 let Defs = [CARRY] in {
 427 def SRAD : XForm_6<31, 794, (outs G8RC:$rA), (ins G8RC:$rS, GPRC:$rB),
 428                    "srad $rA, $rS, $rB", IntRotateD,
 429                    [(set G8RC:$rA, (PPCsra G8RC:$rS, GPRC:$rB))]>, isPPC64;
 430 }
 431
 432 def EXTSB8 : XForm_11<31, 954, (outs G8RC:$rA), (ins G8RC:$rS),
 433                       "extsb $rA, $rS", IntGeneral,
 434                       [(set G8RC:$rA, (sext_inreg G8RC:$rS, i8))]>;
 435 def EXTSH8 : XForm_11<31, 922, (outs G8RC:$rA), (ins G8RC:$rS),
 436                       "extsh $rA, $rS", IntGeneral,
 437                       [(set G8RC:$rA, (sext_inreg G8RC:$rS, i16))]>;
 438
 439 def EXTSW  : XForm_11<31, 986, (outs G8RC:$rA), (ins G8RC:$rS),
 440                       "extsw $rA, $rS", IntGeneral,
 441                       [(set G8RC:$rA, (sext_inreg G8RC:$rS, i32))]>, isPPC64;
 442 /// EXTSW_32 - Just like EXTSW, but works on '32-bit' registers.
 443 def EXTSW_32 : XForm_11<31, 986, (outs GPRC:$rA), (ins GPRC:$rS),
 444                       "extsw $rA, $rS", IntGeneral,
 445                       [(set GPRC:$rA, (PPCextsw_32 GPRC:$rS))]>, isPPC64;
 446 def EXTSW_32_64 : XForm_11<31, 986, (outs G8RC:$rA), (ins GPRC:$rS),
 447                       "extsw $rA, $rS", IntGeneral,
 448                       [(set G8RC:$rA, (sext GPRC:$rS))]>, isPPC64;
 449
 450 let Defs = [CARRY] in {
 451 def SRADI  : XSForm_1<31, 413, (outs G8RC:$rA), (ins G8RC:$rS, u6imm:$SH),
 452                       "sradi $rA, $rS, $SH", IntRotateD,
 453                       [(set G8RC:$rA, (sra G8RC:$rS, (i32 imm:$SH)))]>, isPPC64;
 454 }
 455 def CNTLZD : XForm_11<31, 58, (outs G8RC:$rA), (ins G8RC:$rS),
 456                       "cntlzd $rA, $rS", IntGeneral,
 457                       [(set G8RC:$rA, (ctlz G8RC:$rS))]>;
 458
 459 def DIVD  : XOForm_1<31, 489, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 460                      "divd $rT, $rA, $rB", IntDivD,
 461                      [(set G8RC:$rT, (sdiv G8RC:$rA, G8RC:$rB))]>, isPPC64,
 462                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
 463 def DIVDU : XOForm_1<31, 457, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 464                      "divdu $rT, $rA, $rB", IntDivD,
 465                      [(set G8RC:$rT, (udiv G8RC:$rA, G8RC:$rB))]>, isPPC64,
 466                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
 467 def MULLD : XOForm_1<31, 233, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 468                      "mulld $rT, $rA, $rB", IntMulHD,
 469                      [(set G8RC:$rT, (mul G8RC:$rA, G8RC:$rB))]>, isPPC64;
 470
 471
 472 let isCommutable = 1 in {
 473 def RLDIMI : MDForm_1<30, 3,
 474                       (outs G8RC:$rA), (ins G8RC:$rSi, G8RC:$rS, u6imm:$SH, u6imm:$MB),
 475                       "rldimi $rA, $rS, $SH, $MB", IntRotateD,
 476                       []>, isPPC64, RegConstraint<"$rSi = $rA">,
 477                       NoEncode<"$rSi">;
 478 }
 479
 480 // Rotate instructions.
 481 def RLDCL  : MDForm_1<30, 0,
 482                       (outs G8RC:$rA), (ins G8RC:$rS, GPRC:$rB, u6imm:$MB),
 483                       "rldcl $rA, $rS, $rB, $MB", IntRotateD,
 484                       []>, isPPC64;
 485 def RLDICL : MDForm_1<30, 0,
 486                       (outs G8RC:$rA), (ins G8RC:$rS, u6imm:$SH, u6imm:$MB),
 487                       "rldicl $rA, $rS, $SH, $MB", IntRotateD,
 488                       []>, isPPC64;
 489 def RLDICR : MDForm_1<30, 1,
 490                       (outs G8RC:$rA), (ins G8RC:$rS, u6imm:$SH, u6imm:$ME),
 491                       "rldicr $rA, $rS, $SH, $ME", IntRotateD,
 492                       []>, isPPC64;
 493
 494 def RLWINM8 : MForm_2<21,
 495                      (outs G8RC:$rA), (ins G8RC:$rS, u5imm:$SH, u5imm:$MB, u5imm:$ME),
 496                      "rlwinm $rA, $rS, $SH, $MB, $ME", IntGeneral,
 497                      []>;
 498
 499 }  // End FXU Operations.
 500
 501
 502 //===----------------------------------------------------------------------===//
 503 // Load/Store instructions.
 504 //
 505
 506
 507 // Sign extending loads.
 508 let canFoldAsLoad = 1, PPC970_Unit = 2 in {
 509 def LHA8: DForm_1<42, (outs G8RC:$rD), (ins memri:$src),
 510                   "lha $rD, $src", LdStLHA,
 511                   [(set G8RC:$rD, (sextloadi16 iaddr:$src))]>,
 512                   PPC970_DGroup_Cracked;
 513 def LWA  : DSForm_1<58, 2, (outs G8RC:$rD), (ins memrix:$src),
 514                     "lwa $rD, $src", LdStLWA,
 515                     [(set G8RC:$rD, (sextloadi32 ixaddr:$src))]>, isPPC64,
 516                     PPC970_DGroup_Cracked;
 517 def LHAX8: XForm_1<31, 343, (outs G8RC:$rD), (ins memrr:$src),
 518                    "lhax $rD, $src", LdStLHA,
 519                    [(set G8RC:$rD, (sextloadi16 xaddr:$src))]>,
 520                    PPC970_DGroup_Cracked;
 521 def LWAX : XForm_1<31, 341, (outs G8RC:$rD), (ins memrr:$src),
 522                    "lwax $rD, $src", LdStLHA,
 523                    [(set G8RC:$rD, (sextloadi32 xaddr:$src))]>, isPPC64,
 524                    PPC970_DGroup_Cracked;
 525
 526 // Update forms.
 527 let mayLoad = 1 in
 528 def LHAU8 : DForm_1a<43, (outs G8RC:$rD, ptr_rc:$ea_result), (ins symbolLo:$disp,
 529                             ptr_rc:$rA),
 530                     "lhau $rD, $disp($rA)", LdStLoad,
 531                     []>, RegConstraint<"$rA = $ea_result">,
 532                     NoEncode<"$ea_result">;
 533 // NO LWAU!
 534
 535 }
 536
 537 // Zero extending loads.
 538 let canFoldAsLoad = 1, PPC970_Unit = 2 in {
 539 def LBZ8 : DForm_1<34, (outs G8RC:$rD), (ins memri:$src),
 540                   "lbz $rD, $src", LdStLoad,
 541                   [(set G8RC:$rD, (zextloadi8 iaddr:$src))]>;
 542 def LHZ8 : DForm_1<40, (outs G8RC:$rD), (ins memri:$src),
 543                   "lhz $rD, $src", LdStLoad,
 544                   [(set G8RC:$rD, (zextloadi16 iaddr:$src))]>;
 545 def LWZ8 : DForm_1<32, (outs G8RC:$rD), (ins memri:$src),
 546                   "lwz $rD, $src", LdStLoad,
 547                   [(set G8RC:$rD, (zextloadi32 iaddr:$src))]>, isPPC64;
 548
 549 def LBZX8 : XForm_1<31,  87, (outs G8RC:$rD), (ins memrr:$src),
 550                    "lbzx $rD, $src", LdStLoad,
 551                    [(set G8RC:$rD, (zextloadi8 xaddr:$src))]>;
 552 def LHZX8 : XForm_1<31, 279, (outs G8RC:$rD), (ins memrr:$src),
 553                    "lhzx $rD, $src", LdStLoad,
 554                    [(set G8RC:$rD, (zextloadi16 xaddr:$src))]>;
 555 def LWZX8 : XForm_1<31,  23, (outs G8RC:$rD), (ins memrr:$src),
 556                    "lwzx $rD, $src", LdStLoad,
 557                    [(set G8RC:$rD, (zextloadi32 xaddr:$src))]>;
 558
 559
 560 // Update forms.
 561 let mayLoad = 1 in {
 562 def LBZU8 : DForm_1<35, (outs G8RC:$rD, ptr_rc:$ea_result), (ins memri:$addr),
 563                     "lbzu $rD, $addr", LdStLoad,
 564                     []>, RegConstraint<"$addr.reg = $ea_result">,
 565                     NoEncode<"$ea_result">;
 566 def LHZU8 : DForm_1<41, (outs G8RC:$rD, ptr_rc:$ea_result), (ins memri:$addr),
 567                     "lhzu $rD, $addr", LdStLoad,
 568                     []>, RegConstraint<"$addr.reg = $ea_result">,
 569                     NoEncode<"$ea_result">;
 570 def LWZU8 : DForm_1<33, (outs G8RC:$rD, ptr_rc:$ea_result), (ins memri:$addr),
 571                     "lwzu $rD, $addr", LdStLoad,
 572                     []>, RegConstraint<"$addr.reg = $ea_result">,
 573                     NoEncode<"$ea_result">;
 574 }
 575 }
 576
 577
 578 // Full 8-byte loads.
 579 let canFoldAsLoad = 1, PPC970_Unit = 2 in {
 580 def LD   : DSForm_1<58, 0, (outs G8RC:$rD), (ins memrix:$src),
 581                     "ld $rD, $src", LdStLD,
 582                     [(set G8RC:$rD, (load ixaddr:$src))]>, isPPC64;
 583 def LDtoc: Pseudo<(outs G8RC:$rD), (ins tocentry:$disp, G8RC:$reg),
 584                   "",
 585                   [(set G8RC:$rD,
 586                      (PPCtoc_entry tglobaladdr:$disp, G8RC:$reg))]>, isPPC64;
 587
 588 let hasSideEffects = 1 in {
 589 let RST = 2, DS_RA = 0 in // FIXME: Should be a pseudo.
 590 def LDinto_toc: DSForm_1<58, 0, (outs), (ins G8RC:$reg),
 591                     "ld 2, 8($reg)", LdStLD,
 592                     [(PPCload_toc G8RC:$reg)]>, isPPC64;
 593
 594 let RST = 2, DS_RA = 0 in // FIXME: Should be a pseudo.
 595 def LDtoc_restore : DSForm_1<58, 0, (outs), (ins),
 596                     "ld 2, 40(1)", LdStLD,
 597                     [(PPCtoc_restore)]>, isPPC64;
 598 }
 599 def LDX  : XForm_1<31,  21, (outs G8RC:$rD), (ins memrr:$src),
 600                    "ldx $rD, $src", LdStLD,
 601                    [(set G8RC:$rD, (load xaddr:$src))]>, isPPC64;
 602
 603 let mayLoad = 1 in
 604 def LDU  : DSForm_1<58, 1, (outs G8RC:$rD, ptr_rc:$ea_result), (ins memrix:$addr),
 605                     "ldu $rD, $addr", LdStLD,
 606                     []>, RegConstraint<"$addr.reg = $ea_result">, isPPC64,
 607                     NoEncode<"$ea_result">;
 608
 609 }
 610
 611 def : Pat<(PPCload ixaddr:$src),
 612           (LD ixaddr:$src)>;
 613 def : Pat<(PPCload xaddr:$src),
 614           (LDX xaddr:$src)>;
 615
 616 let PPC970_Unit = 2 in {
 617 // Truncating stores.
 618 def STB8 : DForm_1<38, (outs), (ins G8RC:$rS, memri:$src),
 619                    "stb $rS, $src", LdStStore,
 620                    [(truncstorei8 G8RC:$rS, iaddr:$src)]>;
 621 def STH8 : DForm_1<44, (outs), (ins G8RC:$rS, memri:$src),
 622                    "sth $rS, $src", LdStStore,
 623                    [(truncstorei16 G8RC:$rS, iaddr:$src)]>;
 624 def STW8 : DForm_1<36, (outs), (ins G8RC:$rS, memri:$src),
 625                    "stw $rS, $src", LdStStore,
 626                    [(truncstorei32 G8RC:$rS, iaddr:$src)]>;
 627 def STBX8 : XForm_8<31, 215, (outs), (ins G8RC:$rS, memrr:$dst),
 628                    "stbx $rS, $dst", LdStStore,
 629                    [(truncstorei8 G8RC:$rS, xaddr:$dst)]>,
 630                    PPC970_DGroup_Cracked;
 631 def STHX8 : XForm_8<31, 407, (outs), (ins G8RC:$rS, memrr:$dst),
 632                    "sthx $rS, $dst", LdStStore,
 633                    [(truncstorei16 G8RC:$rS, xaddr:$dst)]>,
 634                    PPC970_DGroup_Cracked;
 635 def STWX8 : XForm_8<31, 151, (outs), (ins G8RC:$rS, memrr:$dst),
 636                    "stwx $rS, $dst", LdStStore,
 637                    [(truncstorei32 G8RC:$rS, xaddr:$dst)]>,
 638                    PPC970_DGroup_Cracked;
 639 // Normal 8-byte stores.
 640 def STD  : DSForm_1<62, 0, (outs), (ins G8RC:$rS, memrix:$dst),
 641                     "std $rS, $dst", LdStSTD,
 642                     [(store G8RC:$rS, ixaddr:$dst)]>, isPPC64;
 643 def STDX  : XForm_8<31, 149, (outs), (ins G8RC:$rS, memrr:$dst),
 644                    "stdx $rS, $dst", LdStSTD,
 645                    [(store G8RC:$rS, xaddr:$dst)]>, isPPC64,
 646                    PPC970_DGroup_Cracked;
 647 }
 648
 649 let PPC970_Unit = 2 in {
 650
 651 def STBU8 : DForm_1a<38, (outs ptr_rc:$ea_res), (ins G8RC:$rS,
 652                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 653                     "stbu $rS, $ptroff($ptrreg)", LdStStore,
 654                     [(set ptr_rc:$ea_res,
 655                           (pre_truncsti8 G8RC:$rS, ptr_rc:$ptrreg,
 656                                          iaddroff:$ptroff))]>,
 657                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 658 def STHU8 : DForm_1a<45, (outs ptr_rc:$ea_res), (ins G8RC:$rS,
 659                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 660                     "sthu $rS, $ptroff($ptrreg)", LdStStore,
 661                     [(set ptr_rc:$ea_res,
 662                         (pre_truncsti16 G8RC:$rS, ptr_rc:$ptrreg,
 663                                         iaddroff:$ptroff))]>,
 664                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 665
 666 def STWU8 : DForm_1a<37, (outs ptr_rc:$ea_res), (ins G8RC:$rS,
 667                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 668                     "stwu $rS, $ptroff($ptrreg)", LdStStore,
 669                     [(set ptr_rc:$ea_res,
 670                           (pre_truncsti32 G8RC:$rS, ptr_rc:$ptrreg,
 671                                           iaddroff:$ptroff))]>,
 672                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 673
 674 def STDU : DSForm_1a<62, 1, (outs ptr_rc:$ea_res), (ins G8RC:$rS,
 675                                         s16immX4:$ptroff, ptr_rc:$ptrreg),
 676                     "stdu $rS, $ptroff($ptrreg)", LdStSTD,
 677                     [(set ptr_rc:$ea_res, (pre_store G8RC:$rS, ptr_rc:$ptrreg,
 678                                                      iaddroff:$ptroff))]>,
 679                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">,
 680                     isPPC64;
 681
 682 let mayStore = 1 in
 683 def STDUX : XForm_8<31, 181, (outs), (ins G8RC:$rS, memrr:$dst),
 684                    "stdux $rS, $dst", LdStSTD,
 685                    []>, isPPC64;
 686
 687 // STD_32/STDX_32 - Just like STD/STDX, but uses a '32-bit' input register.
 688 def STD_32  : DSForm_1<62, 0, (outs), (ins GPRC:$rT, memrix:$dst),
 689                        "std $rT, $dst", LdStSTD,
 690                        [(PPCstd_32  GPRC:$rT, ixaddr:$dst)]>, isPPC64;
 691 def STDX_32  : XForm_8<31, 149, (outs), (ins GPRC:$rT, memrr:$dst),
 692                        "stdx $rT, $dst", LdStSTD,
 693                        [(PPCstd_32  GPRC:$rT, xaddr:$dst)]>, isPPC64,
 694                        PPC970_DGroup_Cracked;
 695 }
 696
 697
 698
 699 //===----------------------------------------------------------------------===//
 700 // Floating point instructions.
 701 //
 702
 703
 704 let PPC970_Unit = 3, Uses = [RM] in {  // FPU Operations.
 705 def FCFID  : XForm_26<63, 846, (outs F8RC:$frD), (ins F8RC:$frB),
 706                       "fcfid $frD, $frB", FPGeneral,
 707                       [(set F8RC:$frD, (PPCfcfid F8RC:$frB))]>, isPPC64;
 708 def FCTIDZ : XForm_26<63, 815, (outs F8RC:$frD), (ins F8RC:$frB),
 709                       "fctidz $frD, $frB", FPGeneral,
 710                       [(set F8RC:$frD, (PPCfctidz F8RC:$frB))]>, isPPC64;
 711 }
 712
 713
 714 //===----------------------------------------------------------------------===//
 715 // Instruction Patterns
 716 //
 717
 718 // Extensions and truncates to/from 32-bit regs.
 719 def : Pat<(i64 (zext GPRC:$in)),
 720           (RLDICL (OR4To8 GPRC:$in, GPRC:$in), 0, 32)>;
 721 def : Pat<(i64 (anyext GPRC:$in)),
 722           (OR4To8 GPRC:$in, GPRC:$in)>;
 723 def : Pat<(i32 (trunc G8RC:$in)),
 724           (OR8To4 G8RC:$in, G8RC:$in)>;
 725
 726 // Extending loads with i64 targets.
 727 def : Pat<(zextloadi1 iaddr:$src),
 728           (LBZ8 iaddr:$src)>;
 729 def : Pat<(zextloadi1 xaddr:$src),
 730           (LBZX8 xaddr:$src)>;
 731 def : Pat<(extloadi1 iaddr:$src),
 732           (LBZ8 iaddr:$src)>;
 733 def : Pat<(extloadi1 xaddr:$src),
 734           (LBZX8 xaddr:$src)>;
 735 def : Pat<(extloadi8 iaddr:$src),
 736           (LBZ8 iaddr:$src)>;
 737 def : Pat<(extloadi8 xaddr:$src),
 738           (LBZX8 xaddr:$src)>;
 739 def : Pat<(extloadi16 iaddr:$src),
 740           (LHZ8 iaddr:$src)>;
 741 def : Pat<(extloadi16 xaddr:$src),
 742           (LHZX8 xaddr:$src)>;
 743 def : Pat<(extloadi32 iaddr:$src),
 744           (LWZ8 iaddr:$src)>;
 745 def : Pat<(extloadi32 xaddr:$src),
 746           (LWZX8 xaddr:$src)>;
 747
 748 // Standard shifts.  These are represented separately from the real shifts above
 749 // so that we can distinguish between shifts that allow 6-bit and 7-bit shift
 750 // amounts.
 751 def : Pat<(sra G8RC:$rS, GPRC:$rB),
 752           (SRAD G8RC:$rS, GPRC:$rB)>;
 753 def : Pat<(srl G8RC:$rS, GPRC:$rB),
 754           (SRD G8RC:$rS, GPRC:$rB)>;
 755 def : Pat<(shl G8RC:$rS, GPRC:$rB),
 756           (SLD G8RC:$rS, GPRC:$rB)>;
 757
 758 // SHL/SRL
 759 def : Pat<(shl G8RC:$in, (i32 imm:$imm)),
 760           (RLDICR G8RC:$in, imm:$imm, (SHL64 imm:$imm))>;
 761 def : Pat<(srl G8RC:$in, (i32 imm:$imm)),
 762           (RLDICL G8RC:$in, (SRL64 imm:$imm), imm:$imm)>;
 763
 764 // ROTL
 765 def : Pat<(rotl G8RC:$in, GPRC:$sh),
 766           (RLDCL G8RC:$in, GPRC:$sh, 0)>;
 767 def : Pat<(rotl G8RC:$in, (i32 imm:$imm)),
 768           (RLDICL G8RC:$in, imm:$imm, 0)>;
 769
 770 // Hi and Lo for Darwin Global Addresses.
 771 def : Pat<(PPChi tglobaladdr:$in, 0), (LIS8 tglobaladdr:$in)>;
 772 def : Pat<(PPClo tglobaladdr:$in, 0), (LI8  tglobaladdr:$in)>;
 773 def : Pat<(PPChi tconstpool:$in , 0), (LIS8 tconstpool:$in)>;
 774 def : Pat<(PPClo tconstpool:$in , 0), (LI8  tconstpool:$in)>;
 775 def : Pat<(PPChi tjumptable:$in , 0), (LIS8 tjumptable:$in)>;
 776 def : Pat<(PPClo tjumptable:$in , 0), (LI8  tjumptable:$in)>;
 777 def : Pat<(PPChi tblockaddress:$in, 0), (LIS8 tblockaddress:$in)>;
 778 def : Pat<(PPClo tblockaddress:$in, 0), (LI8  tblockaddress:$in)>;
 779 def : Pat<(PPChi tglobaltlsaddr:$g, G8RC:$in),
 780           (ADDIS8 G8RC:$in, tglobaltlsaddr:$g)>;
 781 def : Pat<(PPClo tglobaltlsaddr:$g, G8RC:$in),
 782           (ADDI8L G8RC:$in, tglobaltlsaddr:$g)>;
 783 def : Pat<(add G8RC:$in, (PPChi tglobaladdr:$g, 0)),
 784           (ADDIS8 G8RC:$in, tglobaladdr:$g)>;
 785 def : Pat<(add G8RC:$in, (PPChi tconstpool:$g, 0)),
 786           (ADDIS8 G8RC:$in, tconstpool:$g)>;
 787 def : Pat<(add G8RC:$in, (PPChi tjumptable:$g, 0)),
 788           (ADDIS8 G8RC:$in, tjumptable:$g)>;
 789 def : Pat<(add G8RC:$in, (PPChi tblockaddress:$g, 0)),
 790           (ADDIS8 G8RC:$in, tblockaddress:$g)>;