lib/Target/PowerPC/PPCInstr64Bit.td

   1 //===-- PPCInstr64Bit.td - The PowerPC 64-bit Support ------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the PowerPC 64-bit instructions.  These patterns are used
  11 // both when in ppc64 mode and when in "use 64-bit extensions in 32-bit" mode.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // 64-bit operands.
  17 //
  18 def s16imm64 : Operand<i64> {
  19   let PrintMethod = "printS16ImmOperand";
  20 }
  21 def u16imm64 : Operand<i64> {
  22   let PrintMethod = "printU16ImmOperand";
  23 }
  24 def symbolHi64 : Operand<i64> {
  25   let PrintMethod = "printSymbolHi";
  26   let EncoderMethod = "getHA16Encoding";
  27 }
  28 def symbolLo64 : Operand<i64> {
  29   let PrintMethod = "printSymbolLo";
  30   let EncoderMethod = "getLO16Encoding";
  31 }
  32
  33 //===----------------------------------------------------------------------===//
  34 // 64-bit transformation functions.
  35 //
  36
  37 def SHL64 : SDNodeXForm<imm, [{
  38   // Transformation function: 63 - imm
  39   return getI32Imm(63 - N->getZExtValue());
  40 }]>;
  41
  42 def SRL64 : SDNodeXForm<imm, [{
  43   // Transformation function: 64 - imm
  44   return N->getZExtValue() ? getI32Imm(64 - N->getZExtValue()) : getI32Imm(0);
  45 }]>;
  46
  47 def HI32_48 : SDNodeXForm<imm, [{
  48   // Transformation function: shift the immediate value down into the low bits.
  49   return getI32Imm((unsigned short)(N->getZExtValue() >> 32));
  50 }]>;
  51
  52 def HI48_64 : SDNodeXForm<imm, [{
  53   // Transformation function: shift the immediate value down into the low bits.
  54   return getI32Imm((unsigned short)(N->getZExtValue() >> 48));
  55 }]>;
  56
  57
  58 //===----------------------------------------------------------------------===//
  59 // Calls.
  60 //
  61
  62 let Defs = [LR8] in
  63   def MovePCtoLR8 : Pseudo<(outs), (ins), "", []>,
  64                     PPC970_Unit_BRU;
  65
  66 // Darwin ABI Calls.
  67 let isCall = 1, PPC970_Unit = 7, Defs = [LR8] in {
  68   // Convenient aliases for call instructions
  69   let Uses = [RM] in {
  70     def BL8_Darwin  : IForm<18, 0, 1,
  71                             (outs), (ins calltarget:$func, variable_ops),
  72                             "bl $func", BrB, []>;  // See Pat patterns below.
  73     def BLA8_Darwin : IForm<18, 1, 1,
  74                           (outs), (ins aaddr:$func, variable_ops),
  75                           "bla $func", BrB, [(PPCcall_Darwin (i64 imm:$func))]>;
  76   }
  77   let Uses = [CTR8, RM] in {
  78     def BCTRL8_Darwin : XLForm_2_ext<19, 528, 20, 0, 1,
  79                                   (outs), (ins variable_ops),
  80                                   "bctrl", BrB,
  81                                   [(PPCbctrl_Darwin)]>, Requires<[In64BitMode]>;
  82   }
  83 }
  84
  85 // ELF 64 ABI Calls = Darwin ABI Calls
  86 // Used to define BL8_ELF and BLA8_ELF
  87 let isCall = 1, PPC970_Unit = 7, Defs = [LR8] in {
  88   // Convenient aliases for call instructions
  89   let Uses = [RM] in {
  90     def BL8_ELF  : IForm<18, 0, 1,
  91                          (outs), (ins calltarget:$func, variable_ops),
  92                          "bl $func", BrB, []>;  // See Pat patterns below.
  93
  94     let isCodeGenOnly = 1 in
  95     def BL8_NOP_ELF  : IForm_and_DForm_4_zero<18, 0, 1, 24,
  96                              (outs), (ins calltarget:$func, variable_ops),
  97                              "bl $func\n\tnop", BrB, []>;
  98
  99     def BLA8_ELF : IForm<18, 1, 1,
 100                          (outs), (ins aaddr:$func, variable_ops),
 101                          "bla $func", BrB, [(PPCcall_SVR4 (i64 imm:$func))]>;
 102
 103     let isCodeGenOnly = 1 in
 104     def BLA8_NOP_ELF : IForm_and_DForm_4_zero<18, 1, 1, 24,
 105                              (outs), (ins aaddr:$func, variable_ops),
 106                              "bla $func\n\tnop", BrB,
 107                              [(PPCcall_nop_SVR4 (i64 imm:$func))]>;
 108   }
 109   let Uses = [X11, CTR8, RM] in {
 110     def BCTRL8_ELF : XLForm_2_ext<19, 528, 20, 0, 1,
 111                                (outs), (ins variable_ops),
 112                                "bctrl", BrB,
 113                                [(PPCbctrl_SVR4)]>, Requires<[In64BitMode]>;
 114   }
 115 }
 116
 117
 118 // Calls
 119 def : Pat<(PPCcall_Darwin (i64 tglobaladdr:$dst)),
 120           (BL8_Darwin tglobaladdr:$dst)>;
 121 def : Pat<(PPCcall_Darwin (i64 texternalsym:$dst)),
 122           (BL8_Darwin texternalsym:$dst)>;
 123
 124 def : Pat<(PPCcall_SVR4 (i64 tglobaladdr:$dst)),
 125           (BL8_ELF tglobaladdr:$dst)>;
 126 def : Pat<(PPCcall_nop_SVR4 (i64 tglobaladdr:$dst)),
 127           (BL8_NOP_ELF tglobaladdr:$dst)>;
 128
 129 def : Pat<(PPCcall_SVR4 (i64 texternalsym:$dst)),
 130           (BL8_ELF texternalsym:$dst)>;
 131 def : Pat<(PPCcall_nop_SVR4 (i64 texternalsym:$dst)),
 132           (BL8_NOP_ELF texternalsym:$dst)>;
 133
 134 def : Pat<(PPCnop),
 135           (NOP)>;
 136
 137 // Atomic operations
 138 let usesCustomInserter = 1 in {
 139   let Defs = [CR0] in {
 140     def ATOMIC_LOAD_ADD_I64 : Pseudo<
 141       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "",
 142       [(set G8RC:$dst, (atomic_load_add_64 xoaddr:$ptr, G8RC:$incr))]>;
 143     def ATOMIC_LOAD_SUB_I64 : Pseudo<
 144       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "",
 145       [(set G8RC:$dst, (atomic_load_sub_64 xoaddr:$ptr, G8RC:$incr))]>;
 146     def ATOMIC_LOAD_OR_I64 : Pseudo<
 147       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "",
 148       [(set G8RC:$dst, (atomic_load_or_64 xoaddr:$ptr, G8RC:$incr))]>;
 149     def ATOMIC_LOAD_XOR_I64 : Pseudo<
 150       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "",
 151       [(set G8RC:$dst, (atomic_load_xor_64 xoaddr:$ptr, G8RC:$incr))]>;
 152     def ATOMIC_LOAD_AND_I64 : Pseudo<
 153       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "",
 154       [(set G8RC:$dst, (atomic_load_and_64 xoaddr:$ptr, G8RC:$incr))]>;
 155     def ATOMIC_LOAD_NAND_I64 : Pseudo<
 156       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$incr), "",
 157       [(set G8RC:$dst, (atomic_load_nand_64 xoaddr:$ptr, G8RC:$incr))]>;
 158
 159     def ATOMIC_CMP_SWAP_I64 : Pseudo<
 160       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$old, G8RC:$new), "",
 161       [(set G8RC:$dst,
 162                     (atomic_cmp_swap_64 xoaddr:$ptr, G8RC:$old, G8RC:$new))]>;
 163
 164     def ATOMIC_SWAP_I64 : Pseudo<
 165       (outs G8RC:$dst), (ins memrr:$ptr, G8RC:$new), "",
 166       [(set G8RC:$dst, (atomic_swap_64 xoaddr:$ptr, G8RC:$new))]>;
 167   }
 168 }
 169
 170 // Instructions to support atomic operations
 171 def LDARX : XForm_1<31,  84, (outs G8RC:$rD), (ins memrr:$ptr),
 172                    "ldarx $rD, $ptr", LdStLDARX,
 173                    [(set G8RC:$rD, (PPClarx xoaddr:$ptr))]>;
 174
 175 let Defs = [CR0] in
 176 def STDCX : XForm_1<31, 214, (outs), (ins G8RC:$rS, memrr:$dst),
 177                    "stdcx. $rS, $dst", LdStSTDCX,
 178                    [(PPCstcx G8RC:$rS, xoaddr:$dst)]>,
 179                    isDOT;
 180
 181 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
 182 def TCRETURNdi8 :Pseudo< (outs),
 183                         (ins calltarget:$dst, i32imm:$offset, variable_ops),
 184                  "#TC_RETURNd8 $dst $offset",
 185                  []>;
 186
 187 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
 188 def TCRETURNai8 :Pseudo<(outs), (ins aaddr:$func, i32imm:$offset, variable_ops),
 189                  "#TC_RETURNa8 $func $offset",
 190                  [(PPCtc_return (i64 imm:$func), imm:$offset)]>;
 191
 192 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
 193 def TCRETURNri8 : Pseudo<(outs), (ins CTRRC8:$dst, i32imm:$offset, variable_ops),
 194                  "#TC_RETURNr8 $dst $offset",
 195                  []>;
 196
 197
 198 let isTerminator = 1, isBarrier = 1, PPC970_Unit = 7, isBranch = 1,
 199     isIndirectBranch = 1, isCall = 1, Uses = [CTR8, RM] in {
 200   let isReturn = 1 in {
 201     def TAILBCTR8 : XLForm_2_ext<19, 528, 20, 0, 0, (outs), (ins), "bctr", BrB, []>,
 202         Requires<[In64BitMode]>;
 203   }
 204
 205   def BCTR8 : XLForm_2_ext<19, 528, 20, 0, 0, (outs), (ins), "bctr", BrB, []>,
 206       Requires<[In64BitMode]>;
 207 }
 208
 209
 210 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7,
 211     isBarrier = 1, isCall = 1, isReturn = 1, Uses = [RM] in
 212 def TAILB8   : IForm<18, 0, 0, (outs), (ins calltarget:$dst),
 213                   "b $dst", BrB,
 214                   []>;
 215
 216
 217 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7,
 218     isBarrier = 1, isCall = 1, isReturn = 1, Uses = [RM] in
 219 def TAILBA8   : IForm<18, 0, 0, (outs), (ins aaddr:$dst),
 220                   "ba $dst", BrB,
 221                   []>;
 222
 223 def : Pat<(PPCtc_return (i64 tglobaladdr:$dst),  imm:$imm),
 224           (TCRETURNdi8 tglobaladdr:$dst, imm:$imm)>;
 225
 226 def : Pat<(PPCtc_return (i64 texternalsym:$dst), imm:$imm),
 227           (TCRETURNdi8 texternalsym:$dst, imm:$imm)>;
 228
 229 def : Pat<(PPCtc_return CTRRC8:$dst, imm:$imm),
 230           (TCRETURNri8 CTRRC8:$dst, imm:$imm)>;
 231
 232 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7 in {
 233   let Defs = [CTR8], Uses = [CTR8] in {
 234     def BDZ8  : IForm_ext<16, 18, 0, 0, (outs), (ins condbrtarget:$dst),
 235                          "bdz $dst",  BrB, []>;
 236     def BDNZ8 : IForm_ext<16, 16, 0, 0, (outs), (ins condbrtarget:$dst),
 237                          "bdnz $dst", BrB, []>;
 238   }
 239 }
 240
 241 // 64-but CR instructions
 242 def MTCRF8 : XFXForm_5<31, 144, (outs crbitm:$FXM), (ins G8RC:$rS),
 243                       "mtcrf $FXM, $rS", BrMCRX>,
 244             PPC970_MicroCode, PPC970_Unit_CRU;
 245
 246 def MFCR8pseud: XFXForm_3<31, 19, (outs G8RC:$rT), (ins crbitm:$FXM),
 247                        "", SprMFCR>,
 248             PPC970_MicroCode, PPC970_Unit_CRU;
 249
 250 def MFCR8 : XFXForm_3<31, 19, (outs G8RC:$rT), (ins),
 251                      "mfcr $rT", SprMFCR>,
 252                      PPC970_MicroCode, PPC970_Unit_CRU;
 253
 254 //===----------------------------------------------------------------------===//
 255 // 64-bit SPR manipulation instrs.
 256
 257 let Uses = [CTR8] in {
 258 def MFCTR8 : XFXForm_1_ext<31, 339, 9, (outs G8RC:$rT), (ins),
 259                            "mfctr $rT", SprMFSPR>,
 260              PPC970_DGroup_First, PPC970_Unit_FXU;
 261 }
 262 let Pattern = [(PPCmtctr G8RC:$rS)], Defs = [CTR8] in {
 263 def MTCTR8 : XFXForm_7_ext<31, 467, 9, (outs), (ins G8RC:$rS),
 264                            "mtctr $rS", SprMTSPR>,
 265              PPC970_DGroup_First, PPC970_Unit_FXU;
 266 }
 267
 268 let Defs = [X1], Uses = [X1] in
 269 def DYNALLOC8 : Pseudo<(outs G8RC:$result), (ins G8RC:$negsize, memri:$fpsi),"",
 270                        [(set G8RC:$result,
 271                              (PPCdynalloc G8RC:$negsize, iaddr:$fpsi))]>;
 272
 273 let Defs = [LR8] in {
 274 def MTLR8  : XFXForm_7_ext<31, 467, 8, (outs), (ins G8RC:$rS),
 275                            "mtlr $rS", SprMTSPR>,
 276              PPC970_DGroup_First, PPC970_Unit_FXU;
 277 }
 278 let Uses = [LR8] in {
 279 def MFLR8  : XFXForm_1_ext<31, 339, 8, (outs G8RC:$rT), (ins),
 280                            "mflr $rT", SprMFSPR>,
 281              PPC970_DGroup_First, PPC970_Unit_FXU;
 282 }
 283
 284 //===----------------------------------------------------------------------===//
 285 // Fixed point instructions.
 286 //
 287
 288 let PPC970_Unit = 1 in {  // FXU Operations.
 289
 290 def LI8  : DForm_2_r0<14, (outs G8RC:$rD), (ins symbolLo64:$imm),
 291                       "li $rD, $imm", IntSimple,
 292                       [(set G8RC:$rD, immSExt16:$imm)]>;
 293 def LIS8 : DForm_2_r0<15, (outs G8RC:$rD), (ins symbolHi64:$imm),
 294                       "lis $rD, $imm", IntSimple,
 295                       [(set G8RC:$rD, imm16ShiftedSExt:$imm)]>;
 296
 297 // Logical ops.
 298 def NAND8: XForm_6<31, 476, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 299                    "nand $rA, $rS, $rB", IntSimple,
 300                    [(set G8RC:$rA, (not (and G8RC:$rS, G8RC:$rB)))]>;
 301 def AND8 : XForm_6<31,  28, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 302                    "and $rA, $rS, $rB", IntSimple,
 303                    [(set G8RC:$rA, (and G8RC:$rS, G8RC:$rB))]>;
 304 def ANDC8: XForm_6<31,  60, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 305                    "andc $rA, $rS, $rB", IntSimple,
 306                    [(set G8RC:$rA, (and G8RC:$rS, (not G8RC:$rB)))]>;
 307 def OR8  : XForm_6<31, 444, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 308                    "or $rA, $rS, $rB", IntSimple,
 309                    [(set G8RC:$rA, (or G8RC:$rS, G8RC:$rB))]>;
 310 def NOR8 : XForm_6<31, 124, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 311                    "nor $rA, $rS, $rB", IntSimple,
 312                    [(set G8RC:$rA, (not (or G8RC:$rS, G8RC:$rB)))]>;
 313 def ORC8 : XForm_6<31, 412, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 314                    "orc $rA, $rS, $rB", IntSimple,
 315                    [(set G8RC:$rA, (or G8RC:$rS, (not G8RC:$rB)))]>;
 316 def EQV8 : XForm_6<31, 284, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 317                    "eqv $rA, $rS, $rB", IntSimple,
 318                    [(set G8RC:$rA, (not (xor G8RC:$rS, G8RC:$rB)))]>;
 319 def XOR8 : XForm_6<31, 316, (outs G8RC:$rA), (ins G8RC:$rS, G8RC:$rB),
 320                    "xor $rA, $rS, $rB", IntSimple,
 321                    [(set G8RC:$rA, (xor G8RC:$rS, G8RC:$rB))]>;
 322
 323 // Logical ops with immediate.
 324 def ANDIo8  : DForm_4<28, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 325                       "andi. $dst, $src1, $src2", IntGeneral,
 326                       [(set G8RC:$dst, (and G8RC:$src1, immZExt16:$src2))]>,
 327                       isDOT;
 328 def ANDISo8 : DForm_4<29, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 329                      "andis. $dst, $src1, $src2", IntGeneral,
 330                     [(set G8RC:$dst, (and G8RC:$src1,imm16ShiftedZExt:$src2))]>,
 331                      isDOT;
 332 def ORI8    : DForm_4<24, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 333                       "ori $dst, $src1, $src2", IntSimple,
 334                       [(set G8RC:$dst, (or G8RC:$src1, immZExt16:$src2))]>;
 335 def ORIS8   : DForm_4<25, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 336                       "oris $dst, $src1, $src2", IntSimple,
 337                     [(set G8RC:$dst, (or G8RC:$src1, imm16ShiftedZExt:$src2))]>;
 338 def XORI8   : DForm_4<26, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 339                       "xori $dst, $src1, $src2", IntSimple,
 340                       [(set G8RC:$dst, (xor G8RC:$src1, immZExt16:$src2))]>;
 341 def XORIS8  : DForm_4<27, (outs G8RC:$dst), (ins G8RC:$src1, u16imm:$src2),
 342                       "xoris $dst, $src1, $src2", IntSimple,
 343                    [(set G8RC:$dst, (xor G8RC:$src1, imm16ShiftedZExt:$src2))]>;
 344
 345 def ADD8  : XOForm_1<31, 266, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 346                      "add $rT, $rA, $rB", IntSimple,
 347                      [(set G8RC:$rT, (add G8RC:$rA, G8RC:$rB))]>;
 348
 349 let Defs = [CARRY] in {
 350 def ADDC8 : XOForm_1<31, 10, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 351                      "addc $rT, $rA, $rB", IntGeneral,
 352                      [(set G8RC:$rT, (addc G8RC:$rA, G8RC:$rB))]>,
 353                      PPC970_DGroup_Cracked;
 354 def ADDIC8 : DForm_2<12, (outs G8RC:$rD), (ins G8RC:$rA, s16imm64:$imm),
 355                      "addic $rD, $rA, $imm", IntGeneral,
 356                      [(set G8RC:$rD, (addc G8RC:$rA, immSExt16:$imm))]>;
 357 }
 358 def ADDI8  : DForm_2<14, (outs G8RC:$rD), (ins G8RC:$rA, s16imm64:$imm),
 359                      "addi $rD, $rA, $imm", IntSimple,
 360                      [(set G8RC:$rD, (add G8RC:$rA, immSExt16:$imm))]>;
 361 def ADDI8L  : DForm_2<14, (outs G8RC:$rD), (ins G8RC:$rA, symbolLo64:$imm),
 362                      "addi $rD, $rA, $imm", IntSimple,
 363                      [(set G8RC:$rD, (add G8RC:$rA, immSExt16:$imm))]>;
 364 def ADDIS8 : DForm_2<15, (outs G8RC:$rD), (ins G8RC:$rA, symbolHi64:$imm),
 365                      "addis $rD, $rA, $imm", IntSimple,
 366                      [(set G8RC:$rD, (add G8RC:$rA, imm16ShiftedSExt:$imm))]>;
 367
 368 let Defs = [CARRY] in {
 369 def SUBFIC8: DForm_2< 8, (outs G8RC:$rD), (ins G8RC:$rA, s16imm64:$imm),
 370                      "subfic $rD, $rA, $imm", IntGeneral,
 371                      [(set G8RC:$rD, (subc immSExt16:$imm, G8RC:$rA))]>;
 372 def SUBFC8 : XOForm_1<31, 8, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 373                       "subfc $rT, $rA, $rB", IntGeneral,
 374                       [(set G8RC:$rT, (subc G8RC:$rB, G8RC:$rA))]>,
 375                       PPC970_DGroup_Cracked;
 376 }
 377 def SUBF8 : XOForm_1<31, 40, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 378                      "subf $rT, $rA, $rB", IntGeneral,
 379                      [(set G8RC:$rT, (sub G8RC:$rB, G8RC:$rA))]>;
 380 def NEG8    : XOForm_3<31, 104, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 381                        "neg $rT, $rA", IntSimple,
 382                        [(set G8RC:$rT, (ineg G8RC:$rA))]>;
 383 let Uses = [CARRY], Defs = [CARRY] in {
 384 def ADDE8   : XOForm_1<31, 138, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 385                        "adde $rT, $rA, $rB", IntGeneral,
 386                        [(set G8RC:$rT, (adde G8RC:$rA, G8RC:$rB))]>;
 387 def ADDME8  : XOForm_3<31, 234, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 388                        "addme $rT, $rA", IntGeneral,
 389                        [(set G8RC:$rT, (adde G8RC:$rA, -1))]>;
 390 def ADDZE8  : XOForm_3<31, 202, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 391                        "addze $rT, $rA", IntGeneral,
 392                        [(set G8RC:$rT, (adde G8RC:$rA, 0))]>;
 393 def SUBFE8  : XOForm_1<31, 136, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 394                        "subfe $rT, $rA, $rB", IntGeneral,
 395                        [(set G8RC:$rT, (sube G8RC:$rB, G8RC:$rA))]>;
 396 def SUBFME8 : XOForm_3<31, 232, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 397                        "subfme $rT, $rA", IntGeneral,
 398                        [(set G8RC:$rT, (sube -1, G8RC:$rA))]>;
 399 def SUBFZE8 : XOForm_3<31, 200, 0, (outs G8RC:$rT), (ins G8RC:$rA),
 400                        "subfze $rT, $rA", IntGeneral,
 401                        [(set G8RC:$rT, (sube 0, G8RC:$rA))]>;
 402 }
 403
 404
 405 def MULHD : XOForm_1<31, 73, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 406                      "mulhd $rT, $rA, $rB", IntMulHW,
 407                      [(set G8RC:$rT, (mulhs G8RC:$rA, G8RC:$rB))]>;
 408 def MULHDU : XOForm_1<31, 9, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 409                      "mulhdu $rT, $rA, $rB", IntMulHWU,
 410                      [(set G8RC:$rT, (mulhu G8RC:$rA, G8RC:$rB))]>;
 411
 412 def CMPD   : XForm_16_ext<31, 0, (outs CRRC:$crD), (ins G8RC:$rA, G8RC:$rB),
 413                           "cmpd $crD, $rA, $rB", IntCompare>, isPPC64;
 414 def CMPLD  : XForm_16_ext<31, 32, (outs CRRC:$crD), (ins G8RC:$rA, G8RC:$rB),
 415                           "cmpld $crD, $rA, $rB", IntCompare>, isPPC64;
 416 def CMPDI  : DForm_5_ext<11, (outs CRRC:$crD), (ins G8RC:$rA, s16imm:$imm),
 417                          "cmpdi $crD, $rA, $imm", IntCompare>, isPPC64;
 418 def CMPLDI : DForm_6_ext<10, (outs CRRC:$dst), (ins G8RC:$src1, u16imm:$src2),
 419                          "cmpldi $dst, $src1, $src2", IntCompare>, isPPC64;
 420
 421 def SLD  : XForm_6<31,  27, (outs G8RC:$rA), (ins G8RC:$rS, GPRC:$rB),
 422                    "sld $rA, $rS, $rB", IntRotateD,
 423                    [(set G8RC:$rA, (PPCshl G8RC:$rS, GPRC:$rB))]>, isPPC64;
 424 def SRD  : XForm_6<31, 539, (outs G8RC:$rA), (ins G8RC:$rS, GPRC:$rB),
 425                    "srd $rA, $rS, $rB", IntRotateD,
 426                    [(set G8RC:$rA, (PPCsrl G8RC:$rS, GPRC:$rB))]>, isPPC64;
 427 let Defs = [CARRY] in {
 428 def SRAD : XForm_6<31, 794, (outs G8RC:$rA), (ins G8RC:$rS, GPRC:$rB),
 429                    "srad $rA, $rS, $rB", IntRotateD,
 430                    [(set G8RC:$rA, (PPCsra G8RC:$rS, GPRC:$rB))]>, isPPC64;
 431 }
 432
 433 def EXTSB8 : XForm_11<31, 954, (outs G8RC:$rA), (ins G8RC:$rS),
 434                       "extsb $rA, $rS", IntSimple,
 435                       [(set G8RC:$rA, (sext_inreg G8RC:$rS, i8))]>;
 436 def EXTSH8 : XForm_11<31, 922, (outs G8RC:$rA), (ins G8RC:$rS),
 437                       "extsh $rA, $rS", IntSimple,
 438                       [(set G8RC:$rA, (sext_inreg G8RC:$rS, i16))]>;
 439
 440 def EXTSW  : XForm_11<31, 986, (outs G8RC:$rA), (ins G8RC:$rS),
 441                       "extsw $rA, $rS", IntSimple,
 442                       [(set G8RC:$rA, (sext_inreg G8RC:$rS, i32))]>, isPPC64;
 443 /// EXTSW_32 - Just like EXTSW, but works on '32-bit' registers.
 444 def EXTSW_32 : XForm_11<31, 986, (outs GPRC:$rA), (ins GPRC:$rS),
 445                       "extsw $rA, $rS", IntSimple,
 446                       [(set GPRC:$rA, (PPCextsw_32 GPRC:$rS))]>, isPPC64;
 447 def EXTSW_32_64 : XForm_11<31, 986, (outs G8RC:$rA), (ins GPRC:$rS),
 448                       "extsw $rA, $rS", IntSimple,
 449                       [(set G8RC:$rA, (sext GPRC:$rS))]>, isPPC64;
 450
 451 let Defs = [CARRY] in {
 452 def SRADI  : XSForm_1<31, 413, (outs G8RC:$rA), (ins G8RC:$rS, u6imm:$SH),
 453                       "sradi $rA, $rS, $SH", IntRotateD,
 454                       [(set G8RC:$rA, (sra G8RC:$rS, (i32 imm:$SH)))]>, isPPC64;
 455 }
 456 def CNTLZD : XForm_11<31, 58, (outs G8RC:$rA), (ins G8RC:$rS),
 457                       "cntlzd $rA, $rS", IntGeneral,
 458                       [(set G8RC:$rA, (ctlz G8RC:$rS))]>;
 459
 460 def DIVD  : XOForm_1<31, 489, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 461                      "divd $rT, $rA, $rB", IntDivD,
 462                      [(set G8RC:$rT, (sdiv G8RC:$rA, G8RC:$rB))]>, isPPC64,
 463                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
 464 def DIVDU : XOForm_1<31, 457, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 465                      "divdu $rT, $rA, $rB", IntDivD,
 466                      [(set G8RC:$rT, (udiv G8RC:$rA, G8RC:$rB))]>, isPPC64,
 467                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
 468 def MULLD : XOForm_1<31, 233, 0, (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB),
 469                      "mulld $rT, $rA, $rB", IntMulHD,
 470                      [(set G8RC:$rT, (mul G8RC:$rA, G8RC:$rB))]>, isPPC64;
 471
 472
 473 let isCommutable = 1 in {
 474 def RLDIMI : MDForm_1<30, 3,
 475                       (outs G8RC:$rA), (ins G8RC:$rSi, G8RC:$rS, u6imm:$SH, u6imm:$MB),
 476                       "rldimi $rA, $rS, $SH, $MB", IntRotateD,
 477                       []>, isPPC64, RegConstraint<"$rSi = $rA">,
 478                       NoEncode<"$rSi">;
 479 }
 480
 481 // Rotate instructions.
 482 def RLDCL  : MDForm_1<30, 0,
 483                       (outs G8RC:$rA), (ins G8RC:$rS, GPRC:$rB, u6imm:$MB),
 484                       "rldcl $rA, $rS, $rB, $MB", IntRotateD,
 485                       []>, isPPC64;
 486 def RLDICL : MDForm_1<30, 0,
 487                       (outs G8RC:$rA), (ins G8RC:$rS, u6imm:$SH, u6imm:$MB),
 488                       "rldicl $rA, $rS, $SH, $MB", IntRotateD,
 489                       []>, isPPC64;
 490 def RLDICR : MDForm_1<30, 1,
 491                       (outs G8RC:$rA), (ins G8RC:$rS, u6imm:$SH, u6imm:$ME),
 492                       "rldicr $rA, $rS, $SH, $ME", IntRotateD,
 493                       []>, isPPC64;
 494
 495 def RLWINM8 : MForm_2<21,
 496                      (outs G8RC:$rA), (ins G8RC:$rS, u5imm:$SH, u5imm:$MB, u5imm:$ME),
 497                      "rlwinm $rA, $rS, $SH, $MB, $ME", IntGeneral,
 498                      []>;
 499
 500 def ISEL8   : AForm_1<31, 15,
 501                      (outs G8RC:$rT), (ins G8RC:$rA, G8RC:$rB, pred:$cond),
 502                      "isel $rT, $rA, $rB, $cond", IntGeneral,
 503                      []>;
 504 }  // End FXU Operations.
 505
 506
 507 //===----------------------------------------------------------------------===//
 508 // Load/Store instructions.
 509 //
 510
 511
 512 // Sign extending loads.
 513 let canFoldAsLoad = 1, PPC970_Unit = 2 in {
 514 def LHA8: DForm_1<42, (outs G8RC:$rD), (ins memri:$src),
 515                   "lha $rD, $src", LdStLHA,
 516                   [(set G8RC:$rD, (sextloadi16 iaddr:$src))]>,
 517                   PPC970_DGroup_Cracked;
 518 def LWA  : DSForm_1<58, 2, (outs G8RC:$rD), (ins memrix:$src),
 519                     "lwa $rD, $src", LdStLWA,
 520                     [(set G8RC:$rD, (sextloadi32 ixaddr:$src))]>, isPPC64,
 521                     PPC970_DGroup_Cracked;
 522 def LHAX8: XForm_1<31, 343, (outs G8RC:$rD), (ins memrr:$src),
 523                    "lhax $rD, $src", LdStLHA,
 524                    [(set G8RC:$rD, (sextloadi16 xaddr:$src))]>,
 525                    PPC970_DGroup_Cracked;
 526 def LWAX : XForm_1<31, 341, (outs G8RC:$rD), (ins memrr:$src),
 527                    "lwax $rD, $src", LdStLHA,
 528                    [(set G8RC:$rD, (sextloadi32 xaddr:$src))]>, isPPC64,
 529                    PPC970_DGroup_Cracked;
 530
 531 // Update forms.
 532 let mayLoad = 1 in
 533 def LHAU8 : DForm_1a<43, (outs G8RC:$rD, ptr_rc:$ea_result), (ins symbolLo:$disp,
 534                             ptr_rc:$rA),
 535                     "lhau $rD, $disp($rA)", LdStLoad,
 536                     []>, RegConstraint<"$rA = $ea_result">,
 537                     NoEncode<"$ea_result">;
 538 // NO LWAU!
 539
 540 def LHAUX8 : XForm_1<31, 375, (outs G8RC:$rD, ptr_rc:$ea_result),
 541                     (ins memrr:$addr),
 542                     "lhaux $rD, $addr", LdStLoad,
 543                     []>, RegConstraint<"$addr.offreg = $ea_result">,
 544                     NoEncode<"$ea_result">;
 545 def LWAUX : XForm_1<31, 375, (outs G8RC:$rD, ptr_rc:$ea_result),
 546                     (ins memrr:$addr),
 547                     "lwaux $rD, $addr", LdStLoad,
 548                     []>, RegConstraint<"$addr.offreg = $ea_result">,
 549                     NoEncode<"$ea_result">, isPPC64;
 550 }
 551
 552 // Zero extending loads.
 553 let canFoldAsLoad = 1, PPC970_Unit = 2 in {
 554 def LBZ8 : DForm_1<34, (outs G8RC:$rD), (ins memri:$src),
 555                   "lbz $rD, $src", LdStLoad,
 556                   [(set G8RC:$rD, (zextloadi8 iaddr:$src))]>;
 557 def LHZ8 : DForm_1<40, (outs G8RC:$rD), (ins memri:$src),
 558                   "lhz $rD, $src", LdStLoad,
 559                   [(set G8RC:$rD, (zextloadi16 iaddr:$src))]>;
 560 def LWZ8 : DForm_1<32, (outs G8RC:$rD), (ins memri:$src),
 561                   "lwz $rD, $src", LdStLoad,
 562                   [(set G8RC:$rD, (zextloadi32 iaddr:$src))]>, isPPC64;
 563
 564 def LBZX8 : XForm_1<31,  87, (outs G8RC:$rD), (ins memrr:$src),
 565                    "lbzx $rD, $src", LdStLoad,
 566                    [(set G8RC:$rD, (zextloadi8 xaddr:$src))]>;
 567 def LHZX8 : XForm_1<31, 279, (outs G8RC:$rD), (ins memrr:$src),
 568                    "lhzx $rD, $src", LdStLoad,
 569                    [(set G8RC:$rD, (zextloadi16 xaddr:$src))]>;
 570 def LWZX8 : XForm_1<31,  23, (outs G8RC:$rD), (ins memrr:$src),
 571                    "lwzx $rD, $src", LdStLoad,
 572                    [(set G8RC:$rD, (zextloadi32 xaddr:$src))]>;
 573
 574
 575 // Update forms.
 576 let mayLoad = 1 in {
 577 def LBZU8 : DForm_1<35, (outs G8RC:$rD, ptr_rc:$ea_result), (ins memri:$addr),
 578                     "lbzu $rD, $addr", LdStLoad,
 579                     []>, RegConstraint<"$addr.reg = $ea_result">,
 580                     NoEncode<"$ea_result">;
 581 def LHZU8 : DForm_1<41, (outs G8RC:$rD, ptr_rc:$ea_result), (ins memri:$addr),
 582                     "lhzu $rD, $addr", LdStLoad,
 583                     []>, RegConstraint<"$addr.reg = $ea_result">,
 584                     NoEncode<"$ea_result">;
 585 def LWZU8 : DForm_1<33, (outs G8RC:$rD, ptr_rc:$ea_result), (ins memri:$addr),
 586                     "lwzu $rD, $addr", LdStLoad,
 587                     []>, RegConstraint<"$addr.reg = $ea_result">,
 588                     NoEncode<"$ea_result">;
 589
 590 def LBZUX8 : XForm_1<31, 119, (outs G8RC:$rD, ptr_rc:$ea_result),
 591                    (ins memrr:$addr),
 592                    "lbzux $rD, $addr", LdStLoad,
 593                    []>, RegConstraint<"$addr.offreg = $ea_result">,
 594                    NoEncode<"$ea_result">;
 595 def LHZUX8 : XForm_1<31, 331, (outs G8RC:$rD, ptr_rc:$ea_result),
 596                    (ins memrr:$addr),
 597                    "lhzux $rD, $addr", LdStLoad,
 598                    []>, RegConstraint<"$addr.offreg = $ea_result">,
 599                    NoEncode<"$ea_result">;
 600 def LWZUX8 : XForm_1<31, 55, (outs G8RC:$rD, ptr_rc:$ea_result),
 601                    (ins memrr:$addr),
 602                    "lwzux $rD, $addr", LdStLoad,
 603                    []>, RegConstraint<"$addr.offreg = $ea_result">,
 604                    NoEncode<"$ea_result">;
 605 }
 606 }
 607
 608
 609 // Full 8-byte loads.
 610 let canFoldAsLoad = 1, PPC970_Unit = 2 in {
 611 def LD   : DSForm_1<58, 0, (outs G8RC:$rD), (ins memrix:$src),
 612                     "ld $rD, $src", LdStLD,
 613                     [(set G8RC:$rD, (load ixaddr:$src))]>, isPPC64;
 614 def LDtoc: Pseudo<(outs G8RC:$rD), (ins tocentry:$disp, G8RC:$reg),
 615                   "",
 616                   [(set G8RC:$rD,
 617                      (PPCtoc_entry tglobaladdr:$disp, G8RC:$reg))]>, isPPC64;
 618
 619 let hasSideEffects = 1 in {
 620 let RST = 2, DS_RA = 0 in // FIXME: Should be a pseudo.
 621 def LDinto_toc: DSForm_1<58, 0, (outs), (ins G8RC:$reg),
 622                     "ld 2, 8($reg)", LdStLD,
 623                     [(PPCload_toc G8RC:$reg)]>, isPPC64;
 624
 625 let RST = 2, DS_RA = 0 in // FIXME: Should be a pseudo.
 626 def LDtoc_restore : DSForm_1<58, 0, (outs), (ins),
 627                     "ld 2, 40(1)", LdStLD,
 628                     [(PPCtoc_restore)]>, isPPC64;
 629 }
 630 def LDX  : XForm_1<31,  21, (outs G8RC:$rD), (ins memrr:$src),
 631                    "ldx $rD, $src", LdStLD,
 632                    [(set G8RC:$rD, (load xaddr:$src))]>, isPPC64;
 633
 634 let mayLoad = 1 in
 635 def LDU  : DSForm_1<58, 1, (outs G8RC:$rD, ptr_rc:$ea_result), (ins memrix:$addr),
 636                     "ldu $rD, $addr", LdStLD,
 637                     []>, RegConstraint<"$addr.reg = $ea_result">, isPPC64,
 638                     NoEncode<"$ea_result">;
 639
 640 def LDUX : XForm_1<31, 53, (outs G8RC:$rD, ptr_rc:$ea_result),
 641                    (ins memrr:$addr),
 642                    "ldux $rD, $addr", LdStLoad,
 643                    []>, RegConstraint<"$addr.offreg = $ea_result">,
 644                    NoEncode<"$ea_result">, isPPC64;
 645 }
 646
 647 def : Pat<(PPCload ixaddr:$src),
 648           (LD ixaddr:$src)>;
 649 def : Pat<(PPCload xaddr:$src),
 650           (LDX xaddr:$src)>;
 651
 652 let PPC970_Unit = 2 in {
 653 // Truncating stores.
 654 def STB8 : DForm_1<38, (outs), (ins G8RC:$rS, memri:$src),
 655                    "stb $rS, $src", LdStStore,
 656                    [(truncstorei8 G8RC:$rS, iaddr:$src)]>;
 657 def STH8 : DForm_1<44, (outs), (ins G8RC:$rS, memri:$src),
 658                    "sth $rS, $src", LdStStore,
 659                    [(truncstorei16 G8RC:$rS, iaddr:$src)]>;
 660 def STW8 : DForm_1<36, (outs), (ins G8RC:$rS, memri:$src),
 661                    "stw $rS, $src", LdStStore,
 662                    [(truncstorei32 G8RC:$rS, iaddr:$src)]>;
 663 def STBX8 : XForm_8<31, 215, (outs), (ins G8RC:$rS, memrr:$dst),
 664                    "stbx $rS, $dst", LdStStore,
 665                    [(truncstorei8 G8RC:$rS, xaddr:$dst)]>,
 666                    PPC970_DGroup_Cracked;
 667 def STHX8 : XForm_8<31, 407, (outs), (ins G8RC:$rS, memrr:$dst),
 668                    "sthx $rS, $dst", LdStStore,
 669                    [(truncstorei16 G8RC:$rS, xaddr:$dst)]>,
 670                    PPC970_DGroup_Cracked;
 671 def STWX8 : XForm_8<31, 151, (outs), (ins G8RC:$rS, memrr:$dst),
 672                    "stwx $rS, $dst", LdStStore,
 673                    [(truncstorei32 G8RC:$rS, xaddr:$dst)]>,
 674                    PPC970_DGroup_Cracked;
 675 // Normal 8-byte stores.
 676 def STD  : DSForm_1<62, 0, (outs), (ins G8RC:$rS, memrix:$dst),
 677                     "std $rS, $dst", LdStSTD,
 678                     [(store G8RC:$rS, ixaddr:$dst)]>, isPPC64;
 679 def STDX  : XForm_8<31, 149, (outs), (ins G8RC:$rS, memrr:$dst),
 680                    "stdx $rS, $dst", LdStSTD,
 681                    [(store G8RC:$rS, xaddr:$dst)]>, isPPC64,
 682                    PPC970_DGroup_Cracked;
 683 }
 684
 685 let PPC970_Unit = 2 in {
 686
 687 def STBU8 : DForm_1a<38, (outs ptr_rc:$ea_res), (ins G8RC:$rS,
 688                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 689                     "stbu $rS, $ptroff($ptrreg)", LdStStore,
 690                     [(set ptr_rc:$ea_res,
 691                           (pre_truncsti8 G8RC:$rS, ptr_rc:$ptrreg,
 692                                          iaddroff:$ptroff))]>,
 693                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 694 def STHU8 : DForm_1a<45, (outs ptr_rc:$ea_res), (ins G8RC:$rS,
 695                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 696                     "sthu $rS, $ptroff($ptrreg)", LdStStore,
 697                     [(set ptr_rc:$ea_res,
 698                         (pre_truncsti16 G8RC:$rS, ptr_rc:$ptrreg,
 699                                         iaddroff:$ptroff))]>,
 700                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 701
 702 def STWU8 : DForm_1a<37, (outs ptr_rc:$ea_res), (ins G8RC:$rS,
 703                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 704                     "stwu $rS, $ptroff($ptrreg)", LdStStore,
 705                     [(set ptr_rc:$ea_res,
 706                           (pre_truncsti32 G8RC:$rS, ptr_rc:$ptrreg,
 707                                           iaddroff:$ptroff))]>,
 708                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 709
 710 def STDU : DSForm_1a<62, 1, (outs ptr_rc:$ea_res), (ins G8RC:$rS,
 711                                         s16immX4:$ptroff, ptr_rc:$ptrreg),
 712                     "stdu $rS, $ptroff($ptrreg)", LdStSTD,
 713                     [(set ptr_rc:$ea_res, (pre_store G8RC:$rS, ptr_rc:$ptrreg,
 714                                                      iaddroff:$ptroff))]>,
 715                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">,
 716                     isPPC64;
 717
 718
 719 def STBUX8 : XForm_8<31, 247, (outs ptr_rc:$ea_res),
 720                               (ins G8RC:$rS, ptr_rc:$ptroff, ptr_rc:$ptrreg),
 721                     "stbux $rS, $ptroff, $ptrreg", LdStStore,
 722                     [(set ptr_rc:$ea_res,
 723                        (pre_truncsti8 G8RC:$rS,
 724                                       ptr_rc:$ptrreg, xaddroff:$ptroff))]>,
 725                     RegConstraint<"$ptroff = $ea_res">, NoEncode<"$ea_res">,
 726                     PPC970_DGroup_Cracked;
 727
 728 def STHUX8 : XForm_8<31, 439, (outs ptr_rc:$ea_res),
 729                               (ins G8RC:$rS, ptr_rc:$ptroff, ptr_rc:$ptrreg),
 730                     "sthux $rS, $ptroff, $ptrreg", LdStStore,
 731                     [(set ptr_rc:$ea_res,
 732                        (pre_truncsti16 G8RC:$rS,
 733                                        ptr_rc:$ptrreg, xaddroff:$ptroff))]>,
 734                     RegConstraint<"$ptroff = $ea_res">, NoEncode<"$ea_res">,
 735                     PPC970_DGroup_Cracked;
 736
 737 def STWUX8 : XForm_8<31, 183, (outs ptr_rc:$ea_res),
 738                               (ins G8RC:$rS, ptr_rc:$ptroff, ptr_rc:$ptrreg),
 739                     "stwux $rS, $ptroff, $ptrreg", LdStStore,
 740                     [(set ptr_rc:$ea_res,
 741                        (pre_truncsti32 G8RC:$rS,
 742                                        ptr_rc:$ptrreg, xaddroff:$ptroff))]>,
 743                     RegConstraint<"$ptroff = $ea_res">, NoEncode<"$ea_res">,
 744                     PPC970_DGroup_Cracked;
 745
 746 def STDUX : XForm_8<31, 181, (outs ptr_rc:$ea_res),
 747                               (ins G8RC:$rS, ptr_rc:$ptroff, ptr_rc:$ptrreg),
 748                     "stdux $rS, $ptroff, $ptrreg", LdStStore,
 749                     [(set ptr_rc:$ea_res,
 750                        (pre_store G8RC:$rS, ptr_rc:$ptrreg, xaddroff:$ptroff))]>,
 751                     RegConstraint<"$ptroff = $ea_res">, NoEncode<"$ea_res">,
 752                     PPC970_DGroup_Cracked, isPPC64;
 753
 754 // STD_32/STDX_32 - Just like STD/STDX, but uses a '32-bit' input register.
 755 def STD_32  : DSForm_1<62, 0, (outs), (ins GPRC:$rT, memrix:$dst),
 756                        "std $rT, $dst", LdStSTD,
 757                        [(PPCstd_32  GPRC:$rT, ixaddr:$dst)]>, isPPC64;
 758 def STDX_32  : XForm_8<31, 149, (outs), (ins GPRC:$rT, memrr:$dst),
 759                        "stdx $rT, $dst", LdStSTD,
 760                        [(PPCstd_32  GPRC:$rT, xaddr:$dst)]>, isPPC64,
 761                        PPC970_DGroup_Cracked;
 762 }
 763
 764
 765
 766 //===----------------------------------------------------------------------===//
 767 // Floating point instructions.
 768 //
 769
 770
 771 let PPC970_Unit = 3, Uses = [RM] in {  // FPU Operations.
 772 def FCFID  : XForm_26<63, 846, (outs F8RC:$frD), (ins F8RC:$frB),
 773                       "fcfid $frD, $frB", FPGeneral,
 774                       [(set F8RC:$frD, (PPCfcfid F8RC:$frB))]>, isPPC64;
 775 def FCTIDZ : XForm_26<63, 815, (outs F8RC:$frD), (ins F8RC:$frB),
 776                       "fctidz $frD, $frB", FPGeneral,
 777                       [(set F8RC:$frD, (PPCfctidz F8RC:$frB))]>, isPPC64;
 778 }
 779
 780
 781 //===----------------------------------------------------------------------===//
 782 // Instruction Patterns
 783 //
 784
 785 // Extensions and truncates to/from 32-bit regs.
 786 def : Pat<(i64 (zext GPRC:$in)),
 787           (RLDICL (INSERT_SUBREG (i64 (IMPLICIT_DEF)), GPRC:$in, sub_32),
 788                   0, 32)>;
 789 def : Pat<(i64 (anyext GPRC:$in)),
 790           (INSERT_SUBREG (i64 (IMPLICIT_DEF)), GPRC:$in, sub_32)>;
 791 def : Pat<(i32 (trunc G8RC:$in)),
 792           (EXTRACT_SUBREG G8RC:$in, sub_32)>;
 793
 794 // Extending loads with i64 targets.
 795 def : Pat<(zextloadi1 iaddr:$src),
 796           (LBZ8 iaddr:$src)>;
 797 def : Pat<(zextloadi1 xaddr:$src),
 798           (LBZX8 xaddr:$src)>;
 799 def : Pat<(extloadi1 iaddr:$src),
 800           (LBZ8 iaddr:$src)>;
 801 def : Pat<(extloadi1 xaddr:$src),
 802           (LBZX8 xaddr:$src)>;
 803 def : Pat<(extloadi8 iaddr:$src),
 804           (LBZ8 iaddr:$src)>;
 805 def : Pat<(extloadi8 xaddr:$src),
 806           (LBZX8 xaddr:$src)>;
 807 def : Pat<(extloadi16 iaddr:$src),
 808           (LHZ8 iaddr:$src)>;
 809 def : Pat<(extloadi16 xaddr:$src),
 810           (LHZX8 xaddr:$src)>;
 811 def : Pat<(extloadi32 iaddr:$src),
 812           (LWZ8 iaddr:$src)>;
 813 def : Pat<(extloadi32 xaddr:$src),
 814           (LWZX8 xaddr:$src)>;
 815
 816 // Standard shifts.  These are represented separately from the real shifts above
 817 // so that we can distinguish between shifts that allow 6-bit and 7-bit shift
 818 // amounts.
 819 def : Pat<(sra G8RC:$rS, GPRC:$rB),
 820           (SRAD G8RC:$rS, GPRC:$rB)>;
 821 def : Pat<(srl G8RC:$rS, GPRC:$rB),
 822           (SRD G8RC:$rS, GPRC:$rB)>;
 823 def : Pat<(shl G8RC:$rS, GPRC:$rB),
 824           (SLD G8RC:$rS, GPRC:$rB)>;
 825
 826 // SHL/SRL
 827 def : Pat<(shl G8RC:$in, (i32 imm:$imm)),
 828           (RLDICR G8RC:$in, imm:$imm, (SHL64 imm:$imm))>;
 829 def : Pat<(srl G8RC:$in, (i32 imm:$imm)),
 830           (RLDICL G8RC:$in, (SRL64 imm:$imm), imm:$imm)>;
 831
 832 // ROTL
 833 def : Pat<(rotl G8RC:$in, GPRC:$sh),
 834           (RLDCL G8RC:$in, GPRC:$sh, 0)>;
 835 def : Pat<(rotl G8RC:$in, (i32 imm:$imm)),
 836           (RLDICL G8RC:$in, imm:$imm, 0)>;
 837
 838 // Hi and Lo for Darwin Global Addresses.
 839 def : Pat<(PPChi tglobaladdr:$in, 0), (LIS8 tglobaladdr:$in)>;
 840 def : Pat<(PPClo tglobaladdr:$in, 0), (LI8  tglobaladdr:$in)>;
 841 def : Pat<(PPChi tconstpool:$in , 0), (LIS8 tconstpool:$in)>;
 842 def : Pat<(PPClo tconstpool:$in , 0), (LI8  tconstpool:$in)>;
 843 def : Pat<(PPChi tjumptable:$in , 0), (LIS8 tjumptable:$in)>;
 844 def : Pat<(PPClo tjumptable:$in , 0), (LI8  tjumptable:$in)>;
 845 def : Pat<(PPChi tblockaddress:$in, 0), (LIS8 tblockaddress:$in)>;
 846 def : Pat<(PPClo tblockaddress:$in, 0), (LI8  tblockaddress:$in)>;
 847 def : Pat<(PPChi tglobaltlsaddr:$g, G8RC:$in),
 848           (ADDIS8 G8RC:$in, tglobaltlsaddr:$g)>;
 849 def : Pat<(PPClo tglobaltlsaddr:$g, G8RC:$in),
 850           (ADDI8L G8RC:$in, tglobaltlsaddr:$g)>;
 851 def : Pat<(add G8RC:$in, (PPChi tglobaladdr:$g, 0)),
 852           (ADDIS8 G8RC:$in, tglobaladdr:$g)>;
 853 def : Pat<(add G8RC:$in, (PPChi tconstpool:$g, 0)),
 854           (ADDIS8 G8RC:$in, tconstpool:$g)>;
 855 def : Pat<(add G8RC:$in, (PPChi tjumptable:$g, 0)),
 856           (ADDIS8 G8RC:$in, tjumptable:$g)>;
 857 def : Pat<(add G8RC:$in, (PPChi tblockaddress:$g, 0)),
 858           (ADDIS8 G8RC:$in, tblockaddress:$g)>;