lib/Target/Mips/MipsInstrFormats.td

   1 //===- MipsRegisterInfo.td - Mips Register defs -----------------*- C++ -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Bruno Cardoso Lopes and is distributed under the
   6 // University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 //  Describe MIPS instructions format
  12 //
  13 //  All the possible Mips fields are:
  14 //
  15 //  opcode  - operation code.
  16 //  rs      - src reg.
  17 //  rt      - dst reg (on a 2 regs instr) or src reg (on a 3 reg instr).
  18 //  rd      - dst reg, only used on 3 regs instr.
  19 //  shamt   - only used on shift instructions, contains the shift amount.
  20 //  funct   - combined with opcode field give us an operation code.
  21 //
  22 //===----------------------------------------------------------------------===//
  23
  24 // Generic Mips Format
  25 class MipsInst<dag outs, dag ins, string asmstr, list<dag> pattern,
  26                InstrItinClass itin>: Instruction
  27 {
  28   field bits<32> Inst;
  29
  30   let Namespace = "Mips";
  31
  32   bits<6> opcode;
  33
  34   // Top 5 bits are the 'opcode' field
  35   let Inst{31-26} = opcode;
  36
  37   dag OutOperandList = outs;
  38   dag InOperandList  = ins;
  39
  40   let AsmString   = asmstr;
  41   let Pattern     = pattern;
  42 }
  43
  44
  45 //===----------------------------------------------------------------------===//
  46 // Format R instruction class in Mips : <|opcode|rs|rt|rd|shamt|funct|>
  47 //===----------------------------------------------------------------------===//
  48
  49 class FR<bits<6> op, bits<6> _funct, dag outs, dag ins, string asmstr,
  50          list<dag> pattern, InstrItinClass itin>:
  51       MipsInst<outs, ins, asmstr, pattern, itin>
  52 {
  53   bits<5>  rd;
  54   bits<5>  rs;
  55   bits<5>  rt;
  56   bits<5>  shamt;
  57   bits<6>  funct;
  58
  59   let opcode = op;
  60   let funct  = _funct;
  61
  62   let Inst{25-21} = rs;
  63   let Inst{20-16} = rt;
  64   let Inst{15-11} = rd;
  65   let Inst{10-6}  = shamt;
  66   let Inst{5-0}   = funct;
  67 }
  68
  69 //===----------------------------------------------------------------------===//
  70 // Format I instruction class in Mips : <|opcode|rs|rt|immediate|>
  71 //===----------------------------------------------------------------------===//
  72
  73 class FI<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern,
  74          InstrItinClass itin>: MipsInst<outs, ins, asmstr, pattern, itin>
  75 {
  76   bits<5>  rt;
  77   bits<5>  rs;
  78   bits<16> imm16;
  79
  80   let opcode = op;
  81
  82   let Inst{25-21} = rs;
  83   let Inst{20-16} = rt;
  84   let Inst{15-0}  = imm16;
  85 }
  86
  87 //===----------------------------------------------------------------------===//
  88 // Format J instruction class in Mips : <|opcode|address|>
  89 //===----------------------------------------------------------------------===//
  90
  91 class FJ<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern,
  92          InstrItinClass itin>: MipsInst<outs, ins, asmstr, pattern, itin>
  93 {
  94   bits<26> addr;
  95
  96   let opcode = op;
  97
  98   let Inst{25-0} = addr;
  99 }