lib/Target/PowerPC/PPCInstr64Bit.td

   1 //===-- PPCInstr64Bit.td - The PowerPC 64-bit Support ------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the PowerPC 64-bit instructions.  These patterns are used
  11 // both when in ppc64 mode and when in "use 64-bit extensions in 32-bit" mode.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // 64-bit operands.
  17 //
  18 def s16imm64 : Operand<i64> {
  19   let PrintMethod = "printS16ImmOperand";
  20 }
  21 def u16imm64 : Operand<i64> {
  22   let PrintMethod = "printU16ImmOperand";
  23 }
  24 def symbolHi64 : Operand<i64> {
  25   let PrintMethod = "printSymbolHi";
  26   let EncoderMethod = "getHA16Encoding";
  27 }
  28 def symbolLo64 : Operand<i64> {
  29   let PrintMethod = "printSymbolLo";
  30   let EncoderMethod = "getLO16Encoding";
  31 }
  32 def tocentry : Operand<iPTR> {
  33   let MIOperandInfo = (ops i64imm:$imm);
  34 }
  35 def tlsreg : Operand<i64> {
  36   let EncoderMethod = "getTLSRegEncoding";
  37 }
  38 def tlsgd : Operand<i64> {}
  39
  40 //===----------------------------------------------------------------------===//
  41 // 64-bit transformation functions.
  42 //
  43
  44 def SHL64 : SDNodeXForm<imm, [{
  45   // Transformation function: 63 - imm
  46   return getI32Imm(63 - N->getZExtValue());
  47 }]>;
  48
  49 def SRL64 : SDNodeXForm<imm, [{
  50   // Transformation function: 64 - imm
  51   return N->getZExtValue() ? getI32Imm(64 - N->getZExtValue()) : getI32Imm(0);
  52 }]>;
  53
  54 def HI32_48 : SDNodeXForm<imm, [{
  55   // Transformation function: shift the immediate value down into the low bits.
  56   return getI32Imm((unsigned short)(N->getZExtValue() >> 32));
  57 }]>;
  58
  59 def HI48_64 : SDNodeXForm<imm, [{
  60   // Transformation function: shift the immediate value down into the low bits.
  61   return getI32Imm((unsigned short)(N->getZExtValue() >> 48));
  62 }]>;
  63
  64
  65 //===----------------------------------------------------------------------===//
  66 // Calls.
  67 //
  68
  69 let isTerminator = 1, isBarrier = 1, PPC970_Unit = 7 in {
  70   let isBranch = 1, isIndirectBranch = 1, Uses = [CTR8] in
  71     def BCTR8 : XLForm_2_ext<19, 528, 20, 0, 0, (outs), (ins), "bctr", BrB, []>,
  72         Requires<[In64BitMode]>;
  73 }
  74
  75 let Defs = [LR8] in
  76   def MovePCtoLR8 : Pseudo<(outs), (ins), "#MovePCtoLR8", []>,
  77                     PPC970_Unit_BRU;
  78
  79 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7 in {
  80   let Defs = [CTR8], Uses = [CTR8] in {
  81     def BDZ8  : BForm_1<16, 18, 0, 0, (outs), (ins condbrtarget:$dst),
  82                         "bdz $dst">;
  83     def BDNZ8 : BForm_1<16, 16, 0, 0, (outs), (ins condbrtarget:$dst),
  84                         "bdnz $dst">;
  85   }
  86 }
  87
  88 let isCall = 1, PPC970_Unit = 7, Defs = [LR8] in {
  89   // Convenient aliases for call instructions
  90   let Uses = [RM] in {
  91     def BL8  : IForm<18, 0, 1, (outs), (ins calltarget:$func),
  92                      "bl $func", BrB, []>;  // See Pat patterns below.
  93
  94     def BLA8 : IForm<18, 1, 1, (outs), (ins aaddr:$func),
  95                      "bla $func", BrB, [(PPCcall (i64 imm:$func))]>;
  96   }
  97   let Uses = [RM], isCodeGenOnly = 1 in {
  98     def BL8_NOP  : IForm_and_DForm_4_zero<18, 0, 1, 24,
  99                              (outs), (ins calltarget:$func),
 100                              "bl $func\n\tnop", BrB, []>;
 101
 102     def BL8_NOP_TLSGD : IForm_and_DForm_4_zero<18, 0, 1, 24,
 103                                   (outs), (ins calltarget:$func, tlsgd:$sym),
 104                                   "bl $func($sym)\n\tnop", BrB, []>;
 105
 106     def BL8_NOP_TLSLD : IForm_and_DForm_4_zero<18, 0, 1, 24,
 107                                   (outs), (ins calltarget:$func, tlsgd:$sym),
 108                                   "bl $func($sym)\n\tnop", BrB, []>;
 109
 110     def BLA8_NOP : IForm_and_DForm_4_zero<18, 1, 1, 24,
 111                              (outs), (ins aaddr:$func),
 112                              "bla $func\n\tnop", BrB,
 113                              [(PPCcall_nop (i64 imm:$func))]>;
 114   }
 115   let Uses = [CTR8, RM] in {
 116     def BCTRL8 : XLForm_2_ext<19, 528, 20, 0, 1, (outs), (ins),
 117                               "bctrl", BrB, [(PPCbctrl)]>,
 118                  Requires<[In64BitMode]>;
 119   }
 120 }
 121
 122
 123 // Calls
 124 def : Pat<(PPCcall (i64 tglobaladdr:$dst)),
 125           (BL8 tglobaladdr:$dst)>;
 126 def : Pat<(PPCcall_nop (i64 tglobaladdr:$dst)),
 127           (BL8_NOP tglobaladdr:$dst)>;
 128
 129 def : Pat<(PPCcall (i64 texternalsym:$dst)),
 130           (BL8 texternalsym:$dst)>;
 131 def : Pat<(PPCcall_nop (i64 texternalsym:$dst)),
 132           (BL8_NOP texternalsym:$dst)>;
 133
 134 // Atomic operations
 135 let usesCustomInserter = 1 in {
 136   let Defs = [CR0] in {
 137     def ATOMIC_LOAD_ADD_I64 : Pseudo<
 138       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "#ATOMIC_LOAD_ADD_I64",
 139       [(set i64:$dst, (atomic_load_add_64 xoaddr:$ptr, i64:$incr))]>;
 140     def ATOMIC_LOAD_SUB_I64 : Pseudo<
 141       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "#ATOMIC_LOAD_SUB_I64",
 142       [(set i64:$dst, (atomic_load_sub_64 xoaddr:$ptr, i64:$incr))]>;
 143     def ATOMIC_LOAD_OR_I64 : Pseudo<
 144       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "#ATOMIC_LOAD_OR_I64",
 145       [(set i64:$dst, (atomic_load_or_64 xoaddr:$ptr, i64:$incr))]>;
 146     def ATOMIC_LOAD_XOR_I64 : Pseudo<
 147       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "#ATOMIC_LOAD_XOR_I64",
 148       [(set i64:$dst, (atomic_load_xor_64 xoaddr:$ptr, i64:$incr))]>;
 149     def ATOMIC_LOAD_AND_I64 : Pseudo<
 150       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "#ATOMIC_LOAD_AND_i64",
 151       [(set i64:$dst, (atomic_load_and_64 xoaddr:$ptr, i64:$incr))]>;
 152     def ATOMIC_LOAD_NAND_I64 : Pseudo<
 153       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "#ATOMIC_LOAD_NAND_I64",
 154       [(set i64:$dst, (atomic_load_nand_64 xoaddr:$ptr, i64:$incr))]>;
 155
 156     def ATOMIC_CMP_SWAP_I64 : Pseudo<
 157       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$old, G8RC:$new), "#ATOMIC_CMP_SWAP_I64",
 158       [(set i64:$dst, (atomic_cmp_swap_64 xoaddr:$ptr, i64:$old, i64:$new))]>;
 159
 160     def ATOMIC_SWAP_I64 : Pseudo<
 161       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$new), "#ATOMIC_SWAP_I64",
 162       [(set i64:$dst, (atomic_swap_64 xoaddr:$ptr, i64:$new))]>;
 163   }
 164 }
 165
 166 // Instructions to support atomic operations
 167 def LDARX : XForm_1<31,  84, (outs G8RC:$rD), (ins memrr:$ptr),
 168                    "ldarx $rD, $ptr", LdStLDARX,
 169                    [(set i64:$rD, (PPClarx xoaddr:$ptr))]>;
 170
 171 let Defs = [CR0] in
 172 def STDCX : XForm_1<31, 214, (outs), (ins G8RC:$rS, memrr:$dst),
 173                    "stdcx. $rS, $dst", LdStSTDCX,
 174                    [(PPCstcx i64:$rS, xoaddr:$dst)]>,
 175                    isDOT;
 176
 177 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
 178 def TCRETURNdi8 :Pseudo< (outs),
 179                         (ins calltarget:$dst, i32imm:$offset),
 180                  "#TC_RETURNd8 $dst $offset",
 181                  []>;
 182
 183 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
 184 def TCRETURNai8 :Pseudo<(outs), (ins aaddr:$func, i32imm:$offset),
 185                  "#TC_RETURNa8 $func $offset",
 186                  [(PPCtc_return (i64 imm:$func), imm:$offset)]>;
 187
 188 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
 189 def TCRETURNri8 : Pseudo<(outs), (ins CTRRC8:$dst, i32imm:$offset),
 190                  "#TC_RETURNr8 $dst $offset",
 191                  []>;
 192
 193 let isCodeGenOnly = 1 in {
 194
 195 let isTerminator = 1, isBarrier = 1, PPC970_Unit = 7, isBranch = 1,
 196     isIndirectBranch = 1, isCall = 1, isReturn = 1, Uses = [CTR8, RM] in
 197 def TAILBCTR8 : XLForm_2_ext<19, 528, 20, 0, 0, (outs), (ins), "bctr", BrB, []>,
 198     Requires<[In64BitMode]>;
 199
 200
 201 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7,
 202     isBarrier = 1, isCall = 1, isReturn = 1, Uses = [RM] in
 203 def TAILB8   : IForm<18, 0, 0, (outs), (ins calltarget:$dst),
 204                   "b $dst", BrB,
 205                   []>;
 206
 207
 208 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7,
 209     isBarrier = 1, isCall = 1, isReturn = 1, Uses = [RM] in
 210 def TAILBA8   : IForm<18, 0, 0, (outs), (ins aaddr:$dst),
 211                   "ba $dst", BrB,
 212                   []>;
 213
 214 }
 215
 216 def : Pat<(PPCtc_return (i64 tglobaladdr:$dst),  imm:$imm),
 217           (TCRETURNdi8 tglobaladdr:$dst, imm:$imm)>;
 218
 219 def : Pat<(PPCtc_return (i64 texternalsym:$dst), imm:$imm),
 220           (TCRETURNdi8 texternalsym:$dst, imm:$imm)>;
 221
 222 def : Pat<(PPCtc_return CTRRC8:$dst, imm:$imm),
 223           (TCRETURNri8 CTRRC8:$dst, imm:$imm)>;
 224
 225
 226 // 64-bit CR instructions
 227 def MTCRF8 : XFXForm_5<31, 144, (outs crbitm:$FXM), (ins G8RC:$rS),
 228                       "mtcrf $FXM, $rS", BrMCRX>,
 229             PPC970_MicroCode, PPC970_Unit_CRU;
 230
 231 let isCodeGenOnly = 1 in
 232 def MFCR8pseud: XFXForm_3<31, 19, (outs G8RC:$rT), (ins crbitm:$FXM),
 233                        "#MFCR8pseud", SprMFCR>,
 234             PPC970_MicroCode, PPC970_Unit_CRU;
 235
 236 def MFCR8 : XFXForm_3<31, 19, (outs G8RC:$rT), (ins),
 237                      "mfcr $rT", SprMFCR>,
 238                      PPC970_MicroCode, PPC970_Unit_CRU;
 239
 240 let hasSideEffects = 1, isBarrier = 1, usesCustomInserter = 1 in {
 241   def EH_SjLj_SetJmp64  : Pseudo<(outs GPRC:$dst), (ins memr:$buf),
 242                             "#EH_SJLJ_SETJMP64",
 243                             [(set i32:$dst, (PPCeh_sjlj_setjmp addr:$buf))]>,
 244                           Requires<[In64BitMode]>;
 245   let isTerminator = 1 in
 246   def EH_SjLj_LongJmp64 : Pseudo<(outs), (ins memr:$buf),
 247                             "#EH_SJLJ_LONGJMP64",
 248                             [(PPCeh_sjlj_longjmp addr:$buf)]>,
 249                           Requires<[In64BitMode]>;
 250 }
 251
 252 //===----------------------------------------------------------------------===//
 253 // 64-bit SPR manipulation instrs.
 254
 255 let Uses = [CTR8] in {
 256 def MFCTR8 : XFXForm_1_ext<31, 339, 9, (outs G8RC:$rT), (ins),
 257                            "mfctr $rT", SprMFSPR>,
 258              PPC970_DGroup_First, PPC970_Unit_FXU;
 259 }
 260 let Pattern = [(PPCmtctr i64:$rS)], Defs = [CTR8] in {
 261 def MTCTR8 : XFXForm_7_ext<31, 467, 9, (outs), (ins G8RC:$rS),
 262                            "mtctr $rS", SprMTSPR>,
 263              PPC970_DGroup_First, PPC970_Unit_FXU;
 264 }
 265
 266 let Pattern = [(set i64:$rT, readcyclecounter)] in
 267 def MFTB8 : XFXForm_1_ext<31, 339, 268, (outs G8RC:$rT), (ins),
 268                           "mfspr $rT, 268", SprMFTB>,
 269             PPC970_DGroup_First, PPC970_Unit_FXU;
 270 // Note that encoding mftb using mfspr is now the preferred form,
 271 // and has been since at least ISA v2.03. The mftb instruction has
 272 // now been phased out. Using mfspr, however, is known not to work on
 273 // the POWER3.
 274
 275 let Defs = [X1], Uses = [X1] in
 276 def DYNALLOC8 : Pseudo<(outs G8RC:$result), (ins G8RC:$negsize, memri:$fpsi),"#DYNALLOC8",
 277                        [(set i64:$result,
 278                              (PPCdynalloc i64:$negsize, iaddr:$fpsi))]>;
 279
 280 let Defs = [LR8] in {
 281 def MTLR8  : XFXForm_7_ext<31, 467, 8, (outs), (ins G8RC:$rS),
 282                            "mtlr $rS", SprMTSPR>,
 283              PPC970_DGroup_First, PPC970_Unit_FXU;
 284 }
 285 let Uses = [LR8] in {
 286 def MFLR8  : XFXForm_1_ext<31, 339, 8, (outs G8RC:$rT), (ins),
 287                            "mflr $rT", SprMFSPR>,
 288              PPC970_DGroup_First, PPC970_Unit_FXU;
 289 }
 290
 291 //===----------------------------------------------------------------------===//
 292 // Fixed point instructions.
 293 //
 294
 295 let PPC970_Unit = 1 in {  // FXU Operations.
 296
 297 let isReMaterializable = 1, isAsCheapAsAMove = 1, isMoveImm = 1 in {
 298 def LI8  : DForm_2_r0<14, (outs G8RC:$rD), (ins symbolLo64:$imm),
 299                       "li $rD, $imm", IntSimple,
 300                       [(set i64:$rD, immSExt16:$imm)]>;
 301 def LIS8 : DForm_2_r0<15, (outs G8RC:$rD), (ins symbolHi64:$imm),
 302                       "lis $rD, $imm", IntSimple,
 303                       [(set i64:$rD, imm16ShiftedSExt:$imm)]>;
 304 }
 305
 306 // Logical ops.
 307 def NAND8: XForm_6<31, 476, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 308                    "nand $rA, $rS, $rB", IntSimple,
 309                    [(set i64:$rA, (not (and i64:$rS, i64:$rB)))]>;
 310 def AND8 : XForm_6<31,  28, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 311                    "and $rA, $rS, $rB", IntSimple,
 312                    [(set i64:$rA, (and i64:$rS, i64:$rB))]>;
 313 def ANDC8: XForm_6<31,  60, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 314                    "andc $rA, $rS, $rB", IntSimple,
 315                    [(set i64:$rA, (and i64:$rS, (not i64:$rB)))]>;
 316 def OR8  : XForm_6<31, 444, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 317                    "or $rA, $rS, $rB", IntSimple,
 318                    [(set i64:$rA, (or i64:$rS, i64:$rB))]>;
 319 def NOR8 : XForm_6<31, 124, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 320                    "nor $rA, $rS, $rB", IntSimple,
 321                    [(set i64:$rA, (not (or i64:$rS, i64:$rB)))]>;
 322 def ORC8 : XForm_6<31, 412, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 323                    "orc $rA, $rS, $rB", IntSimple,
 324                    [(set i64:$rA, (or i64:$rS, (not i64:$rB)))]>;
 325 def EQV8 : XForm_6<31, 284, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 326                    "eqv $rA, $rS, $rB", IntSimple,
 327                    [(set i64:$rA, (not (xor i64:$rS, i64:$rB)))]>;
 328 def XOR8 : XForm_6<31, 316, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 329                    "xor $rA, $rS, $rB", IntSimple,
 330                    [(set i64:$rA, (xor i64:$rS, i64:$rB))]>;
 331
 332 // Logical ops with immediate.
 333 def ANDIo8  : DForm_4<28, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 334                       "andi. $dst, $src1, $src2", IntGeneral,
 335                       [(set i64:$dst, (and i64:$src1, immZExt16:$src2))]>,
 336                       isDOT;
 337 def ANDISo8 : DForm_4<29, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 338                      "andis. $dst, $src1, $src2", IntGeneral,
 339                     [(set i64:$dst, (and i64:$src1, imm16ShiftedZExt:$src2))]>,
 340                      isDOT;
 341 def ORI8    : DForm_4<24, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 342                       "ori $dst, $src1, $src2", IntSimple,
 343                       [(set i64:$dst, (or i64:$src1, immZExt16:$src2))]>;
 344 def ORIS8   : DForm_4<25, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 345                       "oris $dst, $src1, $src2", IntSimple,
 346                     [(set i64:$dst, (or i64:$src1, imm16ShiftedZExt:$src2))]>;
 347 def XORI8   : DForm_4<26, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 348                       "xori $dst, $src1, $src2", IntSimple,
 349                       [(set i64:$dst, (xor i64:$src1, immZExt16:$src2))]>;
 350 def XORIS8  : DForm_4<27, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 351                       "xoris $dst, $src1, $src2", IntSimple,
 352                    [(set i64:$dst, (xor i64:$src1, imm16ShiftedZExt:$src2))]>;
 353
 354 def ADD8  : XOForm_1<31, 266, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 355                      "add $rT, $rA, $rB", IntSimple,
 356                      [(set i64:$rT, (add i64:$rA, i64:$rB))]>;
 357 // ADD8 has a special form: reg = ADD8(reg, sym@tls) for use by the
 358 // initial-exec thread-local storage model.
 359 let isCodeGenOnly = 1 in
 360 def ADD8TLS  : XOForm_1<31, 266, 0, (outs G8RC:$rT), (ins G8RC:$rA, tlsreg:$rB),
 361                         "add $rT, $rA, $rB@tls", IntSimple,
 362                         [(set i64:$rT, (add i64:$rA, tglobaltlsaddr:$rB))]>;
 363
 364 let Defs = [CARRY] in {
 365 def ADDC8 : XOForm_1<31, 10, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 366                      "addc $rT, $rA, $rB", IntGeneral,
 367                      [(set i64:$rT, (addc i64:$rA, i64:$rB))]>,
 368                      PPC970_DGroup_Cracked;
 369 def ADDIC8 : DForm_2<12, (outs G8RC:$rD), (ins G8RC:$rA, s16imm64:$imm),
 370                      "addic $rD, $rA, $imm", IntGeneral,
 371                      [(set i64:$rD, (addc i64:$rA, immSExt16:$imm))]>;
 372 }
 373 def ADDI8  : DForm_2<14, (outs G8RC:$rD), (ins G8RC_NOX0:$rA, symbolLo64:$imm),
 374                      "addi $rD, $rA, $imm", IntSimple,
 375                      [(set i64:$rD, (add i64:$rA, immSExt16:$imm))]>;
 376 def ADDIS8 : DForm_2<15, (outs G8RC:$rD), (ins G8RC_NOX0:$rA, symbolHi64:$imm),
 377                      "addis $rD, $rA, $imm", IntSimple,
 378                      [(set i64:$rD, (add i64:$rA, imm16ShiftedSExt:$imm))]>;
 379
 380 let Defs = [CARRY] in {
 381 def SUBFIC8: DForm_2< 8, (outs G8RC:$rD), (ins G8RC:$rA, s16imm64:$imm),
 382                      "subfic $rD, $rA, $imm", IntGeneral,
 383                      [(set i64:$rD, (subc immSExt16:$imm, i64:$rA))]>;
 384 def SUBFC8 : XOForm_1<31, 8, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 385                       "subfc $rT, $rA, $rB", IntGeneral,
 386                       [(set i64:$rT, (subc i64:$rB, i64:$rA))]>,
 387                       PPC970_DGroup_Cracked;
 388 }
 389 def SUBF8 : XOForm_1<31, 40, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 390                      "subf $rT, $rA, $rB", IntGeneral,
 391                      [(set i64:$rT, (sub i64:$rB, i64:$rA))]>;
 392 def NEG8    : XOForm_3<31, 104, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 393                        "neg $rT, $rA", IntSimple,
 394                        [(set i64:$rT, (ineg i64:$rA))]>;
 395 let Uses = [CARRY], Defs = [CARRY] in {
 396 def ADDE8   : XOForm_1<31, 138, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 397                        "adde $rT, $rA, $rB", IntGeneral,
 398                        [(set i64:$rT, (adde i64:$rA, i64:$rB))]>;
 399 def ADDME8  : XOForm_3<31, 234, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 400                        "addme $rT, $rA", IntGeneral,
 401                        [(set i64:$rT, (adde i64:$rA, -1))]>;
 402 def ADDZE8  : XOForm_3<31, 202, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 403                        "addze $rT, $rA", IntGeneral,
 404                        [(set i64:$rT, (adde i64:$rA, 0))]>;
 405 def SUBFE8  : XOForm_1<31, 136, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 406                        "subfe $rT, $rA, $rB", IntGeneral,
 407                        [(set i64:$rT, (sube i64:$rB, i64:$rA))]>;
 408 def SUBFME8 : XOForm_3<31, 232, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 409                        "subfme $rT, $rA", IntGeneral,
 410                        [(set i64:$rT, (sube -1, i64:$rA))]>;
 411 def SUBFZE8 : XOForm_3<31, 200, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 412                        "subfze $rT, $rA", IntGeneral,
 413                        [(set i64:$rT, (sube 0, i64:$rA))]>;
 414 }
 415
 416
 417 def MULHD : XOForm_1<31, 73, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 418                      "mulhd $rT, $rA, $rB", IntMulHW,
 419                      [(set i64:$rT, (mulhs i64:$rA, i64:$rB))]>;
 420 def MULHDU : XOForm_1<31, 9, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 421                      "mulhdu $rT, $rA, $rB", IntMulHWU,
 422                      [(set i64:$rT, (mulhu i64:$rA, i64:$rB))]>;
 423
 424 def CMPD   : XForm_16_ext<31, 0, (outs CRRC:$crD), (ins G8RC:$rA, G8RC:$rB),
 425                           "cmpd $crD, $rA, $rB", IntCompare>, isPPC64;
 426 def CMPLD  : XForm_16_ext<31, 32, (outs CRRC:$crD), (ins G8RC:$rA, G8RC:$rB),
 427                           "cmpld $crD, $rA, $rB", IntCompare>, isPPC64;
 428 def CMPDI  : DForm_5_ext<11, (outs CRRC:$crD), (ins G8RC:$rA, s16imm:$imm),
 429                          "cmpdi $crD, $rA, $imm", IntCompare>, isPPC64;
 430 def CMPLDI : DForm_6_ext<10, (outs CRRC:$dst), (ins G8RC:$src1, u16imm:$src2),
 431                          "cmpldi $dst, $src1, $src2", IntCompare>, isPPC64;
 432
 433 def SLD  : XForm_6<31,  27, (outs G8RC:$rA), (ins G8RC:$rS, GPRC:$rB),
 434                    "sld $rA, $rS, $rB", IntRotateD,
 435                    [(set i64:$rA, (PPCshl i64:$rS, i32:$rB))]>, isPPC64;
 436 def SRD  : XForm_6<31, 539, (outs G8RC:$rA), (ins G8RC:$rS, GPRC:$rB),
 437                    "srd $rA, $rS, $rB", IntRotateD,
 438                    [(set i64:$rA, (PPCsrl i64:$rS, i32:$rB))]>, isPPC64;
 439 let Defs = [CARRY] in {
 440 def SRAD : XForm_6<31, 794, (outs G8RC:$rA), (ins G8RC:$rS, GPRC:$rB),
 441                    "srad $rA, $rS, $rB", IntRotateD,
 442                    [(set i64:$rA, (PPCsra i64:$rS, i32:$rB))]>, isPPC64;
 443 }
 444
 445 def EXTSB8 : XForm_11<31, 954, (outs G8RC:$rA), (ins G8RC:$rS),
 446                       "extsb $rA, $rS", IntSimple,
 447                       [(set i64:$rA, (sext_inreg i64:$rS, i8))]>;
 448 def EXTSH8 : XForm_11<31, 922, (outs G8RC:$rA), (ins G8RC:$rS),
 449                       "extsh $rA, $rS", IntSimple,
 450                       [(set i64:$rA, (sext_inreg i64:$rS, i16))]>;
 451
 452 def EXTSW  : XForm_11<31, 986, (outs G8RC:$rA), (ins G8RC:$rS),
 453                       "extsw $rA, $rS", IntSimple,
 454                       [(set i64:$rA, (sext_inreg i64:$rS, i32))]>, isPPC64;
 455 def EXTSW_32_64 : XForm_11<31, 986, (outs G8RC:$rA), (ins GPRC:$rS),
 456                       "extsw $rA, $rS", IntSimple,
 457                       [(set i64:$rA, (sext i32:$rS))]>, isPPC64;
 458
 459 let Defs = [CARRY] in {
 460 def SRADI  : XSForm_1<31, 413, (outs G8RC:$rA), (ins G8RC:$rS, u6imm:$SH),
 461                       "sradi $rA, $rS, $SH", IntRotateDI,
 462                       [(set i64:$rA, (sra i64:$rS, (i32 imm:$SH)))]>, isPPC64;
 463 }
 464 def CNTLZD : XForm_11<31, 58, (outs G8RC:$rA), (ins G8RC:$rS),
 465                       "cntlzd $rA, $rS", IntGeneral,
 466                       [(set i64:$rA, (ctlz i64:$rS))]>;
 467 def POPCNTD : XForm_11<31, 506, (outs G8RC:$rA), (ins G8RC:$rS),
 468                       "popcntd $rA, $rS", IntGeneral,
 469                       [(set i64:$rA, (ctpop i64:$rS))]>;
 470
 471 def DIVD  : XOForm_1<31, 489, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 472                      "divd $rT, $rA, $rB", IntDivD,
 473                      [(set i64:$rT, (sdiv i64:$rA, i64:$rB))]>, isPPC64,
 474                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
 475 def DIVDU : XOForm_1<31, 457, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 476                      "divdu $rT, $rA, $rB", IntDivD,
 477                      [(set i64:$rT, (udiv i64:$rA, i64:$rB))]>, isPPC64,
 478                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
 479 def MULLD : XOForm_1<31, 233, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 480                      "mulld $rT, $rA, $rB", IntMulHD,
 481                      [(set i64:$rT, (mul i64:$rA, i64:$rB))]>, isPPC64;
 482
 483
 484 let isCommutable = 1 in {
 485 def RLDIMI : MDForm_1<30, 3,
 486                       (outs G8RC:$rA), (ins G8RC:$rSi, G8RC:$rS, u6imm:$SH, u6imm:$MB),
 487                       "rldimi $rA, $rS, $SH, $MB", IntRotateDI,
 488                       []>, isPPC64, RegConstraint<"$rSi = $rA">,
 489                       NoEncode<"$rSi">;
 490 }
 491
 492 // Rotate instructions.
 493 def RLDCL  : MDForm_1<30, 0,
 494                       (outs G8RC:$rA), (ins G8RC:$rS, GPRC:$rB, u6imm:$MBE),
 495                       "rldcl $rA, $rS, $rB, $MBE", IntRotateD,
 496                       []>, isPPC64;
 497 def RLDICL : MDForm_1<30, 0,
 498                       (outs G8RC:$rA), (ins G8RC:$rS, u6imm:$SH, u6imm:$MBE),
 499                       "rldicl $rA, $rS, $SH, $MBE", IntRotateDI,
 500                       []>, isPPC64;
 501 def RLDICR : MDForm_1<30, 1,
 502                       (outs G8RC:$rA), (ins G8RC:$rS, u6imm:$SH, u6imm:$MBE),
 503                       "rldicr $rA, $rS, $SH, $MBE", IntRotateDI,
 504                       []>, isPPC64;
 505
 506 def RLWINM8 : MForm_2<21,
 507                      (outs G8RC:$rA), (ins G8RC:$rS, u5imm:$SH, u5imm:$MB, u5imm:$ME),
 508                      "rlwinm $rA, $rS, $SH, $MB, $ME", IntGeneral,
 509                      []>;
 510
 511 def ISEL8   : AForm_4<31, 15,
 512                      (outs G8RC:$rT), (ins G8RC_NOX0:$rA, G8RC:$rB, CRBITRC:$cond),
 513                      "isel $rT, $rA, $rB, $cond", IntGeneral,
 514                      []>;
 515 }  // End FXU Operations.
 516
 517
 518 //===----------------------------------------------------------------------===//
 519 // Load/Store instructions.
 520 //
 521
 522
 523 // Sign extending loads.
 524 let canFoldAsLoad = 1, PPC970_Unit = 2 in {
 525 def LHA8: DForm_1<42, (outs G8RC:$rD), (ins memri:$src),
 526                   "lha $rD, $src", LdStLHA,
 527                   [(set i64:$rD, (sextloadi16 iaddr:$src))]>,
 528                   PPC970_DGroup_Cracked;
 529 def LWA  : DSForm_1<58, 2, (outs G8RC:$rD), (ins memrix:$src),
 530                     "lwa $rD, $src", LdStLWA,
 531                     [(set i64:$rD,
 532                           (aligned4sextloadi32 ixaddr:$src))]>, isPPC64,
 533                     PPC970_DGroup_Cracked;
 534 def LHAX8: XForm_1<31, 343, (outs G8RC:$rD), (ins memrr:$src),
 535                    "lhax $rD, $src", LdStLHA,
 536                    [(set i64:$rD, (sextloadi16 xaddr:$src))]>,
 537                    PPC970_DGroup_Cracked;
 538 def LWAX : XForm_1<31, 341, (outs G8RC:$rD), (ins memrr:$src),
 539                    "lwax $rD, $src", LdStLHA,
 540                    [(set i64:$rD, (sextloadi32 xaddr:$src))]>, isPPC64,
 541                    PPC970_DGroup_Cracked;
 542
 543 // Update forms.
 544 let mayLoad = 1 in {
 545 def LHAU8 : DForm_1<43, (outs G8RC:$rD, ptr_rc_nor0:$ea_result),
 546                     (ins memri:$addr),
 547                     "lhau $rD, $addr", LdStLHAU,
 548                     []>, RegConstraint<"$addr.reg = $ea_result">,
 549                     NoEncode<"$ea_result">;
 550 // NO LWAU!
 551
 552 def LHAUX8 : XForm_1<31, 375, (outs G8RC:$rD, ptr_rc_nor0:$ea_result),
 553                     (ins memrr:$addr),
 554                     "lhaux $rD, $addr", LdStLHAU,
 555                     []>, RegConstraint<"$addr.ptrreg = $ea_result">,
 556                     NoEncode<"$ea_result">;
 557 def LWAUX : XForm_1<31, 373, (outs G8RC:$rD, ptr_rc_nor0:$ea_result),
 558                     (ins memrr:$addr),
 559                     "lwaux $rD, $addr", LdStLHAU,
 560                     []>, RegConstraint<"$addr.ptrreg = $ea_result">,
 561                     NoEncode<"$ea_result">, isPPC64;
 562 }
 563 }
 564
 565 // Zero extending loads.
 566 let canFoldAsLoad = 1, PPC970_Unit = 2 in {
 567 def LBZ8 : DForm_1<34, (outs G8RC:$rD), (ins memri:$src),
 568                   "lbz $rD, $src", LdStLoad,
 569                   [(set i64:$rD, (zextloadi8 iaddr:$src))]>;
 570 def LHZ8 : DForm_1<40, (outs G8RC:$rD), (ins memri:$src),
 571                   "lhz $rD, $src", LdStLoad,
 572                   [(set i64:$rD, (zextloadi16 iaddr:$src))]>;
 573 def LWZ8 : DForm_1<32, (outs G8RC:$rD), (ins memri:$src),
 574                   "lwz $rD, $src", LdStLoad,
 575                   [(set i64:$rD, (zextloadi32 iaddr:$src))]>, isPPC64;
 576
 577 def LBZX8 : XForm_1<31,  87, (outs G8RC:$rD), (ins memrr:$src),
 578                    "lbzx $rD, $src", LdStLoad,
 579                    [(set i64:$rD, (zextloadi8 xaddr:$src))]>;
 580 def LHZX8 : XForm_1<31, 279, (outs G8RC:$rD), (ins memrr:$src),
 581                    "lhzx $rD, $src", LdStLoad,
 582                    [(set i64:$rD, (zextloadi16 xaddr:$src))]>;
 583 def LWZX8 : XForm_1<31,  23, (outs G8RC:$rD), (ins memrr:$src),
 584                    "lwzx $rD, $src", LdStLoad,
 585                    [(set i64:$rD, (zextloadi32 xaddr:$src))]>;
 586
 587
 588 // Update forms.
 589 let mayLoad = 1 in {
 590 def LBZU8 : DForm_1<35, (outs G8RC:$rD, ptr_rc_nor0:$ea_result), (ins memri:$addr),
 591                     "lbzu $rD, $addr", LdStLoadUpd,
 592                     []>, RegConstraint<"$addr.reg = $ea_result">,
 593                     NoEncode<"$ea_result">;
 594 def LHZU8 : DForm_1<41, (outs G8RC:$rD, ptr_rc_nor0:$ea_result), (ins memri:$addr),
 595                     "lhzu $rD, $addr", LdStLoadUpd,
 596                     []>, RegConstraint<"$addr.reg = $ea_result">,
 597                     NoEncode<"$ea_result">;
 598 def LWZU8 : DForm_1<33, (outs G8RC:$rD, ptr_rc_nor0:$ea_result), (ins memri:$addr),
 599                     "lwzu $rD, $addr", LdStLoadUpd,
 600                     []>, RegConstraint<"$addr.reg = $ea_result">,
 601                     NoEncode<"$ea_result">;
 602
 603 def LBZUX8 : XForm_1<31, 119, (outs G8RC:$rD, ptr_rc_nor0:$ea_result),
 604                    (ins memrr:$addr),
 605                    "lbzux $rD, $addr", LdStLoadUpd,
 606                    []>, RegConstraint<"$addr.ptrreg = $ea_result">,
 607                    NoEncode<"$ea_result">;
 608 def LHZUX8 : XForm_1<31, 311, (outs G8RC:$rD, ptr_rc_nor0:$ea_result),
 609                    (ins memrr:$addr),
 610                    "lhzux $rD, $addr", LdStLoadUpd,
 611                    []>, RegConstraint<"$addr.ptrreg = $ea_result">,
 612                    NoEncode<"$ea_result">;
 613 def LWZUX8 : XForm_1<31, 55, (outs G8RC:$rD, ptr_rc_nor0:$ea_result),
 614                    (ins memrr:$addr),
 615                    "lwzux $rD, $addr", LdStLoadUpd,
 616                    []>, RegConstraint<"$addr.ptrreg = $ea_result">,
 617                    NoEncode<"$ea_result">;
 618 }
 619 }
 620
 621
 622 // Full 8-byte loads.
 623 let canFoldAsLoad = 1, PPC970_Unit = 2 in {
 624 def LD   : DSForm_1<58, 0, (outs G8RC:$rD), (ins memrix:$src),
 625                     "ld $rD, $src", LdStLD,
 626                     [(set i64:$rD, (aligned4load ixaddr:$src))]>, isPPC64;
 627 // The following three definitions are selected for small code model only.
 628 // Otherwise, we need to create two instructions to form a 32-bit offset,
 629 // so we have a custom matcher for TOC_ENTRY in PPCDAGToDAGIsel::Select().
 630 def LDtoc: Pseudo<(outs G8RC:$rD), (ins tocentry:$disp, G8RC:$reg),
 631                   "#LDtoc",
 632                   [(set i64:$rD,
 633                      (PPCtoc_entry tglobaladdr:$disp, i64:$reg))]>, isPPC64;
 634 def LDtocJTI: Pseudo<(outs G8RC:$rD), (ins tocentry:$disp, G8RC:$reg),
 635                   "#LDtocJTI",
 636                   [(set i64:$rD,
 637                      (PPCtoc_entry tjumptable:$disp, i64:$reg))]>, isPPC64;
 638 def LDtocCPT: Pseudo<(outs G8RC:$rD), (ins tocentry:$disp, G8RC:$reg),
 639                   "#LDtocCPT",
 640                   [(set i64:$rD,
 641                      (PPCtoc_entry tconstpool:$disp, i64:$reg))]>, isPPC64;
 642
 643 let hasSideEffects = 1, isCodeGenOnly = 1 in {
 644 let RST = 2, DS = 2 in
 645 def LDinto_toc: DSForm_1a<58, 0, (outs), (ins G8RC:$reg),
 646                     "ld 2, 8($reg)", LdStLD,
 647                     [(PPCload_toc i64:$reg)]>, isPPC64;
 648
 649 let RST = 2, DS = 10, RA = 1 in
 650 def LDtoc_restore : DSForm_1a<58, 0, (outs), (ins),
 651                     "ld 2, 40(1)", LdStLD,
 652                     [(PPCtoc_restore)]>, isPPC64;
 653 }
 654 def LDX  : XForm_1<31,  21, (outs G8RC:$rD), (ins memrr:$src),
 655                    "ldx $rD, $src", LdStLD,
 656                    [(set i64:$rD, (load xaddr:$src))]>, isPPC64;
 657 def LDBRX : XForm_1<31,  532, (outs G8RC:$rD), (ins memrr:$src),
 658                    "ldbrx $rD, $src", LdStLoad,
 659                    [(set i64:$rD, (PPClbrx xoaddr:$src, i64))]>, isPPC64;
 660
 661 let mayLoad = 1 in
 662 def LDU  : DSForm_1<58, 1, (outs G8RC:$rD, ptr_rc_nor0:$ea_result), (ins memrix:$addr),
 663                     "ldu $rD, $addr", LdStLDU,
 664                     []>, RegConstraint<"$addr.reg = $ea_result">, isPPC64,
 665                     NoEncode<"$ea_result">;
 666
 667 def LDUX : XForm_1<31, 53, (outs G8RC:$rD, ptr_rc_nor0:$ea_result),
 668                    (ins memrr:$addr),
 669                    "ldux $rD, $addr", LdStLDU,
 670                    []>, RegConstraint<"$addr.ptrreg = $ea_result">,
 671                    NoEncode<"$ea_result">, isPPC64;
 672 }
 673
 674 def : Pat<(PPCload ixaddr:$src),
 675           (LD ixaddr:$src)>;
 676 def : Pat<(PPCload xaddr:$src),
 677           (LDX xaddr:$src)>;
 678
 679 // Support for medium and large code model.
 680 def ADDIStocHA: Pseudo<(outs G8RC:$rD), (ins G8RC_NOX0:$reg, tocentry:$disp),
 681                        "#ADDIStocHA",
 682                        [(set i64:$rD,
 683                          (PPCaddisTocHA i64:$reg, tglobaladdr:$disp))]>,
 684                        isPPC64;
 685 def LDtocL: Pseudo<(outs G8RC:$rD), (ins tocentry:$disp, G8RC_NOX0:$reg),
 686                    "#LDtocL",
 687                    [(set i64:$rD,
 688                      (PPCldTocL tglobaladdr:$disp, i64:$reg))]>, isPPC64;
 689 def ADDItocL: Pseudo<(outs G8RC:$rD), (ins G8RC_NOX0:$reg, tocentry:$disp),
 690                      "#ADDItocL",
 691                      [(set i64:$rD,
 692                        (PPCaddiTocL i64:$reg, tglobaladdr:$disp))]>, isPPC64;
 693
 694 // Support for thread-local storage.
 695 def ADDISgotTprelHA: Pseudo<(outs G8RC:$rD), (ins G8RC_NOX0:$reg, symbolHi64:$disp),
 696                          "#ADDISgotTprelHA",
 697                          [(set i64:$rD,
 698                            (PPCaddisGotTprelHA i64:$reg,
 699                                                tglobaltlsaddr:$disp))]>,
 700                   isPPC64;
 701 def LDgotTprelL: Pseudo<(outs G8RC:$rD), (ins symbolLo64:$disp, G8RC_NOX0:$reg),
 702                         "#LDgotTprelL",
 703                         [(set i64:$rD,
 704                           (PPCldGotTprelL tglobaltlsaddr:$disp, i64:$reg))]>,
 705                  isPPC64;
 706 def : Pat<(PPCaddTls i64:$in, tglobaltlsaddr:$g),
 707           (ADD8TLS $in, tglobaltlsaddr:$g)>;
 708 def ADDIStlsgdHA: Pseudo<(outs G8RC:$rD), (ins G8RC_NOX0:$reg, symbolHi64:$disp),
 709                          "#ADDIStlsgdHA",
 710                          [(set i64:$rD,
 711                            (PPCaddisTlsgdHA i64:$reg, tglobaltlsaddr:$disp))]>,
 712                   isPPC64;
 713 def ADDItlsgdL : Pseudo<(outs G8RC:$rD), (ins G8RC_NOX0:$reg, symbolLo64:$disp),
 714                        "#ADDItlsgdL",
 715                        [(set i64:$rD,
 716                          (PPCaddiTlsgdL i64:$reg, tglobaltlsaddr:$disp))]>,
 717                  isPPC64;
 718 def GETtlsADDR : Pseudo<(outs G8RC:$rD), (ins G8RC:$reg, tlsgd:$sym),
 719                         "#GETtlsADDR",
 720                         [(set i64:$rD,
 721                           (PPCgetTlsAddr i64:$reg, tglobaltlsaddr:$sym))]>,
 722                  isPPC64;
 723 def ADDIStlsldHA: Pseudo<(outs G8RC:$rD), (ins G8RC_NOX0:$reg, symbolHi64:$disp),
 724                          "#ADDIStlsldHA",
 725                          [(set i64:$rD,
 726                            (PPCaddisTlsldHA i64:$reg, tglobaltlsaddr:$disp))]>,
 727                   isPPC64;
 728 def ADDItlsldL : Pseudo<(outs G8RC:$rD), (ins G8RC_NOX0:$reg, symbolLo64:$disp),
 729                        "#ADDItlsldL",
 730                        [(set i64:$rD,
 731                          (PPCaddiTlsldL i64:$reg, tglobaltlsaddr:$disp))]>,
 732                  isPPC64;
 733 def GETtlsldADDR : Pseudo<(outs G8RC:$rD), (ins G8RC:$reg, tlsgd:$sym),
 734                           "#GETtlsldADDR",
 735                           [(set i64:$rD,
 736                             (PPCgetTlsldAddr i64:$reg, tglobaltlsaddr:$sym))]>,
 737                    isPPC64;
 738 def ADDISdtprelHA: Pseudo<(outs G8RC:$rD), (ins G8RC_NOX0:$reg, symbolHi64:$disp),
 739                           "#ADDISdtprelHA",
 740                           [(set i64:$rD,
 741                             (PPCaddisDtprelHA i64:$reg,
 742                                               tglobaltlsaddr:$disp))]>,
 743                    isPPC64;
 744 def ADDIdtprelL : Pseudo<(outs G8RC:$rD), (ins G8RC_NOX0:$reg, symbolLo64:$disp),
 745                          "#ADDIdtprelL",
 746                          [(set i64:$rD,
 747                            (PPCaddiDtprelL i64:$reg, tglobaltlsaddr:$disp))]>,
 748                   isPPC64;
 749
 750 let PPC970_Unit = 2 in {
 751 // Truncating stores.
 752 def STB8 : DForm_1<38, (outs), (ins G8RC:$rS, memri:$src),
 753                    "stb $rS, $src", LdStStore,
 754                    [(truncstorei8 i64:$rS, iaddr:$src)]>;
 755 def STH8 : DForm_1<44, (outs), (ins G8RC:$rS, memri:$src),
 756                    "sth $rS, $src", LdStStore,
 757                    [(truncstorei16 i64:$rS, iaddr:$src)]>;
 758 def STW8 : DForm_1<36, (outs), (ins G8RC:$rS, memri:$src),
 759                    "stw $rS, $src", LdStStore,
 760                    [(truncstorei32 i64:$rS, iaddr:$src)]>;
 761 def STBX8 : XForm_8<31, 215, (outs), (ins G8RC:$rS, memrr:$dst),
 762                    "stbx $rS, $dst", LdStStore,
 763                    [(truncstorei8 i64:$rS, xaddr:$dst)]>,
 764                    PPC970_DGroup_Cracked;
 765 def STHX8 : XForm_8<31, 407, (outs), (ins G8RC:$rS, memrr:$dst),
 766                    "sthx $rS, $dst", LdStStore,
 767                    [(truncstorei16 i64:$rS, xaddr:$dst)]>,
 768                    PPC970_DGroup_Cracked;
 769 def STWX8 : XForm_8<31, 151, (outs), (ins G8RC:$rS, memrr:$dst),
 770                    "stwx $rS, $dst", LdStStore,
 771                    [(truncstorei32 i64:$rS, xaddr:$dst)]>,
 772                    PPC970_DGroup_Cracked;
 773 // Normal 8-byte stores.
 774 def STD  : DSForm_1<62, 0, (outs), (ins G8RC:$rS, memrix:$dst),
 775                     "std $rS, $dst", LdStSTD,
 776                     [(aligned4store i64:$rS, ixaddr:$dst)]>, isPPC64;
 777 def STDX  : XForm_8<31, 149, (outs), (ins G8RC:$rS, memrr:$dst),
 778                    "stdx $rS, $dst", LdStSTD,
 779                    [(store i64:$rS, xaddr:$dst)]>, isPPC64,
 780                    PPC970_DGroup_Cracked;
 781 def STDBRX: XForm_8<31, 660, (outs), (ins G8RC:$rS, memrr:$dst),
 782                    "stdbrx $rS, $dst", LdStStore,
 783                    [(PPCstbrx i64:$rS, xoaddr:$dst, i64)]>, isPPC64,
 784                    PPC970_DGroup_Cracked;
 785 }
 786
 787 // Stores with Update (pre-inc).
 788 let PPC970_Unit = 2, mayStore = 1 in {
 789 def STBU8 : DForm_1<39, (outs ptr_rc_nor0:$ea_res), (ins G8RC:$rS, memri:$dst),
 790                    "stbu $rS, $dst", LdStStoreUpd, []>,
 791                    RegConstraint<"$dst.reg = $ea_res">, NoEncode<"$ea_res">;
 792 def STHU8 : DForm_1<45, (outs ptr_rc_nor0:$ea_res), (ins G8RC:$rS, memri:$dst),
 793                    "sthu $rS, $dst", LdStStoreUpd, []>,
 794                    RegConstraint<"$dst.reg = $ea_res">, NoEncode<"$ea_res">;
 795 def STWU8 : DForm_1<37, (outs ptr_rc_nor0:$ea_res), (ins G8RC:$rS, memri:$dst),
 796                    "stwu $rS, $dst", LdStStoreUpd, []>,
 797                    RegConstraint<"$dst.reg = $ea_res">, NoEncode<"$ea_res">;
 798 def STDU : DSForm_1<62, 1, (outs ptr_rc_nor0:$ea_res), (ins G8RC:$rS, memrix:$dst),
 799                    "stdu $rS, $dst", LdStSTDU, []>,
 800                    RegConstraint<"$dst.reg = $ea_res">, NoEncode<"$ea_res">,
 801                    isPPC64;
 802
 803 def STBUX8: XForm_8<31, 247, (outs ptr_rc_nor0:$ea_res), (ins G8RC:$rS, memrr:$dst),
 804                     "stbux $rS, $dst", LdStStoreUpd, []>,
 805                     RegConstraint<"$dst.ptrreg = $ea_res">, NoEncode<"$ea_res">,
 806                     PPC970_DGroup_Cracked;
 807 def STHUX8: XForm_8<31, 439, (outs ptr_rc_nor0:$ea_res), (ins G8RC:$rS, memrr:$dst),
 808                     "sthux $rS, $dst", LdStStoreUpd, []>,
 809                     RegConstraint<"$dst.ptrreg = $ea_res">, NoEncode<"$ea_res">,
 810                     PPC970_DGroup_Cracked;
 811 def STWUX8: XForm_8<31, 183, (outs ptr_rc_nor0:$ea_res), (ins G8RC:$rS, memrr:$dst),
 812                     "stwux $rS, $dst", LdStStoreUpd, []>,
 813                     RegConstraint<"$dst.ptrreg = $ea_res">, NoEncode<"$ea_res">,
 814                     PPC970_DGroup_Cracked;
 815 def STDUX : XForm_8<31, 181, (outs ptr_rc_nor0:$ea_res), (ins G8RC:$rS, memrr:$dst),
 816                     "stdux $rS, $dst", LdStSTDU, []>,
 817                     RegConstraint<"$dst.ptrreg = $ea_res">, NoEncode<"$ea_res">,
 818                     PPC970_DGroup_Cracked, isPPC64;
 819 }
 820
 821 // Patterns to match the pre-inc stores.  We can't put the patterns on
 822 // the instruction definitions directly as ISel wants the address base
 823 // and offset to be separate operands, not a single complex operand.
 824 def : Pat<(pre_truncsti8 i64:$rS, iPTR:$ptrreg, iaddroff:$ptroff),
 825           (STBU8 $rS, iaddroff:$ptroff, $ptrreg)>;
 826 def : Pat<(pre_truncsti16 i64:$rS, iPTR:$ptrreg, iaddroff:$ptroff),
 827           (STHU8 $rS, iaddroff:$ptroff, $ptrreg)>;
 828 def : Pat<(pre_truncsti32 i64:$rS, iPTR:$ptrreg, iaddroff:$ptroff),
 829           (STWU8 $rS, iaddroff:$ptroff, $ptrreg)>;
 830 def : Pat<(aligned4pre_store i64:$rS, iPTR:$ptrreg, iaddroff:$ptroff),
 831           (STDU $rS, iaddroff:$ptroff, $ptrreg)>;
 832
 833 def : Pat<(pre_truncsti8 i64:$rS, iPTR:$ptrreg, iPTR:$ptroff),
 834           (STBUX8 $rS, $ptrreg, $ptroff)>;
 835 def : Pat<(pre_truncsti16 i64:$rS, iPTR:$ptrreg, iPTR:$ptroff),
 836           (STHUX8 $rS, $ptrreg, $ptroff)>;
 837 def : Pat<(pre_truncsti32 i64:$rS, iPTR:$ptrreg, iPTR:$ptroff),
 838           (STWUX8 $rS, $ptrreg, $ptroff)>;
 839 def : Pat<(pre_store i64:$rS, iPTR:$ptrreg, iPTR:$ptroff),
 840           (STDUX $rS, $ptrreg, $ptroff)>;
 841
 842
 843 //===----------------------------------------------------------------------===//
 844 // Floating point instructions.
 845 //
 846
 847
 848 let PPC970_Unit = 3, Uses = [RM] in {  // FPU Operations.
 849 def FCFID  : XForm_26<63, 846, (outs F8RC:$frD), (ins F8RC:$frB),
 850                       "fcfid $frD, $frB", FPGeneral,
 851                       [(set f64:$frD, (PPCfcfid f64:$frB))]>, isPPC64;
 852 def FCTIDZ : XForm_26<63, 815, (outs F8RC:$frD), (ins F8RC:$frB),
 853                       "fctidz $frD, $frB", FPGeneral,
 854                       [(set f64:$frD, (PPCfctidz f64:$frB))]>, isPPC64;
 855 }
 856
 857
 858 //===----------------------------------------------------------------------===//
 859 // Instruction Patterns
 860 //
 861
 862 // Extensions and truncates to/from 32-bit regs.
 863 def : Pat<(i64 (zext i32:$in)),
 864           (RLDICL (INSERT_SUBREG (i64 (IMPLICIT_DEF)), $in, sub_32),
 865                   0, 32)>;
 866 def : Pat<(i64 (anyext i32:$in)),
 867           (INSERT_SUBREG (i64 (IMPLICIT_DEF)), $in, sub_32)>;
 868 def : Pat<(i32 (trunc i64:$in)),
 869           (EXTRACT_SUBREG $in, sub_32)>;
 870
 871 // Extending loads with i64 targets.
 872 def : Pat<(zextloadi1 iaddr:$src),
 873           (LBZ8 iaddr:$src)>;
 874 def : Pat<(zextloadi1 xaddr:$src),
 875           (LBZX8 xaddr:$src)>;
 876 def : Pat<(extloadi1 iaddr:$src),
 877           (LBZ8 iaddr:$src)>;
 878 def : Pat<(extloadi1 xaddr:$src),
 879           (LBZX8 xaddr:$src)>;
 880 def : Pat<(extloadi8 iaddr:$src),
 881           (LBZ8 iaddr:$src)>;
 882 def : Pat<(extloadi8 xaddr:$src),
 883           (LBZX8 xaddr:$src)>;
 884 def : Pat<(extloadi16 iaddr:$src),
 885           (LHZ8 iaddr:$src)>;
 886 def : Pat<(extloadi16 xaddr:$src),
 887           (LHZX8 xaddr:$src)>;
 888 def : Pat<(extloadi32 iaddr:$src),
 889           (LWZ8 iaddr:$src)>;
 890 def : Pat<(extloadi32 xaddr:$src),
 891           (LWZX8 xaddr:$src)>;
 892
 893 // Standard shifts.  These are represented separately from the real shifts above
 894 // so that we can distinguish between shifts that allow 6-bit and 7-bit shift
 895 // amounts.
 896 def : Pat<(sra i64:$rS, i32:$rB),
 897           (SRAD $rS, $rB)>;
 898 def : Pat<(srl i64:$rS, i32:$rB),
 899           (SRD $rS, $rB)>;
 900 def : Pat<(shl i64:$rS, i32:$rB),
 901           (SLD $rS, $rB)>;
 902
 903 // SHL/SRL
 904 def : Pat<(shl i64:$in, (i32 imm:$imm)),
 905           (RLDICR $in, imm:$imm, (SHL64 imm:$imm))>;
 906 def : Pat<(srl i64:$in, (i32 imm:$imm)),
 907           (RLDICL $in, (SRL64 imm:$imm), imm:$imm)>;
 908
 909 // ROTL
 910 def : Pat<(rotl i64:$in, i32:$sh),
 911           (RLDCL $in, $sh, 0)>;
 912 def : Pat<(rotl i64:$in, (i32 imm:$imm)),
 913           (RLDICL $in, imm:$imm, 0)>;
 914
 915 // Hi and Lo for Darwin Global Addresses.
 916 def : Pat<(PPChi tglobaladdr:$in, 0), (LIS8 tglobaladdr:$in)>;
 917 def : Pat<(PPClo tglobaladdr:$in, 0), (LI8  tglobaladdr:$in)>;
 918 def : Pat<(PPChi tconstpool:$in , 0), (LIS8 tconstpool:$in)>;
 919 def : Pat<(PPClo tconstpool:$in , 0), (LI8  tconstpool:$in)>;
 920 def : Pat<(PPChi tjumptable:$in , 0), (LIS8 tjumptable:$in)>;
 921 def : Pat<(PPClo tjumptable:$in , 0), (LI8  tjumptable:$in)>;
 922 def : Pat<(PPChi tblockaddress:$in, 0), (LIS8 tblockaddress:$in)>;
 923 def : Pat<(PPClo tblockaddress:$in, 0), (LI8  tblockaddress:$in)>;
 924 def : Pat<(PPChi tglobaltlsaddr:$g, i64:$in),
 925           (ADDIS8 $in, tglobaltlsaddr:$g)>;
 926 def : Pat<(PPClo tglobaltlsaddr:$g, i64:$in),
 927           (ADDI8 $in, tglobaltlsaddr:$g)>;
 928 def : Pat<(add i64:$in, (PPChi tglobaladdr:$g, 0)),
 929           (ADDIS8 $in, tglobaladdr:$g)>;
 930 def : Pat<(add i64:$in, (PPChi tconstpool:$g, 0)),
 931           (ADDIS8 $in, tconstpool:$g)>;
 932 def : Pat<(add i64:$in, (PPChi tjumptable:$g, 0)),
 933           (ADDIS8 $in, tjumptable:$g)>;
 934 def : Pat<(add i64:$in, (PPChi tblockaddress:$g, 0)),
 935           (ADDIS8 $in, tblockaddress:$g)>;
 936
 937 // Patterns to match r+r indexed loads and stores for
 938 // addresses without at least 4-byte alignment.
 939 def : Pat<(i64 (unaligned4sextloadi32 xoaddr:$src)),
 940           (LWAX xoaddr:$src)>;
 941 def : Pat<(i64 (unaligned4load xoaddr:$src)),
 942           (LDX xoaddr:$src)>;
 943 def : Pat<(unaligned4store i64:$rS, xoaddr:$dst),
 944           (STDX $rS, xoaddr:$dst)>;
 945