lib/Target/Mips/MipsInstrInfo.td

   1 //===- MipsInstrInfo.td - Target Description for Mips Target -*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file contains the Mips implementation of the TargetInstrInfo class.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14
  15 //===----------------------------------------------------------------------===//
  16 // Mips profiles and nodes
  17 //===----------------------------------------------------------------------===//
  18
  19 def SDT_MipsJmpLink      : SDTypeProfile<0, 1, [SDTCisVT<0, iPTR>]>;
  20 def SDT_MipsCMov         : SDTypeProfile<1, 4, [SDTCisSameAs<0, 1>,
  21                                                 SDTCisSameAs<1, 2>,
  22                                                 SDTCisSameAs<3, 4>,
  23                                                 SDTCisInt<4>]>;
  24 def SDT_MipsCallSeqStart : SDCallSeqStart<[SDTCisVT<0, i32>]>;
  25 def SDT_MipsCallSeqEnd   : SDCallSeqEnd<[SDTCisVT<0, i32>, SDTCisVT<1, i32>]>;
  26 def SDT_ExtractLOHI : SDTypeProfile<1, 2, [SDTCisInt<0>, SDTCisVT<1, untyped>,
  27                                            SDTCisVT<2, i32>]>;
  28 def SDT_InsertLOHI : SDTypeProfile<1, 2, [SDTCisVT<0, untyped>,
  29                                           SDTCisVT<1, i32>,
  30                                           SDTCisSameAs<1, 2>]>;
  31 def SDT_MipsMultDiv : SDTypeProfile<1, 2, [SDTCisVT<0, untyped>, SDTCisInt<1>,
  32                                     SDTCisSameAs<1, 2>]>;
  33 def SDT_MipsMAddMSub : SDTypeProfile<1, 3,
  34                                      [SDTCisVT<0, untyped>, SDTCisSameAs<0, 3>,
  35                                       SDTCisVT<1, i32>, SDTCisSameAs<1, 2>]>;
  36 def SDT_MipsDivRem16 : SDTypeProfile<0, 2, [SDTCisInt<0>, SDTCisSameAs<0, 1>]>;
  37
  38 def SDT_MipsThreadPointer : SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;
  39
  40 def SDT_Sync             : SDTypeProfile<0, 1, [SDTCisVT<0, i32>]>;
  41
  42 def SDT_Ext : SDTypeProfile<1, 3, [SDTCisInt<0>, SDTCisSameAs<0, 1>,
  43                                    SDTCisVT<2, i32>, SDTCisSameAs<2, 3>]>;
  44 def SDT_Ins : SDTypeProfile<1, 4, [SDTCisInt<0>, SDTCisSameAs<0, 1>,
  45                                    SDTCisVT<2, i32>, SDTCisSameAs<2, 3>,
  46                                    SDTCisSameAs<0, 4>]>;
  47
  48 def SDTMipsLoadLR  : SDTypeProfile<1, 2,
  49                                    [SDTCisInt<0>, SDTCisPtrTy<1>,
  50                                     SDTCisSameAs<0, 2>]>;
  51
  52 // Call
  53 def MipsJmpLink : SDNode<"MipsISD::JmpLink",SDT_MipsJmpLink,
  54                          [SDNPHasChain, SDNPOutGlue, SDNPOptInGlue,
  55                           SDNPVariadic]>;
  56
  57 // Tail call
  58 def MipsTailCall : SDNode<"MipsISD::TailCall", SDT_MipsJmpLink,
  59                           [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
  60
  61 // Hi and Lo nodes are used to handle global addresses. Used on
  62 // MipsISelLowering to lower stuff like GlobalAddress, ExternalSymbol
  63 // static model. (nothing to do with Mips Registers Hi and Lo)
  64 def MipsHi    : SDNode<"MipsISD::Hi", SDTIntUnaryOp>;
  65 def MipsLo    : SDNode<"MipsISD::Lo", SDTIntUnaryOp>;
  66 def MipsGPRel : SDNode<"MipsISD::GPRel", SDTIntUnaryOp>;
  67
  68 // TlsGd node is used to handle General Dynamic TLS
  69 def MipsTlsGd : SDNode<"MipsISD::TlsGd", SDTIntUnaryOp>;
  70
  71 // TprelHi and TprelLo nodes are used to handle Local Exec TLS
  72 def MipsTprelHi    : SDNode<"MipsISD::TprelHi", SDTIntUnaryOp>;
  73 def MipsTprelLo    : SDNode<"MipsISD::TprelLo", SDTIntUnaryOp>;
  74
  75 // Thread pointer
  76 def MipsThreadPointer: SDNode<"MipsISD::ThreadPointer", SDT_MipsThreadPointer>;
  77
  78 // Return
  79 def MipsRet : SDNode<"MipsISD::Ret", SDTNone,
  80                      [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
  81
  82 // These are target-independent nodes, but have target-specific formats.
  83 def callseq_start : SDNode<"ISD::CALLSEQ_START", SDT_MipsCallSeqStart,
  84                            [SDNPHasChain, SDNPSideEffect, SDNPOutGlue]>;
  85 def callseq_end   : SDNode<"ISD::CALLSEQ_END", SDT_MipsCallSeqEnd,
  86                            [SDNPHasChain, SDNPSideEffect,
  87                             SDNPOptInGlue, SDNPOutGlue]>;
  88
  89 // Node used to extract integer from LO/HI register.
  90 def ExtractLOHI : SDNode<"MipsISD::ExtractLOHI", SDT_ExtractLOHI>;
  91
  92 // Node used to insert 32-bit integers to LOHI register pair.
  93 def InsertLOHI : SDNode<"MipsISD::InsertLOHI", SDT_InsertLOHI>;
  94
  95 // Mult nodes.
  96 def MipsMult  : SDNode<"MipsISD::Mult", SDT_MipsMultDiv>;
  97 def MipsMultu : SDNode<"MipsISD::Multu", SDT_MipsMultDiv>;
  98
  99 // MAdd*/MSub* nodes
 100 def MipsMAdd  : SDNode<"MipsISD::MAdd", SDT_MipsMAddMSub>;
 101 def MipsMAddu : SDNode<"MipsISD::MAddu", SDT_MipsMAddMSub>;
 102 def MipsMSub  : SDNode<"MipsISD::MSub", SDT_MipsMAddMSub>;
 103 def MipsMSubu : SDNode<"MipsISD::MSubu", SDT_MipsMAddMSub>;
 104
 105 // DivRem(u) nodes
 106 def MipsDivRem    : SDNode<"MipsISD::DivRem", SDT_MipsMultDiv>;
 107 def MipsDivRemU   : SDNode<"MipsISD::DivRemU", SDT_MipsMultDiv>;
 108 def MipsDivRem16  : SDNode<"MipsISD::DivRem16", SDT_MipsDivRem16,
 109                            [SDNPOutGlue]>;
 110 def MipsDivRemU16 : SDNode<"MipsISD::DivRemU16", SDT_MipsDivRem16,
 111                            [SDNPOutGlue]>;
 112
 113 // Target constant nodes that are not part of any isel patterns and remain
 114 // unchanged can cause instructions with illegal operands to be emitted.
 115 // Wrapper node patterns give the instruction selector a chance to replace
 116 // target constant nodes that would otherwise remain unchanged with ADDiu
 117 // nodes. Without these wrapper node patterns, the following conditional move
 118 // instrucion is emitted when function cmov2 in test/CodeGen/Mips/cmov.ll is
 119 // compiled:
 120 //  movn  %got(d)($gp), %got(c)($gp), $4
 121 // This instruction is illegal since movn can take only register operands.
 122
 123 def MipsWrapper    : SDNode<"MipsISD::Wrapper", SDTIntBinOp>;
 124
 125 def MipsSync : SDNode<"MipsISD::Sync", SDT_Sync, [SDNPHasChain,SDNPSideEffect]>;
 126
 127 def MipsExt :  SDNode<"MipsISD::Ext", SDT_Ext>;
 128 def MipsIns :  SDNode<"MipsISD::Ins", SDT_Ins>;
 129
 130 def MipsLWL : SDNode<"MipsISD::LWL", SDTMipsLoadLR,
 131                      [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 132 def MipsLWR : SDNode<"MipsISD::LWR", SDTMipsLoadLR,
 133                      [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 134 def MipsSWL : SDNode<"MipsISD::SWL", SDTStore,
 135                      [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 136 def MipsSWR : SDNode<"MipsISD::SWR", SDTStore,
 137                      [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 138 def MipsLDL : SDNode<"MipsISD::LDL", SDTMipsLoadLR,
 139                      [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 140 def MipsLDR : SDNode<"MipsISD::LDR", SDTMipsLoadLR,
 141                      [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 142 def MipsSDL : SDNode<"MipsISD::SDL", SDTStore,
 143                      [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 144 def MipsSDR : SDNode<"MipsISD::SDR", SDTStore,
 145                      [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 146
 147 //===----------------------------------------------------------------------===//
 148 // Mips Instruction Predicate Definitions.
 149 //===----------------------------------------------------------------------===//
 150 def HasSEInReg  :     Predicate<"Subtarget.hasSEInReg()">,
 151                       AssemblerPredicate<"FeatureSEInReg">;
 152 def HasBitCount :     Predicate<"Subtarget.hasBitCount()">,
 153                       AssemblerPredicate<"FeatureBitCount">;
 154 def HasSwap     :     Predicate<"Subtarget.hasSwap()">,
 155                       AssemblerPredicate<"FeatureSwap">;
 156 def HasCondMov  :     Predicate<"Subtarget.hasCondMov()">,
 157                       AssemblerPredicate<"FeatureCondMov">;
 158 def HasFPIdx    :     Predicate<"Subtarget.hasFPIdx()">,
 159                       AssemblerPredicate<"FeatureFPIdx">;
 160 def HasMips32    :    Predicate<"Subtarget.hasMips32()">,
 161                       AssemblerPredicate<"FeatureMips32">;
 162 def HasMips32r2  :    Predicate<"Subtarget.hasMips32r2()">,
 163                       AssemblerPredicate<"FeatureMips32r2">;
 164 def HasMips64    :    Predicate<"Subtarget.hasMips64()">,
 165                       AssemblerPredicate<"FeatureMips64">;
 166 def NotMips64    :    Predicate<"!Subtarget.hasMips64()">,
 167                       AssemblerPredicate<"!FeatureMips64">;
 168 def HasMips64r2  :    Predicate<"Subtarget.hasMips64r2()">,
 169                       AssemblerPredicate<"FeatureMips64r2">;
 170 def IsN64       :     Predicate<"Subtarget.isABI_N64()">,
 171                       AssemblerPredicate<"FeatureN64">;
 172 def NotN64      :     Predicate<"!Subtarget.isABI_N64()">,
 173                       AssemblerPredicate<"!FeatureN64">;
 174 def InMips16Mode :    Predicate<"Subtarget.inMips16Mode()">,
 175                       AssemblerPredicate<"FeatureMips16">;
 176 def RelocStatic :     Predicate<"TM.getRelocationModel() == Reloc::Static">,
 177                       AssemblerPredicate<"FeatureMips32">;
 178 def RelocPIC    :     Predicate<"TM.getRelocationModel() == Reloc::PIC_">,
 179                       AssemblerPredicate<"FeatureMips32">;
 180 def NoNaNsFPMath :    Predicate<"TM.Options.NoNaNsFPMath">,
 181                       AssemblerPredicate<"FeatureMips32">;
 182 def HasStdEnc :       Predicate<"Subtarget.hasStandardEncoding()">,
 183                       AssemblerPredicate<"!FeatureMips16">;
 184 def NotDSP :          Predicate<"!Subtarget.hasDSP()">;
 185
 186 class MipsPat<dag pattern, dag result> : Pat<pattern, result> {
 187   let Predicates = [HasStdEnc];
 188 }
 189
 190 class IsCommutable {
 191   bit isCommutable = 1;
 192 }
 193
 194 class IsBranch {
 195   bit isBranch = 1;
 196 }
 197
 198 class IsReturn {
 199   bit isReturn = 1;
 200 }
 201
 202 class IsCall {
 203   bit isCall = 1;
 204 }
 205
 206 class IsTailCall {
 207   bit isCall = 1;
 208   bit isTerminator = 1;
 209   bit isReturn = 1;
 210   bit isBarrier = 1;
 211   bit hasExtraSrcRegAllocReq = 1;
 212   bit isCodeGenOnly = 1;
 213 }
 214
 215 class IsAsCheapAsAMove {
 216   bit isAsCheapAsAMove = 1;
 217 }
 218
 219 class NeverHasSideEffects {
 220   bit neverHasSideEffects = 1;
 221 }
 222
 223 //===----------------------------------------------------------------------===//
 224 // Instruction format superclass
 225 //===----------------------------------------------------------------------===//
 226
 227 include "MipsInstrFormats.td"
 228
 229 //===----------------------------------------------------------------------===//
 230 // Mips Operand, Complex Patterns and Transformations Definitions.
 231 //===----------------------------------------------------------------------===//
 232
 233 // Instruction operand types
 234 def jmptarget   : Operand<OtherVT> {
 235   let EncoderMethod = "getJumpTargetOpValue";
 236 }
 237 def brtarget    : Operand<OtherVT> {
 238   let EncoderMethod = "getBranchTargetOpValue";
 239   let OperandType = "OPERAND_PCREL";
 240   let DecoderMethod = "DecodeBranchTarget";
 241 }
 242 def calltarget  : Operand<iPTR> {
 243   let EncoderMethod = "getJumpTargetOpValue";
 244 }
 245 def calltarget64: Operand<i64>;
 246 def simm16      : Operand<i32> {
 247   let DecoderMethod= "DecodeSimm16";
 248 }
 249
 250 def simm20      : Operand<i32> {
 251 }
 252
 253 def uimm20      : Operand<i32> {
 254 }
 255
 256 def uimm10      : Operand<i32> {
 257 }
 258
 259 def simm16_64   : Operand<i64>;
 260 def shamt       : Operand<i32>;
 261
 262 // Unsigned Operand
 263 def uimm16      : Operand<i32> {
 264   let PrintMethod = "printUnsignedImm";
 265 }
 266
 267 def MipsMemAsmOperand : AsmOperandClass {
 268   let Name = "Mem";
 269   let ParserMethod = "parseMemOperand";
 270 }
 271
 272 // Address operand
 273 def mem : Operand<i32> {
 274   let PrintMethod = "printMemOperand";
 275   let MIOperandInfo = (ops CPURegs, simm16);
 276   let EncoderMethod = "getMemEncoding";
 277   let ParserMatchClass = MipsMemAsmOperand;
 278   let OperandType = "OPERAND_MEMORY";
 279 }
 280
 281 def mem64 : Operand<i64> {
 282   let PrintMethod = "printMemOperand";
 283   let MIOperandInfo = (ops CPU64Regs, simm16_64);
 284   let EncoderMethod = "getMemEncoding";
 285   let ParserMatchClass = MipsMemAsmOperand;
 286   let OperandType = "OPERAND_MEMORY";
 287 }
 288
 289 def mem_ea : Operand<i32> {
 290   let PrintMethod = "printMemOperandEA";
 291   let MIOperandInfo = (ops CPURegs, simm16);
 292   let EncoderMethod = "getMemEncoding";
 293   let OperandType = "OPERAND_MEMORY";
 294 }
 295
 296 def mem_ea_64 : Operand<i64> {
 297   let PrintMethod = "printMemOperandEA";
 298   let MIOperandInfo = (ops CPU64Regs, simm16_64);
 299   let EncoderMethod = "getMemEncoding";
 300   let OperandType = "OPERAND_MEMORY";
 301 }
 302
 303 // size operand of ext instruction
 304 def size_ext : Operand<i32> {
 305   let EncoderMethod = "getSizeExtEncoding";
 306   let DecoderMethod = "DecodeExtSize";
 307 }
 308
 309 // size operand of ins instruction
 310 def size_ins : Operand<i32> {
 311   let EncoderMethod = "getSizeInsEncoding";
 312   let DecoderMethod = "DecodeInsSize";
 313 }
 314
 315 // Transformation Function - get the lower 16 bits.
 316 def LO16 : SDNodeXForm<imm, [{
 317   return getImm(N, N->getZExtValue() & 0xFFFF);
 318 }]>;
 319
 320 // Transformation Function - get the higher 16 bits.
 321 def HI16 : SDNodeXForm<imm, [{
 322   return getImm(N, (N->getZExtValue() >> 16) & 0xFFFF);
 323 }]>;
 324
 325 // Plus 1.
 326 def Plus1 : SDNodeXForm<imm, [{ return getImm(N, N->getSExtValue() + 1); }]>;
 327
 328 // Node immediate fits as 16-bit sign extended on target immediate.
 329 // e.g. addi, andi
 330 def immSExt8  : PatLeaf<(imm), [{ return isInt<8>(N->getSExtValue()); }]>;
 331
 332 // Node immediate fits as 16-bit sign extended on target immediate.
 333 // e.g. addi, andi
 334 def immSExt16  : PatLeaf<(imm), [{ return isInt<16>(N->getSExtValue()); }]>;
 335
 336 // Node immediate fits as 15-bit sign extended on target immediate.
 337 // e.g. addi, andi
 338 def immSExt15  : PatLeaf<(imm), [{ return isInt<15>(N->getSExtValue()); }]>;
 339
 340 // Node immediate fits as 16-bit zero extended on target immediate.
 341 // The LO16 param means that only the lower 16 bits of the node
 342 // immediate are caught.
 343 // e.g. addiu, sltiu
 344 def immZExt16  : PatLeaf<(imm), [{
 345   if (N->getValueType(0) == MVT::i32)
 346     return (uint32_t)N->getZExtValue() == (unsigned short)N->getZExtValue();
 347   else
 348     return (uint64_t)N->getZExtValue() == (unsigned short)N->getZExtValue();
 349 }], LO16>;
 350
 351 // Immediate can be loaded with LUi (32-bit int with lower 16-bit cleared).
 352 def immLow16Zero : PatLeaf<(imm), [{
 353   int64_t Val = N->getSExtValue();
 354   return isInt<32>(Val) && !(Val & 0xffff);
 355 }]>;
 356
 357 // shamt field must fit in 5 bits.
 358 def immZExt5 : ImmLeaf<i32, [{return Imm == (Imm & 0x1f);}]>;
 359
 360 // True if (N + 1) fits in 16-bit field.
 361 def immSExt16Plus1 : PatLeaf<(imm), [{
 362   return isInt<17>(N->getSExtValue()) && isInt<16>(N->getSExtValue() + 1);
 363 }]>;
 364
 365 // Mips Address Mode! SDNode frameindex could possibily be a match
 366 // since load and store instructions from stack used it.
 367 def addr :
 368   ComplexPattern<iPTR, 2, "selectIntAddr", [frameindex]>;
 369
 370 def addrRegImm :
 371   ComplexPattern<iPTR, 2, "selectAddrRegImm", [frameindex]>;
 372
 373 def addrDefault :
 374   ComplexPattern<iPTR, 2, "selectAddrDefault", [frameindex]>;
 375
 376 //===----------------------------------------------------------------------===//
 377 // Instructions specific format
 378 //===----------------------------------------------------------------------===//
 379
 380 // Arithmetic and logical instructions with 3 register operands.
 381 class ArithLogicR<string opstr, RegisterOperand RO, bit isComm = 0,
 382                   InstrItinClass Itin = NoItinerary,
 383                   SDPatternOperator OpNode = null_frag>:
 384   InstSE<(outs RO:$rd), (ins RO:$rs, RO:$rt),
 385          !strconcat(opstr, "\t$rd, $rs, $rt"),
 386          [(set RO:$rd, (OpNode RO:$rs, RO:$rt))], Itin, FrmR, opstr> {
 387   let isCommutable = isComm;
 388   let isReMaterializable = 1;
 389 }
 390
 391 // Arithmetic and logical instructions with 2 register operands.
 392 class ArithLogicI<string opstr, Operand Od, RegisterOperand RO,
 393                   InstrItinClass Itin = NoItinerary,
 394                   SDPatternOperator imm_type = null_frag,
 395                   SDPatternOperator OpNode = null_frag> :
 396   InstSE<(outs RO:$rt), (ins RO:$rs, Od:$imm16),
 397          !strconcat(opstr, "\t$rt, $rs, $imm16"),
 398          [(set RO:$rt, (OpNode RO:$rs, imm_type:$imm16))],
 399          Itin, FrmI, opstr> {
 400   let isReMaterializable = 1;
 401   let TwoOperandAliasConstraint = "$rs = $rt";
 402 }
 403
 404 // Arithmetic Multiply ADD/SUB
 405 class MArithR<string opstr, bit isComm = 0> :
 406   InstSE<(outs), (ins CPURegsOpnd:$rs, CPURegsOpnd:$rt),
 407          !strconcat(opstr, "\t$rs, $rt"), [], IIImult, FrmR> {
 408   let Defs = [HI, LO];
 409   let Uses = [HI, LO];
 410   let isCommutable = isComm;
 411 }
 412
 413 //  Logical
 414 class LogicNOR<string opstr, RegisterOperand RC>:
 415   InstSE<(outs RC:$rd), (ins RC:$rs, RC:$rt),
 416          !strconcat(opstr, "\t$rd, $rs, $rt"),
 417          [(set RC:$rd, (not (or RC:$rs, RC:$rt)))], IIArith, FrmR, opstr> {
 418   let isCommutable = 1;
 419 }
 420
 421 // Shifts
 422 class shift_rotate_imm<string opstr, Operand ImmOpnd,
 423                        RegisterOperand RC, SDPatternOperator OpNode = null_frag,
 424                        SDPatternOperator PF = null_frag> :
 425   InstSE<(outs RC:$rd), (ins RC:$rt, ImmOpnd:$shamt),
 426          !strconcat(opstr, "\t$rd, $rt, $shamt"),
 427          [(set RC:$rd, (OpNode RC:$rt, PF:$shamt))], IIArith, FrmR, opstr>;
 428
 429 class shift_rotate_reg<string opstr, RegisterOperand RC,
 430                        SDPatternOperator OpNode = null_frag>:
 431   InstSE<(outs RC:$rd), (ins RC:$rt, CPURegsOpnd:$rs),
 432          !strconcat(opstr, "\t$rd, $rt, $rs"),
 433          [(set RC:$rd, (OpNode RC:$rt, CPURegsOpnd:$rs))], IIArith, FrmR, opstr>;
 434
 435 // Load Upper Imediate
 436 class LoadUpper<string opstr, RegisterClass RC, Operand Imm>:
 437   InstSE<(outs RC:$rt), (ins Imm:$imm16), !strconcat(opstr, "\t$rt, $imm16"),
 438          [], IIArith, FrmI>, IsAsCheapAsAMove {
 439   let neverHasSideEffects = 1;
 440   let isReMaterializable = 1;
 441 }
 442
 443 class FMem<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern,
 444           InstrItinClass itin>: FFI<op, outs, ins, asmstr, pattern> {
 445   bits<21> addr;
 446   let Inst{25-21} = addr{20-16};
 447   let Inst{15-0}  = addr{15-0};
 448   let DecoderMethod = "DecodeMem";
 449 }
 450
 451 // Memory Load/Store
 452 class Load<string opstr, SDPatternOperator OpNode, RegisterClass RC,
 453            InstrItinClass Itin, Operand MemOpnd, ComplexPattern Addr,
 454            string ofsuffix> :
 455   InstSE<(outs RC:$rt), (ins MemOpnd:$addr), !strconcat(opstr, "\t$rt, $addr"),
 456          [(set RC:$rt, (OpNode Addr:$addr))], NoItinerary, FrmI,
 457          !strconcat(opstr, ofsuffix)> {
 458   let DecoderMethod = "DecodeMem";
 459   let canFoldAsLoad = 1;
 460   let mayLoad = 1;
 461 }
 462
 463 class Store<string opstr, SDPatternOperator OpNode, RegisterClass RC,
 464             InstrItinClass Itin, Operand MemOpnd, ComplexPattern Addr,
 465             string ofsuffix> :
 466   InstSE<(outs), (ins RC:$rt, MemOpnd:$addr), !strconcat(opstr, "\t$rt, $addr"),
 467          [(OpNode RC:$rt, Addr:$addr)], NoItinerary, FrmI,
 468          !strconcat(opstr, ofsuffix)> {
 469   let DecoderMethod = "DecodeMem";
 470   let mayStore = 1;
 471 }
 472
 473 multiclass LoadM<string opstr, RegisterClass RC,
 474                  SDPatternOperator OpNode = null_frag,
 475                  InstrItinClass Itin = NoItinerary,
 476                  ComplexPattern Addr = addr> {
 477   def NAME : Load<opstr, OpNode, RC, Itin, mem, Addr, "">,
 478              Requires<[NotN64, HasStdEnc]>;
 479   def _P8  : Load<opstr, OpNode, RC, Itin, mem64, Addr, "_p8">,
 480              Requires<[IsN64, HasStdEnc]> {
 481     let DecoderNamespace = "Mips64";
 482     let isCodeGenOnly = 1;
 483   }
 484 }
 485
 486 multiclass StoreM<string opstr, RegisterClass RC,
 487                   SDPatternOperator OpNode = null_frag,
 488                   InstrItinClass Itin = NoItinerary,
 489                   ComplexPattern Addr = addr> {
 490   def NAME : Store<opstr, OpNode, RC, Itin, mem, Addr, "">,
 491              Requires<[NotN64, HasStdEnc]>;
 492   def _P8  : Store<opstr, OpNode, RC, Itin, mem64, Addr, "_p8">,
 493              Requires<[IsN64, HasStdEnc]> {
 494     let DecoderNamespace = "Mips64";
 495     let isCodeGenOnly = 1;
 496   }
 497 }
 498
 499 // Load/Store Left/Right
 500 let canFoldAsLoad = 1 in
 501 class LoadLeftRight<string opstr, SDNode OpNode, RegisterClass RC,
 502                     Operand MemOpnd> :
 503   InstSE<(outs RC:$rt), (ins MemOpnd:$addr, RC:$src),
 504          !strconcat(opstr, "\t$rt, $addr"),
 505          [(set RC:$rt, (OpNode addr:$addr, RC:$src))], NoItinerary, FrmI> {
 506   let DecoderMethod = "DecodeMem";
 507   string Constraints = "$src = $rt";
 508 }
 509
 510 class StoreLeftRight<string opstr, SDNode OpNode, RegisterClass RC,
 511                      Operand MemOpnd>:
 512   InstSE<(outs), (ins RC:$rt, MemOpnd:$addr), !strconcat(opstr, "\t$rt, $addr"),
 513          [(OpNode RC:$rt, addr:$addr)], NoItinerary, FrmI> {
 514   let DecoderMethod = "DecodeMem";
 515 }
 516
 517 multiclass LoadLeftRightM<string opstr, SDNode OpNode, RegisterClass RC> {
 518   def NAME : LoadLeftRight<opstr, OpNode, RC, mem>,
 519              Requires<[NotN64, HasStdEnc]>;
 520   def _P8  : LoadLeftRight<opstr, OpNode, RC, mem64>,
 521              Requires<[IsN64, HasStdEnc]> {
 522     let DecoderNamespace = "Mips64";
 523     let isCodeGenOnly = 1;
 524   }
 525 }
 526
 527 multiclass StoreLeftRightM<string opstr, SDNode OpNode, RegisterClass RC> {
 528   def NAME : StoreLeftRight<opstr, OpNode, RC, mem>,
 529              Requires<[NotN64, HasStdEnc]>;
 530   def _P8  : StoreLeftRight<opstr, OpNode, RC, mem64>,
 531              Requires<[IsN64, HasStdEnc]> {
 532     let DecoderNamespace = "Mips64";
 533     let isCodeGenOnly = 1;
 534   }
 535 }
 536
 537 // Conditional Branch
 538 class CBranch<string opstr, PatFrag cond_op, RegisterOperand RC> :
 539   InstSE<(outs), (ins RC:$rs, RC:$rt, brtarget:$offset),
 540          !strconcat(opstr, "\t$rs, $rt, $offset"),
 541          [(brcond (i32 (cond_op RC:$rs, RC:$rt)), bb:$offset)], IIBranch,
 542          FrmI> {
 543   let isBranch = 1;
 544   let isTerminator = 1;
 545   let hasDelaySlot = 1;
 546   let Defs = [AT];
 547 }
 548
 549 class CBranchZero<string opstr, PatFrag cond_op, RegisterOperand RC> :
 550   InstSE<(outs), (ins RC:$rs, brtarget:$offset),
 551          !strconcat(opstr, "\t$rs, $offset"),
 552          [(brcond (i32 (cond_op RC:$rs, 0)), bb:$offset)], IIBranch, FrmI> {
 553   let isBranch = 1;
 554   let isTerminator = 1;
 555   let hasDelaySlot = 1;
 556   let Defs = [AT];
 557 }
 558
 559 // SetCC
 560 class SetCC_R<string opstr, PatFrag cond_op, RegisterClass RC> :
 561   InstSE<(outs CPURegsOpnd:$rd), (ins RC:$rs, RC:$rt),
 562          !strconcat(opstr, "\t$rd, $rs, $rt"),
 563          [(set CPURegsOpnd:$rd, (cond_op RC:$rs, RC:$rt))],
 564          IIslt, FrmR, opstr>;
 565
 566 class SetCC_I<string opstr, PatFrag cond_op, Operand Od, PatLeaf imm_type,
 567               RegisterClass RC>:
 568   InstSE<(outs CPURegsOpnd:$rt), (ins RC:$rs, Od:$imm16),
 569          !strconcat(opstr, "\t$rt, $rs, $imm16"),
 570          [(set CPURegsOpnd:$rt, (cond_op RC:$rs, imm_type:$imm16))],
 571          IIslt, FrmI, opstr>;
 572
 573 // Jump
 574 class JumpFJ<DAGOperand opnd, string opstr, SDPatternOperator operator,
 575              SDPatternOperator targetoperator> :
 576   InstSE<(outs), (ins opnd:$target), !strconcat(opstr, "\t$target"),
 577          [(operator targetoperator:$target)], IIBranch, FrmJ> {
 578   let isTerminator=1;
 579   let isBarrier=1;
 580   let hasDelaySlot = 1;
 581   let DecoderMethod = "DecodeJumpTarget";
 582   let Defs = [AT];
 583 }
 584
 585 // Unconditional branch
 586 class UncondBranch<string opstr> :
 587   InstSE<(outs), (ins brtarget:$offset), !strconcat(opstr, "\t$offset"),
 588          [(br bb:$offset)], IIBranch, FrmI> {
 589   let isBranch = 1;
 590   let isTerminator = 1;
 591   let isBarrier = 1;
 592   let hasDelaySlot = 1;
 593   let Predicates = [RelocPIC, HasStdEnc];
 594   let Defs = [AT];
 595 }
 596
 597 // Base class for indirect branch and return instruction classes.
 598 let isTerminator=1, isBarrier=1, hasDelaySlot = 1 in
 599 class JumpFR<RegisterClass RC, SDPatternOperator operator = null_frag>:
 600   InstSE<(outs), (ins RC:$rs), "jr\t$rs", [(operator RC:$rs)], IIBranch, FrmR>;
 601
 602 // Indirect branch
 603 class IndirectBranch<RegisterClass RC>: JumpFR<RC, brind> {
 604   let isBranch = 1;
 605   let isIndirectBranch = 1;
 606 }
 607
 608 // Return instruction
 609 class RetBase<RegisterClass RC>: JumpFR<RC> {
 610   let isReturn = 1;
 611   let isCodeGenOnly = 1;
 612   let hasCtrlDep = 1;
 613   let hasExtraSrcRegAllocReq = 1;
 614 }
 615
 616 // Jump and Link (Call)
 617 let isCall=1, hasDelaySlot=1, Defs = [RA] in {
 618   class JumpLink<string opstr> :
 619     InstSE<(outs), (ins calltarget:$target), !strconcat(opstr, "\t$target"),
 620            [(MipsJmpLink imm:$target)], IIBranch, FrmJ> {
 621     let DecoderMethod = "DecodeJumpTarget";
 622   }
 623
 624   class JumpLinkRegPseudo<RegisterClass RC, Instruction JALRInst,
 625                           Register RetReg>:
 626     PseudoSE<(outs), (ins RC:$rs), [(MipsJmpLink RC:$rs)], IIBranch>,
 627     PseudoInstExpansion<(JALRInst RetReg, RC:$rs)>;
 628
 629   class JumpLinkReg<string opstr, RegisterClass RC>:
 630     InstSE<(outs RC:$rd), (ins RC:$rs), !strconcat(opstr, "\t$rd, $rs"),
 631            [], IIBranch, FrmR>;
 632
 633   class BGEZAL_FT<string opstr, RegisterOperand RO> :
 634     InstSE<(outs), (ins RO:$rs, brtarget:$offset),
 635            !strconcat(opstr, "\t$rs, $offset"), [], IIBranch, FrmI>;
 636
 637 }
 638
 639 class BAL_BR_Pseudo<Instruction RealInst> :
 640   PseudoSE<(outs), (ins brtarget:$offset), [], IIBranch>,
 641   PseudoInstExpansion<(RealInst ZERO, brtarget:$offset)> {
 642   let isBranch = 1;
 643   let isTerminator = 1;
 644   let isBarrier = 1;
 645   let hasDelaySlot = 1;
 646   let Defs = [RA];
 647 }
 648
 649 // Syscall
 650 class SYS_FT<string opstr> :
 651   InstSE<(outs), (ins uimm20:$code_),
 652          !strconcat(opstr, "\t$code_"), [], NoItinerary, FrmI>;
 653 // Break
 654 class BRK_FT<string opstr> :
 655   InstSE<(outs), (ins uimm10:$code_1, uimm10:$code_2),
 656          !strconcat(opstr, "\t$code_1, $code_2"), [], NoItinerary, FrmOther>;
 657
 658 // (D)Eret
 659 class ER_FT<string opstr> :
 660   InstSE<(outs), (ins),
 661          opstr, [], NoItinerary, FrmOther>;
 662
 663 // Sync
 664 let hasSideEffects = 1 in
 665 class SYNC_FT :
 666   InstSE<(outs), (ins i32imm:$stype), "sync $stype", [(MipsSync imm:$stype)],
 667          NoItinerary, FrmOther>;
 668
 669 let hasSideEffects = 1 in
 670 class TEQ_FT<string opstr, RegisterOperand RO> :
 671   InstSE<(outs), (ins RO:$rs, RO:$rt, uimm16:$code_),
 672          !strconcat(opstr, "\t$rs, $rt, $code_"), [], NoItinerary, FrmI>;
 673
 674 // Mul, Div
 675 class Mult<string opstr, InstrItinClass itin, RegisterOperand RO,
 676            list<Register> DefRegs> :
 677   InstSE<(outs), (ins RO:$rs, RO:$rt), !strconcat(opstr, "\t$rs, $rt"), [],
 678          itin, FrmR, opstr> {
 679   let isCommutable = 1;
 680   let Defs = DefRegs;
 681   let neverHasSideEffects = 1;
 682 }
 683
 684 // Pseudo multiply/divide instruction with explicit accumulator register
 685 // operands.
 686 class MultDivPseudo<Instruction RealInst, RegisterClass R0, RegisterOperand R1,
 687                     SDPatternOperator OpNode, InstrItinClass Itin,
 688                     bit IsComm = 1, bit HasSideEffects = 0,
 689                     bit UsesCustomInserter = 0> :
 690   PseudoSE<(outs R0:$ac), (ins R1:$rs, R1:$rt),
 691            [(set R0:$ac, (OpNode R1:$rs, R1:$rt))], Itin>,
 692   PseudoInstExpansion<(RealInst R1:$rs, R1:$rt)> {
 693   let isCommutable = IsComm;
 694   let hasSideEffects = HasSideEffects;
 695   let usesCustomInserter = UsesCustomInserter;
 696 }
 697
 698 // Pseudo multiply add/sub instruction with explicit accumulator register
 699 // operands.
 700 class MAddSubPseudo<Instruction RealInst, SDPatternOperator OpNode>
 701   : PseudoSE<(outs ACRegs:$ac),
 702              (ins CPURegsOpnd:$rs, CPURegsOpnd:$rt, ACRegs:$acin),
 703              [(set ACRegs:$ac,
 704               (OpNode CPURegsOpnd:$rs, CPURegsOpnd:$rt, ACRegs:$acin))],
 705              IIImult>,
 706     PseudoInstExpansion<(RealInst CPURegsOpnd:$rs, CPURegsOpnd:$rt)> {
 707   string Constraints = "$acin = $ac";
 708 }
 709
 710 class Div<string opstr, InstrItinClass itin, RegisterOperand RO,
 711           list<Register> DefRegs> :
 712   InstSE<(outs), (ins RO:$rs, RO:$rt), !strconcat(opstr, "\t$$zero, $rs, $rt"),
 713          [], itin, FrmR> {
 714   let Defs = DefRegs;
 715 }
 716
 717 // Move from Hi/Lo
 718 class MoveFromLOHI<string opstr, RegisterClass RC, list<Register> UseRegs>:
 719   InstSE<(outs RC:$rd), (ins), !strconcat(opstr, "\t$rd"), [], IIHiLo, FrmR> {
 720   let Uses = UseRegs;
 721   let neverHasSideEffects = 1;
 722 }
 723
 724 class MoveToLOHI<string opstr, RegisterClass RC, list<Register> DefRegs>:
 725   InstSE<(outs), (ins RC:$rs), !strconcat(opstr, "\t$rs"), [], IIHiLo, FrmR> {
 726   let Defs = DefRegs;
 727   let neverHasSideEffects = 1;
 728 }
 729
 730 class EffectiveAddress<string opstr, RegisterClass RC, Operand Mem> :
 731   InstSE<(outs RC:$rt), (ins Mem:$addr), !strconcat(opstr, "\t$rt, $addr"),
 732          [(set RC:$rt, addr:$addr)], NoItinerary, FrmI> {
 733   let isCodeGenOnly = 1;
 734   let DecoderMethod = "DecodeMem";
 735 }
 736
 737 // Count Leading Ones/Zeros in Word
 738 class CountLeading0<string opstr, RegisterOperand RO>:
 739   InstSE<(outs RO:$rd), (ins RO:$rs), !strconcat(opstr, "\t$rd, $rs"),
 740          [(set RO:$rd, (ctlz RO:$rs))], IIArith, FrmR>,
 741   Requires<[HasBitCount, HasStdEnc]>;
 742
 743 class CountLeading1<string opstr, RegisterOperand RO>:
 744   InstSE<(outs RO:$rd), (ins RO:$rs), !strconcat(opstr, "\t$rd, $rs"),
 745          [(set RO:$rd, (ctlz (not RO:$rs)))], IIArith, FrmR>,
 746   Requires<[HasBitCount, HasStdEnc]>;
 747
 748
 749 // Sign Extend in Register.
 750 class SignExtInReg<string opstr, ValueType vt, RegisterClass RC> :
 751   InstSE<(outs RC:$rd), (ins RC:$rt), !strconcat(opstr, "\t$rd, $rt"),
 752          [(set RC:$rd, (sext_inreg RC:$rt, vt))], IIseb, FrmR> {
 753   let Predicates = [HasSEInReg, HasStdEnc];
 754 }
 755
 756 // Subword Swap
 757 class SubwordSwap<string opstr, RegisterOperand RO>:
 758   InstSE<(outs RO:$rd), (ins RO:$rt), !strconcat(opstr, "\t$rd, $rt"), [],
 759          NoItinerary, FrmR> {
 760   let Predicates = [HasSwap, HasStdEnc];
 761   let neverHasSideEffects = 1;
 762 }
 763
 764 // Read Hardware
 765 class ReadHardware<RegisterClass CPURegClass, RegisterOperand RO> :
 766   InstSE<(outs CPURegClass:$rt), (ins RO:$rd), "rdhwr\t$rt, $rd", [],
 767          IIArith, FrmR>;
 768
 769 // Ext and Ins
 770 class ExtBase<string opstr, RegisterOperand RO>:
 771   InstSE<(outs RO:$rt), (ins RO:$rs, uimm16:$pos, size_ext:$size),
 772          !strconcat(opstr, " $rt, $rs, $pos, $size"),
 773          [(set RO:$rt, (MipsExt RO:$rs, imm:$pos, imm:$size))], NoItinerary,
 774          FrmR> {
 775   let Predicates = [HasMips32r2, HasStdEnc];
 776 }
 777
 778 class InsBase<string opstr, RegisterOperand RO>:
 779   InstSE<(outs RO:$rt), (ins RO:$rs, uimm16:$pos, size_ins:$size, RO:$src),
 780          !strconcat(opstr, " $rt, $rs, $pos, $size"),
 781          [(set RO:$rt, (MipsIns RO:$rs, imm:$pos, imm:$size, RO:$src))],
 782          NoItinerary, FrmR> {
 783   let Predicates = [HasMips32r2, HasStdEnc];
 784   let Constraints = "$src = $rt";
 785 }
 786
 787 // Atomic instructions with 2 source operands (ATOMIC_SWAP & ATOMIC_LOAD_*).
 788 class Atomic2Ops<PatFrag Op, RegisterClass DRC, RegisterClass PRC> :
 789   PseudoSE<(outs DRC:$dst), (ins PRC:$ptr, DRC:$incr),
 790            [(set DRC:$dst, (Op PRC:$ptr, DRC:$incr))]>;
 791
 792 multiclass Atomic2Ops32<PatFrag Op> {
 793   def NAME : Atomic2Ops<Op, CPURegs, CPURegs>, Requires<[NotN64, HasStdEnc]>;
 794   def _P8  : Atomic2Ops<Op, CPURegs, CPU64Regs>,
 795              Requires<[IsN64, HasStdEnc]> {
 796     let DecoderNamespace = "Mips64";
 797   }
 798 }
 799
 800 // Atomic Compare & Swap.
 801 class AtomicCmpSwap<PatFrag Op, RegisterClass DRC, RegisterClass PRC> :
 802   PseudoSE<(outs DRC:$dst), (ins PRC:$ptr, DRC:$cmp, DRC:$swap),
 803            [(set DRC:$dst, (Op PRC:$ptr, DRC:$cmp, DRC:$swap))]>;
 804
 805 multiclass AtomicCmpSwap32<PatFrag Op>  {
 806   def NAME : AtomicCmpSwap<Op, CPURegs, CPURegs>,
 807              Requires<[NotN64, HasStdEnc]>;
 808   def _P8  : AtomicCmpSwap<Op, CPURegs, CPU64Regs>,
 809              Requires<[IsN64, HasStdEnc]> {
 810     let DecoderNamespace = "Mips64";
 811   }
 812 }
 813
 814 class LLBase<string opstr, RegisterOperand RO, Operand Mem> :
 815   InstSE<(outs RO:$rt), (ins Mem:$addr), !strconcat(opstr, "\t$rt, $addr"),
 816          [], NoItinerary, FrmI> {
 817   let DecoderMethod = "DecodeMem";
 818   let mayLoad = 1;
 819 }
 820
 821 class SCBase<string opstr, RegisterOperand RO, Operand Mem> :
 822   InstSE<(outs RO:$dst), (ins RO:$rt, Mem:$addr),
 823          !strconcat(opstr, "\t$rt, $addr"), [], NoItinerary, FrmI> {
 824   let DecoderMethod = "DecodeMem";
 825   let mayStore = 1;
 826   let Constraints = "$rt = $dst";
 827 }
 828
 829 class MFC3OP<dag outs, dag ins, string asmstr> :
 830   InstSE<outs, ins, asmstr, [], NoItinerary, FrmFR>;
 831
 832 let isBarrier = 1, isTerminator = 1, isCodeGenOnly = 1 in
 833 def TRAP : InstSE<(outs), (ins), "break", [(trap)], NoItinerary, FrmOther> {
 834    let Inst = 0x0000000d;
 835 }
 836
 837 //===----------------------------------------------------------------------===//
 838 // Pseudo instructions
 839 //===----------------------------------------------------------------------===//
 840
 841 // Return RA.
 842 let isReturn=1, isTerminator=1, hasDelaySlot=1, isBarrier=1, hasCtrlDep=1 in
 843 def RetRA : PseudoSE<(outs), (ins), [(MipsRet)]>;
 844
 845 let Defs = [SP], Uses = [SP], hasSideEffects = 1 in {
 846 def ADJCALLSTACKDOWN : MipsPseudo<(outs), (ins i32imm:$amt),
 847                                   [(callseq_start timm:$amt)]>;
 848 def ADJCALLSTACKUP   : MipsPseudo<(outs), (ins i32imm:$amt1, i32imm:$amt2),
 849                                   [(callseq_end timm:$amt1, timm:$amt2)]>;
 850 }
 851
 852 let usesCustomInserter = 1 in {
 853   defm ATOMIC_LOAD_ADD_I8   : Atomic2Ops32<atomic_load_add_8>;
 854   defm ATOMIC_LOAD_ADD_I16  : Atomic2Ops32<atomic_load_add_16>;
 855   defm ATOMIC_LOAD_ADD_I32  : Atomic2Ops32<atomic_load_add_32>;
 856   defm ATOMIC_LOAD_SUB_I8   : Atomic2Ops32<atomic_load_sub_8>;
 857   defm ATOMIC_LOAD_SUB_I16  : Atomic2Ops32<atomic_load_sub_16>;
 858   defm ATOMIC_LOAD_SUB_I32  : Atomic2Ops32<atomic_load_sub_32>;
 859   defm ATOMIC_LOAD_AND_I8   : Atomic2Ops32<atomic_load_and_8>;
 860   defm ATOMIC_LOAD_AND_I16  : Atomic2Ops32<atomic_load_and_16>;
 861   defm ATOMIC_LOAD_AND_I32  : Atomic2Ops32<atomic_load_and_32>;
 862   defm ATOMIC_LOAD_OR_I8    : Atomic2Ops32<atomic_load_or_8>;
 863   defm ATOMIC_LOAD_OR_I16   : Atomic2Ops32<atomic_load_or_16>;
 864   defm ATOMIC_LOAD_OR_I32   : Atomic2Ops32<atomic_load_or_32>;
 865   defm ATOMIC_LOAD_XOR_I8   : Atomic2Ops32<atomic_load_xor_8>;
 866   defm ATOMIC_LOAD_XOR_I16  : Atomic2Ops32<atomic_load_xor_16>;
 867   defm ATOMIC_LOAD_XOR_I32  : Atomic2Ops32<atomic_load_xor_32>;
 868   defm ATOMIC_LOAD_NAND_I8  : Atomic2Ops32<atomic_load_nand_8>;
 869   defm ATOMIC_LOAD_NAND_I16 : Atomic2Ops32<atomic_load_nand_16>;
 870   defm ATOMIC_LOAD_NAND_I32 : Atomic2Ops32<atomic_load_nand_32>;
 871
 872   defm ATOMIC_SWAP_I8       : Atomic2Ops32<atomic_swap_8>;
 873   defm ATOMIC_SWAP_I16      : Atomic2Ops32<atomic_swap_16>;
 874   defm ATOMIC_SWAP_I32      : Atomic2Ops32<atomic_swap_32>;
 875
 876   defm ATOMIC_CMP_SWAP_I8   : AtomicCmpSwap32<atomic_cmp_swap_8>;
 877   defm ATOMIC_CMP_SWAP_I16  : AtomicCmpSwap32<atomic_cmp_swap_16>;
 878   defm ATOMIC_CMP_SWAP_I32  : AtomicCmpSwap32<atomic_cmp_swap_32>;
 879 }
 880
 881 /// Pseudo instructions for loading and storing accumulator registers.
 882 let isPseudo = 1 in {
 883   defm LOAD_AC64  : LoadM<"load_ac64", ACRegs>;
 884   defm STORE_AC64 : StoreM<"store_ac64", ACRegs>;
 885 }
 886
 887 //===----------------------------------------------------------------------===//
 888 // Instruction definition
 889 //===----------------------------------------------------------------------===//
 890 //===----------------------------------------------------------------------===//
 891 // MipsI Instructions
 892 //===----------------------------------------------------------------------===//
 893
 894 /// Arithmetic Instructions (ALU Immediate)
 895 def ADDiu : MMRel, ArithLogicI<"addiu", simm16, CPURegsOpnd, IIArith, immSExt16,
 896                                add>,
 897             ADDI_FM<0x9>, IsAsCheapAsAMove;
 898 def ADDi  : MMRel, ArithLogicI<"addi", simm16, CPURegsOpnd>, ADDI_FM<0x8>;
 899 def SLTi  : MMRel, SetCC_I<"slti", setlt, simm16, immSExt16, CPURegs>,
 900             SLTI_FM<0xa>;
 901 def SLTiu : MMRel, SetCC_I<"sltiu", setult, simm16, immSExt16, CPURegs>,
 902             SLTI_FM<0xb>;
 903 def ANDi  : MMRel, ArithLogicI<"andi", uimm16, CPURegsOpnd, IILogic, immZExt16,
 904                                and>,
 905             ADDI_FM<0xc>;
 906 def ORi   : MMRel, ArithLogicI<"ori", uimm16, CPURegsOpnd, IILogic, immZExt16,
 907                                or>,
 908             ADDI_FM<0xd>;
 909 def XORi  : MMRel, ArithLogicI<"xori", uimm16, CPURegsOpnd, IILogic, immZExt16,
 910                                xor>,
 911             ADDI_FM<0xe>;
 912 def LUi   : MMRel, LoadUpper<"lui", CPURegs, uimm16>, LUI_FM;
 913
 914 /// Arithmetic Instructions (3-Operand, R-Type)
 915 def ADDu  : MMRel, ArithLogicR<"addu", CPURegsOpnd, 1, IIArith, add>,
 916             ADD_FM<0, 0x21>;
 917 def SUBu  : MMRel, ArithLogicR<"subu", CPURegsOpnd, 0, IIArith, sub>,
 918             ADD_FM<0, 0x23>;
 919 def MUL   : MMRel, ArithLogicR<"mul", CPURegsOpnd, 1, IIImul, mul>,
 920             ADD_FM<0x1c, 2>;
 921 def ADD   : MMRel, ArithLogicR<"add", CPURegsOpnd>, ADD_FM<0, 0x20>;
 922 def SUB   : MMRel, ArithLogicR<"sub", CPURegsOpnd>, ADD_FM<0, 0x22>;
 923 def SLT   : MMRel, SetCC_R<"slt", setlt, CPURegs>, ADD_FM<0, 0x2a>;
 924 def SLTu  : MMRel, SetCC_R<"sltu", setult, CPURegs>, ADD_FM<0, 0x2b>;
 925 def AND   : MMRel, ArithLogicR<"and", CPURegsOpnd, 1, IILogic, and>,
 926             ADD_FM<0, 0x24>;
 927 def OR    : MMRel, ArithLogicR<"or", CPURegsOpnd, 1, IILogic, or>,
 928             ADD_FM<0, 0x25>;
 929 def XOR   : MMRel, ArithLogicR<"xor", CPURegsOpnd, 1, IILogic, xor>,
 930             ADD_FM<0, 0x26>;
 931 def NOR   : MMRel, LogicNOR<"nor", CPURegsOpnd>, ADD_FM<0, 0x27>;
 932
 933 /// Shift Instructions
 934 def SLL  : MMRel, shift_rotate_imm<"sll", shamt, CPURegsOpnd, shl, immZExt5>,
 935            SRA_FM<0, 0>;
 936 def SRL  : MMRel, shift_rotate_imm<"srl", shamt, CPURegsOpnd, srl, immZExt5>,
 937            SRA_FM<2, 0>;
 938 def SRA  : MMRel, shift_rotate_imm<"sra", shamt, CPURegsOpnd, sra, immZExt5>,
 939            SRA_FM<3, 0>;
 940 def SLLV : MMRel, shift_rotate_reg<"sllv", CPURegsOpnd, shl>, SRLV_FM<4, 0>;
 941 def SRLV : MMRel, shift_rotate_reg<"srlv", CPURegsOpnd, srl>, SRLV_FM<6, 0>;
 942 def SRAV : MMRel, shift_rotate_reg<"srav", CPURegsOpnd, sra>, SRLV_FM<7, 0>;
 943
 944 // Rotate Instructions
 945 let Predicates = [HasMips32r2, HasStdEnc] in {
 946   def ROTR  : MMRel, shift_rotate_imm<"rotr", shamt, CPURegsOpnd, rotr,
 947                                       immZExt5>,
 948               SRA_FM<2, 1>;
 949   def ROTRV : MMRel, shift_rotate_reg<"rotrv", CPURegsOpnd, rotr>,
 950               SRLV_FM<6, 1>;
 951 }
 952
 953 /// Load and Store Instructions
 954 ///  aligned
 955 defm LB  : LoadM<"lb", CPURegs, sextloadi8, IILoad>, MMRel, LW_FM<0x20>;
 956 defm LBu : LoadM<"lbu", CPURegs, zextloadi8, IILoad, addrDefault>, MMRel,
 957            LW_FM<0x24>;
 958 defm LH  : LoadM<"lh", CPURegs, sextloadi16, IILoad, addrDefault>, MMRel,
 959            LW_FM<0x21>;
 960 defm LHu : LoadM<"lhu", CPURegs, zextloadi16, IILoad>, MMRel, LW_FM<0x25>;
 961 defm LW  : LoadM<"lw", CPURegs, load, IILoad, addrDefault>, MMRel, LW_FM<0x23>;
 962 defm SB  : StoreM<"sb", CPURegs, truncstorei8, IIStore>, MMRel, LW_FM<0x28>;
 963 defm SH  : StoreM<"sh", CPURegs, truncstorei16, IIStore>, MMRel, LW_FM<0x29>;
 964 defm SW  : StoreM<"sw", CPURegs, store, IIStore>, MMRel, LW_FM<0x2b>;
 965
 966 /// load/store left/right
 967 defm LWL : LoadLeftRightM<"lwl", MipsLWL, CPURegs>, LW_FM<0x22>;
 968 defm LWR : LoadLeftRightM<"lwr", MipsLWR, CPURegs>, LW_FM<0x26>;
 969 defm SWL : StoreLeftRightM<"swl", MipsSWL, CPURegs>, LW_FM<0x2a>;
 970 defm SWR : StoreLeftRightM<"swr", MipsSWR, CPURegs>, LW_FM<0x2e>;
 971
 972 def SYNC : SYNC_FT, SYNC_FM;
 973 def TEQ : TEQ_FT<"teq", CPURegsOpnd>, TEQ_FM<0x34>;
 974
 975 def BREAK : BRK_FT<"break">, BRK_FM<0xd>;
 976 def SYSCALL : SYS_FT<"syscall">, SYS_FM<0xc>;
 977
 978 def ERET : ER_FT<"eret">, ER_FM<0x18>;
 979 def DERET : ER_FT<"deret">, ER_FM<0x1f>;
 980
 981 /// Load-linked, Store-conditional
 982 let Predicates = [NotN64, HasStdEnc] in {
 983   def LL : LLBase<"ll", CPURegsOpnd, mem>, LW_FM<0x30>;
 984   def SC : SCBase<"sc", CPURegsOpnd, mem>, LW_FM<0x38>;
 985 }
 986
 987 let Predicates = [IsN64, HasStdEnc], DecoderNamespace = "Mips64" in {
 988   def LL_P8 : LLBase<"ll", CPURegsOpnd, mem64>, LW_FM<0x30>;
 989   def SC_P8 : SCBase<"sc", CPURegsOpnd, mem64>, LW_FM<0x38>;
 990 }
 991
 992 /// Jump and Branch Instructions
 993 def J       : JumpFJ<jmptarget, "j", br, bb>, FJ<2>,
 994               Requires<[RelocStatic, HasStdEnc]>, IsBranch;
 995 def JR      : IndirectBranch<CPURegs>, MTLO_FM<8>;
 996 def B       : UncondBranch<"b">, B_FM;
 997 def BEQ     : CBranch<"beq", seteq, CPURegsOpnd>, BEQ_FM<4>;
 998 def BNE     : CBranch<"bne", setne, CPURegsOpnd>, BEQ_FM<5>;
 999 def BGEZ    : CBranchZero<"bgez", setge, CPURegsOpnd>, BGEZ_FM<1, 1>;
1000 def BGTZ    : CBranchZero<"bgtz", setgt, CPURegsOpnd>, BGEZ_FM<7, 0>;
1001 def BLEZ    : CBranchZero<"blez", setle, CPURegsOpnd>, BGEZ_FM<6, 0>;
1002 def BLTZ    : CBranchZero<"bltz", setlt, CPURegsOpnd>, BGEZ_FM<1, 0>;
1003
1004 def JAL  : JumpLink<"jal">, FJ<3>;
1005 def JALR : JumpLinkReg<"jalr", CPURegs>, JALR_FM;
1006 def JALRPseudo : JumpLinkRegPseudo<CPURegs, JALR, RA>;
1007 def BGEZAL : BGEZAL_FT<"bgezal", CPURegsOpnd>, BGEZAL_FM<0x11>;
1008 def BLTZAL : BGEZAL_FT<"bltzal", CPURegsOpnd>, BGEZAL_FM<0x10>;
1009 def BAL_BR : BAL_BR_Pseudo<BGEZAL>;
1010 def TAILCALL : JumpFJ<calltarget, "j", MipsTailCall, imm>, FJ<2>, IsTailCall;
1011 def TAILCALL_R : JumpFR<CPURegs, MipsTailCall>, MTLO_FM<8>, IsTailCall;
1012
1013 def RET : RetBase<CPURegs>, MTLO_FM<8>;
1014
1015 // Exception handling related node and instructions.
1016 // The conversion sequence is:
1017 // ISD::EH_RETURN -> MipsISD::EH_RETURN ->
1018 // MIPSeh_return -> (stack change + indirect branch)
1019 //
1020 // MIPSeh_return takes the place of regular return instruction
1021 // but takes two arguments (V1, V0) which are used for storing
1022 // the offset and return address respectively.
1023 def SDT_MipsEHRET : SDTypeProfile<0, 2, [SDTCisInt<0>, SDTCisPtrTy<1>]>;
1024
1025 def MIPSehret : SDNode<"MipsISD::EH_RETURN", SDT_MipsEHRET,
1026                       [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
1027
1028 let Uses = [V0, V1], isTerminator = 1, isReturn = 1, isBarrier = 1 in {
1029   def MIPSeh_return32 : MipsPseudo<(outs), (ins CPURegs:$spoff, CPURegs:$dst),
1030                                 [(MIPSehret CPURegs:$spoff, CPURegs:$dst)]>;
1031   def MIPSeh_return64 : MipsPseudo<(outs), (ins CPU64Regs:$spoff,
1032                                                 CPU64Regs:$dst),
1033                                 [(MIPSehret CPU64Regs:$spoff, CPU64Regs:$dst)]>;
1034 }
1035
1036 /// Multiply and Divide Instructions.
1037 def MULT  : MMRel, Mult<"mult", IIImult, CPURegsOpnd, [HI, LO]>,
1038             MULT_FM<0, 0x18>;
1039 def MULTu : MMRel, Mult<"multu", IIImult, CPURegsOpnd, [HI, LO]>,
1040             MULT_FM<0, 0x19>;
1041 def PseudoMULT  : MultDivPseudo<MULT, ACRegs, CPURegsOpnd, MipsMult, IIImult>;
1042 def PseudoMULTu : MultDivPseudo<MULTu, ACRegs, CPURegsOpnd, MipsMultu, IIImult>;
1043 def SDIV  : Div<"div", IIIdiv, CPURegsOpnd, [HI, LO]>, MULT_FM<0, 0x1a>;
1044 def UDIV  : Div<"divu", IIIdiv, CPURegsOpnd, [HI, LO]>, MULT_FM<0, 0x1b>;
1045 def PseudoSDIV : MultDivPseudo<SDIV, ACRegs, CPURegsOpnd, MipsDivRem, IIIdiv,
1046                                0, 1, 1>;
1047 def PseudoUDIV : MultDivPseudo<UDIV, ACRegs, CPURegsOpnd, MipsDivRemU, IIIdiv,
1048                                0, 1, 1>;
1049
1050 def MTHI : MoveToLOHI<"mthi", CPURegs, [HI]>, MTLO_FM<0x11>;
1051 def MTLO : MoveToLOHI<"mtlo", CPURegs, [LO]>, MTLO_FM<0x13>;
1052 def MFHI : MoveFromLOHI<"mfhi", CPURegs, [HI]>, MFLO_FM<0x10>;
1053 def MFLO : MoveFromLOHI<"mflo", CPURegs, [LO]>, MFLO_FM<0x12>;
1054
1055 /// Sign Ext In Register Instructions.
1056 def SEB : SignExtInReg<"seb", i8, CPURegs>, SEB_FM<0x10, 0x20>;
1057 def SEH : SignExtInReg<"seh", i16, CPURegs>, SEB_FM<0x18, 0x20>;
1058
1059 /// Count Leading
1060 def CLZ : CountLeading0<"clz", CPURegsOpnd>, CLO_FM<0x20>;
1061 def CLO : CountLeading1<"clo", CPURegsOpnd>, CLO_FM<0x21>;
1062
1063 /// Word Swap Bytes Within Halfwords
1064 def WSBH : SubwordSwap<"wsbh", CPURegsOpnd>, SEB_FM<2, 0x20>;
1065
1066 /// No operation.
1067 def NOP : PseudoSE<(outs), (ins), []>, PseudoInstExpansion<(SLL ZERO, ZERO, 0)>;
1068
1069 // FrameIndexes are legalized when they are operands from load/store
1070 // instructions. The same not happens for stack address copies, so an
1071 // add op with mem ComplexPattern is used and the stack address copy
1072 // can be matched. It's similar to Sparc LEA_ADDRi
1073 def LEA_ADDiu : EffectiveAddress<"addiu", CPURegs, mem_ea>, LW_FM<9>;
1074
1075 // MADD*/MSUB*
1076 def MADD  : MArithR<"madd", 1>, MULT_FM<0x1c, 0>;
1077 def MADDU : MArithR<"maddu", 1>, MULT_FM<0x1c, 1>;
1078 def MSUB  : MArithR<"msub">, MULT_FM<0x1c, 4>;
1079 def MSUBU : MArithR<"msubu">, MULT_FM<0x1c, 5>;
1080 def PseudoMADD  : MAddSubPseudo<MADD, MipsMAdd>;
1081 def PseudoMADDU : MAddSubPseudo<MADDU, MipsMAddu>;
1082 def PseudoMSUB  : MAddSubPseudo<MSUB, MipsMSub>;
1083 def PseudoMSUBU : MAddSubPseudo<MSUBU, MipsMSubu>;
1084
1085 def RDHWR : ReadHardware<CPURegs, HWRegsOpnd>, RDHWR_FM;
1086
1087 def EXT : ExtBase<"ext", CPURegsOpnd>, EXT_FM<0>;
1088 def INS : InsBase<"ins", CPURegsOpnd>, EXT_FM<4>;
1089
1090 /// Move Control Registers From/To CPU Registers
1091 def MFC0_3OP : MFC3OP<(outs CPURegsOpnd:$rt),
1092                       (ins CPURegsOpnd:$rd, uimm16:$sel),
1093                       "mfc0\t$rt, $rd, $sel">, MFC3OP_FM<0x10, 0>;
1094
1095 def MTC0_3OP : MFC3OP<(outs CPURegsOpnd:$rd, uimm16:$sel),
1096                       (ins CPURegsOpnd:$rt),
1097                       "mtc0\t$rt, $rd, $sel">, MFC3OP_FM<0x10, 4>;
1098
1099 def MFC2_3OP : MFC3OP<(outs CPURegsOpnd:$rt),
1100                       (ins CPURegsOpnd:$rd, uimm16:$sel),
1101                       "mfc2\t$rt, $rd, $sel">, MFC3OP_FM<0x12, 0>;
1102
1103 def MTC2_3OP : MFC3OP<(outs CPURegsOpnd:$rd, uimm16:$sel),
1104                       (ins CPURegsOpnd:$rt),
1105                       "mtc2\t$rt, $rd, $sel">, MFC3OP_FM<0x12, 4>;
1106
1107 //===----------------------------------------------------------------------===//
1108 // Instruction aliases
1109 //===----------------------------------------------------------------------===//
1110 def : InstAlias<"move $dst, $src",
1111                 (ADDu CPURegsOpnd:$dst, CPURegsOpnd:$src,ZERO), 1>,
1112       Requires<[NotMips64]>;
1113 def : InstAlias<"bal $offset", (BGEZAL ZERO, brtarget:$offset), 1>;
1114 def : InstAlias<"addu $rs, $rt, $imm",
1115                 (ADDiu CPURegsOpnd:$rs, CPURegsOpnd:$rt, simm16:$imm), 0>;
1116 def : InstAlias<"add $rs, $rt, $imm",
1117                 (ADDi CPURegsOpnd:$rs, CPURegsOpnd:$rt, simm16:$imm), 0>;
1118 def : InstAlias<"and $rs, $rt, $imm",
1119                 (ANDi CPURegsOpnd:$rs, CPURegsOpnd:$rt, simm16:$imm), 0>;
1120 def : InstAlias<"j $rs", (JR CPURegs:$rs), 0>,
1121       Requires<[NotMips64]>;
1122 def : InstAlias<"jalr $rs", (JALR RA, CPURegs:$rs)>, Requires<[NotMips64]>;
1123 def : InstAlias<"jal $rs", (JALR RA, CPURegs:$rs), 0>, Requires<[NotMips64]>;
1124 def : InstAlias<"jal $rd,$rs", (JALR CPURegs:$rd, CPURegs:$rs), 0>,
1125                  Requires<[NotMips64]>;
1126 def : InstAlias<"not $rt, $rs",
1127                 (NOR CPURegsOpnd:$rt, CPURegsOpnd:$rs, ZERO), 1>;
1128 def : InstAlias<"neg $rt, $rs",
1129                 (SUB CPURegsOpnd:$rt, ZERO, CPURegsOpnd:$rs), 1>;
1130 def : InstAlias<"negu $rt, $rs",
1131                 (SUBu CPURegsOpnd:$rt, ZERO, CPURegsOpnd:$rs), 1>;
1132 def : InstAlias<"slt $rs, $rt, $imm",
1133                 (SLTi CPURegsOpnd:$rs, CPURegs:$rt, simm16:$imm), 0>;
1134 def : InstAlias<"xor $rs, $rt, $imm",
1135                 (XORi CPURegsOpnd:$rs, CPURegsOpnd:$rt, uimm16:$imm), 1>,
1136       Requires<[NotMips64]>;
1137 def : InstAlias<"or $rs, $rt, $imm",
1138                 (ORi CPURegsOpnd:$rs, CPURegsOpnd:$rt, uimm16:$imm), 1>,
1139                  Requires<[NotMips64]>;
1140 def : InstAlias<"nop", (SLL ZERO, ZERO, 0), 1>;
1141 def : InstAlias<"mfc0 $rt, $rd",
1142                 (MFC0_3OP CPURegsOpnd:$rt, CPURegsOpnd:$rd, 0), 0>;
1143 def : InstAlias<"mtc0 $rt, $rd",
1144                 (MTC0_3OP CPURegsOpnd:$rd, 0, CPURegsOpnd:$rt), 0>;
1145 def : InstAlias<"mfc2 $rt, $rd",
1146                 (MFC2_3OP CPURegsOpnd:$rt, CPURegsOpnd:$rd, 0), 0>;
1147 def : InstAlias<"mtc2 $rt, $rd",
1148                 (MTC2_3OP CPURegsOpnd:$rd, 0, CPURegsOpnd:$rt), 0>;
1149 def : InstAlias<"bnez $rs,$offset",
1150                  (BNE CPURegsOpnd:$rs, ZERO, brtarget:$offset), 1>,
1151                  Requires<[NotMips64]>;
1152 def : InstAlias<"beqz $rs,$offset",
1153                  (BEQ CPURegsOpnd:$rs, ZERO, brtarget:$offset), 1>,
1154                  Requires<[NotMips64]>;
1155 def : InstAlias<"syscall", (SYSCALL 0), 1>;
1156
1157 def : InstAlias<"break $imm", (BREAK uimm10:$imm, 0), 1>;
1158 def : InstAlias<"break", (BREAK 0, 0), 1>;
1159 //===----------------------------------------------------------------------===//
1160 // Assembler Pseudo Instructions
1161 //===----------------------------------------------------------------------===//
1162
1163 class LoadImm32< string instr_asm, Operand Od, RegisterOperand RO> :
1164   MipsAsmPseudoInst<(outs RO:$rt), (ins Od:$imm32),
1165                      !strconcat(instr_asm, "\t$rt, $imm32")> ;
1166 def LoadImm32Reg : LoadImm32<"li", shamt,CPURegsOpnd>;
1167
1168 class LoadAddress<string instr_asm, Operand MemOpnd, RegisterOperand RO> :
1169   MipsAsmPseudoInst<(outs RO:$rt), (ins MemOpnd:$addr),
1170                      !strconcat(instr_asm, "\t$rt, $addr")> ;
1171 def LoadAddr32Reg : LoadAddress<"la", mem, CPURegsOpnd>;
1172
1173 class LoadAddressImm<string instr_asm, Operand Od, RegisterOperand RO> :
1174   MipsAsmPseudoInst<(outs RO:$rt), (ins Od:$imm32),
1175                      !strconcat(instr_asm, "\t$rt, $imm32")> ;
1176 def LoadAddr32Imm : LoadAddressImm<"la", shamt,CPURegsOpnd>;
1177
1178
1179
1180 //===----------------------------------------------------------------------===//
1181 //  Arbitrary patterns that map to one or more instructions
1182 //===----------------------------------------------------------------------===//
1183
1184 // Load/store pattern templates.
1185 class LoadRegImmPat<Instruction LoadInst, ValueType ValTy, PatFrag Node> :
1186   MipsPat<(ValTy (Node addrRegImm:$a)), (LoadInst addrRegImm:$a)>;
1187
1188 class StoreRegImmPat<Instruction StoreInst, ValueType ValTy> :
1189   MipsPat<(store ValTy:$v, addrRegImm:$a), (StoreInst ValTy:$v, addrRegImm:$a)>;
1190
1191 // Small immediates
1192 def : MipsPat<(i32 immSExt16:$in),
1193               (ADDiu ZERO, imm:$in)>;
1194 def : MipsPat<(i32 immZExt16:$in),
1195               (ORi ZERO, imm:$in)>;
1196 def : MipsPat<(i32 immLow16Zero:$in),
1197               (LUi (HI16 imm:$in))>;
1198
1199 // Arbitrary immediates
1200 def : MipsPat<(i32 imm:$imm),
1201           (ORi (LUi (HI16 imm:$imm)), (LO16 imm:$imm))>;
1202
1203 // Carry MipsPatterns
1204 def : MipsPat<(subc CPURegs:$lhs, CPURegs:$rhs),
1205               (SUBu CPURegs:$lhs, CPURegs:$rhs)>;
1206 let Predicates = [HasStdEnc, NotDSP] in {
1207   def : MipsPat<(addc CPURegs:$lhs, CPURegs:$rhs),
1208                 (ADDu CPURegs:$lhs, CPURegs:$rhs)>;
1209   def : MipsPat<(addc  CPURegs:$src, immSExt16:$imm),
1210                 (ADDiu CPURegs:$src, imm:$imm)>;
1211 }
1212
1213 // Call
1214 def : MipsPat<(MipsJmpLink (i32 tglobaladdr:$dst)),
1215               (JAL tglobaladdr:$dst)>;
1216 def : MipsPat<(MipsJmpLink (i32 texternalsym:$dst)),
1217               (JAL texternalsym:$dst)>;
1218 //def : MipsPat<(MipsJmpLink CPURegs:$dst),
1219 //              (JALR CPURegs:$dst)>;
1220
1221 // Tail call
1222 def : MipsPat<(MipsTailCall (iPTR tglobaladdr:$dst)),
1223               (TAILCALL tglobaladdr:$dst)>;
1224 def : MipsPat<(MipsTailCall (iPTR texternalsym:$dst)),
1225               (TAILCALL texternalsym:$dst)>;
1226 // hi/lo relocs
1227 def : MipsPat<(MipsHi tglobaladdr:$in), (LUi tglobaladdr:$in)>;
1228 def : MipsPat<(MipsHi tblockaddress:$in), (LUi tblockaddress:$in)>;
1229 def : MipsPat<(MipsHi tjumptable:$in), (LUi tjumptable:$in)>;
1230 def : MipsPat<(MipsHi tconstpool:$in), (LUi tconstpool:$in)>;
1231 def : MipsPat<(MipsHi tglobaltlsaddr:$in), (LUi tglobaltlsaddr:$in)>;
1232 def : MipsPat<(MipsHi texternalsym:$in), (LUi texternalsym:$in)>;
1233
1234 def : MipsPat<(MipsLo tglobaladdr:$in), (ADDiu ZERO, tglobaladdr:$in)>;
1235 def : MipsPat<(MipsLo tblockaddress:$in), (ADDiu ZERO, tblockaddress:$in)>;
1236 def : MipsPat<(MipsLo tjumptable:$in), (ADDiu ZERO, tjumptable:$in)>;
1237 def : MipsPat<(MipsLo tconstpool:$in), (ADDiu ZERO, tconstpool:$in)>;
1238 def : MipsPat<(MipsLo tglobaltlsaddr:$in), (ADDiu ZERO, tglobaltlsaddr:$in)>;
1239 def : MipsPat<(MipsLo texternalsym:$in), (ADDiu ZERO, texternalsym:$in)>;
1240
1241 def : MipsPat<(add CPURegs:$hi, (MipsLo tglobaladdr:$lo)),
1242               (ADDiu CPURegs:$hi, tglobaladdr:$lo)>;
1243 def : MipsPat<(add CPURegs:$hi, (MipsLo tblockaddress:$lo)),
1244               (ADDiu CPURegs:$hi, tblockaddress:$lo)>;
1245 def : MipsPat<(add CPURegs:$hi, (MipsLo tjumptable:$lo)),
1246               (ADDiu CPURegs:$hi, tjumptable:$lo)>;
1247 def : MipsPat<(add CPURegs:$hi, (MipsLo tconstpool:$lo)),
1248               (ADDiu CPURegs:$hi, tconstpool:$lo)>;
1249 def : MipsPat<(add CPURegs:$hi, (MipsLo tglobaltlsaddr:$lo)),
1250               (ADDiu CPURegs:$hi, tglobaltlsaddr:$lo)>;
1251
1252 // gp_rel relocs
1253 def : MipsPat<(add CPURegs:$gp, (MipsGPRel tglobaladdr:$in)),
1254               (ADDiu CPURegs:$gp, tglobaladdr:$in)>;
1255 def : MipsPat<(add CPURegs:$gp, (MipsGPRel tconstpool:$in)),
1256               (ADDiu CPURegs:$gp, tconstpool:$in)>;
1257
1258 // wrapper_pic
1259 class WrapperPat<SDNode node, Instruction ADDiuOp, RegisterClass RC>:
1260       MipsPat<(MipsWrapper RC:$gp, node:$in),
1261               (ADDiuOp RC:$gp, node:$in)>;
1262
1263 def : WrapperPat<tglobaladdr, ADDiu, CPURegs>;
1264 def : WrapperPat<tconstpool, ADDiu, CPURegs>;
1265 def : WrapperPat<texternalsym, ADDiu, CPURegs>;
1266 def : WrapperPat<tblockaddress, ADDiu, CPURegs>;
1267 def : WrapperPat<tjumptable, ADDiu, CPURegs>;
1268 def : WrapperPat<tglobaltlsaddr, ADDiu, CPURegs>;
1269
1270 // Mips does not have "not", so we expand our way
1271 def : MipsPat<(not CPURegs:$in),
1272               (NOR CPURegsOpnd:$in, ZERO)>;
1273
1274 // extended loads
1275 let Predicates = [NotN64, HasStdEnc] in {
1276   def : MipsPat<(i32 (extloadi1  addr:$src)), (LBu addr:$src)>;
1277   def : MipsPat<(i32 (extloadi8  addr:$src)), (LBu addr:$src)>;
1278   def : MipsPat<(i32 (extloadi16 addr:$src)), (LHu addr:$src)>;
1279 }
1280 let Predicates = [IsN64, HasStdEnc] in {
1281   def : MipsPat<(i32 (extloadi1  addr:$src)), (LBu_P8 addr:$src)>;
1282   def : MipsPat<(i32 (extloadi8  addr:$src)), (LBu_P8 addr:$src)>;
1283   def : MipsPat<(i32 (extloadi16 addr:$src)), (LHu_P8 addr:$src)>;
1284 }
1285
1286 // peepholes
1287 let Predicates = [NotN64, HasStdEnc] in {
1288   def : MipsPat<(store (i32 0), addr:$dst), (SW ZERO, addr:$dst)>;
1289 }
1290 let Predicates = [IsN64, HasStdEnc] in {
1291   def : MipsPat<(store (i32 0), addr:$dst), (SW_P8 ZERO, addr:$dst)>;
1292 }
1293
1294 // brcond patterns
1295 multiclass BrcondPats<RegisterClass RC, Instruction BEQOp, Instruction BNEOp,
1296                       Instruction SLTOp, Instruction SLTuOp, Instruction SLTiOp,
1297                       Instruction SLTiuOp, Register ZEROReg> {
1298 def : MipsPat<(brcond (i32 (setne RC:$lhs, 0)), bb:$dst),
1299               (BNEOp RC:$lhs, ZEROReg, bb:$dst)>;
1300 def : MipsPat<(brcond (i32 (seteq RC:$lhs, 0)), bb:$dst),
1301               (BEQOp RC:$lhs, ZEROReg, bb:$dst)>;
1302
1303 def : MipsPat<(brcond (i32 (setge RC:$lhs, RC:$rhs)), bb:$dst),
1304               (BEQ (SLTOp RC:$lhs, RC:$rhs), ZERO, bb:$dst)>;
1305 def : MipsPat<(brcond (i32 (setuge RC:$lhs, RC:$rhs)), bb:$dst),
1306               (BEQ (SLTuOp RC:$lhs, RC:$rhs), ZERO, bb:$dst)>;
1307 def : MipsPat<(brcond (i32 (setge RC:$lhs, immSExt16:$rhs)), bb:$dst),
1308               (BEQ (SLTiOp RC:$lhs, immSExt16:$rhs), ZERO, bb:$dst)>;
1309 def : MipsPat<(brcond (i32 (setuge RC:$lhs, immSExt16:$rhs)), bb:$dst),
1310               (BEQ (SLTiuOp RC:$lhs, immSExt16:$rhs), ZERO, bb:$dst)>;
1311 def : MipsPat<(brcond (i32 (setgt RC:$lhs, immSExt16Plus1:$rhs)), bb:$dst),
1312               (BEQ (SLTiOp RC:$lhs, (Plus1 imm:$rhs)), ZERO, bb:$dst)>;
1313 def : MipsPat<(brcond (i32 (setugt RC:$lhs, immSExt16Plus1:$rhs)), bb:$dst),
1314               (BEQ (SLTiuOp RC:$lhs, (Plus1 imm:$rhs)), ZERO, bb:$dst)>;
1315
1316 def : MipsPat<(brcond (i32 (setle RC:$lhs, RC:$rhs)), bb:$dst),
1317               (BEQ (SLTOp RC:$rhs, RC:$lhs), ZERO, bb:$dst)>;
1318 def : MipsPat<(brcond (i32 (setule RC:$lhs, RC:$rhs)), bb:$dst),
1319               (BEQ (SLTuOp RC:$rhs, RC:$lhs), ZERO, bb:$dst)>;
1320
1321 def : MipsPat<(brcond RC:$cond, bb:$dst),
1322               (BNEOp RC:$cond, ZEROReg, bb:$dst)>;
1323 }
1324
1325 defm : BrcondPats<CPURegs, BEQ, BNE, SLT, SLTu, SLTi, SLTiu, ZERO>;
1326
1327 def : MipsPat<(brcond (i32 (setlt i32:$lhs, 1)), bb:$dst),
1328               (BLEZ i32:$lhs, bb:$dst)>;
1329 def : MipsPat<(brcond (i32 (setgt i32:$lhs, -1)), bb:$dst),
1330               (BGEZ i32:$lhs, bb:$dst)>;
1331
1332 // setcc patterns
1333 multiclass SeteqPats<RegisterClass RC, Instruction SLTiuOp, Instruction XOROp,
1334                      Instruction SLTuOp, Register ZEROReg> {
1335   def : MipsPat<(seteq RC:$lhs, 0),
1336                 (SLTiuOp RC:$lhs, 1)>;
1337   def : MipsPat<(setne RC:$lhs, 0),
1338                 (SLTuOp ZEROReg, RC:$lhs)>;
1339   def : MipsPat<(seteq RC:$lhs, RC:$rhs),
1340                 (SLTiuOp (XOROp RC:$lhs, RC:$rhs), 1)>;
1341   def : MipsPat<(setne RC:$lhs, RC:$rhs),
1342                 (SLTuOp ZEROReg, (XOROp RC:$lhs, RC:$rhs))>;
1343 }
1344
1345 multiclass SetlePats<RegisterClass RC, Instruction SLTOp, Instruction SLTuOp> {
1346   def : MipsPat<(setle RC:$lhs, RC:$rhs),
1347                 (XORi (SLTOp RC:$rhs, RC:$lhs), 1)>;
1348   def : MipsPat<(setule RC:$lhs, RC:$rhs),
1349                 (XORi (SLTuOp RC:$rhs, RC:$lhs), 1)>;
1350 }
1351
1352 multiclass SetgtPats<RegisterClass RC, Instruction SLTOp, Instruction SLTuOp> {
1353   def : MipsPat<(setgt RC:$lhs, RC:$rhs),
1354                 (SLTOp RC:$rhs, RC:$lhs)>;
1355   def : MipsPat<(setugt RC:$lhs, RC:$rhs),
1356                 (SLTuOp RC:$rhs, RC:$lhs)>;
1357 }
1358
1359 multiclass SetgePats<RegisterClass RC, Instruction SLTOp, Instruction SLTuOp> {
1360   def : MipsPat<(setge RC:$lhs, RC:$rhs),
1361                 (XORi (SLTOp RC:$lhs, RC:$rhs), 1)>;
1362   def : MipsPat<(setuge RC:$lhs, RC:$rhs),
1363                 (XORi (SLTuOp RC:$lhs, RC:$rhs), 1)>;
1364 }
1365
1366 multiclass SetgeImmPats<RegisterClass RC, Instruction SLTiOp,
1367                         Instruction SLTiuOp> {
1368   def : MipsPat<(setge RC:$lhs, immSExt16:$rhs),
1369                 (XORi (SLTiOp RC:$lhs, immSExt16:$rhs), 1)>;
1370   def : MipsPat<(setuge RC:$lhs, immSExt16:$rhs),
1371                 (XORi (SLTiuOp RC:$lhs, immSExt16:$rhs), 1)>;
1372 }
1373
1374 defm : SeteqPats<CPURegs, SLTiu, XOR, SLTu, ZERO>;
1375 defm : SetlePats<CPURegs, SLT, SLTu>;
1376 defm : SetgtPats<CPURegs, SLT, SLTu>;
1377 defm : SetgePats<CPURegs, SLT, SLTu>;
1378 defm : SetgeImmPats<CPURegs, SLTi, SLTiu>;
1379
1380 // bswap pattern
1381 def : MipsPat<(bswap CPURegs:$rt), (ROTR (WSBH CPURegs:$rt), 16)>;
1382
1383 // mflo/hi patterns.
1384 def : MipsPat<(i32 (ExtractLOHI ACRegs:$ac, imm:$lohi_idx)),
1385               (EXTRACT_SUBREG ACRegs:$ac, imm:$lohi_idx)>;
1386
1387 // Load halfword/word patterns.
1388 let AddedComplexity = 40 in {
1389   let Predicates = [NotN64, HasStdEnc] in {
1390     def : LoadRegImmPat<LBu, i32, zextloadi8>;
1391     def : LoadRegImmPat<LH, i32, sextloadi16>;
1392     def : LoadRegImmPat<LW, i32, load>;
1393   }
1394   let Predicates = [IsN64, HasStdEnc] in {
1395     def : LoadRegImmPat<LBu_P8, i32, zextloadi8>;
1396     def : LoadRegImmPat<LH_P8, i32, sextloadi16>;
1397     def : LoadRegImmPat<LW_P8, i32, load>;
1398   }
1399 }
1400
1401 //===----------------------------------------------------------------------===//
1402 // Floating Point Support
1403 //===----------------------------------------------------------------------===//
1404
1405 include "MipsInstrFPU.td"
1406 include "Mips64InstrInfo.td"
1407 include "MipsCondMov.td"
1408
1409 //
1410 // Mips16
1411
1412 include "Mips16InstrFormats.td"
1413 include "Mips16InstrInfo.td"
1414
1415 // DSP
1416 include "MipsDSPInstrFormats.td"
1417 include "MipsDSPInstrInfo.td"
1418
1419 // Micromips
1420 include "MicroMipsInstrFormats.td"
1421 include "MicroMipsInstrInfo.td"