lib/Target/Mips/MipsInstrFPU.td

   1 //===-- MipsInstrFPU.td - Mips FPU Instruction Information -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Mips FPU instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Floating Point Instructions
  16 // ------------------------
  17 // * 64bit fp:
  18 //    - 32 64-bit registers (default mode)
  19 //    - 16 even 32-bit registers (32-bit compatible mode) for
  20 //      single and double access.
  21 // * 32bit fp:
  22 //    - 16 even 32-bit registers - single and double (aliased)
  23 //    - 32 32-bit registers (within single-only mode)
  24 //===----------------------------------------------------------------------===//
  25
  26 // Floating Point Compare and Branch
  27 def SDT_MipsFPBrcond : SDTypeProfile<0, 3, [SDTCisInt<0>,
  28                                             SDTCisVT<1, i32>,
  29                                             SDTCisVT<2, OtherVT>]>;
  30 def SDT_MipsFPCmp : SDTypeProfile<0, 3, [SDTCisSameAs<0, 1>, SDTCisFP<1>,
  31                                          SDTCisVT<2, i32>]>;
  32 def SDT_MipsCMovFP : SDTypeProfile<1, 3, [SDTCisSameAs<0, 1>, SDTCisVT<2, i32>,
  33                                           SDTCisSameAs<1, 3>]>;
  34 def SDT_MipsTruncIntFP : SDTypeProfile<1, 1, [SDTCisFP<0>, SDTCisFP<1>]>;
  35 def SDT_MipsBuildPairF64 : SDTypeProfile<1, 2, [SDTCisVT<0, f64>,
  36                                                 SDTCisVT<1, i32>,
  37                                                 SDTCisSameAs<1, 2>]>;
  38 def SDT_MipsExtractElementF64 : SDTypeProfile<1, 2, [SDTCisVT<0, i32>,
  39                                                      SDTCisVT<1, f64>,
  40                                                      SDTCisVT<2, i32>]>;
  41
  42 def MipsFPCmp : SDNode<"MipsISD::FPCmp", SDT_MipsFPCmp, [SDNPOutGlue]>;
  43 def MipsCMovFP_T : SDNode<"MipsISD::CMovFP_T", SDT_MipsCMovFP, [SDNPInGlue]>;
  44 def MipsCMovFP_F : SDNode<"MipsISD::CMovFP_F", SDT_MipsCMovFP, [SDNPInGlue]>;
  45 def MipsFPBrcond : SDNode<"MipsISD::FPBrcond", SDT_MipsFPBrcond,
  46                           [SDNPHasChain, SDNPOptInGlue]>;
  47 def MipsTruncIntFP : SDNode<"MipsISD::TruncIntFP", SDT_MipsTruncIntFP>;
  48 def MipsBuildPairF64 : SDNode<"MipsISD::BuildPairF64", SDT_MipsBuildPairF64>;
  49 def MipsExtractElementF64 : SDNode<"MipsISD::ExtractElementF64",
  50                                    SDT_MipsExtractElementF64>;
  51
  52 // Operand for printing out a condition code.
  53 let PrintMethod = "printFCCOperand", DecoderMethod = "DecodeCondCode" in
  54   def condcode : Operand<i32>;
  55
  56 //===----------------------------------------------------------------------===//
  57 // Feature predicates.
  58 //===----------------------------------------------------------------------===//
  59
  60 def IsFP64bit        : Predicate<"Subtarget.isFP64bit()">,
  61                        AssemblerPredicate<"FeatureFP64Bit">;
  62 def NotFP64bit       : Predicate<"!Subtarget.isFP64bit()">,
  63                        AssemblerPredicate<"!FeatureFP64Bit">;
  64 def IsSingleFloat    : Predicate<"Subtarget.isSingleFloat()">,
  65                        AssemblerPredicate<"FeatureSingleFloat">;
  66 def IsNotSingleFloat : Predicate<"!Subtarget.isSingleFloat()">,
  67                        AssemblerPredicate<"!FeatureSingleFloat">;
  68
  69 // FP immediate patterns.
  70 def fpimm0 : PatLeaf<(fpimm), [{
  71   return N->isExactlyValue(+0.0);
  72 }]>;
  73
  74 def fpimm0neg : PatLeaf<(fpimm), [{
  75   return N->isExactlyValue(-0.0);
  76 }]>;
  77
  78 //===----------------------------------------------------------------------===//
  79 // Instruction Class Templates
  80 //
  81 // A set of multiclasses is used to address the register usage.
  82 //
  83 // S32 - single precision in 16 32bit even fp registers
  84 //       single precision in 32 32bit fp registers in SingleOnly mode
  85 // S64 - single precision in 32 64bit fp registers (In64BitMode)
  86 // D32 - double precision in 16 32bit even fp registers
  87 // D64 - double precision in 32 64bit fp registers (In64BitMode)
  88 //
  89 // Only S32 and D32 are supported right now.
  90 //===----------------------------------------------------------------------===//
  91
  92 class ADDS_FT<string opstr, RegisterOperand RC, InstrItinClass Itin, bit IsComm,
  93               SDPatternOperator OpNode= null_frag> :
  94   InstSE<(outs RC:$fd), (ins RC:$fs, RC:$ft),
  95          !strconcat(opstr, "\t$fd, $fs, $ft"),
  96          [(set RC:$fd, (OpNode RC:$fs, RC:$ft))], Itin, FrmFR, opstr> {
  97   let isCommutable = IsComm;
  98 }
  99
 100 multiclass ADDS_M<string opstr, InstrItinClass Itin, bit IsComm,
 101                   SDPatternOperator OpNode = null_frag> {
 102   def _D32 : MMRel, ADDS_FT<opstr, AFGR64Opnd, Itin, IsComm, OpNode>,
 103              Requires<[NotFP64bit, HasStdEnc]>;
 104   def _D64 : ADDS_FT<opstr, FGR64Opnd, Itin,
 105                      IsComm, OpNode>,
 106              Requires<[IsFP64bit, HasStdEnc]> {
 107     string DecoderNamespace = "Mips64";
 108   }
 109 }
 110
 111 class ABSS_FT<string opstr, RegisterOperand DstRC, RegisterOperand SrcRC,
 112               InstrItinClass Itin, SDPatternOperator OpNode= null_frag> :
 113   InstSE<(outs DstRC:$fd), (ins SrcRC:$fs), !strconcat(opstr, "\t$fd, $fs"),
 114          [(set DstRC:$fd, (OpNode SrcRC:$fs))], Itin, FrmFR, opstr>,
 115   NeverHasSideEffects;
 116
 117 multiclass ABSS_M<string opstr, InstrItinClass Itin,
 118                   SDPatternOperator OpNode= null_frag> {
 119   def _D32 : MMRel, ABSS_FT<opstr, AFGR64Opnd, AFGR64Opnd, Itin, OpNode>,
 120              Requires<[NotFP64bit, HasStdEnc]>;
 121   def _D64 : ABSS_FT<opstr, FGR64Opnd, FGR64Opnd, Itin, OpNode>,
 122              Requires<[IsFP64bit, HasStdEnc]> {
 123     string DecoderNamespace = "Mips64";
 124   }
 125 }
 126
 127 multiclass ROUND_M<string opstr, InstrItinClass Itin> {
 128   def _D32 : MMRel, ABSS_FT<opstr, FGR32Opnd, AFGR64Opnd, Itin>,
 129              Requires<[NotFP64bit, HasStdEnc]>;
 130   def _D64 : ABSS_FT<opstr, FGR32Opnd, FGR64Opnd, Itin>,
 131              Requires<[IsFP64bit, HasStdEnc]> {
 132     let DecoderNamespace = "Mips64";
 133   }
 134 }
 135
 136 class MFC1_FT<string opstr, RegisterOperand DstRC, RegisterOperand SrcRC,
 137               InstrItinClass Itin, SDPatternOperator OpNode= null_frag> :
 138   InstSE<(outs DstRC:$rt), (ins SrcRC:$fs), !strconcat(opstr, "\t$rt, $fs"),
 139          [(set DstRC:$rt, (OpNode SrcRC:$fs))], Itin, FrmFR, opstr>;
 140
 141 class MTC1_FT<string opstr, RegisterOperand DstRC, RegisterOperand SrcRC,
 142               InstrItinClass Itin, SDPatternOperator OpNode= null_frag> :
 143   InstSE<(outs DstRC:$fs), (ins SrcRC:$rt), !strconcat(opstr, "\t$rt, $fs"),
 144          [(set DstRC:$fs, (OpNode SrcRC:$rt))], Itin, FrmFR, opstr>;
 145
 146 class LW_FT<string opstr, RegisterOperand RC, InstrItinClass Itin,
 147             SDPatternOperator OpNode= null_frag> :
 148   InstSE<(outs RC:$rt), (ins mem:$addr), !strconcat(opstr, "\t$rt, $addr"),
 149          [(set RC:$rt, (OpNode addrDefault:$addr))], Itin, FrmFI, opstr> {
 150   let DecoderMethod = "DecodeFMem";
 151   let mayLoad = 1;
 152 }
 153
 154 class SW_FT<string opstr, RegisterOperand RC, InstrItinClass Itin,
 155             SDPatternOperator OpNode= null_frag> :
 156   InstSE<(outs), (ins RC:$rt, mem:$addr), !strconcat(opstr, "\t$rt, $addr"),
 157          [(OpNode RC:$rt, addrDefault:$addr)], Itin, FrmFI, opstr> {
 158   let DecoderMethod = "DecodeFMem";
 159   let mayStore = 1;
 160 }
 161
 162 class MADDS_FT<string opstr, RegisterOperand RC, InstrItinClass Itin,
 163                SDPatternOperator OpNode = null_frag> :
 164   InstSE<(outs RC:$fd), (ins RC:$fr, RC:$fs, RC:$ft),
 165          !strconcat(opstr, "\t$fd, $fr, $fs, $ft"),
 166          [(set RC:$fd, (OpNode (fmul RC:$fs, RC:$ft), RC:$fr))], Itin,
 167          FrmFR, opstr>;
 168
 169 class NMADDS_FT<string opstr, RegisterOperand RC, InstrItinClass Itin,
 170                 SDPatternOperator OpNode = null_frag> :
 171   InstSE<(outs RC:$fd), (ins RC:$fr, RC:$fs, RC:$ft),
 172          !strconcat(opstr, "\t$fd, $fr, $fs, $ft"),
 173          [(set RC:$fd, (fsub fpimm0, (OpNode (fmul RC:$fs, RC:$ft), RC:$fr)))],
 174          Itin, FrmFR, opstr>;
 175
 176 class LWXC1_FT<string opstr, RegisterOperand DRC,
 177                InstrItinClass Itin, SDPatternOperator OpNode = null_frag> :
 178   InstSE<(outs DRC:$fd), (ins PtrRC:$base, PtrRC:$index),
 179          !strconcat(opstr, "\t$fd, ${index}(${base})"),
 180          [(set DRC:$fd, (OpNode (add iPTR:$base, iPTR:$index)))], Itin,
 181          FrmFI, opstr> {
 182   let AddedComplexity = 20;
 183 }
 184
 185 class SWXC1_FT<string opstr, RegisterOperand DRC,
 186                InstrItinClass Itin, SDPatternOperator OpNode = null_frag> :
 187   InstSE<(outs), (ins DRC:$fs, PtrRC:$base, PtrRC:$index),
 188          !strconcat(opstr, "\t$fs, ${index}(${base})"),
 189          [(OpNode DRC:$fs, (add iPTR:$base, iPTR:$index))], Itin,
 190          FrmFI, opstr> {
 191   let AddedComplexity = 20;
 192 }
 193
 194 class BC1F_FT<string opstr, DAGOperand opnd, InstrItinClass Itin,
 195               SDPatternOperator Op = null_frag>  :
 196   InstSE<(outs), (ins FCCRegsOpnd:$fcc, opnd:$offset),
 197          !strconcat(opstr, "\t$fcc, $offset"),
 198          [(MipsFPBrcond Op, FCCRegsOpnd:$fcc, bb:$offset)], Itin,
 199          FrmFI, opstr> {
 200   let isBranch = 1;
 201   let isTerminator = 1;
 202   let hasDelaySlot = 1;
 203   let Defs = [AT];
 204 }
 205
 206 class CEQS_FT<string typestr, RegisterClass RC, InstrItinClass Itin,
 207               SDPatternOperator OpNode = null_frag>  :
 208   InstSE<(outs), (ins RC:$fs, RC:$ft, condcode:$cond),
 209          !strconcat("c.$cond.", typestr, "\t$fs, $ft"),
 210          [(OpNode RC:$fs, RC:$ft, imm:$cond)], Itin, FrmFR,
 211          !strconcat("c.$cond.", typestr)> {
 212   let Defs = [FCC0];
 213   let isCodeGenOnly = 1;
 214 }
 215
 216 class C_COND_FT<string CondStr, string Typestr, RegisterOperand RC,
 217                 InstrItinClass itin>  :
 218    InstSE<(outs), (ins RC:$fs, RC:$ft),
 219           !strconcat("c.", CondStr, ".", Typestr, "\t$fs, $ft"), [], itin,
 220           FrmFR>;
 221
 222 multiclass C_COND_M<string TypeStr, RegisterOperand RC, bits<5> fmt,
 223                     InstrItinClass itin> {
 224   def C_F_#NAME : C_COND_FT<"f", TypeStr, RC, itin>, C_COND_FM<fmt, 0>;
 225   def C_UN_#NAME : C_COND_FT<"un", TypeStr, RC, itin>, C_COND_FM<fmt, 1>;
 226   def C_EQ_#NAME : C_COND_FT<"eq", TypeStr, RC, itin>, C_COND_FM<fmt, 2>;
 227   def C_UEQ_#NAME : C_COND_FT<"ueq", TypeStr, RC, itin>, C_COND_FM<fmt, 3>;
 228   def C_OLT_#NAME : C_COND_FT<"olt", TypeStr, RC, itin>, C_COND_FM<fmt, 4>;
 229   def C_ULT_#NAME : C_COND_FT<"ult", TypeStr, RC, itin>, C_COND_FM<fmt, 5>;
 230   def C_OLE_#NAME : C_COND_FT<"ole", TypeStr, RC, itin>, C_COND_FM<fmt, 6>;
 231   def C_ULE_#NAME : C_COND_FT<"ule", TypeStr, RC, itin>, C_COND_FM<fmt, 7>;
 232   def C_SF_#NAME : C_COND_FT<"sf", TypeStr, RC, itin>, C_COND_FM<fmt, 8>;
 233   def C_NGLE_#NAME : C_COND_FT<"ngle", TypeStr, RC, itin>, C_COND_FM<fmt, 9>;
 234   def C_SEQ_#NAME : C_COND_FT<"seq", TypeStr, RC, itin>, C_COND_FM<fmt, 10>;
 235   def C_NGL_#NAME : C_COND_FT<"ngl", TypeStr, RC, itin>, C_COND_FM<fmt, 11>;
 236   def C_LT_#NAME : C_COND_FT<"lt", TypeStr, RC, itin>, C_COND_FM<fmt, 12>;
 237   def C_NGE_#NAME : C_COND_FT<"nge", TypeStr, RC, itin>, C_COND_FM<fmt, 13>;
 238   def C_LE_#NAME : C_COND_FT<"le", TypeStr, RC, itin>, C_COND_FM<fmt, 14>;
 239   def C_NGT_#NAME : C_COND_FT<"ngt", TypeStr, RC, itin>, C_COND_FM<fmt, 15>;
 240 }
 241
 242 defm S : C_COND_M<"s", FGR32Opnd, 16, II_C_CC_S>;
 243 defm D32 : C_COND_M<"d", AFGR64Opnd, 17, II_C_CC_D>,
 244            Requires<[NotFP64bit, HasStdEnc]>;
 245 let DecoderNamespace = "Mips64" in
 246 defm D64 : C_COND_M<"d", FGR64Opnd, 17, II_C_CC_D>,
 247            Requires<[IsFP64bit, HasStdEnc]>;
 248
 249 //===----------------------------------------------------------------------===//
 250 // Floating Point Instructions
 251 //===----------------------------------------------------------------------===//
 252 def ROUND_W_S  : MMRel, ABSS_FT<"round.w.s", FGR32Opnd, FGR32Opnd, II_ROUND>,
 253                  ABSS_FM<0xc, 16>;
 254 def TRUNC_W_S  : MMRel, ABSS_FT<"trunc.w.s", FGR32Opnd, FGR32Opnd, II_TRUNC>,
 255                  ABSS_FM<0xd, 16>;
 256 def CEIL_W_S   : MMRel, ABSS_FT<"ceil.w.s", FGR32Opnd, FGR32Opnd, II_CEIL>,
 257                  ABSS_FM<0xe, 16>;
 258 def FLOOR_W_S  : MMRel, ABSS_FT<"floor.w.s", FGR32Opnd, FGR32Opnd, II_FLOOR>,
 259                  ABSS_FM<0xf, 16>;
 260 def CVT_W_S    : MMRel, ABSS_FT<"cvt.w.s", FGR32Opnd, FGR32Opnd, II_CVT>,
 261                  ABSS_FM<0x24, 16>;
 262
 263 defm ROUND_W : ROUND_M<"round.w.d", II_ROUND>, ABSS_FM<0xc, 17>;
 264 defm TRUNC_W : ROUND_M<"trunc.w.d", II_TRUNC>, ABSS_FM<0xd, 17>;
 265 defm CEIL_W  : ROUND_M<"ceil.w.d", II_CEIL>, ABSS_FM<0xe, 17>;
 266 defm FLOOR_W : ROUND_M<"floor.w.d", II_FLOOR>, ABSS_FM<0xf, 17>;
 267 defm CVT_W   : ROUND_M<"cvt.w.d", II_CVT>, ABSS_FM<0x24, 17>;
 268
 269 let Predicates = [IsFP64bit, HasStdEnc], DecoderNamespace = "Mips64" in {
 270   def ROUND_L_S : ABSS_FT<"round.l.s", FGR64Opnd, FGR32Opnd, II_ROUND>,
 271                   ABSS_FM<0x8, 16>;
 272   def ROUND_L_D64 : ABSS_FT<"round.l.d", FGR64Opnd, FGR64Opnd, II_ROUND>,
 273                     ABSS_FM<0x8, 17>;
 274   def TRUNC_L_S : ABSS_FT<"trunc.l.s", FGR64Opnd, FGR32Opnd, II_TRUNC>,
 275                   ABSS_FM<0x9, 16>;
 276   def TRUNC_L_D64 : ABSS_FT<"trunc.l.d", FGR64Opnd, FGR64Opnd, II_TRUNC>,
 277                     ABSS_FM<0x9, 17>;
 278   def CEIL_L_S  : ABSS_FT<"ceil.l.s", FGR64Opnd, FGR32Opnd, II_CEIL>,
 279                   ABSS_FM<0xa, 16>;
 280   def CEIL_L_D64 : ABSS_FT<"ceil.l.d", FGR64Opnd, FGR64Opnd, II_CEIL>,
 281                    ABSS_FM<0xa, 17>;
 282   def FLOOR_L_S : ABSS_FT<"floor.l.s", FGR64Opnd, FGR32Opnd, II_FLOOR>,
 283                   ABSS_FM<0xb, 16>;
 284   def FLOOR_L_D64 : ABSS_FT<"floor.l.d", FGR64Opnd, FGR64Opnd, II_FLOOR>,
 285                     ABSS_FM<0xb, 17>;
 286 }
 287
 288 def CVT_S_W : MMRel, ABSS_FT<"cvt.s.w", FGR32Opnd, FGR32Opnd, II_CVT>,
 289               ABSS_FM<0x20, 20>;
 290 def CVT_L_S : MMRel, ABSS_FT<"cvt.l.s", FGR64Opnd, FGR32Opnd, II_CVT>,
 291               ABSS_FM<0x25, 16>;
 292 def CVT_L_D64: MMRel, ABSS_FT<"cvt.l.d", FGR64Opnd, FGR64Opnd, II_CVT>,
 293                ABSS_FM<0x25, 17>;
 294
 295 let Predicates = [NotFP64bit, HasStdEnc] in {
 296   def CVT_S_D32 : MMRel, ABSS_FT<"cvt.s.d", FGR32Opnd, AFGR64Opnd, II_CVT>,
 297                   ABSS_FM<0x20, 17>;
 298   def CVT_D32_W : MMRel, ABSS_FT<"cvt.d.w", AFGR64Opnd, FGR32Opnd, II_CVT>,
 299                   ABSS_FM<0x21, 20>;
 300   def CVT_D32_S : MMRel, ABSS_FT<"cvt.d.s", AFGR64Opnd, FGR32Opnd, II_CVT>,
 301                   ABSS_FM<0x21, 16>;
 302 }
 303
 304 let Predicates = [IsFP64bit, HasStdEnc], DecoderNamespace = "Mips64" in {
 305   def CVT_S_D64 : ABSS_FT<"cvt.s.d", FGR32Opnd, FGR64Opnd, II_CVT>,
 306                   ABSS_FM<0x20, 17>;
 307   def CVT_S_L   : ABSS_FT<"cvt.s.l", FGR32Opnd, FGR64Opnd, II_CVT>,
 308                   ABSS_FM<0x20, 21>;
 309   def CVT_D64_W : ABSS_FT<"cvt.d.w", FGR64Opnd, FGR32Opnd, II_CVT>,
 310                   ABSS_FM<0x21, 20>;
 311   def CVT_D64_S : ABSS_FT<"cvt.d.s", FGR64Opnd, FGR32Opnd, II_CVT>,
 312                   ABSS_FM<0x21, 16>;
 313   def CVT_D64_L : ABSS_FT<"cvt.d.l", FGR64Opnd, FGR64Opnd, II_CVT>,
 314                   ABSS_FM<0x21, 21>;
 315 }
 316
 317 let isPseudo = 1, isCodeGenOnly = 1 in {
 318   def PseudoCVT_S_W : ABSS_FT<"", FGR32Opnd, GPR32Opnd, II_CVT>;
 319   def PseudoCVT_D32_W : ABSS_FT<"", AFGR64Opnd, GPR32Opnd, II_CVT>;
 320   def PseudoCVT_S_L : ABSS_FT<"", FGR64Opnd, GPR64Opnd, II_CVT>;
 321   def PseudoCVT_D64_W : ABSS_FT<"", FGR64Opnd, GPR32Opnd, II_CVT>;
 322   def PseudoCVT_D64_L : ABSS_FT<"", FGR64Opnd, GPR64Opnd, II_CVT>;
 323 }
 324
 325 let Predicates = [NoNaNsFPMath, HasStdEnc] in {
 326   def FABS_S : MMRel, ABSS_FT<"abs.s", FGR32Opnd, FGR32Opnd, II_ABS, fabs>,
 327                ABSS_FM<0x5, 16>;
 328   def FNEG_S : MMRel, ABSS_FT<"neg.s", FGR32Opnd, FGR32Opnd, II_NEG, fneg>,
 329                ABSS_FM<0x7, 16>;
 330   defm FABS : ABSS_M<"abs.d", II_ABS, fabs>, ABSS_FM<0x5, 17>;
 331   defm FNEG : ABSS_M<"neg.d", II_NEG, fneg>, ABSS_FM<0x7, 17>;
 332 }
 333
 334 def FSQRT_S : MMRel, ABSS_FT<"sqrt.s", FGR32Opnd, FGR32Opnd, II_SQRT_S, fsqrt>,
 335               ABSS_FM<0x4, 16>;
 336 defm FSQRT : ABSS_M<"sqrt.d", II_SQRT_D, fsqrt>, ABSS_FM<0x4, 17>;
 337
 338 // The odd-numbered registers are only referenced when doing loads,
 339 // stores, and moves between floating-point and integer registers.
 340 // When defining instructions, we reference all 32-bit registers,
 341 // regardless of register aliasing.
 342
 343 /// Move Control Registers From/To CPU Registers
 344 def CFC1 : MMRel, MFC1_FT<"cfc1", GPR32Opnd, CCROpnd, II_CFC1>, MFC1_FM<2>;
 345 def CTC1 : MMRel, MTC1_FT<"ctc1", CCROpnd, GPR32Opnd, II_CTC1>, MFC1_FM<6>;
 346 def MFC1 : MMRel, MFC1_FT<"mfc1", GPR32Opnd, FGR32Opnd, II_MFC1,
 347                           bitconvert>, MFC1_FM<0>;
 348 def MTC1 : MMRel, MTC1_FT<"mtc1", FGR32Opnd, GPR32Opnd, II_MTC1,
 349                           bitconvert>, MFC1_FM<4>;
 350 def MFHC1 : MMRel, MFC1_FT<"mfhc1", GPR32Opnd, FGRH32Opnd, II_MFHC1>,
 351             MFC1_FM<3>;
 352 def MTHC1 : MMRel, MTC1_FT<"mthc1", FGRH32Opnd, GPR32Opnd, II_MTHC1>,
 353             MFC1_FM<7>;
 354 def DMFC1 : MFC1_FT<"dmfc1", GPR64Opnd, FGR64Opnd, II_DMFC1,
 355             bitconvert>, MFC1_FM<1>;
 356 def DMTC1 : MTC1_FT<"dmtc1", FGR64Opnd, GPR64Opnd, II_DMTC1,
 357             bitconvert>, MFC1_FM<5>;
 358
 359 def FMOV_S   : MMRel, ABSS_FT<"mov.s", FGR32Opnd, FGR32Opnd, II_MOV_S>,
 360                ABSS_FM<0x6, 16>;
 361 def FMOV_D32 : MMRel, ABSS_FT<"mov.d", AFGR64Opnd, AFGR64Opnd, II_MOV_D>,
 362                ABSS_FM<0x6, 17>, Requires<[NotFP64bit, HasStdEnc]>;
 363 def FMOV_D64 : ABSS_FT<"mov.d", FGR64Opnd, FGR64Opnd, II_MOV_D>,
 364                ABSS_FM<0x6, 17>, Requires<[IsFP64bit, HasStdEnc]> {
 365                  let DecoderNamespace = "Mips64";
 366 }
 367
 368 /// Floating Point Memory Instructions
 369 let Predicates = [HasStdEnc] in {
 370   def LWC1 : MMRel, LW_FT<"lwc1", FGR32Opnd, II_LWC1, load>, LW_FM<0x31>;
 371   def SWC1 : MMRel, SW_FT<"swc1", FGR32Opnd, II_SWC1, store>, LW_FM<0x39>;
 372 }
 373
 374 let Predicates = [IsFP64bit, HasStdEnc], DecoderNamespace = "Mips64" in {
 375   def LDC164 : LW_FT<"ldc1", FGR64Opnd, II_LDC1, load>, LW_FM<0x35>;
 376   def SDC164 : SW_FT<"sdc1", FGR64Opnd, II_SDC1, store>, LW_FM<0x3d>;
 377 }
 378
 379 let Predicates = [NotFP64bit, HasStdEnc] in {
 380   def LDC1 : MMRel, LW_FT<"ldc1", AFGR64Opnd, II_LDC1, load>, LW_FM<0x35>;
 381   def SDC1 : MMRel, SW_FT<"sdc1", AFGR64Opnd, II_SDC1, store>, LW_FM<0x3d>;
 382 }
 383
 384 /// Cop2 Memory Instructions
 385 let Predicates = [HasStdEnc] in {
 386   def LWC2 : LW_FT<"lwc2", COP2Opnd, NoItinerary, load>, LW_FM<0x32>;
 387   def SWC2 : SW_FT<"swc2", COP2Opnd, NoItinerary, store>, LW_FM<0x3a>;
 388   def LDC2 : LW_FT<"ldc2", COP2Opnd, NoItinerary, load>, LW_FM<0x36>;
 389   def SDC2 : SW_FT<"sdc2", COP2Opnd, NoItinerary, store>, LW_FM<0x3e>;
 390 }
 391
 392 // Indexed loads and stores.
 393 // Base register + offset register addressing mode (indicated by "x" in the
 394 // instruction mnemonic) is disallowed under NaCl.
 395 let Predicates = [HasFPIdx, HasStdEnc, IsNotNaCl] in {
 396   def LWXC1 : MMRel, LWXC1_FT<"lwxc1", FGR32Opnd, II_LWXC1, load>, LWXC1_FM<0>;
 397   def SWXC1 : MMRel, SWXC1_FT<"swxc1", FGR32Opnd, II_SWXC1, store>, SWXC1_FM<8>;
 398 }
 399
 400 let Predicates = [HasFPIdx, NotFP64bit, HasStdEnc, NotInMicroMips,
 401                   IsNotNaCl] in {
 402   def LDXC1 : LWXC1_FT<"ldxc1", AFGR64Opnd, II_LDXC1, load>, LWXC1_FM<1>;
 403   def SDXC1 : SWXC1_FT<"sdxc1", AFGR64Opnd, II_SDXC1, store>, SWXC1_FM<9>;
 404 }
 405
 406 let Predicates = [HasFPIdx, IsFP64bit, HasStdEnc],
 407     DecoderNamespace="Mips64" in {
 408   def LDXC164 : LWXC1_FT<"ldxc1", FGR64Opnd, II_LDXC1, load>, LWXC1_FM<1>;
 409   def SDXC164 : SWXC1_FT<"sdxc1", FGR64Opnd, II_SDXC1, store>, SWXC1_FM<9>;
 410 }
 411
 412 // Load/store doubleword indexed unaligned.
 413 let Predicates = [NotFP64bit, HasStdEnc, IsNotNaCl] in {
 414   def LUXC1 : MMRel, LWXC1_FT<"luxc1", AFGR64Opnd, II_LUXC1>, LWXC1_FM<0x5>;
 415   def SUXC1 : MMRel, SWXC1_FT<"suxc1", AFGR64Opnd, II_SUXC1>, SWXC1_FM<0xd>;
 416 }
 417
 418 let Predicates = [IsFP64bit, HasStdEnc], DecoderNamespace="Mips64" in {
 419   def LUXC164 : LWXC1_FT<"luxc1", FGR64Opnd, II_LUXC1>, LWXC1_FM<0x5>;
 420   def SUXC164 : SWXC1_FT<"suxc1", FGR64Opnd, II_SUXC1>, SWXC1_FM<0xd>;
 421 }
 422
 423 /// Floating-point Aritmetic
 424 def FADD_S : MMRel, ADDS_FT<"add.s", FGR32Opnd, II_ADD_S, 1, fadd>,
 425              ADDS_FM<0x00, 16>;
 426 defm FADD :  ADDS_M<"add.d", II_ADD_D, 1, fadd>, ADDS_FM<0x00, 17>;
 427 def FDIV_S : MMRel, ADDS_FT<"div.s", FGR32Opnd, II_DIV_S, 0, fdiv>,
 428              ADDS_FM<0x03, 16>;
 429 defm FDIV :  ADDS_M<"div.d", II_DIV_D, 0, fdiv>, ADDS_FM<0x03, 17>;
 430 def FMUL_S : MMRel, ADDS_FT<"mul.s", FGR32Opnd, II_MUL_S, 1, fmul>,
 431              ADDS_FM<0x02, 16>;
 432 defm FMUL :  ADDS_M<"mul.d", II_MUL_D, 1, fmul>, ADDS_FM<0x02, 17>;
 433 def FSUB_S : MMRel, ADDS_FT<"sub.s", FGR32Opnd, II_SUB_S, 0, fsub>,
 434              ADDS_FM<0x01, 16>;
 435 defm FSUB :  ADDS_M<"sub.d", II_SUB_D, 0, fsub>, ADDS_FM<0x01, 17>;
 436
 437 let Predicates = [HasMips32r2, HasStdEnc] in {
 438   def MADD_S : MMRel, MADDS_FT<"madd.s", FGR32Opnd, II_MADD_S, fadd>,
 439                MADDS_FM<4, 0>;
 440   def MSUB_S : MMRel, MADDS_FT<"msub.s", FGR32Opnd, II_MSUB_S, fsub>,
 441                MADDS_FM<5, 0>;
 442 }
 443
 444 let Predicates = [HasMips32r2, NoNaNsFPMath, HasStdEnc] in {
 445   def NMADD_S : MMRel, NMADDS_FT<"nmadd.s", FGR32Opnd, II_NMADD_S, fadd>,
 446                 MADDS_FM<6, 0>;
 447   def NMSUB_S : MMRel, NMADDS_FT<"nmsub.s", FGR32Opnd, II_NMSUB_S, fsub>,
 448                 MADDS_FM<7, 0>;
 449 }
 450
 451 let Predicates = [HasMips32r2, NotFP64bit, HasStdEnc] in {
 452   def MADD_D32 : MMRel, MADDS_FT<"madd.d", AFGR64Opnd, II_MADD_D, fadd>,
 453                  MADDS_FM<4, 1>;
 454   def MSUB_D32 : MMRel, MADDS_FT<"msub.d", AFGR64Opnd, II_MSUB_D, fsub>,
 455                  MADDS_FM<5, 1>;
 456 }
 457
 458 let Predicates = [HasMips32r2, NotFP64bit, NoNaNsFPMath, HasStdEnc] in {
 459   def NMADD_D32 : MMRel, NMADDS_FT<"nmadd.d", AFGR64Opnd, II_NMADD_D, fadd>,
 460                   MADDS_FM<6, 1>;
 461   def NMSUB_D32 : MMRel, NMADDS_FT<"nmsub.d", AFGR64Opnd, II_NMSUB_D, fsub>,
 462                   MADDS_FM<7, 1>;
 463 }
 464
 465 let Predicates = [HasMips32r2, IsFP64bit, HasStdEnc], isCodeGenOnly=1 in {
 466   def MADD_D64 : MADDS_FT<"madd.d", FGR64Opnd, II_MADD_D, fadd>,
 467                  MADDS_FM<4, 1>;
 468   def MSUB_D64 : MADDS_FT<"msub.d", FGR64Opnd, II_MSUB_D, fsub>,
 469                  MADDS_FM<5, 1>;
 470 }
 471
 472 let Predicates = [HasMips32r2, IsFP64bit, NoNaNsFPMath, HasStdEnc],
 473     isCodeGenOnly=1 in {
 474   def NMADD_D64 : NMADDS_FT<"nmadd.d", FGR64Opnd, II_NMADD_D, fadd>,
 475                   MADDS_FM<6, 1>;
 476   def NMSUB_D64 : NMADDS_FT<"nmsub.d", FGR64Opnd, II_NMSUB_D, fsub>,
 477                   MADDS_FM<7, 1>;
 478 }
 479
 480 //===----------------------------------------------------------------------===//
 481 // Floating Point Branch Codes
 482 //===----------------------------------------------------------------------===//
 483 // Mips branch codes. These correspond to condcode in MipsInstrInfo.h.
 484 // They must be kept in synch.
 485 def MIPS_BRANCH_F  : PatLeaf<(i32 0)>;
 486 def MIPS_BRANCH_T  : PatLeaf<(i32 1)>;
 487
 488 def BC1F : MMRel, BC1F_FT<"bc1f", brtarget, IIBranch, MIPS_BRANCH_F>,
 489            BC1F_FM<0, 0>;
 490 def BC1T : MMRel, BC1F_FT<"bc1t", brtarget, IIBranch, MIPS_BRANCH_T>,
 491            BC1F_FM<0, 1>;
 492
 493 //===----------------------------------------------------------------------===//
 494 // Floating Point Flag Conditions
 495 //===----------------------------------------------------------------------===//
 496 // Mips condition codes. They must correspond to condcode in MipsInstrInfo.h.
 497 // They must be kept in synch.
 498 def MIPS_FCOND_F    : PatLeaf<(i32 0)>;
 499 def MIPS_FCOND_UN   : PatLeaf<(i32 1)>;
 500 def MIPS_FCOND_OEQ  : PatLeaf<(i32 2)>;
 501 def MIPS_FCOND_UEQ  : PatLeaf<(i32 3)>;
 502 def MIPS_FCOND_OLT  : PatLeaf<(i32 4)>;
 503 def MIPS_FCOND_ULT  : PatLeaf<(i32 5)>;
 504 def MIPS_FCOND_OLE  : PatLeaf<(i32 6)>;
 505 def MIPS_FCOND_ULE  : PatLeaf<(i32 7)>;
 506 def MIPS_FCOND_SF   : PatLeaf<(i32 8)>;
 507 def MIPS_FCOND_NGLE : PatLeaf<(i32 9)>;
 508 def MIPS_FCOND_SEQ  : PatLeaf<(i32 10)>;
 509 def MIPS_FCOND_NGL  : PatLeaf<(i32 11)>;
 510 def MIPS_FCOND_LT   : PatLeaf<(i32 12)>;
 511 def MIPS_FCOND_NGE  : PatLeaf<(i32 13)>;
 512 def MIPS_FCOND_LE   : PatLeaf<(i32 14)>;
 513 def MIPS_FCOND_NGT  : PatLeaf<(i32 15)>;
 514
 515 /// Floating Point Compare
 516 def FCMP_S32 : MMRel, CEQS_FT<"s", FGR32, II_C_CC_S, MipsFPCmp>, CEQS_FM<16>;
 517 def FCMP_D32 : MMRel, CEQS_FT<"d", AFGR64, II_C_CC_D, MipsFPCmp>, CEQS_FM<17>,
 518                Requires<[NotFP64bit, HasStdEnc]>;
 519 let DecoderNamespace = "Mips64" in
 520 def FCMP_D64 : CEQS_FT<"d", FGR64, II_C_CC_D, MipsFPCmp>, CEQS_FM<17>,
 521                Requires<[IsFP64bit, HasStdEnc]>;
 522
 523 //===----------------------------------------------------------------------===//
 524 // Floating Point Pseudo-Instructions
 525 //===----------------------------------------------------------------------===//
 526
 527 // This pseudo instr gets expanded into 2 mtc1 instrs after register
 528 // allocation.
 529 class BuildPairF64Base<RegisterOperand RO> :
 530   PseudoSE<(outs RO:$dst), (ins GPR32Opnd:$lo, GPR32Opnd:$hi),
 531            [(set RO:$dst, (MipsBuildPairF64 GPR32Opnd:$lo, GPR32Opnd:$hi))]>;
 532
 533 def BuildPairF64 : BuildPairF64Base<AFGR64Opnd>,
 534                    Requires<[NotFP64bit, HasStdEnc]>;
 535 def BuildPairF64_64 : BuildPairF64Base<FGR64Opnd>,
 536                       Requires<[IsFP64bit, HasStdEnc]>;
 537
 538 // This pseudo instr gets expanded into 2 mfc1 instrs after register
 539 // allocation.
 540 // if n is 0, lower part of src is extracted.
 541 // if n is 1, higher part of src is extracted.
 542 class ExtractElementF64Base<RegisterOperand RO> :
 543   PseudoSE<(outs GPR32Opnd:$dst), (ins RO:$src, i32imm:$n),
 544            [(set GPR32Opnd:$dst, (MipsExtractElementF64 RO:$src, imm:$n))]>;
 545
 546 def ExtractElementF64 : ExtractElementF64Base<AFGR64Opnd>,
 547                         Requires<[NotFP64bit, HasStdEnc]>;
 548 def ExtractElementF64_64 : ExtractElementF64Base<FGR64Opnd>,
 549                            Requires<[IsFP64bit, HasStdEnc]>;
 550
 551 //===----------------------------------------------------------------------===//
 552 // InstAliases.
 553 //===----------------------------------------------------------------------===//
 554 def : InstAlias<"bc1t $offset", (BC1T FCC0, brtarget:$offset)>;
 555 def : InstAlias<"bc1f $offset", (BC1F FCC0, brtarget:$offset)>;
 556
 557 //===----------------------------------------------------------------------===//
 558 // Floating Point Patterns
 559 //===----------------------------------------------------------------------===//
 560 def : MipsPat<(f32 fpimm0), (MTC1 ZERO)>;
 561 def : MipsPat<(f32 fpimm0neg), (FNEG_S (MTC1 ZERO))>;
 562
 563 def : MipsPat<(f32 (sint_to_fp GPR32Opnd:$src)),
 564               (PseudoCVT_S_W GPR32Opnd:$src)>;
 565 def : MipsPat<(MipsTruncIntFP FGR32Opnd:$src),
 566               (TRUNC_W_S FGR32Opnd:$src)>;
 567
 568 let Predicates = [NotFP64bit, HasStdEnc] in {
 569   def : MipsPat<(f64 (sint_to_fp GPR32Opnd:$src)),
 570                 (PseudoCVT_D32_W GPR32Opnd:$src)>;
 571   def : MipsPat<(MipsTruncIntFP AFGR64Opnd:$src),
 572                 (TRUNC_W_D32 AFGR64Opnd:$src)>;
 573   def : MipsPat<(f32 (fround AFGR64Opnd:$src)),
 574                 (CVT_S_D32 AFGR64Opnd:$src)>;
 575   def : MipsPat<(f64 (fextend FGR32Opnd:$src)),
 576                 (CVT_D32_S FGR32Opnd:$src)>;
 577 }
 578
 579 let Predicates = [IsFP64bit, HasStdEnc] in {
 580   def : MipsPat<(f64 fpimm0), (DMTC1 ZERO_64)>;
 581   def : MipsPat<(f64 fpimm0neg), (FNEG_D64 (DMTC1 ZERO_64))>;
 582
 583   def : MipsPat<(f64 (sint_to_fp GPR32Opnd:$src)),
 584                 (PseudoCVT_D64_W GPR32Opnd:$src)>;
 585   def : MipsPat<(f32 (sint_to_fp GPR64Opnd:$src)),
 586                 (EXTRACT_SUBREG (PseudoCVT_S_L GPR64Opnd:$src), sub_lo)>;
 587   def : MipsPat<(f64 (sint_to_fp GPR64Opnd:$src)),
 588                 (PseudoCVT_D64_L GPR64Opnd:$src)>;
 589
 590   def : MipsPat<(MipsTruncIntFP FGR64Opnd:$src),
 591                 (TRUNC_W_D64 FGR64Opnd:$src)>;
 592   def : MipsPat<(MipsTruncIntFP FGR32Opnd:$src),
 593                 (TRUNC_L_S FGR32Opnd:$src)>;
 594   def : MipsPat<(MipsTruncIntFP FGR64Opnd:$src),
 595                 (TRUNC_L_D64 FGR64Opnd:$src)>;
 596
 597   def : MipsPat<(f32 (fround FGR64Opnd:$src)),
 598                 (CVT_S_D64 FGR64Opnd:$src)>;
 599   def : MipsPat<(f64 (fextend FGR32Opnd:$src)),
 600                 (CVT_D64_S FGR32Opnd:$src)>;
 601 }
 602
 603 // Patterns for loads/stores with a reg+imm operand.
 604 let AddedComplexity = 40 in {
 605   let Predicates = [HasStdEnc] in {
 606     def : LoadRegImmPat<LWC1, f32, load>;
 607     def : StoreRegImmPat<SWC1, f32>;
 608   }
 609
 610   let Predicates = [IsFP64bit, HasStdEnc] in {
 611     def : LoadRegImmPat<LDC164, f64, load>;
 612     def : StoreRegImmPat<SDC164, f64>;
 613   }
 614
 615   let Predicates = [NotFP64bit, HasStdEnc] in {
 616     def : LoadRegImmPat<LDC1, f64, load>;
 617     def : StoreRegImmPat<SDC1, f64>;
 618   }
 619 }