lib/Target/Mips/MipsInstrInfo.td

   1 //===- MipsInstrInfo.td - Target Description for Mips Target -*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file contains the Mips implementation of the TargetInstrInfo class.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14
  15 //===----------------------------------------------------------------------===//
  16 // Mips profiles and nodes
  17 //===----------------------------------------------------------------------===//
  18
  19 def SDT_MipsJmpLink      : SDTypeProfile<0, 1, [SDTCisVT<0, iPTR>]>;
  20 def SDT_MipsCMov         : SDTypeProfile<1, 4, [SDTCisSameAs<0, 1>,
  21                                                 SDTCisSameAs<1, 2>,
  22                                                 SDTCisSameAs<3, 4>,
  23                                                 SDTCisInt<4>]>;
  24 def SDT_MipsCallSeqStart : SDCallSeqStart<[SDTCisVT<0, i32>]>;
  25 def SDT_MipsCallSeqEnd   : SDCallSeqEnd<[SDTCisVT<0, i32>, SDTCisVT<1, i32>]>;
  26 def SDT_MipsMAddMSub     : SDTypeProfile<0, 4,
  27                                          [SDTCisVT<0, i32>, SDTCisSameAs<0, 1>,
  28                                           SDTCisSameAs<1, 2>,
  29                                           SDTCisSameAs<2, 3>]>;
  30 def SDT_MipsDivRem       : SDTypeProfile<0, 2,
  31                                          [SDTCisInt<0>,
  32                                           SDTCisSameAs<0, 1>]>;
  33
  34 def SDT_MipsThreadPointer : SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;
  35
  36 def SDT_Sync             : SDTypeProfile<0, 1, [SDTCisVT<0, i32>]>;
  37
  38 def SDT_Ext : SDTypeProfile<1, 3, [SDTCisInt<0>, SDTCisSameAs<0, 1>,
  39                                    SDTCisVT<2, i32>, SDTCisSameAs<2, 3>]>;
  40 def SDT_Ins : SDTypeProfile<1, 4, [SDTCisInt<0>, SDTCisSameAs<0, 1>,
  41                                    SDTCisVT<2, i32>, SDTCisSameAs<2, 3>,
  42                                    SDTCisSameAs<0, 4>]>;
  43
  44 def SDTMipsLoadLR  : SDTypeProfile<1, 2,
  45                                    [SDTCisInt<0>, SDTCisPtrTy<1>,
  46                                     SDTCisSameAs<0, 2>]>;
  47
  48 // Call
  49 def MipsJmpLink : SDNode<"MipsISD::JmpLink",SDT_MipsJmpLink,
  50                          [SDNPHasChain, SDNPOutGlue, SDNPOptInGlue,
  51                           SDNPVariadic]>;
  52
  53 // Tail call
  54 def MipsTailCall : SDNode<"MipsISD::TailCall", SDT_MipsJmpLink,
  55                           [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
  56
  57 // Hi and Lo nodes are used to handle global addresses. Used on
  58 // MipsISelLowering to lower stuff like GlobalAddress, ExternalSymbol
  59 // static model. (nothing to do with Mips Registers Hi and Lo)
  60 def MipsHi    : SDNode<"MipsISD::Hi", SDTIntUnaryOp>;
  61 def MipsLo    : SDNode<"MipsISD::Lo", SDTIntUnaryOp>;
  62 def MipsGPRel : SDNode<"MipsISD::GPRel", SDTIntUnaryOp>;
  63
  64 // TlsGd node is used to handle General Dynamic TLS
  65 def MipsTlsGd : SDNode<"MipsISD::TlsGd", SDTIntUnaryOp>;
  66
  67 // TprelHi and TprelLo nodes are used to handle Local Exec TLS
  68 def MipsTprelHi    : SDNode<"MipsISD::TprelHi", SDTIntUnaryOp>;
  69 def MipsTprelLo    : SDNode<"MipsISD::TprelLo", SDTIntUnaryOp>;
  70
  71 // Thread pointer
  72 def MipsThreadPointer: SDNode<"MipsISD::ThreadPointer", SDT_MipsThreadPointer>;
  73
  74 // Return
  75 def MipsRet : SDNode<"MipsISD::Ret", SDTNone, [SDNPHasChain, SDNPOptInGlue]>;
  76
  77 // These are target-independent nodes, but have target-specific formats.
  78 def callseq_start : SDNode<"ISD::CALLSEQ_START", SDT_MipsCallSeqStart,
  79                            [SDNPHasChain, SDNPSideEffect, SDNPOutGlue]>;
  80 def callseq_end   : SDNode<"ISD::CALLSEQ_END", SDT_MipsCallSeqEnd,
  81                            [SDNPHasChain, SDNPSideEffect,
  82                             SDNPOptInGlue, SDNPOutGlue]>;
  83
  84 // MAdd*/MSub* nodes
  85 def MipsMAdd      : SDNode<"MipsISD::MAdd", SDT_MipsMAddMSub,
  86                            [SDNPOptInGlue, SDNPOutGlue]>;
  87 def MipsMAddu     : SDNode<"MipsISD::MAddu", SDT_MipsMAddMSub,
  88                            [SDNPOptInGlue, SDNPOutGlue]>;
  89 def MipsMSub      : SDNode<"MipsISD::MSub", SDT_MipsMAddMSub,
  90                            [SDNPOptInGlue, SDNPOutGlue]>;
  91 def MipsMSubu     : SDNode<"MipsISD::MSubu", SDT_MipsMAddMSub,
  92                            [SDNPOptInGlue, SDNPOutGlue]>;
  93
  94 // DivRem(u) nodes
  95 def MipsDivRem    : SDNode<"MipsISD::DivRem", SDT_MipsDivRem,
  96                            [SDNPOutGlue]>;
  97 def MipsDivRemU   : SDNode<"MipsISD::DivRemU", SDT_MipsDivRem,
  98                            [SDNPOutGlue]>;
  99
 100 // Target constant nodes that are not part of any isel patterns and remain
 101 // unchanged can cause instructions with illegal operands to be emitted.
 102 // Wrapper node patterns give the instruction selector a chance to replace
 103 // target constant nodes that would otherwise remain unchanged with ADDiu
 104 // nodes. Without these wrapper node patterns, the following conditional move
 105 // instrucion is emitted when function cmov2 in test/CodeGen/Mips/cmov.ll is
 106 // compiled:
 107 //  movn  %got(d)($gp), %got(c)($gp), $4
 108 // This instruction is illegal since movn can take only register operands.
 109
 110 def MipsWrapper    : SDNode<"MipsISD::Wrapper", SDTIntBinOp>;
 111
 112 def MipsSync : SDNode<"MipsISD::Sync", SDT_Sync, [SDNPHasChain,SDNPSideEffect]>;
 113
 114 def MipsExt :  SDNode<"MipsISD::Ext", SDT_Ext>;
 115 def MipsIns :  SDNode<"MipsISD::Ins", SDT_Ins>;
 116
 117 def MipsLWL : SDNode<"MipsISD::LWL", SDTMipsLoadLR,
 118                      [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 119 def MipsLWR : SDNode<"MipsISD::LWR", SDTMipsLoadLR,
 120                      [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 121 def MipsSWL : SDNode<"MipsISD::SWL", SDTStore,
 122                      [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 123 def MipsSWR : SDNode<"MipsISD::SWR", SDTStore,
 124                      [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 125 def MipsLDL : SDNode<"MipsISD::LDL", SDTMipsLoadLR,
 126                      [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 127 def MipsLDR : SDNode<"MipsISD::LDR", SDTMipsLoadLR,
 128                      [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 129 def MipsSDL : SDNode<"MipsISD::SDL", SDTStore,
 130                      [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 131 def MipsSDR : SDNode<"MipsISD::SDR", SDTStore,
 132                      [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 133
 134 //===----------------------------------------------------------------------===//
 135 // Mips Instruction Predicate Definitions.
 136 //===----------------------------------------------------------------------===//
 137 def HasSEInReg  :     Predicate<"Subtarget.hasSEInReg()">,
 138                       AssemblerPredicate<"FeatureSEInReg">;
 139 def HasBitCount :     Predicate<"Subtarget.hasBitCount()">,
 140                       AssemblerPredicate<"FeatureBitCount">;
 141 def HasSwap     :     Predicate<"Subtarget.hasSwap()">,
 142                       AssemblerPredicate<"FeatureSwap">;
 143 def HasCondMov  :     Predicate<"Subtarget.hasCondMov()">,
 144                       AssemblerPredicate<"FeatureCondMov">;
 145 def HasFPIdx    :     Predicate<"Subtarget.hasFPIdx()">,
 146                       AssemblerPredicate<"FeatureFPIdx">;
 147 def HasMips32    :    Predicate<"Subtarget.hasMips32()">,
 148                       AssemblerPredicate<"FeatureMips32">;
 149 def HasMips32r2  :    Predicate<"Subtarget.hasMips32r2()">,
 150                       AssemblerPredicate<"FeatureMips32r2">;
 151 def HasMips64    :    Predicate<"Subtarget.hasMips64()">,
 152                       AssemblerPredicate<"FeatureMips64">;
 153 def NotMips64    :    Predicate<"!Subtarget.hasMips64()">,
 154                       AssemblerPredicate<"!FeatureMips64">;
 155 def HasMips64r2  :    Predicate<"Subtarget.hasMips64r2()">,
 156                       AssemblerPredicate<"FeatureMips64r2">;
 157 def IsN64       :     Predicate<"Subtarget.isABI_N64()">,
 158                       AssemblerPredicate<"FeatureN64">;
 159 def NotN64      :     Predicate<"!Subtarget.isABI_N64()">,
 160                       AssemblerPredicate<"!FeatureN64">;
 161 def InMips16Mode :    Predicate<"Subtarget.inMips16Mode()">,
 162                       AssemblerPredicate<"FeatureMips16">;
 163 def RelocStatic :     Predicate<"TM.getRelocationModel() == Reloc::Static">,
 164                       AssemblerPredicate<"FeatureMips32">;
 165 def RelocPIC    :     Predicate<"TM.getRelocationModel() == Reloc::PIC_">,
 166                       AssemblerPredicate<"FeatureMips32">;
 167 def NoNaNsFPMath :    Predicate<"TM.Options.NoNaNsFPMath">,
 168                       AssemblerPredicate<"FeatureMips32">;
 169 def HasStdEnc :       Predicate<"Subtarget.hasStandardEncoding()">,
 170                       AssemblerPredicate<"!FeatureMips16">;
 171
 172 class MipsPat<dag pattern, dag result> : Pat<pattern, result> {
 173   let Predicates = [HasStdEnc];
 174 }
 175
 176 class IsCommutable {
 177   bit isCommutable = 1;
 178 }
 179
 180 class IsBranch {
 181   bit isBranch = 1;
 182 }
 183
 184 class IsReturn {
 185   bit isReturn = 1;
 186 }
 187
 188 class IsCall {
 189   bit isCall = 1;
 190 }
 191
 192 class IsTailCall {
 193   bit isCall = 1;
 194   bit isTerminator = 1;
 195   bit isReturn = 1;
 196   bit isBarrier = 1;
 197   bit hasExtraSrcRegAllocReq = 1;
 198   bit isCodeGenOnly = 1;
 199 }
 200
 201 class IsAsCheapAsAMove {
 202   bit isAsCheapAsAMove = 1;
 203 }
 204
 205 class NeverHasSideEffects {
 206   bit neverHasSideEffects = 1;
 207 }
 208
 209 //===----------------------------------------------------------------------===//
 210 // Instruction format superclass
 211 //===----------------------------------------------------------------------===//
 212
 213 include "MipsInstrFormats.td"
 214
 215 //===----------------------------------------------------------------------===//
 216 // Mips Operand, Complex Patterns and Transformations Definitions.
 217 //===----------------------------------------------------------------------===//
 218
 219 // Instruction operand types
 220 def jmptarget   : Operand<OtherVT> {
 221   let EncoderMethod = "getJumpTargetOpValue";
 222 }
 223 def brtarget    : Operand<OtherVT> {
 224   let EncoderMethod = "getBranchTargetOpValue";
 225   let OperandType = "OPERAND_PCREL";
 226   let DecoderMethod = "DecodeBranchTarget";
 227 }
 228 def calltarget  : Operand<iPTR> {
 229   let EncoderMethod = "getJumpTargetOpValue";
 230 }
 231 def calltarget64: Operand<i64>;
 232 def simm16      : Operand<i32> {
 233   let DecoderMethod= "DecodeSimm16";
 234 }
 235 def simm16_64   : Operand<i64>;
 236 def shamt       : Operand<i32>;
 237
 238 // Unsigned Operand
 239 def uimm16      : Operand<i32> {
 240   let PrintMethod = "printUnsignedImm";
 241 }
 242
 243 def MipsMemAsmOperand : AsmOperandClass {
 244   let Name = "Mem";
 245   let ParserMethod = "parseMemOperand";
 246 }
 247
 248 // Address operand
 249 def mem : Operand<i32> {
 250   let PrintMethod = "printMemOperand";
 251   let MIOperandInfo = (ops CPURegs, simm16);
 252   let EncoderMethod = "getMemEncoding";
 253   let ParserMatchClass = MipsMemAsmOperand;
 254 }
 255
 256 def mem64 : Operand<i64> {
 257   let PrintMethod = "printMemOperand";
 258   let MIOperandInfo = (ops CPU64Regs, simm16_64);
 259   let EncoderMethod = "getMemEncoding";
 260   let ParserMatchClass = MipsMemAsmOperand;
 261 }
 262
 263 def mem_ea : Operand<i32> {
 264   let PrintMethod = "printMemOperandEA";
 265   let MIOperandInfo = (ops CPURegs, simm16);
 266   let EncoderMethod = "getMemEncoding";
 267 }
 268
 269 def mem_ea_64 : Operand<i64> {
 270   let PrintMethod = "printMemOperandEA";
 271   let MIOperandInfo = (ops CPU64Regs, simm16_64);
 272   let EncoderMethod = "getMemEncoding";
 273 }
 274
 275 // size operand of ext instruction
 276 def size_ext : Operand<i32> {
 277   let EncoderMethod = "getSizeExtEncoding";
 278   let DecoderMethod = "DecodeExtSize";
 279 }
 280
 281 // size operand of ins instruction
 282 def size_ins : Operand<i32> {
 283   let EncoderMethod = "getSizeInsEncoding";
 284   let DecoderMethod = "DecodeInsSize";
 285 }
 286
 287 // Transformation Function - get the lower 16 bits.
 288 def LO16 : SDNodeXForm<imm, [{
 289   return getImm(N, N->getZExtValue() & 0xFFFF);
 290 }]>;
 291
 292 // Transformation Function - get the higher 16 bits.
 293 def HI16 : SDNodeXForm<imm, [{
 294   return getImm(N, (N->getZExtValue() >> 16) & 0xFFFF);
 295 }]>;
 296
 297 // Node immediate fits as 16-bit sign extended on target immediate.
 298 // e.g. addi, andi
 299 def immSExt16  : PatLeaf<(imm), [{ return isInt<16>(N->getSExtValue()); }]>;
 300
 301 // Node immediate fits as 16-bit zero extended on target immediate.
 302 // The LO16 param means that only the lower 16 bits of the node
 303 // immediate are caught.
 304 // e.g. addiu, sltiu
 305 def immZExt16  : PatLeaf<(imm), [{
 306   if (N->getValueType(0) == MVT::i32)
 307     return (uint32_t)N->getZExtValue() == (unsigned short)N->getZExtValue();
 308   else
 309     return (uint64_t)N->getZExtValue() == (unsigned short)N->getZExtValue();
 310 }], LO16>;
 311
 312 // Immediate can be loaded with LUi (32-bit int with lower 16-bit cleared).
 313 def immLow16Zero : PatLeaf<(imm), [{
 314   int64_t Val = N->getSExtValue();
 315   return isInt<32>(Val) && !(Val & 0xffff);
 316 }]>;
 317
 318 // shamt field must fit in 5 bits.
 319 def immZExt5 : ImmLeaf<i32, [{return Imm == (Imm & 0x1f);}]>;
 320
 321 // Mips Address Mode! SDNode frameindex could possibily be a match
 322 // since load and store instructions from stack used it.
 323 def addr :
 324   ComplexPattern<iPTR, 2, "SelectAddr", [frameindex], [SDNPWantParent]>;
 325
 326 //===----------------------------------------------------------------------===//
 327 // Instructions specific format
 328 //===----------------------------------------------------------------------===//
 329
 330 /// Move Control Registers From/To CPU Registers
 331 def MFC0_3OP  : MFC3OP<0x10, 0, (outs CPURegs:$rt),
 332                        (ins CPURegs:$rd, uimm16:$sel),"mfc0\t$rt, $rd, $sel">;
 333 def : InstAlias<"mfc0 $rt, $rd", (MFC0_3OP CPURegs:$rt, CPURegs:$rd, 0)>;
 334
 335 def MTC0_3OP  : MFC3OP<0x10, 4, (outs CPURegs:$rd, uimm16:$sel),
 336                        (ins CPURegs:$rt),"mtc0\t$rt, $rd, $sel">;
 337 def : InstAlias<"mtc0 $rt, $rd", (MTC0_3OP CPURegs:$rd, 0, CPURegs:$rt)>;
 338
 339 def MFC2_3OP  : MFC3OP<0x12, 0, (outs CPURegs:$rt),
 340                        (ins CPURegs:$rd, uimm16:$sel),"mfc2\t$rt, $rd, $sel">;
 341 def : InstAlias<"mfc2 $rt, $rd", (MFC2_3OP CPURegs:$rt, CPURegs:$rd, 0)>;
 342
 343 def MTC2_3OP  : MFC3OP<0x12, 4, (outs CPURegs:$rd, uimm16:$sel),
 344                        (ins CPURegs:$rt),"mtc2\t$rt, $rd, $sel">;
 345 def : InstAlias<"mtc2 $rt, $rd", (MTC2_3OP CPURegs:$rd, 0, CPURegs:$rt)>;
 346
 347 // Arithmetic and logical instructions with 3 register operands.
 348 class ArithLogicR<string opstr, InstrItinClass Itin, RegisterClass RC,
 349                   bit isComm = 0, SDPatternOperator OpNode = null_frag>:
 350   InstSE<(outs RC:$rd), (ins RC:$rs, RC:$rt),
 351          !strconcat(opstr, "\t$rd, $rs, $rt"),
 352          [(set RC:$rd, (OpNode RC:$rs, RC:$rt))], Itin, FrmR> {
 353   let isCommutable = isComm;
 354   let isReMaterializable = 1;
 355 }
 356
 357 // Arithmetic and logical instructions with 2 register operands.
 358 class ArithLogicI<string opstr, Operand Od, PatLeaf imm_type,
 359                   RegisterClass RC, SDPatternOperator OpNode = null_frag> :
 360   InstSE<(outs RC:$rt), (ins RC:$rs, Od:$imm16),
 361          !strconcat(opstr, "\t$rt, $rs, $imm16"),
 362          [(set RC:$rt, (OpNode RC:$rs, imm_type:$imm16))], IIAlu, FrmI> {
 363   let isReMaterializable = 1;
 364 }
 365
 366 // Arithmetic Multiply ADD/SUB
 367 let rd = 0, shamt = 0, Defs = [HI, LO], Uses = [HI, LO] in
 368 class MArithR<bits<6> func, string instr_asm, SDNode op, bit isComm = 0> :
 369   FR<0x1c, func, (outs), (ins CPURegs:$rs, CPURegs:$rt),
 370      !strconcat(instr_asm, "\t$rs, $rt"),
 371      [(op CPURegs:$rs, CPURegs:$rt, LO, HI)], IIImul> {
 372   let rd = 0;
 373   let shamt = 0;
 374   let isCommutable = isComm;
 375 }
 376
 377 //  Logical
 378 class LogicNOR<bits<6> op, bits<6> func, string instr_asm, RegisterClass RC>:
 379   FR<op, func, (outs RC:$rd), (ins RC:$rs, RC:$rt),
 380      !strconcat(instr_asm, "\t$rd, $rs, $rt"),
 381      [(set RC:$rd, (not (or RC:$rs, RC:$rt)))], IIAlu> {
 382   let shamt = 0;
 383   let isCommutable = 1;
 384 }
 385
 386 // Shifts
 387 class shift_rotate_imm<string opstr, PatFrag PF, Operand ImmOpnd,
 388                        RegisterClass RC, SDPatternOperator OpNode> :
 389   InstSE<(outs RC:$rd), (ins RC:$rt, ImmOpnd:$shamt),
 390          !strconcat(opstr, "\t$rd, $rt, $shamt"),
 391          [(set RC:$rd, (OpNode RC:$rt, PF:$shamt))], IIAlu, FrmR>;
 392
 393 // 32-bit shift instructions.
 394 class shift_rotate_imm32<string opstr, SDPatternOperator OpNode = null_frag> :
 395   shift_rotate_imm<opstr, immZExt5, shamt, CPURegs, OpNode>;
 396
 397 class shift_rotate_reg<bits<6> func, bits<5> isRotate, string instr_asm,
 398                        SDNode OpNode, RegisterClass RC>:
 399   FR<0x00, func, (outs RC:$rd), (ins CPURegs:$rs, RC:$rt),
 400      !strconcat(instr_asm, "\t$rd, $rt, $rs"),
 401      [(set RC:$rd, (OpNode RC:$rt, CPURegs:$rs))], IIAlu> {
 402   let shamt = isRotate;
 403 }
 404
 405 // Load Upper Imediate
 406 class LoadUpper<bits<6> op, string instr_asm, RegisterClass RC, Operand Imm>:
 407   FI<op, (outs RC:$rt), (ins Imm:$imm16),
 408      !strconcat(instr_asm, "\t$rt, $imm16"), [], IIAlu>, IsAsCheapAsAMove {
 409   let rs = 0;
 410   let neverHasSideEffects = 1;
 411   let isReMaterializable = 1;
 412 }
 413
 414 class FMem<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern,
 415           InstrItinClass itin>: FFI<op, outs, ins, asmstr, pattern> {
 416   bits<21> addr;
 417   let Inst{25-21} = addr{20-16};
 418   let Inst{15-0}  = addr{15-0};
 419   let DecoderMethod = "DecodeMem";
 420 }
 421
 422 // Memory Load/Store
 423 let canFoldAsLoad = 1 in
 424 class LoadM<bits<6> op, string instr_asm, PatFrag OpNode, RegisterClass RC,
 425             Operand MemOpnd, bit Pseudo>:
 426   FMem<op, (outs RC:$rt), (ins MemOpnd:$addr),
 427      !strconcat(instr_asm, "\t$rt, $addr"),
 428      [(set RC:$rt, (OpNode addr:$addr))], IILoad> {
 429   let isPseudo = Pseudo;
 430 }
 431
 432 class StoreM<bits<6> op, string instr_asm, PatFrag OpNode, RegisterClass RC,
 433              Operand MemOpnd, bit Pseudo>:
 434   FMem<op, (outs), (ins RC:$rt, MemOpnd:$addr),
 435      !strconcat(instr_asm, "\t$rt, $addr"),
 436      [(OpNode RC:$rt, addr:$addr)], IIStore> {
 437   let isPseudo = Pseudo;
 438 }
 439
 440 // 32-bit load.
 441 multiclass LoadM32<bits<6> op, string instr_asm, PatFrag OpNode,
 442                    bit Pseudo = 0> {
 443   def #NAME# : LoadM<op, instr_asm, OpNode, CPURegs, mem, Pseudo>,
 444                Requires<[NotN64, HasStdEnc]>;
 445   def _P8    : LoadM<op, instr_asm, OpNode, CPURegs, mem64, Pseudo>,
 446                Requires<[IsN64, HasStdEnc]> {
 447     let DecoderNamespace = "Mips64";
 448     let isCodeGenOnly = 1;
 449   }
 450 }
 451
 452 // 64-bit load.
 453 multiclass LoadM64<bits<6> op, string instr_asm, PatFrag OpNode,
 454                    bit Pseudo = 0> {
 455   def #NAME# : LoadM<op, instr_asm, OpNode, CPU64Regs, mem, Pseudo>,
 456                Requires<[NotN64, HasStdEnc]>;
 457   def _P8    : LoadM<op, instr_asm, OpNode, CPU64Regs, mem64, Pseudo>,
 458                Requires<[IsN64, HasStdEnc]> {
 459     let DecoderNamespace = "Mips64";
 460     let isCodeGenOnly = 1;
 461   }
 462 }
 463
 464 // 32-bit store.
 465 multiclass StoreM32<bits<6> op, string instr_asm, PatFrag OpNode,
 466                     bit Pseudo = 0> {
 467   def #NAME# : StoreM<op, instr_asm, OpNode, CPURegs, mem, Pseudo>,
 468                Requires<[NotN64, HasStdEnc]>;
 469   def _P8    : StoreM<op, instr_asm, OpNode, CPURegs, mem64, Pseudo>,
 470                Requires<[IsN64, HasStdEnc]> {
 471     let DecoderNamespace = "Mips64";
 472     let isCodeGenOnly = 1;
 473   }
 474 }
 475
 476 // 64-bit store.
 477 multiclass StoreM64<bits<6> op, string instr_asm, PatFrag OpNode,
 478                     bit Pseudo = 0> {
 479   def #NAME# : StoreM<op, instr_asm, OpNode, CPU64Regs, mem, Pseudo>,
 480                Requires<[NotN64, HasStdEnc]>;
 481   def _P8    : StoreM<op, instr_asm, OpNode, CPU64Regs, mem64, Pseudo>,
 482                Requires<[IsN64, HasStdEnc]> {
 483     let DecoderNamespace = "Mips64";
 484     let isCodeGenOnly = 1;
 485   }
 486 }
 487
 488 // Load/Store Left/Right
 489 let canFoldAsLoad = 1 in
 490 class LoadLeftRight<bits<6> op, string instr_asm, SDNode OpNode,
 491                     RegisterClass RC, Operand MemOpnd> :
 492   FMem<op, (outs RC:$rt), (ins MemOpnd:$addr, RC:$src),
 493        !strconcat(instr_asm, "\t$rt, $addr"),
 494        [(set RC:$rt, (OpNode addr:$addr, RC:$src))], IILoad> {
 495   string Constraints = "$src = $rt";
 496 }
 497
 498 class StoreLeftRight<bits<6> op, string instr_asm, SDNode OpNode,
 499                      RegisterClass RC, Operand MemOpnd>:
 500   FMem<op, (outs), (ins RC:$rt, MemOpnd:$addr),
 501        !strconcat(instr_asm, "\t$rt, $addr"), [(OpNode RC:$rt, addr:$addr)],
 502        IIStore>;
 503
 504 // 32-bit load left/right.
 505 multiclass LoadLeftRightM32<bits<6> op, string instr_asm, SDNode OpNode> {
 506   def #NAME# : LoadLeftRight<op, instr_asm, OpNode, CPURegs, mem>,
 507                Requires<[NotN64, HasStdEnc]>;
 508   def _P8    : LoadLeftRight<op, instr_asm, OpNode, CPURegs, mem64>,
 509                Requires<[IsN64, HasStdEnc]> {
 510     let DecoderNamespace = "Mips64";
 511     let isCodeGenOnly = 1;
 512   }
 513 }
 514
 515 // 64-bit load left/right.
 516 multiclass LoadLeftRightM64<bits<6> op, string instr_asm, SDNode OpNode> {
 517   def #NAME# : LoadLeftRight<op, instr_asm, OpNode, CPU64Regs, mem>,
 518                Requires<[NotN64, HasStdEnc]>;
 519   def _P8    : LoadLeftRight<op, instr_asm, OpNode, CPU64Regs, mem64>,
 520                Requires<[IsN64, HasStdEnc]> {
 521     let DecoderNamespace = "Mips64";
 522     let isCodeGenOnly = 1;
 523   }
 524 }
 525
 526 // 32-bit store left/right.
 527 multiclass StoreLeftRightM32<bits<6> op, string instr_asm, SDNode OpNode> {
 528   def #NAME# : StoreLeftRight<op, instr_asm, OpNode, CPURegs, mem>,
 529                Requires<[NotN64, HasStdEnc]>;
 530   def _P8    : StoreLeftRight<op, instr_asm, OpNode, CPURegs, mem64>,
 531                Requires<[IsN64, HasStdEnc]> {
 532     let DecoderNamespace = "Mips64";
 533     let isCodeGenOnly = 1;
 534   }
 535 }
 536
 537 // 64-bit store left/right.
 538 multiclass StoreLeftRightM64<bits<6> op, string instr_asm, SDNode OpNode> {
 539   def #NAME# : StoreLeftRight<op, instr_asm, OpNode, CPU64Regs, mem>,
 540                Requires<[NotN64, HasStdEnc]>;
 541   def _P8    : StoreLeftRight<op, instr_asm, OpNode, CPU64Regs, mem64>,
 542                Requires<[IsN64, HasStdEnc]> {
 543     let DecoderNamespace = "Mips64";
 544     let isCodeGenOnly = 1;
 545   }
 546 }
 547
 548 // Conditional Branch
 549 class CBranch<bits<6> op, string instr_asm, PatFrag cond_op, RegisterClass RC>:
 550   BranchBase<op, (outs), (ins RC:$rs, RC:$rt, brtarget:$imm16),
 551              !strconcat(instr_asm, "\t$rs, $rt, $imm16"),
 552              [(brcond (i32 (cond_op RC:$rs, RC:$rt)), bb:$imm16)], IIBranch> {
 553   let isBranch = 1;
 554   let isTerminator = 1;
 555   let hasDelaySlot = 1;
 556   let Defs = [AT];
 557 }
 558
 559 class CBranchZero<bits<6> op, bits<5> _rt, string instr_asm, PatFrag cond_op,
 560                   RegisterClass RC>:
 561   BranchBase<op, (outs), (ins RC:$rs, brtarget:$imm16),
 562              !strconcat(instr_asm, "\t$rs, $imm16"),
 563              [(brcond (i32 (cond_op RC:$rs, 0)), bb:$imm16)], IIBranch> {
 564   let rt = _rt;
 565   let isBranch = 1;
 566   let isTerminator = 1;
 567   let hasDelaySlot = 1;
 568   let Defs = [AT];
 569 }
 570
 571 // SetCC
 572 class SetCC_R<bits<6> op, bits<6> func, string instr_asm, PatFrag cond_op,
 573               RegisterClass RC>:
 574   FR<op, func, (outs CPURegs:$rd), (ins RC:$rs, RC:$rt),
 575      !strconcat(instr_asm, "\t$rd, $rs, $rt"),
 576      [(set CPURegs:$rd, (cond_op RC:$rs, RC:$rt))],
 577      IIAlu> {
 578   let shamt = 0;
 579 }
 580
 581 class SetCC_I<bits<6> op, string instr_asm, PatFrag cond_op, Operand Od,
 582               PatLeaf imm_type, RegisterClass RC>:
 583   FI<op, (outs CPURegs:$rt), (ins RC:$rs, Od:$imm16),
 584      !strconcat(instr_asm, "\t$rt, $rs, $imm16"),
 585      [(set CPURegs:$rt, (cond_op RC:$rs, imm_type:$imm16))],
 586      IIAlu>;
 587
 588 // Jump
 589 class JumpFJ<bits<6> op, DAGOperand opnd, string instr_asm,
 590              SDPatternOperator operator, SDPatternOperator targetoperator>:
 591   FJ<op, (outs), (ins opnd:$target), !strconcat(instr_asm, "\t$target"),
 592      [(operator targetoperator:$target)], IIBranch> {
 593   let isTerminator=1;
 594   let isBarrier=1;
 595   let hasDelaySlot = 1;
 596   let DecoderMethod = "DecodeJumpTarget";
 597   let Defs = [AT];
 598 }
 599
 600 // Unconditional branch
 601 class UncondBranch<bits<6> op, string instr_asm>:
 602   BranchBase<op, (outs), (ins brtarget:$imm16),
 603              !strconcat(instr_asm, "\t$imm16"), [(br bb:$imm16)], IIBranch> {
 604   let rs = 0;
 605   let rt = 0;
 606   let isBranch = 1;
 607   let isTerminator = 1;
 608   let isBarrier = 1;
 609   let hasDelaySlot = 1;
 610   let Predicates = [RelocPIC, HasStdEnc];
 611   let Defs = [AT];
 612 }
 613
 614 // Base class for indirect branch and return instruction classes.
 615 let isTerminator=1, isBarrier=1, hasDelaySlot = 1 in
 616 class JumpFR<RegisterClass RC, SDPatternOperator operator = null_frag>:
 617   FR<0, 0x8, (outs), (ins RC:$rs), "jr\t$rs", [(operator RC:$rs)], IIBranch> {
 618   let rt = 0;
 619   let rd = 0;
 620   let shamt = 0;
 621 }
 622
 623 // Indirect branch
 624 class IndirectBranch<RegisterClass RC>: JumpFR<RC, brind> {
 625   let isBranch = 1;
 626   let isIndirectBranch = 1;
 627 }
 628
 629 // Return instruction
 630 class RetBase<RegisterClass RC>: JumpFR<RC> {
 631   let isReturn = 1;
 632   let isCodeGenOnly = 1;
 633   let hasCtrlDep = 1;
 634   let hasExtraSrcRegAllocReq = 1;
 635 }
 636
 637 // Jump and Link (Call)
 638 let isCall=1, hasDelaySlot=1, Defs = [RA] in {
 639   class JumpLink<bits<6> op, string instr_asm>:
 640     FJ<op, (outs), (ins calltarget:$target),
 641        !strconcat(instr_asm, "\t$target"), [(MipsJmpLink imm:$target)],
 642        IIBranch> {
 643        let DecoderMethod = "DecodeJumpTarget";
 644        }
 645
 646   class JumpLinkReg<bits<6> op, bits<6> func, string instr_asm,
 647                     RegisterClass RC>:
 648     FR<op, func, (outs), (ins RC:$rs),
 649        !strconcat(instr_asm, "\t$rs"), [(MipsJmpLink RC:$rs)], IIBranch> {
 650     let rt = 0;
 651     let rd = 31;
 652     let shamt = 0;
 653   }
 654
 655   class BranchLink<string instr_asm, bits<5> _rt, RegisterClass RC>:
 656     FI<0x1, (outs), (ins RC:$rs, brtarget:$imm16),
 657        !strconcat(instr_asm, "\t$rs, $imm16"), [], IIBranch> {
 658     let rt = _rt;
 659   }
 660 }
 661
 662 // Mul, Div
 663 class Mult<bits<6> func, string instr_asm, InstrItinClass itin,
 664            RegisterClass RC, list<Register> DefRegs>:
 665   FR<0x00, func, (outs), (ins RC:$rs, RC:$rt),
 666      !strconcat(instr_asm, "\t$rs, $rt"), [], itin> {
 667   let rd = 0;
 668   let shamt = 0;
 669   let isCommutable = 1;
 670   let Defs = DefRegs;
 671   let neverHasSideEffects = 1;
 672 }
 673
 674 class Mult32<bits<6> func, string instr_asm, InstrItinClass itin>:
 675   Mult<func, instr_asm, itin, CPURegs, [HI, LO]>;
 676
 677 class Div<SDNode op, bits<6> func, string instr_asm, InstrItinClass itin,
 678           RegisterClass RC, list<Register> DefRegs>:
 679   FR<0x00, func, (outs), (ins RC:$rs, RC:$rt),
 680      !strconcat(instr_asm, "\t$$zero, $rs, $rt"),
 681      [(op RC:$rs, RC:$rt)], itin> {
 682   let rd = 0;
 683   let shamt = 0;
 684   let Defs = DefRegs;
 685 }
 686
 687 class Div32<SDNode op, bits<6> func, string instr_asm, InstrItinClass itin>:
 688   Div<op, func, instr_asm, itin, CPURegs, [HI, LO]>;
 689
 690 // Move from Hi/Lo
 691 class MoveFromLOHI<bits<6> func, string instr_asm, RegisterClass RC,
 692                    list<Register> UseRegs>:
 693   FR<0x00, func, (outs RC:$rd), (ins),
 694      !strconcat(instr_asm, "\t$rd"), [], IIHiLo> {
 695   let rs = 0;
 696   let rt = 0;
 697   let shamt = 0;
 698   let Uses = UseRegs;
 699   let neverHasSideEffects = 1;
 700 }
 701
 702 class MoveToLOHI<bits<6> func, string instr_asm, RegisterClass RC,
 703                  list<Register> DefRegs>:
 704   FR<0x00, func, (outs), (ins RC:$rs),
 705      !strconcat(instr_asm, "\t$rs"), [], IIHiLo> {
 706   let rt = 0;
 707   let rd = 0;
 708   let shamt = 0;
 709   let Defs = DefRegs;
 710   let neverHasSideEffects = 1;
 711 }
 712
 713 class EffectiveAddress<bits<6> opc, string instr_asm, RegisterClass RC, Operand Mem> :
 714   FMem<opc, (outs RC:$rt), (ins Mem:$addr),
 715      instr_asm, [(set RC:$rt, addr:$addr)], IIAlu> {
 716  let isCodeGenOnly = 1;
 717 }
 718
 719 // Count Leading Ones/Zeros in Word
 720 class CountLeading0<bits<6> func, string instr_asm, RegisterClass RC>:
 721   FR<0x1c, func, (outs RC:$rd), (ins RC:$rs),
 722      !strconcat(instr_asm, "\t$rd, $rs"),
 723      [(set RC:$rd, (ctlz RC:$rs))], IIAlu>,
 724      Requires<[HasBitCount, HasStdEnc]> {
 725   let shamt = 0;
 726   let rt = rd;
 727 }
 728
 729 class CountLeading1<bits<6> func, string instr_asm, RegisterClass RC>:
 730   FR<0x1c, func, (outs RC:$rd), (ins RC:$rs),
 731      !strconcat(instr_asm, "\t$rd, $rs"),
 732      [(set RC:$rd, (ctlz (not RC:$rs)))], IIAlu>,
 733      Requires<[HasBitCount, HasStdEnc]> {
 734   let shamt = 0;
 735   let rt = rd;
 736 }
 737
 738 // Sign Extend in Register.
 739 class SignExtInReg<bits<5> sa, string instr_asm, ValueType vt,
 740                    RegisterClass RC>:
 741   FR<0x1f, 0x20, (outs RC:$rd), (ins RC:$rt),
 742      !strconcat(instr_asm, "\t$rd, $rt"),
 743      [(set RC:$rd, (sext_inreg RC:$rt, vt))], NoItinerary> {
 744   let rs = 0;
 745   let shamt = sa;
 746   let Predicates = [HasSEInReg, HasStdEnc];
 747 }
 748
 749 // Subword Swap
 750 class SubwordSwap<bits<6> func, bits<5> sa, string instr_asm, RegisterClass RC>:
 751   FR<0x1f, func, (outs RC:$rd), (ins RC:$rt),
 752      !strconcat(instr_asm, "\t$rd, $rt"), [], NoItinerary> {
 753   let rs = 0;
 754   let shamt = sa;
 755   let Predicates = [HasSwap, HasStdEnc];
 756   let neverHasSideEffects = 1;
 757 }
 758
 759 // Read Hardware
 760 class ReadHardware<RegisterClass CPURegClass, RegisterClass HWRegClass>
 761   : FR<0x1f, 0x3b, (outs CPURegClass:$rt), (ins HWRegClass:$rd),
 762        "rdhwr\t$rt, $rd", [], IIAlu> {
 763   let rs = 0;
 764   let shamt = 0;
 765 }
 766
 767 // Ext and Ins
 768 class ExtBase<bits<6> _funct, string instr_asm, RegisterClass RC>:
 769   FR<0x1f, _funct, (outs RC:$rt), (ins RC:$rs, uimm16:$pos, size_ext:$sz),
 770      !strconcat(instr_asm, " $rt, $rs, $pos, $sz"),
 771      [(set RC:$rt, (MipsExt RC:$rs, imm:$pos, imm:$sz))], NoItinerary> {
 772   bits<5> pos;
 773   bits<5> sz;
 774   let rd = sz;
 775   let shamt = pos;
 776   let Predicates = [HasMips32r2, HasStdEnc];
 777 }
 778
 779 class InsBase<bits<6> _funct, string instr_asm, RegisterClass RC>:
 780   FR<0x1f, _funct, (outs RC:$rt),
 781      (ins RC:$rs, uimm16:$pos, size_ins:$sz, RC:$src),
 782      !strconcat(instr_asm, " $rt, $rs, $pos, $sz"),
 783      [(set RC:$rt, (MipsIns RC:$rs, imm:$pos, imm:$sz, RC:$src))],
 784      NoItinerary> {
 785   bits<5> pos;
 786   bits<5> sz;
 787   let rd = sz;
 788   let shamt = pos;
 789   let Predicates = [HasMips32r2, HasStdEnc];
 790   let Constraints = "$src = $rt";
 791 }
 792
 793 // Atomic instructions with 2 source operands (ATOMIC_SWAP & ATOMIC_LOAD_*).
 794 class Atomic2Ops<PatFrag Op, string Opstr, RegisterClass DRC,
 795                  RegisterClass PRC> :
 796   PseudoSE<(outs DRC:$dst), (ins PRC:$ptr, DRC:$incr),
 797            !strconcat("atomic_", Opstr, "\t$dst, $ptr, $incr"),
 798            [(set DRC:$dst, (Op PRC:$ptr, DRC:$incr))]>;
 799
 800 multiclass Atomic2Ops32<PatFrag Op, string Opstr> {
 801   def #NAME# : Atomic2Ops<Op, Opstr, CPURegs, CPURegs>,
 802                           Requires<[NotN64, HasStdEnc]>;
 803   def _P8    : Atomic2Ops<Op, Opstr, CPURegs, CPU64Regs>,
 804                           Requires<[IsN64, HasStdEnc]> {
 805     let DecoderNamespace = "Mips64";
 806   }
 807 }
 808
 809 // Atomic Compare & Swap.
 810 class AtomicCmpSwap<PatFrag Op, string Width, RegisterClass DRC,
 811                     RegisterClass PRC> :
 812   PseudoSE<(outs DRC:$dst), (ins PRC:$ptr, DRC:$cmp, DRC:$swap),
 813            !strconcat("atomic_cmp_swap_", Width, "\t$dst, $ptr, $cmp, $swap"),
 814            [(set DRC:$dst, (Op PRC:$ptr, DRC:$cmp, DRC:$swap))]>;
 815
 816 multiclass AtomicCmpSwap32<PatFrag Op, string Width>  {
 817   def #NAME# : AtomicCmpSwap<Op, Width, CPURegs, CPURegs>,
 818                              Requires<[NotN64, HasStdEnc]>;
 819   def _P8    : AtomicCmpSwap<Op, Width, CPURegs, CPU64Regs>,
 820                              Requires<[IsN64, HasStdEnc]> {
 821     let DecoderNamespace = "Mips64";
 822   }
 823 }
 824
 825 class LLBase<bits<6> Opc, string opstring, RegisterClass RC, Operand Mem> :
 826   FMem<Opc, (outs RC:$rt), (ins Mem:$addr),
 827        !strconcat(opstring, "\t$rt, $addr"), [], IILoad> {
 828   let mayLoad = 1;
 829 }
 830
 831 class SCBase<bits<6> Opc, string opstring, RegisterClass RC, Operand Mem> :
 832   FMem<Opc, (outs RC:$dst), (ins RC:$rt, Mem:$addr),
 833        !strconcat(opstring, "\t$rt, $addr"), [], IIStore> {
 834   let mayStore = 1;
 835   let Constraints = "$rt = $dst";
 836 }
 837
 838 //===----------------------------------------------------------------------===//
 839 // Pseudo instructions
 840 //===----------------------------------------------------------------------===//
 841
 842 // Return RA.
 843 let isReturn=1, isTerminator=1, hasDelaySlot=1, isBarrier=1, hasCtrlDep=1 in
 844 def RetRA : PseudoSE<(outs), (ins), "", [(MipsRet)]>;
 845
 846 let Defs = [SP], Uses = [SP], hasSideEffects = 1 in {
 847 def ADJCALLSTACKDOWN : MipsPseudo<(outs), (ins i32imm:$amt),
 848                                   "!ADJCALLSTACKDOWN $amt",
 849                                   [(callseq_start timm:$amt)]>;
 850 def ADJCALLSTACKUP   : MipsPseudo<(outs), (ins i32imm:$amt1, i32imm:$amt2),
 851                                   "!ADJCALLSTACKUP $amt1",
 852                                   [(callseq_end timm:$amt1, timm:$amt2)]>;
 853 }
 854
 855 // When handling PIC code the assembler needs .cpload and .cprestore
 856 // directives. If the real instructions corresponding these directives
 857 // are used, we have the same behavior, but get also a bunch of warnings
 858 // from the assembler.
 859 let neverHasSideEffects = 1 in
 860 def CPRESTORE : PseudoSE<(outs), (ins i32imm:$loc, CPURegs:$gp),
 861                          ".cprestore\t$loc", []>;
 862
 863 let usesCustomInserter = 1 in {
 864   defm ATOMIC_LOAD_ADD_I8   : Atomic2Ops32<atomic_load_add_8, "load_add_8">;
 865   defm ATOMIC_LOAD_ADD_I16  : Atomic2Ops32<atomic_load_add_16, "load_add_16">;
 866   defm ATOMIC_LOAD_ADD_I32  : Atomic2Ops32<atomic_load_add_32, "load_add_32">;
 867   defm ATOMIC_LOAD_SUB_I8   : Atomic2Ops32<atomic_load_sub_8, "load_sub_8">;
 868   defm ATOMIC_LOAD_SUB_I16  : Atomic2Ops32<atomic_load_sub_16, "load_sub_16">;
 869   defm ATOMIC_LOAD_SUB_I32  : Atomic2Ops32<atomic_load_sub_32, "load_sub_32">;
 870   defm ATOMIC_LOAD_AND_I8   : Atomic2Ops32<atomic_load_and_8, "load_and_8">;
 871   defm ATOMIC_LOAD_AND_I16  : Atomic2Ops32<atomic_load_and_16, "load_and_16">;
 872   defm ATOMIC_LOAD_AND_I32  : Atomic2Ops32<atomic_load_and_32, "load_and_32">;
 873   defm ATOMIC_LOAD_OR_I8    : Atomic2Ops32<atomic_load_or_8, "load_or_8">;
 874   defm ATOMIC_LOAD_OR_I16   : Atomic2Ops32<atomic_load_or_16, "load_or_16">;
 875   defm ATOMIC_LOAD_OR_I32   : Atomic2Ops32<atomic_load_or_32, "load_or_32">;
 876   defm ATOMIC_LOAD_XOR_I8   : Atomic2Ops32<atomic_load_xor_8, "load_xor_8">;
 877   defm ATOMIC_LOAD_XOR_I16  : Atomic2Ops32<atomic_load_xor_16, "load_xor_16">;
 878   defm ATOMIC_LOAD_XOR_I32  : Atomic2Ops32<atomic_load_xor_32, "load_xor_32">;
 879   defm ATOMIC_LOAD_NAND_I8  : Atomic2Ops32<atomic_load_nand_8, "load_nand_8">;
 880   defm ATOMIC_LOAD_NAND_I16 : Atomic2Ops32<atomic_load_nand_16, "load_nand_16">;
 881   defm ATOMIC_LOAD_NAND_I32 : Atomic2Ops32<atomic_load_nand_32, "load_nand_32">;
 882
 883   defm ATOMIC_SWAP_I8       : Atomic2Ops32<atomic_swap_8, "swap_8">;
 884   defm ATOMIC_SWAP_I16      : Atomic2Ops32<atomic_swap_16, "swap_16">;
 885   defm ATOMIC_SWAP_I32      : Atomic2Ops32<atomic_swap_32, "swap_32">;
 886
 887   defm ATOMIC_CMP_SWAP_I8   : AtomicCmpSwap32<atomic_cmp_swap_8, "8">;
 888   defm ATOMIC_CMP_SWAP_I16  : AtomicCmpSwap32<atomic_cmp_swap_16, "16">;
 889   defm ATOMIC_CMP_SWAP_I32  : AtomicCmpSwap32<atomic_cmp_swap_32, "32">;
 890 }
 891
 892 //===----------------------------------------------------------------------===//
 893 // Instruction definition
 894 //===----------------------------------------------------------------------===//
 895
 896 class LoadImm32< string instr_asm, Operand Od, RegisterClass RC> :
 897   MipsAsmPseudoInst<(outs RC:$rt), (ins Od:$imm32),
 898                      !strconcat(instr_asm, "\t$rt, $imm32")> ;
 899 def LoadImm32Reg : LoadImm32<"li", shamt,CPURegs>;
 900
 901 class LoadAddress<string instr_asm, Operand MemOpnd, RegisterClass RC> :
 902   MipsAsmPseudoInst<(outs RC:$rt), (ins MemOpnd:$addr),
 903                      !strconcat(instr_asm, "\t$rt, $addr")> ;
 904 def LoadAddr32Reg : LoadAddress<"la", mem, CPURegs>;
 905
 906 class LoadAddressImm<string instr_asm, Operand Od, RegisterClass RC> :
 907   MipsAsmPseudoInst<(outs RC:$rt), (ins Od:$imm32),
 908                      !strconcat(instr_asm, "\t$rt, $imm32")> ;
 909 def LoadAddr32Imm : LoadAddressImm<"la", shamt,CPURegs>;
 910
 911 //===----------------------------------------------------------------------===//
 912 // MipsI Instructions
 913 //===----------------------------------------------------------------------===//
 914
 915 /// Arithmetic Instructions (ALU Immediate)
 916 def ADDiu : ArithLogicI<"addiu", simm16, immSExt16, CPURegs, add>,
 917             ADDI_FM<0x9>, IsAsCheapAsAMove;
 918 def ADDi  : ArithLogicI<"addi", simm16, immSExt16, CPURegs>, ADDI_FM<0x8>;
 919 def SLTi  : SetCC_I<0x0a, "slti", setlt, simm16, immSExt16, CPURegs>;
 920 def SLTiu : SetCC_I<0x0b, "sltiu", setult, simm16, immSExt16, CPURegs>;
 921 def ANDi  : ArithLogicI<"andi", uimm16, immZExt16, CPURegs, and>, ADDI_FM<0xc>;
 922 def ORi   : ArithLogicI<"ori", uimm16, immZExt16, CPURegs, or>, ADDI_FM<0xd>;
 923 def XORi  : ArithLogicI<"xori", uimm16, immZExt16, CPURegs, xor>, ADDI_FM<0xe>;
 924 def LUi   : LoadUpper<0x0f, "lui", CPURegs, uimm16>;
 925
 926 /// Arithmetic Instructions (3-Operand, R-Type)
 927 def ADDu : ArithLogicR<"addu", IIAlu, CPURegs, 1, add>, ADD_FM<0, 0x21>;
 928 def SUBu : ArithLogicR<"subu", IIAlu, CPURegs, 0, sub>, ADD_FM<0, 0x23>;
 929 def ADD  : ArithLogicR<"add", IIAlu, CPURegs, 1>, ADD_FM<0, 0x20>;
 930 def SUB  : ArithLogicR<"sub", IIAlu, CPURegs, 0>, ADD_FM<0, 0x22>;
 931 def SLT  : SetCC_R<0x00, 0x2a, "slt", setlt, CPURegs>;
 932 def SLTu : SetCC_R<0x00, 0x2b, "sltu", setult, CPURegs>;
 933 def AND  : ArithLogicR<"and", IIAlu, CPURegs, 1, and>, ADD_FM<0, 0x24>;
 934 def OR   : ArithLogicR<"or", IIAlu, CPURegs, 1, or>, ADD_FM<0, 0x25>;
 935 def XOR  : ArithLogicR<"xor", IIAlu, CPURegs, 1, xor>, ADD_FM<0, 0x26>;
 936 def NOR  : LogicNOR<0x00, 0x27, "nor", CPURegs>;
 937
 938 /// Shift Instructions
 939 def SLL  : shift_rotate_imm32<"sll", shl>, SRA_FM<0, 0>;
 940 def SRL  : shift_rotate_imm32<"srl", srl>, SRA_FM<2, 0>;
 941 def SRA  : shift_rotate_imm32<"sra", sra>, SRA_FM<3, 0>;
 942 def SLLV : shift_rotate_reg<0x04, 0x00, "sllv", shl, CPURegs>;
 943 def SRLV : shift_rotate_reg<0x06, 0x00, "srlv", srl, CPURegs>;
 944 def SRAV : shift_rotate_reg<0x07, 0x00, "srav", sra, CPURegs>;
 945
 946 // Rotate Instructions
 947 let Predicates = [HasMips32r2, HasStdEnc] in {
 948   def ROTR  : shift_rotate_imm32<"rotr", rotr>, SRA_FM<2, 1>;
 949   def ROTRV : shift_rotate_reg<0x06, 0x01, "rotrv", rotr, CPURegs>;
 950 }
 951
 952 /// Load and Store Instructions
 953 ///  aligned
 954 defm LB      : LoadM32<0x20, "lb",  sextloadi8>;
 955 defm LBu     : LoadM32<0x24, "lbu", zextloadi8>;
 956 defm LH      : LoadM32<0x21, "lh",  sextloadi16>;
 957 defm LHu     : LoadM32<0x25, "lhu", zextloadi16>;
 958 defm LW      : LoadM32<0x23, "lw",  load>;
 959 defm SB      : StoreM32<0x28, "sb", truncstorei8>;
 960 defm SH      : StoreM32<0x29, "sh", truncstorei16>;
 961 defm SW      : StoreM32<0x2b, "sw", store>;
 962
 963 /// load/store left/right
 964 defm LWL : LoadLeftRightM32<0x22, "lwl", MipsLWL>;
 965 defm LWR : LoadLeftRightM32<0x26, "lwr", MipsLWR>;
 966 defm SWL : StoreLeftRightM32<0x2a, "swl", MipsSWL>;
 967 defm SWR : StoreLeftRightM32<0x2e, "swr", MipsSWR>;
 968
 969 let hasSideEffects = 1 in
 970 def SYNC : InstSE<(outs), (ins i32imm:$stype), "sync $stype",
 971                   [(MipsSync imm:$stype)], NoItinerary, FrmOther>
 972 {
 973   bits<5> stype;
 974   let Opcode = 0;
 975   let Inst{25-11} = 0;
 976   let Inst{10-6} = stype;
 977   let Inst{5-0} = 15;
 978 }
 979
 980 /// Load-linked, Store-conditional
 981 def LL    : LLBase<0x30, "ll", CPURegs, mem>,
 982             Requires<[NotN64, HasStdEnc]>;
 983 def LL_P8 : LLBase<0x30, "ll", CPURegs, mem64>,
 984             Requires<[IsN64, HasStdEnc]> {
 985   let DecoderNamespace = "Mips64";
 986 }
 987
 988 def SC    : SCBase<0x38, "sc", CPURegs, mem>,
 989             Requires<[NotN64, HasStdEnc]>;
 990 def SC_P8 : SCBase<0x38, "sc", CPURegs, mem64>,
 991             Requires<[IsN64, HasStdEnc]> {
 992   let DecoderNamespace = "Mips64";
 993 }
 994
 995 /// Jump and Branch Instructions
 996 def J       : JumpFJ<0x02, jmptarget, "j", br, bb>,
 997               Requires<[RelocStatic, HasStdEnc]>, IsBranch;
 998 def JR      : IndirectBranch<CPURegs>;
 999 def B       : UncondBranch<0x04, "b">;
1000 def BEQ     : CBranch<0x04, "beq", seteq, CPURegs>;
1001 def BNE     : CBranch<0x05, "bne", setne, CPURegs>;
1002 def BGEZ    : CBranchZero<0x01, 1, "bgez", setge, CPURegs>;
1003 def BGTZ    : CBranchZero<0x07, 0, "bgtz", setgt, CPURegs>;
1004 def BLEZ    : CBranchZero<0x06, 0, "blez", setle, CPURegs>;
1005 def BLTZ    : CBranchZero<0x01, 0, "bltz", setlt, CPURegs>;
1006
1007 let rt = 0, rs = 0, isBranch = 1, isTerminator = 1, isBarrier = 1,
1008     hasDelaySlot = 1, Defs = [RA] in
1009 def BAL_BR: FI<0x1, (outs), (ins brtarget:$imm16), "bal\t$imm16", [], IIBranch>;
1010
1011 def JAL  : JumpLink<0x03, "jal">;
1012 def JALR : JumpLinkReg<0x00, 0x09, "jalr", CPURegs>;
1013 def BGEZAL  : BranchLink<"bgezal", 0x11, CPURegs>;
1014 def BLTZAL  : BranchLink<"bltzal", 0x10, CPURegs>;
1015 def TAILCALL : JumpFJ<0x02, calltarget, "j", MipsTailCall, imm>, IsTailCall;
1016 def TAILCALL_R : JumpFR<CPURegs, MipsTailCall>, IsTailCall;
1017
1018 def RET : RetBase<CPURegs>;
1019
1020 /// Multiply and Divide Instructions.
1021 def MULT    : Mult32<0x18, "mult", IIImul>;
1022 def MULTu   : Mult32<0x19, "multu", IIImul>;
1023 def SDIV    : Div32<MipsDivRem, 0x1a, "div", IIIdiv>;
1024 def UDIV    : Div32<MipsDivRemU, 0x1b, "divu", IIIdiv>;
1025
1026 def MTHI : MoveToLOHI<0x11, "mthi", CPURegs, [HI]>;
1027 def MTLO : MoveToLOHI<0x13, "mtlo", CPURegs, [LO]>;
1028 def MFHI : MoveFromLOHI<0x10, "mfhi", CPURegs, [HI]>;
1029 def MFLO : MoveFromLOHI<0x12, "mflo", CPURegs, [LO]>;
1030
1031 /// Sign Ext In Register Instructions.
1032 def SEB : SignExtInReg<0x10, "seb", i8, CPURegs>;
1033 def SEH : SignExtInReg<0x18, "seh", i16, CPURegs>;
1034
1035 /// Count Leading
1036 def CLZ : CountLeading0<0x20, "clz", CPURegs>;
1037 def CLO : CountLeading1<0x21, "clo", CPURegs>;
1038
1039 /// Word Swap Bytes Within Halfwords
1040 def WSBH : SubwordSwap<0x20, 0x2, "wsbh", CPURegs>;
1041
1042 /// No operation
1043 let addr=0 in
1044   def NOP   : FJ<0, (outs), (ins), "nop", [], IIAlu>;
1045
1046 // FrameIndexes are legalized when they are operands from load/store
1047 // instructions. The same not happens for stack address copies, so an
1048 // add op with mem ComplexPattern is used and the stack address copy
1049 // can be matched. It's similar to Sparc LEA_ADDRi
1050 def LEA_ADDiu : EffectiveAddress<0x09,"addiu\t$rt, $addr", CPURegs, mem_ea>;
1051
1052 // MADD*/MSUB*
1053 def MADD  : MArithR<0, "madd", MipsMAdd, 1>;
1054 def MADDU : MArithR<1, "maddu", MipsMAddu, 1>;
1055 def MSUB  : MArithR<4, "msub", MipsMSub>;
1056 def MSUBU : MArithR<5, "msubu", MipsMSubu>;
1057
1058 // MUL is a assembly macro in the current used ISAs. In recent ISA's
1059 // it is a real instruction.
1060 def MUL   : ArithLogicR<"mul", IIImul, CPURegs, 1, mul>, ADD_FM<0x1c, 0x02>;
1061
1062 def RDHWR : ReadHardware<CPURegs, HWRegs>;
1063
1064 def EXT : ExtBase<0, "ext", CPURegs>;
1065 def INS : InsBase<4, "ins", CPURegs>;
1066
1067 //===----------------------------------------------------------------------===//
1068 // Instruction aliases
1069 //===----------------------------------------------------------------------===//
1070 def : InstAlias<"move $dst,$src", (ADD CPURegs:$dst,CPURegs:$src,ZERO)>;
1071 def : InstAlias<"bal $offset", (BGEZAL RA,brtarget:$offset)>;
1072 def : InstAlias<"addu $rs,$rt,$imm",
1073                 (ADDiu CPURegs:$rs,CPURegs:$rt,simm16:$imm)>;
1074 def : InstAlias<"add $rs,$rt,$imm",
1075                 (ADDi CPURegs:$rs,CPURegs:$rt,simm16:$imm)>;
1076 def : InstAlias<"and $rs,$rt,$imm",
1077                 (ANDi CPURegs:$rs,CPURegs:$rt,simm16:$imm)>;
1078 def : InstAlias<"j $rs", (JR CPURegs:$rs)>;
1079 def : InstAlias<"not $rt,$rs", (NOR CPURegs:$rt,CPURegs:$rs,ZERO)>;
1080 def : InstAlias<"neg $rt,$rs", (SUB CPURegs:$rt,ZERO,CPURegs:$rs)>;
1081 def : InstAlias<"negu $rt,$rs", (SUBu CPURegs:$rt,ZERO,CPURegs:$rs)>;
1082 def : InstAlias<"slt $rs,$rt,$imm",
1083                 (SLTi CPURegs:$rs,CPURegs:$rt,simm16:$imm)>;
1084 def : InstAlias<"xor $rs,$rt,$imm",
1085                 (XORi CPURegs:$rs,CPURegs:$rt,simm16:$imm)>;
1086
1087 //===----------------------------------------------------------------------===//
1088 //  Arbitrary patterns that map to one or more instructions
1089 //===----------------------------------------------------------------------===//
1090
1091 // Small immediates
1092 def : MipsPat<(i32 immSExt16:$in),
1093               (ADDiu ZERO, imm:$in)>;
1094 def : MipsPat<(i32 immZExt16:$in),
1095               (ORi ZERO, imm:$in)>;
1096 def : MipsPat<(i32 immLow16Zero:$in),
1097               (LUi (HI16 imm:$in))>;
1098
1099 // Arbitrary immediates
1100 def : MipsPat<(i32 imm:$imm),
1101           (ORi (LUi (HI16 imm:$imm)), (LO16 imm:$imm))>;
1102
1103 // Carry MipsPatterns
1104 def : MipsPat<(subc CPURegs:$lhs, CPURegs:$rhs),
1105               (SUBu CPURegs:$lhs, CPURegs:$rhs)>;
1106 def : MipsPat<(addc CPURegs:$lhs, CPURegs:$rhs),
1107               (ADDu CPURegs:$lhs, CPURegs:$rhs)>;
1108 def : MipsPat<(addc  CPURegs:$src, immSExt16:$imm),
1109               (ADDiu CPURegs:$src, imm:$imm)>;
1110
1111 // Call
1112 def : MipsPat<(MipsJmpLink (i32 tglobaladdr:$dst)),
1113               (JAL tglobaladdr:$dst)>;
1114 def : MipsPat<(MipsJmpLink (i32 texternalsym:$dst)),
1115               (JAL texternalsym:$dst)>;
1116 //def : MipsPat<(MipsJmpLink CPURegs:$dst),
1117 //              (JALR CPURegs:$dst)>;
1118
1119 // Tail call
1120 def : MipsPat<(MipsTailCall (iPTR tglobaladdr:$dst)),
1121               (TAILCALL tglobaladdr:$dst)>;
1122 def : MipsPat<(MipsTailCall (iPTR texternalsym:$dst)),
1123               (TAILCALL texternalsym:$dst)>;
1124 // hi/lo relocs
1125 def : MipsPat<(MipsHi tglobaladdr:$in), (LUi tglobaladdr:$in)>;
1126 def : MipsPat<(MipsHi tblockaddress:$in), (LUi tblockaddress:$in)>;
1127 def : MipsPat<(MipsHi tjumptable:$in), (LUi tjumptable:$in)>;
1128 def : MipsPat<(MipsHi tconstpool:$in), (LUi tconstpool:$in)>;
1129 def : MipsPat<(MipsHi tglobaltlsaddr:$in), (LUi tglobaltlsaddr:$in)>;
1130 def : MipsPat<(MipsHi texternalsym:$in), (LUi texternalsym:$in)>;
1131
1132 def : MipsPat<(MipsLo tglobaladdr:$in), (ADDiu ZERO, tglobaladdr:$in)>;
1133 def : MipsPat<(MipsLo tblockaddress:$in), (ADDiu ZERO, tblockaddress:$in)>;
1134 def : MipsPat<(MipsLo tjumptable:$in), (ADDiu ZERO, tjumptable:$in)>;
1135 def : MipsPat<(MipsLo tconstpool:$in), (ADDiu ZERO, tconstpool:$in)>;
1136 def : MipsPat<(MipsLo tglobaltlsaddr:$in), (ADDiu ZERO, tglobaltlsaddr:$in)>;
1137 def : MipsPat<(MipsLo texternalsym:$in), (ADDiu ZERO, texternalsym:$in)>;
1138
1139 def : MipsPat<(add CPURegs:$hi, (MipsLo tglobaladdr:$lo)),
1140               (ADDiu CPURegs:$hi, tglobaladdr:$lo)>;
1141 def : MipsPat<(add CPURegs:$hi, (MipsLo tblockaddress:$lo)),
1142               (ADDiu CPURegs:$hi, tblockaddress:$lo)>;
1143 def : MipsPat<(add CPURegs:$hi, (MipsLo tjumptable:$lo)),
1144               (ADDiu CPURegs:$hi, tjumptable:$lo)>;
1145 def : MipsPat<(add CPURegs:$hi, (MipsLo tconstpool:$lo)),
1146               (ADDiu CPURegs:$hi, tconstpool:$lo)>;
1147 def : MipsPat<(add CPURegs:$hi, (MipsLo tglobaltlsaddr:$lo)),
1148               (ADDiu CPURegs:$hi, tglobaltlsaddr:$lo)>;
1149
1150 // gp_rel relocs
1151 def : MipsPat<(add CPURegs:$gp, (MipsGPRel tglobaladdr:$in)),
1152               (ADDiu CPURegs:$gp, tglobaladdr:$in)>;
1153 def : MipsPat<(add CPURegs:$gp, (MipsGPRel tconstpool:$in)),
1154               (ADDiu CPURegs:$gp, tconstpool:$in)>;
1155
1156 // wrapper_pic
1157 class WrapperPat<SDNode node, Instruction ADDiuOp, RegisterClass RC>:
1158       MipsPat<(MipsWrapper RC:$gp, node:$in),
1159               (ADDiuOp RC:$gp, node:$in)>;
1160
1161 def : WrapperPat<tglobaladdr, ADDiu, CPURegs>;
1162 def : WrapperPat<tconstpool, ADDiu, CPURegs>;
1163 def : WrapperPat<texternalsym, ADDiu, CPURegs>;
1164 def : WrapperPat<tblockaddress, ADDiu, CPURegs>;
1165 def : WrapperPat<tjumptable, ADDiu, CPURegs>;
1166 def : WrapperPat<tglobaltlsaddr, ADDiu, CPURegs>;
1167
1168 // Mips does not have "not", so we expand our way
1169 def : MipsPat<(not CPURegs:$in),
1170               (NOR CPURegs:$in, ZERO)>;
1171
1172 // extended loads
1173 let Predicates = [NotN64, HasStdEnc] in {
1174   def : MipsPat<(i32 (extloadi1  addr:$src)), (LBu addr:$src)>;
1175   def : MipsPat<(i32 (extloadi8  addr:$src)), (LBu addr:$src)>;
1176   def : MipsPat<(i32 (extloadi16 addr:$src)), (LHu addr:$src)>;
1177 }
1178 let Predicates = [IsN64, HasStdEnc] in {
1179   def : MipsPat<(i32 (extloadi1  addr:$src)), (LBu_P8 addr:$src)>;
1180   def : MipsPat<(i32 (extloadi8  addr:$src)), (LBu_P8 addr:$src)>;
1181   def : MipsPat<(i32 (extloadi16 addr:$src)), (LHu_P8 addr:$src)>;
1182 }
1183
1184 // peepholes
1185 let Predicates = [NotN64, HasStdEnc] in {
1186   def : MipsPat<(store (i32 0), addr:$dst), (SW ZERO, addr:$dst)>;
1187 }
1188 let Predicates = [IsN64, HasStdEnc] in {
1189   def : MipsPat<(store (i32 0), addr:$dst), (SW_P8 ZERO, addr:$dst)>;
1190 }
1191
1192 // brcond patterns
1193 multiclass BrcondPats<RegisterClass RC, Instruction BEQOp, Instruction BNEOp,
1194                       Instruction SLTOp, Instruction SLTuOp, Instruction SLTiOp,
1195                       Instruction SLTiuOp, Register ZEROReg> {
1196 def : MipsPat<(brcond (i32 (setne RC:$lhs, 0)), bb:$dst),
1197               (BNEOp RC:$lhs, ZEROReg, bb:$dst)>;
1198 def : MipsPat<(brcond (i32 (seteq RC:$lhs, 0)), bb:$dst),
1199               (BEQOp RC:$lhs, ZEROReg, bb:$dst)>;
1200
1201 def : MipsPat<(brcond (i32 (setge RC:$lhs, RC:$rhs)), bb:$dst),
1202               (BEQ (SLTOp RC:$lhs, RC:$rhs), ZERO, bb:$dst)>;
1203 def : MipsPat<(brcond (i32 (setuge RC:$lhs, RC:$rhs)), bb:$dst),
1204               (BEQ (SLTuOp RC:$lhs, RC:$rhs), ZERO, bb:$dst)>;
1205 def : MipsPat<(brcond (i32 (setge RC:$lhs, immSExt16:$rhs)), bb:$dst),
1206               (BEQ (SLTiOp RC:$lhs, immSExt16:$rhs), ZERO, bb:$dst)>;
1207 def : MipsPat<(brcond (i32 (setuge RC:$lhs, immSExt16:$rhs)), bb:$dst),
1208               (BEQ (SLTiuOp RC:$lhs, immSExt16:$rhs), ZERO, bb:$dst)>;
1209
1210 def : MipsPat<(brcond (i32 (setle RC:$lhs, RC:$rhs)), bb:$dst),
1211               (BEQ (SLTOp RC:$rhs, RC:$lhs), ZERO, bb:$dst)>;
1212 def : MipsPat<(brcond (i32 (setule RC:$lhs, RC:$rhs)), bb:$dst),
1213               (BEQ (SLTuOp RC:$rhs, RC:$lhs), ZERO, bb:$dst)>;
1214
1215 def : MipsPat<(brcond RC:$cond, bb:$dst),
1216               (BNEOp RC:$cond, ZEROReg, bb:$dst)>;
1217 }
1218
1219 defm : BrcondPats<CPURegs, BEQ, BNE, SLT, SLTu, SLTi, SLTiu, ZERO>;
1220
1221 // setcc patterns
1222 multiclass SeteqPats<RegisterClass RC, Instruction SLTiuOp, Instruction XOROp,
1223                      Instruction SLTuOp, Register ZEROReg> {
1224   def : MipsPat<(seteq RC:$lhs, RC:$rhs),
1225                 (SLTiuOp (XOROp RC:$lhs, RC:$rhs), 1)>;
1226   def : MipsPat<(setne RC:$lhs, RC:$rhs),
1227                 (SLTuOp ZEROReg, (XOROp RC:$lhs, RC:$rhs))>;
1228 }
1229
1230 multiclass SetlePats<RegisterClass RC, Instruction SLTOp, Instruction SLTuOp> {
1231   def : MipsPat<(setle RC:$lhs, RC:$rhs),
1232                 (XORi (SLTOp RC:$rhs, RC:$lhs), 1)>;
1233   def : MipsPat<(setule RC:$lhs, RC:$rhs),
1234                 (XORi (SLTuOp RC:$rhs, RC:$lhs), 1)>;
1235 }
1236
1237 multiclass SetgtPats<RegisterClass RC, Instruction SLTOp, Instruction SLTuOp> {
1238   def : MipsPat<(setgt RC:$lhs, RC:$rhs),
1239                 (SLTOp RC:$rhs, RC:$lhs)>;
1240   def : MipsPat<(setugt RC:$lhs, RC:$rhs),
1241                 (SLTuOp RC:$rhs, RC:$lhs)>;
1242 }
1243
1244 multiclass SetgePats<RegisterClass RC, Instruction SLTOp, Instruction SLTuOp> {
1245   def : MipsPat<(setge RC:$lhs, RC:$rhs),
1246                 (XORi (SLTOp RC:$lhs, RC:$rhs), 1)>;
1247   def : MipsPat<(setuge RC:$lhs, RC:$rhs),
1248                 (XORi (SLTuOp RC:$lhs, RC:$rhs), 1)>;
1249 }
1250
1251 multiclass SetgeImmPats<RegisterClass RC, Instruction SLTiOp,
1252                         Instruction SLTiuOp> {
1253   def : MipsPat<(setge RC:$lhs, immSExt16:$rhs),
1254                 (XORi (SLTiOp RC:$lhs, immSExt16:$rhs), 1)>;
1255   def : MipsPat<(setuge RC:$lhs, immSExt16:$rhs),
1256                 (XORi (SLTiuOp RC:$lhs, immSExt16:$rhs), 1)>;
1257 }
1258
1259 defm : SeteqPats<CPURegs, SLTiu, XOR, SLTu, ZERO>;
1260 defm : SetlePats<CPURegs, SLT, SLTu>;
1261 defm : SetgtPats<CPURegs, SLT, SLTu>;
1262 defm : SetgePats<CPURegs, SLT, SLTu>;
1263 defm : SetgeImmPats<CPURegs, SLTi, SLTiu>;
1264
1265 // bswap pattern
1266 def : MipsPat<(bswap CPURegs:$rt), (ROTR (WSBH CPURegs:$rt), 16)>;
1267
1268 //===----------------------------------------------------------------------===//
1269 // Floating Point Support
1270 //===----------------------------------------------------------------------===//
1271
1272 include "MipsInstrFPU.td"
1273 include "Mips64InstrInfo.td"
1274 include "MipsCondMov.td"
1275
1276 //
1277 // Mips16
1278
1279 include "Mips16InstrFormats.td"
1280 include "Mips16InstrInfo.td"
1281
1282 // DSP
1283 include "MipsDSPInstrFormats.td"
1284 include "MipsDSPInstrInfo.td"
1285