lib/Target/Mips/Mips64InstrInfo.td

   1 //===- Mips64InstrInfo.td - Mips64 Instruction Information -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes Mips64 instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Mips Operand, Complex Patterns and Transformations Definitions.
  16 //===----------------------------------------------------------------------===//
  17
  18 // Instruction operand types
  19 def shamt_64       : Operand<i64>;
  20
  21 // Unsigned Operand
  22 def uimm16_64      : Operand<i64> {
  23   let PrintMethod = "printUnsignedImm";
  24 }
  25
  26 // Transformation Function - get Imm - 32.
  27 def Subtract32 : SDNodeXForm<imm, [{
  28   return getI32Imm((unsigned)N->getZExtValue() - 32);
  29 }]>;
  30
  31 // shamt field must fit in 5 bits.
  32 def immZExt5_64 : ImmLeaf<i64, [{return Imm == (Imm & 0x1f);}]>;
  33
  34 // imm32_63 predicate - True if imm is in range [32, 63].
  35 def imm32_63 : ImmLeaf<i64,
  36                        [{return (int32_t)Imm >= 32 && (int32_t)Imm < 64;}],
  37                        Subtract32>;
  38
  39 //===----------------------------------------------------------------------===//
  40 // Instructions specific format
  41 //===----------------------------------------------------------------------===//
  42 // Shifts
  43 // 64-bit shift instructions.
  44 class shift_rotate_imm64<bits<6> func, bits<5> isRotate, string instr_asm,
  45                          SDNode OpNode>:
  46   shift_rotate_imm<func, isRotate, instr_asm, OpNode, immZExt5_64, shamt_64,
  47                    CPU64Regs>;
  48
  49 class shift_rotate_imm64_32<bits<6> func, bits<5> isRotate, string instr_asm,
  50                             SDNode OpNode>:
  51   shift_rotate_imm<func, isRotate, instr_asm, OpNode, imm32_63, shamt_64,
  52                    CPU64Regs>;
  53
  54 class LogicR_shift_rotate_reg64<bits<6> func, bits<5> _shamt, string instr_asm,
  55                                 SDNode OpNode>:
  56   FR<0x00, func, (outs CPU64Regs:$dst), (ins CPU64Regs:$c, CPU64Regs:$b),
  57      !strconcat(instr_asm, "\t$dst, $b, $c"),
  58      [(set CPU64Regs:$dst, (OpNode CPU64Regs:$b, CPU64Regs:$c))], IIAlu> {
  59   let shamt = _shamt;
  60 }
  61
  62 // Mul, Div
  63 let Defs = [HI64, LO64] in {
  64   let isCommutable = 1 in
  65   class Mul64<bits<6> func, string instr_asm, InstrItinClass itin>:
  66     FR<0x00, func, (outs), (ins CPU64Regs:$a, CPU64Regs:$b),
  67        !strconcat(instr_asm, "\t$a, $b"), [], itin>;
  68
  69   class Div64<SDNode op, bits<6> func, string instr_asm, InstrItinClass itin>:
  70               FR<0x00, func, (outs), (ins CPU64Regs:$a, CPU64Regs:$b),
  71               !strconcat(instr_asm, "\t$$zero, $a, $b"),
  72               [(op CPU64Regs:$a, CPU64Regs:$b)], itin>;
  73 }
  74
  75 // Move from Hi/Lo
  76 let shamt = 0 in {
  77 let rs = 0, rt = 0 in
  78 class MoveFromLOHI64<bits<6> func, string instr_asm>:
  79   FR<0x00, func, (outs CPU64Regs:$dst), (ins),
  80      !strconcat(instr_asm, "\t$dst"), [], IIHiLo>;
  81
  82 let rt = 0, rd = 0 in
  83 class MoveToLOHI64<bits<6> func, string instr_asm>:
  84   FR<0x00, func, (outs), (ins CPU64Regs:$src),
  85      !strconcat(instr_asm, "\t$src"), [], IIHiLo>;
  86 }
  87
  88 // Count Leading Ones/Zeros in Word
  89 class CountLeading64<bits<6> func, string instr_asm, list<dag> pattern>:
  90   FR<0x1c, func, (outs CPU64Regs:$dst), (ins CPU64Regs:$src),
  91      !strconcat(instr_asm, "\t$dst, $src"), pattern, IIAlu>,
  92      Requires<[HasBitCount]> {
  93   let shamt = 0;
  94   let rt = rd;
  95 }
  96
  97 //===----------------------------------------------------------------------===//
  98 // Instruction definition
  99 //===----------------------------------------------------------------------===//
 100
 101 /// Arithmetic Instructions (ALU Immediate)
 102 def DADDiu   : ArithLogicI<0x19, "daddiu", add, simm16_64, immSExt16,
 103                            CPU64Regs>;
 104 def DANDi    : ArithLogicI<0x0c, "andi", and, uimm16_64, immZExt16, CPU64Regs>;
 105 def SLTi64   : SetCC_I<0x0a, "slti", setlt, simm16_64, immSExt16, CPU64Regs>;
 106 def SLTiu64  : SetCC_I<0x0b, "sltiu", setult, simm16_64, immSExt16, CPU64Regs>;
 107 def ORi64    : ArithLogicI<0x0d, "ori", or, uimm16_64, immZExt16, CPU64Regs>;
 108 def XORi64   : ArithLogicI<0x0e, "xori", xor, uimm16_64, immZExt16, CPU64Regs>;
 109
 110 /// Arithmetic Instructions (3-Operand, R-Type)
 111 def DADDu    : ArithLogicR<0x00, 0x2d, "daddu", add, IIAlu, CPU64Regs, 1>;
 112 def DSUBu    : ArithLogicR<0x00, 0x2f, "dsubu", sub, IIAlu, CPU64Regs>;
 113 def SLT64    : SetCC_R<0x00, 0x2a, "slt", setlt, CPU64Regs>;
 114 def SLTu64   : SetCC_R<0x00, 0x2b, "sltu", setult, CPU64Regs>;
 115 def AND64    : ArithLogicR<0x00, 0x24, "and", and, IIAlu, CPU64Regs, 1>;
 116 def OR64     : ArithLogicR<0x00, 0x25, "or", or, IIAlu, CPU64Regs, 1>;
 117 def XOR64    : ArithLogicR<0x00, 0x26, "xor", xor, IIAlu, CPU64Regs, 1>;
 118 def NOR64    : LogicNOR<0x00, 0x27, "nor", CPU64Regs>;
 119
 120 /// Shift Instructions
 121 def DSLL     : shift_rotate_imm64<0x38, 0x00, "dsll", shl>;
 122 def DSRL     : shift_rotate_imm64<0x3a, 0x00, "dsrl", srl>;
 123 def DSRA     : shift_rotate_imm64<0x3b, 0x00, "dsra", sra>;
 124 def DSLL32   : shift_rotate_imm64_32<0x3c, 0x00, "dsll32", shl>;
 125 def DSRL32   : shift_rotate_imm64_32<0x3e, 0x00, "dsrl32", srl>;
 126 def DSRA32   : shift_rotate_imm64_32<0x3f, 0x00, "dsra32", sra>;
 127 def DSLLV    : LogicR_shift_rotate_reg64<0x24, 0x00, "dsllv", shl>;
 128 def DSRLV    : LogicR_shift_rotate_reg64<0x26, 0x00, "dsrlv", srl>;
 129 def DSRAV    : LogicR_shift_rotate_reg64<0x27, 0x00, "dsrav", sra>;
 130
 131 // Rotate Instructions
 132 let Predicates = [HasMips64r2] in {
 133   def DROTR    : shift_rotate_imm64<0x3a, 0x01, "drotr", rotr>;
 134   def DROTR32  : shift_rotate_imm64_32<0x3e, 0x01, "drotr32", rotr>;
 135   def DROTRV   : LogicR_shift_rotate_reg64<0x16, 0x01, "drotrv", rotr>;
 136 }
 137
 138 /// Load and Store Instructions
 139 ///  aligned
 140 defm LB64    : LoadM64<0x20, "lb",  sextloadi8>;
 141 defm LBu64   : LoadM64<0x24, "lbu", zextloadi8>;
 142 defm LH64    : LoadM64<0x21, "lh",  sextloadi16_a>;
 143 defm LHu64   : LoadM64<0x25, "lhu", zextloadi16_a>;
 144 defm LW64    : LoadM64<0x23, "lw",  sextloadi32_a>;
 145 defm LWu64   : LoadM64<0x27, "lwu", zextloadi32_a>;
 146 defm SB64    : StoreM64<0x28, "sb", truncstorei8>;
 147 defm SH64    : StoreM64<0x29, "sh", truncstorei16_a>;
 148 defm SW64    : StoreM64<0x2b, "sw", truncstorei32_a>;
 149 defm LD      : LoadM64<0x37, "ld",  load_a>;
 150 defm SD      : StoreM64<0x3f, "sd", store_a>;
 151
 152 ///  unaligned
 153 defm ULH64     : LoadM64<0x21, "ulh",  sextloadi16_u, 1>;
 154 defm ULHu64    : LoadM64<0x25, "ulhu", zextloadi16_u, 1>;
 155 defm ULW64     : LoadM64<0x23, "ulw",  sextloadi32_u, 1>;
 156 defm USH64     : StoreM64<0x29, "ush", truncstorei16_u, 1>;
 157 defm USW64     : StoreM64<0x2b, "usw", truncstorei32_u, 1>;
 158 defm ULD       : LoadM64<0x37, "uld",  load_u, 1>;
 159 defm USD       : StoreM64<0x3f, "usd", store_u, 1>;
 160
 161 /// Jump and Branch Instructions
 162 def BEQ64  : CBranch<0x04, "beq", seteq, CPU64Regs>;
 163 def BNE64  : CBranch<0x05, "bne", setne, CPU64Regs>;
 164 def BGEZ64 : CBranchZero<0x01, 1, "bgez", setge, CPU64Regs>;
 165 def BGTZ64 : CBranchZero<0x07, 0, "bgtz", setgt, CPU64Regs>;
 166 def BLEZ64 : CBranchZero<0x07, 0, "blez", setle, CPU64Regs>;
 167 def BLTZ64 : CBranchZero<0x01, 0, "bltz", setlt, CPU64Regs>;
 168
 169 /// Multiply and Divide Instructions.
 170 def DMULT    : Mul64<0x1c, "dmult", IIImul>;
 171 def DMULTu   : Mul64<0x1d, "dmultu", IIImul>;
 172 def DSDIV    : Div64<MipsDivRem, 0x1e, "ddiv", IIIdiv>;
 173 def DUDIV    : Div64<MipsDivRemU, 0x1f, "ddivu", IIIdiv>;
 174
 175 let Defs = [HI64] in
 176   def MTHI64  : MoveToLOHI64<0x11, "mthi">;
 177 let Defs = [LO64] in
 178   def MTLO64  : MoveToLOHI64<0x13, "mtlo">;
 179
 180 let Uses = [HI64] in
 181   def MFHI64  : MoveFromLOHI64<0x10, "mfhi">;
 182 let Uses = [LO64] in
 183   def MFLO64  : MoveFromLOHI64<0x12, "mflo">;
 184
 185 /// Count Leading
 186 def DCLZ : CountLeading64<0x24, "dclz",
 187                           [(set CPU64Regs:$dst, (ctlz CPU64Regs:$src))]>;
 188 def DCLO : CountLeading64<0x25, "dclo",
 189                           [(set CPU64Regs:$dst, (ctlz (not CPU64Regs:$src)))]>;
 190
 191 //===----------------------------------------------------------------------===//
 192 //  Arbitrary patterns that map to one or more instructions
 193 //===----------------------------------------------------------------------===//
 194
 195 // Small immediates
 196 def : Pat<(i64 immSExt16:$in),
 197           (DADDiu ZERO_64, imm:$in)>;
 198 def : Pat<(i64 immZExt16:$in),
 199           (ORi64 ZERO_64, imm:$in)>;
 200
 201 // zextloadi32_u
 202 def : Pat<(zextloadi32_u addr:$a), (DSRL (DSLL (ULW64_P8 addr:$a), 32), 32)>,
 203       Requires<[IsN64]>;
 204 def : Pat<(zextloadi32_u addr:$a), (DSRL (DSLL (ULW64 addr:$a), 32), 32)>,
 205       Requires<[NotN64]>;
 206
 207 // hi/lo relocs
 208 def : Pat<(i64 (MipsLo tglobaladdr:$in)), (DADDiu ZERO_64, tglobaladdr:$in)>;
 209
 210 defm : BrcondPats<CPU64Regs, BEQ64, BNE64, SLT64, SLTu64, SLTi64, SLTiu64,
 211                   ZERO_64>;
 212
 213 // setcc patterns
 214 defm : SeteqPats<CPU64Regs, SLTiu64, XOR64, SLTu64, ZERO_64>;
 215 defm : SetlePats<CPU64Regs, SLT64, SLTu64>;
 216 defm : SetgtPats<CPU64Regs, SLT64, SLTu64>;
 217 defm : SetgePats<CPU64Regs, SLT64, SLTu64>;
 218 defm : SetgeImmPats<CPU64Regs, SLTi64, SLTiu64>;