lib/Target/Mips/MipsInstrInfo.td

   1 //===- MipsInstrInfo.td - Target Description for Mips Target -*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file contains the Mips implementation of the TargetInstrInfo class.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14
  15 //===----------------------------------------------------------------------===//
  16 // Mips profiles and nodes
  17 //===----------------------------------------------------------------------===//
  18
  19 def SDT_MipsJmpLink      : SDTypeProfile<0, 1, [SDTCisVT<0, iPTR>]>;
  20 def SDT_MipsCMov         : SDTypeProfile<1, 4, [SDTCisSameAs<0, 1>,
  21                                                 SDTCisSameAs<1, 2>,
  22                                                 SDTCisSameAs<3, 4>,
  23                                                 SDTCisInt<4>]>;
  24 def SDT_MipsCallSeqStart : SDCallSeqStart<[SDTCisVT<0, i32>]>;
  25 def SDT_MipsCallSeqEnd   : SDCallSeqEnd<[SDTCisVT<0, i32>, SDTCisVT<1, i32>]>;
  26 def SDT_MipsMAddMSub     : SDTypeProfile<0, 4,
  27                                          [SDTCisVT<0, i32>, SDTCisSameAs<0, 1>,
  28                                           SDTCisSameAs<1, 2>,
  29                                           SDTCisSameAs<2, 3>]>;
  30 def SDT_MipsDivRem       : SDTypeProfile<0, 2,
  31                                          [SDTCisInt<0>,
  32                                           SDTCisSameAs<0, 1>]>;
  33
  34 def SDT_MipsThreadPointer : SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;
  35
  36 def SDT_Sync             : SDTypeProfile<0, 1, [SDTCisVT<0, i32>]>;
  37
  38 def SDT_Ext : SDTypeProfile<1, 3, [SDTCisInt<0>, SDTCisSameAs<0, 1>,
  39                                    SDTCisVT<2, i32>, SDTCisSameAs<2, 3>]>;
  40 def SDT_Ins : SDTypeProfile<1, 4, [SDTCisInt<0>, SDTCisSameAs<0, 1>,
  41                                    SDTCisVT<2, i32>, SDTCisSameAs<2, 3>,
  42                                    SDTCisSameAs<0, 4>]>;
  43
  44 def SDTMipsLoadLR  : SDTypeProfile<1, 2,
  45                                    [SDTCisInt<0>, SDTCisPtrTy<1>,
  46                                     SDTCisSameAs<0, 2>]>;
  47
  48 // Call
  49 def MipsJmpLink : SDNode<"MipsISD::JmpLink",SDT_MipsJmpLink,
  50                          [SDNPHasChain, SDNPOutGlue, SDNPOptInGlue,
  51                           SDNPVariadic]>;
  52
  53 // Tail call
  54 def MipsTailCall : SDNode<"MipsISD::TailCall", SDT_MipsJmpLink,
  55                           [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
  56
  57 // Hi and Lo nodes are used to handle global addresses. Used on
  58 // MipsISelLowering to lower stuff like GlobalAddress, ExternalSymbol
  59 // static model. (nothing to do with Mips Registers Hi and Lo)
  60 def MipsHi    : SDNode<"MipsISD::Hi", SDTIntUnaryOp>;
  61 def MipsLo    : SDNode<"MipsISD::Lo", SDTIntUnaryOp>;
  62 def MipsGPRel : SDNode<"MipsISD::GPRel", SDTIntUnaryOp>;
  63
  64 // TlsGd node is used to handle General Dynamic TLS
  65 def MipsTlsGd : SDNode<"MipsISD::TlsGd", SDTIntUnaryOp>;
  66
  67 // TprelHi and TprelLo nodes are used to handle Local Exec TLS
  68 def MipsTprelHi    : SDNode<"MipsISD::TprelHi", SDTIntUnaryOp>;
  69 def MipsTprelLo    : SDNode<"MipsISD::TprelLo", SDTIntUnaryOp>;
  70
  71 // Thread pointer
  72 def MipsThreadPointer: SDNode<"MipsISD::ThreadPointer", SDT_MipsThreadPointer>;
  73
  74 // Return
  75 def MipsRet : SDNode<"MipsISD::Ret", SDTNone, [SDNPHasChain, SDNPOptInGlue]>;
  76
  77 // These are target-independent nodes, but have target-specific formats.
  78 def callseq_start : SDNode<"ISD::CALLSEQ_START", SDT_MipsCallSeqStart,
  79                            [SDNPHasChain, SDNPSideEffect, SDNPOutGlue]>;
  80 def callseq_end   : SDNode<"ISD::CALLSEQ_END", SDT_MipsCallSeqEnd,
  81                            [SDNPHasChain, SDNPSideEffect,
  82                             SDNPOptInGlue, SDNPOutGlue]>;
  83
  84 // MAdd*/MSub* nodes
  85 def MipsMAdd      : SDNode<"MipsISD::MAdd", SDT_MipsMAddMSub,
  86                            [SDNPOptInGlue, SDNPOutGlue]>;
  87 def MipsMAddu     : SDNode<"MipsISD::MAddu", SDT_MipsMAddMSub,
  88                            [SDNPOptInGlue, SDNPOutGlue]>;
  89 def MipsMSub      : SDNode<"MipsISD::MSub", SDT_MipsMAddMSub,
  90                            [SDNPOptInGlue, SDNPOutGlue]>;
  91 def MipsMSubu     : SDNode<"MipsISD::MSubu", SDT_MipsMAddMSub,
  92                            [SDNPOptInGlue, SDNPOutGlue]>;
  93
  94 // DivRem(u) nodes
  95 def MipsDivRem    : SDNode<"MipsISD::DivRem", SDT_MipsDivRem,
  96                            [SDNPOutGlue]>;
  97 def MipsDivRemU   : SDNode<"MipsISD::DivRemU", SDT_MipsDivRem,
  98                            [SDNPOutGlue]>;
  99
 100 // Target constant nodes that are not part of any isel patterns and remain
 101 // unchanged can cause instructions with illegal operands to be emitted.
 102 // Wrapper node patterns give the instruction selector a chance to replace
 103 // target constant nodes that would otherwise remain unchanged with ADDiu
 104 // nodes. Without these wrapper node patterns, the following conditional move
 105 // instrucion is emitted when function cmov2 in test/CodeGen/Mips/cmov.ll is
 106 // compiled:
 107 //  movn  %got(d)($gp), %got(c)($gp), $4
 108 // This instruction is illegal since movn can take only register operands.
 109
 110 def MipsWrapper    : SDNode<"MipsISD::Wrapper", SDTIntBinOp>;
 111
 112 def MipsSync : SDNode<"MipsISD::Sync", SDT_Sync, [SDNPHasChain,SDNPSideEffect]>;
 113
 114 def MipsExt :  SDNode<"MipsISD::Ext", SDT_Ext>;
 115 def MipsIns :  SDNode<"MipsISD::Ins", SDT_Ins>;
 116
 117 def MipsLWL : SDNode<"MipsISD::LWL", SDTMipsLoadLR,
 118                      [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 119 def MipsLWR : SDNode<"MipsISD::LWR", SDTMipsLoadLR,
 120                      [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 121 def MipsSWL : SDNode<"MipsISD::SWL", SDTStore,
 122                      [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 123 def MipsSWR : SDNode<"MipsISD::SWR", SDTStore,
 124                      [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 125 def MipsLDL : SDNode<"MipsISD::LDL", SDTMipsLoadLR,
 126                      [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 127 def MipsLDR : SDNode<"MipsISD::LDR", SDTMipsLoadLR,
 128                      [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 129 def MipsSDL : SDNode<"MipsISD::SDL", SDTStore,
 130                      [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 131 def MipsSDR : SDNode<"MipsISD::SDR", SDTStore,
 132                      [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 133
 134 //===----------------------------------------------------------------------===//
 135 // Mips Instruction Predicate Definitions.
 136 //===----------------------------------------------------------------------===//
 137 def HasSEInReg  :     Predicate<"Subtarget.hasSEInReg()">,
 138                       AssemblerPredicate<"FeatureSEInReg">;
 139 def HasBitCount :     Predicate<"Subtarget.hasBitCount()">,
 140                       AssemblerPredicate<"FeatureBitCount">;
 141 def HasSwap     :     Predicate<"Subtarget.hasSwap()">,
 142                       AssemblerPredicate<"FeatureSwap">;
 143 def HasCondMov  :     Predicate<"Subtarget.hasCondMov()">,
 144                       AssemblerPredicate<"FeatureCondMov">;
 145 def HasFPIdx    :     Predicate<"Subtarget.hasFPIdx()">,
 146                       AssemblerPredicate<"FeatureFPIdx">;
 147 def HasMips32    :    Predicate<"Subtarget.hasMips32()">,
 148                       AssemblerPredicate<"FeatureMips32">;
 149 def HasMips32r2  :    Predicate<"Subtarget.hasMips32r2()">,
 150                       AssemblerPredicate<"FeatureMips32r2">;
 151 def HasMips64    :    Predicate<"Subtarget.hasMips64()">,
 152                       AssemblerPredicate<"FeatureMips64">;
 153 def NotMips64    :    Predicate<"!Subtarget.hasMips64()">,
 154                       AssemblerPredicate<"!FeatureMips64">;
 155 def HasMips64r2  :    Predicate<"Subtarget.hasMips64r2()">,
 156                       AssemblerPredicate<"FeatureMips64r2">;
 157 def IsN64       :     Predicate<"Subtarget.isABI_N64()">,
 158                       AssemblerPredicate<"FeatureN64">;
 159 def NotN64      :     Predicate<"!Subtarget.isABI_N64()">,
 160                       AssemblerPredicate<"!FeatureN64">;
 161 def InMips16Mode :    Predicate<"Subtarget.inMips16Mode()">,
 162                       AssemblerPredicate<"FeatureMips16">;
 163 def RelocStatic :     Predicate<"TM.getRelocationModel() == Reloc::Static">,
 164                       AssemblerPredicate<"FeatureMips32">;
 165 def RelocPIC    :     Predicate<"TM.getRelocationModel() == Reloc::PIC_">,
 166                       AssemblerPredicate<"FeatureMips32">;
 167 def NoNaNsFPMath :    Predicate<"TM.Options.NoNaNsFPMath">,
 168                       AssemblerPredicate<"FeatureMips32">;
 169 def HasStdEnc :       Predicate<"Subtarget.hasStandardEncoding()">,
 170                       AssemblerPredicate<"!FeatureMips16">;
 171
 172 class MipsPat<dag pattern, dag result> : Pat<pattern, result> {
 173   let Predicates = [HasStdEnc];
 174 }
 175
 176 class IsCommutable {
 177   bit isCommutable = 1;
 178 }
 179
 180 class IsBranch {
 181   bit isBranch = 1;
 182 }
 183
 184 class IsReturn {
 185   bit isReturn = 1;
 186 }
 187
 188 class IsCall {
 189   bit isCall = 1;
 190 }
 191
 192 class IsTailCall {
 193   bit isCall = 1;
 194   bit isTerminator = 1;
 195   bit isReturn = 1;
 196   bit isBarrier = 1;
 197   bit hasExtraSrcRegAllocReq = 1;
 198   bit isCodeGenOnly = 1;
 199 }
 200
 201 class IsAsCheapAsAMove {
 202   bit isAsCheapAsAMove = 1;
 203 }
 204
 205 class NeverHasSideEffects {
 206   bit neverHasSideEffects = 1;
 207 }
 208
 209 //===----------------------------------------------------------------------===//
 210 // Instruction format superclass
 211 //===----------------------------------------------------------------------===//
 212
 213 include "MipsInstrFormats.td"
 214
 215 //===----------------------------------------------------------------------===//
 216 // Mips Operand, Complex Patterns and Transformations Definitions.
 217 //===----------------------------------------------------------------------===//
 218
 219 // Instruction operand types
 220 def jmptarget   : Operand<OtherVT> {
 221   let EncoderMethod = "getJumpTargetOpValue";
 222 }
 223 def brtarget    : Operand<OtherVT> {
 224   let EncoderMethod = "getBranchTargetOpValue";
 225   let OperandType = "OPERAND_PCREL";
 226   let DecoderMethod = "DecodeBranchTarget";
 227 }
 228 def calltarget  : Operand<iPTR> {
 229   let EncoderMethod = "getJumpTargetOpValue";
 230 }
 231 def calltarget64: Operand<i64>;
 232 def simm16      : Operand<i32> {
 233   let DecoderMethod= "DecodeSimm16";
 234 }
 235 def simm16_64   : Operand<i64>;
 236 def shamt       : Operand<i32>;
 237
 238 // Unsigned Operand
 239 def uimm16      : Operand<i32> {
 240   let PrintMethod = "printUnsignedImm";
 241 }
 242
 243 def MipsMemAsmOperand : AsmOperandClass {
 244   let Name = "Mem";
 245   let ParserMethod = "parseMemOperand";
 246 }
 247
 248 // Address operand
 249 def mem : Operand<i32> {
 250   let PrintMethod = "printMemOperand";
 251   let MIOperandInfo = (ops CPURegs, simm16);
 252   let EncoderMethod = "getMemEncoding";
 253   let ParserMatchClass = MipsMemAsmOperand;
 254 }
 255
 256 def mem64 : Operand<i64> {
 257   let PrintMethod = "printMemOperand";
 258   let MIOperandInfo = (ops CPU64Regs, simm16_64);
 259   let EncoderMethod = "getMemEncoding";
 260   let ParserMatchClass = MipsMemAsmOperand;
 261 }
 262
 263 def mem_ea : Operand<i32> {
 264   let PrintMethod = "printMemOperandEA";
 265   let MIOperandInfo = (ops CPURegs, simm16);
 266   let EncoderMethod = "getMemEncoding";
 267 }
 268
 269 def mem_ea_64 : Operand<i64> {
 270   let PrintMethod = "printMemOperandEA";
 271   let MIOperandInfo = (ops CPU64Regs, simm16_64);
 272   let EncoderMethod = "getMemEncoding";
 273 }
 274
 275 // size operand of ext instruction
 276 def size_ext : Operand<i32> {
 277   let EncoderMethod = "getSizeExtEncoding";
 278   let DecoderMethod = "DecodeExtSize";
 279 }
 280
 281 // size operand of ins instruction
 282 def size_ins : Operand<i32> {
 283   let EncoderMethod = "getSizeInsEncoding";
 284   let DecoderMethod = "DecodeInsSize";
 285 }
 286
 287 // Transformation Function - get the lower 16 bits.
 288 def LO16 : SDNodeXForm<imm, [{
 289   return getImm(N, N->getZExtValue() & 0xFFFF);
 290 }]>;
 291
 292 // Transformation Function - get the higher 16 bits.
 293 def HI16 : SDNodeXForm<imm, [{
 294   return getImm(N, (N->getZExtValue() >> 16) & 0xFFFF);
 295 }]>;
 296
 297 // Node immediate fits as 16-bit sign extended on target immediate.
 298 // e.g. addi, andi
 299 def immSExt16  : PatLeaf<(imm), [{ return isInt<16>(N->getSExtValue()); }]>;
 300
 301 // Node immediate fits as 16-bit zero extended on target immediate.
 302 // The LO16 param means that only the lower 16 bits of the node
 303 // immediate are caught.
 304 // e.g. addiu, sltiu
 305 def immZExt16  : PatLeaf<(imm), [{
 306   if (N->getValueType(0) == MVT::i32)
 307     return (uint32_t)N->getZExtValue() == (unsigned short)N->getZExtValue();
 308   else
 309     return (uint64_t)N->getZExtValue() == (unsigned short)N->getZExtValue();
 310 }], LO16>;
 311
 312 // Immediate can be loaded with LUi (32-bit int with lower 16-bit cleared).
 313 def immLow16Zero : PatLeaf<(imm), [{
 314   int64_t Val = N->getSExtValue();
 315   return isInt<32>(Val) && !(Val & 0xffff);
 316 }]>;
 317
 318 // shamt field must fit in 5 bits.
 319 def immZExt5 : ImmLeaf<i32, [{return Imm == (Imm & 0x1f);}]>;
 320
 321 // Mips Address Mode! SDNode frameindex could possibily be a match
 322 // since load and store instructions from stack used it.
 323 def addr :
 324   ComplexPattern<iPTR, 2, "SelectAddr", [frameindex], [SDNPWantParent]>;
 325
 326 //===----------------------------------------------------------------------===//
 327 // Instructions specific format
 328 //===----------------------------------------------------------------------===//
 329
 330 /// Move Control Registers From/To CPU Registers
 331 def MFC0_3OP  : MFC3OP<0x10, 0, (outs CPURegs:$rt),
 332                        (ins CPURegs:$rd, uimm16:$sel),"mfc0\t$rt, $rd, $sel">;
 333 def : InstAlias<"mfc0 $rt, $rd", (MFC0_3OP CPURegs:$rt, CPURegs:$rd, 0)>;
 334
 335 def MTC0_3OP  : MFC3OP<0x10, 4, (outs CPURegs:$rd, uimm16:$sel),
 336                        (ins CPURegs:$rt),"mtc0\t$rt, $rd, $sel">;
 337 def : InstAlias<"mtc0 $rt, $rd", (MTC0_3OP CPURegs:$rd, 0, CPURegs:$rt)>;
 338
 339 def MFC2_3OP  : MFC3OP<0x12, 0, (outs CPURegs:$rt),
 340                        (ins CPURegs:$rd, uimm16:$sel),"mfc2\t$rt, $rd, $sel">;
 341 def : InstAlias<"mfc2 $rt, $rd", (MFC2_3OP CPURegs:$rt, CPURegs:$rd, 0)>;
 342
 343 def MTC2_3OP  : MFC3OP<0x12, 4, (outs CPURegs:$rd, uimm16:$sel),
 344                        (ins CPURegs:$rt),"mtc2\t$rt, $rd, $sel">;
 345 def : InstAlias<"mtc2 $rt, $rd", (MTC2_3OP CPURegs:$rd, 0, CPURegs:$rt)>;
 346
 347 // Arithmetic and logical instructions with 3 register operands.
 348 class ArithLogicR<string opstr, RegisterClass RC, bit isComm = 0,
 349                   InstrItinClass Itin = NoItinerary,
 350                   SDPatternOperator OpNode = null_frag>:
 351   InstSE<(outs RC:$rd), (ins RC:$rs, RC:$rt),
 352          !strconcat(opstr, "\t$rd, $rs, $rt"),
 353          [(set RC:$rd, (OpNode RC:$rs, RC:$rt))], Itin, FrmR> {
 354   let isCommutable = isComm;
 355   let isReMaterializable = 1;
 356 }
 357
 358 // Arithmetic and logical instructions with 2 register operands.
 359 class ArithLogicI<string opstr, Operand Od, RegisterClass RC,
 360                   SDPatternOperator imm_type = null_frag,
 361                   SDPatternOperator OpNode = null_frag> :
 362   InstSE<(outs RC:$rt), (ins RC:$rs, Od:$imm16),
 363          !strconcat(opstr, "\t$rt, $rs, $imm16"),
 364          [(set RC:$rt, (OpNode RC:$rs, imm_type:$imm16))], IIAlu, FrmI> {
 365   let isReMaterializable = 1;
 366 }
 367
 368 // Arithmetic Multiply ADD/SUB
 369 let rd = 0, shamt = 0, Defs = [HI, LO], Uses = [HI, LO] in
 370 class MArithR<bits<6> func, string instr_asm, SDNode op, bit isComm = 0> :
 371   FR<0x1c, func, (outs), (ins CPURegs:$rs, CPURegs:$rt),
 372      !strconcat(instr_asm, "\t$rs, $rt"),
 373      [(op CPURegs:$rs, CPURegs:$rt, LO, HI)], IIImul> {
 374   let rd = 0;
 375   let shamt = 0;
 376   let isCommutable = isComm;
 377 }
 378
 379 //  Logical
 380 class LogicNOR<bits<6> op, bits<6> func, string instr_asm, RegisterClass RC>:
 381   FR<op, func, (outs RC:$rd), (ins RC:$rs, RC:$rt),
 382      !strconcat(instr_asm, "\t$rd, $rs, $rt"),
 383      [(set RC:$rd, (not (or RC:$rs, RC:$rt)))], IIAlu> {
 384   let shamt = 0;
 385   let isCommutable = 1;
 386 }
 387
 388 // Shifts
 389 class shift_rotate_imm<string opstr, PatFrag PF, Operand ImmOpnd,
 390                        RegisterClass RC, SDPatternOperator OpNode> :
 391   InstSE<(outs RC:$rd), (ins RC:$rt, ImmOpnd:$shamt),
 392          !strconcat(opstr, "\t$rd, $rt, $shamt"),
 393          [(set RC:$rd, (OpNode RC:$rt, PF:$shamt))], IIAlu, FrmR>;
 394
 395 // 32-bit shift instructions.
 396 class shift_rotate_imm32<string opstr, SDPatternOperator OpNode = null_frag> :
 397   shift_rotate_imm<opstr, immZExt5, shamt, CPURegs, OpNode>;
 398
 399 class shift_rotate_reg<string opstr, SDNode OpNode, RegisterClass RC>:
 400   InstSE<(outs RC:$rd), (ins CPURegs:$rs, RC:$rt),
 401          !strconcat(opstr, "\t$rd, $rt, $rs"),
 402          [(set RC:$rd, (OpNode RC:$rt, CPURegs:$rs))], IIAlu, FrmR>;
 403
 404 // Load Upper Imediate
 405 class LoadUpper<bits<6> op, string instr_asm, RegisterClass RC, Operand Imm>:
 406   FI<op, (outs RC:$rt), (ins Imm:$imm16),
 407      !strconcat(instr_asm, "\t$rt, $imm16"), [], IIAlu>, IsAsCheapAsAMove {
 408   let rs = 0;
 409   let neverHasSideEffects = 1;
 410   let isReMaterializable = 1;
 411 }
 412
 413 class FMem<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern,
 414           InstrItinClass itin>: FFI<op, outs, ins, asmstr, pattern> {
 415   bits<21> addr;
 416   let Inst{25-21} = addr{20-16};
 417   let Inst{15-0}  = addr{15-0};
 418   let DecoderMethod = "DecodeMem";
 419 }
 420
 421 // Memory Load/Store
 422 let canFoldAsLoad = 1 in
 423 class LoadM<bits<6> op, string instr_asm, PatFrag OpNode, RegisterClass RC,
 424             Operand MemOpnd, bit Pseudo>:
 425   FMem<op, (outs RC:$rt), (ins MemOpnd:$addr),
 426      !strconcat(instr_asm, "\t$rt, $addr"),
 427      [(set RC:$rt, (OpNode addr:$addr))], IILoad> {
 428   let isPseudo = Pseudo;
 429 }
 430
 431 class StoreM<bits<6> op, string instr_asm, PatFrag OpNode, RegisterClass RC,
 432              Operand MemOpnd, bit Pseudo>:
 433   FMem<op, (outs), (ins RC:$rt, MemOpnd:$addr),
 434      !strconcat(instr_asm, "\t$rt, $addr"),
 435      [(OpNode RC:$rt, addr:$addr)], IIStore> {
 436   let isPseudo = Pseudo;
 437 }
 438
 439 // 32-bit load.
 440 multiclass LoadM32<bits<6> op, string instr_asm, PatFrag OpNode,
 441                    bit Pseudo = 0> {
 442   def #NAME# : LoadM<op, instr_asm, OpNode, CPURegs, mem, Pseudo>,
 443                Requires<[NotN64, HasStdEnc]>;
 444   def _P8    : LoadM<op, instr_asm, OpNode, CPURegs, mem64, Pseudo>,
 445                Requires<[IsN64, HasStdEnc]> {
 446     let DecoderNamespace = "Mips64";
 447     let isCodeGenOnly = 1;
 448   }
 449 }
 450
 451 // 64-bit load.
 452 multiclass LoadM64<bits<6> op, string instr_asm, PatFrag OpNode,
 453                    bit Pseudo = 0> {
 454   def #NAME# : LoadM<op, instr_asm, OpNode, CPU64Regs, mem, Pseudo>,
 455                Requires<[NotN64, HasStdEnc]>;
 456   def _P8    : LoadM<op, instr_asm, OpNode, CPU64Regs, mem64, Pseudo>,
 457                Requires<[IsN64, HasStdEnc]> {
 458     let DecoderNamespace = "Mips64";
 459     let isCodeGenOnly = 1;
 460   }
 461 }
 462
 463 // 32-bit store.
 464 multiclass StoreM32<bits<6> op, string instr_asm, PatFrag OpNode,
 465                     bit Pseudo = 0> {
 466   def #NAME# : StoreM<op, instr_asm, OpNode, CPURegs, mem, Pseudo>,
 467                Requires<[NotN64, HasStdEnc]>;
 468   def _P8    : StoreM<op, instr_asm, OpNode, CPURegs, mem64, Pseudo>,
 469                Requires<[IsN64, HasStdEnc]> {
 470     let DecoderNamespace = "Mips64";
 471     let isCodeGenOnly = 1;
 472   }
 473 }
 474
 475 // 64-bit store.
 476 multiclass StoreM64<bits<6> op, string instr_asm, PatFrag OpNode,
 477                     bit Pseudo = 0> {
 478   def #NAME# : StoreM<op, instr_asm, OpNode, CPU64Regs, mem, Pseudo>,
 479                Requires<[NotN64, HasStdEnc]>;
 480   def _P8    : StoreM<op, instr_asm, OpNode, CPU64Regs, mem64, Pseudo>,
 481                Requires<[IsN64, HasStdEnc]> {
 482     let DecoderNamespace = "Mips64";
 483     let isCodeGenOnly = 1;
 484   }
 485 }
 486
 487 // Load/Store Left/Right
 488 let canFoldAsLoad = 1 in
 489 class LoadLeftRight<bits<6> op, string instr_asm, SDNode OpNode,
 490                     RegisterClass RC, Operand MemOpnd> :
 491   FMem<op, (outs RC:$rt), (ins MemOpnd:$addr, RC:$src),
 492        !strconcat(instr_asm, "\t$rt, $addr"),
 493        [(set RC:$rt, (OpNode addr:$addr, RC:$src))], IILoad> {
 494   string Constraints = "$src = $rt";
 495 }
 496
 497 class StoreLeftRight<bits<6> op, string instr_asm, SDNode OpNode,
 498                      RegisterClass RC, Operand MemOpnd>:
 499   FMem<op, (outs), (ins RC:$rt, MemOpnd:$addr),
 500        !strconcat(instr_asm, "\t$rt, $addr"), [(OpNode RC:$rt, addr:$addr)],
 501        IIStore>;
 502
 503 // 32-bit load left/right.
 504 multiclass LoadLeftRightM32<bits<6> op, string instr_asm, SDNode OpNode> {
 505   def #NAME# : LoadLeftRight<op, instr_asm, OpNode, CPURegs, mem>,
 506                Requires<[NotN64, HasStdEnc]>;
 507   def _P8    : LoadLeftRight<op, instr_asm, OpNode, CPURegs, mem64>,
 508                Requires<[IsN64, HasStdEnc]> {
 509     let DecoderNamespace = "Mips64";
 510     let isCodeGenOnly = 1;
 511   }
 512 }
 513
 514 // 64-bit load left/right.
 515 multiclass LoadLeftRightM64<bits<6> op, string instr_asm, SDNode OpNode> {
 516   def #NAME# : LoadLeftRight<op, instr_asm, OpNode, CPU64Regs, mem>,
 517                Requires<[NotN64, HasStdEnc]>;
 518   def _P8    : LoadLeftRight<op, instr_asm, OpNode, CPU64Regs, mem64>,
 519                Requires<[IsN64, HasStdEnc]> {
 520     let DecoderNamespace = "Mips64";
 521     let isCodeGenOnly = 1;
 522   }
 523 }
 524
 525 // 32-bit store left/right.
 526 multiclass StoreLeftRightM32<bits<6> op, string instr_asm, SDNode OpNode> {
 527   def #NAME# : StoreLeftRight<op, instr_asm, OpNode, CPURegs, mem>,
 528                Requires<[NotN64, HasStdEnc]>;
 529   def _P8    : StoreLeftRight<op, instr_asm, OpNode, CPURegs, mem64>,
 530                Requires<[IsN64, HasStdEnc]> {
 531     let DecoderNamespace = "Mips64";
 532     let isCodeGenOnly = 1;
 533   }
 534 }
 535
 536 // 64-bit store left/right.
 537 multiclass StoreLeftRightM64<bits<6> op, string instr_asm, SDNode OpNode> {
 538   def #NAME# : StoreLeftRight<op, instr_asm, OpNode, CPU64Regs, mem>,
 539                Requires<[NotN64, HasStdEnc]>;
 540   def _P8    : StoreLeftRight<op, instr_asm, OpNode, CPU64Regs, mem64>,
 541                Requires<[IsN64, HasStdEnc]> {
 542     let DecoderNamespace = "Mips64";
 543     let isCodeGenOnly = 1;
 544   }
 545 }
 546
 547 // Conditional Branch
 548 class CBranch<bits<6> op, string instr_asm, PatFrag cond_op, RegisterClass RC>:
 549   BranchBase<op, (outs), (ins RC:$rs, RC:$rt, brtarget:$imm16),
 550              !strconcat(instr_asm, "\t$rs, $rt, $imm16"),
 551              [(brcond (i32 (cond_op RC:$rs, RC:$rt)), bb:$imm16)], IIBranch> {
 552   let isBranch = 1;
 553   let isTerminator = 1;
 554   let hasDelaySlot = 1;
 555   let Defs = [AT];
 556 }
 557
 558 class CBranchZero<bits<6> op, bits<5> _rt, string instr_asm, PatFrag cond_op,
 559                   RegisterClass RC>:
 560   BranchBase<op, (outs), (ins RC:$rs, brtarget:$imm16),
 561              !strconcat(instr_asm, "\t$rs, $imm16"),
 562              [(brcond (i32 (cond_op RC:$rs, 0)), bb:$imm16)], IIBranch> {
 563   let rt = _rt;
 564   let isBranch = 1;
 565   let isTerminator = 1;
 566   let hasDelaySlot = 1;
 567   let Defs = [AT];
 568 }
 569
 570 // SetCC
 571 class SetCC_R<bits<6> op, bits<6> func, string instr_asm, PatFrag cond_op,
 572               RegisterClass RC>:
 573   FR<op, func, (outs CPURegs:$rd), (ins RC:$rs, RC:$rt),
 574      !strconcat(instr_asm, "\t$rd, $rs, $rt"),
 575      [(set CPURegs:$rd, (cond_op RC:$rs, RC:$rt))],
 576      IIAlu> {
 577   let shamt = 0;
 578 }
 579
 580 class SetCC_I<bits<6> op, string instr_asm, PatFrag cond_op, Operand Od,
 581               PatLeaf imm_type, RegisterClass RC>:
 582   FI<op, (outs CPURegs:$rt), (ins RC:$rs, Od:$imm16),
 583      !strconcat(instr_asm, "\t$rt, $rs, $imm16"),
 584      [(set CPURegs:$rt, (cond_op RC:$rs, imm_type:$imm16))],
 585      IIAlu>;
 586
 587 // Jump
 588 class JumpFJ<bits<6> op, DAGOperand opnd, string instr_asm,
 589              SDPatternOperator operator, SDPatternOperator targetoperator>:
 590   FJ<op, (outs), (ins opnd:$target), !strconcat(instr_asm, "\t$target"),
 591      [(operator targetoperator:$target)], IIBranch> {
 592   let isTerminator=1;
 593   let isBarrier=1;
 594   let hasDelaySlot = 1;
 595   let DecoderMethod = "DecodeJumpTarget";
 596   let Defs = [AT];
 597 }
 598
 599 // Unconditional branch
 600 class UncondBranch<bits<6> op, string instr_asm>:
 601   BranchBase<op, (outs), (ins brtarget:$imm16),
 602              !strconcat(instr_asm, "\t$imm16"), [(br bb:$imm16)], IIBranch> {
 603   let rs = 0;
 604   let rt = 0;
 605   let isBranch = 1;
 606   let isTerminator = 1;
 607   let isBarrier = 1;
 608   let hasDelaySlot = 1;
 609   let Predicates = [RelocPIC, HasStdEnc];
 610   let Defs = [AT];
 611 }
 612
 613 // Base class for indirect branch and return instruction classes.
 614 let isTerminator=1, isBarrier=1, hasDelaySlot = 1 in
 615 class JumpFR<RegisterClass RC, SDPatternOperator operator = null_frag>:
 616   FR<0, 0x8, (outs), (ins RC:$rs), "jr\t$rs", [(operator RC:$rs)], IIBranch> {
 617   let rt = 0;
 618   let rd = 0;
 619   let shamt = 0;
 620 }
 621
 622 // Indirect branch
 623 class IndirectBranch<RegisterClass RC>: JumpFR<RC, brind> {
 624   let isBranch = 1;
 625   let isIndirectBranch = 1;
 626 }
 627
 628 // Return instruction
 629 class RetBase<RegisterClass RC>: JumpFR<RC> {
 630   let isReturn = 1;
 631   let isCodeGenOnly = 1;
 632   let hasCtrlDep = 1;
 633   let hasExtraSrcRegAllocReq = 1;
 634 }
 635
 636 // Jump and Link (Call)
 637 let isCall=1, hasDelaySlot=1, Defs = [RA] in {
 638   class JumpLink<bits<6> op, string instr_asm>:
 639     FJ<op, (outs), (ins calltarget:$target),
 640        !strconcat(instr_asm, "\t$target"), [(MipsJmpLink imm:$target)],
 641        IIBranch> {
 642        let DecoderMethod = "DecodeJumpTarget";
 643        }
 644
 645   class JumpLinkReg<bits<6> op, bits<6> func, string instr_asm,
 646                     RegisterClass RC>:
 647     FR<op, func, (outs), (ins RC:$rs),
 648        !strconcat(instr_asm, "\t$rs"), [(MipsJmpLink RC:$rs)], IIBranch> {
 649     let rt = 0;
 650     let rd = 31;
 651     let shamt = 0;
 652   }
 653
 654   class BranchLink<string instr_asm, bits<5> _rt, RegisterClass RC>:
 655     FI<0x1, (outs), (ins RC:$rs, brtarget:$imm16),
 656        !strconcat(instr_asm, "\t$rs, $imm16"), [], IIBranch> {
 657     let rt = _rt;
 658   }
 659 }
 660
 661 // Mul, Div
 662 class Mult<bits<6> func, string instr_asm, InstrItinClass itin,
 663            RegisterClass RC, list<Register> DefRegs>:
 664   FR<0x00, func, (outs), (ins RC:$rs, RC:$rt),
 665      !strconcat(instr_asm, "\t$rs, $rt"), [], itin> {
 666   let rd = 0;
 667   let shamt = 0;
 668   let isCommutable = 1;
 669   let Defs = DefRegs;
 670   let neverHasSideEffects = 1;
 671 }
 672
 673 class Mult32<bits<6> func, string instr_asm, InstrItinClass itin>:
 674   Mult<func, instr_asm, itin, CPURegs, [HI, LO]>;
 675
 676 class Div<SDNode op, bits<6> func, string instr_asm, InstrItinClass itin,
 677           RegisterClass RC, list<Register> DefRegs>:
 678   FR<0x00, func, (outs), (ins RC:$rs, RC:$rt),
 679      !strconcat(instr_asm, "\t$$zero, $rs, $rt"),
 680      [(op RC:$rs, RC:$rt)], itin> {
 681   let rd = 0;
 682   let shamt = 0;
 683   let Defs = DefRegs;
 684 }
 685
 686 class Div32<SDNode op, bits<6> func, string instr_asm, InstrItinClass itin>:
 687   Div<op, func, instr_asm, itin, CPURegs, [HI, LO]>;
 688
 689 // Move from Hi/Lo
 690 class MoveFromLOHI<bits<6> func, string instr_asm, RegisterClass RC,
 691                    list<Register> UseRegs>:
 692   FR<0x00, func, (outs RC:$rd), (ins),
 693      !strconcat(instr_asm, "\t$rd"), [], IIHiLo> {
 694   let rs = 0;
 695   let rt = 0;
 696   let shamt = 0;
 697   let Uses = UseRegs;
 698   let neverHasSideEffects = 1;
 699 }
 700
 701 class MoveToLOHI<bits<6> func, string instr_asm, RegisterClass RC,
 702                  list<Register> DefRegs>:
 703   FR<0x00, func, (outs), (ins RC:$rs),
 704      !strconcat(instr_asm, "\t$rs"), [], IIHiLo> {
 705   let rt = 0;
 706   let rd = 0;
 707   let shamt = 0;
 708   let Defs = DefRegs;
 709   let neverHasSideEffects = 1;
 710 }
 711
 712 class EffectiveAddress<bits<6> opc, string instr_asm, RegisterClass RC, Operand Mem> :
 713   FMem<opc, (outs RC:$rt), (ins Mem:$addr),
 714      instr_asm, [(set RC:$rt, addr:$addr)], IIAlu> {
 715  let isCodeGenOnly = 1;
 716 }
 717
 718 // Count Leading Ones/Zeros in Word
 719 class CountLeading0<bits<6> func, string instr_asm, RegisterClass RC>:
 720   FR<0x1c, func, (outs RC:$rd), (ins RC:$rs),
 721      !strconcat(instr_asm, "\t$rd, $rs"),
 722      [(set RC:$rd, (ctlz RC:$rs))], IIAlu>,
 723      Requires<[HasBitCount, HasStdEnc]> {
 724   let shamt = 0;
 725   let rt = rd;
 726 }
 727
 728 class CountLeading1<bits<6> func, string instr_asm, RegisterClass RC>:
 729   FR<0x1c, func, (outs RC:$rd), (ins RC:$rs),
 730      !strconcat(instr_asm, "\t$rd, $rs"),
 731      [(set RC:$rd, (ctlz (not RC:$rs)))], IIAlu>,
 732      Requires<[HasBitCount, HasStdEnc]> {
 733   let shamt = 0;
 734   let rt = rd;
 735 }
 736
 737 // Sign Extend in Register.
 738 class SignExtInReg<bits<5> sa, string instr_asm, ValueType vt,
 739                    RegisterClass RC>:
 740   FR<0x1f, 0x20, (outs RC:$rd), (ins RC:$rt),
 741      !strconcat(instr_asm, "\t$rd, $rt"),
 742      [(set RC:$rd, (sext_inreg RC:$rt, vt))], NoItinerary> {
 743   let rs = 0;
 744   let shamt = sa;
 745   let Predicates = [HasSEInReg, HasStdEnc];
 746 }
 747
 748 // Subword Swap
 749 class SubwordSwap<bits<6> func, bits<5> sa, string instr_asm, RegisterClass RC>:
 750   FR<0x1f, func, (outs RC:$rd), (ins RC:$rt),
 751      !strconcat(instr_asm, "\t$rd, $rt"), [], NoItinerary> {
 752   let rs = 0;
 753   let shamt = sa;
 754   let Predicates = [HasSwap, HasStdEnc];
 755   let neverHasSideEffects = 1;
 756 }
 757
 758 // Read Hardware
 759 class ReadHardware<RegisterClass CPURegClass, RegisterClass HWRegClass>
 760   : FR<0x1f, 0x3b, (outs CPURegClass:$rt), (ins HWRegClass:$rd),
 761        "rdhwr\t$rt, $rd", [], IIAlu> {
 762   let rs = 0;
 763   let shamt = 0;
 764 }
 765
 766 // Ext and Ins
 767 class ExtBase<bits<6> _funct, string instr_asm, RegisterClass RC>:
 768   FR<0x1f, _funct, (outs RC:$rt), (ins RC:$rs, uimm16:$pos, size_ext:$sz),
 769      !strconcat(instr_asm, " $rt, $rs, $pos, $sz"),
 770      [(set RC:$rt, (MipsExt RC:$rs, imm:$pos, imm:$sz))], NoItinerary> {
 771   bits<5> pos;
 772   bits<5> sz;
 773   let rd = sz;
 774   let shamt = pos;
 775   let Predicates = [HasMips32r2, HasStdEnc];
 776 }
 777
 778 class InsBase<bits<6> _funct, string instr_asm, RegisterClass RC>:
 779   FR<0x1f, _funct, (outs RC:$rt),
 780      (ins RC:$rs, uimm16:$pos, size_ins:$sz, RC:$src),
 781      !strconcat(instr_asm, " $rt, $rs, $pos, $sz"),
 782      [(set RC:$rt, (MipsIns RC:$rs, imm:$pos, imm:$sz, RC:$src))],
 783      NoItinerary> {
 784   bits<5> pos;
 785   bits<5> sz;
 786   let rd = sz;
 787   let shamt = pos;
 788   let Predicates = [HasMips32r2, HasStdEnc];
 789   let Constraints = "$src = $rt";
 790 }
 791
 792 // Atomic instructions with 2 source operands (ATOMIC_SWAP & ATOMIC_LOAD_*).
 793 class Atomic2Ops<PatFrag Op, string Opstr, RegisterClass DRC,
 794                  RegisterClass PRC> :
 795   PseudoSE<(outs DRC:$dst), (ins PRC:$ptr, DRC:$incr),
 796            !strconcat("atomic_", Opstr, "\t$dst, $ptr, $incr"),
 797            [(set DRC:$dst, (Op PRC:$ptr, DRC:$incr))]>;
 798
 799 multiclass Atomic2Ops32<PatFrag Op, string Opstr> {
 800   def #NAME# : Atomic2Ops<Op, Opstr, CPURegs, CPURegs>,
 801                           Requires<[NotN64, HasStdEnc]>;
 802   def _P8    : Atomic2Ops<Op, Opstr, CPURegs, CPU64Regs>,
 803                           Requires<[IsN64, HasStdEnc]> {
 804     let DecoderNamespace = "Mips64";
 805   }
 806 }
 807
 808 // Atomic Compare & Swap.
 809 class AtomicCmpSwap<PatFrag Op, string Width, RegisterClass DRC,
 810                     RegisterClass PRC> :
 811   PseudoSE<(outs DRC:$dst), (ins PRC:$ptr, DRC:$cmp, DRC:$swap),
 812            !strconcat("atomic_cmp_swap_", Width, "\t$dst, $ptr, $cmp, $swap"),
 813            [(set DRC:$dst, (Op PRC:$ptr, DRC:$cmp, DRC:$swap))]>;
 814
 815 multiclass AtomicCmpSwap32<PatFrag Op, string Width>  {
 816   def #NAME# : AtomicCmpSwap<Op, Width, CPURegs, CPURegs>,
 817                              Requires<[NotN64, HasStdEnc]>;
 818   def _P8    : AtomicCmpSwap<Op, Width, CPURegs, CPU64Regs>,
 819                              Requires<[IsN64, HasStdEnc]> {
 820     let DecoderNamespace = "Mips64";
 821   }
 822 }
 823
 824 class LLBase<bits<6> Opc, string opstring, RegisterClass RC, Operand Mem> :
 825   FMem<Opc, (outs RC:$rt), (ins Mem:$addr),
 826        !strconcat(opstring, "\t$rt, $addr"), [], IILoad> {
 827   let mayLoad = 1;
 828 }
 829
 830 class SCBase<bits<6> Opc, string opstring, RegisterClass RC, Operand Mem> :
 831   FMem<Opc, (outs RC:$dst), (ins RC:$rt, Mem:$addr),
 832        !strconcat(opstring, "\t$rt, $addr"), [], IIStore> {
 833   let mayStore = 1;
 834   let Constraints = "$rt = $dst";
 835 }
 836
 837 //===----------------------------------------------------------------------===//
 838 // Pseudo instructions
 839 //===----------------------------------------------------------------------===//
 840
 841 // Return RA.
 842 let isReturn=1, isTerminator=1, hasDelaySlot=1, isBarrier=1, hasCtrlDep=1 in
 843 def RetRA : PseudoSE<(outs), (ins), "", [(MipsRet)]>;
 844
 845 let Defs = [SP], Uses = [SP], hasSideEffects = 1 in {
 846 def ADJCALLSTACKDOWN : MipsPseudo<(outs), (ins i32imm:$amt),
 847                                   "!ADJCALLSTACKDOWN $amt",
 848                                   [(callseq_start timm:$amt)]>;
 849 def ADJCALLSTACKUP   : MipsPseudo<(outs), (ins i32imm:$amt1, i32imm:$amt2),
 850                                   "!ADJCALLSTACKUP $amt1",
 851                                   [(callseq_end timm:$amt1, timm:$amt2)]>;
 852 }
 853
 854 // When handling PIC code the assembler needs .cpload and .cprestore
 855 // directives. If the real instructions corresponding these directives
 856 // are used, we have the same behavior, but get also a bunch of warnings
 857 // from the assembler.
 858 let neverHasSideEffects = 1 in
 859 def CPRESTORE : PseudoSE<(outs), (ins i32imm:$loc, CPURegs:$gp),
 860                          ".cprestore\t$loc", []>;
 861
 862 let usesCustomInserter = 1 in {
 863   defm ATOMIC_LOAD_ADD_I8   : Atomic2Ops32<atomic_load_add_8, "load_add_8">;
 864   defm ATOMIC_LOAD_ADD_I16  : Atomic2Ops32<atomic_load_add_16, "load_add_16">;
 865   defm ATOMIC_LOAD_ADD_I32  : Atomic2Ops32<atomic_load_add_32, "load_add_32">;
 866   defm ATOMIC_LOAD_SUB_I8   : Atomic2Ops32<atomic_load_sub_8, "load_sub_8">;
 867   defm ATOMIC_LOAD_SUB_I16  : Atomic2Ops32<atomic_load_sub_16, "load_sub_16">;
 868   defm ATOMIC_LOAD_SUB_I32  : Atomic2Ops32<atomic_load_sub_32, "load_sub_32">;
 869   defm ATOMIC_LOAD_AND_I8   : Atomic2Ops32<atomic_load_and_8, "load_and_8">;
 870   defm ATOMIC_LOAD_AND_I16  : Atomic2Ops32<atomic_load_and_16, "load_and_16">;
 871   defm ATOMIC_LOAD_AND_I32  : Atomic2Ops32<atomic_load_and_32, "load_and_32">;
 872   defm ATOMIC_LOAD_OR_I8    : Atomic2Ops32<atomic_load_or_8, "load_or_8">;
 873   defm ATOMIC_LOAD_OR_I16   : Atomic2Ops32<atomic_load_or_16, "load_or_16">;
 874   defm ATOMIC_LOAD_OR_I32   : Atomic2Ops32<atomic_load_or_32, "load_or_32">;
 875   defm ATOMIC_LOAD_XOR_I8   : Atomic2Ops32<atomic_load_xor_8, "load_xor_8">;
 876   defm ATOMIC_LOAD_XOR_I16  : Atomic2Ops32<atomic_load_xor_16, "load_xor_16">;
 877   defm ATOMIC_LOAD_XOR_I32  : Atomic2Ops32<atomic_load_xor_32, "load_xor_32">;
 878   defm ATOMIC_LOAD_NAND_I8  : Atomic2Ops32<atomic_load_nand_8, "load_nand_8">;
 879   defm ATOMIC_LOAD_NAND_I16 : Atomic2Ops32<atomic_load_nand_16, "load_nand_16">;
 880   defm ATOMIC_LOAD_NAND_I32 : Atomic2Ops32<atomic_load_nand_32, "load_nand_32">;
 881
 882   defm ATOMIC_SWAP_I8       : Atomic2Ops32<atomic_swap_8, "swap_8">;
 883   defm ATOMIC_SWAP_I16      : Atomic2Ops32<atomic_swap_16, "swap_16">;
 884   defm ATOMIC_SWAP_I32      : Atomic2Ops32<atomic_swap_32, "swap_32">;
 885
 886   defm ATOMIC_CMP_SWAP_I8   : AtomicCmpSwap32<atomic_cmp_swap_8, "8">;
 887   defm ATOMIC_CMP_SWAP_I16  : AtomicCmpSwap32<atomic_cmp_swap_16, "16">;
 888   defm ATOMIC_CMP_SWAP_I32  : AtomicCmpSwap32<atomic_cmp_swap_32, "32">;
 889 }
 890
 891 //===----------------------------------------------------------------------===//
 892 // Instruction definition
 893 //===----------------------------------------------------------------------===//
 894
 895 class LoadImm32< string instr_asm, Operand Od, RegisterClass RC> :
 896   MipsAsmPseudoInst<(outs RC:$rt), (ins Od:$imm32),
 897                      !strconcat(instr_asm, "\t$rt, $imm32")> ;
 898 def LoadImm32Reg : LoadImm32<"li", shamt,CPURegs>;
 899
 900 class LoadAddress<string instr_asm, Operand MemOpnd, RegisterClass RC> :
 901   MipsAsmPseudoInst<(outs RC:$rt), (ins MemOpnd:$addr),
 902                      !strconcat(instr_asm, "\t$rt, $addr")> ;
 903 def LoadAddr32Reg : LoadAddress<"la", mem, CPURegs>;
 904
 905 class LoadAddressImm<string instr_asm, Operand Od, RegisterClass RC> :
 906   MipsAsmPseudoInst<(outs RC:$rt), (ins Od:$imm32),
 907                      !strconcat(instr_asm, "\t$rt, $imm32")> ;
 908 def LoadAddr32Imm : LoadAddressImm<"la", shamt,CPURegs>;
 909
 910 //===----------------------------------------------------------------------===//
 911 // MipsI Instructions
 912 //===----------------------------------------------------------------------===//
 913
 914 /// Arithmetic Instructions (ALU Immediate)
 915 def ADDiu : ArithLogicI<"addiu", simm16, CPURegs, immSExt16, add>,
 916             ADDI_FM<0x9>, IsAsCheapAsAMove;
 917 def ADDi  : ArithLogicI<"addi", simm16, CPURegs>, ADDI_FM<0x8>;
 918 def SLTi  : SetCC_I<0x0a, "slti", setlt, simm16, immSExt16, CPURegs>;
 919 def SLTiu : SetCC_I<0x0b, "sltiu", setult, simm16, immSExt16, CPURegs>;
 920 def ANDi  : ArithLogicI<"andi", uimm16, CPURegs, immZExt16, and>, ADDI_FM<0xc>;
 921 def ORi   : ArithLogicI<"ori", uimm16, CPURegs, immZExt16, or>, ADDI_FM<0xd>;
 922 def XORi  : ArithLogicI<"xori", uimm16, CPURegs, immZExt16, xor>, ADDI_FM<0xe>;
 923 def LUi   : LoadUpper<0x0f, "lui", CPURegs, uimm16>;
 924
 925 /// Arithmetic Instructions (3-Operand, R-Type)
 926 def ADDu : ArithLogicR<"addu", CPURegs, 1, IIAlu, add>, ADD_FM<0, 0x21>;
 927 def SUBu : ArithLogicR<"subu", CPURegs, 0, IIAlu, sub>, ADD_FM<0, 0x23>;
 928 def ADD  : ArithLogicR<"add", CPURegs>, ADD_FM<0, 0x20>;
 929 def SUB  : ArithLogicR<"sub", CPURegs>, ADD_FM<0, 0x22>;
 930 def SLT  : SetCC_R<0x00, 0x2a, "slt", setlt, CPURegs>;
 931 def SLTu : SetCC_R<0x00, 0x2b, "sltu", setult, CPURegs>;
 932 def AND  : ArithLogicR<"and", CPURegs, 1, IIAlu, and>, ADD_FM<0, 0x24>;
 933 def OR   : ArithLogicR<"or", CPURegs, 1, IIAlu, or>, ADD_FM<0, 0x25>;
 934 def XOR  : ArithLogicR<"xor", CPURegs, 1, IIAlu, xor>, ADD_FM<0, 0x26>;
 935 def NOR  : LogicNOR<0x00, 0x27, "nor", CPURegs>;
 936
 937 /// Shift Instructions
 938 def SLL  : shift_rotate_imm32<"sll", shl>, SRA_FM<0, 0>;
 939 def SRL  : shift_rotate_imm32<"srl", srl>, SRA_FM<2, 0>;
 940 def SRA  : shift_rotate_imm32<"sra", sra>, SRA_FM<3, 0>;
 941 def SLLV : shift_rotate_reg<"sllv", shl, CPURegs>, SRLV_FM<4, 0>;
 942 def SRLV : shift_rotate_reg<"srlv", srl, CPURegs>, SRLV_FM<6, 0>;
 943 def SRAV : shift_rotate_reg<"srav", sra, CPURegs>, SRLV_FM<7, 0>;
 944
 945 // Rotate Instructions
 946 let Predicates = [HasMips32r2, HasStdEnc] in {
 947   def ROTR  : shift_rotate_imm32<"rotr", rotr>, SRA_FM<2, 1>;
 948   def ROTRV : shift_rotate_reg<"rotrv", rotr, CPURegs>, SRLV_FM<6, 1>;
 949 }
 950
 951 /// Load and Store Instructions
 952 ///  aligned
 953 defm LB      : LoadM32<0x20, "lb",  sextloadi8>;
 954 defm LBu     : LoadM32<0x24, "lbu", zextloadi8>;
 955 defm LH      : LoadM32<0x21, "lh",  sextloadi16>;
 956 defm LHu     : LoadM32<0x25, "lhu", zextloadi16>;
 957 defm LW      : LoadM32<0x23, "lw",  load>;
 958 defm SB      : StoreM32<0x28, "sb", truncstorei8>;
 959 defm SH      : StoreM32<0x29, "sh", truncstorei16>;
 960 defm SW      : StoreM32<0x2b, "sw", store>;
 961
 962 /// load/store left/right
 963 defm LWL : LoadLeftRightM32<0x22, "lwl", MipsLWL>;
 964 defm LWR : LoadLeftRightM32<0x26, "lwr", MipsLWR>;
 965 defm SWL : StoreLeftRightM32<0x2a, "swl", MipsSWL>;
 966 defm SWR : StoreLeftRightM32<0x2e, "swr", MipsSWR>;
 967
 968 let hasSideEffects = 1 in
 969 def SYNC : InstSE<(outs), (ins i32imm:$stype), "sync $stype",
 970                   [(MipsSync imm:$stype)], NoItinerary, FrmOther>
 971 {
 972   bits<5> stype;
 973   let Opcode = 0;
 974   let Inst{25-11} = 0;
 975   let Inst{10-6} = stype;
 976   let Inst{5-0} = 15;
 977 }
 978
 979 /// Load-linked, Store-conditional
 980 def LL    : LLBase<0x30, "ll", CPURegs, mem>,
 981             Requires<[NotN64, HasStdEnc]>;
 982 def LL_P8 : LLBase<0x30, "ll", CPURegs, mem64>,
 983             Requires<[IsN64, HasStdEnc]> {
 984   let DecoderNamespace = "Mips64";
 985 }
 986
 987 def SC    : SCBase<0x38, "sc", CPURegs, mem>,
 988             Requires<[NotN64, HasStdEnc]>;
 989 def SC_P8 : SCBase<0x38, "sc", CPURegs, mem64>,
 990             Requires<[IsN64, HasStdEnc]> {
 991   let DecoderNamespace = "Mips64";
 992 }
 993
 994 /// Jump and Branch Instructions
 995 def J       : JumpFJ<0x02, jmptarget, "j", br, bb>,
 996               Requires<[RelocStatic, HasStdEnc]>, IsBranch;
 997 def JR      : IndirectBranch<CPURegs>;
 998 def B       : UncondBranch<0x04, "b">;
 999 def BEQ     : CBranch<0x04, "beq", seteq, CPURegs>;
1000 def BNE     : CBranch<0x05, "bne", setne, CPURegs>;
1001 def BGEZ    : CBranchZero<0x01, 1, "bgez", setge, CPURegs>;
1002 def BGTZ    : CBranchZero<0x07, 0, "bgtz", setgt, CPURegs>;
1003 def BLEZ    : CBranchZero<0x06, 0, "blez", setle, CPURegs>;
1004 def BLTZ    : CBranchZero<0x01, 0, "bltz", setlt, CPURegs>;
1005
1006 let rt = 0, rs = 0, isBranch = 1, isTerminator = 1, isBarrier = 1,
1007     hasDelaySlot = 1, Defs = [RA] in
1008 def BAL_BR: FI<0x1, (outs), (ins brtarget:$imm16), "bal\t$imm16", [], IIBranch>;
1009
1010 def JAL  : JumpLink<0x03, "jal">;
1011 def JALR : JumpLinkReg<0x00, 0x09, "jalr", CPURegs>;
1012 def BGEZAL  : BranchLink<"bgezal", 0x11, CPURegs>;
1013 def BLTZAL  : BranchLink<"bltzal", 0x10, CPURegs>;
1014 def TAILCALL : JumpFJ<0x02, calltarget, "j", MipsTailCall, imm>, IsTailCall;
1015 def TAILCALL_R : JumpFR<CPURegs, MipsTailCall>, IsTailCall;
1016
1017 def RET : RetBase<CPURegs>;
1018
1019 /// Multiply and Divide Instructions.
1020 def MULT    : Mult32<0x18, "mult", IIImul>;
1021 def MULTu   : Mult32<0x19, "multu", IIImul>;
1022 def SDIV    : Div32<MipsDivRem, 0x1a, "div", IIIdiv>;
1023 def UDIV    : Div32<MipsDivRemU, 0x1b, "divu", IIIdiv>;
1024
1025 def MTHI : MoveToLOHI<0x11, "mthi", CPURegs, [HI]>;
1026 def MTLO : MoveToLOHI<0x13, "mtlo", CPURegs, [LO]>;
1027 def MFHI : MoveFromLOHI<0x10, "mfhi", CPURegs, [HI]>;
1028 def MFLO : MoveFromLOHI<0x12, "mflo", CPURegs, [LO]>;
1029
1030 /// Sign Ext In Register Instructions.
1031 def SEB : SignExtInReg<0x10, "seb", i8, CPURegs>;
1032 def SEH : SignExtInReg<0x18, "seh", i16, CPURegs>;
1033
1034 /// Count Leading
1035 def CLZ : CountLeading0<0x20, "clz", CPURegs>;
1036 def CLO : CountLeading1<0x21, "clo", CPURegs>;
1037
1038 /// Word Swap Bytes Within Halfwords
1039 def WSBH : SubwordSwap<0x20, 0x2, "wsbh", CPURegs>;
1040
1041 /// No operation
1042 let addr=0 in
1043   def NOP   : FJ<0, (outs), (ins), "nop", [], IIAlu>;
1044
1045 // FrameIndexes are legalized when they are operands from load/store
1046 // instructions. The same not happens for stack address copies, so an
1047 // add op with mem ComplexPattern is used and the stack address copy
1048 // can be matched. It's similar to Sparc LEA_ADDRi
1049 def LEA_ADDiu : EffectiveAddress<0x09,"addiu\t$rt, $addr", CPURegs, mem_ea>;
1050
1051 // MADD*/MSUB*
1052 def MADD  : MArithR<0, "madd", MipsMAdd, 1>;
1053 def MADDU : MArithR<1, "maddu", MipsMAddu, 1>;
1054 def MSUB  : MArithR<4, "msub", MipsMSub>;
1055 def MSUBU : MArithR<5, "msubu", MipsMSubu>;
1056
1057 // MUL is a assembly macro in the current used ISAs. In recent ISA's
1058 // it is a real instruction.
1059 def MUL   : ArithLogicR<"mul", CPURegs, 1, IIImul, mul>, ADD_FM<0x1c, 0x02>;
1060
1061 def RDHWR : ReadHardware<CPURegs, HWRegs>;
1062
1063 def EXT : ExtBase<0, "ext", CPURegs>;
1064 def INS : InsBase<4, "ins", CPURegs>;
1065
1066 //===----------------------------------------------------------------------===//
1067 // Instruction aliases
1068 //===----------------------------------------------------------------------===//
1069 def : InstAlias<"move $dst,$src", (ADD CPURegs:$dst,CPURegs:$src,ZERO)>;
1070 def : InstAlias<"bal $offset", (BGEZAL RA,brtarget:$offset)>;
1071 def : InstAlias<"addu $rs,$rt,$imm",
1072                 (ADDiu CPURegs:$rs,CPURegs:$rt,simm16:$imm)>;
1073 def : InstAlias<"add $rs,$rt,$imm",
1074                 (ADDi CPURegs:$rs,CPURegs:$rt,simm16:$imm)>;
1075 def : InstAlias<"and $rs,$rt,$imm",
1076                 (ANDi CPURegs:$rs,CPURegs:$rt,simm16:$imm)>;
1077 def : InstAlias<"j $rs", (JR CPURegs:$rs)>;
1078 def : InstAlias<"not $rt,$rs", (NOR CPURegs:$rt,CPURegs:$rs,ZERO)>;
1079 def : InstAlias<"neg $rt,$rs", (SUB CPURegs:$rt,ZERO,CPURegs:$rs)>;
1080 def : InstAlias<"negu $rt,$rs", (SUBu CPURegs:$rt,ZERO,CPURegs:$rs)>;
1081 def : InstAlias<"slt $rs,$rt,$imm",
1082                 (SLTi CPURegs:$rs,CPURegs:$rt,simm16:$imm)>;
1083 def : InstAlias<"xor $rs,$rt,$imm",
1084                 (XORi CPURegs:$rs,CPURegs:$rt,simm16:$imm)>;
1085
1086 //===----------------------------------------------------------------------===//
1087 //  Arbitrary patterns that map to one or more instructions
1088 //===----------------------------------------------------------------------===//
1089
1090 // Small immediates
1091 def : MipsPat<(i32 immSExt16:$in),
1092               (ADDiu ZERO, imm:$in)>;
1093 def : MipsPat<(i32 immZExt16:$in),
1094               (ORi ZERO, imm:$in)>;
1095 def : MipsPat<(i32 immLow16Zero:$in),
1096               (LUi (HI16 imm:$in))>;
1097
1098 // Arbitrary immediates
1099 def : MipsPat<(i32 imm:$imm),
1100           (ORi (LUi (HI16 imm:$imm)), (LO16 imm:$imm))>;
1101
1102 // Carry MipsPatterns
1103 def : MipsPat<(subc CPURegs:$lhs, CPURegs:$rhs),
1104               (SUBu CPURegs:$lhs, CPURegs:$rhs)>;
1105 def : MipsPat<(addc CPURegs:$lhs, CPURegs:$rhs),
1106               (ADDu CPURegs:$lhs, CPURegs:$rhs)>;
1107 def : MipsPat<(addc  CPURegs:$src, immSExt16:$imm),
1108               (ADDiu CPURegs:$src, imm:$imm)>;
1109
1110 // Call
1111 def : MipsPat<(MipsJmpLink (i32 tglobaladdr:$dst)),
1112               (JAL tglobaladdr:$dst)>;
1113 def : MipsPat<(MipsJmpLink (i32 texternalsym:$dst)),
1114               (JAL texternalsym:$dst)>;
1115 //def : MipsPat<(MipsJmpLink CPURegs:$dst),
1116 //              (JALR CPURegs:$dst)>;
1117
1118 // Tail call
1119 def : MipsPat<(MipsTailCall (iPTR tglobaladdr:$dst)),
1120               (TAILCALL tglobaladdr:$dst)>;
1121 def : MipsPat<(MipsTailCall (iPTR texternalsym:$dst)),
1122               (TAILCALL texternalsym:$dst)>;
1123 // hi/lo relocs
1124 def : MipsPat<(MipsHi tglobaladdr:$in), (LUi tglobaladdr:$in)>;
1125 def : MipsPat<(MipsHi tblockaddress:$in), (LUi tblockaddress:$in)>;
1126 def : MipsPat<(MipsHi tjumptable:$in), (LUi tjumptable:$in)>;
1127 def : MipsPat<(MipsHi tconstpool:$in), (LUi tconstpool:$in)>;
1128 def : MipsPat<(MipsHi tglobaltlsaddr:$in), (LUi tglobaltlsaddr:$in)>;
1129 def : MipsPat<(MipsHi texternalsym:$in), (LUi texternalsym:$in)>;
1130
1131 def : MipsPat<(MipsLo tglobaladdr:$in), (ADDiu ZERO, tglobaladdr:$in)>;
1132 def : MipsPat<(MipsLo tblockaddress:$in), (ADDiu ZERO, tblockaddress:$in)>;
1133 def : MipsPat<(MipsLo tjumptable:$in), (ADDiu ZERO, tjumptable:$in)>;
1134 def : MipsPat<(MipsLo tconstpool:$in), (ADDiu ZERO, tconstpool:$in)>;
1135 def : MipsPat<(MipsLo tglobaltlsaddr:$in), (ADDiu ZERO, tglobaltlsaddr:$in)>;
1136 def : MipsPat<(MipsLo texternalsym:$in), (ADDiu ZERO, texternalsym:$in)>;
1137
1138 def : MipsPat<(add CPURegs:$hi, (MipsLo tglobaladdr:$lo)),
1139               (ADDiu CPURegs:$hi, tglobaladdr:$lo)>;
1140 def : MipsPat<(add CPURegs:$hi, (MipsLo tblockaddress:$lo)),
1141               (ADDiu CPURegs:$hi, tblockaddress:$lo)>;
1142 def : MipsPat<(add CPURegs:$hi, (MipsLo tjumptable:$lo)),
1143               (ADDiu CPURegs:$hi, tjumptable:$lo)>;
1144 def : MipsPat<(add CPURegs:$hi, (MipsLo tconstpool:$lo)),
1145               (ADDiu CPURegs:$hi, tconstpool:$lo)>;
1146 def : MipsPat<(add CPURegs:$hi, (MipsLo tglobaltlsaddr:$lo)),
1147               (ADDiu CPURegs:$hi, tglobaltlsaddr:$lo)>;
1148
1149 // gp_rel relocs
1150 def : MipsPat<(add CPURegs:$gp, (MipsGPRel tglobaladdr:$in)),
1151               (ADDiu CPURegs:$gp, tglobaladdr:$in)>;
1152 def : MipsPat<(add CPURegs:$gp, (MipsGPRel tconstpool:$in)),
1153               (ADDiu CPURegs:$gp, tconstpool:$in)>;
1154
1155 // wrapper_pic
1156 class WrapperPat<SDNode node, Instruction ADDiuOp, RegisterClass RC>:
1157       MipsPat<(MipsWrapper RC:$gp, node:$in),
1158               (ADDiuOp RC:$gp, node:$in)>;
1159
1160 def : WrapperPat<tglobaladdr, ADDiu, CPURegs>;
1161 def : WrapperPat<tconstpool, ADDiu, CPURegs>;
1162 def : WrapperPat<texternalsym, ADDiu, CPURegs>;
1163 def : WrapperPat<tblockaddress, ADDiu, CPURegs>;
1164 def : WrapperPat<tjumptable, ADDiu, CPURegs>;
1165 def : WrapperPat<tglobaltlsaddr, ADDiu, CPURegs>;
1166
1167 // Mips does not have "not", so we expand our way
1168 def : MipsPat<(not CPURegs:$in),
1169               (NOR CPURegs:$in, ZERO)>;
1170
1171 // extended loads
1172 let Predicates = [NotN64, HasStdEnc] in {
1173   def : MipsPat<(i32 (extloadi1  addr:$src)), (LBu addr:$src)>;
1174   def : MipsPat<(i32 (extloadi8  addr:$src)), (LBu addr:$src)>;
1175   def : MipsPat<(i32 (extloadi16 addr:$src)), (LHu addr:$src)>;
1176 }
1177 let Predicates = [IsN64, HasStdEnc] in {
1178   def : MipsPat<(i32 (extloadi1  addr:$src)), (LBu_P8 addr:$src)>;
1179   def : MipsPat<(i32 (extloadi8  addr:$src)), (LBu_P8 addr:$src)>;
1180   def : MipsPat<(i32 (extloadi16 addr:$src)), (LHu_P8 addr:$src)>;
1181 }
1182
1183 // peepholes
1184 let Predicates = [NotN64, HasStdEnc] in {
1185   def : MipsPat<(store (i32 0), addr:$dst), (SW ZERO, addr:$dst)>;
1186 }
1187 let Predicates = [IsN64, HasStdEnc] in {
1188   def : MipsPat<(store (i32 0), addr:$dst), (SW_P8 ZERO, addr:$dst)>;
1189 }
1190
1191 // brcond patterns
1192 multiclass BrcondPats<RegisterClass RC, Instruction BEQOp, Instruction BNEOp,
1193                       Instruction SLTOp, Instruction SLTuOp, Instruction SLTiOp,
1194                       Instruction SLTiuOp, Register ZEROReg> {
1195 def : MipsPat<(brcond (i32 (setne RC:$lhs, 0)), bb:$dst),
1196               (BNEOp RC:$lhs, ZEROReg, bb:$dst)>;
1197 def : MipsPat<(brcond (i32 (seteq RC:$lhs, 0)), bb:$dst),
1198               (BEQOp RC:$lhs, ZEROReg, bb:$dst)>;
1199
1200 def : MipsPat<(brcond (i32 (setge RC:$lhs, RC:$rhs)), bb:$dst),
1201               (BEQ (SLTOp RC:$lhs, RC:$rhs), ZERO, bb:$dst)>;
1202 def : MipsPat<(brcond (i32 (setuge RC:$lhs, RC:$rhs)), bb:$dst),
1203               (BEQ (SLTuOp RC:$lhs, RC:$rhs), ZERO, bb:$dst)>;
1204 def : MipsPat<(brcond (i32 (setge RC:$lhs, immSExt16:$rhs)), bb:$dst),
1205               (BEQ (SLTiOp RC:$lhs, immSExt16:$rhs), ZERO, bb:$dst)>;
1206 def : MipsPat<(brcond (i32 (setuge RC:$lhs, immSExt16:$rhs)), bb:$dst),
1207               (BEQ (SLTiuOp RC:$lhs, immSExt16:$rhs), ZERO, bb:$dst)>;
1208
1209 def : MipsPat<(brcond (i32 (setle RC:$lhs, RC:$rhs)), bb:$dst),
1210               (BEQ (SLTOp RC:$rhs, RC:$lhs), ZERO, bb:$dst)>;
1211 def : MipsPat<(brcond (i32 (setule RC:$lhs, RC:$rhs)), bb:$dst),
1212               (BEQ (SLTuOp RC:$rhs, RC:$lhs), ZERO, bb:$dst)>;
1213
1214 def : MipsPat<(brcond RC:$cond, bb:$dst),
1215               (BNEOp RC:$cond, ZEROReg, bb:$dst)>;
1216 }
1217
1218 defm : BrcondPats<CPURegs, BEQ, BNE, SLT, SLTu, SLTi, SLTiu, ZERO>;
1219
1220 // setcc patterns
1221 multiclass SeteqPats<RegisterClass RC, Instruction SLTiuOp, Instruction XOROp,
1222                      Instruction SLTuOp, Register ZEROReg> {
1223   def : MipsPat<(seteq RC:$lhs, RC:$rhs),
1224                 (SLTiuOp (XOROp RC:$lhs, RC:$rhs), 1)>;
1225   def : MipsPat<(setne RC:$lhs, RC:$rhs),
1226                 (SLTuOp ZEROReg, (XOROp RC:$lhs, RC:$rhs))>;
1227 }
1228
1229 multiclass SetlePats<RegisterClass RC, Instruction SLTOp, Instruction SLTuOp> {
1230   def : MipsPat<(setle RC:$lhs, RC:$rhs),
1231                 (XORi (SLTOp RC:$rhs, RC:$lhs), 1)>;
1232   def : MipsPat<(setule RC:$lhs, RC:$rhs),
1233                 (XORi (SLTuOp RC:$rhs, RC:$lhs), 1)>;
1234 }
1235
1236 multiclass SetgtPats<RegisterClass RC, Instruction SLTOp, Instruction SLTuOp> {
1237   def : MipsPat<(setgt RC:$lhs, RC:$rhs),
1238                 (SLTOp RC:$rhs, RC:$lhs)>;
1239   def : MipsPat<(setugt RC:$lhs, RC:$rhs),
1240                 (SLTuOp RC:$rhs, RC:$lhs)>;
1241 }
1242
1243 multiclass SetgePats<RegisterClass RC, Instruction SLTOp, Instruction SLTuOp> {
1244   def : MipsPat<(setge RC:$lhs, RC:$rhs),
1245                 (XORi (SLTOp RC:$lhs, RC:$rhs), 1)>;
1246   def : MipsPat<(setuge RC:$lhs, RC:$rhs),
1247                 (XORi (SLTuOp RC:$lhs, RC:$rhs), 1)>;
1248 }
1249
1250 multiclass SetgeImmPats<RegisterClass RC, Instruction SLTiOp,
1251                         Instruction SLTiuOp> {
1252   def : MipsPat<(setge RC:$lhs, immSExt16:$rhs),
1253                 (XORi (SLTiOp RC:$lhs, immSExt16:$rhs), 1)>;
1254   def : MipsPat<(setuge RC:$lhs, immSExt16:$rhs),
1255                 (XORi (SLTiuOp RC:$lhs, immSExt16:$rhs), 1)>;
1256 }
1257
1258 defm : SeteqPats<CPURegs, SLTiu, XOR, SLTu, ZERO>;
1259 defm : SetlePats<CPURegs, SLT, SLTu>;
1260 defm : SetgtPats<CPURegs, SLT, SLTu>;
1261 defm : SetgePats<CPURegs, SLT, SLTu>;
1262 defm : SetgeImmPats<CPURegs, SLTi, SLTiu>;
1263
1264 // bswap pattern
1265 def : MipsPat<(bswap CPURegs:$rt), (ROTR (WSBH CPURegs:$rt), 16)>;
1266
1267 //===----------------------------------------------------------------------===//
1268 // Floating Point Support
1269 //===----------------------------------------------------------------------===//
1270
1271 include "MipsInstrFPU.td"
1272 include "Mips64InstrInfo.td"
1273 include "MipsCondMov.td"
1274
1275 //
1276 // Mips16
1277
1278 include "Mips16InstrFormats.td"
1279 include "Mips16InstrInfo.td"
1280
1281 // DSP
1282 include "MipsDSPInstrFormats.td"
1283 include "MipsDSPInstrInfo.td"
1284