lib/Target/Mips/MipsInstrFPU.td

   1 //===-- MipsInstrFPU.td - Mips FPU Instruction Information -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Mips FPU instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Floating Point Instructions
  16 // ------------------------
  17 // * 64bit fp:
  18 //    - 32 64-bit registers (default mode)
  19 //    - 16 even 32-bit registers (32-bit compatible mode) for
  20 //      single and double access.
  21 // * 32bit fp:
  22 //    - 16 even 32-bit registers - single and double (aliased)
  23 //    - 32 32-bit registers (within single-only mode)
  24 //===----------------------------------------------------------------------===//
  25
  26 // Floating Point Compare and Branch
  27 def SDT_MipsFPBrcond : SDTypeProfile<0, 2, [SDTCisInt<0>,
  28                                             SDTCisVT<1, OtherVT>]>;
  29 def SDT_MipsFPCmp : SDTypeProfile<0, 3, [SDTCisSameAs<0, 1>, SDTCisFP<1>,
  30                                          SDTCisVT<2, i32>]>;
  31 def SDT_MipsCMovFP : SDTypeProfile<1, 2, [SDTCisSameAs<0, 1>,
  32                                           SDTCisSameAs<1, 2>]>;
  33 def SDT_MipsBuildPairF64 : SDTypeProfile<1, 2, [SDTCisVT<0, f64>,
  34                                                 SDTCisVT<1, i32>,
  35                                                 SDTCisSameAs<1, 2>]>;
  36 def SDT_MipsExtractElementF64 : SDTypeProfile<1, 2, [SDTCisVT<0, i32>,
  37                                                      SDTCisVT<1, f64>,
  38                                                      SDTCisVT<2, i32>]>;
  39
  40 def MipsFPCmp : SDNode<"MipsISD::FPCmp", SDT_MipsFPCmp, [SDNPOutGlue]>;
  41 def MipsCMovFP_T : SDNode<"MipsISD::CMovFP_T", SDT_MipsCMovFP, [SDNPInGlue]>;
  42 def MipsCMovFP_F : SDNode<"MipsISD::CMovFP_F", SDT_MipsCMovFP, [SDNPInGlue]>;
  43 def MipsFPBrcond : SDNode<"MipsISD::FPBrcond", SDT_MipsFPBrcond,
  44                           [SDNPHasChain, SDNPOptInGlue]>;
  45 def MipsBuildPairF64 : SDNode<"MipsISD::BuildPairF64", SDT_MipsBuildPairF64>;
  46 def MipsExtractElementF64 : SDNode<"MipsISD::ExtractElementF64",
  47                                    SDT_MipsExtractElementF64>;
  48
  49 // Operand for printing out a condition code.
  50 let PrintMethod = "printFCCOperand", DecoderMethod = "DecodeCondCode" in
  51   def condcode : Operand<i32>;
  52
  53 //===----------------------------------------------------------------------===//
  54 // Feature predicates.
  55 //===----------------------------------------------------------------------===//
  56
  57 def IsFP64bit        : Predicate<"Subtarget.isFP64bit()">,
  58                        AssemblerPredicate<"FeatureFP64Bit">;
  59 def NotFP64bit       : Predicate<"!Subtarget.isFP64bit()">,
  60                        AssemblerPredicate<"!FeatureFP64Bit">;
  61 def IsSingleFloat    : Predicate<"Subtarget.isSingleFloat()">,
  62                        AssemblerPredicate<"FeatureSingleFloat">;
  63 def IsNotSingleFloat : Predicate<"!Subtarget.isSingleFloat()">,
  64                        AssemblerPredicate<"!FeatureSingleFloat">;
  65
  66 // FP immediate patterns.
  67 def fpimm0 : PatLeaf<(fpimm), [{
  68   return N->isExactlyValue(+0.0);
  69 }]>;
  70
  71 def fpimm0neg : PatLeaf<(fpimm), [{
  72   return N->isExactlyValue(-0.0);
  73 }]>;
  74
  75 //===----------------------------------------------------------------------===//
  76 // Instruction Class Templates
  77 //
  78 // A set of multiclasses is used to address the register usage.
  79 //
  80 // S32 - single precision in 16 32bit even fp registers
  81 //       single precision in 32 32bit fp registers in SingleOnly mode
  82 // S64 - single precision in 32 64bit fp registers (In64BitMode)
  83 // D32 - double precision in 16 32bit even fp registers
  84 // D64 - double precision in 32 64bit fp registers (In64BitMode)
  85 //
  86 // Only S32 and D32 are supported right now.
  87 //===----------------------------------------------------------------------===//
  88
  89 class ADDS_FT<string opstr, RegisterClass RC, InstrItinClass Itin, bit IsComm,
  90               SDPatternOperator OpNode= null_frag> :
  91   InstSE<(outs RC:$fd), (ins RC:$fs, RC:$ft),
  92          !strconcat(opstr, "\t$fd, $fs, $ft"),
  93          [(set RC:$fd, (OpNode RC:$fs, RC:$ft))], Itin, FrmFR> {
  94   let isCommutable = IsComm;
  95 }
  96
  97 multiclass ADDS_M<string opstr, InstrItinClass Itin, bit IsComm,
  98                   SDPatternOperator OpNode = null_frag> {
  99   def _D32 : ADDS_FT<opstr, AFGR64, Itin, IsComm, OpNode>,
 100              Requires<[NotFP64bit, HasStdEnc]>;
 101   def _D64 : ADDS_FT<opstr, FGR64, Itin, IsComm, OpNode>,
 102              Requires<[IsFP64bit, HasStdEnc]> {
 103     string DecoderNamespace = "Mips64";
 104   }
 105 }
 106
 107 class ABSS_FT<string opstr, RegisterClass DstRC, RegisterClass SrcRC,
 108               InstrItinClass Itin, SDPatternOperator OpNode= null_frag> :
 109   InstSE<(outs DstRC:$fd), (ins SrcRC:$fs), !strconcat(opstr, "\t$fd, $fs"),
 110          [(set DstRC:$fd, (OpNode SrcRC:$fs))], Itin, FrmFR>,
 111   NeverHasSideEffects;
 112
 113 multiclass ABSS_M<string opstr, InstrItinClass Itin,
 114                   SDPatternOperator OpNode= null_frag> {
 115   def _D32 : ABSS_FT<opstr, AFGR64, AFGR64, Itin, OpNode>,
 116              Requires<[NotFP64bit, HasStdEnc]>;
 117   def _D64 : ABSS_FT<opstr, FGR64, FGR64, Itin, OpNode>,
 118              Requires<[IsFP64bit, HasStdEnc]> {
 119     string DecoderNamespace = "Mips64";
 120   }
 121 }
 122
 123 multiclass ROUND_M<string opstr, InstrItinClass Itin> {
 124   def _D32 : ABSS_FT<opstr, FGR32, AFGR64, Itin>,
 125              Requires<[NotFP64bit, HasStdEnc]>;
 126   def _D64 : ABSS_FT<opstr, FGR32, FGR64, Itin>,
 127              Requires<[IsFP64bit, HasStdEnc]> {
 128     let DecoderNamespace = "Mips64";
 129   }
 130 }
 131
 132 class MFC1_FT<string opstr, RegisterClass DstRC, RegisterClass SrcRC,
 133               InstrItinClass Itin, SDPatternOperator OpNode= null_frag> :
 134   InstSE<(outs DstRC:$rt), (ins SrcRC:$fs), !strconcat(opstr, "\t$rt, $fs"),
 135          [(set DstRC:$rt, (OpNode SrcRC:$fs))], Itin, FrmFR>;
 136
 137 class MTC1_FT<string opstr, RegisterClass DstRC, RegisterClass SrcRC,
 138               InstrItinClass Itin, SDPatternOperator OpNode= null_frag> :
 139   InstSE<(outs DstRC:$fs), (ins SrcRC:$rt), !strconcat(opstr, "\t$rt, $fs"),
 140          [(set DstRC:$fs, (OpNode SrcRC:$rt))], Itin, FrmFR>;
 141
 142 class MFC1_FT_CCR<string opstr, RegisterClass DstRC, RegisterOperand SrcRC,
 143               InstrItinClass Itin, SDPatternOperator OpNode= null_frag> :
 144   InstSE<(outs DstRC:$rt), (ins SrcRC:$fs), !strconcat(opstr, "\t$rt, $fs"),
 145          [(set DstRC:$rt, (OpNode SrcRC:$fs))], Itin, FrmFR>;
 146
 147 class MTC1_FT_CCR<string opstr, RegisterOperand DstRC, RegisterClass SrcRC,
 148               InstrItinClass Itin, SDPatternOperator OpNode= null_frag> :
 149   InstSE<(outs DstRC:$fs), (ins SrcRC:$rt), !strconcat(opstr, "\t$rt, $fs"),
 150          [(set DstRC:$fs, (OpNode SrcRC:$rt))], Itin, FrmFR>;
 151
 152 class LW_FT<string opstr, RegisterClass RC, InstrItinClass Itin,
 153             Operand MemOpnd, SDPatternOperator OpNode= null_frag> :
 154   InstSE<(outs RC:$rt), (ins MemOpnd:$addr), !strconcat(opstr, "\t$rt, $addr"),
 155          [(set RC:$rt, (OpNode addr:$addr))], Itin, FrmFI> {
 156   let DecoderMethod = "DecodeFMem";
 157 }
 158
 159 class SW_FT<string opstr, RegisterClass RC, InstrItinClass Itin,
 160             Operand MemOpnd, SDPatternOperator OpNode= null_frag> :
 161   InstSE<(outs), (ins RC:$rt, MemOpnd:$addr), !strconcat(opstr, "\t$rt, $addr"),
 162          [(OpNode RC:$rt, addr:$addr)], Itin, FrmFI> {
 163   let DecoderMethod = "DecodeFMem";
 164 }
 165
 166 class MADDS_FT<string opstr, RegisterClass RC, InstrItinClass Itin,
 167                SDPatternOperator OpNode = null_frag> :
 168   InstSE<(outs RC:$fd), (ins RC:$fr, RC:$fs, RC:$ft),
 169          !strconcat(opstr, "\t$fd, $fr, $fs, $ft"),
 170          [(set RC:$fd, (OpNode (fmul RC:$fs, RC:$ft), RC:$fr))], Itin, FrmFR>;
 171
 172 class NMADDS_FT<string opstr, RegisterClass RC, InstrItinClass Itin,
 173                 SDPatternOperator OpNode = null_frag> :
 174   InstSE<(outs RC:$fd), (ins RC:$fr, RC:$fs, RC:$ft),
 175          !strconcat(opstr, "\t$fd, $fr, $fs, $ft"),
 176          [(set RC:$fd, (fsub fpimm0, (OpNode (fmul RC:$fs, RC:$ft), RC:$fr)))],
 177          Itin, FrmFR>;
 178
 179 class LWXC1_FT<string opstr, RegisterClass DRC, RegisterClass PRC,
 180                InstrItinClass Itin, SDPatternOperator OpNode = null_frag> :
 181   InstSE<(outs DRC:$fd), (ins PRC:$base, PRC:$index),
 182          !strconcat(opstr, "\t$fd, ${index}(${base})"),
 183          [(set DRC:$fd, (OpNode (add PRC:$base, PRC:$index)))], Itin, FrmFI>;
 184
 185 class SWXC1_FT<string opstr, RegisterClass DRC, RegisterClass PRC,
 186                InstrItinClass Itin, SDPatternOperator OpNode = null_frag> :
 187   InstSE<(outs), (ins DRC:$fs, PRC:$base, PRC:$index),
 188          !strconcat(opstr, "\t$fs, ${index}(${base})"),
 189          [(OpNode DRC:$fs, (add PRC:$base, PRC:$index))], Itin, FrmFI>;
 190
 191 class BC1F_FT<string opstr, InstrItinClass Itin,
 192               SDPatternOperator Op = null_frag>  :
 193   InstSE<(outs), (ins brtarget:$offset), !strconcat(opstr, "\t$offset"),
 194          [(MipsFPBrcond Op, bb:$offset)], Itin, FrmFI> {
 195   let isBranch = 1;
 196   let isTerminator = 1;
 197   let hasDelaySlot = 1;
 198   let Defs = [AT];
 199   let Uses = [FCR31];
 200 }
 201
 202 class CEQS_FT<string typestr, RegisterClass RC, InstrItinClass Itin,
 203               SDPatternOperator OpNode = null_frag>  :
 204   InstSE<(outs), (ins RC:$fs, RC:$ft, condcode:$cond),
 205          !strconcat("c.$cond.", typestr, "\t$fs, $ft"),
 206          [(OpNode RC:$fs, RC:$ft, imm:$cond)], Itin, FrmFR> {
 207   let Defs = [FCR31];
 208 }
 209
 210 //===----------------------------------------------------------------------===//
 211 // Floating Point Instructions
 212 //===----------------------------------------------------------------------===//
 213 def ROUND_W_S  : ABSS_FT<"round.w.s", FGR32, FGR32, IIFcvt>, ABSS_FM<0xc, 16>;
 214 def TRUNC_W_S  : ABSS_FT<"trunc.w.s", FGR32, FGR32, IIFcvt>, ABSS_FM<0xd, 16>;
 215 def CEIL_W_S   : ABSS_FT<"ceil.w.s", FGR32, FGR32, IIFcvt>, ABSS_FM<0xe, 16>;
 216 def FLOOR_W_S  : ABSS_FT<"floor.w.s", FGR32, FGR32, IIFcvt>, ABSS_FM<0xf, 16>;
 217 def CVT_W_S    : ABSS_FT<"cvt.w.s", FGR32, FGR32, IIFcvt>, ABSS_FM<0x24, 16>;
 218
 219 defm ROUND_W : ROUND_M<"round.w.d", IIFcvt>, ABSS_FM<0xc, 17>;
 220 defm TRUNC_W : ROUND_M<"trunc.w.d", IIFcvt>, ABSS_FM<0xd, 17>;
 221 defm CEIL_W  : ROUND_M<"ceil.w.d", IIFcvt>, ABSS_FM<0xe, 17>;
 222 defm FLOOR_W : ROUND_M<"floor.w.d", IIFcvt>, ABSS_FM<0xf, 17>;
 223 defm CVT_W   : ROUND_M<"cvt.w.d", IIFcvt>, ABSS_FM<0x24, 17>;
 224
 225 let Predicates = [IsFP64bit, HasStdEnc], DecoderNamespace = "Mips64" in {
 226   def ROUND_L_S : ABSS_FT<"round.l.s", FGR64, FGR32, IIFcvt>, ABSS_FM<0x8, 16>;
 227   def ROUND_L_D64 : ABSS_FT<"round.l.d", FGR64, FGR64, IIFcvt>,
 228                     ABSS_FM<0x8, 17>;
 229   def TRUNC_L_S : ABSS_FT<"trunc.l.s", FGR64, FGR32, IIFcvt>, ABSS_FM<0x9, 16>;
 230   def TRUNC_L_D64 : ABSS_FT<"trunc.l.d", FGR64, FGR64, IIFcvt>,
 231                     ABSS_FM<0x9, 17>;
 232   def CEIL_L_S  : ABSS_FT<"ceil.l.s", FGR64, FGR32, IIFcvt>, ABSS_FM<0xa, 16>;
 233   def CEIL_L_D64 : ABSS_FT<"ceil.l.d", FGR64, FGR64, IIFcvt>, ABSS_FM<0xa, 17>;
 234   def FLOOR_L_S : ABSS_FT<"floor.l.s", FGR64, FGR32, IIFcvt>, ABSS_FM<0xb, 16>;
 235   def FLOOR_L_D64 : ABSS_FT<"floor.l.d", FGR64, FGR64, IIFcvt>,
 236                     ABSS_FM<0xb, 17>;
 237 }
 238
 239 def CVT_S_W : ABSS_FT<"cvt.s.w", FGR32, FGR32, IIFcvt>, ABSS_FM<0x20, 20>;
 240 def CVT_L_S : ABSS_FT<"cvt.l.s", FGR64, FGR32, IIFcvt>, ABSS_FM<0x25, 16>;
 241 def CVT_L_D64: ABSS_FT<"cvt.l.d", FGR64, FGR64, IIFcvt>, ABSS_FM<0x25, 17>;
 242
 243 let Predicates = [NotFP64bit, HasStdEnc] in {
 244   def CVT_S_D32 : ABSS_FT<"cvt.s.d", FGR32, AFGR64, IIFcvt>, ABSS_FM<0x20, 17>;
 245   def CVT_D32_W : ABSS_FT<"cvt.d.w", AFGR64, FGR32, IIFcvt>, ABSS_FM<0x21, 20>;
 246   def CVT_D32_S : ABSS_FT<"cvt.d.s", AFGR64, FGR32, IIFcvt>, ABSS_FM<0x21, 16>;
 247 }
 248
 249 let Predicates = [IsFP64bit, HasStdEnc], DecoderNamespace = "Mips64" in {
 250  def CVT_S_D64 : ABSS_FT<"cvt.s.d", FGR32, FGR64, IIFcvt>, ABSS_FM<0x20, 17>;
 251  def CVT_S_L   : ABSS_FT<"cvt.s.l", FGR32, FGR64, IIFcvt>, ABSS_FM<0x20, 21>;
 252  def CVT_D64_W : ABSS_FT<"cvt.d.w", FGR64, FGR32, IIFcvt>, ABSS_FM<0x21, 20>;
 253  def CVT_D64_S : ABSS_FT<"cvt.d.s", FGR64, FGR32, IIFcvt>, ABSS_FM<0x21, 16>;
 254  def CVT_D64_L : ABSS_FT<"cvt.d.l", FGR64, FGR64, IIFcvt>, ABSS_FM<0x21, 21>;
 255 }
 256
 257 let Predicates = [NoNaNsFPMath, HasStdEnc] in {
 258   def FABS_S : ABSS_FT<"abs.s", FGR32, FGR32, IIFcvt, fabs>, ABSS_FM<0x5, 16>;
 259   def FNEG_S : ABSS_FT<"neg.s", FGR32, FGR32, IIFcvt, fneg>, ABSS_FM<0x7, 16>;
 260   defm FABS : ABSS_M<"abs.d", IIFcvt, fabs>, ABSS_FM<0x5, 17>;
 261   defm FNEG : ABSS_M<"neg.d", IIFcvt, fneg>, ABSS_FM<0x7, 17>;
 262 }
 263
 264 def  FSQRT_S : ABSS_FT<"sqrt.s", FGR32, FGR32, IIFsqrtSingle, fsqrt>,
 265                ABSS_FM<0x4, 16>;
 266 defm FSQRT : ABSS_M<"sqrt.d", IIFsqrtDouble, fsqrt>, ABSS_FM<0x4, 17>;
 267
 268 // The odd-numbered registers are only referenced when doing loads,
 269 // stores, and moves between floating-point and integer registers.
 270 // When defining instructions, we reference all 32-bit registers,
 271 // regardless of register aliasing.
 272
 273 /// Move Control Registers From/To CPU Registers
 274 def CFC1 : MFC1_FT_CCR<"cfc1", CPURegs, CCROpnd, IIFmove>, MFC1_FM<2>;
 275 def CTC1 : MTC1_FT_CCR<"ctc1", CCROpnd, CPURegs, IIFmove>, MFC1_FM<6>;
 276 def MFC1 : MFC1_FT<"mfc1", CPURegs, FGR32, IIFmove, bitconvert>, MFC1_FM<0>;
 277 def MTC1 : MTC1_FT<"mtc1", FGR32, CPURegs, IIFmove, bitconvert>, MFC1_FM<4>;
 278 def DMFC1 : MFC1_FT<"dmfc1", CPU64Regs, FGR64, IIFmove, bitconvert>, MFC1_FM<1>;
 279 def DMTC1 : MTC1_FT<"dmtc1", FGR64, CPU64Regs, IIFmove, bitconvert>, MFC1_FM<5>;
 280
 281 def FMOV_S   : ABSS_FT<"mov.s", FGR32, FGR32, IIFmove>, ABSS_FM<0x6, 16>;
 282 def FMOV_D32 : ABSS_FT<"mov.d", AFGR64, AFGR64, IIFmove>, ABSS_FM<0x6, 17>,
 283                Requires<[NotFP64bit, HasStdEnc]>;
 284 def FMOV_D64 : ABSS_FT<"mov.d", FGR64, FGR64, IIFmove>, ABSS_FM<0x6, 17>,
 285                Requires<[IsFP64bit, HasStdEnc]> {
 286   let DecoderNamespace = "Mips64";
 287 }
 288
 289 /// Floating Point Memory Instructions
 290 let Predicates = [IsN64, HasStdEnc], DecoderNamespace = "Mips64" in {
 291   def LWC1_P8 : LW_FT<"lwc1", FGR32, IILoad, mem64, load>, LW_FM<0x31>;
 292   def SWC1_P8 : SW_FT<"swc1", FGR32, IIStore, mem64, store>, LW_FM<0x39>;
 293   def LDC164_P8 : LW_FT<"ldc1", FGR64, IILoad, mem64, load>, LW_FM<0x35> {
 294     let isCodeGenOnly =1;
 295   }
 296   def SDC164_P8 : SW_FT<"sdc1", FGR64, IIStore, mem64, store>, LW_FM<0x3d> {
 297     let isCodeGenOnly =1;
 298   }
 299 }
 300
 301 let Predicates = [NotN64, HasStdEnc] in {
 302   def LWC1 : LW_FT<"lwc1", FGR32, IILoad, mem, load>, LW_FM<0x31>;
 303   def SWC1 : SW_FT<"swc1", FGR32, IIStore, mem, store>, LW_FM<0x39>;
 304 }
 305
 306 let Predicates = [NotN64, HasMips64, HasStdEnc],
 307   DecoderNamespace = "Mips64" in {
 308   def LDC164 : LW_FT<"ldc1", FGR64, IILoad, mem, load>, LW_FM<0x35>;
 309   def SDC164 : SW_FT<"sdc1", FGR64, IIStore, mem, store>, LW_FM<0x3d>;
 310 }
 311
 312 let Predicates = [NotN64, NotMips64, HasStdEnc] in {
 313   def LDC1 : LW_FT<"ldc1", AFGR64, IILoad, mem, load>, LW_FM<0x35>;
 314   def SDC1 : SW_FT<"sdc1", AFGR64, IIStore, mem, store>, LW_FM<0x3d>;
 315 }
 316
 317 // Indexed loads and stores.
 318 let Predicates = [HasFPIdx, HasStdEnc] in {
 319   def LWXC1 : LWXC1_FT<"lwxc1", FGR32, CPURegs, IILoad, load>, LWXC1_FM<0>;
 320   def SWXC1 : SWXC1_FT<"swxc1", FGR32, CPURegs, IIStore, store>, SWXC1_FM<8>;
 321 }
 322
 323 let Predicates = [HasMips32r2, NotMips64, HasStdEnc] in {
 324   def LDXC1 : LWXC1_FT<"ldxc1", AFGR64, CPURegs, IILoad, load>, LWXC1_FM<1>;
 325   def SDXC1 : SWXC1_FT<"sdxc1", AFGR64, CPURegs, IIStore, store>, SWXC1_FM<9>;
 326 }
 327
 328 let Predicates = [HasMips64, NotN64, HasStdEnc], DecoderNamespace="Mips64" in {
 329   def LDXC164 : LWXC1_FT<"ldxc1", FGR64, CPURegs, IILoad, load>, LWXC1_FM<1>;
 330   def SDXC164 : SWXC1_FT<"sdxc1", FGR64, CPURegs, IIStore, store>, SWXC1_FM<9>;
 331 }
 332
 333 // n64
 334 let Predicates = [IsN64, HasStdEnc], isCodeGenOnly=1 in {
 335   def LWXC1_P8 : LWXC1_FT<"lwxc1", FGR32, CPU64Regs, IILoad, load>, LWXC1_FM<0>;
 336   def LDXC164_P8 : LWXC1_FT<"ldxc1", FGR64, CPU64Regs, IILoad, load>,
 337                    LWXC1_FM<1>;
 338   def SWXC1_P8 : SWXC1_FT<"swxc1", FGR32, CPU64Regs, IIStore, store>,
 339                  SWXC1_FM<8>;
 340   def SDXC164_P8 : SWXC1_FT<"sdxc1", FGR64, CPU64Regs, IIStore, store>,
 341                    SWXC1_FM<9>;
 342 }
 343
 344 // Load/store doubleword indexed unaligned.
 345 let Predicates = [NotMips64, HasStdEnc] in {
 346   def LUXC1 : LWXC1_FT<"luxc1", AFGR64, CPURegs, IILoad>, LWXC1_FM<0x5>;
 347   def SUXC1 : SWXC1_FT<"suxc1", AFGR64, CPURegs, IIStore>, SWXC1_FM<0xd>;
 348 }
 349
 350 let Predicates = [HasMips64, HasStdEnc],
 351   DecoderNamespace="Mips64" in {
 352   def LUXC164 : LWXC1_FT<"luxc1", FGR64, CPURegs, IILoad>, LWXC1_FM<0x5>;
 353   def SUXC164 : SWXC1_FT<"suxc1", FGR64, CPURegs, IIStore>, SWXC1_FM<0xd>;
 354 }
 355
 356 /// Floating-point Aritmetic
 357 def FADD_S : ADDS_FT<"add.s", FGR32, IIFadd, 1, fadd>, ADDS_FM<0x00, 16>;
 358 defm FADD : ADDS_M<"add.d", IIFadd, 1, fadd>, ADDS_FM<0x00, 17>;
 359 def FDIV_S : ADDS_FT<"div.s", FGR32, IIFdivSingle, 0, fdiv>, ADDS_FM<0x03, 16>;
 360 defm FDIV : ADDS_M<"div.d", IIFdivDouble, 0, fdiv>, ADDS_FM<0x03, 17>;
 361 def FMUL_S : ADDS_FT<"mul.s", FGR32, IIFmulSingle, 1, fmul>, ADDS_FM<0x02, 16>;
 362 defm FMUL : ADDS_M<"mul.d", IIFmulDouble, 1, fmul>, ADDS_FM<0x02, 17>;
 363 def FSUB_S : ADDS_FT<"sub.s", FGR32, IIFadd, 0, fsub>, ADDS_FM<0x01, 16>;
 364 defm FSUB : ADDS_M<"sub.d", IIFadd, 0, fsub>, ADDS_FM<0x01, 17>;
 365
 366 let Predicates = [HasMips32r2, HasStdEnc] in {
 367   def MADD_S : MADDS_FT<"madd.s", FGR32, IIFmulSingle, fadd>, MADDS_FM<4, 0>;
 368   def MSUB_S : MADDS_FT<"msub.s", FGR32, IIFmulSingle, fsub>, MADDS_FM<5, 0>;
 369 }
 370
 371 let Predicates = [HasMips32r2, NoNaNsFPMath, HasStdEnc] in {
 372   def NMADD_S : NMADDS_FT<"nmadd.s", FGR32, IIFmulSingle, fadd>, MADDS_FM<6, 0>;
 373   def NMSUB_S : NMADDS_FT<"nmsub.s", FGR32, IIFmulSingle, fsub>, MADDS_FM<7, 0>;
 374 }
 375
 376 let Predicates = [HasMips32r2, NotFP64bit, HasStdEnc] in {
 377   def MADD_D32 : MADDS_FT<"madd.d", AFGR64, IIFmulDouble, fadd>, MADDS_FM<4, 1>;
 378   def MSUB_D32 : MADDS_FT<"msub.d", AFGR64, IIFmulDouble, fsub>, MADDS_FM<5, 1>;
 379 }
 380
 381 let Predicates = [HasMips32r2, NotFP64bit, NoNaNsFPMath, HasStdEnc] in {
 382   def NMADD_D32 : NMADDS_FT<"nmadd.d", AFGR64, IIFmulDouble, fadd>,
 383                   MADDS_FM<6, 1>;
 384   def NMSUB_D32 : NMADDS_FT<"nmsub.d", AFGR64, IIFmulDouble, fsub>,
 385                   MADDS_FM<7, 1>;
 386 }
 387
 388 let Predicates = [HasMips32r2, IsFP64bit, HasStdEnc], isCodeGenOnly=1 in {
 389   def MADD_D64 : MADDS_FT<"madd.d", FGR64, IIFmulDouble, fadd>, MADDS_FM<4, 1>;
 390   def MSUB_D64 : MADDS_FT<"msub.d", FGR64, IIFmulDouble, fsub>, MADDS_FM<5, 1>;
 391 }
 392
 393 let Predicates = [HasMips32r2, IsFP64bit, NoNaNsFPMath, HasStdEnc],
 394     isCodeGenOnly=1 in {
 395   def NMADD_D64 : NMADDS_FT<"nmadd.d", FGR64, IIFmulDouble, fadd>,
 396                   MADDS_FM<6, 1>;
 397   def NMSUB_D64 : NMADDS_FT<"nmsub.d", FGR64, IIFmulDouble, fsub>,
 398                   MADDS_FM<7, 1>;
 399 }
 400
 401 //===----------------------------------------------------------------------===//
 402 // Floating Point Branch Codes
 403 //===----------------------------------------------------------------------===//
 404 // Mips branch codes. These correspond to condcode in MipsInstrInfo.h.
 405 // They must be kept in synch.
 406 def MIPS_BRANCH_F  : PatLeaf<(i32 0)>;
 407 def MIPS_BRANCH_T  : PatLeaf<(i32 1)>;
 408
 409 let DecoderMethod = "DecodeBC1" in {
 410 def BC1F : BC1F_FT<"bc1f", IIBranch, MIPS_BRANCH_F>, BC1F_FM<0, 0>;
 411 def BC1T : BC1F_FT<"bc1t", IIBranch, MIPS_BRANCH_T>, BC1F_FM<0, 1>;
 412 }
 413 //===----------------------------------------------------------------------===//
 414 // Floating Point Flag Conditions
 415 //===----------------------------------------------------------------------===//
 416 // Mips condition codes. They must correspond to condcode in MipsInstrInfo.h.
 417 // They must be kept in synch.
 418 def MIPS_FCOND_F    : PatLeaf<(i32 0)>;
 419 def MIPS_FCOND_UN   : PatLeaf<(i32 1)>;
 420 def MIPS_FCOND_OEQ  : PatLeaf<(i32 2)>;
 421 def MIPS_FCOND_UEQ  : PatLeaf<(i32 3)>;
 422 def MIPS_FCOND_OLT  : PatLeaf<(i32 4)>;
 423 def MIPS_FCOND_ULT  : PatLeaf<(i32 5)>;
 424 def MIPS_FCOND_OLE  : PatLeaf<(i32 6)>;
 425 def MIPS_FCOND_ULE  : PatLeaf<(i32 7)>;
 426 def MIPS_FCOND_SF   : PatLeaf<(i32 8)>;
 427 def MIPS_FCOND_NGLE : PatLeaf<(i32 9)>;
 428 def MIPS_FCOND_SEQ  : PatLeaf<(i32 10)>;
 429 def MIPS_FCOND_NGL  : PatLeaf<(i32 11)>;
 430 def MIPS_FCOND_LT   : PatLeaf<(i32 12)>;
 431 def MIPS_FCOND_NGE  : PatLeaf<(i32 13)>;
 432 def MIPS_FCOND_LE   : PatLeaf<(i32 14)>;
 433 def MIPS_FCOND_NGT  : PatLeaf<(i32 15)>;
 434
 435 /// Floating Point Compare
 436 def FCMP_S32 : CEQS_FT<"s", FGR32, IIFcmp, MipsFPCmp>, CEQS_FM<16>;
 437 def FCMP_D32 : CEQS_FT<"d", AFGR64, IIFcmp, MipsFPCmp>, CEQS_FM<17>,
 438                Requires<[NotFP64bit, HasStdEnc]>;
 439 let DecoderNamespace = "Mips64" in
 440 def FCMP_D64 : CEQS_FT<"d", FGR64, IIFcmp, MipsFPCmp>, CEQS_FM<17>,
 441                Requires<[IsFP64bit, HasStdEnc]>;
 442
 443 //===----------------------------------------------------------------------===//
 444 // Floating Point Pseudo-Instructions
 445 //===----------------------------------------------------------------------===//
 446 def MOVCCRToCCR : PseudoSE<(outs CCR:$dst), (ins CCROpnd:$src), []>;
 447
 448 // This pseudo instr gets expanded into 2 mtc1 instrs after register
 449 // allocation.
 450 def BuildPairF64 :
 451   PseudoSE<(outs AFGR64:$dst),
 452            (ins CPURegs:$lo, CPURegs:$hi),
 453            [(set AFGR64:$dst, (MipsBuildPairF64 CPURegs:$lo, CPURegs:$hi))]>;
 454
 455 // This pseudo instr gets expanded into 2 mfc1 instrs after register
 456 // allocation.
 457 // if n is 0, lower part of src is extracted.
 458 // if n is 1, higher part of src is extracted.
 459 def ExtractElementF64 :
 460   PseudoSE<(outs CPURegs:$dst), (ins AFGR64:$src, i32imm:$n),
 461            [(set CPURegs:$dst, (MipsExtractElementF64 AFGR64:$src, imm:$n))]>;
 462
 463 //===----------------------------------------------------------------------===//
 464 // Floating Point Patterns
 465 //===----------------------------------------------------------------------===//
 466 def : MipsPat<(f32 fpimm0), (MTC1 ZERO)>;
 467 def : MipsPat<(f32 fpimm0neg), (FNEG_S (MTC1 ZERO))>;
 468
 469 def : MipsPat<(f32 (sint_to_fp CPURegs:$src)), (CVT_S_W (MTC1 CPURegs:$src))>;
 470 def : MipsPat<(i32 (fp_to_sint FGR32:$src)), (MFC1 (TRUNC_W_S FGR32:$src))>;
 471
 472 let Predicates = [NotFP64bit, HasStdEnc] in {
 473   def : MipsPat<(f64 (sint_to_fp CPURegs:$src)),
 474                 (CVT_D32_W (MTC1 CPURegs:$src))>;
 475   def : MipsPat<(i32 (fp_to_sint AFGR64:$src)),
 476                 (MFC1 (TRUNC_W_D32 AFGR64:$src))>;
 477   def : MipsPat<(f32 (fround AFGR64:$src)), (CVT_S_D32 AFGR64:$src)>;
 478   def : MipsPat<(f64 (fextend FGR32:$src)), (CVT_D32_S FGR32:$src)>;
 479 }
 480
 481 let Predicates = [IsFP64bit, HasStdEnc] in {
 482   def : MipsPat<(f64 fpimm0), (DMTC1 ZERO_64)>;
 483   def : MipsPat<(f64 fpimm0neg), (FNEG_D64 (DMTC1 ZERO_64))>;
 484
 485   def : MipsPat<(f64 (sint_to_fp CPURegs:$src)),
 486                 (CVT_D64_W (MTC1 CPURegs:$src))>;
 487   def : MipsPat<(f32 (sint_to_fp CPU64Regs:$src)),
 488                 (CVT_S_L (DMTC1 CPU64Regs:$src))>;
 489   def : MipsPat<(f64 (sint_to_fp CPU64Regs:$src)),
 490                 (CVT_D64_L (DMTC1 CPU64Regs:$src))>;
 491
 492   def : MipsPat<(i32 (fp_to_sint FGR64:$src)),
 493                 (MFC1 (TRUNC_W_D64 FGR64:$src))>;
 494   def : MipsPat<(i64 (fp_to_sint FGR32:$src)), (DMFC1 (TRUNC_L_S FGR32:$src))>;
 495   def : MipsPat<(i64 (fp_to_sint FGR64:$src)),
 496                 (DMFC1 (TRUNC_L_D64 FGR64:$src))>;
 497
 498   def : MipsPat<(f32 (fround FGR64:$src)), (CVT_S_D64 FGR64:$src)>;
 499   def : MipsPat<(f64 (fextend FGR32:$src)), (CVT_D64_S FGR32:$src)>;
 500 }