lib/Target/Mips/MicroMips32r6InstrInfo.td

   1 //=- MicroMips32r6InstrInfo.td - MicroMips r6 Instruction Information -*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes microMIPSr6 instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 //
  16 // Instruction Encodings
  17 //
  18 //===----------------------------------------------------------------------===//
  19 class ADD_MMR6_ENC : ARITH_FM_MMR6<"add", 0x110>;
  20 class ADDIU_MMR6_ENC : ADDI_FM_MMR6<"addiu", 0xc>;
  21 class ADDU_MMR6_ENC : ARITH_FM_MMR6<"addu", 0x150>;
  22 class ADDIUPC_MMR6_ENC : PCREL19_FM_MMR6<0b00>;
  23 class ALUIPC_MMR6_ENC : PCREL16_FM_MMR6<0b11111>;
  24 class AUIPC_MMR6_ENC  : PCREL16_FM_MMR6<0b11110>;
  25 class ALIGN_MMR6_ENC : POOL32A_ALIGN_FM_MMR6<0b011111>;
  26 class AUI_MMR6_ENC : AUI_FM_MMR6;
  27 class BALC_MMR6_ENC  : BRANCH_OFF26_FM<0b101101>;
  28 class BC_MMR6_ENC : BRANCH_OFF26_FM<0b100101>;
  29 class BITSWAP_MMR6_ENC : POOL32A_BITSWAP_FM_MMR6<0b101100>;
  30 class CACHE_MMR6_ENC : CACHE_PREF_FM_MMR6<0b001000, 0b0110>;
  31 class CLO_MMR6_ENC : POOL32A_2R_FM_MMR6<0b0100101100>;
  32 class CLZ_MMR6_ENC : SPECIAL_2R_FM_MMR6<0b010000>;
  33 class DIV_MMR6_ENC : ARITH_FM_MMR6<"div", 0x118>;
  34 class DIVU_MMR6_ENC : ARITH_FM_MMR6<"divu", 0x198>;
  35 class JIALC_MMR6_ENC : JMP_IDX_COMPACT_FM<0b100000>;
  36 class JIC_MMR6_ENC   : JMP_IDX_COMPACT_FM<0b101000>;
  37 class LSA_MMR6_ENC : POOL32A_LSA_FM<0b001111>;
  38 class LWPC_MMR6_ENC  : PCREL19_FM_MMR6<0b01>;
  39 class MOD_MMR6_ENC : ARITH_FM_MMR6<"mod", 0x158>;
  40 class MODU_MMR6_ENC : ARITH_FM_MMR6<"modu", 0x1d8>;
  41 class MUL_MMR6_ENC : ARITH_FM_MMR6<"mul", 0x18>;
  42 class MUH_MMR6_ENC : ARITH_FM_MMR6<"muh", 0x58>;
  43 class MULU_MMR6_ENC : ARITH_FM_MMR6<"mulu", 0x98>;
  44 class MUHU_MMR6_ENC : ARITH_FM_MMR6<"muhu", 0xd8>;
  45 class PREF_MMR6_ENC : CACHE_PREF_FM_MMR6<0b011000, 0b0010>;
  46 class SELEQZ_MMR6_ENC : POOL32A_FM_MMR6<0b0101000000>;
  47 class SELNEZ_MMR6_ENC : POOL32A_FM_MMR6<0b0110000000>;
  48 class SUB_MMR6_ENC : ARITH_FM_MMR6<"sub", 0x190>;
  49 class SUBU_MMR6_ENC : ARITH_FM_MMR6<"subu", 0x1d0>;
  50
  51 //===----------------------------------------------------------------------===//
  52 //
  53 // Instruction Descriptions
  54 //
  55 //===----------------------------------------------------------------------===//
  56
  57 class ADD_MMR6_DESC : ArithLogicR<"add", GPR32Opnd>;
  58 class ADDIU_MMR6_DESC : ArithLogicI<"addiu", simm16, GPR32Opnd>;
  59 class ADDU_MMR6_DESC : ArithLogicR<"addu", GPR32Opnd>;
  60 class MUL_MMR6_DESC : ArithLogicR<"mul", GPR32Opnd>;
  61 class MUH_MMR6_DESC : ArithLogicR<"muh", GPR32Opnd>;
  62 class MULU_MMR6_DESC : ArithLogicR<"mulu", GPR32Opnd>;
  63 class MUHU_MMR6_DESC : ArithLogicR<"muhu", GPR32Opnd>;
  64
  65 class BC_MMR6_DESC_BASE<string instr_asm, DAGOperand opnd>
  66     : BRANCH_DESC_BASE, MMR6Arch<instr_asm> {
  67   dag InOperandList = (ins opnd:$offset);
  68   dag OutOperandList = (outs);
  69   string AsmString = !strconcat(instr_asm, "\t$offset");
  70   bit isBarrier = 1;
  71 }
  72
  73 class BALC_MMR6_DESC : BC_MMR6_DESC_BASE<"balc", brtarget26> {
  74   bit isCall = 1;
  75   list<Register> Defs = [RA];
  76 }
  77 class BC_MMR6_DESC : BC_MMR6_DESC_BASE<"bc", brtarget26>;
  78 class SUB_MMR6_DESC : ArithLogicR<"sub", GPR32Opnd>;
  79 class SUBU_MMR6_DESC : ArithLogicR<"subu", GPR32Opnd>;
  80
  81 class BITSWAP_MMR6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd>
  82     : MMR6Arch<instr_asm> {
  83   dag OutOperandList = (outs GPROpnd:$rd);
  84   dag InOperandList = (ins GPROpnd:$rt);
  85   string AsmString = !strconcat(instr_asm, "\t$rd, $rt");
  86   list<dag> Pattern = [];
  87 }
  88
  89 class BITSWAP_MMR6_DESC : BITSWAP_MMR6_DESC_BASE<"bitswap", GPR32Opnd>;
  90
  91 class CACHE_HINT_MMR6_DESC<string instr_asm, Operand MemOpnd,
  92                            RegisterOperand GPROpnd> : MMR6Arch<instr_asm> {
  93   dag OutOperandList = (outs);
  94   dag InOperandList = (ins MemOpnd:$addr, uimm5:$hint);
  95   string AsmString = !strconcat(instr_asm, "\t$hint, $addr");
  96   list<dag> Pattern = [];
  97   string DecoderMethod = "DecodeCacheOpMM";
  98 }
  99
 100 class CACHE_MMR6_DESC : CACHE_HINT_MMR6_DESC<"cache", mem_mm_12, GPR32Opnd>;
 101 class PREF_MMR6_DESC : CACHE_HINT_MMR6_DESC<"pref", mem_mm_12, GPR32Opnd>;
 102
 103 class CLO_CLZ_MMR6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd>
 104     : MMR6Arch<instr_asm> {
 105   dag OutOperandList = (outs GPROpnd:$rt);
 106   dag InOperandList = (ins GPROpnd:$rs);
 107   string AsmString = !strconcat(instr_asm, "\t$rt, $rs");
 108 }
 109
 110 class CLO_MMR6_DESC : CLO_CLZ_MMR6_DESC_BASE<"clo", GPR32Opnd>;
 111 class CLZ_MMR6_DESC : CLO_CLZ_MMR6_DESC_BASE<"clz", GPR32Opnd>;
 112
 113 class JMP_MMR6_IDX_COMPACT_DESC_BASE<string opstr, DAGOperand opnd,
 114                                      RegisterOperand GPROpnd>
 115     : MMR6Arch<opstr> {
 116   dag InOperandList = (ins GPROpnd:$rt, opnd:$offset);
 117   string AsmString = !strconcat(opstr, "\t$rt, $offset");
 118   list<dag> Pattern = [];
 119   bit isTerminator = 1;
 120   bit hasDelaySlot = 0;
 121 }
 122
 123 class JIALC_MMR6_DESC : JMP_MMR6_IDX_COMPACT_DESC_BASE<"jialc", calloffset16,
 124                                                        GPR32Opnd> {
 125   bit isCall = 1;
 126   list<Register> Defs = [RA];
 127 }
 128
 129 class JIC_MMR6_DESC : JMP_MMR6_IDX_COMPACT_DESC_BASE<"jic", jmpoffset16,
 130                                                      GPR32Opnd> {
 131   bit isBarrier = 1;
 132   list<Register> Defs = [AT];
 133 }
 134
 135 class ALIGN_MMR6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 136                       Operand ImmOpnd>  : MMR6Arch<instr_asm> {
 137   dag OutOperandList = (outs GPROpnd:$rd);
 138   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt, ImmOpnd:$bp);
 139   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt, $bp");
 140   list<dag> Pattern = [];
 141 }
 142
 143 class ALIGN_MMR6_DESC : ALIGN_MMR6_DESC_BASE<"align", GPR32Opnd, uimm2>;
 144
 145 class AUI_MMR6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd>
 146     : MMR6Arch<instr_asm> {
 147   dag OutOperandList = (outs GPROpnd:$rt);
 148   dag InOperandList = (ins GPROpnd:$rs, simm16:$imm);
 149   string AsmString = !strconcat(instr_asm, "\t$rt, $rs, $imm");
 150   list<dag> Pattern = [];
 151 }
 152
 153 class AUI_MMR6_DESC : AUI_MMR6_DESC_BASE<"aui", GPR32Opnd>;
 154
 155 class ALUIPC_MMR6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd>
 156     : MMR6Arch<instr_asm> {
 157   dag OutOperandList = (outs GPROpnd:$rt);
 158   dag InOperandList = (ins simm16:$imm);
 159   string AsmString = !strconcat(instr_asm, "\t$rt, $imm");
 160   list<dag> Pattern = [];
 161 }
 162
 163 class ALUIPC_MMR6_DESC : ALUIPC_MMR6_DESC_BASE<"aluipc", GPR32Opnd>;
 164 class AUIPC_MMR6_DESC : ALUIPC_MMR6_DESC_BASE<"auipc", GPR32Opnd>;
 165
 166 class LSA_MMR6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 167                          Operand ImmOpnd> : MMR6Arch<instr_asm> {
 168   dag OutOperandList = (outs GPROpnd:$rd);
 169   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt, ImmOpnd:$imm2);
 170   string AsmString = !strconcat(instr_asm, "\t$rt, $rs, $rd, $imm2");
 171   list<dag> Pattern = [];
 172 }
 173
 174 class LSA_MMR6_DESC : LSA_MMR6_DESC_BASE<"lsa", GPR32Opnd, uimm2>;
 175
 176 class PCREL_MMR6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 177                            Operand ImmOpnd> : MMR6Arch<instr_asm> {
 178   dag OutOperandList = (outs GPROpnd:$rt);
 179   dag InOperandList = (ins ImmOpnd:$imm);
 180   string AsmString = !strconcat(instr_asm, "\t$rt, $imm");
 181   list<dag> Pattern = [];
 182 }
 183
 184 class ADDIUPC_MMR6_DESC : PCREL_MMR6_DESC_BASE<"addiupc", GPR32Opnd, simm19_lsl2>;
 185 class LWPC_MMR6_DESC: PCREL_MMR6_DESC_BASE<"lwpc", GPR32Opnd, simm19_lsl2>;
 186
 187 class SELEQNE_Z_MMR6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd>
 188     : MMR6Arch<instr_asm> {
 189   dag OutOperandList = (outs GPROpnd:$rd);
 190   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt);
 191   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt");
 192   list<dag> Pattern = [];
 193 }
 194
 195 class SELEQZ_MMR6_DESC : SELEQNE_Z_MMR6_DESC_BASE<"seleqz", GPR32Opnd>;
 196 class SELNEZ_MMR6_DESC : SELEQNE_Z_MMR6_DESC_BASE<"selnez", GPR32Opnd>;
 197 class DIV_MMR6_DESC : ArithLogicR<"div", GPR32Opnd>;
 198 class DIVU_MMR6_DESC : ArithLogicR<"divu", GPR32Opnd>;
 199 class MOD_MMR6_DESC : ArithLogicR<"mod", GPR32Opnd>;
 200 class MODU_MMR6_DESC : ArithLogicR<"modu", GPR32Opnd>;
 201
 202 //===----------------------------------------------------------------------===//
 203 //
 204 // Instruction Definitions
 205 //
 206 //===----------------------------------------------------------------------===//
 207
 208 let DecoderNamespace = "MicroMips32r6" in {
 209 def ADD_MMR6 : StdMMR6Rel, ADD_MMR6_DESC, ADD_MMR6_ENC, ISA_MICROMIPS32R6;
 210 def ADDIU_MMR6 : StdMMR6Rel, ADDIU_MMR6_DESC, ADDIU_MMR6_ENC, ISA_MICROMIPS32R6;
 211 def ADDU_MMR6 : StdMMR6Rel, ADDU_MMR6_DESC, ADDU_MMR6_ENC, ISA_MICROMIPS32R6;
 212 def ADDIUPC_MMR6 : R6MMR6Rel, ADDIUPC_MMR6_ENC, ADDIUPC_MMR6_DESC,
 213                    ISA_MICROMIPS32R6;
 214 def ALUIPC_MMR6 : R6MMR6Rel, ALUIPC_MMR6_ENC, ALUIPC_MMR6_DESC,
 215                   ISA_MICROMIPS32R6;
 216 def AUIPC_MMR6 : R6MMR6Rel, AUIPC_MMR6_ENC, AUIPC_MMR6_DESC, ISA_MICROMIPS32R6;
 217 def ALIGN_MMR6 : R6MMR6Rel, ALIGN_MMR6_ENC, ALIGN_MMR6_DESC, ISA_MICROMIPS32R6;
 218 def AUI_MMR6 : R6MMR6Rel, AUI_MMR6_ENC, AUI_MMR6_DESC, ISA_MICROMIPS32R6;
 219 def BALC_MMR6 : R6MMR6Rel, BALC_MMR6_ENC, BALC_MMR6_DESC, ISA_MICROMIPS32R6;
 220 def BC_MMR6 : R6MMR6Rel, BC_MMR6_ENC, BC_MMR6_DESC, ISA_MICROMIPS32R6;
 221 def BITSWAP_MMR6 : R6MMR6Rel, BITSWAP_MMR6_ENC, BITSWAP_MMR6_DESC,
 222                    ISA_MICROMIPS32R6;
 223 def CACHE_MMR6 : R6MMR6Rel, CACHE_MMR6_ENC, CACHE_MMR6_DESC, ISA_MICROMIPS32R6;
 224 def CLO_MMR6 : R6MMR6Rel, CLO_MMR6_ENC, CLO_MMR6_DESC, ISA_MICROMIPS32R6;
 225 def CLZ_MMR6 : R6MMR6Rel, CLZ_MMR6_ENC, CLZ_MMR6_DESC, ISA_MICROMIPS32R6;
 226 def DIV_MMR6 : R6MMR6Rel, DIV_MMR6_DESC, DIV_MMR6_ENC, ISA_MICROMIPS32R6;
 227 def DIVU_MMR6 : R6MMR6Rel, DIVU_MMR6_DESC, DIVU_MMR6_ENC, ISA_MICROMIPS32R6;
 228 def JIALC_MMR6 : R6MMR6Rel, JIALC_MMR6_ENC, JIALC_MMR6_DESC, ISA_MICROMIPS32R6;
 229 def JIC_MMR6 : R6MMR6Rel, JIC_MMR6_ENC, JIC_MMR6_DESC, ISA_MICROMIPS32R6;
 230 def LSA_MMR6 : R6MMR6Rel, LSA_MMR6_ENC, LSA_MMR6_DESC, ISA_MICROMIPS32R6;
 231 def LWPC_MMR6 : R6MMR6Rel, LWPC_MMR6_ENC, LWPC_MMR6_DESC, ISA_MICROMIPS32R6;
 232 def MOD_MMR6 : R6MMR6Rel, MOD_MMR6_DESC, MOD_MMR6_ENC, ISA_MICROMIPS32R6;
 233 def MODU_MMR6 : R6MMR6Rel, MODU_MMR6_DESC, MODU_MMR6_ENC, ISA_MICROMIPS32R6;
 234 def MUL_MMR6 : R6MMR6Rel, MUL_MMR6_DESC, MUL_MMR6_ENC, ISA_MICROMIPS32R6;
 235 def MUH_MMR6 : R6MMR6Rel, MUH_MMR6_DESC, MUH_MMR6_ENC, ISA_MICROMIPS32R6;
 236 def MULU_MMR6 : R6MMR6Rel, MULU_MMR6_DESC, MULU_MMR6_ENC, ISA_MICROMIPS32R6;
 237 def MUHU_MMR6 : R6MMR6Rel, MUHU_MMR6_DESC, MUHU_MMR6_ENC, ISA_MICROMIPS32R6;
 238 def PREF_MMR6 : R6MMR6Rel, PREF_MMR6_ENC, PREF_MMR6_DESC, ISA_MICROMIPS32R6;
 239 def SELEQZ_MMR6 : R6MMR6Rel, SELEQZ_MMR6_ENC, SELEQZ_MMR6_DESC,
 240                   ISA_MICROMIPS32R6;
 241 def SELNEZ_MMR6 : R6MMR6Rel, SELNEZ_MMR6_ENC, SELNEZ_MMR6_DESC,
 242                   ISA_MICROMIPS32R6;
 243 def SUB_MMR6 : StdMMR6Rel, SUB_MMR6_DESC, SUB_MMR6_ENC, ISA_MICROMIPS32R6;
 244 def SUBU_MMR6 : StdMMR6Rel, SUBU_MMR6_DESC, SUBU_MMR6_ENC, ISA_MICROMIPS32R6;
 245 }