lib/Target/Mips/MipsInstrFormats.td

   1 //===-- MipsInstrFormats.td - Mips Instruction Formats -----*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 //  Describe MIPS instructions format
  12 //
  13 //  CPU INSTRUCTION FORMATS
  14 //
  15 //  opcode  - operation code.
  16 //  rs      - src reg.
  17 //  rt      - dst reg (on a 2 regs instr) or src reg (on a 3 reg instr).
  18 //  rd      - dst reg, only used on 3 regs instr.
  19 //  shamt   - only used on shift instructions, contains the shift amount.
  20 //  funct   - combined with opcode field give us an operation code.
  21 //
  22 //===----------------------------------------------------------------------===//
  23
  24 // Format specifies the encoding used by the instruction.  This is part of the
  25 // ad-hoc solution used to emit machine instruction encodings by our machine
  26 // code emitter.
  27 class Format<bits<4> val> {
  28   bits<4> Value = val;
  29 }
  30
  31 def Pseudo    : Format<0>;
  32 def FrmR      : Format<1>;
  33 def FrmI      : Format<2>;
  34 def FrmJ      : Format<3>;
  35 def FrmFR     : Format<4>;
  36 def FrmFI     : Format<5>;
  37 def FrmOther  : Format<6>; // Instruction w/ a custom format
  38
  39 class MMRel;
  40
  41 def Std2MicroMips : InstrMapping {
  42   let FilterClass = "MMRel";
  43   // Instructions with the same BaseOpcode and isNVStore values form a row.
  44   let RowFields = ["BaseOpcode"];
  45   // Instructions with the same predicate sense form a column.
  46   let ColFields = ["Arch"];
  47   // The key column is the unpredicated instructions.
  48   let KeyCol = ["se"];
  49   // Value columns are PredSense=true and PredSense=false
  50   let ValueCols = [["se"], ["micromips"]];
  51 }
  52
  53 class StdArch {
  54   string Arch = "se";
  55 }
  56
  57 // Generic Mips Format
  58 class MipsInst<dag outs, dag ins, string asmstr, list<dag> pattern,
  59                InstrItinClass itin, Format f>: Instruction
  60 {
  61   field bits<32> Inst;
  62   Format Form = f;
  63
  64   let Namespace = "Mips";
  65
  66   let Size = 4;
  67
  68   bits<6> Opcode = 0;
  69
  70   // Top 6 bits are the 'opcode' field
  71   let Inst{31-26} = Opcode;
  72
  73   let OutOperandList = outs;
  74   let InOperandList  = ins;
  75
  76   let AsmString   = asmstr;
  77   let Pattern     = pattern;
  78   let Itinerary   = itin;
  79
  80   //
  81   // Attributes specific to Mips instructions...
  82   //
  83   bits<4> FormBits = Form.Value;
  84
  85   // TSFlags layout should be kept in sync with MipsInstrInfo.h.
  86   let TSFlags{3-0}   = FormBits;
  87
  88   let DecoderNamespace = "Mips";
  89
  90   field bits<32> SoftFail = 0;
  91 }
  92
  93 // Mips32/64 Instruction Format
  94 class InstSE<dag outs, dag ins, string asmstr, list<dag> pattern,
  95              InstrItinClass itin, Format f, string opstr = ""> :
  96   MipsInst<outs, ins, asmstr, pattern, itin, f>, PredicateControl {
  97   let EncodingPredicates = [HasStdEnc];
  98   string BaseOpcode = opstr;
  99   string Arch;
 100 }
 101
 102 // Mips Pseudo Instructions Format
 103 class MipsPseudo<dag outs, dag ins, list<dag> pattern,
 104                  InstrItinClass itin = IIPseudo> :
 105   MipsInst<outs, ins, "", pattern, itin, Pseudo> {
 106   let isCodeGenOnly = 1;
 107   let isPseudo = 1;
 108 }
 109
 110 // Mips32/64 Pseudo Instruction Format
 111 class PseudoSE<dag outs, dag ins, list<dag> pattern,
 112                InstrItinClass itin = IIPseudo> :
 113   MipsPseudo<outs, ins, pattern, itin>, PredicateControl {
 114   let EncodingPredicates = [HasStdEnc];
 115 }
 116
 117 // Pseudo-instructions for alternate assembly syntax (never used by codegen).
 118 // These are aliases that require C++ handling to convert to the target
 119 // instruction, while InstAliases can be handled directly by tblgen.
 120 class MipsAsmPseudoInst<dag outs, dag ins, string asmstr>:
 121   MipsInst<outs, ins, asmstr, [], IIPseudo, Pseudo> {
 122   let isPseudo = 1;
 123   let Pattern = [];
 124 }
 125 //===----------------------------------------------------------------------===//
 126 // Format R instruction class in Mips : <|opcode|rs|rt|rd|shamt|funct|>
 127 //===----------------------------------------------------------------------===//
 128
 129 class FR<bits<6> op, bits<6> _funct, dag outs, dag ins, string asmstr,
 130          list<dag> pattern, InstrItinClass itin>:
 131   InstSE<outs, ins, asmstr, pattern, itin, FrmR>
 132 {
 133   bits<5>  rd;
 134   bits<5>  rs;
 135   bits<5>  rt;
 136   bits<5>  shamt;
 137   bits<6>  funct;
 138
 139   let Opcode = op;
 140   let funct  = _funct;
 141
 142   let Inst{25-21} = rs;
 143   let Inst{20-16} = rt;
 144   let Inst{15-11} = rd;
 145   let Inst{10-6}  = shamt;
 146   let Inst{5-0}   = funct;
 147 }
 148
 149 //===----------------------------------------------------------------------===//
 150 // Format I instruction class in Mips : <|opcode|rs|rt|immediate|>
 151 //===----------------------------------------------------------------------===//
 152
 153 class FI<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern,
 154          InstrItinClass itin>: InstSE<outs, ins, asmstr, pattern, itin, FrmI>
 155 {
 156   bits<5>  rt;
 157   bits<5>  rs;
 158   bits<16> imm16;
 159
 160   let Opcode = op;
 161
 162   let Inst{25-21} = rs;
 163   let Inst{20-16} = rt;
 164   let Inst{15-0}  = imm16;
 165 }
 166
 167 class BranchBase<bits<6> op, dag outs, dag ins, string asmstr,
 168                   list<dag> pattern, InstrItinClass itin>:
 169   InstSE<outs, ins, asmstr, pattern, itin, FrmI>
 170 {
 171   bits<5>  rs;
 172   bits<5>  rt;
 173   bits<16> imm16;
 174
 175   let Opcode = op;
 176
 177   let Inst{25-21} = rs;
 178   let Inst{20-16} = rt;
 179   let Inst{15-0}  = imm16;
 180 }
 181
 182 //===----------------------------------------------------------------------===//
 183 // Format J instruction class in Mips : <|opcode|address|>
 184 //===----------------------------------------------------------------------===//
 185
 186 class FJ<bits<6> op> : StdArch
 187 {
 188   bits<26> target;
 189
 190   bits<32> Inst;
 191
 192   let Inst{31-26} = op;
 193   let Inst{25-0}  = target;
 194 }
 195
 196 //===----------------------------------------------------------------------===//
 197 // MFC instruction class in Mips : <|op|mf|rt|rd|0000000|sel|>
 198 //===----------------------------------------------------------------------===//
 199 class MFC3OP_FM<bits<6> op, bits<5> mfmt>
 200 {
 201   bits<5> rt;
 202   bits<5> rd;
 203   bits<3> sel;
 204
 205   bits<32> Inst;
 206
 207   let Inst{31-26} = op;
 208   let Inst{25-21} = mfmt;
 209   let Inst{20-16} = rt;
 210   let Inst{15-11} = rd;
 211   let Inst{10-3}  = 0;
 212   let Inst{2-0}   = sel;
 213 }
 214
 215 class ADD_FM<bits<6> op, bits<6> funct> : StdArch {
 216   bits<5> rd;
 217   bits<5> rs;
 218   bits<5> rt;
 219
 220   bits<32> Inst;
 221
 222   let Inst{31-26} = op;
 223   let Inst{25-21} = rs;
 224   let Inst{20-16} = rt;
 225   let Inst{15-11} = rd;
 226   let Inst{10-6}  = 0;
 227   let Inst{5-0}   = funct;
 228 }
 229
 230 class ADDI_FM<bits<6> op> : StdArch {
 231   bits<5>  rs;
 232   bits<5>  rt;
 233   bits<16> imm16;
 234
 235   bits<32> Inst;
 236
 237   let Inst{31-26} = op;
 238   let Inst{25-21} = rs;
 239   let Inst{20-16} = rt;
 240   let Inst{15-0}  = imm16;
 241 }
 242
 243 class SRA_FM<bits<6> funct, bit rotate> : StdArch {
 244   bits<5> rd;
 245   bits<5> rt;
 246   bits<5> shamt;
 247
 248   bits<32> Inst;
 249
 250   let Inst{31-26} = 0;
 251   let Inst{25-22} = 0;
 252   let Inst{21}    = rotate;
 253   let Inst{20-16} = rt;
 254   let Inst{15-11} = rd;
 255   let Inst{10-6}  = shamt;
 256   let Inst{5-0}   = funct;
 257 }
 258
 259 class SRLV_FM<bits<6> funct, bit rotate> : StdArch {
 260   bits<5> rd;
 261   bits<5> rt;
 262   bits<5> rs;
 263
 264   bits<32> Inst;
 265
 266   let Inst{31-26} = 0;
 267   let Inst{25-21} = rs;
 268   let Inst{20-16} = rt;
 269   let Inst{15-11} = rd;
 270   let Inst{10-7}  = 0;
 271   let Inst{6}     = rotate;
 272   let Inst{5-0}   = funct;
 273 }
 274
 275 class BEQ_FM<bits<6> op> : StdArch {
 276   bits<5>  rs;
 277   bits<5>  rt;
 278   bits<16> offset;
 279
 280   bits<32> Inst;
 281
 282   let Inst{31-26} = op;
 283   let Inst{25-21} = rs;
 284   let Inst{20-16} = rt;
 285   let Inst{15-0}  = offset;
 286 }
 287
 288 class BGEZ_FM<bits<6> op, bits<5> funct> : StdArch {
 289   bits<5>  rs;
 290   bits<16> offset;
 291
 292   bits<32> Inst;
 293
 294   let Inst{31-26} = op;
 295   let Inst{25-21} = rs;
 296   let Inst{20-16} = funct;
 297   let Inst{15-0}  = offset;
 298 }
 299
 300 class SLTI_FM<bits<6> op> : StdArch {
 301   bits<5> rt;
 302   bits<5> rs;
 303   bits<16> imm16;
 304
 305   bits<32> Inst;
 306
 307   let Inst{31-26} = op;
 308   let Inst{25-21} = rs;
 309   let Inst{20-16} = rt;
 310   let Inst{15-0}  = imm16;
 311 }
 312
 313 class MFLO_FM<bits<6> funct> : StdArch {
 314   bits<5> rd;
 315
 316   bits<32> Inst;
 317
 318   let Inst{31-26} = 0;
 319   let Inst{25-16} = 0;
 320   let Inst{15-11} = rd;
 321   let Inst{10-6}  = 0;
 322   let Inst{5-0}   = funct;
 323 }
 324
 325 class MTLO_FM<bits<6> funct> : StdArch {
 326   bits<5> rs;
 327
 328   bits<32> Inst;
 329
 330   let Inst{31-26} = 0;
 331   let Inst{25-21} = rs;
 332   let Inst{20-6}  = 0;
 333   let Inst{5-0}   = funct;
 334 }
 335
 336 class SEB_FM<bits<5> funct, bits<6> funct2> : StdArch {
 337   bits<5> rd;
 338   bits<5> rt;
 339
 340   bits<32> Inst;
 341
 342   let Inst{31-26} = 0x1f;
 343   let Inst{25-21} = 0;
 344   let Inst{20-16} = rt;
 345   let Inst{15-11} = rd;
 346   let Inst{10-6}  = funct;
 347   let Inst{5-0}   = funct2;
 348 }
 349
 350 class CLO_FM<bits<6> funct> : StdArch {
 351   bits<5> rd;
 352   bits<5> rs;
 353   bits<5> rt;
 354
 355   bits<32> Inst;
 356
 357   let Inst{31-26} = 0x1c;
 358   let Inst{25-21} = rs;
 359   let Inst{20-16} = rt;
 360   let Inst{15-11} = rd;
 361   let Inst{10-6}  = 0;
 362   let Inst{5-0}   = funct;
 363   let rt = rd;
 364 }
 365
 366 class LUI_FM : StdArch {
 367   bits<5> rt;
 368   bits<16> imm16;
 369
 370   bits<32> Inst;
 371
 372   let Inst{31-26} = 0xf;
 373   let Inst{25-21} = 0;
 374   let Inst{20-16} = rt;
 375   let Inst{15-0}  = imm16;
 376 }
 377
 378 class JALR_FM {
 379   bits<5> rd;
 380   bits<5> rs;
 381
 382   bits<32> Inst;
 383
 384   let Inst{31-26} = 0;
 385   let Inst{25-21} = rs;
 386   let Inst{20-16} = 0;
 387   let Inst{15-11} = rd;
 388   let Inst{10-6}  = 0;
 389   let Inst{5-0}   = 9;
 390 }
 391
 392 class BGEZAL_FM<bits<5> funct> : StdArch {
 393   bits<5>  rs;
 394   bits<16> offset;
 395
 396   bits<32> Inst;
 397
 398   let Inst{31-26} = 1;
 399   let Inst{25-21} = rs;
 400   let Inst{20-16} = funct;
 401   let Inst{15-0}  = offset;
 402 }
 403
 404 class SYNC_FM : StdArch {
 405   bits<5> stype;
 406
 407   bits<32> Inst;
 408
 409   let Inst{31-26} = 0;
 410   let Inst{10-6}  = stype;
 411   let Inst{5-0}   = 0xf;
 412 }
 413
 414 class SYNCI_FM : StdArch {
 415   // Produced by the mem_simm16 address as reg << 16 | imm (see getMemEncoding).
 416   bits<21> addr;
 417   bits<5> rs = addr{20-16};
 418   bits<16> offset = addr{15-0};
 419
 420   bits<32> Inst;
 421
 422   let Inst{31-26} = 0b000001;
 423   let Inst{25-21} = rs;
 424   let Inst{20-16} = 0b11111;
 425   let Inst{15-0}  = offset;
 426 }
 427
 428 class MULT_FM<bits<6> op, bits<6> funct> : StdArch {
 429   bits<5>  rs;
 430   bits<5>  rt;
 431
 432   bits<32> Inst;
 433
 434   let Inst{31-26} = op;
 435   let Inst{25-21} = rs;
 436   let Inst{20-16} = rt;
 437   let Inst{15-6}  = 0;
 438   let Inst{5-0}   = funct;
 439 }
 440
 441 class EXT_FM<bits<6> funct> : StdArch {
 442   bits<5> rt;
 443   bits<5> rs;
 444   bits<5> pos;
 445   bits<5> size;
 446
 447   bits<32> Inst;
 448
 449   let Inst{31-26} = 0x1f;
 450   let Inst{25-21} = rs;
 451   let Inst{20-16} = rt;
 452   let Inst{15-11} = size;
 453   let Inst{10-6}  = pos;
 454   let Inst{5-0}   = funct;
 455 }
 456
 457 class RDHWR_FM : StdArch {
 458   bits<5> rt;
 459   bits<5> rd;
 460
 461   bits<32> Inst;
 462
 463   let Inst{31-26} = 0x1f;
 464   let Inst{25-21} = 0;
 465   let Inst{20-16} = rt;
 466   let Inst{15-11} = rd;
 467   let Inst{10-6}  = 0;
 468   let Inst{5-0}   = 0x3b;
 469 }
 470
 471 class TEQ_FM<bits<6> funct> : StdArch {
 472   bits<5> rs;
 473   bits<5> rt;
 474   bits<10> code_;
 475
 476   bits<32> Inst;
 477
 478   let Inst{31-26} = 0;
 479   let Inst{25-21} = rs;
 480   let Inst{20-16} = rt;
 481   let Inst{15-6}  = code_;
 482   let Inst{5-0}   = funct;
 483 }
 484
 485 class TEQI_FM<bits<5> funct> : StdArch {
 486   bits<5> rs;
 487   bits<16> imm16;
 488
 489   bits<32> Inst;
 490
 491   let Inst{31-26} = 1;
 492   let Inst{25-21} = rs;
 493   let Inst{20-16}   = funct;
 494   let Inst{15-0}  = imm16;
 495 }
 496
 497 class WAIT_FM : StdArch {
 498   bits<32> Inst;
 499
 500   let Inst{31-26} = 0x10;
 501   let Inst{25}    = 1;
 502   let Inst{24-6}  = 0;
 503   let Inst{5-0}   = 0x20;
 504 }
 505
 506 class EXTS_FM<bits<6> funct> : StdArch {
 507   bits<5> rt;
 508   bits<5> rs;
 509   bits<5> pos;
 510   bits<5> lenm1;
 511
 512   bits<32> Inst;
 513
 514   let Inst{31-26} = 0x1c;
 515   let Inst{25-21} = rs;
 516   let Inst{20-16} = rt;
 517   let Inst{15-11} = lenm1;
 518   let Inst{10-6}  = pos;
 519   let Inst{5-0}   = funct;
 520 }
 521
 522 class MTMR_FM<bits<6> funct> : StdArch {
 523   bits<5> rs;
 524
 525   bits<32> Inst;
 526
 527   let Inst{31-26} = 0x1c;
 528   let Inst{25-21} = rs;
 529   let Inst{20-6}  = 0;
 530   let Inst{5-0}   = funct;
 531 }
 532
 533 class POP_FM<bits<6> funct> : StdArch {
 534   bits<5> rd;
 535   bits<5> rs;
 536
 537   bits<32> Inst;
 538
 539   let Inst{31-26} = 0x1c;
 540   let Inst{25-21} = rs;
 541   let Inst{20-16} = 0;
 542   let Inst{15-11} = rd;
 543   let Inst{10-6}  = 0;
 544   let Inst{5-0}   = funct;
 545 }
 546
 547 class SEQ_FM<bits<6> funct> : StdArch {
 548   bits<5> rd;
 549   bits<5> rs;
 550   bits<5> rt;
 551
 552   bits<32> Inst;
 553
 554   let Inst{31-26} = 0x1c;
 555   let Inst{25-21} = rs;
 556   let Inst{20-16} = rt;
 557   let Inst{15-11} = rd;
 558   let Inst{10-6}  = 0;
 559   let Inst{5-0}   = funct;
 560 }
 561
 562 class SEQI_FM<bits<6> funct> : StdArch {
 563   bits<5> rs;
 564   bits<5> rt;
 565   bits<10> imm10;
 566
 567   bits<32> Inst;
 568
 569   let Inst{31-26} = 0x1c;
 570   let Inst{25-21} = rs;
 571   let Inst{20-16} = rt;
 572   let Inst{15-6}  = imm10;
 573   let Inst{5-0}   = funct;
 574 }
 575
 576 //===----------------------------------------------------------------------===//
 577 //  System calls format <op|code_|funct>
 578 //===----------------------------------------------------------------------===//
 579
 580 class SYS_FM<bits<6> funct> : StdArch
 581 {
 582   bits<20> code_;
 583   bits<32> Inst;
 584   let Inst{31-26} = 0x0;
 585   let Inst{25-6} = code_;
 586   let Inst{5-0}  = funct;
 587 }
 588
 589 //===----------------------------------------------------------------------===//
 590 //  Break instruction format <op|code_1|funct>
 591 //===----------------------------------------------------------------------===//
 592
 593 class BRK_FM<bits<6> funct> : StdArch
 594 {
 595   bits<10> code_1;
 596   bits<10> code_2;
 597   bits<32> Inst;
 598   let Inst{31-26} = 0x0;
 599   let Inst{25-16} = code_1;
 600   let Inst{15-6}  = code_2;
 601   let Inst{5-0}   = funct;
 602 }
 603
 604 //===----------------------------------------------------------------------===//
 605 //  Exception return format <Cop0|1|0|funct>
 606 //===----------------------------------------------------------------------===//
 607
 608 class ER_FM<bits<6> funct> : StdArch
 609 {
 610   bits<32> Inst;
 611   let Inst{31-26} = 0x10;
 612   let Inst{25}    = 1;
 613   let Inst{24-6}  = 0;
 614   let Inst{5-0}   = funct;
 615 }
 616
 617
 618 //===----------------------------------------------------------------------===//
 619 //  Enable/disable interrupt instruction format <Cop0|MFMC0|rt|12|0|sc|0|0>
 620 //===----------------------------------------------------------------------===//
 621
 622 class EI_FM<bits<1> sc> : StdArch
 623 {
 624   bits<32> Inst;
 625   bits<5> rt;
 626   let Inst{31-26} = 0x10;
 627   let Inst{25-21} = 0xb;
 628   let Inst{20-16} = rt;
 629   let Inst{15-11} = 0xc;
 630   let Inst{10-6}  = 0;
 631   let Inst{5}     = sc;
 632   let Inst{4-0}   = 0;
 633 }
 634
 635 //===----------------------------------------------------------------------===//
 636 //
 637 //  FLOATING POINT INSTRUCTION FORMATS
 638 //
 639 //  opcode  - operation code.
 640 //  fs      - src reg.
 641 //  ft      - dst reg (on a 2 regs instr) or src reg (on a 3 reg instr).
 642 //  fd      - dst reg, only used on 3 regs instr.
 643 //  fmt     - double or single precision.
 644 //  funct   - combined with opcode field give us an operation code.
 645 //
 646 //===----------------------------------------------------------------------===//
 647
 648 //===----------------------------------------------------------------------===//
 649 // Format FI instruction class in Mips : <|opcode|base|ft|immediate|>
 650 //===----------------------------------------------------------------------===//
 651
 652 class FFI<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern>:
 653   InstSE<outs, ins, asmstr, pattern, NoItinerary, FrmFI>
 654 {
 655   bits<5>  ft;
 656   bits<5>  base;
 657   bits<16> imm16;
 658
 659   let Opcode = op;
 660
 661   let Inst{25-21} = base;
 662   let Inst{20-16} = ft;
 663   let Inst{15-0}  = imm16;
 664 }
 665
 666 class ADDS_FM<bits<6> funct, bits<5> fmt> : StdArch {
 667   bits<5> fd;
 668   bits<5> fs;
 669   bits<5> ft;
 670
 671   bits<32> Inst;
 672
 673   let Inst{31-26} = 0x11;
 674   let Inst{25-21} = fmt;
 675   let Inst{20-16} = ft;
 676   let Inst{15-11} = fs;
 677   let Inst{10-6}  = fd;
 678   let Inst{5-0}   = funct;
 679 }
 680
 681 class ABSS_FM<bits<6> funct, bits<5> fmt> : StdArch {
 682   bits<5> fd;
 683   bits<5> fs;
 684
 685   bits<32> Inst;
 686
 687   let Inst{31-26} = 0x11;
 688   let Inst{25-21} = fmt;
 689   let Inst{20-16} = 0;
 690   let Inst{15-11} = fs;
 691   let Inst{10-6}  = fd;
 692   let Inst{5-0}   = funct;
 693 }
 694
 695 class MFC1_FM<bits<5> funct> : StdArch {
 696   bits<5> rt;
 697   bits<5> fs;
 698
 699   bits<32> Inst;
 700
 701   let Inst{31-26} = 0x11;
 702   let Inst{25-21} = funct;
 703   let Inst{20-16} = rt;
 704   let Inst{15-11} = fs;
 705   let Inst{10-0}  = 0;
 706 }
 707
 708 class LW_FM<bits<6> op> : StdArch {
 709   bits<5> rt;
 710   bits<21> addr;
 711
 712   bits<32> Inst;
 713
 714   let Inst{31-26} = op;
 715   let Inst{25-21} = addr{20-16};
 716   let Inst{20-16} = rt;
 717   let Inst{15-0}  = addr{15-0};
 718 }
 719
 720 class MADDS_FM<bits<3> funct, bits<3> fmt> : StdArch {
 721   bits<5> fd;
 722   bits<5> fr;
 723   bits<5> fs;
 724   bits<5> ft;
 725
 726   bits<32> Inst;
 727
 728   let Inst{31-26} = 0x13;
 729   let Inst{25-21} = fr;
 730   let Inst{20-16} = ft;
 731   let Inst{15-11} = fs;
 732   let Inst{10-6}  = fd;
 733   let Inst{5-3}   = funct;
 734   let Inst{2-0}   = fmt;
 735 }
 736
 737 class LWXC1_FM<bits<6> funct> : StdArch {
 738   bits<5> fd;
 739   bits<5> base;
 740   bits<5> index;
 741
 742   bits<32> Inst;
 743
 744   let Inst{31-26} = 0x13;
 745   let Inst{25-21} = base;
 746   let Inst{20-16} = index;
 747   let Inst{15-11} = 0;
 748   let Inst{10-6}  = fd;
 749   let Inst{5-0}   = funct;
 750 }
 751
 752 class SWXC1_FM<bits<6> funct> : StdArch {
 753   bits<5> fs;
 754   bits<5> base;
 755   bits<5> index;
 756
 757   bits<32> Inst;
 758
 759   let Inst{31-26} = 0x13;
 760   let Inst{25-21} = base;
 761   let Inst{20-16} = index;
 762   let Inst{15-11} = fs;
 763   let Inst{10-6}  = 0;
 764   let Inst{5-0}   = funct;
 765 }
 766
 767 class BC1F_FM<bit nd, bit tf> : StdArch {
 768   bits<3>  fcc;
 769   bits<16> offset;
 770
 771   bits<32> Inst;
 772
 773   let Inst{31-26} = 0x11;
 774   let Inst{25-21} = 0x8;
 775   let Inst{20-18} = fcc;
 776   let Inst{17} = nd;
 777   let Inst{16} = tf;
 778   let Inst{15-0} = offset;
 779 }
 780
 781 class CEQS_FM<bits<5> fmt> : StdArch {
 782   bits<5> fs;
 783   bits<5> ft;
 784   bits<4> cond;
 785
 786   bits<32> Inst;
 787
 788   let Inst{31-26} = 0x11;
 789   let Inst{25-21} = fmt;
 790   let Inst{20-16} = ft;
 791   let Inst{15-11} = fs;
 792   let Inst{10-8} = 0; // cc
 793   let Inst{7-4} = 0x3;
 794   let Inst{3-0} = cond;
 795 }
 796
 797 class C_COND_FM<bits<5> fmt, bits<4> c> : CEQS_FM<fmt> {
 798   let cond = c;
 799 }
 800
 801 class CMov_I_F_FM<bits<6> funct, bits<5> fmt> : StdArch {
 802   bits<5> fd;
 803   bits<5> fs;
 804   bits<5> rt;
 805
 806   bits<32> Inst;
 807
 808   let Inst{31-26} = 0x11;
 809   let Inst{25-21} = fmt;
 810   let Inst{20-16} = rt;
 811   let Inst{15-11} = fs;
 812   let Inst{10-6} = fd;
 813   let Inst{5-0} = funct;
 814 }
 815
 816 class CMov_F_I_FM<bit tf> : StdArch {
 817   bits<5> rd;
 818   bits<5> rs;
 819   bits<3> fcc;
 820
 821   bits<32> Inst;
 822
 823   let Inst{31-26} = 0;
 824   let Inst{25-21} = rs;
 825   let Inst{20-18} = fcc;
 826   let Inst{17} = 0;
 827   let Inst{16} = tf;
 828   let Inst{15-11} = rd;
 829   let Inst{10-6} = 0;
 830   let Inst{5-0} = 1;
 831 }
 832
 833 class CMov_F_F_FM<bits<5> fmt, bit tf> : StdArch {
 834   bits<5> fd;
 835   bits<5> fs;
 836   bits<3> fcc;
 837
 838   bits<32> Inst;
 839
 840   let Inst{31-26} = 0x11;
 841   let Inst{25-21} = fmt;
 842   let Inst{20-18} = fcc;
 843   let Inst{17} = 0;
 844   let Inst{16} = tf;
 845   let Inst{15-11} = fs;
 846   let Inst{10-6} = fd;
 847   let Inst{5-0} = 0x11;
 848 }
 849
 850 class BARRIER_FM<bits<5> op> : StdArch {
 851   bits<32> Inst;
 852
 853   let Inst{31-26} = 0; // SPECIAL
 854   let Inst{25-21} = 0;
 855   let Inst{20-16} = 0; // rt = 0
 856   let Inst{15-11} = 0; // rd = 0
 857   let Inst{10-6} = op; // Operation
 858   let Inst{5-0} = 0;   // SLL
 859 }
 860
 861 class SDBBP_FM : StdArch {
 862   bits<20> code_;
 863
 864   bits<32> Inst;
 865
 866   let Inst{31-26} = 0b011100; // SPECIAL2
 867   let Inst{25-6} = code_;
 868   let Inst{5-0} = 0b111111;   // SDBBP
 869 }
 870
 871 class JR_HB_FM<bits<6> op> : StdArch{
 872   bits<5> rs;
 873
 874   bits<32> Inst;
 875
 876   let Inst{31-26} = 0; // SPECIAL
 877   let Inst{25-21} = rs;
 878   let Inst{20-11} = 0;
 879   let Inst{10} = 1;
 880   let Inst{9-6} = 0;
 881   let Inst{5-0} = op;
 882 }
 883
 884 class JALR_HB_FM<bits<6> op> : StdArch {
 885   bits<5> rd;
 886   bits<5> rs;
 887
 888   bits<32> Inst;
 889
 890   let Inst{31-26} = 0; // SPECIAL
 891   let Inst{25-21} = rs;
 892   let Inst{20-16} = 0;
 893   let Inst{15-11} = rd;
 894   let Inst{10} = 1;
 895   let Inst{9-6} = 0;
 896   let Inst{5-0} = op;
 897 }
 898
 899 class COP0_TLB_FM<bits<6> op> : StdArch {
 900   bits<32> Inst;
 901
 902   let Inst{31-26} = 0x10; // COP0
 903   let Inst{25} = 1;       // CO
 904   let Inst{24-6} = 0;
 905   let Inst{5-0} = op;     // Operation
 906 }
 907
 908 class CACHEOP_FM<bits<6> op> : StdArch {
 909   bits<21> addr;
 910   bits<5> hint;
 911   bits<5> base = addr{20-16};
 912   bits<16> offset = addr{15-0};
 913
 914   bits<32> Inst;
 915
 916   let Inst{31-26} = op;
 917   let Inst{25-21} = base;
 918   let Inst{20-16} = hint;
 919   let Inst{15-0}  = offset;
 920 }