lib/Target/Hexagon/HexagonInstrInfo.td

   1 //==- HexagonInstrInfo.td - Target Description for Hexagon -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Hexagon instructions in TableGen format.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "HexagonInstrFormats.td"
  15 include "HexagonOperands.td"
  16
  17 // Pattern fragment that combines the value type and the register class
  18 // into a single parameter.
  19 // The pat frags in the definitions below need to have a named register,
  20 // otherwise i32 will be assumed regardless of the register class. The
  21 // name of the register does not matter.
  22 def I1  : PatLeaf<(i1 PredRegs:$R)>;
  23 def I32 : PatLeaf<(i32 IntRegs:$R)>;
  24 def I64 : PatLeaf<(i64 DoubleRegs:$R)>;
  25 def F32 : PatLeaf<(f32 IntRegs:$R)>;
  26 def F64 : PatLeaf<(f64 DoubleRegs:$R)>;
  27
  28 // Pattern fragments to extract the low and high subregisters from a
  29 // 64-bit value.
  30 def LoReg: OutPatFrag<(ops node:$Rs),
  31                       (EXTRACT_SUBREG (i64 $Rs), subreg_loreg)>;
  32
  33 //===----------------------------------------------------------------------===//
  34
  35 //===----------------------------------------------------------------------===//
  36 // Compare
  37 //===----------------------------------------------------------------------===//
  38 let hasSideEffects = 0, isCompare = 1, InputType = "imm", isExtendable = 1,
  39     opExtendable = 2 in
  40 class T_CMP <string mnemonic, bits<2> MajOp, bit isNot, Operand ImmOp>
  41   : ALU32Inst <(outs PredRegs:$dst),
  42                (ins IntRegs:$src1, ImmOp:$src2),
  43   "$dst = "#!if(isNot, "!","")#mnemonic#"($src1, #$src2)",
  44   [], "",ALU32_2op_tc_2early_SLOT0123 >, ImmRegRel {
  45     bits<2> dst;
  46     bits<5> src1;
  47     bits<10> src2;
  48     let CextOpcode = mnemonic;
  49     let opExtentBits  = !if(!eq(mnemonic, "cmp.gtu"), 9, 10);
  50     let isExtentSigned = !if(!eq(mnemonic, "cmp.gtu"), 0, 1);
  51
  52     let IClass = 0b0111;
  53
  54     let Inst{27-24} = 0b0101;
  55     let Inst{23-22} = MajOp;
  56     let Inst{21}    = !if(!eq(mnemonic, "cmp.gtu"), 0, src2{9});
  57     let Inst{20-16} = src1;
  58     let Inst{13-5}  = src2{8-0};
  59     let Inst{4}     = isNot;
  60     let Inst{3-2}   = 0b00;
  61     let Inst{1-0}   = dst;
  62   }
  63
  64 def C2_cmpeqi   : T_CMP <"cmp.eq",  0b00, 0, s10Ext>;
  65 def C2_cmpgti   : T_CMP <"cmp.gt",  0b01, 0, s10Ext>;
  66 def C2_cmpgtui  : T_CMP <"cmp.gtu", 0b10, 0, u9Ext>;
  67
  68 class T_CMP_pat <InstHexagon MI, PatFrag OpNode, PatLeaf ImmPred>
  69   : Pat<(i1 (OpNode (i32 IntRegs:$src1), ImmPred:$src2)),
  70         (MI IntRegs:$src1, ImmPred:$src2)>;
  71
  72 def : T_CMP_pat <C2_cmpeqi,  seteq,  s10ImmPred>;
  73 def : T_CMP_pat <C2_cmpgti,  setgt,  s10ImmPred>;
  74 def : T_CMP_pat <C2_cmpgtui, setugt, u9ImmPred>;
  75
  76 //===----------------------------------------------------------------------===//
  77 // ALU32/ALU +
  78 //===----------------------------------------------------------------------===//
  79 def SDTHexagonI64I32I32 : SDTypeProfile<1, 2,
  80   [SDTCisVT<0, i64>, SDTCisVT<1, i32>, SDTCisSameAs<1, 2>]>;
  81
  82 def HexagonCOMBINE : SDNode<"HexagonISD::COMBINE", SDTHexagonI64I32I32>;
  83
  84 let hasSideEffects = 0, hasNewValue = 1, InputType = "reg" in
  85 class T_ALU32_3op<string mnemonic, bits<3> MajOp, bits<3> MinOp, bit OpsRev,
  86                   bit IsComm>
  87   : ALU32_rr<(outs IntRegs:$Rd), (ins IntRegs:$Rs, IntRegs:$Rt),
  88              "$Rd = "#mnemonic#"($Rs, $Rt)",
  89              [], "", ALU32_3op_tc_1_SLOT0123>, ImmRegRel, PredRel {
  90   let isCommutable = IsComm;
  91   let BaseOpcode = mnemonic#_rr;
  92   let CextOpcode = mnemonic;
  93
  94   bits<5> Rs;
  95   bits<5> Rt;
  96   bits<5> Rd;
  97
  98   let IClass = 0b1111;
  99   let Inst{27} = 0b0;
 100   let Inst{26-24} = MajOp;
 101   let Inst{23-21} = MinOp;
 102   let Inst{20-16} = !if(OpsRev,Rt,Rs);
 103   let Inst{12-8} = !if(OpsRev,Rs,Rt);
 104   let Inst{4-0} = Rd;
 105 }
 106
 107 let hasSideEffects = 0, hasNewValue = 1 in
 108 class T_ALU32_3op_pred<string mnemonic, bits<3> MajOp, bits<3> MinOp,
 109                        bit OpsRev, bit PredNot, bit PredNew>
 110   : ALU32_rr<(outs IntRegs:$Rd), (ins PredRegs:$Pu, IntRegs:$Rs, IntRegs:$Rt),
 111              "if ("#!if(PredNot,"!","")#"$Pu"#!if(PredNew,".new","")#") "#
 112              "$Rd = "#mnemonic#"($Rs, $Rt)",
 113              [], "", ALU32_3op_tc_1_SLOT0123>, ImmRegRel, PredNewRel {
 114   let isPredicated = 1;
 115   let isPredicatedFalse = PredNot;
 116   let isPredicatedNew = PredNew;
 117   let BaseOpcode = mnemonic#_rr;
 118   let CextOpcode = mnemonic;
 119
 120   bits<2> Pu;
 121   bits<5> Rs;
 122   bits<5> Rt;
 123   bits<5> Rd;
 124
 125   let IClass = 0b1111;
 126   let Inst{27} = 0b1;
 127   let Inst{26-24} = MajOp;
 128   let Inst{23-21} = MinOp;
 129   let Inst{20-16} = !if(OpsRev,Rt,Rs);
 130   let Inst{13} = PredNew;
 131   let Inst{12-8} = !if(OpsRev,Rs,Rt);
 132   let Inst{7} = PredNot;
 133   let Inst{6-5} = Pu;
 134   let Inst{4-0} = Rd;
 135 }
 136
 137 class T_ALU32_combineh<string Op1, string Op2, bits<3> MajOp, bits<3> MinOp,
 138                       bit OpsRev>
 139   : T_ALU32_3op<"", MajOp, MinOp, OpsRev, 0> {
 140   let AsmString = "$Rd = combine($Rs"#Op1#", $Rt"#Op2#")";
 141 }
 142
 143 let isCodeGenOnly = 0 in {
 144 def A2_combine_hh : T_ALU32_combineh<".h", ".h", 0b011, 0b100, 1>;
 145 def A2_combine_hl : T_ALU32_combineh<".h", ".l", 0b011, 0b101, 1>;
 146 def A2_combine_lh : T_ALU32_combineh<".l", ".h", 0b011, 0b110, 1>;
 147 def A2_combine_ll : T_ALU32_combineh<".l", ".l", 0b011, 0b111, 1>;
 148 }
 149
 150 class T_ALU32_3op_sfx<string mnemonic, string suffix, bits<3> MajOp,
 151                       bits<3> MinOp, bit OpsRev, bit IsComm>
 152   : T_ALU32_3op<"", MajOp, MinOp, OpsRev, IsComm> {
 153   let AsmString = "$Rd = "#mnemonic#"($Rs, $Rt)"#suffix;
 154 }
 155
 156 let Defs = [USR_OVF], Itinerary = ALU32_3op_tc_2_SLOT0123,
 157     isCodeGenOnly = 0 in {
 158   def A2_addsat   : T_ALU32_3op_sfx<"add",    ":sat", 0b110, 0b010, 0, 1>;
 159   def A2_subsat   : T_ALU32_3op_sfx<"sub",    ":sat", 0b110, 0b110, 1, 0>;
 160 }
 161
 162 multiclass T_ALU32_3op_p<string mnemonic, bits<3> MajOp, bits<3> MinOp,
 163                          bit OpsRev> {
 164   def t    : T_ALU32_3op_pred<mnemonic, MajOp, MinOp, OpsRev, 0, 0>;
 165   def f    : T_ALU32_3op_pred<mnemonic, MajOp, MinOp, OpsRev, 1, 0>;
 166   def tnew : T_ALU32_3op_pred<mnemonic, MajOp, MinOp, OpsRev, 0, 1>;
 167   def fnew : T_ALU32_3op_pred<mnemonic, MajOp, MinOp, OpsRev, 1, 1>;
 168 }
 169
 170 multiclass T_ALU32_3op_A2<string mnemonic, bits<3> MajOp, bits<3> MinOp,
 171                           bit OpsRev, bit IsComm> {
 172   let isPredicable = 1 in
 173   def  A2_#NAME  : T_ALU32_3op  <mnemonic, MajOp, MinOp, OpsRev, IsComm>;
 174   defm A2_p#NAME : T_ALU32_3op_p<mnemonic, MajOp, MinOp, OpsRev>;
 175 }
 176
 177 let isCodeGenOnly = 0 in {
 178 defm add : T_ALU32_3op_A2<"add", 0b011, 0b000, 0, 1>;
 179 defm and : T_ALU32_3op_A2<"and", 0b001, 0b000, 0, 1>;
 180 defm or  : T_ALU32_3op_A2<"or",  0b001, 0b001, 0, 1>;
 181 defm sub : T_ALU32_3op_A2<"sub", 0b011, 0b001, 1, 0>;
 182 defm xor : T_ALU32_3op_A2<"xor", 0b001, 0b011, 0, 1>;
 183 }
 184
 185 // Pats for instruction selection.
 186 class BinOp32_pat<SDNode Op, InstHexagon MI, ValueType ResT>
 187   : Pat<(ResT (Op (i32 IntRegs:$Rs), (i32 IntRegs:$Rt))),
 188         (ResT (MI IntRegs:$Rs, IntRegs:$Rt))>;
 189
 190 def: BinOp32_pat<add, A2_add, i32>;
 191 def: BinOp32_pat<and, A2_and, i32>;
 192 def: BinOp32_pat<or,  A2_or,  i32>;
 193 def: BinOp32_pat<sub, A2_sub, i32>;
 194 def: BinOp32_pat<xor, A2_xor, i32>;
 195
 196 // A few special cases producing register pairs:
 197 let OutOperandList = (outs DoubleRegs:$Rd), hasNewValue = 0,
 198     isCodeGenOnly = 0 in {
 199   def S2_packhl    : T_ALU32_3op  <"packhl",  0b101, 0b100, 0, 0>;
 200
 201   let isPredicable = 1 in
 202     def A2_combinew  : T_ALU32_3op  <"combine", 0b101, 0b000, 0, 0>;
 203
 204   // Conditional combinew uses "newt/f" instead of "t/fnew".
 205   def C2_ccombinewt    : T_ALU32_3op_pred<"combine", 0b101, 0b000, 0, 0, 0>;
 206   def C2_ccombinewf    : T_ALU32_3op_pred<"combine", 0b101, 0b000, 0, 1, 0>;
 207   def C2_ccombinewnewt : T_ALU32_3op_pred<"combine", 0b101, 0b000, 0, 0, 1>;
 208   def C2_ccombinewnewf : T_ALU32_3op_pred<"combine", 0b101, 0b000, 0, 1, 1>;
 209 }
 210
 211 let hasSideEffects = 0, hasNewValue = 1, isCompare = 1, InputType = "reg"  in
 212 class T_ALU32_3op_cmp<string mnemonic, bits<2> MinOp, bit IsNeg, bit IsComm>
 213   : ALU32_rr<(outs PredRegs:$Pd), (ins IntRegs:$Rs, IntRegs:$Rt),
 214              "$Pd = "#mnemonic#"($Rs, $Rt)",
 215              [], "", ALU32_3op_tc_1_SLOT0123>, ImmRegRel {
 216   let CextOpcode = mnemonic;
 217   let isCommutable = IsComm;
 218   bits<5> Rs;
 219   bits<5> Rt;
 220   bits<2> Pd;
 221
 222   let IClass = 0b1111;
 223   let Inst{27-24} = 0b0010;
 224   let Inst{22-21} = MinOp;
 225   let Inst{20-16} = Rs;
 226   let Inst{12-8} = Rt;
 227   let Inst{4} = IsNeg;
 228   let Inst{3-2} = 0b00;
 229   let Inst{1-0} = Pd;
 230 }
 231
 232 let Itinerary = ALU32_3op_tc_2early_SLOT0123, isCodeGenOnly = 0 in {
 233   def C2_cmpeq   : T_ALU32_3op_cmp< "cmp.eq",  0b00, 0, 1>;
 234   def C2_cmpgt   : T_ALU32_3op_cmp< "cmp.gt",  0b10, 0, 0>;
 235   def C2_cmpgtu  : T_ALU32_3op_cmp< "cmp.gtu", 0b11, 0, 0>;
 236 }
 237
 238 // Patfrag to convert the usual comparison patfrags (e.g. setlt) to ones
 239 // that reverse the order of the operands.
 240 class RevCmp<PatFrag F> : PatFrag<(ops node:$rhs, node:$lhs), F.Fragment>;
 241
 242 // Pats for compares. They use PatFrags as operands, not SDNodes,
 243 // since seteq/setgt/etc. are defined as ParFrags.
 244 class T_cmp32_rr_pat<InstHexagon MI, PatFrag Op, ValueType VT>
 245   : Pat<(VT (Op (i32 IntRegs:$Rs), (i32 IntRegs:$Rt))),
 246         (VT (MI IntRegs:$Rs, IntRegs:$Rt))>;
 247
 248 def: T_cmp32_rr_pat<C2_cmpeq,  seteq, i1>;
 249 def: T_cmp32_rr_pat<C2_cmpgt,  setgt, i1>;
 250 def: T_cmp32_rr_pat<C2_cmpgtu, setugt, i1>;
 251
 252 def: T_cmp32_rr_pat<C2_cmpgt,  RevCmp<setlt>,  i1>;
 253 def: T_cmp32_rr_pat<C2_cmpgtu, RevCmp<setult>, i1>;
 254
 255 let CextOpcode = "MUX", InputType = "reg", hasNewValue = 1,
 256   isCodeGenOnly = 0 in
 257 def C2_mux: ALU32_rr<(outs IntRegs:$Rd),
 258                      (ins PredRegs:$Pu, IntRegs:$Rs, IntRegs:$Rt),
 259       "$Rd = mux($Pu, $Rs, $Rt)", [], "", ALU32_3op_tc_1_SLOT0123>, ImmRegRel {
 260   bits<5> Rd;
 261   bits<2> Pu;
 262   bits<5> Rs;
 263   bits<5> Rt;
 264
 265   let CextOpcode = "mux";
 266   let InputType = "reg";
 267   let hasSideEffects = 0;
 268   let IClass = 0b1111;
 269
 270   let Inst{27-24} = 0b0100;
 271   let Inst{20-16} = Rs;
 272   let Inst{12-8} = Rt;
 273   let Inst{6-5} = Pu;
 274   let Inst{4-0} = Rd;
 275 }
 276
 277 def: Pat<(i32 (select (i1 PredRegs:$Pu), (i32 IntRegs:$Rs), (i32 IntRegs:$Rt))),
 278          (C2_mux PredRegs:$Pu, IntRegs:$Rs, IntRegs:$Rt)>;
 279
 280 // Combines the two immediates into a double register.
 281 // Increase complexity to make it greater than any complexity of a combine
 282 // that involves a register.
 283
 284 let isReMaterializable = 1, isMoveImm = 1, isAsCheapAsAMove = 1,
 285     isExtentSigned = 1, isExtendable = 1, opExtentBits = 8, opExtendable = 1,
 286     AddedComplexity = 75, isCodeGenOnly = 0 in
 287 def A2_combineii: ALU32Inst <(outs DoubleRegs:$Rdd), (ins s8Ext:$s8, s8Imm:$S8),
 288   "$Rdd = combine(#$s8, #$S8)",
 289   [(set (i64 DoubleRegs:$Rdd),
 290         (i64 (HexagonCOMBINE(i32 s8ExtPred:$s8), (i32 s8ImmPred:$S8))))]> {
 291     bits<5> Rdd;
 292     bits<8> s8;
 293     bits<8> S8;
 294
 295     let IClass = 0b0111;
 296     let Inst{27-23} = 0b11000;
 297     let Inst{22-16} = S8{7-1};
 298     let Inst{13}    = S8{0};
 299     let Inst{12-5}  = s8;
 300     let Inst{4-0}   = Rdd;
 301   }
 302
 303 //===----------------------------------------------------------------------===//
 304 // Template class for predicated ADD of a reg and an Immediate value.
 305 //===----------------------------------------------------------------------===//
 306 let hasNewValue = 1 in
 307 class T_Addri_Pred <bit PredNot, bit PredNew>
 308   : ALU32_ri <(outs IntRegs:$Rd),
 309               (ins PredRegs:$Pu, IntRegs:$Rs, s8Ext:$s8),
 310   !if(PredNot, "if (!$Pu", "if ($Pu")#!if(PredNew,".new) $Rd = ",
 311   ") $Rd = ")#"add($Rs, #$s8)"> {
 312     bits<5> Rd;
 313     bits<2> Pu;
 314     bits<5> Rs;
 315     bits<8> s8;
 316
 317     let isPredicatedNew = PredNew;
 318     let IClass = 0b0111;
 319
 320     let Inst{27-24} = 0b0100;
 321     let Inst{23}    = PredNot;
 322     let Inst{22-21} = Pu;
 323     let Inst{20-16} = Rs;
 324     let Inst{13}    = PredNew;
 325     let Inst{12-5}  = s8;
 326     let Inst{4-0}   = Rd;
 327   }
 328
 329 //===----------------------------------------------------------------------===//
 330 // A2_addi: Add a signed immediate to a register.
 331 //===----------------------------------------------------------------------===//
 332 let hasNewValue = 1 in
 333 class T_Addri <Operand immOp, list<dag> pattern = [] >
 334   : ALU32_ri <(outs IntRegs:$Rd),
 335               (ins IntRegs:$Rs, immOp:$s16),
 336   "$Rd = add($Rs, #$s16)", pattern,
 337   //[(set (i32 IntRegs:$Rd), (add (i32 IntRegs:$Rs), (s16ExtPred:$s16)))],
 338   "", ALU32_ADDI_tc_1_SLOT0123> {
 339     bits<5> Rd;
 340     bits<5> Rs;
 341     bits<16> s16;
 342
 343     let IClass = 0b1011;
 344
 345     let Inst{27-21} = s16{15-9};
 346     let Inst{20-16} = Rs;
 347     let Inst{13-5}  = s16{8-0};
 348     let Inst{4-0}   = Rd;
 349   }
 350
 351 //===----------------------------------------------------------------------===//
 352 // Multiclass for ADD of a register and an immediate value.
 353 //===----------------------------------------------------------------------===//
 354 multiclass Addri_Pred<string mnemonic, bit PredNot> {
 355   let isPredicatedFalse = PredNot in {
 356     def _c#NAME : T_Addri_Pred<PredNot, 0>;
 357     // Predicate new
 358     def _cdn#NAME : T_Addri_Pred<PredNot, 1>;
 359   }
 360 }
 361
 362 let isExtendable = 1, InputType = "imm" in
 363 multiclass Addri_base<string mnemonic, SDNode OpNode> {
 364   let CextOpcode = mnemonic, BaseOpcode = mnemonic#_ri in {
 365     let opExtendable = 2, isExtentSigned = 1, opExtentBits = 16,
 366     isPredicable = 1 in
 367     def NAME : T_Addri< s16Ext, // Rd=add(Rs,#s16)
 368                         [(set (i32 IntRegs:$Rd),
 369                               (add IntRegs:$Rs, s16ExtPred:$s16))]>;
 370
 371     let opExtendable = 3, isExtentSigned = 1, opExtentBits = 8,
 372     hasSideEffects = 0, isPredicated = 1 in {
 373       defm Pt : Addri_Pred<mnemonic, 0>;
 374       defm NotPt : Addri_Pred<mnemonic, 1>;
 375     }
 376   }
 377 }
 378
 379 let isCodeGenOnly = 0 in
 380 defm ADD_ri : Addri_base<"add", add>, ImmRegRel, PredNewRel;
 381
 382 //===----------------------------------------------------------------------===//
 383 // Template class used for the following ALU32 instructions.
 384 // Rd=and(Rs,#s10)
 385 // Rd=or(Rs,#s10)
 386 //===----------------------------------------------------------------------===//
 387 let isExtendable = 1, opExtendable = 2, isExtentSigned = 1, opExtentBits = 10,
 388 InputType = "imm", hasNewValue = 1 in
 389 class T_ALU32ri_logical <string mnemonic, SDNode OpNode, bits<2> MinOp>
 390   : ALU32_ri <(outs IntRegs:$Rd),
 391               (ins IntRegs:$Rs, s10Ext:$s10),
 392   "$Rd = "#mnemonic#"($Rs, #$s10)" ,
 393   [(set (i32 IntRegs:$Rd), (OpNode (i32 IntRegs:$Rs), s10ExtPred:$s10))]> {
 394     bits<5> Rd;
 395     bits<5> Rs;
 396     bits<10> s10;
 397     let CextOpcode = mnemonic;
 398
 399     let IClass = 0b0111;
 400
 401     let Inst{27-24} = 0b0110;
 402     let Inst{23-22} = MinOp;
 403     let Inst{21}    = s10{9};
 404     let Inst{20-16} = Rs;
 405     let Inst{13-5}  = s10{8-0};
 406     let Inst{4-0}   = Rd;
 407   }
 408
 409 let isCodeGenOnly = 0 in {
 410 def OR_ri  : T_ALU32ri_logical<"or", or, 0b10>, ImmRegRel;
 411 def AND_ri : T_ALU32ri_logical<"and", and, 0b00>, ImmRegRel;
 412 }
 413
 414 // Subtract register from immediate
 415 // Rd32=sub(#s10,Rs32)
 416 let isExtendable = 1, opExtendable = 1, isExtentSigned = 1, opExtentBits = 10,
 417 CextOpcode = "sub", InputType = "imm", hasNewValue = 1, isCodeGenOnly = 0 in
 418 def SUB_ri: ALU32_ri <(outs IntRegs:$Rd), (ins s10Ext:$s10, IntRegs:$Rs),
 419   "$Rd = sub(#$s10, $Rs)" ,
 420   [(set IntRegs:$Rd, (sub s10ExtPred:$s10, IntRegs:$Rs))] > ,
 421   ImmRegRel {
 422     bits<5> Rd;
 423     bits<10> s10;
 424     bits<5> Rs;
 425
 426     let IClass = 0b0111;
 427
 428     let Inst{27-22} = 0b011001;
 429     let Inst{21}    = s10{9};
 430     let Inst{20-16} = Rs;
 431     let Inst{13-5}  = s10{8-0};
 432     let Inst{4-0}   = Rd;
 433   }
 434
 435 // Nop.
 436 let hasSideEffects = 0, isCodeGenOnly = 0 in
 437 def A2_nop: ALU32Inst <(outs), (ins), "nop" > {
 438   let IClass = 0b0111;
 439   let Inst{27-24} = 0b1111;
 440 }
 441 // Rd = not(Rs) gets mapped to Rd=sub(#-1, Rs).
 442 def : Pat<(not (i32 IntRegs:$src1)),
 443           (SUB_ri -1, (i32 IntRegs:$src1))>;
 444
 445 let hasSideEffects = 0, hasNewValue = 1 in
 446 class T_tfr16<bit isHi>
 447   : ALU32Inst <(outs IntRegs:$Rx), (ins IntRegs:$src1, u16Imm:$u16),
 448   "$Rx"#!if(isHi, ".h", ".l")#" = #$u16",
 449   [], "$src1 = $Rx" > {
 450     bits<5> Rx;
 451     bits<16> u16;
 452
 453     let IClass = 0b0111;
 454     let Inst{27-26} = 0b00;
 455     let Inst{25-24} = !if(isHi, 0b10, 0b01);
 456     let Inst{23-22} = u16{15-14};
 457     let Inst{21}    = 0b1;
 458     let Inst{20-16} = Rx;
 459     let Inst{13-0}  = u16{13-0};
 460   }
 461
 462 let isCodeGenOnly = 0 in {
 463 def A2_tfril: T_tfr16<0>;
 464 def A2_tfrih: T_tfr16<1>;
 465 }
 466
 467 // Conditional transfer is an alias to conditional "Rd = add(Rs, #0)".
 468 let isPredicated = 1, hasNewValue = 1, opNewValue = 0 in
 469 class T_tfr_pred<bit isPredNot, bit isPredNew>
 470   : ALU32Inst<(outs IntRegs:$dst),
 471               (ins PredRegs:$src1, IntRegs:$src2),
 472               "if ("#!if(isPredNot, "!", "")#
 473               "$src1"#!if(isPredNew, ".new", "")#
 474               ") $dst = $src2"> {
 475     bits<5> dst;
 476     bits<2> src1;
 477     bits<5> src2;
 478
 479     let isPredicatedFalse = isPredNot;
 480     let isPredicatedNew = isPredNew;
 481     let IClass = 0b0111;
 482
 483     let Inst{27-24} = 0b0100;
 484     let Inst{23} = isPredNot;
 485     let Inst{13} = isPredNew;
 486     let Inst{12-5} = 0;
 487     let Inst{4-0} = dst;
 488     let Inst{22-21} = src1;
 489     let Inst{20-16} = src2;
 490   }
 491
 492 let isPredicable = 1 in
 493 class T_tfr : ALU32Inst<(outs IntRegs:$dst), (ins IntRegs:$src),
 494               "$dst = $src"> {
 495     bits<5> dst;
 496     bits<5> src;
 497
 498     let IClass = 0b0111;
 499
 500     let Inst{27-21} = 0b0000011;
 501     let Inst{20-16} = src;
 502     let Inst{13}    = 0b0;
 503     let Inst{4-0}   = dst;
 504   }
 505
 506 let InputType = "reg", hasNewValue = 1, hasSideEffects = 0 in
 507 multiclass tfr_base<string CextOp> {
 508   let CextOpcode = CextOp, BaseOpcode = CextOp in {
 509     def NAME : T_tfr;
 510
 511     // Predicate
 512     def t : T_tfr_pred<0, 0>;
 513     def f : T_tfr_pred<1, 0>;
 514     // Predicate new
 515     def tnew : T_tfr_pred<0, 1>;
 516     def fnew : T_tfr_pred<1, 1>;
 517   }
 518 }
 519
 520 // Assembler mapped to C2_ccombinew[t|f|newt|newf].
 521 // Please don't add bits to this instruction as it'll be converted into
 522 // 'combine' before object code emission.
 523 let isPredicated = 1 in
 524 class T_tfrp_pred<bit PredNot, bit PredNew>
 525   : ALU32_rr <(outs DoubleRegs:$dst),
 526               (ins PredRegs:$src1, DoubleRegs:$src2),
 527   "if ("#!if(PredNot, "!", "")#"$src1"
 528         #!if(PredNew, ".new", "")#") $dst = $src2" > {
 529     let isPredicatedFalse = PredNot;
 530     let isPredicatedNew = PredNew;
 531   }
 532
 533 // Assembler mapped to A2_combinew.
 534 // Please don't add bits to this instruction as it'll be converted into
 535 // 'combine' before object code emission.
 536 class T_tfrp : ALU32Inst <(outs DoubleRegs:$dst),
 537                (ins DoubleRegs:$src),
 538     "$dst = $src">;
 539
 540 let hasSideEffects = 0 in
 541 multiclass TFR64_base<string BaseName> {
 542   let BaseOpcode = BaseName in {
 543     let isPredicable = 1 in
 544     def NAME : T_tfrp;
 545     // Predicate
 546     def t : T_tfrp_pred <0, 0>;
 547     def f : T_tfrp_pred <1, 0>;
 548     // Predicate new
 549     def tnew : T_tfrp_pred <0, 1>;
 550     def fnew : T_tfrp_pred <1, 1>;
 551   }
 552 }
 553
 554 let InputType = "imm", isExtendable = 1, isExtentSigned = 1, opExtentBits = 12,
 555     isMoveImm = 1, opExtendable = 2, BaseOpcode = "TFRI", CextOpcode = "TFR",
 556     hasSideEffects = 0, isPredicated = 1, hasNewValue = 1 in
 557 class T_TFRI_Pred<bit PredNot, bit PredNew>
 558   : ALU32_ri<(outs IntRegs:$Rd), (ins PredRegs:$Pu, s12Ext:$s12),
 559     "if ("#!if(PredNot,"!","")#"$Pu"#!if(PredNew,".new","")#") $Rd = #$s12",
 560     [], "", ALU32_2op_tc_1_SLOT0123>, ImmRegRel, PredNewRel {
 561   let isPredicatedFalse = PredNot;
 562   let isPredicatedNew = PredNew;
 563
 564   bits<5> Rd;
 565   bits<2> Pu;
 566   bits<12> s12;
 567
 568   let IClass = 0b0111;
 569   let Inst{27-24} = 0b1110;
 570   let Inst{23} = PredNot;
 571   let Inst{22-21} = Pu;
 572   let Inst{20} = 0b0;
 573   let Inst{19-16,12-5} = s12;
 574   let Inst{13} = PredNew;
 575   let Inst{4-0} = Rd;
 576 }
 577
 578 let isCodeGenOnly = 0 in {
 579 def C2_cmoveit    : T_TFRI_Pred<0, 0>;
 580 def C2_cmoveif    : T_TFRI_Pred<1, 0>;
 581 def C2_cmovenewit : T_TFRI_Pred<0, 1>;
 582 def C2_cmovenewif : T_TFRI_Pred<1, 1>;
 583 }
 584
 585 let InputType = "imm", isExtendable = 1, isExtentSigned = 1,
 586     CextOpcode = "TFR", BaseOpcode = "TFRI", hasNewValue = 1, opNewValue = 0,
 587     isAsCheapAsAMove = 1 , opExtendable = 1, opExtentBits = 16, isMoveImm = 1,
 588     isPredicated = 0, isPredicable = 1, isReMaterializable = 1,
 589     isCodeGenOnly = 0 in
 590 def A2_tfrsi : ALU32Inst<(outs IntRegs:$Rd), (ins s16Ext:$s16), "$Rd = #$s16",
 591     [(set (i32 IntRegs:$Rd), s16ExtPred:$s16)], "", ALU32_2op_tc_1_SLOT0123>,
 592     ImmRegRel, PredRel {
 593   bits<5> Rd;
 594   bits<16> s16;
 595
 596   let IClass = 0b0111;
 597   let Inst{27-24} = 0b1000;
 598   let Inst{23-22,20-16,13-5} = s16;
 599   let Inst{4-0} = Rd;
 600 }
 601
 602 let isCodeGenOnly = 0 in
 603 defm A2_tfr  : tfr_base<"TFR">, ImmRegRel, PredNewRel;
 604 defm A2_tfrp : TFR64_base<"TFR64">, PredNewRel;
 605
 606 // Assembler mapped
 607 let isReMaterializable = 1, isMoveImm = 1, isAsCheapAsAMove = 1 in
 608 def A2_tfrpi : ALU64_rr<(outs DoubleRegs:$dst), (ins s8Imm64:$src1),
 609                       "$dst = #$src1",
 610                       [(set (i64 DoubleRegs:$dst), s8Imm64Pred:$src1)]>;
 611
 612 // TODO: see if this instruction can be deleted..
 613 let isExtendable = 1, opExtendable = 1, opExtentBits = 6 in
 614 def TFRI64_V4 : ALU64_rr<(outs DoubleRegs:$dst), (ins u6Ext:$src1),
 615                          "$dst = #$src1">;
 616
 617 //===----------------------------------------------------------------------===//
 618 // ALU32/ALU -
 619 //===----------------------------------------------------------------------===//
 620
 621
 622 //===----------------------------------------------------------------------===//
 623 // ALU32/PERM +
 624 //===----------------------------------------------------------------------===//
 625 // Scalar mux register immediate.
 626 let hasSideEffects = 0, isExtentSigned = 1, CextOpcode = "MUX",
 627     InputType = "imm", hasNewValue = 1, isExtendable = 1, opExtentBits = 8 in
 628 class T_MUX1 <bit MajOp, dag ins, string AsmStr>
 629       : ALU32Inst <(outs IntRegs:$Rd), ins, AsmStr>, ImmRegRel {
 630   bits<5> Rd;
 631   bits<2> Pu;
 632   bits<8> s8;
 633   bits<5> Rs;
 634
 635   let IClass = 0b0111;
 636   let Inst{27-24} = 0b0011;
 637   let Inst{23} = MajOp;
 638   let Inst{22-21} = Pu;
 639   let Inst{20-16} = Rs;
 640   let Inst{13}    = 0b0;
 641   let Inst{12-5}  = s8;
 642   let Inst{4-0}   = Rd;
 643 }
 644
 645 let opExtendable = 2, isCodeGenOnly = 0 in
 646 def C2_muxri : T_MUX1<0b1, (ins PredRegs:$Pu, s8Ext:$s8, IntRegs:$Rs),
 647                            "$Rd = mux($Pu, #$s8, $Rs)">;
 648
 649 let opExtendable = 3, isCodeGenOnly = 0 in
 650 def C2_muxir : T_MUX1<0b0, (ins PredRegs:$Pu, IntRegs:$Rs, s8Ext:$s8),
 651                            "$Rd = mux($Pu, $Rs, #$s8)">;
 652
 653 def : Pat<(i32 (select I1:$Pu, s8ExtPred:$s8, I32:$Rs)),
 654           (C2_muxri I1:$Pu, s8ExtPred:$s8, I32:$Rs)>;
 655
 656 def : Pat<(i32 (select I1:$Pu, I32:$Rs, s8ExtPred:$s8)),
 657           (C2_muxir I1:$Pu, I32:$Rs, s8ExtPred:$s8)>;
 658
 659 // C2_muxii: Scalar mux immediates.
 660 let isExtentSigned = 1, hasNewValue = 1, isExtendable = 1,
 661     opExtentBits = 8, opExtendable = 2, isCodeGenOnly = 0 in
 662 def C2_muxii: ALU32Inst <(outs IntRegs:$Rd),
 663                          (ins PredRegs:$Pu, s8Ext:$s8, s8Imm:$S8),
 664   "$Rd = mux($Pu, #$s8, #$S8)" ,
 665   [(set (i32 IntRegs:$Rd),
 666         (i32 (select I1:$Pu, s8ExtPred:$s8, s8ImmPred:$S8)))] > {
 667     bits<5> Rd;
 668     bits<2> Pu;
 669     bits<8> s8;
 670     bits<8> S8;
 671
 672     let IClass = 0b0111;
 673
 674     let Inst{27-25} = 0b101;
 675     let Inst{24-23} = Pu;
 676     let Inst{22-16} = S8{7-1};
 677     let Inst{13}    = S8{0};
 678     let Inst{12-5}  = s8;
 679     let Inst{4-0}   = Rd;
 680   }
 681
 682 //===----------------------------------------------------------------------===//
 683 // template class for non-predicated alu32_2op instructions
 684 // - aslh, asrh, sxtb, sxth, zxth
 685 //===----------------------------------------------------------------------===//
 686 let hasNewValue = 1, opNewValue = 0 in
 687 class T_ALU32_2op <string mnemonic, bits<3> minOp> :
 688     ALU32Inst < (outs IntRegs:$Rd), (ins IntRegs:$Rs),
 689     "$Rd = "#mnemonic#"($Rs)", [] > {
 690   bits<5> Rd;
 691   bits<5> Rs;
 692
 693   let IClass = 0b0111;
 694
 695   let Inst{27-24} = 0b0000;
 696   let Inst{23-21} = minOp;
 697   let Inst{13} = 0b0;
 698   let Inst{4-0} = Rd;
 699   let Inst{20-16} = Rs;
 700 }
 701
 702 //===----------------------------------------------------------------------===//
 703 // template class for predicated alu32_2op instructions
 704 // - aslh, asrh, sxtb, sxth, zxtb, zxth
 705 //===----------------------------------------------------------------------===//
 706 let hasSideEffects = 0, validSubTargets = HasV4SubT,
 707     hasNewValue = 1, opNewValue = 0 in
 708 class T_ALU32_2op_Pred <string mnemonic, bits<3> minOp, bit isPredNot,
 709     bit isPredNew > :
 710     ALU32Inst <(outs IntRegs:$Rd), (ins PredRegs:$Pu, IntRegs:$Rs),
 711     !if(isPredNot, "if (!$Pu", "if ($Pu")
 712     #!if(isPredNew, ".new) ",") ")#"$Rd = "#mnemonic#"($Rs)"> {
 713   bits<5> Rd;
 714   bits<2> Pu;
 715   bits<5> Rs;
 716
 717   let IClass = 0b0111;
 718
 719   let Inst{27-24} = 0b0000;
 720   let Inst{23-21} = minOp;
 721   let Inst{13} = 0b1;
 722   let Inst{11} = isPredNot;
 723   let Inst{10} = isPredNew;
 724   let Inst{4-0} = Rd;
 725   let Inst{9-8} = Pu;
 726   let Inst{20-16} = Rs;
 727 }
 728
 729 multiclass ALU32_2op_Pred<string mnemonic, bits<3> minOp, bit PredNot> {
 730   let isPredicatedFalse = PredNot in {
 731     def NAME : T_ALU32_2op_Pred<mnemonic, minOp, PredNot, 0>;
 732
 733     // Predicate new
 734     let isPredicatedNew = 1 in
 735     def NAME#new : T_ALU32_2op_Pred<mnemonic, minOp, PredNot, 1>;
 736   }
 737 }
 738
 739 multiclass ALU32_2op_base<string mnemonic, bits<3> minOp> {
 740   let BaseOpcode = mnemonic in {
 741     let isPredicable = 1, hasSideEffects = 0 in
 742     def A2_#NAME : T_ALU32_2op<mnemonic, minOp>;
 743
 744     let validSubTargets = HasV4SubT, isPredicated = 1, hasSideEffects = 0 in {
 745       defm A4_p#NAME#t : ALU32_2op_Pred<mnemonic, minOp, 0>;
 746       defm A4_p#NAME#f : ALU32_2op_Pred<mnemonic, minOp, 1>;
 747     }
 748   }
 749 }
 750
 751 let isCodeGenOnly = 0 in {
 752 defm aslh : ALU32_2op_base<"aslh", 0b000>, PredNewRel;
 753 defm asrh : ALU32_2op_base<"asrh", 0b001>, PredNewRel;
 754 defm sxtb : ALU32_2op_base<"sxtb", 0b101>, PredNewRel;
 755 defm sxth : ALU32_2op_base<"sxth", 0b111>, PredNewRel;
 756 defm zxth : ALU32_2op_base<"zxth", 0b110>, PredNewRel;
 757 }
 758
 759 // Rd=zxtb(Rs): assembler mapped to Rd=and(Rs,#255).
 760 // Compiler would want to generate 'zxtb' instead of 'and' becuase 'zxtb' has
 761 // predicated forms while 'and' doesn't. Since integrated assembler can't
 762 // handle 'mapped' instructions, we need to encode 'zxtb' same as 'and' where
 763 // immediate operand is set to '255'.
 764
 765 let hasNewValue = 1, opNewValue = 0 in
 766 class T_ZXTB: ALU32Inst < (outs IntRegs:$Rd), (ins IntRegs:$Rs),
 767   "$Rd = zxtb($Rs)", [] > { // Rd = and(Rs,255)
 768     bits<5> Rd;
 769     bits<5> Rs;
 770     bits<10> s10 = 255;
 771
 772     let IClass = 0b0111;
 773
 774     let Inst{27-22} = 0b011000;
 775     let Inst{4-0} = Rd;
 776     let Inst{20-16} = Rs;
 777     let Inst{21} = s10{9};
 778     let Inst{13-5} = s10{8-0};
 779 }
 780
 781 //Rd=zxtb(Rs): assembler mapped to "Rd=and(Rs,#255)
 782 multiclass ZXTB_base <string mnemonic, bits<3> minOp> {
 783   let BaseOpcode = mnemonic in {
 784     let isPredicable = 1, hasSideEffects = 0 in
 785     def A2_#NAME : T_ZXTB;
 786
 787     let validSubTargets = HasV4SubT, isPredicated = 1, hasSideEffects = 0 in {
 788       defm A4_p#NAME#t : ALU32_2op_Pred<mnemonic, minOp, 0>;
 789       defm A4_p#NAME#f : ALU32_2op_Pred<mnemonic, minOp, 1>;
 790     }
 791   }
 792 }
 793
 794 let isCodeGenOnly=0 in
 795 defm zxtb : ZXTB_base<"zxtb",0b100>, PredNewRel;
 796
 797 def: Pat<(shl I32:$src1, (i32 16)),   (A2_aslh I32:$src1)>;
 798 def: Pat<(sra I32:$src1, (i32 16)),   (A2_asrh I32:$src1)>;
 799 def: Pat<(sext_inreg I32:$src1, i8),  (A2_sxtb I32:$src1)>;
 800 def: Pat<(sext_inreg I32:$src1, i16), (A2_sxth I32:$src1)>;
 801
 802 // Mux.
 803 def VMUX_prr64 : ALU64_rr<(outs DoubleRegs:$dst), (ins PredRegs:$src1,
 804                                                    DoubleRegs:$src2,
 805                                                    DoubleRegs:$src3),
 806             "$dst = vmux($src1, $src2, $src3)",
 807             []>;
 808
 809
 810 //===----------------------------------------------------------------------===//
 811 // ALU32/PERM -
 812 //===----------------------------------------------------------------------===//
 813
 814
 815 //===----------------------------------------------------------------------===//
 816 // ALU32/PRED +
 817 //===----------------------------------------------------------------------===//
 818
 819 // SDNode for converting immediate C to C-1.
 820 def DEC_CONST_SIGNED : SDNodeXForm<imm, [{
 821    // Return the byte immediate const-1 as an SDNode.
 822    int32_t imm = N->getSExtValue();
 823    return XformSToSM1Imm(imm);
 824 }]>;
 825
 826 // SDNode for converting immediate C to C-1.
 827 def DEC_CONST_UNSIGNED : SDNodeXForm<imm, [{
 828    // Return the byte immediate const-1 as an SDNode.
 829    uint32_t imm = N->getZExtValue();
 830    return XformUToUM1Imm(imm);
 831 }]>;
 832
 833 def CTLZ64_rr : SInst<(outs IntRegs:$dst), (ins DoubleRegs:$src1),
 834     "$dst = cl0($src1)",
 835     [(set (i32 IntRegs:$dst), (i32 (trunc (ctlz (i64 DoubleRegs:$src1)))))]>;
 836
 837 def CTTZ64_rr : SInst<(outs IntRegs:$dst), (ins DoubleRegs:$src1),
 838     "$dst = ct0($src1)",
 839     [(set (i32 IntRegs:$dst), (i32 (trunc (cttz (i64 DoubleRegs:$src1)))))]>;
 840
 841 //===----------------------------------------------------------------------===//
 842 // ALU32/PRED -
 843 //===----------------------------------------------------------------------===//
 844
 845
 846 //===----------------------------------------------------------------------===//
 847 // ALU64/ALU +
 848 //===----------------------------------------------------------------------===//// Add.
 849 //===----------------------------------------------------------------------===//
 850 // Template Class
 851 // Add/Subtract halfword
 852 // Rd=add(Rt.L,Rs.[HL])[:sat]
 853 // Rd=sub(Rt.L,Rs.[HL])[:sat]
 854 // Rd=add(Rt.[LH],Rs.[HL])[:sat][:<16]
 855 // Rd=sub(Rt.[LH],Rs.[HL])[:sat][:<16]
 856 //===----------------------------------------------------------------------===//
 857
 858 let  hasNewValue = 1, opNewValue = 0 in
 859 class T_XTYPE_ADD_SUB <bits<2> LHbits, bit isSat, bit hasShift, bit isSub>
 860   : ALU64Inst <(outs IntRegs:$Rd), (ins IntRegs:$Rt, IntRegs:$Rs),
 861   "$Rd = "#!if(isSub,"sub","add")#"($Rt."
 862           #!if(hasShift, !if(LHbits{1},"h","l"),"l") #", $Rs."
 863           #!if(hasShift, !if(LHbits{0},"h)","l)"), !if(LHbits{1},"h)","l)"))
 864           #!if(isSat,":sat","")
 865           #!if(hasShift,":<<16",""), [], "", ALU64_tc_1_SLOT23> {
 866     bits<5> Rd;
 867     bits<5> Rt;
 868     bits<5> Rs;
 869     let IClass = 0b1101;
 870
 871     let Inst{27-23} = 0b01010;
 872     let Inst{22} = hasShift;
 873     let Inst{21} = isSub;
 874     let Inst{7} = isSat;
 875     let Inst{6-5} = LHbits;
 876     let Inst{4-0} = Rd;
 877     let Inst{12-8} = Rt;
 878     let Inst{20-16} = Rs;
 879   }
 880
 881 //Rd=sub(Rt.L,Rs.[LH])
 882 let isCodeGenOnly = 0 in {
 883 def A2_subh_l16_ll : T_XTYPE_ADD_SUB <0b00, 0, 0, 1>;
 884 def A2_subh_l16_hl : T_XTYPE_ADD_SUB <0b10, 0, 0, 1>;
 885 }
 886
 887 let isCodeGenOnly = 0 in {
 888 //Rd=add(Rt.L,Rs.[LH])
 889 def A2_addh_l16_ll : T_XTYPE_ADD_SUB <0b00, 0, 0, 0>;
 890 def A2_addh_l16_hl : T_XTYPE_ADD_SUB <0b10, 0, 0, 0>;
 891 }
 892
 893 let Itinerary = ALU64_tc_2_SLOT23, Defs = [USR_OVF], isCodeGenOnly = 0 in {
 894   //Rd=sub(Rt.L,Rs.[LH]):sat
 895   def A2_subh_l16_sat_ll : T_XTYPE_ADD_SUB <0b00, 1, 0, 1>;
 896   def A2_subh_l16_sat_hl : T_XTYPE_ADD_SUB <0b10, 1, 0, 1>;
 897
 898   //Rd=add(Rt.L,Rs.[LH]):sat
 899   def A2_addh_l16_sat_ll : T_XTYPE_ADD_SUB <0b00, 1, 0, 0>;
 900   def A2_addh_l16_sat_hl : T_XTYPE_ADD_SUB <0b10, 1, 0, 0>;
 901 }
 902
 903 //Rd=sub(Rt.[LH],Rs.[LH]):<<16
 904 let isCodeGenOnly = 0 in {
 905 def A2_subh_h16_ll : T_XTYPE_ADD_SUB <0b00, 0, 1, 1>;
 906 def A2_subh_h16_lh : T_XTYPE_ADD_SUB <0b01, 0, 1, 1>;
 907 def A2_subh_h16_hl : T_XTYPE_ADD_SUB <0b10, 0, 1, 1>;
 908 def A2_subh_h16_hh : T_XTYPE_ADD_SUB <0b11, 0, 1, 1>;
 909 }
 910
 911 //Rd=add(Rt.[LH],Rs.[LH]):<<16
 912 let isCodeGenOnly = 0 in {
 913 def A2_addh_h16_ll : T_XTYPE_ADD_SUB <0b00, 0, 1, 0>;
 914 def A2_addh_h16_lh : T_XTYPE_ADD_SUB <0b01, 0, 1, 0>;
 915 def A2_addh_h16_hl : T_XTYPE_ADD_SUB <0b10, 0, 1, 0>;
 916 def A2_addh_h16_hh : T_XTYPE_ADD_SUB <0b11, 0, 1, 0>;
 917 }
 918
 919 let Itinerary = ALU64_tc_2_SLOT23, Defs = [USR_OVF], isCodeGenOnly = 0 in {
 920   //Rd=sub(Rt.[LH],Rs.[LH]):sat:<<16
 921   def A2_subh_h16_sat_ll : T_XTYPE_ADD_SUB <0b00, 1, 1, 1>;
 922   def A2_subh_h16_sat_lh : T_XTYPE_ADD_SUB <0b01, 1, 1, 1>;
 923   def A2_subh_h16_sat_hl : T_XTYPE_ADD_SUB <0b10, 1, 1, 1>;
 924   def A2_subh_h16_sat_hh : T_XTYPE_ADD_SUB <0b11, 1, 1, 1>;
 925
 926   //Rd=add(Rt.[LH],Rs.[LH]):sat:<<16
 927   def A2_addh_h16_sat_ll : T_XTYPE_ADD_SUB <0b00, 1, 1, 0>;
 928   def A2_addh_h16_sat_lh : T_XTYPE_ADD_SUB <0b01, 1, 1, 0>;
 929   def A2_addh_h16_sat_hl : T_XTYPE_ADD_SUB <0b10, 1, 1, 0>;
 930   def A2_addh_h16_sat_hh : T_XTYPE_ADD_SUB <0b11, 1, 1, 0>;
 931 }
 932
 933 // Add halfword.
 934 def: Pat<(sext_inreg (add I32:$src1, I32:$src2), i16),
 935          (A2_addh_l16_ll I32:$src1, I32:$src2)>;
 936
 937 def: Pat<(sra (add (shl I32:$src1, (i32 16)), I32:$src2), (i32 16)),
 938          (A2_addh_l16_hl I32:$src1, I32:$src2)>;
 939
 940 def: Pat<(shl (add I32:$src1, I32:$src2), (i32 16)),
 941          (A2_addh_h16_ll I32:$src1, I32:$src2)>;
 942
 943 // Subtract halfword.
 944 def: Pat<(sext_inreg (sub I32:$src1, I32:$src2), i16),
 945          (A2_subh_l16_ll I32:$src1, I32:$src2)>;
 946
 947 def: Pat<(shl (sub I32:$src1, I32:$src2), (i32 16)),
 948          (A2_subh_h16_ll I32:$src1, I32:$src2)>;
 949
 950 let hasSideEffects = 0, hasNewValue = 1, isCodeGenOnly = 0 in
 951 def S2_parityp: ALU64Inst<(outs IntRegs:$Rd),
 952       (ins DoubleRegs:$Rs, DoubleRegs:$Rt),
 953       "$Rd = parity($Rs, $Rt)", [], "", ALU64_tc_2_SLOT23> {
 954   bits<5> Rd;
 955   bits<5> Rs;
 956   bits<5> Rt;
 957
 958   let IClass = 0b1101;
 959   let Inst{27-24} = 0b0000;
 960   let Inst{20-16} = Rs;
 961   let Inst{12-8} = Rt;
 962   let Inst{4-0} = Rd;
 963 }
 964
 965 let hasNewValue = 1, opNewValue = 0, hasSideEffects = 0 in
 966 class T_XTYPE_MIN_MAX < bit isMax, bit isUnsigned >
 967   : ALU64Inst < (outs IntRegs:$Rd), (ins IntRegs:$Rt, IntRegs:$Rs),
 968   "$Rd = "#!if(isMax,"max","min")#!if(isUnsigned,"u","")
 969           #"($Rt, $Rs)", [], "", ALU64_tc_2_SLOT23> {
 970     bits<5> Rd;
 971     bits<5> Rt;
 972     bits<5> Rs;
 973
 974     let IClass = 0b1101;
 975
 976     let Inst{27-23} = 0b01011;
 977     let Inst{22-21} = !if(isMax, 0b10, 0b01);
 978     let Inst{7} = isUnsigned;
 979     let Inst{4-0} = Rd;
 980     let Inst{12-8} = !if(isMax, Rs, Rt);
 981     let Inst{20-16} = !if(isMax, Rt, Rs);
 982   }
 983
 984 let isCodeGenOnly = 0 in {
 985 def A2_min  : T_XTYPE_MIN_MAX < 0, 0 >;
 986 def A2_minu : T_XTYPE_MIN_MAX < 0, 1 >;
 987 def A2_max  : T_XTYPE_MIN_MAX < 1, 0 >;
 988 def A2_maxu : T_XTYPE_MIN_MAX < 1, 1 >;
 989 }
 990
 991 // Here, depending on  the operand being selected, we'll either generate a
 992 // min or max instruction.
 993 // Ex:
 994 // (a>b)?a:b --> max(a,b) => Here check performed is '>' and the value selected
 995 // is the larger of two. So, the corresponding HexagonInst is passed in 'Inst'.
 996 // (a>b)?b:a --> min(a,b) => Here check performed is '>' but the smaller value
 997 // is selected and the corresponding HexagonInst is passed in 'SwapInst'.
 998
 999 multiclass T_MinMax_pats <PatFrag Op, RegisterClass RC, ValueType VT,
1000                           InstHexagon Inst, InstHexagon SwapInst> {
1001   def: Pat<(select (i1 (Op (VT RC:$src1), (VT RC:$src2))),
1002                    (VT RC:$src1), (VT RC:$src2)),
1003            (Inst RC:$src1, RC:$src2)>;
1004   def: Pat<(select (i1 (Op (VT RC:$src1), (VT RC:$src2))),
1005                    (VT RC:$src2), (VT RC:$src1)),
1006            (SwapInst RC:$src1, RC:$src2)>;
1007 }
1008
1009
1010 multiclass MinMax_pats <PatFrag Op, InstHexagon Inst, InstHexagon SwapInst> {
1011   defm: T_MinMax_pats<Op, IntRegs, i32, Inst, SwapInst>;
1012
1013   def: Pat<(sext_inreg (i32 (select (i1 (Op (i32 PositiveHalfWord:$src1),
1014                                             (i32 PositiveHalfWord:$src2))),
1015                                     (i32 PositiveHalfWord:$src1),
1016                                     (i32 PositiveHalfWord:$src2))), i16),
1017            (Inst IntRegs:$src1, IntRegs:$src2)>;
1018
1019   def: Pat<(sext_inreg (i32 (select (i1 (Op (i32 PositiveHalfWord:$src1),
1020                                             (i32 PositiveHalfWord:$src2))),
1021                                     (i32 PositiveHalfWord:$src2),
1022                                     (i32 PositiveHalfWord:$src1))), i16),
1023            (SwapInst IntRegs:$src1, IntRegs:$src2)>;
1024 }
1025
1026 let AddedComplexity = 200 in {
1027   defm: MinMax_pats<setge,  A2_max,  A2_min>;
1028   defm: MinMax_pats<setgt,  A2_max,  A2_min>;
1029   defm: MinMax_pats<setle,  A2_min,  A2_max>;
1030   defm: MinMax_pats<setlt,  A2_min,  A2_max>;
1031   defm: MinMax_pats<setuge, A2_maxu, A2_minu>;
1032   defm: MinMax_pats<setugt, A2_maxu, A2_minu>;
1033   defm: MinMax_pats<setule, A2_minu, A2_maxu>;
1034   defm: MinMax_pats<setult, A2_minu, A2_maxu>;
1035 }
1036
1037 class T_cmp64_rr<string mnemonic, bits<3> MinOp, bit IsComm>
1038   : ALU64_rr<(outs PredRegs:$Pd), (ins DoubleRegs:$Rs, DoubleRegs:$Rt),
1039              "$Pd = "#mnemonic#"($Rs, $Rt)", [], "", ALU64_tc_2early_SLOT23> {
1040   let isCompare = 1;
1041   let isCommutable = IsComm;
1042   let hasSideEffects = 0;
1043
1044   bits<2> Pd;
1045   bits<5> Rs;
1046   bits<5> Rt;
1047
1048   let IClass = 0b1101;
1049   let Inst{27-21} = 0b0010100;
1050   let Inst{20-16} = Rs;
1051   let Inst{12-8} = Rt;
1052   let Inst{7-5} = MinOp;
1053   let Inst{1-0} = Pd;
1054 }
1055
1056 let isCodeGenOnly = 0 in {
1057 def C2_cmpeqp  : T_cmp64_rr<"cmp.eq",  0b000, 1>;
1058 def C2_cmpgtp  : T_cmp64_rr<"cmp.gt",  0b010, 0>;
1059 def C2_cmpgtup : T_cmp64_rr<"cmp.gtu", 0b100, 0>;
1060 }
1061
1062 class T_cmp64_rr_pat<InstHexagon MI, PatFrag CmpOp>
1063   : Pat<(i1 (CmpOp (i64 DoubleRegs:$Rs), (i64 DoubleRegs:$Rt))),
1064         (i1 (MI DoubleRegs:$Rs, DoubleRegs:$Rt))>;
1065
1066 def: T_cmp64_rr_pat<C2_cmpeqp,  seteq>;
1067 def: T_cmp64_rr_pat<C2_cmpgtp,  setgt>;
1068 def: T_cmp64_rr_pat<C2_cmpgtup, setugt>;
1069 def: T_cmp64_rr_pat<C2_cmpgtp,  RevCmp<setlt>>;
1070 def: T_cmp64_rr_pat<C2_cmpgtup, RevCmp<setult>>;
1071
1072 class T_ALU64_rr<string mnemonic, string suffix, bits<4> RegType,
1073                  bits<3> MajOp, bits<3> MinOp, bit OpsRev, bit IsComm,
1074                  string Op2Pfx>
1075   : ALU64_rr<(outs DoubleRegs:$Rd), (ins DoubleRegs:$Rs, DoubleRegs:$Rt),
1076              "$Rd = " #mnemonic# "($Rs, " #Op2Pfx# "$Rt)" #suffix, [],
1077              "", ALU64_tc_1_SLOT23> {
1078   let hasSideEffects = 0;
1079   let isCommutable = IsComm;
1080
1081   bits<5> Rs;
1082   bits<5> Rt;
1083   bits<5> Rd;
1084
1085   let IClass = 0b1101;
1086   let Inst{27-24} = RegType;
1087   let Inst{23-21} = MajOp;
1088   let Inst{20-16} = !if (OpsRev,Rt,Rs);
1089   let Inst{12-8} = !if (OpsRev,Rs,Rt);
1090   let Inst{7-5} = MinOp;
1091   let Inst{4-0} = Rd;
1092 }
1093
1094 class T_ALU64_arith<string mnemonic, bits<3> MajOp, bits<3> MinOp, bit IsSat,
1095                     bit OpsRev, bit IsComm>
1096   : T_ALU64_rr<mnemonic, !if(IsSat,":sat",""), 0b0011, MajOp, MinOp, OpsRev,
1097                IsComm, "">;
1098
1099 let isCodeGenOnly = 0 in {
1100 def A2_addp : T_ALU64_arith<"add", 0b000, 0b111, 0, 0, 1>;
1101 def A2_subp : T_ALU64_arith<"sub", 0b001, 0b111, 0, 1, 0>;
1102 }
1103
1104 def: Pat<(i64 (add I64:$Rs, I64:$Rt)), (A2_addp I64:$Rs, I64:$Rt)>;
1105 def: Pat<(i64 (sub I64:$Rs, I64:$Rt)), (A2_subp I64:$Rs, I64:$Rt)>;
1106
1107 class T_ALU64_logical<string mnemonic, bits<3> MinOp, bit OpsRev, bit IsComm,
1108                       bit IsNeg>
1109   : T_ALU64_rr<mnemonic, "", 0b0011, 0b111, MinOp, OpsRev, IsComm,
1110                !if(IsNeg,"~","")>;
1111
1112 let isCodeGenOnly = 0 in {
1113 def A2_andp : T_ALU64_logical<"and", 0b000, 0, 1, 0>;
1114 def A2_orp  : T_ALU64_logical<"or",  0b010, 0, 1, 0>;
1115 def A2_xorp : T_ALU64_logical<"xor", 0b100, 0, 1, 0>;
1116 }
1117
1118 def: Pat<(i64 (and I64:$Rs, I64:$Rt)), (A2_andp I64:$Rs, I64:$Rt)>;
1119 def: Pat<(i64 (or  I64:$Rs, I64:$Rt)), (A2_orp  I64:$Rs, I64:$Rt)>;
1120 def: Pat<(i64 (xor I64:$Rs, I64:$Rt)), (A2_xorp I64:$Rs, I64:$Rt)>;
1121
1122 //===----------------------------------------------------------------------===//
1123 // ALU64/ALU -
1124 //===----------------------------------------------------------------------===//
1125
1126 //===----------------------------------------------------------------------===//
1127 // ALU64/BIT +
1128 //===----------------------------------------------------------------------===//
1129 //
1130 //===----------------------------------------------------------------------===//
1131 // ALU64/BIT -
1132 //===----------------------------------------------------------------------===//
1133
1134 //===----------------------------------------------------------------------===//
1135 // ALU64/PERM +
1136 //===----------------------------------------------------------------------===//
1137 //
1138 //===----------------------------------------------------------------------===//
1139 // ALU64/PERM -
1140 //===----------------------------------------------------------------------===//
1141
1142 //===----------------------------------------------------------------------===//
1143 // CR +
1144 //===----------------------------------------------------------------------===//
1145 // Logical reductions on predicates.
1146
1147 // Looping instructions.
1148
1149 // Pipelined looping instructions.
1150
1151 // Logical operations on predicates.
1152 let hasSideEffects = 0 in
1153 class T_LOGICAL_1OP<string MnOp, bits<2> OpBits>
1154     : CRInst<(outs PredRegs:$Pd), (ins PredRegs:$Ps),
1155              "$Pd = " # MnOp # "($Ps)", [], "", CR_tc_2early_SLOT23> {
1156   bits<2> Pd;
1157   bits<2> Ps;
1158
1159   let IClass = 0b0110;
1160   let Inst{27-23} = 0b10111;
1161   let Inst{22-21} = OpBits;
1162   let Inst{20} = 0b0;
1163   let Inst{17-16} = Ps;
1164   let Inst{13} = 0b0;
1165   let Inst{1-0} = Pd;
1166 }
1167
1168 let isCodeGenOnly = 0 in {
1169 def C2_any8 : T_LOGICAL_1OP<"any8", 0b00>;
1170 def C2_all8 : T_LOGICAL_1OP<"all8", 0b01>;
1171 def C2_not  : T_LOGICAL_1OP<"not",  0b10>;
1172 }
1173
1174 def: Pat<(i1 (not (i1 PredRegs:$Ps))),
1175          (C2_not PredRegs:$Ps)>;
1176
1177 let hasSideEffects = 0 in
1178 class T_LOGICAL_2OP<string MnOp, bits<3> OpBits, bit IsNeg, bit Rev>
1179     : CRInst<(outs PredRegs:$Pd), (ins PredRegs:$Ps, PredRegs:$Pt),
1180              "$Pd = " # MnOp # "($Ps, " # !if (IsNeg,"!","") # "$Pt)",
1181              [], "", CR_tc_2early_SLOT23> {
1182   bits<2> Pd;
1183   bits<2> Ps;
1184   bits<2> Pt;
1185
1186   let IClass = 0b0110;
1187   let Inst{27-24} = 0b1011;
1188   let Inst{23-21} = OpBits;
1189   let Inst{20} = 0b0;
1190   let Inst{17-16} = !if(Rev,Pt,Ps);  // Rs and Rt are reversed for some
1191   let Inst{13} = 0b0;                // instructions.
1192   let Inst{9-8} = !if(Rev,Ps,Pt);
1193   let Inst{1-0} = Pd;
1194 }
1195
1196 let isCodeGenOnly = 0 in {
1197 def C2_and  : T_LOGICAL_2OP<"and", 0b000, 0, 1>;
1198 def C2_or   : T_LOGICAL_2OP<"or",  0b001, 0, 1>;
1199 def C2_xor  : T_LOGICAL_2OP<"xor", 0b010, 0, 0>;
1200 def C2_andn : T_LOGICAL_2OP<"and", 0b011, 1, 1>;
1201 def C2_orn  : T_LOGICAL_2OP<"or",  0b111, 1, 1>;
1202 }
1203
1204 def: Pat<(i1 (and I1:$Ps, I1:$Pt)),       (C2_and  I1:$Ps, I1:$Pt)>;
1205 def: Pat<(i1 (or  I1:$Ps, I1:$Pt)),       (C2_or   I1:$Ps, I1:$Pt)>;
1206 def: Pat<(i1 (xor I1:$Ps, I1:$Pt)),       (C2_xor  I1:$Ps, I1:$Pt)>;
1207 def: Pat<(i1 (and I1:$Ps, (not I1:$Pt))), (C2_andn I1:$Ps, I1:$Pt)>;
1208 def: Pat<(i1 (or  I1:$Ps, (not I1:$Pt))), (C2_orn  I1:$Ps, I1:$Pt)>;
1209
1210 let hasSideEffects = 0, hasNewValue = 1, isCodeGenOnly = 0 in
1211 def C2_vitpack : SInst<(outs IntRegs:$Rd), (ins PredRegs:$Ps, PredRegs:$Pt),
1212       "$Rd = vitpack($Ps, $Pt)", [], "", S_2op_tc_1_SLOT23> {
1213   bits<5> Rd;
1214   bits<2> Ps;
1215   bits<2> Pt;
1216
1217   let IClass = 0b1000;
1218   let Inst{27-24} = 0b1001;
1219   let Inst{22-21} = 0b00;
1220   let Inst{17-16} = Ps;
1221   let Inst{9-8} = Pt;
1222   let Inst{4-0} = Rd;
1223 }
1224
1225 let hasSideEffects = 0, isCodeGenOnly = 0 in
1226 def C2_mask : SInst<(outs DoubleRegs:$Rd), (ins PredRegs:$Pt),
1227       "$Rd = mask($Pt)", [], "", S_2op_tc_1_SLOT23> {
1228   bits<5> Rd;
1229   bits<2> Pt;
1230
1231   let IClass = 0b1000;
1232   let Inst{27-24} = 0b0110;
1233   let Inst{9-8} = Pt;
1234   let Inst{4-0} = Rd;
1235 }
1236
1237 def VALIGN_rrp : SInst<(outs DoubleRegs:$dst), (ins DoubleRegs:$src1,
1238                                                     DoubleRegs:$src2,
1239                                                     PredRegs:$src3),
1240              "$dst = valignb($src1, $src2, $src3)",
1241              []>;
1242
1243 def VSPLICE_rrp : SInst<(outs DoubleRegs:$dst), (ins DoubleRegs:$src1,
1244                                                      DoubleRegs:$src2,
1245                                                      PredRegs:$src3),
1246              "$dst = vspliceb($src1, $src2, $src3)",
1247              []>;
1248
1249 // User control register transfer.
1250 //===----------------------------------------------------------------------===//
1251 // CR -
1252 //===----------------------------------------------------------------------===//
1253
1254 //===----------------------------------------------------------------------===//
1255 // JR +
1256 //===----------------------------------------------------------------------===//
1257
1258 def retflag : SDNode<"HexagonISD::RET_FLAG", SDTNone,
1259                                [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
1260 def eh_return: SDNode<"HexagonISD::EH_RETURN", SDTNone, [SDNPHasChain]>;
1261
1262 def SDHexagonBR_JT: SDTypeProfile<0, 1, [SDTCisVT<0, i32>]>;
1263 def HexagonBR_JT: SDNode<"HexagonISD::BR_JT", SDHexagonBR_JT, [SDNPHasChain]>;
1264
1265 class CondStr<string CReg, bit True, bit New> {
1266   string S = "if (" # !if(True,"","!") # CReg # !if(New,".new","") # ") ";
1267 }
1268 class JumpOpcStr<string Mnemonic, bit New, bit Taken> {
1269   string S = Mnemonic # !if(New, !if(Taken,":t",":nt"), "");
1270 }
1271
1272 let isBranch = 1, isBarrier = 1, Defs = [PC], hasSideEffects = 0,
1273     isPredicable = 1,
1274     isExtendable = 1, opExtendable = 0, isExtentSigned = 1,
1275     opExtentBits = 24, opExtentAlign = 2, InputType = "imm" in
1276 class T_JMP<string ExtStr>
1277   : JInst<(outs), (ins brtarget:$dst),
1278       "jump " # ExtStr # "$dst",
1279       [], "", J_tc_2early_SLOT23> {
1280     bits<24> dst;
1281     let IClass = 0b0101;
1282
1283     let Inst{27-25} = 0b100;
1284     let Inst{24-16} = dst{23-15};
1285     let Inst{13-1} = dst{14-2};
1286 }
1287
1288 let isBranch = 1, Defs = [PC], hasSideEffects = 0, isPredicated = 1,
1289     isExtendable = 1, opExtendable = 1, isExtentSigned = 1,
1290     opExtentBits = 17, opExtentAlign = 2, InputType = "imm" in
1291 class T_JMP_c<bit PredNot, bit isPredNew, bit isTak, string ExtStr>
1292   : JInst<(outs), (ins PredRegs:$src, brtarget:$dst),
1293       CondStr<"$src", !if(PredNot,0,1), isPredNew>.S #
1294         JumpOpcStr<"jump", isPredNew, isTak>.S # " " #
1295         ExtStr # "$dst",
1296       [], "", J_tc_2early_SLOT23>, ImmRegRel {
1297     let isTaken = isTak;
1298     let isPredicatedFalse = PredNot;
1299     let isPredicatedNew = isPredNew;
1300     bits<2> src;
1301     bits<17> dst;
1302
1303     let IClass = 0b0101;
1304
1305     let Inst{27-24} = 0b1100;
1306     let Inst{21} = PredNot;
1307     let Inst{12} = !if(isPredNew, isTak, zero);
1308     let Inst{11} = isPredNew;
1309     let Inst{9-8} = src;
1310     let Inst{23-22} = dst{16-15};
1311     let Inst{20-16} = dst{14-10};
1312     let Inst{13} = dst{9};
1313     let Inst{7-1} = dst{8-2};
1314   }
1315
1316 multiclass JMP_Pred<bit PredNot, string ExtStr> {
1317   def NAME : T_JMP_c<PredNot, 0, 0, ExtStr>;
1318   // Predicate new
1319   def NAME#newpt : T_JMP_c<PredNot, 1, 1, ExtStr>; // taken
1320   def NAME#new   : T_JMP_c<PredNot, 1, 0, ExtStr>; // not taken
1321 }
1322
1323 multiclass JMP_base<string BaseOp, string ExtStr> {
1324   let BaseOpcode = BaseOp in {
1325     def NAME : T_JMP<ExtStr>;
1326     defm t : JMP_Pred<0, ExtStr>;
1327     defm f : JMP_Pred<1, ExtStr>;
1328   }
1329 }
1330
1331 // Jumps to address stored in a register, JUMPR_MISC
1332 // if ([[!]P[.new]]) jumpr[:t/nt] Rs
1333 let isBranch = 1, isIndirectBranch = 1, isBarrier = 1, Defs = [PC],
1334     isPredicable = 1, hasSideEffects = 0, InputType = "reg" in
1335 class T_JMPr
1336   : JRInst<(outs), (ins IntRegs:$dst),
1337       "jumpr $dst", [], "", J_tc_2early_SLOT2> {
1338     bits<5> dst;
1339
1340     let IClass = 0b0101;
1341     let Inst{27-21} = 0b0010100;
1342     let Inst{20-16} = dst;
1343 }
1344
1345 let isBranch = 1, isIndirectBranch = 1, Defs = [PC], isPredicated = 1,
1346     hasSideEffects = 0, InputType = "reg" in
1347 class T_JMPr_c <bit PredNot, bit isPredNew, bit isTak>
1348   : JRInst <(outs), (ins PredRegs:$src, IntRegs:$dst),
1349       CondStr<"$src", !if(PredNot,0,1), isPredNew>.S #
1350         JumpOpcStr<"jumpr", isPredNew, isTak>.S # " $dst", [],
1351       "", J_tc_2early_SLOT2> {
1352
1353     let isTaken = isTak;
1354     let isPredicatedFalse = PredNot;
1355     let isPredicatedNew = isPredNew;
1356     bits<2> src;
1357     bits<5> dst;
1358
1359     let IClass = 0b0101;
1360
1361     let Inst{27-22} = 0b001101;
1362     let Inst{21} = PredNot;
1363     let Inst{20-16} = dst;
1364     let Inst{12} = !if(isPredNew, isTak, zero);
1365     let Inst{11} = isPredNew;
1366     let Inst{9-8} = src;
1367 }
1368
1369 multiclass JMPR_Pred<bit PredNot> {
1370   def NAME: T_JMPr_c<PredNot, 0, 0>;
1371   // Predicate new
1372   def NAME#newpt  : T_JMPr_c<PredNot, 1, 1>; // taken
1373   def NAME#new    : T_JMPr_c<PredNot, 1, 0>; // not taken
1374 }
1375
1376 multiclass JMPR_base<string BaseOp> {
1377   let BaseOpcode = BaseOp in {
1378     def NAME : T_JMPr;
1379     defm t : JMPR_Pred<0>;
1380     defm f : JMPR_Pred<1>;
1381   }
1382 }
1383
1384 let isCall = 1, hasSideEffects = 1 in
1385 class JUMPR_MISC_CALLR<bit isPred, bit isPredNot,
1386                dag InputDag = (ins IntRegs:$Rs)>
1387   : JRInst<(outs), InputDag,
1388       !if(isPred, !if(isPredNot, "if (!$Pu) callr $Rs",
1389                                  "if ($Pu) callr $Rs"),
1390                                  "callr $Rs"),
1391       [], "", J_tc_2early_SLOT2> {
1392     bits<5> Rs;
1393     bits<2> Pu;
1394     let isPredicated = isPred;
1395     let isPredicatedFalse = isPredNot;
1396
1397     let IClass = 0b0101;
1398     let Inst{27-25} = 0b000;
1399     let Inst{24-23} = !if (isPred, 0b10, 0b01);
1400     let Inst{22} = 0;
1401     let Inst{21} = isPredNot;
1402     let Inst{9-8} = !if (isPred, Pu, 0b00);
1403     let Inst{20-16} = Rs;
1404
1405   }
1406
1407 let Defs = VolatileV3.Regs, isCodeGenOnly = 0 in {
1408   def J2_callrt : JUMPR_MISC_CALLR<1, 0, (ins PredRegs:$Pu, IntRegs:$Rs)>;
1409   def J2_callrf : JUMPR_MISC_CALLR<1, 1, (ins PredRegs:$Pu, IntRegs:$Rs)>;
1410 }
1411
1412 let isTerminator = 1, hasSideEffects = 0, isCodeGenOnly = 0 in {
1413   defm J2_jump : JMP_base<"JMP", "">, PredNewRel;
1414
1415   // Deal with explicit assembly
1416   //  - never extened a jump #,  always extend a jump ##
1417   let isAsmParserOnly = 1 in {
1418     defm J2_jump_ext   : JMP_base<"JMP", "##">;
1419     defm J2_jump_noext : JMP_base<"JMP", "#">;
1420   }
1421
1422   defm J2_jumpr : JMPR_base<"JMPr">, PredNewRel;
1423
1424   let isReturn = 1, isCodeGenOnly = 1 in
1425   defm JMPret : JMPR_base<"JMPret">, PredNewRel;
1426 }
1427
1428 def: Pat<(br bb:$dst),
1429          (J2_jump brtarget:$dst)>;
1430 def: Pat<(retflag),
1431          (JMPret (i32 R31))>;
1432 def: Pat<(brcond (i1 PredRegs:$src1), bb:$offset),
1433          (J2_jumpt PredRegs:$src1, bb:$offset)>;
1434
1435 // A return through builtin_eh_return.
1436 let isReturn = 1, isTerminator = 1, isBarrier = 1, hasSideEffects = 0,
1437     isCodeGenOnly = 1, Defs = [PC], Uses = [R28], isPredicable = 0 in
1438 def EH_RETURN_JMPR : T_JMPr;
1439
1440 def: Pat<(eh_return),
1441          (EH_RETURN_JMPR (i32 R31))>;
1442 def: Pat<(HexagonBR_JT (i32 IntRegs:$dst)),
1443          (J2_jumpr IntRegs:$dst)>;
1444 def: Pat<(brind (i32 IntRegs:$dst)),
1445          (J2_jumpr IntRegs:$dst)>;
1446
1447 //===----------------------------------------------------------------------===//
1448 // JR -
1449 //===----------------------------------------------------------------------===//
1450
1451 //===----------------------------------------------------------------------===//
1452 // LD +
1453 //===----------------------------------------------------------------------===//
1454 let isExtendable = 1, opExtendable = 2, isExtentSigned = 1, AddedComplexity = 20 in
1455 class T_load_io <string mnemonic, RegisterClass RC, bits<4> MajOp,
1456                  Operand ImmOp>
1457   : LDInst<(outs RC:$dst), (ins IntRegs:$src1, ImmOp:$offset),
1458   "$dst = "#mnemonic#"($src1 + #$offset)", []>, AddrModeRel {
1459     bits<4> name;
1460     bits<5> dst;
1461     bits<5> src1;
1462     bits<14> offset;
1463     bits<11> offsetBits;
1464
1465     string ImmOpStr = !cast<string>(ImmOp);
1466     let offsetBits = !if (!eq(ImmOpStr, "s11_3Ext"), offset{13-3},
1467                      !if (!eq(ImmOpStr, "s11_2Ext"), offset{12-2},
1468                      !if (!eq(ImmOpStr, "s11_1Ext"), offset{11-1},
1469                                       /* s11_0Ext */ offset{10-0})));
1470     let opExtentBits = !if (!eq(ImmOpStr, "s11_3Ext"), 14,
1471                        !if (!eq(ImmOpStr, "s11_2Ext"), 13,
1472                        !if (!eq(ImmOpStr, "s11_1Ext"), 12,
1473                                         /* s11_0Ext */ 11)));
1474     let hasNewValue = !if (!eq(ImmOpStr, "s11_3Ext"), 0, 1);
1475
1476     let IClass = 0b1001;
1477
1478     let Inst{27}    = 0b0;
1479     let Inst{26-25} = offsetBits{10-9};
1480     let Inst{24-21} = MajOp;
1481     let Inst{20-16} = src1;
1482     let Inst{13-5}  = offsetBits{8-0};
1483     let Inst{4-0}   = dst;
1484   }
1485
1486 let opExtendable = 3, isExtentSigned = 0, isPredicated = 1 in
1487 class T_pload_io <string mnemonic, RegisterClass RC, bits<4>MajOp,
1488                   Operand ImmOp, bit isNot, bit isPredNew>
1489   : LDInst<(outs RC:$dst),
1490            (ins PredRegs:$src1, IntRegs:$src2, ImmOp:$offset),
1491   "if ("#!if(isNot, "!$src1", "$src1")
1492        #!if(isPredNew, ".new", "")
1493        #") $dst = "#mnemonic#"($src2 + #$offset)",
1494   [],"", V2LDST_tc_ld_SLOT01> , AddrModeRel {
1495     bits<5> dst;
1496     bits<2> src1;
1497     bits<5> src2;
1498     bits<9> offset;
1499     bits<6> offsetBits;
1500     string ImmOpStr = !cast<string>(ImmOp);
1501
1502     let offsetBits = !if (!eq(ImmOpStr, "u6_3Ext"), offset{8-3},
1503                      !if (!eq(ImmOpStr, "u6_2Ext"), offset{7-2},
1504                      !if (!eq(ImmOpStr, "u6_1Ext"), offset{6-1},
1505                                       /* u6_0Ext */ offset{5-0})));
1506     let opExtentBits = !if (!eq(ImmOpStr, "u6_3Ext"), 9,
1507                        !if (!eq(ImmOpStr, "u6_2Ext"), 8,
1508                        !if (!eq(ImmOpStr, "u6_1Ext"), 7,
1509                                         /* u6_0Ext */ 6)));
1510     let hasNewValue = !if (!eq(ImmOpStr, "u6_3Ext"), 0, 1);
1511     let isPredicatedNew = isPredNew;
1512     let isPredicatedFalse = isNot;
1513
1514     let IClass = 0b0100;
1515
1516     let Inst{27}    = 0b0;
1517     let Inst{27}    = 0b0;
1518     let Inst{26}    = isNot;
1519     let Inst{25}    = isPredNew;
1520     let Inst{24-21} = MajOp;
1521     let Inst{20-16} = src2;
1522     let Inst{13}    = 0b0;
1523     let Inst{12-11} = src1;
1524     let Inst{10-5}  = offsetBits;
1525     let Inst{4-0}   = dst;
1526   }
1527
1528 let isExtendable = 1, hasSideEffects = 0, addrMode = BaseImmOffset in
1529 multiclass LD_Idxd<string mnemonic, string CextOp, RegisterClass RC,
1530                    Operand ImmOp, Operand predImmOp, bits<4>MajOp> {
1531   let CextOpcode = CextOp, BaseOpcode = CextOp#_indexed in {
1532     let isPredicable = 1 in
1533     def L2_#NAME#_io : T_load_io <mnemonic, RC, MajOp, ImmOp>;
1534
1535     // Predicated
1536     def L2_p#NAME#t_io : T_pload_io <mnemonic, RC, MajOp, predImmOp, 0, 0>;
1537     def L2_p#NAME#f_io : T_pload_io <mnemonic, RC, MajOp, predImmOp, 1, 0>;
1538
1539     // Predicated new
1540     def L2_p#NAME#tnew_io : T_pload_io <mnemonic, RC, MajOp, predImmOp, 0, 1>;
1541     def L2_p#NAME#fnew_io : T_pload_io <mnemonic, RC, MajOp, predImmOp, 1, 1>;
1542   }
1543 }
1544
1545 let accessSize = ByteAccess, isCodeGenOnly = 0 in {
1546   defm loadrb:  LD_Idxd <"memb", "LDrib", IntRegs, s11_0Ext, u6_0Ext, 0b1000>;
1547   defm loadrub: LD_Idxd <"memub", "LDriub", IntRegs, s11_0Ext, u6_0Ext, 0b1001>;
1548 }
1549
1550 ///
1551 // Load -- MEMri operand
1552 multiclass LD_MEMri_Pbase<string mnemonic, RegisterClass RC,
1553                           bit isNot, bit isPredNew> {
1554   let isPredicatedNew = isPredNew in
1555   def NAME : LDInst2<(outs RC:$dst),
1556                        (ins PredRegs:$src1, MEMri:$addr),
1557             !if(isNot, "if (!$src1", "if ($src1")#!if(isPredNew, ".new) ",
1558             ") ")#"$dst = "#mnemonic#"($addr)",
1559             []>;
1560 }
1561
1562 multiclass LD_MEMri_Pred<string mnemonic, RegisterClass RC, bit PredNot> {
1563   let isPredicatedFalse = PredNot in {
1564     defm _c#NAME : LD_MEMri_Pbase<mnemonic, RC, PredNot, 0>;
1565     // Predicate new
1566     defm _cdn#NAME : LD_MEMri_Pbase<mnemonic, RC, PredNot, 1>;
1567   }
1568 }
1569
1570 let isExtendable = 1, hasSideEffects = 0 in
1571 multiclass LD_MEMri<string mnemonic, string CextOp, RegisterClass RC,
1572                     bits<5> ImmBits, bits<5> PredImmBits> {
1573
1574   let CextOpcode = CextOp, BaseOpcode = CextOp in {
1575     let opExtendable = 2, isExtentSigned = 1, opExtentBits = ImmBits,
1576         isPredicable = 1 in
1577       def NAME : LDInst2<(outs RC:$dst), (ins MEMri:$addr),
1578                    "$dst = "#mnemonic#"($addr)",
1579                    []>;
1580
1581     let opExtendable = 3, isExtentSigned = 0, opExtentBits = PredImmBits,
1582         isPredicated = 1 in {
1583       defm Pt : LD_MEMri_Pred<mnemonic, RC, 0 >;
1584       defm NotPt : LD_MEMri_Pred<mnemonic, RC, 1 >;
1585     }
1586   }
1587 }
1588
1589 let addrMode = BaseImmOffset, isMEMri = "true" in {
1590   let accessSize = HalfWordAccess in {
1591     defm LDrih: LD_MEMri < "memh", "LDrih", IntRegs, 12, 7>, AddrModeRel;
1592     defm LDriuh: LD_MEMri < "memuh", "LDriuh", IntRegs, 12, 7>, AddrModeRel;
1593  }
1594
1595   let accessSize = WordAccess in
1596     defm LDriw: LD_MEMri < "memw", "LDriw", IntRegs, 13, 8>, AddrModeRel;
1597
1598   let accessSize = DoubleWordAccess in
1599     defm LDrid: LD_MEMri < "memd", "LDrid", DoubleRegs, 14, 9>, AddrModeRel;
1600 }
1601
1602 def : Pat < (i32 (sextloadi8 ADDRriS11_0:$addr)),
1603             (L2_loadrb_io AddrFI:$addr, 0) >;
1604
1605 def : Pat < (i32 (zextloadi8 ADDRriS11_0:$addr)),
1606             (L2_loadrub_io AddrFI:$addr, 0) >;
1607
1608 def : Pat < (i32 (sextloadi16 ADDRriS11_1:$addr)),
1609             (LDrih ADDRriS11_1:$addr) >;
1610
1611 def : Pat < (i32 (zextloadi16 ADDRriS11_1:$addr)),
1612             (LDriuh ADDRriS11_1:$addr) >;
1613
1614 def : Pat < (i32 (load ADDRriS11_2:$addr)),
1615             (LDriw ADDRriS11_2:$addr) >;
1616
1617 def : Pat < (i64 (load ADDRriS11_3:$addr)),
1618             (LDrid ADDRriS11_3:$addr) >;
1619
1620
1621 // Load - Base with Immediate offset addressing mode
1622 multiclass LD_Idxd_Pbase2<string mnemonic, RegisterClass RC, Operand predImmOp,
1623                         bit isNot, bit isPredNew> {
1624   let isPredicatedNew = isPredNew in
1625   def NAME : LDInst2<(outs RC:$dst),
1626                      (ins PredRegs:$src1, IntRegs:$src2, predImmOp:$src3),
1627             !if(isNot, "if (!$src1", "if ($src1")#!if(isPredNew, ".new) ",
1628             ") ")#"$dst = "#mnemonic#"($src2+#$src3)",
1629             []>;
1630 }
1631
1632 multiclass LD_Idxd_Pred2<string mnemonic, RegisterClass RC, Operand predImmOp,
1633                         bit PredNot> {
1634   let isPredicatedFalse = PredNot in {
1635     defm _c#NAME : LD_Idxd_Pbase2<mnemonic, RC, predImmOp, PredNot, 0>;
1636     // Predicate new
1637     defm _cdn#NAME : LD_Idxd_Pbase2<mnemonic, RC, predImmOp, PredNot, 1>;
1638   }
1639 }
1640
1641 let isExtendable = 1, hasSideEffects = 0 in
1642 multiclass LD_Idxd2<string mnemonic, string CextOp, RegisterClass RC,
1643                    Operand ImmOp, Operand predImmOp, bits<5> ImmBits,
1644                    bits<5> PredImmBits> {
1645
1646   let CextOpcode = CextOp, BaseOpcode = CextOp#_indexed in {
1647     let opExtendable = 2, isExtentSigned = 1, opExtentBits = ImmBits,
1648         isPredicable = 1, AddedComplexity = 20 in
1649       def NAME : LDInst2<(outs RC:$dst), (ins IntRegs:$src1, ImmOp:$offset),
1650                    "$dst = "#mnemonic#"($src1+#$offset)",
1651                    []>;
1652
1653     let opExtendable = 3, isExtentSigned = 0, opExtentBits = PredImmBits,
1654         isPredicated = 1 in {
1655       defm Pt : LD_Idxd_Pred2<mnemonic, RC, predImmOp, 0 >;
1656       defm NotPt : LD_Idxd_Pred2<mnemonic, RC, predImmOp, 1 >;
1657     }
1658   }
1659 }
1660
1661 let addrMode = BaseImmOffset in {
1662   let accessSize = HalfWordAccess in {
1663     defm LDrih_indexed: LD_Idxd2 <"memh", "LDrih", IntRegs, s11_1Ext, u6_1Ext,
1664                                  12, 7>, AddrModeRel;
1665     defm LDriuh_indexed: LD_Idxd2 <"memuh", "LDriuh", IntRegs, s11_1Ext, u6_1Ext,
1666                                   12, 7>, AddrModeRel;
1667   }
1668   let accessSize = WordAccess in
1669     defm LDriw_indexed: LD_Idxd2 <"memw", "LDriw", IntRegs, s11_2Ext, u6_2Ext,
1670                                  13, 8>, AddrModeRel;
1671
1672   let accessSize = DoubleWordAccess in
1673     defm LDrid_indexed: LD_Idxd2 <"memd", "LDrid", DoubleRegs, s11_3Ext, u6_3Ext,
1674                                  14, 9>, AddrModeRel;
1675 }
1676
1677 let AddedComplexity = 20 in {
1678 def : Pat < (i32 (sextloadi8 (add IntRegs:$src1, s11_0ExtPred:$offset))),
1679             (L2_loadrb_io IntRegs:$src1, s11_0ExtPred:$offset) >;
1680
1681 def : Pat < (i32 (zextloadi8 (add IntRegs:$src1, s11_0ExtPred:$offset))),
1682             (L2_loadrub_io IntRegs:$src1, s11_0ExtPred:$offset) >;
1683
1684 def : Pat < (i32 (sextloadi16 (add IntRegs:$src1, s11_1ExtPred:$offset))),
1685             (LDrih_indexed IntRegs:$src1, s11_1ExtPred:$offset) >;
1686
1687 def : Pat < (i32 (zextloadi16 (add IntRegs:$src1, s11_1ExtPred:$offset))),
1688             (LDriuh_indexed IntRegs:$src1, s11_1ExtPred:$offset) >;
1689
1690 def : Pat < (i32 (load (add IntRegs:$src1, s11_2ExtPred:$offset))),
1691             (LDriw_indexed IntRegs:$src1, s11_2ExtPred:$offset) >;
1692
1693 def : Pat < (i64 (load (add IntRegs:$src1, s11_3ExtPred:$offset))),
1694             (LDrid_indexed IntRegs:$src1, s11_3ExtPred:$offset) >;
1695 }
1696
1697 //===----------------------------------------------------------------------===//
1698 // Post increment load
1699 //===----------------------------------------------------------------------===//
1700
1701 multiclass LD_PostInc_Pbase<string mnemonic, RegisterClass RC, Operand ImmOp,
1702                             bit isNot, bit isPredNew> {
1703   let isPredicatedNew = isPredNew in
1704   def NAME : LDInst2PI<(outs RC:$dst, IntRegs:$dst2),
1705                        (ins PredRegs:$src1, IntRegs:$src2, ImmOp:$offset),
1706             !if(isNot, "if (!$src1", "if ($src1")#!if(isPredNew, ".new) ",
1707             ") ")#"$dst = "#mnemonic#"($src2++#$offset)",
1708             [],
1709             "$src2 = $dst2">;
1710 }
1711
1712 multiclass LD_PostInc_Pred<string mnemonic, RegisterClass RC,
1713                            Operand ImmOp, bit PredNot> {
1714   let isPredicatedFalse = PredNot in {
1715     defm _c#NAME : LD_PostInc_Pbase<mnemonic, RC, ImmOp, PredNot, 0>;
1716     // Predicate new
1717     let Predicates = [HasV4T], validSubTargets = HasV4SubT in
1718     defm _cdn#NAME#_V4 : LD_PostInc_Pbase<mnemonic, RC, ImmOp, PredNot, 1>;
1719   }
1720 }
1721
1722 multiclass LD_PostInc<string mnemonic, string BaseOp, RegisterClass RC,
1723                       Operand ImmOp> {
1724
1725   let BaseOpcode = "POST_"#BaseOp in {
1726     let isPredicable = 1 in
1727     def NAME : LDInst2PI<(outs RC:$dst, IntRegs:$dst2),
1728                          (ins IntRegs:$src1, ImmOp:$offset),
1729                  "$dst = "#mnemonic#"($src1++#$offset)",
1730                  [],
1731                  "$src1 = $dst2">;
1732
1733     let isPredicated = 1 in {
1734       defm Pt : LD_PostInc_Pred<mnemonic, RC, ImmOp, 0 >;
1735       defm NotPt : LD_PostInc_Pred<mnemonic, RC, ImmOp, 1 >;
1736     }
1737   }
1738 }
1739
1740 let hasCtrlDep = 1, hasSideEffects = 0, addrMode = PostInc in {
1741   defm POST_LDrib : LD_PostInc<"memb", "LDrib", IntRegs, s4_0Imm>,
1742                     PredNewRel;
1743   defm POST_LDriub : LD_PostInc<"memub", "LDriub", IntRegs, s4_0Imm>,
1744                     PredNewRel;
1745   defm POST_LDrih : LD_PostInc<"memh", "LDrih", IntRegs, s4_1Imm>,
1746                     PredNewRel;
1747   defm POST_LDriuh : LD_PostInc<"memuh", "LDriuh", IntRegs, s4_1Imm>,
1748                     PredNewRel;
1749   defm POST_LDriw : LD_PostInc<"memw", "LDriw", IntRegs, s4_2Imm>,
1750                     PredNewRel;
1751   defm POST_LDrid : LD_PostInc<"memd", "LDrid", DoubleRegs, s4_3Imm>,
1752                     PredNewRel;
1753 }
1754
1755 def : Pat< (i32 (extloadi1 ADDRriS11_0:$addr)),
1756            (i32 (L2_loadrb_io AddrFI:$addr, 0)) >;
1757
1758 // Load byte any-extend.
1759 def : Pat < (i32 (extloadi8 ADDRriS11_0:$addr)),
1760             (i32 (L2_loadrb_io AddrFI:$addr, 0)) >;
1761
1762 // Indexed load byte any-extend.
1763 let AddedComplexity = 20 in
1764 def : Pat < (i32 (extloadi8 (add IntRegs:$src1, s11_0ImmPred:$offset))),
1765             (i32 (L2_loadrb_io IntRegs:$src1, s11_0ImmPred:$offset)) >;
1766
1767 def : Pat < (i32 (extloadi16 ADDRriS11_1:$addr)),
1768             (i32 (LDrih ADDRriS11_1:$addr))>;
1769
1770 let AddedComplexity = 20 in
1771 def : Pat < (i32 (extloadi16 (add IntRegs:$src1, s11_1ImmPred:$offset))),
1772             (i32 (LDrih_indexed IntRegs:$src1, s11_1ImmPred:$offset)) >;
1773
1774 let AddedComplexity = 10 in
1775 def : Pat < (i32 (zextloadi1 ADDRriS11_0:$addr)),
1776             (i32 (L2_loadrub_io AddrFI:$addr, 0))>;
1777
1778 let AddedComplexity = 20 in
1779 def : Pat < (i32 (zextloadi1 (add IntRegs:$src1, s11_0ImmPred:$offset))),
1780             (i32 (L2_loadrub_io IntRegs:$src1, s11_0ImmPred:$offset))>;
1781
1782 // Load predicate.
1783 let isExtendable = 1, opExtendable = 2, isExtentSigned = 1, opExtentBits = 13,
1784 isPseudo = 1, Defs = [R10,R11,D5], hasSideEffects = 0 in
1785 def LDriw_pred : LDInst2<(outs PredRegs:$dst),
1786             (ins MEMri:$addr),
1787             "Error; should not emit",
1788             []>;
1789
1790 // Deallocate stack frame.
1791 let Defs = [R29, R30, R31], Uses = [R29], hasSideEffects = 0 in {
1792   def DEALLOCFRAME : LDInst2<(outs), (ins),
1793                      "deallocframe",
1794                      []>;
1795 }
1796
1797 // Load and unpack bytes to halfwords.
1798 //===----------------------------------------------------------------------===//
1799 // LD -
1800 //===----------------------------------------------------------------------===//
1801
1802 //===----------------------------------------------------------------------===//
1803 // MTYPE/ALU +
1804 //===----------------------------------------------------------------------===//
1805 //===----------------------------------------------------------------------===//
1806 // MTYPE/ALU -
1807 //===----------------------------------------------------------------------===//
1808
1809 //===----------------------------------------------------------------------===//
1810 // MTYPE/COMPLEX +
1811 //===----------------------------------------------------------------------===//
1812 //===----------------------------------------------------------------------===//
1813 // MTYPE/COMPLEX -
1814 //===----------------------------------------------------------------------===//
1815
1816 //===----------------------------------------------------------------------===//
1817 // MTYPE/MPYH +
1818 //===----------------------------------------------------------------------===//
1819
1820 //===----------------------------------------------------------------------===//
1821 // Template Class
1822 // MPYS / Multipy signed/unsigned halfwords
1823 //Rd=mpy[u](Rs.[H|L],Rt.[H|L])[:<<1][:rnd][:sat]
1824 //===----------------------------------------------------------------------===//
1825
1826 let hasNewValue = 1, opNewValue = 0 in
1827 class T_M2_mpy < bits<2> LHbits, bit isSat, bit isRnd,
1828                  bit hasShift, bit isUnsigned>
1829   : MInst < (outs IntRegs:$Rd), (ins IntRegs:$Rs, IntRegs:$Rt),
1830   "$Rd = "#!if(isUnsigned,"mpyu","mpy")#"($Rs."#!if(LHbits{1},"h","l")
1831                                        #", $Rt."#!if(LHbits{0},"h)","l)")
1832                                        #!if(hasShift,":<<1","")
1833                                        #!if(isRnd,":rnd","")
1834                                        #!if(isSat,":sat",""),
1835   [], "", M_tc_3x_SLOT23 > {
1836     bits<5> Rd;
1837     bits<5> Rs;
1838     bits<5> Rt;
1839
1840     let IClass = 0b1110;
1841
1842     let Inst{27-24} = 0b1100;
1843     let Inst{23} = hasShift;
1844     let Inst{22} = isUnsigned;
1845     let Inst{21} = isRnd;
1846     let Inst{7} = isSat;
1847     let Inst{6-5} = LHbits;
1848     let Inst{4-0} = Rd;
1849     let Inst{20-16} = Rs;
1850     let Inst{12-8} = Rt;
1851   }
1852
1853 //Rd=mpy(Rs.[H|L],Rt.[H|L])[:<<1]
1854 let isCodeGenOnly = 0 in {
1855 def M2_mpy_ll_s1: T_M2_mpy<0b00, 0, 0, 1, 0>;
1856 def M2_mpy_ll_s0: T_M2_mpy<0b00, 0, 0, 0, 0>;
1857 def M2_mpy_lh_s1: T_M2_mpy<0b01, 0, 0, 1, 0>;
1858 def M2_mpy_lh_s0: T_M2_mpy<0b01, 0, 0, 0, 0>;
1859 def M2_mpy_hl_s1: T_M2_mpy<0b10, 0, 0, 1, 0>;
1860 def M2_mpy_hl_s0: T_M2_mpy<0b10, 0, 0, 0, 0>;
1861 def M2_mpy_hh_s1: T_M2_mpy<0b11, 0, 0, 1, 0>;
1862 def M2_mpy_hh_s0: T_M2_mpy<0b11, 0, 0, 0, 0>;
1863 }
1864
1865 //Rd=mpyu(Rs.[H|L],Rt.[H|L])[:<<1]
1866 let isCodeGenOnly = 0 in {
1867 def M2_mpyu_ll_s1: T_M2_mpy<0b00, 0, 0, 1, 1>;
1868 def M2_mpyu_ll_s0: T_M2_mpy<0b00, 0, 0, 0, 1>;
1869 def M2_mpyu_lh_s1: T_M2_mpy<0b01, 0, 0, 1, 1>;
1870 def M2_mpyu_lh_s0: T_M2_mpy<0b01, 0, 0, 0, 1>;
1871 def M2_mpyu_hl_s1: T_M2_mpy<0b10, 0, 0, 1, 1>;
1872 def M2_mpyu_hl_s0: T_M2_mpy<0b10, 0, 0, 0, 1>;
1873 def M2_mpyu_hh_s1: T_M2_mpy<0b11, 0, 0, 1, 1>;
1874 def M2_mpyu_hh_s0: T_M2_mpy<0b11, 0, 0, 0, 1>;
1875 }
1876
1877 //Rd=mpy(Rs.[H|L],Rt.[H|L])[:<<1]:rnd
1878 let isCodeGenOnly = 0 in {
1879 def M2_mpy_rnd_ll_s1: T_M2_mpy <0b00, 0, 1, 1, 0>;
1880 def M2_mpy_rnd_ll_s0: T_M2_mpy <0b00, 0, 1, 0, 0>;
1881 def M2_mpy_rnd_lh_s1: T_M2_mpy <0b01, 0, 1, 1, 0>;
1882 def M2_mpy_rnd_lh_s0: T_M2_mpy <0b01, 0, 1, 0, 0>;
1883 def M2_mpy_rnd_hl_s1: T_M2_mpy <0b10, 0, 1, 1, 0>;
1884 def M2_mpy_rnd_hl_s0: T_M2_mpy <0b10, 0, 1, 0, 0>;
1885 def M2_mpy_rnd_hh_s1: T_M2_mpy <0b11, 0, 1, 1, 0>;
1886 def M2_mpy_rnd_hh_s0: T_M2_mpy <0b11, 0, 1, 0, 0>;
1887 }
1888
1889 //Rd=mpy(Rs.[H|L],Rt.[H|L])[:<<1][:sat]
1890 //Rd=mpy(Rs.[H|L],Rt.[H|L])[:<<1][:rnd][:sat]
1891 let Defs = [USR_OVF], isCodeGenOnly = 0 in {
1892   def M2_mpy_sat_ll_s1: T_M2_mpy <0b00, 1, 0, 1, 0>;
1893   def M2_mpy_sat_ll_s0: T_M2_mpy <0b00, 1, 0, 0, 0>;
1894   def M2_mpy_sat_lh_s1: T_M2_mpy <0b01, 1, 0, 1, 0>;
1895   def M2_mpy_sat_lh_s0: T_M2_mpy <0b01, 1, 0, 0, 0>;
1896   def M2_mpy_sat_hl_s1: T_M2_mpy <0b10, 1, 0, 1, 0>;
1897   def M2_mpy_sat_hl_s0: T_M2_mpy <0b10, 1, 0, 0, 0>;
1898   def M2_mpy_sat_hh_s1: T_M2_mpy <0b11, 1, 0, 1, 0>;
1899   def M2_mpy_sat_hh_s0: T_M2_mpy <0b11, 1, 0, 0, 0>;
1900
1901   def M2_mpy_sat_rnd_ll_s1: T_M2_mpy <0b00, 1, 1, 1, 0>;
1902   def M2_mpy_sat_rnd_ll_s0: T_M2_mpy <0b00, 1, 1, 0, 0>;
1903   def M2_mpy_sat_rnd_lh_s1: T_M2_mpy <0b01, 1, 1, 1, 0>;
1904   def M2_mpy_sat_rnd_lh_s0: T_M2_mpy <0b01, 1, 1, 0, 0>;
1905   def M2_mpy_sat_rnd_hl_s1: T_M2_mpy <0b10, 1, 1, 1, 0>;
1906   def M2_mpy_sat_rnd_hl_s0: T_M2_mpy <0b10, 1, 1, 0, 0>;
1907   def M2_mpy_sat_rnd_hh_s1: T_M2_mpy <0b11, 1, 1, 1, 0>;
1908   def M2_mpy_sat_rnd_hh_s0: T_M2_mpy <0b11, 1, 1, 0, 0>;
1909 }
1910
1911 //===----------------------------------------------------------------------===//
1912 // Template Class
1913 // MPYS / Multipy signed/unsigned halfwords and add/subtract the
1914 // result from the accumulator.
1915 //Rx [-+]= mpy[u](Rs.[H|L],Rt.[H|L])[:<<1][:sat]
1916 //===----------------------------------------------------------------------===//
1917
1918 let hasNewValue = 1, opNewValue = 0 in
1919 class T_M2_mpy_acc < bits<2> LHbits, bit isSat, bit isNac,
1920                  bit hasShift, bit isUnsigned >
1921   : MInst_acc<(outs IntRegs:$Rx), (ins IntRegs:$dst2, IntRegs:$Rs, IntRegs:$Rt),
1922   "$Rx "#!if(isNac,"-= ","+= ")#!if(isUnsigned,"mpyu","mpy")
1923                               #"($Rs."#!if(LHbits{1},"h","l")
1924                               #", $Rt."#!if(LHbits{0},"h)","l)")
1925                               #!if(hasShift,":<<1","")
1926                               #!if(isSat,":sat",""),
1927   [], "$dst2 = $Rx", M_tc_3x_SLOT23 > {
1928     bits<5> Rx;
1929     bits<5> Rs;
1930     bits<5> Rt;
1931
1932     let IClass = 0b1110;
1933     let Inst{27-24} = 0b1110;
1934     let Inst{23} = hasShift;
1935     let Inst{22} = isUnsigned;
1936     let Inst{21} = isNac;
1937     let Inst{7} = isSat;
1938     let Inst{6-5} = LHbits;
1939     let Inst{4-0} = Rx;
1940     let Inst{20-16} = Rs;
1941     let Inst{12-8} = Rt;
1942   }
1943
1944 //Rx += mpy(Rs.[H|L],Rt.[H|L])[:<<1]
1945 let isCodeGenOnly = 0 in {
1946 def M2_mpy_acc_ll_s1: T_M2_mpy_acc <0b00, 0, 0, 1, 0>;
1947 def M2_mpy_acc_ll_s0: T_M2_mpy_acc <0b00, 0, 0, 0, 0>;
1948 def M2_mpy_acc_lh_s1: T_M2_mpy_acc <0b01, 0, 0, 1, 0>;
1949 def M2_mpy_acc_lh_s0: T_M2_mpy_acc <0b01, 0, 0, 0, 0>;
1950 def M2_mpy_acc_hl_s1: T_M2_mpy_acc <0b10, 0, 0, 1, 0>;
1951 def M2_mpy_acc_hl_s0: T_M2_mpy_acc <0b10, 0, 0, 0, 0>;
1952 def M2_mpy_acc_hh_s1: T_M2_mpy_acc <0b11, 0, 0, 1, 0>;
1953 def M2_mpy_acc_hh_s0: T_M2_mpy_acc <0b11, 0, 0, 0, 0>;
1954 }
1955
1956 //Rx += mpyu(Rs.[H|L],Rt.[H|L])[:<<1]
1957 let isCodeGenOnly = 0 in {
1958 def M2_mpyu_acc_ll_s1: T_M2_mpy_acc <0b00, 0, 0, 1, 1>;
1959 def M2_mpyu_acc_ll_s0: T_M2_mpy_acc <0b00, 0, 0, 0, 1>;
1960 def M2_mpyu_acc_lh_s1: T_M2_mpy_acc <0b01, 0, 0, 1, 1>;
1961 def M2_mpyu_acc_lh_s0: T_M2_mpy_acc <0b01, 0, 0, 0, 1>;
1962 def M2_mpyu_acc_hl_s1: T_M2_mpy_acc <0b10, 0, 0, 1, 1>;
1963 def M2_mpyu_acc_hl_s0: T_M2_mpy_acc <0b10, 0, 0, 0, 1>;
1964 def M2_mpyu_acc_hh_s1: T_M2_mpy_acc <0b11, 0, 0, 1, 1>;
1965 def M2_mpyu_acc_hh_s0: T_M2_mpy_acc <0b11, 0, 0, 0, 1>;
1966 }
1967
1968 //Rx -= mpy(Rs.[H|L],Rt.[H|L])[:<<1]
1969 let isCodeGenOnly = 0 in {
1970 def M2_mpy_nac_ll_s1: T_M2_mpy_acc <0b00, 0, 1, 1, 0>;
1971 def M2_mpy_nac_ll_s0: T_M2_mpy_acc <0b00, 0, 1, 0, 0>;
1972 def M2_mpy_nac_lh_s1: T_M2_mpy_acc <0b01, 0, 1, 1, 0>;
1973 def M2_mpy_nac_lh_s0: T_M2_mpy_acc <0b01, 0, 1, 0, 0>;
1974 def M2_mpy_nac_hl_s1: T_M2_mpy_acc <0b10, 0, 1, 1, 0>;
1975 def M2_mpy_nac_hl_s0: T_M2_mpy_acc <0b10, 0, 1, 0, 0>;
1976 def M2_mpy_nac_hh_s1: T_M2_mpy_acc <0b11, 0, 1, 1, 0>;
1977 def M2_mpy_nac_hh_s0: T_M2_mpy_acc <0b11, 0, 1, 0, 0>;
1978 }
1979
1980 //Rx -= mpyu(Rs.[H|L],Rt.[H|L])[:<<1]
1981 let isCodeGenOnly = 0 in {
1982 def M2_mpyu_nac_ll_s1: T_M2_mpy_acc <0b00, 0, 1, 1, 1>;
1983 def M2_mpyu_nac_ll_s0: T_M2_mpy_acc <0b00, 0, 1, 0, 1>;
1984 def M2_mpyu_nac_lh_s1: T_M2_mpy_acc <0b01, 0, 1, 1, 1>;
1985 def M2_mpyu_nac_lh_s0: T_M2_mpy_acc <0b01, 0, 1, 0, 1>;
1986 def M2_mpyu_nac_hl_s1: T_M2_mpy_acc <0b10, 0, 1, 1, 1>;
1987 def M2_mpyu_nac_hl_s0: T_M2_mpy_acc <0b10, 0, 1, 0, 1>;
1988 def M2_mpyu_nac_hh_s1: T_M2_mpy_acc <0b11, 0, 1, 1, 1>;
1989 def M2_mpyu_nac_hh_s0: T_M2_mpy_acc <0b11, 0, 1, 0, 1>;
1990 }
1991
1992 //Rx += mpy(Rs.[H|L],Rt.[H|L])[:<<1]:sat
1993 let isCodeGenOnly = 0 in {
1994 def M2_mpy_acc_sat_ll_s1: T_M2_mpy_acc <0b00, 1, 0, 1, 0>;
1995 def M2_mpy_acc_sat_ll_s0: T_M2_mpy_acc <0b00, 1, 0, 0, 0>;
1996 def M2_mpy_acc_sat_lh_s1: T_M2_mpy_acc <0b01, 1, 0, 1, 0>;
1997 def M2_mpy_acc_sat_lh_s0: T_M2_mpy_acc <0b01, 1, 0, 0, 0>;
1998 def M2_mpy_acc_sat_hl_s1: T_M2_mpy_acc <0b10, 1, 0, 1, 0>;
1999 def M2_mpy_acc_sat_hl_s0: T_M2_mpy_acc <0b10, 1, 0, 0, 0>;
2000 def M2_mpy_acc_sat_hh_s1: T_M2_mpy_acc <0b11, 1, 0, 1, 0>;
2001 def M2_mpy_acc_sat_hh_s0: T_M2_mpy_acc <0b11, 1, 0, 0, 0>;
2002 }
2003
2004 //Rx -= mpy(Rs.[H|L],Rt.[H|L])[:<<1]:sat
2005 let isCodeGenOnly = 0 in {
2006 def M2_mpy_nac_sat_ll_s1: T_M2_mpy_acc <0b00, 1, 1, 1, 0>;
2007 def M2_mpy_nac_sat_ll_s0: T_M2_mpy_acc <0b00, 1, 1, 0, 0>;
2008 def M2_mpy_nac_sat_lh_s1: T_M2_mpy_acc <0b01, 1, 1, 1, 0>;
2009 def M2_mpy_nac_sat_lh_s0: T_M2_mpy_acc <0b01, 1, 1, 0, 0>;
2010 def M2_mpy_nac_sat_hl_s1: T_M2_mpy_acc <0b10, 1, 1, 1, 0>;
2011 def M2_mpy_nac_sat_hl_s0: T_M2_mpy_acc <0b10, 1, 1, 0, 0>;
2012 def M2_mpy_nac_sat_hh_s1: T_M2_mpy_acc <0b11, 1, 1, 1, 0>;
2013 def M2_mpy_nac_sat_hh_s0: T_M2_mpy_acc <0b11, 1, 1, 0, 0>;
2014 }
2015
2016 //===----------------------------------------------------------------------===//
2017 // Template Class
2018 // MPYS / Multipy signed/unsigned halfwords and add/subtract the
2019 // result from the 64-bit destination register.
2020 //Rxx [-+]= mpy[u](Rs.[H|L],Rt.[H|L])[:<<1][:sat]
2021 //===----------------------------------------------------------------------===//
2022
2023 class T_M2_mpyd_acc < bits<2> LHbits, bit isNac, bit hasShift, bit isUnsigned>
2024   : MInst_acc<(outs DoubleRegs:$Rxx),
2025               (ins DoubleRegs:$dst2, IntRegs:$Rs, IntRegs:$Rt),
2026   "$Rxx "#!if(isNac,"-= ","+= ")#!if(isUnsigned,"mpyu","mpy")
2027                                 #"($Rs."#!if(LHbits{1},"h","l")
2028                                 #", $Rt."#!if(LHbits{0},"h)","l)")
2029                                 #!if(hasShift,":<<1",""),
2030   [], "$dst2 = $Rxx", M_tc_3x_SLOT23 > {
2031     bits<5> Rxx;
2032     bits<5> Rs;
2033     bits<5> Rt;
2034
2035     let IClass = 0b1110;
2036
2037     let Inst{27-24} = 0b0110;
2038     let Inst{23} = hasShift;
2039     let Inst{22} = isUnsigned;
2040     let Inst{21} = isNac;
2041     let Inst{7} = 0;
2042     let Inst{6-5} = LHbits;
2043     let Inst{4-0} = Rxx;
2044     let Inst{20-16} = Rs;
2045     let Inst{12-8} = Rt;
2046   }
2047
2048 let isCodeGenOnly = 0 in {
2049 def M2_mpyd_acc_hh_s0: T_M2_mpyd_acc <0b11, 0, 0, 0>;
2050 def M2_mpyd_acc_hl_s0: T_M2_mpyd_acc <0b10, 0, 0, 0>;
2051 def M2_mpyd_acc_lh_s0: T_M2_mpyd_acc <0b01, 0, 0, 0>;
2052 def M2_mpyd_acc_ll_s0: T_M2_mpyd_acc <0b00, 0, 0, 0>;
2053
2054 def M2_mpyd_acc_hh_s1: T_M2_mpyd_acc <0b11, 0, 1, 0>;
2055 def M2_mpyd_acc_hl_s1: T_M2_mpyd_acc <0b10, 0, 1, 0>;
2056 def M2_mpyd_acc_lh_s1: T_M2_mpyd_acc <0b01, 0, 1, 0>;
2057 def M2_mpyd_acc_ll_s1: T_M2_mpyd_acc <0b00, 0, 1, 0>;
2058
2059 def M2_mpyd_nac_hh_s0: T_M2_mpyd_acc <0b11, 1, 0, 0>;
2060 def M2_mpyd_nac_hl_s0: T_M2_mpyd_acc <0b10, 1, 0, 0>;
2061 def M2_mpyd_nac_lh_s0: T_M2_mpyd_acc <0b01, 1, 0, 0>;
2062 def M2_mpyd_nac_ll_s0: T_M2_mpyd_acc <0b00, 1, 0, 0>;
2063
2064 def M2_mpyd_nac_hh_s1: T_M2_mpyd_acc <0b11, 1, 1, 0>;
2065 def M2_mpyd_nac_hl_s1: T_M2_mpyd_acc <0b10, 1, 1, 0>;
2066 def M2_mpyd_nac_lh_s1: T_M2_mpyd_acc <0b01, 1, 1, 0>;
2067 def M2_mpyd_nac_ll_s1: T_M2_mpyd_acc <0b00, 1, 1, 0>;
2068
2069 def M2_mpyud_acc_hh_s0: T_M2_mpyd_acc <0b11, 0, 0, 1>;
2070 def M2_mpyud_acc_hl_s0: T_M2_mpyd_acc <0b10, 0, 0, 1>;
2071 def M2_mpyud_acc_lh_s0: T_M2_mpyd_acc <0b01, 0, 0, 1>;
2072 def M2_mpyud_acc_ll_s0: T_M2_mpyd_acc <0b00, 0, 0, 1>;
2073
2074 def M2_mpyud_acc_hh_s1: T_M2_mpyd_acc <0b11, 0, 1, 1>;
2075 def M2_mpyud_acc_hl_s1: T_M2_mpyd_acc <0b10, 0, 1, 1>;
2076 def M2_mpyud_acc_lh_s1: T_M2_mpyd_acc <0b01, 0, 1, 1>;
2077 def M2_mpyud_acc_ll_s1: T_M2_mpyd_acc <0b00, 0, 1, 1>;
2078
2079 def M2_mpyud_nac_hh_s0: T_M2_mpyd_acc <0b11, 1, 0, 1>;
2080 def M2_mpyud_nac_hl_s0: T_M2_mpyd_acc <0b10, 1, 0, 1>;
2081 def M2_mpyud_nac_lh_s0: T_M2_mpyd_acc <0b01, 1, 0, 1>;
2082 def M2_mpyud_nac_ll_s0: T_M2_mpyd_acc <0b00, 1, 0, 1>;
2083
2084 def M2_mpyud_nac_hh_s1: T_M2_mpyd_acc <0b11, 1, 1, 1>;
2085 def M2_mpyud_nac_hl_s1: T_M2_mpyd_acc <0b10, 1, 1, 1>;
2086 def M2_mpyud_nac_lh_s1: T_M2_mpyd_acc <0b01, 1, 1, 1>;
2087 def M2_mpyud_nac_ll_s1: T_M2_mpyd_acc <0b00, 1, 1, 1>;
2088 }
2089
2090 let hasNewValue = 1, opNewValue = 0 in
2091 class T_MType_mpy <string mnemonic, bits<4> RegTyBits, RegisterClass RC,
2092                    bits<3> MajOp, bits<3> MinOp, bit isSat = 0, bit isRnd = 0,
2093                    string op2Suffix = "", bit isRaw = 0, bit isHi = 0 >
2094   : MInst <(outs IntRegs:$dst), (ins RC:$src1, RC:$src2),
2095   "$dst = "#mnemonic
2096            #"($src1, $src2"#op2Suffix#")"
2097            #!if(MajOp{2}, ":<<1", "")
2098            #!if(isRnd, ":rnd", "")
2099            #!if(isSat, ":sat", "")
2100            #!if(isRaw, !if(isHi, ":raw:hi", ":raw:lo"), ""), [] > {
2101     bits<5> dst;
2102     bits<5> src1;
2103     bits<5> src2;
2104
2105     let IClass = 0b1110;
2106
2107     let Inst{27-24} = RegTyBits;
2108     let Inst{23-21} = MajOp;
2109     let Inst{20-16} = src1;
2110     let Inst{13}    = 0b0;
2111     let Inst{12-8}  = src2;
2112     let Inst{7-5}   = MinOp;
2113     let Inst{4-0}   = dst;
2114   }
2115
2116 class T_MType_dd  <string mnemonic, bits<3> MajOp, bits<3> MinOp,
2117                    bit isSat = 0, bit isRnd = 0 >
2118   : T_MType_mpy <mnemonic, 0b1001, DoubleRegs, MajOp, MinOp, isSat, isRnd>;
2119
2120 class T_MType_rr1  <string mnemonic, bits<3> MajOp, bits<3> MinOp,
2121                     bit isSat = 0, bit isRnd = 0 >
2122   : T_MType_mpy<mnemonic, 0b1101, IntRegs, MajOp, MinOp, isSat, isRnd>;
2123
2124 class T_MType_rr2 <string mnemonic, bits<3> MajOp, bits<3> MinOp,
2125                    bit isSat = 0, bit isRnd = 0, string op2str = "" >
2126   : T_MType_mpy<mnemonic, 0b1101, IntRegs, MajOp, MinOp, isSat, isRnd, op2str>;
2127
2128 let CextOpcode = "mpyi", InputType = "reg", isCodeGenOnly = 0 in
2129 def M2_mpyi    : T_MType_rr1 <"mpyi", 0b000, 0b000>, ImmRegRel;
2130
2131 let isCodeGenOnly = 0 in {
2132 def M2_mpy_up  : T_MType_rr1 <"mpy",  0b000, 0b001>;
2133 def M2_mpyu_up : T_MType_rr1 <"mpyu", 0b010, 0b001>;
2134 }
2135
2136 let isCodeGenOnly = 0 in
2137 def M2_dpmpyss_rnd_s0 : T_MType_rr1 <"mpy", 0b001, 0b001, 0, 1>;
2138
2139 let isCodeGenOnly = 0 in {
2140 def M2_hmmpyh_rs1 : T_MType_rr2 <"mpy", 0b101, 0b100, 1, 1, ".h">;
2141 def M2_hmmpyl_rs1 : T_MType_rr2 <"mpy", 0b111, 0b100, 1, 1, ".l">;
2142 }
2143
2144 // V4 Instructions
2145 let isCodeGenOnly = 0 in {
2146 def M2_mpysu_up : T_MType_rr1 <"mpysu", 0b011, 0b001, 0>;
2147 def M2_mpy_up_s1_sat : T_MType_rr1 <"mpy", 0b111, 0b000, 1>;
2148
2149 def M2_hmmpyh_s1 : T_MType_rr2 <"mpy", 0b101, 0b000, 1, 0, ".h">;
2150 def M2_hmmpyl_s1 : T_MType_rr2 <"mpy", 0b101, 0b001, 1, 0, ".l">;
2151 }
2152
2153 def: Pat<(i32 (mul   I32:$src1, I32:$src2)), (M2_mpyi    I32:$src1, I32:$src2)>;
2154 def: Pat<(i32 (mulhs I32:$src1, I32:$src2)), (M2_mpy_up  I32:$src1, I32:$src2)>;
2155 def: Pat<(i32 (mulhu I32:$src1, I32:$src2)), (M2_mpyu_up I32:$src1, I32:$src2)>;
2156
2157 let hasNewValue = 1, opNewValue = 0 in
2158 class T_MType_mpy_ri <bit isNeg, Operand ImmOp, list<dag> pattern>
2159   : MInst < (outs IntRegs:$Rd), (ins IntRegs:$Rs, ImmOp:$u8),
2160   "$Rd ="#!if(isNeg, "- ", "+ ")#"mpyi($Rs, #$u8)" ,
2161    pattern, "", M_tc_3x_SLOT23> {
2162     bits<5> Rd;
2163     bits<5> Rs;
2164     bits<8> u8;
2165
2166     let IClass = 0b1110;
2167
2168     let Inst{27-24} = 0b0000;
2169     let Inst{23} = isNeg;
2170     let Inst{13} = 0b0;
2171     let Inst{4-0} = Rd;
2172     let Inst{20-16} = Rs;
2173     let Inst{12-5} = u8;
2174   }
2175
2176 let isExtendable = 1, opExtentBits = 8, opExtendable = 2, isCodeGenOnly = 0 in
2177 def M2_mpysip : T_MType_mpy_ri <0, u8Ext,
2178                 [(set (i32 IntRegs:$Rd), (mul IntRegs:$Rs, u8ExtPred:$u8))]>;
2179
2180 let isCodeGenOnly = 0 in
2181 def M2_mpysin :  T_MType_mpy_ri <1, u8Imm,
2182                 [(set (i32 IntRegs:$Rd), (ineg (mul IntRegs:$Rs,
2183                                                     u8ImmPred:$u8)))]>;
2184
2185 // Assember mapped to M2_mpyi
2186 let isAsmParserOnly = 1 in
2187 def M2_mpyui : MInst<(outs IntRegs:$dst),
2188                      (ins IntRegs:$src1, IntRegs:$src2),
2189   "$dst = mpyui($src1, $src2)">;
2190
2191 // Rd=mpyi(Rs,#m9)
2192 // s9 is NOT the same as m9 - but it works.. so far.
2193 // Assembler maps to either Rd=+mpyi(Rs,#u8) or Rd=-mpyi(Rs,#u8)
2194 // depending on the value of m9. See Arch Spec.
2195 let isExtendable = 1, opExtendable = 2, isExtentSigned = 1, opExtentBits = 9,
2196     CextOpcode = "mpyi", InputType = "imm", hasNewValue = 1 in
2197 def M2_mpysmi : MInst<(outs IntRegs:$dst), (ins IntRegs:$src1, s9Ext:$src2),
2198     "$dst = mpyi($src1, #$src2)",
2199     [(set (i32 IntRegs:$dst), (mul (i32 IntRegs:$src1),
2200                                    s9ExtPred:$src2))]>, ImmRegRel;
2201
2202 let hasNewValue = 1, isExtendable = 1,  opExtentBits = 8, opExtendable = 3,
2203     InputType = "imm" in
2204 class T_MType_acc_ri <string mnemonic, bits<3> MajOp, Operand ImmOp,
2205                       list<dag> pattern = []>
2206  : MInst < (outs IntRegs:$dst), (ins IntRegs:$src1, IntRegs:$src2, ImmOp:$src3),
2207   "$dst "#mnemonic#"($src2, #$src3)",
2208   pattern, "$src1 = $dst", M_tc_2_SLOT23> {
2209     bits<5> dst;
2210     bits<5> src2;
2211     bits<8> src3;
2212
2213     let IClass = 0b1110;
2214
2215     let Inst{27-26} = 0b00;
2216     let Inst{25-23} = MajOp;
2217     let Inst{20-16} = src2;
2218     let Inst{13} = 0b0;
2219     let Inst{12-5} = src3;
2220     let Inst{4-0} = dst;
2221   }
2222
2223 let InputType = "reg", hasNewValue = 1 in
2224 class T_MType_acc_rr <string mnemonic, bits<3> MajOp, bits<3> MinOp,
2225                       bit isSwap = 0, list<dag> pattern = [], bit hasNot = 0,
2226                       bit isSat = 0, bit isShift = 0>
2227   : MInst < (outs IntRegs:$dst),
2228             (ins IntRegs:$src1, IntRegs:$src2, IntRegs:$src3),
2229   "$dst "#mnemonic#"($src2, "#!if(hasNot, "~$src3)","$src3)")
2230                           #!if(isShift, ":<<1", "")
2231                           #!if(isSat, ":sat", ""),
2232   pattern, "$src1 = $dst", M_tc_2_SLOT23 > {
2233     bits<5> dst;
2234     bits<5> src2;
2235     bits<5> src3;
2236
2237     let IClass = 0b1110;
2238
2239     let Inst{27-24} = 0b1111;
2240     let Inst{23-21} = MajOp;
2241     let Inst{20-16} = !if(isSwap, src3, src2);
2242     let Inst{13} = 0b0;
2243     let Inst{12-8} = !if(isSwap, src2, src3);
2244     let Inst{7-5} = MinOp;
2245     let Inst{4-0} = dst;
2246   }
2247
2248 let CextOpcode = "MPYI_acc", Itinerary = M_tc_3x_SLOT23, isCodeGenOnly = 0 in {
2249   def M2_macsip : T_MType_acc_ri <"+= mpyi", 0b010, u8Ext,
2250                   [(set (i32 IntRegs:$dst),
2251                         (add (mul IntRegs:$src2, u8ExtPred:$src3),
2252                              IntRegs:$src1))]>, ImmRegRel;
2253
2254   def M2_maci   : T_MType_acc_rr <"+= mpyi", 0b000, 0b000, 0,
2255                  [(set (i32 IntRegs:$dst),
2256                        (add (mul IntRegs:$src2, IntRegs:$src3),
2257                             IntRegs:$src1))]>, ImmRegRel;
2258 }
2259
2260 let CextOpcode = "ADD_acc", isCodeGenOnly = 0 in {
2261   let isExtentSigned = 1 in
2262   def M2_accii : T_MType_acc_ri <"+= add", 0b100, s8Ext,
2263                  [(set (i32 IntRegs:$dst),
2264                        (add (add (i32 IntRegs:$src2), s8_16ExtPred:$src3),
2265                             (i32 IntRegs:$src1)))]>, ImmRegRel;
2266
2267   def M2_acci  : T_MType_acc_rr <"+= add",  0b000, 0b001, 0,
2268                  [(set (i32 IntRegs:$dst),
2269                        (add (add (i32 IntRegs:$src2), (i32 IntRegs:$src3)),
2270                             (i32 IntRegs:$src1)))]>, ImmRegRel;
2271 }
2272
2273 let CextOpcode = "SUB_acc", isCodeGenOnly = 0 in {
2274   let isExtentSigned = 1 in
2275   def M2_naccii : T_MType_acc_ri <"-= add", 0b101, s8Ext>, ImmRegRel;
2276
2277   def M2_nacci  : T_MType_acc_rr <"-= add",  0b100, 0b001, 0>, ImmRegRel;
2278 }
2279
2280 let Itinerary = M_tc_3x_SLOT23, isCodeGenOnly = 0 in
2281 def M2_macsin : T_MType_acc_ri <"-= mpyi", 0b011, u8Ext>;
2282
2283 let isCodeGenOnly = 0 in {
2284 def M2_xor_xacc : T_MType_acc_rr < "^= xor", 0b100, 0b011, 0>;
2285 def M2_subacc : T_MType_acc_rr <"+= sub",  0b000, 0b011, 1>;
2286 }
2287
2288 class T_MType_acc_pat1 <InstHexagon MI, SDNode firstOp, SDNode secOp,
2289                         PatLeaf ImmPred>
2290   : Pat <(secOp IntRegs:$src1, (firstOp IntRegs:$src2, ImmPred:$src3)),
2291          (MI IntRegs:$src1, IntRegs:$src2, ImmPred:$src3)>;
2292
2293 class T_MType_acc_pat2 <InstHexagon MI, SDNode firstOp, SDNode secOp>
2294   : Pat <(i32 (secOp IntRegs:$src1, (firstOp IntRegs:$src2, IntRegs:$src3))),
2295          (MI IntRegs:$src1, IntRegs:$src2, IntRegs:$src3)>;
2296
2297 def : T_MType_acc_pat2 <M2_xor_xacc, xor, xor>;
2298 def : T_MType_acc_pat1 <M2_macsin, mul, sub, u8ExtPred>;
2299
2300 def : T_MType_acc_pat1 <M2_naccii, add, sub, s8_16ExtPred>;
2301 def : T_MType_acc_pat2 <M2_nacci, add, sub>;
2302 //===----------------------------------------------------------------------===//
2303 // Template Class -- Multiply signed/unsigned halfwords with and without
2304 // saturation and rounding
2305 //===----------------------------------------------------------------------===//
2306 class T_M2_mpyd < bits<2> LHbits, bit isRnd, bit hasShift, bit isUnsigned >
2307   : MInst < (outs DoubleRegs:$Rdd), (ins IntRegs:$Rs, IntRegs:$Rt),
2308   "$Rdd = "#!if(isUnsigned,"mpyu","mpy")#"($Rs."#!if(LHbits{1},"h","l")
2309                                        #", $Rt."#!if(LHbits{0},"h)","l)")
2310                                        #!if(hasShift,":<<1","")
2311                                        #!if(isRnd,":rnd",""),
2312   [] > {
2313     bits<5> Rdd;
2314     bits<5> Rs;
2315     bits<5> Rt;
2316
2317     let IClass = 0b1110;
2318
2319     let Inst{27-24} = 0b0100;
2320     let Inst{23} = hasShift;
2321     let Inst{22} = isUnsigned;
2322     let Inst{21} = isRnd;
2323     let Inst{6-5} = LHbits;
2324     let Inst{4-0} = Rdd;
2325     let Inst{20-16} = Rs;
2326     let Inst{12-8} = Rt;
2327 }
2328
2329 let isCodeGenOnly = 0 in {
2330 def M2_mpyd_hh_s0: T_M2_mpyd<0b11, 0, 0, 0>;
2331 def M2_mpyd_hl_s0: T_M2_mpyd<0b10, 0, 0, 0>;
2332 def M2_mpyd_lh_s0: T_M2_mpyd<0b01, 0, 0, 0>;
2333 def M2_mpyd_ll_s0: T_M2_mpyd<0b00, 0, 0, 0>;
2334
2335 def M2_mpyd_hh_s1: T_M2_mpyd<0b11, 0, 1, 0>;
2336 def M2_mpyd_hl_s1: T_M2_mpyd<0b10, 0, 1, 0>;
2337 def M2_mpyd_lh_s1: T_M2_mpyd<0b01, 0, 1, 0>;
2338 def M2_mpyd_ll_s1: T_M2_mpyd<0b00, 0, 1, 0>;
2339
2340 def M2_mpyd_rnd_hh_s0: T_M2_mpyd<0b11, 1, 0, 0>;
2341 def M2_mpyd_rnd_hl_s0: T_M2_mpyd<0b10, 1, 0, 0>;
2342 def M2_mpyd_rnd_lh_s0: T_M2_mpyd<0b01, 1, 0, 0>;
2343 def M2_mpyd_rnd_ll_s0: T_M2_mpyd<0b00, 1, 0, 0>;
2344
2345 def M2_mpyd_rnd_hh_s1: T_M2_mpyd<0b11, 1, 1, 0>;
2346 def M2_mpyd_rnd_hl_s1: T_M2_mpyd<0b10, 1, 1, 0>;
2347 def M2_mpyd_rnd_lh_s1: T_M2_mpyd<0b01, 1, 1, 0>;
2348 def M2_mpyd_rnd_ll_s1: T_M2_mpyd<0b00, 1, 1, 0>;
2349
2350 //Rdd=mpyu(Rs.[HL],Rt.[HL])[:<<1]
2351 def M2_mpyud_hh_s0: T_M2_mpyd<0b11, 0, 0, 1>;
2352 def M2_mpyud_hl_s0: T_M2_mpyd<0b10, 0, 0, 1>;
2353 def M2_mpyud_lh_s0: T_M2_mpyd<0b01, 0, 0, 1>;
2354 def M2_mpyud_ll_s0: T_M2_mpyd<0b00, 0, 0, 1>;
2355
2356 def M2_mpyud_hh_s1: T_M2_mpyd<0b11, 0, 1, 1>;
2357 def M2_mpyud_hl_s1: T_M2_mpyd<0b10, 0, 1, 1>;
2358 def M2_mpyud_lh_s1: T_M2_mpyd<0b01, 0, 1, 1>;
2359 def M2_mpyud_ll_s1: T_M2_mpyd<0b00, 0, 1, 1>;
2360 }
2361 //===----------------------------------------------------------------------===//
2362 // Template Class for xtype mpy:
2363 // Vector multiply
2364 // Complex multiply
2365 // multiply 32X32 and use full result
2366 //===----------------------------------------------------------------------===//
2367 let hasSideEffects = 0 in
2368 class T_XTYPE_mpy64 <string mnemonic, bits<3> MajOp, bits<3> MinOp,
2369                      bit isSat, bit hasShift, bit isConj>
2370    : MInst <(outs DoubleRegs:$Rdd),
2371             (ins IntRegs:$Rs, IntRegs:$Rt),
2372   "$Rdd = "#mnemonic#"($Rs, $Rt"#!if(isConj,"*)",")")
2373                                 #!if(hasShift,":<<1","")
2374                                 #!if(isSat,":sat",""),
2375   [] > {
2376     bits<5> Rdd;
2377     bits<5> Rs;
2378     bits<5> Rt;
2379
2380     let IClass = 0b1110;
2381
2382     let Inst{27-24} = 0b0101;
2383     let Inst{23-21} = MajOp;
2384     let Inst{20-16} = Rs;
2385     let Inst{12-8} = Rt;
2386     let Inst{7-5} = MinOp;
2387     let Inst{4-0} = Rdd;
2388   }
2389
2390 //===----------------------------------------------------------------------===//
2391 // Template Class for xtype mpy with accumulation into 64-bit:
2392 // Vector multiply
2393 // Complex multiply
2394 // multiply 32X32 and use full result
2395 //===----------------------------------------------------------------------===//
2396 class T_XTYPE_mpy64_acc <string op1, string op2, bits<3> MajOp, bits<3> MinOp,
2397                          bit isSat, bit hasShift, bit isConj>
2398   : MInst <(outs DoubleRegs:$Rxx),
2399            (ins DoubleRegs:$dst2, IntRegs:$Rs, IntRegs:$Rt),
2400   "$Rxx "#op2#"= "#op1#"($Rs, $Rt"#!if(isConj,"*)",")")
2401                                    #!if(hasShift,":<<1","")
2402                                    #!if(isSat,":sat",""),
2403
2404   [] , "$dst2 = $Rxx" > {
2405     bits<5> Rxx;
2406     bits<5> Rs;
2407     bits<5> Rt;
2408
2409     let IClass = 0b1110;
2410
2411     let Inst{27-24} = 0b0111;
2412     let Inst{23-21} = MajOp;
2413     let Inst{20-16} = Rs;
2414     let Inst{12-8} = Rt;
2415     let Inst{7-5} = MinOp;
2416     let Inst{4-0} = Rxx;
2417   }
2418
2419 // MPY - Multiply and use full result
2420 // Rdd = mpy[u](Rs,Rt)
2421 let isCodeGenOnly = 0 in {
2422 def M2_dpmpyss_s0 : T_XTYPE_mpy64 < "mpy", 0b000, 0b000, 0, 0, 0>;
2423 def M2_dpmpyuu_s0 : T_XTYPE_mpy64 < "mpyu", 0b010, 0b000, 0, 0, 0>;
2424
2425 // Rxx[+-]= mpy[u](Rs,Rt)
2426 def M2_dpmpyss_acc_s0 : T_XTYPE_mpy64_acc < "mpy",  "+", 0b000, 0b000, 0, 0, 0>;
2427 def M2_dpmpyss_nac_s0 : T_XTYPE_mpy64_acc < "mpy",  "-", 0b001, 0b000, 0, 0, 0>;
2428 def M2_dpmpyuu_acc_s0 : T_XTYPE_mpy64_acc < "mpyu", "+", 0b010, 0b000, 0, 0, 0>;
2429 def M2_dpmpyuu_nac_s0 : T_XTYPE_mpy64_acc < "mpyu", "-", 0b011, 0b000, 0, 0, 0>;
2430 }
2431
2432 def: Pat<(i64 (mul (i64 (anyext (i32 IntRegs:$src1))),
2433                    (i64 (anyext (i32 IntRegs:$src2))))),
2434          (M2_dpmpyuu_s0 IntRegs:$src1, IntRegs:$src2)>;
2435
2436 def: Pat<(i64 (mul (i64 (sext (i32 IntRegs:$src1))),
2437                    (i64 (sext (i32 IntRegs:$src2))))),
2438          (M2_dpmpyss_s0 IntRegs:$src1, IntRegs:$src2)>;
2439
2440 def: Pat<(i64 (mul (is_sext_i32:$src1),
2441                    (is_sext_i32:$src2))),
2442          (M2_dpmpyss_s0 (LoReg DoubleRegs:$src1), (LoReg DoubleRegs:$src2))>;
2443
2444 // Multiply and accumulate, use full result.
2445 // Rxx[+-]=mpy(Rs,Rt)
2446
2447 def: Pat<(i64 (add (i64 DoubleRegs:$src1),
2448                    (mul (i64 (sext (i32 IntRegs:$src2))),
2449                         (i64 (sext (i32 IntRegs:$src3)))))),
2450          (M2_dpmpyss_acc_s0 DoubleRegs:$src1, IntRegs:$src2, IntRegs:$src3)>;
2451
2452 def: Pat<(i64 (sub (i64 DoubleRegs:$src1),
2453                    (mul (i64 (sext (i32 IntRegs:$src2))),
2454                         (i64 (sext (i32 IntRegs:$src3)))))),
2455          (M2_dpmpyss_nac_s0 DoubleRegs:$src1, IntRegs:$src2, IntRegs:$src3)>;
2456
2457 def: Pat<(i64 (add (i64 DoubleRegs:$src1),
2458                    (mul (i64 (anyext (i32 IntRegs:$src2))),
2459                         (i64 (anyext (i32 IntRegs:$src3)))))),
2460          (M2_dpmpyuu_acc_s0 DoubleRegs:$src1, IntRegs:$src2, IntRegs:$src3)>;
2461
2462 def: Pat<(i64 (add (i64 DoubleRegs:$src1),
2463                    (mul (i64 (zext (i32 IntRegs:$src2))),
2464                         (i64 (zext (i32 IntRegs:$src3)))))),
2465          (M2_dpmpyuu_acc_s0 DoubleRegs:$src1, IntRegs:$src2, IntRegs:$src3)>;
2466
2467 def: Pat<(i64 (sub (i64 DoubleRegs:$src1),
2468                    (mul (i64 (anyext (i32 IntRegs:$src2))),
2469                         (i64 (anyext (i32 IntRegs:$src3)))))),
2470          (M2_dpmpyuu_nac_s0 DoubleRegs:$src1, IntRegs:$src2, IntRegs:$src3)>;
2471
2472 def: Pat<(i64 (sub (i64 DoubleRegs:$src1),
2473                    (mul (i64 (zext (i32 IntRegs:$src2))),
2474                         (i64 (zext (i32 IntRegs:$src3)))))),
2475          (M2_dpmpyuu_nac_s0 DoubleRegs:$src1, IntRegs:$src2, IntRegs:$src3)>;
2476
2477 //===----------------------------------------------------------------------===//
2478 // MTYPE/MPYH -
2479 //===----------------------------------------------------------------------===//
2480
2481 //===----------------------------------------------------------------------===//
2482 // MTYPE/MPYS +
2483 //===----------------------------------------------------------------------===//
2484 //===----------------------------------------------------------------------===//
2485 // MTYPE/MPYS -
2486 //===----------------------------------------------------------------------===//
2487
2488 //===----------------------------------------------------------------------===//
2489 // MTYPE/VB +
2490 //===----------------------------------------------------------------------===//
2491 //===----------------------------------------------------------------------===//
2492 // MTYPE/VB -
2493 //===----------------------------------------------------------------------===//
2494
2495 //===----------------------------------------------------------------------===//
2496 // MTYPE/VH  +
2497 //===----------------------------------------------------------------------===//
2498 //===----------------------------------------------------------------------===//
2499 // MTYPE/VH  -
2500 //===----------------------------------------------------------------------===//
2501
2502 //===----------------------------------------------------------------------===//
2503 // ST +
2504 //===----------------------------------------------------------------------===//
2505 ///
2506 // Store doubleword.
2507
2508 //===----------------------------------------------------------------------===//
2509 // Post increment store
2510 //===----------------------------------------------------------------------===//
2511
2512 multiclass ST_PostInc_Pbase<string mnemonic, RegisterClass RC, Operand ImmOp,
2513                             bit isNot, bit isPredNew> {
2514   let isPredicatedNew = isPredNew in
2515   def NAME : STInst2PI<(outs IntRegs:$dst),
2516             (ins PredRegs:$src1, IntRegs:$src2, ImmOp:$offset, RC:$src3),
2517             !if(isNot, "if (!$src1", "if ($src1")#!if(isPredNew, ".new) ",
2518             ") ")#mnemonic#"($src2++#$offset) = $src3",
2519             [],
2520             "$src2 = $dst">;
2521 }
2522
2523 multiclass ST_PostInc_Pred<string mnemonic, RegisterClass RC,
2524                            Operand ImmOp, bit PredNot> {
2525   let isPredicatedFalse = PredNot in {
2526     defm _c#NAME : ST_PostInc_Pbase<mnemonic, RC, ImmOp, PredNot, 0>;
2527     // Predicate new
2528     let Predicates = [HasV4T], validSubTargets = HasV4SubT in
2529     defm _cdn#NAME#_V4 : ST_PostInc_Pbase<mnemonic, RC, ImmOp, PredNot, 1>;
2530   }
2531 }
2532
2533 let hasCtrlDep = 1, isNVStorable = 1, hasSideEffects = 0 in
2534 multiclass ST_PostInc<string mnemonic, string BaseOp, RegisterClass RC,
2535                       Operand ImmOp> {
2536
2537   let hasCtrlDep = 1, BaseOpcode = "POST_"#BaseOp in {
2538     let isPredicable = 1 in
2539     def NAME : STInst2PI<(outs IntRegs:$dst),
2540                 (ins IntRegs:$src1, ImmOp:$offset, RC:$src2),
2541                 mnemonic#"($src1++#$offset) = $src2",
2542                 [],
2543                 "$src1 = $dst">;
2544
2545     let isPredicated = 1 in {
2546       defm Pt : ST_PostInc_Pred<mnemonic, RC, ImmOp, 0 >;
2547       defm NotPt : ST_PostInc_Pred<mnemonic, RC, ImmOp, 1 >;
2548     }
2549   }
2550 }
2551
2552 defm POST_STbri: ST_PostInc <"memb", "STrib", IntRegs, s4_0Imm>, AddrModeRel;
2553 defm POST_SThri: ST_PostInc <"memh", "STrih", IntRegs, s4_1Imm>, AddrModeRel;
2554 defm POST_STwri: ST_PostInc <"memw", "STriw", IntRegs, s4_2Imm>, AddrModeRel;
2555
2556 let isNVStorable = 0 in
2557 defm POST_STdri: ST_PostInc <"memd", "STrid", DoubleRegs, s4_3Imm>, AddrModeRel;
2558
2559 def : Pat<(post_truncsti8 (i32 IntRegs:$src1), IntRegs:$src2,
2560                            s4_3ImmPred:$offset),
2561           (POST_STbri IntRegs:$src2, s4_0ImmPred:$offset, IntRegs:$src1)>;
2562
2563 def : Pat<(post_truncsti16 (i32 IntRegs:$src1), IntRegs:$src2,
2564                             s4_3ImmPred:$offset),
2565           (POST_SThri IntRegs:$src2, s4_1ImmPred:$offset, IntRegs:$src1)>;
2566
2567 def : Pat<(post_store (i32 IntRegs:$src1), IntRegs:$src2, s4_2ImmPred:$offset),
2568           (POST_STwri IntRegs:$src2, s4_1ImmPred:$offset, IntRegs:$src1)>;
2569
2570 def : Pat<(post_store (i64 DoubleRegs:$src1), IntRegs:$src2,
2571                        s4_3ImmPred:$offset),
2572           (POST_STdri IntRegs:$src2, s4_3ImmPred:$offset, DoubleRegs:$src1)>;
2573
2574 //===----------------------------------------------------------------------===//
2575 // multiclass for the store instructions with MEMri operand.
2576 //===----------------------------------------------------------------------===//
2577 multiclass ST_MEMri_Pbase<string mnemonic, RegisterClass RC, bit isNot,
2578                           bit isPredNew> {
2579   let isPredicatedNew = isPredNew in
2580   def NAME : STInst2<(outs),
2581             (ins PredRegs:$src1, MEMri:$addr, RC: $src2),
2582             !if(isNot, "if (!$src1", "if ($src1")#!if(isPredNew, ".new) ",
2583             ") ")#mnemonic#"($addr) = $src2",
2584             []>;
2585 }
2586
2587 multiclass ST_MEMri_Pred<string mnemonic, RegisterClass RC, bit PredNot> {
2588   let isPredicatedFalse = PredNot in {
2589     defm _c#NAME : ST_MEMri_Pbase<mnemonic, RC, PredNot, 0>;
2590
2591     // Predicate new
2592     let validSubTargets = HasV4SubT, Predicates = [HasV4T] in
2593     defm _cdn#NAME#_V4 : ST_MEMri_Pbase<mnemonic, RC, PredNot, 1>;
2594   }
2595 }
2596
2597 let isExtendable = 1, isNVStorable = 1, hasSideEffects = 0 in
2598 multiclass ST_MEMri<string mnemonic, string CextOp, RegisterClass RC,
2599                     bits<5> ImmBits, bits<5> PredImmBits> {
2600
2601   let CextOpcode = CextOp, BaseOpcode = CextOp in {
2602     let opExtendable = 1, isExtentSigned = 1, opExtentBits = ImmBits,
2603          isPredicable = 1 in
2604     def NAME : STInst2<(outs),
2605             (ins MEMri:$addr, RC:$src),
2606             mnemonic#"($addr) = $src",
2607             []>;
2608
2609     let opExtendable = 2, isExtentSigned = 0, opExtentBits = PredImmBits,
2610         isPredicated = 1 in {
2611       defm Pt : ST_MEMri_Pred<mnemonic, RC, 0>;
2612       defm NotPt : ST_MEMri_Pred<mnemonic, RC, 1>;
2613     }
2614   }
2615 }
2616
2617 let addrMode = BaseImmOffset, isMEMri = "true" in {
2618   let accessSize = ByteAccess in
2619     defm STrib: ST_MEMri < "memb", "STrib", IntRegs, 11, 6>, AddrModeRel;
2620
2621   let accessSize = HalfWordAccess in
2622     defm STrih: ST_MEMri < "memh", "STrih", IntRegs, 12, 7>, AddrModeRel;
2623
2624   let accessSize = WordAccess in
2625     defm STriw: ST_MEMri < "memw", "STriw", IntRegs, 13, 8>, AddrModeRel;
2626
2627   let accessSize = DoubleWordAccess, isNVStorable = 0 in
2628     defm STrid: ST_MEMri < "memd", "STrid", DoubleRegs, 14, 9>, AddrModeRel;
2629 }
2630
2631 def : Pat<(truncstorei8 (i32 IntRegs:$src1), ADDRriS11_0:$addr),
2632           (STrib ADDRriS11_0:$addr, (i32 IntRegs:$src1))>;
2633
2634 def : Pat<(truncstorei16 (i32 IntRegs:$src1), ADDRriS11_1:$addr),
2635           (STrih ADDRriS11_1:$addr, (i32 IntRegs:$src1))>;
2636
2637 def : Pat<(store (i32 IntRegs:$src1), ADDRriS11_2:$addr),
2638           (STriw ADDRriS11_2:$addr, (i32 IntRegs:$src1))>;
2639
2640 def : Pat<(store (i64 DoubleRegs:$src1), ADDRriS11_3:$addr),
2641           (STrid ADDRriS11_3:$addr, (i64 DoubleRegs:$src1))>;
2642
2643
2644 //===----------------------------------------------------------------------===//
2645 // multiclass for the store instructions with base+immediate offset
2646 // addressing mode
2647 //===----------------------------------------------------------------------===//
2648 multiclass ST_Idxd_Pbase<string mnemonic, RegisterClass RC, Operand predImmOp,
2649                         bit isNot, bit isPredNew> {
2650   let isPredicatedNew = isPredNew in
2651   def NAME : STInst2<(outs),
2652             (ins PredRegs:$src1, IntRegs:$src2, predImmOp:$src3, RC: $src4),
2653             !if(isNot, "if (!$src1", "if ($src1")#!if(isPredNew, ".new) ",
2654             ") ")#mnemonic#"($src2+#$src3) = $src4",
2655             []>;
2656 }
2657
2658 multiclass ST_Idxd_Pred<string mnemonic, RegisterClass RC, Operand predImmOp,
2659                         bit PredNot> {
2660   let isPredicatedFalse = PredNot, isPredicated = 1 in {
2661     defm _c#NAME : ST_Idxd_Pbase<mnemonic, RC, predImmOp, PredNot, 0>;
2662
2663     // Predicate new
2664     let validSubTargets = HasV4SubT, Predicates = [HasV4T] in
2665     defm _cdn#NAME#_V4 : ST_Idxd_Pbase<mnemonic, RC, predImmOp, PredNot, 1>;
2666   }
2667 }
2668
2669 let isExtendable = 1, isNVStorable = 1, hasSideEffects = 0 in
2670 multiclass ST_Idxd<string mnemonic, string CextOp, RegisterClass RC,
2671                    Operand ImmOp, Operand predImmOp, bits<5> ImmBits,
2672                    bits<5> PredImmBits> {
2673
2674   let CextOpcode = CextOp, BaseOpcode = CextOp#_indexed in {
2675     let opExtendable = 1, isExtentSigned = 1, opExtentBits = ImmBits,
2676          isPredicable = 1 in
2677     def NAME : STInst2<(outs),
2678             (ins IntRegs:$src1, ImmOp:$src2, RC:$src3),
2679             mnemonic#"($src1+#$src2) = $src3",
2680             []>;
2681
2682     let opExtendable = 2, isExtentSigned = 0, opExtentBits = PredImmBits in {
2683       defm Pt : ST_Idxd_Pred<mnemonic, RC, predImmOp, 0>;
2684       defm NotPt : ST_Idxd_Pred<mnemonic, RC, predImmOp, 1>;
2685     }
2686   }
2687 }
2688
2689 let addrMode = BaseImmOffset, InputType = "reg" in {
2690   let accessSize = ByteAccess in
2691     defm STrib_indexed: ST_Idxd < "memb", "STrib", IntRegs, s11_0Ext,
2692                                   u6_0Ext, 11, 6>, AddrModeRel, ImmRegRel;
2693
2694   let accessSize = HalfWordAccess in
2695     defm STrih_indexed: ST_Idxd < "memh", "STrih", IntRegs, s11_1Ext,
2696                                   u6_1Ext, 12, 7>, AddrModeRel, ImmRegRel;
2697
2698   let accessSize = WordAccess in
2699     defm STriw_indexed: ST_Idxd < "memw", "STriw", IntRegs, s11_2Ext,
2700                                   u6_2Ext, 13, 8>, AddrModeRel, ImmRegRel;
2701
2702   let accessSize = DoubleWordAccess, isNVStorable = 0 in
2703     defm STrid_indexed: ST_Idxd < "memd", "STrid", DoubleRegs, s11_3Ext,
2704                                   u6_3Ext, 14, 9>, AddrModeRel;
2705 }
2706
2707 let AddedComplexity = 10 in {
2708 def : Pat<(truncstorei8 (i32 IntRegs:$src1), (add IntRegs:$src2,
2709                                                   s11_0ExtPred:$offset)),
2710           (STrib_indexed IntRegs:$src2, s11_0ImmPred:$offset,
2711                          (i32 IntRegs:$src1))>;
2712
2713 def : Pat<(truncstorei16 (i32 IntRegs:$src1), (add IntRegs:$src2,
2714                                                    s11_1ExtPred:$offset)),
2715           (STrih_indexed IntRegs:$src2, s11_1ImmPred:$offset,
2716                          (i32 IntRegs:$src1))>;
2717
2718 def : Pat<(store (i32 IntRegs:$src1), (add IntRegs:$src2,
2719                                            s11_2ExtPred:$offset)),
2720           (STriw_indexed IntRegs:$src2, s11_2ImmPred:$offset,
2721                          (i32 IntRegs:$src1))>;
2722
2723 def : Pat<(store (i64 DoubleRegs:$src1), (add IntRegs:$src2,
2724                                               s11_3ExtPred:$offset)),
2725           (STrid_indexed IntRegs:$src2, s11_3ImmPred:$offset,
2726                          (i64 DoubleRegs:$src1))>;
2727 }
2728
2729 // memh(Rx++#s4:1)=Rt.H
2730
2731 // Store word.
2732 // Store predicate.
2733 let Defs = [R10,R11,D5], hasSideEffects = 0 in
2734 def STriw_pred : STInst2<(outs),
2735             (ins MEMri:$addr, PredRegs:$src1),
2736             "Error; should not emit",
2737             []>;
2738
2739 // Allocate stack frame.
2740 let Defs = [R29, R30], Uses = [R31, R30], hasSideEffects = 0 in {
2741   def ALLOCFRAME : STInst2<(outs),
2742              (ins i32imm:$amt),
2743              "allocframe(#$amt)",
2744              []>;
2745 }
2746 //===----------------------------------------------------------------------===//
2747 // ST -
2748 //===----------------------------------------------------------------------===//
2749
2750 //===----------------------------------------------------------------------===//
2751 // STYPE/ALU +
2752 //===----------------------------------------------------------------------===//
2753 // Logical NOT.
2754 def NOT_rr64 : ALU64_rr<(outs DoubleRegs:$dst), (ins DoubleRegs:$src1),
2755                "$dst = not($src1)",
2756                [(set (i64 DoubleRegs:$dst), (not (i64 DoubleRegs:$src1)))]>;
2757
2758
2759 //===----------------------------------------------------------------------===//
2760 // STYPE/ALU -
2761 //===----------------------------------------------------------------------===//
2762
2763 let hasSideEffects = 0 in
2764 class T_S2op_1 <string mnemonic, bits<4> RegTyBits, RegisterClass RCOut,
2765                 RegisterClass RCIn, bits<2> MajOp, bits<3> MinOp, bit isSat>
2766   : SInst <(outs RCOut:$dst), (ins RCIn:$src),
2767   "$dst = "#mnemonic#"($src)"#!if(isSat, ":sat", ""),
2768   [], "", S_2op_tc_1_SLOT23 > {
2769     bits<5> dst;
2770     bits<5> src;
2771
2772     let IClass = 0b1000;
2773
2774     let Inst{27-24} = RegTyBits;
2775     let Inst{23-22} = MajOp;
2776     let Inst{21} = 0b0;
2777     let Inst{20-16} = src;
2778     let Inst{7-5} = MinOp;
2779     let Inst{4-0} = dst;
2780   }
2781
2782 class T_S2op_1_di <string mnemonic, bits<2> MajOp, bits<3> MinOp>
2783   : T_S2op_1 <mnemonic, 0b0100, DoubleRegs, IntRegs, MajOp, MinOp, 0>;
2784
2785 let hasNewValue = 1 in
2786 class T_S2op_1_id <string mnemonic, bits<2> MajOp, bits<3> MinOp, bit isSat = 0>
2787   : T_S2op_1 <mnemonic, 0b1000, IntRegs, DoubleRegs, MajOp, MinOp, isSat>;
2788
2789 let hasNewValue = 1 in
2790 class T_S2op_1_ii <string mnemonic, bits<2> MajOp, bits<3> MinOp, bit isSat = 0>
2791   : T_S2op_1 <mnemonic, 0b1100, IntRegs, IntRegs, MajOp, MinOp, isSat>;
2792
2793 // Sign extend word to doubleword
2794 let isCodeGenOnly = 0 in
2795 def A2_sxtw   : T_S2op_1_di <"sxtw", 0b01, 0b000>;
2796
2797 def: Pat <(i64 (sext I32:$src)), (A2_sxtw I32:$src)>;
2798
2799 // Swizzle the bytes of a word
2800 let isCodeGenOnly = 0 in
2801 def A2_swiz : T_S2op_1_ii <"swiz", 0b10, 0b111>;
2802
2803 // Saturate
2804 let Defs = [USR_OVF], isCodeGenOnly = 0 in {
2805   def A2_sat   : T_S2op_1_id <"sat", 0b11, 0b000>;
2806   def A2_satb  : T_S2op_1_ii <"satb", 0b11, 0b111>;
2807   def A2_satub : T_S2op_1_ii <"satub", 0b11, 0b110>;
2808   def A2_sath  : T_S2op_1_ii <"sath", 0b11, 0b100>;
2809   def A2_satuh : T_S2op_1_ii <"satuh", 0b11, 0b101>;
2810 }
2811
2812 let Itinerary = S_2op_tc_2_SLOT23, isCodeGenOnly = 0 in {
2813   // Absolute value word
2814   def A2_abs    : T_S2op_1_ii <"abs", 0b10, 0b100>;
2815
2816   let Defs = [USR_OVF] in
2817   def A2_abssat : T_S2op_1_ii <"abs", 0b10, 0b101, 1>;
2818
2819   // Negate with saturation
2820   let Defs = [USR_OVF] in
2821   def A2_negsat : T_S2op_1_ii <"neg", 0b10, 0b110, 1>;
2822 }
2823
2824 def: Pat<(i32 (select (i1 (setlt (i32 IntRegs:$src), 0)),
2825                       (i32 (sub 0, (i32 IntRegs:$src))),
2826                       (i32 IntRegs:$src))),
2827          (A2_abs IntRegs:$src)>;
2828
2829 let AddedComplexity = 50 in
2830 def: Pat<(i32 (xor (add (sra (i32 IntRegs:$src), (i32 31)),
2831                         (i32 IntRegs:$src)),
2832                    (sra (i32 IntRegs:$src), (i32 31)))),
2833          (A2_abs IntRegs:$src)>;
2834
2835 class T_S2op_2 <string mnemonic, bits<4> RegTyBits, RegisterClass RCOut,
2836                 RegisterClass RCIn, bits<3> MajOp, bits<3> MinOp,
2837                 bit isSat, bit isRnd, list<dag> pattern = []>
2838   : SInst <(outs RCOut:$dst),
2839   (ins RCIn:$src, u5Imm:$u5),
2840   "$dst = "#mnemonic#"($src, #$u5)"#!if(isSat, ":sat", "")
2841                                    #!if(isRnd, ":rnd", ""),
2842   pattern, "", S_2op_tc_2_SLOT23> {
2843     bits<5> dst;
2844     bits<5> src;
2845     bits<5> u5;
2846
2847     let IClass = 0b1000;
2848
2849     let Inst{27-24} = RegTyBits;
2850     let Inst{23-21} = MajOp;
2851     let Inst{20-16} = src;
2852     let Inst{13} = 0b0;
2853     let Inst{12-8} = u5;
2854     let Inst{7-5} = MinOp;
2855     let Inst{4-0} = dst;
2856   }
2857
2858 let hasNewValue = 1 in
2859 class T_S2op_2_ii <string mnemonic, bits<3> MajOp, bits<3> MinOp,
2860                    bit isSat = 0, bit isRnd = 0, list<dag> pattern = []>
2861   : T_S2op_2 <mnemonic, 0b1100, IntRegs, IntRegs, MajOp, MinOp,
2862               isSat, isRnd, pattern>;
2863
2864 class T_S2op_shift <string mnemonic, bits<3> MajOp, bits<3> MinOp, SDNode OpNd>
2865   : T_S2op_2_ii <mnemonic, MajOp, MinOp, 0, 0,
2866     [(set (i32 IntRegs:$dst), (OpNd (i32 IntRegs:$src),
2867                                     (u5ImmPred:$u5)))]>;
2868
2869 // Arithmetic/logical shift right/left by immediate
2870 let Itinerary = S_2op_tc_1_SLOT23, isCodeGenOnly = 0 in {
2871   def S2_asr_i_r : T_S2op_shift <"asr", 0b000, 0b000, sra>;
2872   def S2_lsr_i_r : T_S2op_shift <"lsr", 0b000, 0b001, srl>;
2873   def S2_asl_i_r : T_S2op_shift <"asl", 0b000, 0b010, shl>;
2874 }
2875
2876 // Shift left by immediate with saturation
2877 let Defs = [USR_OVF], isCodeGenOnly = 0 in
2878 def S2_asl_i_r_sat : T_S2op_2_ii <"asl", 0b010, 0b010, 1>;
2879
2880 // Shift right with round
2881 let isCodeGenOnly = 0 in
2882 def S2_asr_i_r_rnd : T_S2op_2_ii <"asr", 0b010, 0b000, 0, 1>;
2883
2884 def: Pat<(i32 (sra (i32 (add (i32 (sra I32:$src1, u5ImmPred:$src2)),
2885                              (i32 1))),
2886                    (i32 1))),
2887          (S2_asr_i_r_rnd IntRegs:$src1, u5ImmPred:$src2)>;
2888
2889 class T_S2op_3<string opc, bits<2>MajOp, bits<3>minOp, bits<1> sat = 0>
2890   : SInst<(outs DoubleRegs:$Rdd), (ins DoubleRegs:$Rss),
2891            "$Rdd = "#opc#"($Rss)"#!if(!eq(sat, 1),":sat","")> {
2892   bits<5> Rss;
2893   bits<5> Rdd;
2894   let IClass = 0b1000;
2895   let Inst{27-24} = 0;
2896   let Inst{23-22} = MajOp;
2897   let Inst{20-16} = Rss;
2898   let Inst{7-5} = minOp;
2899   let Inst{4-0} = Rdd;
2900 }
2901
2902 let isCodeGenOnly = 0 in {
2903 def A2_absp : T_S2op_3 <"abs", 0b10, 0b110>;
2904 def A2_negp : T_S2op_3 <"neg", 0b10, 0b101>;
2905 def A2_notp : T_S2op_3 <"not", 0b10, 0b100>;
2906 }
2907
2908 // Innterleave/deinterleave
2909 let isCodeGenOnly = 0 in {
2910 def S2_interleave   : T_S2op_3 <"interleave",   0b11, 0b101>;
2911 def S2_deinterleave : T_S2op_3 <"deinterleave", 0b11, 0b100>;
2912 }
2913
2914 //===----------------------------------------------------------------------===//
2915 // STYPE/BIT +
2916 //===----------------------------------------------------------------------===//
2917 // Bit count
2918
2919 let hasSideEffects = 0, hasNewValue = 1 in
2920 class T_COUNT_LEADING<string MnOp, bits<3> MajOp, bits<3> MinOp, bit Is32,
2921                 dag Out, dag Inp>
2922     : SInst<Out, Inp, "$Rd = "#MnOp#"($Rs)", [], "", S_2op_tc_1_SLOT23> {
2923   bits<5> Rs;
2924   bits<5> Rd;
2925   let IClass = 0b1000;
2926   let Inst{27} = 0b1;
2927   let Inst{26} = Is32;
2928   let Inst{25-24} = 0b00;
2929   let Inst{23-21} = MajOp;
2930   let Inst{20-16} = Rs;
2931   let Inst{7-5} = MinOp;
2932   let Inst{4-0} = Rd;
2933 }
2934
2935 class T_COUNT_LEADING_32<string MnOp, bits<3> MajOp, bits<3> MinOp>
2936     : T_COUNT_LEADING<MnOp, MajOp, MinOp, 0b1,
2937                       (outs IntRegs:$Rd), (ins IntRegs:$Rs)>;
2938
2939 class T_COUNT_LEADING_64<string MnOp, bits<3> MajOp, bits<3> MinOp>
2940     : T_COUNT_LEADING<MnOp, MajOp, MinOp, 0b0,
2941                       (outs IntRegs:$Rd), (ins DoubleRegs:$Rs)>;
2942
2943 let isCodeGenOnly = 0 in {
2944 def S2_cl0     : T_COUNT_LEADING_32<"cl0",     0b000, 0b101>;
2945 def S2_cl1     : T_COUNT_LEADING_32<"cl1",     0b000, 0b110>;
2946 def S2_ct0     : T_COUNT_LEADING_32<"ct0",     0b010, 0b100>;
2947 def S2_ct1     : T_COUNT_LEADING_32<"ct1",     0b010, 0b101>;
2948 def S2_cl0p    : T_COUNT_LEADING_64<"cl0",     0b010, 0b010>;
2949 def S2_cl1p    : T_COUNT_LEADING_64<"cl1",     0b010, 0b100>;
2950 def S2_clb     : T_COUNT_LEADING_32<"clb",     0b000, 0b100>;
2951 def S2_clbp    : T_COUNT_LEADING_64<"clb",     0b010, 0b000>;
2952 def S2_clbnorm : T_COUNT_LEADING_32<"normamt", 0b000, 0b111>;
2953 }
2954
2955 def: Pat<(i32 (ctlz I32:$Rs)),                (S2_cl0 I32:$Rs)>;
2956 def: Pat<(i32 (ctlz (not I32:$Rs))),          (S2_cl1 I32:$Rs)>;
2957 def: Pat<(i32 (cttz I32:$Rs)),                (S2_ct0 I32:$Rs)>;
2958 def: Pat<(i32 (cttz (not I32:$Rs))),          (S2_ct1 I32:$Rs)>;
2959 def: Pat<(i32 (trunc (ctlz I64:$Rss))),       (S2_cl0p I64:$Rss)>;
2960 def: Pat<(i32 (trunc (ctlz (not I64:$Rss)))), (S2_cl1p I64:$Rss)>;
2961
2962 // Bit set/clear/toggle
2963
2964 let hasSideEffects = 0, hasNewValue = 1 in
2965 class T_SCT_BIT_IMM<string MnOp, bits<3> MinOp>
2966     : SInst<(outs IntRegs:$Rd), (ins IntRegs:$Rs, u5Imm:$u5),
2967             "$Rd = "#MnOp#"($Rs, #$u5)", [], "", S_2op_tc_1_SLOT23> {
2968   bits<5> Rd;
2969   bits<5> Rs;
2970   bits<5> u5;
2971   let IClass = 0b1000;
2972   let Inst{27-21} = 0b1100110;
2973   let Inst{20-16} = Rs;
2974   let Inst{13} = 0b0;
2975   let Inst{12-8} = u5;
2976   let Inst{7-5} = MinOp;
2977   let Inst{4-0} = Rd;
2978 }
2979
2980 let hasSideEffects = 0, hasNewValue = 1 in
2981 class T_SCT_BIT_REG<string MnOp, bits<2> MinOp>
2982     : SInst<(outs IntRegs:$Rd), (ins IntRegs:$Rs, IntRegs:$Rt),
2983             "$Rd = "#MnOp#"($Rs, $Rt)", [], "", S_3op_tc_1_SLOT23> {
2984   bits<5> Rd;
2985   bits<5> Rs;
2986   bits<5> Rt;
2987   let IClass = 0b1100;
2988   let Inst{27-22} = 0b011010;
2989   let Inst{20-16} = Rs;
2990   let Inst{12-8} = Rt;
2991   let Inst{7-6} = MinOp;
2992   let Inst{4-0} = Rd;
2993 }
2994
2995 let isCodeGenOnly = 0 in {
2996 def S2_clrbit_i    : T_SCT_BIT_IMM<"clrbit",    0b001>;
2997 def S2_setbit_i    : T_SCT_BIT_IMM<"setbit",    0b000>;
2998 def S2_togglebit_i : T_SCT_BIT_IMM<"togglebit", 0b010>;
2999 def S2_clrbit_r    : T_SCT_BIT_REG<"clrbit",    0b01>;
3000 def S2_setbit_r    : T_SCT_BIT_REG<"setbit",    0b00>;
3001 def S2_togglebit_r : T_SCT_BIT_REG<"togglebit", 0b10>;
3002 }
3003
3004 def: Pat<(i32 (and (i32 IntRegs:$Rs), (not (shl 1, u5ImmPred:$u5)))),
3005          (S2_clrbit_i IntRegs:$Rs, u5ImmPred:$u5)>;
3006 def: Pat<(i32 (or (i32 IntRegs:$Rs), (shl 1, u5ImmPred:$u5))),
3007          (S2_setbit_i IntRegs:$Rs, u5ImmPred:$u5)>;
3008 def: Pat<(i32 (xor (i32 IntRegs:$Rs), (shl 1, u5ImmPred:$u5))),
3009          (S2_togglebit_i IntRegs:$Rs, u5ImmPred:$u5)>;
3010 def: Pat<(i32 (and (i32 IntRegs:$Rs), (not (shl 1, (i32 IntRegs:$Rt))))),
3011          (S2_clrbit_r IntRegs:$Rs, IntRegs:$Rt)>;
3012 def: Pat<(i32 (or (i32 IntRegs:$Rs), (shl 1, (i32 IntRegs:$Rt)))),
3013          (S2_setbit_r IntRegs:$Rs, IntRegs:$Rt)>;
3014 def: Pat<(i32 (xor (i32 IntRegs:$Rs), (shl 1, (i32 IntRegs:$Rt)))),
3015          (S2_togglebit_r IntRegs:$Rs, IntRegs:$Rt)>;
3016
3017 // Bit test
3018
3019 let hasSideEffects = 0 in
3020 class T_TEST_BIT_IMM<string MnOp, bits<3> MajOp>
3021     : SInst<(outs PredRegs:$Pd), (ins IntRegs:$Rs, u5Imm:$u5),
3022             "$Pd = "#MnOp#"($Rs, #$u5)",
3023             [], "", S_2op_tc_2early_SLOT23> {
3024   bits<2> Pd;
3025   bits<5> Rs;
3026   bits<5> u5;
3027   let IClass = 0b1000;
3028   let Inst{27-24} = 0b0101;
3029   let Inst{23-21} = MajOp;
3030   let Inst{20-16} = Rs;
3031   let Inst{13} = 0;
3032   let Inst{12-8} = u5;
3033   let Inst{1-0} = Pd;
3034 }
3035
3036 let hasSideEffects = 0 in
3037 class T_TEST_BIT_REG<string MnOp, bit IsNeg>
3038     : SInst<(outs PredRegs:$Pd), (ins IntRegs:$Rs, IntRegs:$Rt),
3039             "$Pd = "#MnOp#"($Rs, $Rt)",
3040             [], "", S_3op_tc_2early_SLOT23> {
3041   bits<2> Pd;
3042   bits<5> Rs;
3043   bits<5> Rt;
3044   let IClass = 0b1100;
3045   let Inst{27-22} = 0b011100;
3046   let Inst{21} = IsNeg;
3047   let Inst{20-16} = Rs;
3048   let Inst{12-8} = Rt;
3049   let Inst{1-0} = Pd;
3050 }
3051
3052 let isCodeGenOnly = 0 in {
3053 def S2_tstbit_i : T_TEST_BIT_IMM<"tstbit", 0b000>;
3054 def S2_tstbit_r : T_TEST_BIT_REG<"tstbit", 0>;
3055 }
3056
3057 let AddedComplexity = 20 in { // Complexity greater than cmp reg-imm.
3058   def: Pat<(i1 (setne (and (shl 1, u5ImmPred:$u5), (i32 IntRegs:$Rs)), 0)),
3059            (S2_tstbit_i IntRegs:$Rs, u5ImmPred:$u5)>;
3060   def: Pat<(i1 (setne (and (shl 1, (i32 IntRegs:$Rt)), (i32 IntRegs:$Rs)), 0)),
3061            (S2_tstbit_r IntRegs:$Rs, IntRegs:$Rt)>;
3062   def: Pat<(i1 (trunc (i32 IntRegs:$Rs))),
3063            (S2_tstbit_i IntRegs:$Rs, 0)>;
3064   def: Pat<(i1 (trunc (i64 DoubleRegs:$Rs))),
3065            (S2_tstbit_i (LoReg DoubleRegs:$Rs), 0)>;
3066 }
3067 let hasSideEffects = 0 in
3068 class T_TEST_BITS_IMM<string MnOp, bits<2> MajOp, bit IsNeg>
3069     : SInst<(outs PredRegs:$Pd), (ins IntRegs:$Rs, u6Imm:$u6),
3070             "$Pd = "#MnOp#"($Rs, #$u6)",
3071             [], "", S_2op_tc_2early_SLOT23> {
3072   bits<2> Pd;
3073   bits<5> Rs;
3074   bits<6> u6;
3075   let IClass = 0b1000;
3076   let Inst{27-24} = 0b0101;
3077   let Inst{23-22} = MajOp;
3078   let Inst{21} = IsNeg;
3079   let Inst{20-16} = Rs;
3080   let Inst{13-8} = u6;
3081   let Inst{1-0} = Pd;
3082 }
3083
3084 let hasSideEffects = 0 in
3085 class T_TEST_BITS_REG<string MnOp, bits<2> MajOp, bit IsNeg>
3086     : SInst<(outs PredRegs:$Pd), (ins IntRegs:$Rs, IntRegs:$Rt),
3087             "$Pd = "#MnOp#"($Rs, $Rt)",
3088             [], "", S_3op_tc_2early_SLOT23> {
3089   bits<2> Pd;
3090   bits<5> Rs;
3091   bits<5> Rt;
3092   let IClass = 0b1100;
3093   let Inst{27-24} = 0b0111;
3094   let Inst{23-22} = MajOp;
3095   let Inst{21} = IsNeg;
3096   let Inst{20-16} = Rs;
3097   let Inst{12-8} = Rt;
3098   let Inst{1-0} = Pd;
3099 }
3100
3101 let isCodeGenOnly = 0 in {
3102 def C2_bitsclri : T_TEST_BITS_IMM<"bitsclr", 0b10, 0>;
3103 def C2_bitsclr  : T_TEST_BITS_REG<"bitsclr", 0b10, 0>;
3104 def C2_bitsset  : T_TEST_BITS_REG<"bitsset", 0b01, 0>;
3105 }
3106
3107 let AddedComplexity = 20 in { // Complexity greater than compare reg-imm.
3108   def: Pat<(i1 (seteq (and (i32 IntRegs:$Rs), u6ImmPred:$u6), 0)),
3109            (C2_bitsclri IntRegs:$Rs, u6ImmPred:$u6)>;
3110   def: Pat<(i1 (seteq (and (i32 IntRegs:$Rs), (i32 IntRegs:$Rt)), 0)),
3111            (C2_bitsclr IntRegs:$Rs, IntRegs:$Rt)>;
3112 }
3113
3114 let AddedComplexity = 10 in   // Complexity greater than compare reg-reg.
3115 def: Pat<(i1 (seteq (and (i32 IntRegs:$Rs), (i32 IntRegs:$Rt)), IntRegs:$Rt)),
3116          (C2_bitsset IntRegs:$Rs, IntRegs:$Rt)>;
3117
3118 //===----------------------------------------------------------------------===//
3119 // STYPE/BIT -
3120 //===----------------------------------------------------------------------===//
3121
3122 //===----------------------------------------------------------------------===//
3123 // STYPE/COMPLEX +
3124 //===----------------------------------------------------------------------===//
3125 //===----------------------------------------------------------------------===//
3126 // STYPE/COMPLEX -
3127 //===----------------------------------------------------------------------===//
3128
3129 //===----------------------------------------------------------------------===//
3130 // XTYPE/PERM +
3131 //===----------------------------------------------------------------------===//
3132
3133 //===----------------------------------------------------------------------===//
3134 // XTYPE/PERM -
3135 //===----------------------------------------------------------------------===//
3136
3137 //===----------------------------------------------------------------------===//
3138 // STYPE/PRED +
3139 //===----------------------------------------------------------------------===//
3140
3141 // Predicate transfer.
3142 let hasSideEffects = 0, hasNewValue = 1, isCodeGenOnly = 0 in
3143 def C2_tfrpr : SInst<(outs IntRegs:$Rd), (ins PredRegs:$Ps),
3144       "$Rd = $Ps", [], "", S_2op_tc_1_SLOT23> {
3145   bits<5> Rd;
3146   bits<2> Ps;
3147
3148   let IClass = 0b1000;
3149   let Inst{27-24} = 0b1001;
3150   let Inst{22} = 0b1;
3151   let Inst{17-16} = Ps;
3152   let Inst{4-0} = Rd;
3153 }
3154
3155 // Transfer general register to predicate.
3156 let hasSideEffects = 0, isCodeGenOnly = 0 in
3157 def C2_tfrrp: SInst<(outs PredRegs:$Pd), (ins IntRegs:$Rs),
3158       "$Pd = $Rs", [], "", S_2op_tc_2early_SLOT23> {
3159   bits<2> Pd;
3160   bits<5> Rs;
3161
3162   let IClass = 0b1000;
3163   let Inst{27-21} = 0b0101010;
3164   let Inst{20-16} = Rs;
3165   let Inst{1-0} = Pd;
3166 }
3167
3168
3169 //===----------------------------------------------------------------------===//
3170 // STYPE/PRED -
3171 //===----------------------------------------------------------------------===//
3172
3173 //===----------------------------------------------------------------------===//
3174 // STYPE/SHIFT +
3175 //===----------------------------------------------------------------------===//
3176 class S_2OpInstImm<string Mnemonic, bits<3>MajOp, bits<3>MinOp,
3177                    Operand Imm, list<dag> pattern = [], bit isRnd = 0>
3178   : SInst<(outs DoubleRegs:$dst), (ins DoubleRegs:$src1, Imm:$src2),
3179            "$dst = "#Mnemonic#"($src1, #$src2)"#!if(isRnd, ":rnd", ""),
3180            pattern> {
3181   bits<5> src1;
3182   bits<5> dst;
3183   let IClass = 0b1000;
3184   let Inst{27-24} = 0;
3185   let Inst{23-21} = MajOp;
3186   let Inst{20-16} = src1;
3187   let Inst{7-5} = MinOp;
3188   let Inst{4-0} = dst;
3189 }
3190
3191 class S_2OpInstImmI6<string Mnemonic, SDNode OpNode, bits<3>MinOp>
3192   : S_2OpInstImm<Mnemonic, 0b000, MinOp, u6Imm,
3193   [(set (i64 DoubleRegs:$dst), (OpNode (i64 DoubleRegs:$src1),
3194                                         u6ImmPred:$src2))]> {
3195   bits<6> src2;
3196   let Inst{13-8} = src2;
3197 }
3198
3199 // Shift by immediate.
3200 let isCodeGenOnly = 0 in {
3201 def S2_asr_i_p : S_2OpInstImmI6<"asr", sra, 0b000>;
3202 def S2_asl_i_p : S_2OpInstImmI6<"asl", shl, 0b010>;
3203 def S2_lsr_i_p : S_2OpInstImmI6<"lsr", srl, 0b001>;
3204 }
3205
3206 // Shift left by small amount and add.
3207 let AddedComplexity = 100, hasNewValue = 1, hasSideEffects = 0,
3208     isCodeGenOnly = 0 in
3209 def S2_addasl_rrri: SInst <(outs IntRegs:$Rd),
3210                            (ins IntRegs:$Rt, IntRegs:$Rs, u3Imm:$u3),
3211   "$Rd = addasl($Rt, $Rs, #$u3)" ,
3212   [(set (i32 IntRegs:$Rd), (add (i32 IntRegs:$Rt),
3213                                 (shl (i32 IntRegs:$Rs), u3ImmPred:$u3)))],
3214   "", S_3op_tc_2_SLOT23> {
3215     bits<5> Rd;
3216     bits<5> Rt;
3217     bits<5> Rs;
3218     bits<3> u3;
3219
3220     let IClass = 0b1100;
3221
3222     let Inst{27-21} = 0b0100000;
3223     let Inst{20-16} = Rs;
3224     let Inst{13}    = 0b0;
3225     let Inst{12-8}  = Rt;
3226     let Inst{7-5}   = u3;
3227     let Inst{4-0}   = Rd;
3228   }
3229
3230 //===----------------------------------------------------------------------===//
3231 // STYPE/SHIFT -
3232 //===----------------------------------------------------------------------===//
3233
3234 //===----------------------------------------------------------------------===//
3235 // STYPE/VH +
3236 //===----------------------------------------------------------------------===//
3237 //===----------------------------------------------------------------------===//
3238 // STYPE/VH -
3239 //===----------------------------------------------------------------------===//
3240
3241 //===----------------------------------------------------------------------===//
3242 // STYPE/VW +
3243 //===----------------------------------------------------------------------===//
3244 //===----------------------------------------------------------------------===//
3245 // STYPE/VW -
3246 //===----------------------------------------------------------------------===//
3247
3248 //===----------------------------------------------------------------------===//
3249 // SYSTEM/SUPER +
3250 //===----------------------------------------------------------------------===//
3251
3252 //===----------------------------------------------------------------------===//
3253 // SYSTEM/USER +
3254 //===----------------------------------------------------------------------===//
3255 def HexagonBARRIER: SDNode<"HexagonISD::BARRIER", SDTNone, [SDNPHasChain]>;
3256
3257 let hasSideEffects = 1, isSoloAX = 1, isCodeGenOnly = 0 in
3258 def BARRIER : SYSInst<(outs), (ins),
3259                      "barrier",
3260                      [(HexagonBARRIER)],"",ST_tc_st_SLOT0> {
3261   let Inst{31-28} = 0b1010;
3262   let Inst{27-21} = 0b1000000;
3263 }
3264
3265 //===----------------------------------------------------------------------===//
3266 // SYSTEM/SUPER -
3267 //===----------------------------------------------------------------------===//
3268 //===----------------------------------------------------------------------===//
3269 // CRUSER - Type.
3270 //===----------------------------------------------------------------------===//
3271 // HW loop
3272 let isExtendable = 1, isExtentSigned = 1, opExtentBits = 9, opExtentAlign = 2,
3273     opExtendable = 0, hasSideEffects = 0 in
3274 class LOOP_iBase<string mnemonic, Operand brOp, bit mustExtend = 0>
3275          : CRInst<(outs), (ins brOp:$offset, u10Imm:$src2),
3276            #mnemonic#"($offset, #$src2)",
3277            [], "" , CR_tc_3x_SLOT3> {
3278     bits<9> offset;
3279     bits<10> src2;
3280
3281     let IClass = 0b0110;
3282
3283     let Inst{27-22} = 0b100100;
3284     let Inst{21} = !if (!eq(mnemonic, "loop0"), 0b0, 0b1);
3285     let Inst{20-16} = src2{9-5};
3286     let Inst{12-8} = offset{8-4};
3287     let Inst{7-5} = src2{4-2};
3288     let Inst{4-3} = offset{3-2};
3289     let Inst{1-0} = src2{1-0};
3290 }
3291
3292 let isExtendable = 1, isExtentSigned = 1, opExtentBits = 9, opExtentAlign = 2,
3293     opExtendable = 0, hasSideEffects = 0 in
3294 class LOOP_rBase<string mnemonic, Operand brOp, bit mustExtend = 0>
3295          : CRInst<(outs), (ins brOp:$offset, IntRegs:$src2),
3296            #mnemonic#"($offset, $src2)",
3297            [], "" ,CR_tc_3x_SLOT3> {
3298     bits<9> offset;
3299     bits<5> src2;
3300
3301     let IClass = 0b0110;
3302
3303     let Inst{27-22} = 0b000000;
3304     let Inst{21} = !if (!eq(mnemonic, "loop0"), 0b0, 0b1);
3305     let Inst{20-16} = src2;
3306     let Inst{12-8} = offset{8-4};
3307     let Inst{4-3} = offset{3-2};
3308   }
3309
3310 multiclass LOOP_ri<string mnemonic> {
3311   def i : LOOP_iBase<mnemonic, brtarget>;
3312   def r : LOOP_rBase<mnemonic, brtarget>;
3313 }
3314
3315
3316 let Defs = [SA0, LC0, USR], isCodeGenOnly = 0 in
3317 defm J2_loop0 : LOOP_ri<"loop0">;
3318
3319 // Interestingly only loop0's appear to set usr.lpcfg
3320 let Defs = [SA1, LC1], isCodeGenOnly = 0 in
3321 defm J2_loop1 : LOOP_ri<"loop1">;
3322
3323 let isBranch = 1, isTerminator = 1, hasSideEffects = 0,
3324     Defs = [PC, LC0], Uses = [SA0, LC0] in {
3325 def ENDLOOP0 : Endloop<(outs), (ins brtarget:$offset),
3326                        ":endloop0",
3327                        []>;
3328 }
3329
3330 let isBranch = 1, isTerminator = 1, hasSideEffects = 0,
3331     Defs = [PC, LC1], Uses = [SA1, LC1] in {
3332 def ENDLOOP1 : Endloop<(outs), (ins brtarget:$offset),
3333                        ":endloop1",
3334                        []>;
3335 }
3336
3337 // Pipelined loop instructions, sp[123]loop0
3338 let Defs = [LC0, SA0, P3, USR], hasSideEffects = 0,
3339     isExtentSigned = 1, isExtendable = 1, opExtentBits = 9, opExtentAlign = 2,
3340     opExtendable = 0, isPredicateLate = 1 in
3341 class SPLOOP_iBase<string SP, bits<2> op>
3342   : CRInst <(outs), (ins brtarget:$r7_2, u10Imm:$U10),
3343   "p3 = sp"#SP#"loop0($r7_2, #$U10)" > {
3344     bits<9> r7_2;
3345     bits<10> U10;
3346
3347     let IClass = 0b0110;
3348
3349     let Inst{22-21} = op;
3350     let Inst{27-23} = 0b10011;
3351     let Inst{20-16} = U10{9-5};
3352     let Inst{12-8} = r7_2{8-4};
3353     let Inst{7-5} = U10{4-2};
3354     let Inst{4-3} = r7_2{3-2};
3355     let Inst{1-0} = U10{1-0};
3356   }
3357
3358 let Defs = [LC0, SA0, P3, USR], hasSideEffects = 0,
3359     isExtentSigned = 1, isExtendable = 1, opExtentBits = 9, opExtentAlign = 2,
3360     opExtendable = 0, isPredicateLate = 1 in
3361 class SPLOOP_rBase<string SP, bits<2> op>
3362   : CRInst <(outs), (ins brtarget:$r7_2, IntRegs:$Rs),
3363   "p3 = sp"#SP#"loop0($r7_2, $Rs)" > {
3364     bits<9> r7_2;
3365     bits<5> Rs;
3366
3367     let IClass = 0b0110;
3368
3369     let Inst{22-21} = op;
3370     let Inst{27-23} = 0b00001;
3371     let Inst{20-16} = Rs;
3372     let Inst{12-8} = r7_2{8-4};
3373     let Inst{4-3} = r7_2{3-2};
3374   }
3375
3376 multiclass SPLOOP_ri<string mnemonic, bits<2> op> {
3377   def i : SPLOOP_iBase<mnemonic, op>;
3378   def r : SPLOOP_rBase<mnemonic, op>;
3379 }
3380
3381 let isCodeGenOnly = 0 in {
3382 defm J2_ploop1s : SPLOOP_ri<"1", 0b01>;
3383 defm J2_ploop2s : SPLOOP_ri<"2", 0b10>;
3384 defm J2_ploop3s : SPLOOP_ri<"3", 0b11>;
3385 }
3386
3387 // Transfer to/from Control/GPR Guest/GPR
3388 let hasSideEffects = 0 in
3389 class TFR_CR_RS_base<RegisterClass CTRC, RegisterClass RC, bit isDouble>
3390   : CRInst <(outs CTRC:$dst), (ins RC:$src),
3391   "$dst = $src", [], "", CR_tc_3x_SLOT3> {
3392     bits<5> dst;
3393     bits<5> src;
3394
3395     let IClass = 0b0110;
3396
3397     let Inst{27-25} = 0b001;
3398     let Inst{24} = isDouble;
3399     let Inst{23-21} = 0b001;
3400     let Inst{20-16} = src;
3401     let Inst{4-0} = dst;
3402   }
3403 let isCodeGenOnly = 0 in
3404 def A2_tfrrcr : TFR_CR_RS_base<CtrRegs, IntRegs, 0b0>;
3405 def : InstAlias<"m0 = $Rs", (A2_tfrrcr C6, IntRegs:$Rs)>;
3406 def : InstAlias<"m1 = $Rs", (A2_tfrrcr C7, IntRegs:$Rs)>;
3407
3408 let hasSideEffects = 0 in
3409 class TFR_RD_CR_base<RegisterClass RC, RegisterClass CTRC, bit isSingle>
3410   : CRInst <(outs RC:$dst), (ins CTRC:$src),
3411   "$dst = $src", [], "", CR_tc_3x_SLOT3> {
3412     bits<5> dst;
3413     bits<5> src;
3414
3415     let IClass = 0b0110;
3416
3417     let Inst{27-26} = 0b10;
3418     let Inst{25} = isSingle;
3419     let Inst{24-21} = 0b0000;
3420     let Inst{20-16} = src;
3421     let Inst{4-0} = dst;
3422   }
3423
3424 let hasNewValue = 1, opNewValue = 0, isCodeGenOnly = 0 in
3425 def A2_tfrcrr : TFR_RD_CR_base<IntRegs, CtrRegs, 1>;
3426 def : InstAlias<"$Rd = m0", (A2_tfrcrr IntRegs:$Rd, C6)>;
3427 def : InstAlias<"$Rd = m1", (A2_tfrcrr IntRegs:$Rd, C7)>;
3428
3429 // Y4_trace: Send value to etm trace.
3430 let isSoloAX = 1, hasSideEffects = 0, isCodeGenOnly = 0 in
3431 def Y4_trace: CRInst <(outs), (ins IntRegs:$Rs),
3432   "trace($Rs)"> {
3433     bits<5> Rs;
3434
3435     let IClass = 0b0110;
3436     let Inst{27-21} = 0b0010010;
3437     let Inst{20-16} = Rs;
3438   }
3439
3440 let AddedComplexity = 100, isPredicated = 1 in
3441 def TFR_condset_ri : ALU32_rr<(outs IntRegs:$dst),
3442             (ins PredRegs:$src1, IntRegs:$src2, s12Imm:$src3),
3443             "Error; should not emit",
3444             [(set (i32 IntRegs:$dst),
3445              (i32 (select (i1 PredRegs:$src1), (i32 IntRegs:$src2),
3446                           s12ImmPred:$src3)))]>;
3447
3448 let AddedComplexity = 100, isPredicated = 1 in
3449 def TFR_condset_ir : ALU32_rr<(outs IntRegs:$dst),
3450             (ins PredRegs:$src1, s12Imm:$src2, IntRegs:$src3),
3451             "Error; should not emit",
3452             [(set (i32 IntRegs:$dst),
3453              (i32 (select (i1 PredRegs:$src1), s12ImmPred:$src2,
3454                           (i32 IntRegs:$src3))))]>;
3455
3456 let AddedComplexity = 100, isPredicated = 1 in
3457 def TFR_condset_ii : ALU32_rr<(outs IntRegs:$dst),
3458                               (ins PredRegs:$src1, s12Imm:$src2, s12Imm:$src3),
3459                      "Error; should not emit",
3460                      [(set (i32 IntRegs:$dst),
3461                            (i32 (select (i1 PredRegs:$src1), s12ImmPred:$src2,
3462                                         s12ImmPred:$src3)))]>;
3463
3464 // Generate frameindex addresses.
3465 let isReMaterializable = 1 in
3466 def TFR_FI : ALU32_ri<(outs IntRegs:$dst), (ins FrameIndex:$src1),
3467              "$dst = add($src1)",
3468              [(set (i32 IntRegs:$dst), ADDRri:$src1)]>;
3469
3470 // Support for generating global address.
3471 // Taken from X86InstrInfo.td.
3472 def SDTHexagonCONST32 : SDTypeProfile<1, 1, [
3473                                             SDTCisVT<0, i32>,
3474                                             SDTCisVT<1, i32>,
3475                                             SDTCisPtrTy<0>]>;
3476 def HexagonCONST32 : SDNode<"HexagonISD::CONST32",     SDTHexagonCONST32>;
3477 def HexagonCONST32_GP : SDNode<"HexagonISD::CONST32_GP",     SDTHexagonCONST32>;
3478
3479 // HI/LO Instructions
3480 let isReMaterializable = 1, isMoveImm = 1, hasSideEffects = 0 in
3481 def LO : ALU32_ri<(outs IntRegs:$dst), (ins globaladdress:$global),
3482                   "$dst.l = #LO($global)",
3483                   []>;
3484
3485 let isReMaterializable = 1, isMoveImm = 1, hasSideEffects = 0 in
3486 def HI : ALU32_ri<(outs IntRegs:$dst), (ins globaladdress:$global),
3487                   "$dst.h = #HI($global)",
3488                   []>;
3489
3490 let isReMaterializable = 1, isMoveImm = 1, hasSideEffects = 0 in
3491 def LOi : ALU32_ri<(outs IntRegs:$dst), (ins i32imm:$imm_value),
3492                   "$dst.l = #LO($imm_value)",
3493                   []>;
3494
3495
3496 let isReMaterializable = 1, isMoveImm = 1, hasSideEffects = 0 in
3497 def HIi : ALU32_ri<(outs IntRegs:$dst), (ins i32imm:$imm_value),
3498                   "$dst.h = #HI($imm_value)",
3499                   []>;
3500
3501 let isReMaterializable = 1, isMoveImm = 1, hasSideEffects = 0 in
3502 def LO_jt : ALU32_ri<(outs IntRegs:$dst), (ins jumptablebase:$jt),
3503                   "$dst.l = #LO($jt)",
3504                   []>;
3505
3506 let isReMaterializable = 1, isMoveImm = 1, hasSideEffects = 0 in
3507 def HI_jt : ALU32_ri<(outs IntRegs:$dst), (ins jumptablebase:$jt),
3508                   "$dst.h = #HI($jt)",
3509                   []>;
3510
3511
3512 let isReMaterializable = 1, isMoveImm = 1, hasSideEffects = 0 in
3513 def LO_label : ALU32_ri<(outs IntRegs:$dst), (ins bblabel:$label),
3514                   "$dst.l = #LO($label)",
3515                   []>;
3516
3517 let isReMaterializable = 1, isMoveImm = 1 , hasSideEffects = 0 in
3518 def HI_label : ALU32_ri<(outs IntRegs:$dst), (ins bblabel:$label),
3519                   "$dst.h = #HI($label)",
3520                   []>;
3521
3522 // This pattern is incorrect. When we add small data, we should change
3523 // this pattern to use memw(#foo).
3524 // This is for sdata.
3525 let isMoveImm = 1 in
3526 def CONST32 : LDInst<(outs IntRegs:$dst), (ins globaladdress:$global),
3527               "$dst = CONST32(#$global)",
3528               [(set (i32 IntRegs:$dst),
3529                     (load (HexagonCONST32 tglobaltlsaddr:$global)))]>;
3530
3531 // This is for non-sdata.
3532 let isReMaterializable = 1, isMoveImm = 1 in
3533 def CONST32_set : LDInst2<(outs IntRegs:$dst), (ins globaladdress:$global),
3534                   "$dst = CONST32(#$global)",
3535                   [(set (i32 IntRegs:$dst),
3536                         (HexagonCONST32 tglobaladdr:$global))]>;
3537
3538 let isReMaterializable = 1, isMoveImm = 1 in
3539 def CONST32_set_jt : LDInst2<(outs IntRegs:$dst), (ins jumptablebase:$jt),
3540                      "$dst = CONST32(#$jt)",
3541                      [(set (i32 IntRegs:$dst),
3542                            (HexagonCONST32 tjumptable:$jt))]>;
3543
3544 let isReMaterializable = 1, isMoveImm = 1 in
3545 def CONST32GP_set : LDInst2<(outs IntRegs:$dst), (ins globaladdress:$global),
3546                     "$dst = CONST32(#$global)",
3547                     [(set (i32 IntRegs:$dst),
3548                           (HexagonCONST32_GP tglobaladdr:$global))]>;
3549
3550 let isReMaterializable = 1, isMoveImm = 1 in
3551 def CONST32_Int_Real : LDInst2<(outs IntRegs:$dst), (ins i32imm:$global),
3552                        "$dst = CONST32(#$global)",
3553                        [(set (i32 IntRegs:$dst), imm:$global) ]>;
3554
3555 // Map BlockAddress lowering to CONST32_Int_Real
3556 def : Pat<(HexagonCONST32_GP tblockaddress:$addr),
3557           (CONST32_Int_Real tblockaddress:$addr)>;
3558
3559 let isReMaterializable = 1, isMoveImm = 1 in
3560 def CONST32_Label : LDInst2<(outs IntRegs:$dst), (ins bblabel:$label),
3561                     "$dst = CONST32($label)",
3562                     [(set (i32 IntRegs:$dst), (HexagonCONST32 bbl:$label))]>;
3563
3564 let isReMaterializable = 1, isMoveImm = 1 in
3565 def CONST64_Int_Real : LDInst2<(outs DoubleRegs:$dst), (ins i64imm:$global),
3566                        "$dst = CONST64(#$global)",
3567                        [(set (i64 DoubleRegs:$dst), imm:$global) ]>;
3568
3569 def TFR_PdFalse : SInst<(outs PredRegs:$dst), (ins),
3570                   "$dst = xor($dst, $dst)",
3571                   [(set (i1 PredRegs:$dst), 0)]>;
3572
3573 def MPY_trsext : MInst<(outs IntRegs:$dst), (ins IntRegs:$src1, IntRegs:$src2),
3574        "$dst = mpy($src1, $src2)",
3575        [(set (i32 IntRegs:$dst),
3576              (trunc (i64 (srl (i64 (mul (i64 (sext (i32 IntRegs:$src1))),
3577                                         (i64 (sext (i32 IntRegs:$src2))))),
3578                               (i32 32)))))]>;
3579
3580 // Pseudo instructions.
3581 def SDT_SPCallSeqStart : SDCallSeqStart<[ SDTCisVT<0, i32> ]>;
3582
3583 def SDT_SPCallSeqEnd : SDCallSeqEnd<[ SDTCisVT<0, i32>,
3584                                         SDTCisVT<1, i32> ]>;
3585
3586 def callseq_end : SDNode<"ISD::CALLSEQ_END",   SDT_SPCallSeqEnd,
3587                   [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
3588
3589 def callseq_start : SDNode<"ISD::CALLSEQ_START", SDT_SPCallSeqStart,
3590                     [SDNPHasChain, SDNPOutGlue]>;
3591
3592 def SDT_SPCall : SDTypeProfile<0, 1, [SDTCisVT<0, i32>]>;
3593
3594 def call : SDNode<"HexagonISD::CALL", SDT_SPCall,
3595            [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue, SDNPVariadic]>;
3596
3597 // For tailcalls a HexagonTCRet SDNode has 3 SDNode Properties - a chain,
3598 // Optional Flag and Variable Arguments.
3599 // Its 1 Operand has pointer type.
3600 def HexagonTCRet    : SDNode<"HexagonISD::TC_RETURN", SDT_SPCall,
3601                      [SDNPHasChain,  SDNPOptInGlue, SDNPVariadic]>;
3602
3603 let Defs = [R29, R30], Uses = [R31, R30, R29] in {
3604  def ADJCALLSTACKDOWN : Pseudo<(outs), (ins i32imm:$amt),
3605                         "Should never be emitted",
3606                         [(callseq_start timm:$amt)]>;
3607 }
3608
3609 let Defs = [R29, R30, R31], Uses = [R29] in {
3610  def ADJCALLSTACKUP : Pseudo<(outs), (ins i32imm:$amt1, i32imm:$amt2),
3611                       "Should never be emitted",
3612                       [(callseq_end timm:$amt1, timm:$amt2)]>;
3613 }
3614 // Call subroutine.
3615 let isCall = 1, hasSideEffects = 0,
3616   Defs = [D0, D1, D2, D3, D4, D5, D6, D7, D8, D9, D10,
3617           R22, R23, R28, R31, P0, P1, P2, P3, LC0, LC1, SA0, SA1] in {
3618   def CALL : JInst<(outs), (ins calltarget:$dst),
3619              "call $dst", []>;
3620 }
3621
3622 // Call subroutine indirectly.
3623 let Defs = VolatileV3.Regs, isCodeGenOnly = 0 in
3624 def J2_callr : JUMPR_MISC_CALLR<0, 1>;
3625
3626 // Indirect tail-call.
3627 let isCodeGenOnly = 1, isCall = 1, isReturn = 1  in
3628 def TCRETURNR : T_JMPr;
3629
3630 // Direct tail-calls.
3631 let isCall = 1, isReturn = 1, isBarrier = 1, isPredicable = 0,
3632 isTerminator = 1, isCodeGenOnly = 1 in {
3633   def TCRETURNtg   : JInst<(outs), (ins calltarget:$dst), "jump $dst",
3634       [], "", J_tc_2early_SLOT23>;
3635   def TCRETURNtext : JInst<(outs), (ins calltarget:$dst), "jump $dst",
3636       [], "", J_tc_2early_SLOT23>;
3637 }
3638
3639 // Map call instruction.
3640 def : Pat<(call (i32 IntRegs:$dst)),
3641       (J2_callr (i32 IntRegs:$dst))>, Requires<[HasV2TOnly]>;
3642 def : Pat<(call tglobaladdr:$dst),
3643       (CALL tglobaladdr:$dst)>, Requires<[HasV2TOnly]>;
3644 def : Pat<(call texternalsym:$dst),
3645       (CALL texternalsym:$dst)>, Requires<[HasV2TOnly]>;
3646 //Tail calls.
3647 def : Pat<(HexagonTCRet tglobaladdr:$dst),
3648       (TCRETURNtg tglobaladdr:$dst)>;
3649 def : Pat<(HexagonTCRet texternalsym:$dst),
3650       (TCRETURNtext texternalsym:$dst)>;
3651 def : Pat<(HexagonTCRet (i32 IntRegs:$dst)),
3652       (TCRETURNR (i32 IntRegs:$dst))>;
3653
3654 // Atomic load and store support
3655 // 8 bit atomic load
3656 def : Pat<(atomic_load_8 ADDRriS11_0:$src1),
3657           (i32 (L2_loadrub_io AddrFI:$src1, 0))>;
3658
3659 def : Pat<(atomic_load_8 (add (i32 IntRegs:$src1), s11_0ImmPred:$offset)),
3660           (i32 (L2_loadrub_io (i32 IntRegs:$src1), s11_0ImmPred:$offset))>;
3661
3662 // 16 bit atomic load
3663 def : Pat<(atomic_load_16 ADDRriS11_1:$src1),
3664           (i32 (LDriuh ADDRriS11_1:$src1))>;
3665
3666 def : Pat<(atomic_load_16 (add (i32 IntRegs:$src1), s11_1ImmPred:$offset)),
3667           (i32 (LDriuh_indexed (i32 IntRegs:$src1), s11_1ImmPred:$offset))>;
3668
3669 def : Pat<(atomic_load_32 ADDRriS11_2:$src1),
3670           (i32 (LDriw ADDRriS11_2:$src1))>;
3671
3672 def : Pat<(atomic_load_32 (add (i32 IntRegs:$src1), s11_2ImmPred:$offset)),
3673           (i32 (LDriw_indexed (i32 IntRegs:$src1), s11_2ImmPred:$offset))>;
3674
3675 // 64 bit atomic load
3676 def : Pat<(atomic_load_64 ADDRriS11_3:$src1),
3677           (i64 (LDrid ADDRriS11_3:$src1))>;
3678
3679 def : Pat<(atomic_load_64 (add (i32 IntRegs:$src1), s11_3ImmPred:$offset)),
3680           (i64 (LDrid_indexed (i32 IntRegs:$src1), s11_3ImmPred:$offset))>;
3681
3682
3683 def : Pat<(atomic_store_8 ADDRriS11_0:$src2, (i32 IntRegs:$src1)),
3684           (STrib ADDRriS11_0:$src2, (i32 IntRegs:$src1))>;
3685
3686 def : Pat<(atomic_store_8 (add (i32 IntRegs:$src2), s11_0ImmPred:$offset),
3687                           (i32 IntRegs:$src1)),
3688           (STrib_indexed (i32 IntRegs:$src2), s11_0ImmPred:$offset,
3689                          (i32 IntRegs:$src1))>;
3690
3691
3692 def : Pat<(atomic_store_16 ADDRriS11_1:$src2, (i32 IntRegs:$src1)),
3693           (STrih ADDRriS11_1:$src2, (i32 IntRegs:$src1))>;
3694
3695 def : Pat<(atomic_store_16 (i32 IntRegs:$src1),
3696                           (add (i32 IntRegs:$src2), s11_1ImmPred:$offset)),
3697           (STrih_indexed (i32 IntRegs:$src2), s11_1ImmPred:$offset,
3698                          (i32 IntRegs:$src1))>;
3699
3700 def : Pat<(atomic_store_32 ADDRriS11_2:$src2, (i32 IntRegs:$src1)),
3701           (STriw ADDRriS11_2:$src2, (i32 IntRegs:$src1))>;
3702
3703 def : Pat<(atomic_store_32 (add (i32 IntRegs:$src2), s11_2ImmPred:$offset),
3704                            (i32 IntRegs:$src1)),
3705           (STriw_indexed (i32 IntRegs:$src2), s11_2ImmPred:$offset,
3706                          (i32 IntRegs:$src1))>;
3707
3708
3709
3710
3711 def : Pat<(atomic_store_64 ADDRriS11_3:$src2, (i64 DoubleRegs:$src1)),
3712           (STrid ADDRriS11_3:$src2, (i64 DoubleRegs:$src1))>;
3713
3714 def : Pat<(atomic_store_64 (add (i32 IntRegs:$src2), s11_3ImmPred:$offset),
3715                            (i64 DoubleRegs:$src1)),
3716           (STrid_indexed (i32 IntRegs:$src2), s11_3ImmPred:$offset,
3717                          (i64 DoubleRegs:$src1))>;
3718
3719 // Map from r0 = and(r1, 65535) to r0 = zxth(r1)
3720 def : Pat <(and (i32 IntRegs:$src1), 65535),
3721       (A2_zxth (i32 IntRegs:$src1))>;
3722
3723 // Map from r0 = and(r1, 255) to r0 = zxtb(r1).
3724 def : Pat <(and (i32 IntRegs:$src1), 255),
3725       (A2_zxtb (i32 IntRegs:$src1))>;
3726
3727 // Map Add(p1, true) to p1 = not(p1).
3728 //     Add(p1, false) should never be produced,
3729 //     if it does, it got to be mapped to NOOP.
3730 def : Pat <(add (i1 PredRegs:$src1), -1),
3731       (C2_not (i1 PredRegs:$src1))>;
3732
3733 // Map from p0 = pnot(p0); r0 = mux(p0, #i, #j) => r0 = mux(p0, #j, #i).
3734 def : Pat <(select (not (i1 PredRegs:$src1)), s8ImmPred:$src2, s8ImmPred:$src3),
3735       (i32 (TFR_condset_ii (i1 PredRegs:$src1), s8ImmPred:$src3,
3736                            s8ImmPred:$src2))>;
3737
3738 // Map from p0 = pnot(p0); r0 = select(p0, #i, r1)
3739 // => r0 = TFR_condset_ri(p0, r1, #i)
3740 def : Pat <(select (not (i1 PredRegs:$src1)), s12ImmPred:$src2,
3741                    (i32 IntRegs:$src3)),
3742       (i32 (TFR_condset_ri (i1 PredRegs:$src1), (i32 IntRegs:$src3),
3743                            s12ImmPred:$src2))>;
3744
3745 // Map from p0 = pnot(p0); r0 = mux(p0, r1, #i)
3746 // => r0 = TFR_condset_ir(p0, #i, r1)
3747 def : Pat <(select (not (i1 PredRegs:$src1)), IntRegs:$src2, s12ImmPred:$src3),
3748       (i32 (TFR_condset_ir (i1 PredRegs:$src1), s12ImmPred:$src3,
3749                            (i32 IntRegs:$src2)))>;
3750
3751 // Map from p0 = pnot(p0); if (p0) jump => if (!p0) jump.
3752 def : Pat <(brcond (not (i1 PredRegs:$src1)), bb:$offset),
3753       (J2_jumpf (i1 PredRegs:$src1), bb:$offset)>;
3754
3755 // Map from p2 = pnot(p2); p1 = and(p0, p2) => p1 = and(p0, !p2).
3756 def : Pat <(and (i1 PredRegs:$src1), (not (i1 PredRegs:$src2))),
3757       (i1 (C2_andn (i1 PredRegs:$src1), (i1 PredRegs:$src2)))>;
3758
3759
3760 let AddedComplexity = 100 in
3761 def : Pat <(i64 (zextloadi1 (HexagonCONST32 tglobaladdr:$global))),
3762       (i64 (A2_combinew (A2_tfrsi 0),
3763                        (L2_loadrub_io (CONST32_set tglobaladdr:$global), 0)))>,
3764       Requires<[NoV4T]>;
3765
3766 // Map from i1 loads to 32 bits. This assumes that the i1* is byte aligned.
3767 let AddedComplexity = 10 in
3768 def : Pat <(i32 (zextloadi1 ADDRriS11_0:$addr)),
3769       (i32 (A2_and (i32 (L2_loadrb_io AddrFI:$addr, 0)), (A2_tfrsi 0x1)))>;
3770
3771 // Map from Rdd = sign_extend_inreg(Rss, i32) -> Rdd = A2_sxtw(Rss.lo).
3772 def : Pat <(i64 (sext_inreg (i64 DoubleRegs:$src1), i32)),
3773       (i64 (A2_sxtw (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src1), subreg_loreg))))>;
3774
3775 // Map from Rdd = sign_extend_inreg(Rss, i16) -> Rdd = A2_sxtw(SXTH(Rss.lo)).
3776 def : Pat <(i64 (sext_inreg (i64 DoubleRegs:$src1), i16)),
3777       (i64 (A2_sxtw (i32 (A2_sxth (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src1),
3778                                                  subreg_loreg))))))>;
3779
3780 // Map from Rdd = sign_extend_inreg(Rss, i8) -> Rdd = A2_sxtw(SXTB(Rss.lo)).
3781 def : Pat <(i64 (sext_inreg (i64 DoubleRegs:$src1), i8)),
3782       (i64 (A2_sxtw (i32 (A2_sxtb (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src1),
3783                                                  subreg_loreg))))))>;
3784
3785 // We want to prevent emitting pnot's as much as possible.
3786 // Map brcond with an unsupported setcc to a J2_jumpf.
3787 def : Pat <(brcond (i1 (setne (i32 IntRegs:$src1), (i32 IntRegs:$src2))),
3788                         bb:$offset),
3789       (J2_jumpf (C2_cmpeq (i32 IntRegs:$src1), (i32 IntRegs:$src2)),
3790                 bb:$offset)>;
3791
3792 def : Pat <(brcond (i1 (setne (i32 IntRegs:$src1), s10ImmPred:$src2)),
3793                         bb:$offset),
3794       (J2_jumpf (C2_cmpeqi (i32 IntRegs:$src1), s10ImmPred:$src2), bb:$offset)>;
3795
3796 def : Pat <(brcond (i1 (setne (i1 PredRegs:$src1), (i1 -1))), bb:$offset),
3797       (J2_jumpf (i1 PredRegs:$src1), bb:$offset)>;
3798
3799 def : Pat <(brcond (i1 (setne (i1 PredRegs:$src1), (i1 0))), bb:$offset),
3800       (J2_jumpt (i1 PredRegs:$src1), bb:$offset)>;
3801
3802 // cmp.lt(Rs, Imm) -> !cmp.ge(Rs, Imm) -> !cmp.gt(Rs, Imm-1)
3803 def : Pat <(brcond (i1 (setlt (i32 IntRegs:$src1), s8ImmPred:$src2)),
3804                         bb:$offset),
3805       (J2_jumpf (C2_cmpgti (i32 IntRegs:$src1),
3806                 (DEC_CONST_SIGNED s8ImmPred:$src2)), bb:$offset)>;
3807
3808 // cmp.lt(r0, r1) -> cmp.gt(r1, r0)
3809 def : Pat <(brcond (i1 (setlt (i32 IntRegs:$src1), (i32 IntRegs:$src2))),
3810                         bb:$offset),
3811       (J2_jumpt (C2_cmpgt (i32 IntRegs:$src2), (i32 IntRegs:$src1)), bb:$offset)>;
3812
3813 def : Pat <(brcond (i1 (setuge (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2))),
3814                    bb:$offset),
3815       (J2_jumpf (C2_cmpgtup (i64 DoubleRegs:$src2), (i64 DoubleRegs:$src1)),
3816                    bb:$offset)>;
3817
3818 def : Pat <(brcond (i1 (setule (i32 IntRegs:$src1), (i32 IntRegs:$src2))),
3819                         bb:$offset),
3820       (J2_jumpf (C2_cmpgtu (i32 IntRegs:$src1), (i32 IntRegs:$src2)),
3821                 bb:$offset)>;
3822
3823 def : Pat <(brcond (i1 (setule (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2))),
3824                    bb:$offset),
3825       (J2_jumpf (C2_cmpgtup (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2)),
3826                 bb:$offset)>;
3827
3828 // Map from a 64-bit select to an emulated 64-bit mux.
3829 // Hexagon does not support 64-bit MUXes; so emulate with combines.
3830 def : Pat <(select (i1 PredRegs:$src1), (i64 DoubleRegs:$src2),
3831                    (i64 DoubleRegs:$src3)),
3832       (i64 (A2_combinew (i32 (C2_mux (i1 PredRegs:$src1),
3833                                     (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src2),
3834                                                          subreg_hireg)),
3835                                     (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src3),
3836                                                          subreg_hireg)))),
3837                        (i32 (C2_mux (i1 PredRegs:$src1),
3838                                     (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src2),
3839                                                          subreg_loreg)),
3840                                     (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src3),
3841                                                          subreg_loreg))))))>;
3842
3843 // Map from a 1-bit select to logical ops.
3844 // From LegalizeDAG.cpp: (B1 ? B2 : B3) <=> (B1 & B2)|(!B1&B3).
3845 def : Pat <(select (i1 PredRegs:$src1), (i1 PredRegs:$src2),
3846                    (i1 PredRegs:$src3)),
3847       (C2_or (C2_and (i1 PredRegs:$src1), (i1 PredRegs:$src2)),
3848              (C2_and (C2_not (i1 PredRegs:$src1)), (i1 PredRegs:$src3)))>;
3849
3850 // Map Pd = load(addr) -> Rs = load(addr); Pd = Rs.
3851 def : Pat<(i1 (load ADDRriS11_2:$addr)),
3852       (i1 (C2_tfrrp (i32 (L2_loadrb_io AddrFI:$addr, 0))))>;
3853
3854 // Map for truncating from 64 immediates to 32 bit immediates.
3855 def : Pat<(i32 (trunc (i64 DoubleRegs:$src))),
3856       (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src), subreg_loreg))>;
3857
3858 // Map for truncating from i64 immediates to i1 bit immediates.
3859 def :  Pat<(i1 (trunc (i64 DoubleRegs:$src))),
3860        (i1 (C2_tfrrp (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src),
3861                                           subreg_loreg))))>;
3862
3863 // Map memb(Rs) = Rdd -> memb(Rs) = Rt.
3864 def : Pat<(truncstorei8 (i64 DoubleRegs:$src), ADDRriS11_0:$addr),
3865       (STrib ADDRriS11_0:$addr, (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src),
3866                                                      subreg_loreg)))>;
3867
3868 // Map memh(Rs) = Rdd -> memh(Rs) = Rt.
3869 def : Pat<(truncstorei16 (i64 DoubleRegs:$src), ADDRriS11_0:$addr),
3870       (STrih ADDRriS11_0:$addr, (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src),
3871                                                      subreg_loreg)))>;
3872 // Map memw(Rs) = Rdd -> memw(Rs) = Rt
3873 def : Pat<(truncstorei32 (i64  DoubleRegs:$src), ADDRriS11_0:$addr),
3874       (STriw ADDRriS11_0:$addr, (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src),
3875                                                      subreg_loreg)))>;
3876
3877 // Map memw(Rs) = Rdd -> memw(Rs) = Rt.
3878 def : Pat<(truncstorei32 (i64 DoubleRegs:$src), ADDRriS11_0:$addr),
3879       (STriw ADDRriS11_0:$addr, (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src),
3880                                                      subreg_loreg)))>;
3881
3882 // Map from i1 = constant<-1>; memw(addr) = i1 -> r0 = 1; memw(addr) = r0.
3883 def : Pat<(store (i1 -1), ADDRriS11_2:$addr),
3884       (STrib ADDRriS11_2:$addr, (A2_tfrsi 1))>;
3885
3886
3887 // Map from i1 = constant<-1>; store i1 -> r0 = 1; store r0.
3888 def : Pat<(store (i1 -1), ADDRriS11_2:$addr),
3889       (STrib ADDRriS11_2:$addr, (A2_tfrsi 1))>;
3890
3891 // Map from memb(Rs) = Pd -> Rt = mux(Pd, #0, #1); store Rt.
3892 def : Pat<(store (i1 PredRegs:$src1), ADDRriS11_2:$addr),
3893       (STrib ADDRriS11_2:$addr, (i32 (C2_muxii (i1 PredRegs:$src1), 1, 0)) )>;
3894
3895 // Map Rdd = anyext(Rs) -> Rdd = A2_sxtw(Rs).
3896 // Hexagon_TODO: We can probably use combine but that will cost 2 instructions.
3897 // Better way to do this?
3898 def : Pat<(i64 (anyext (i32 IntRegs:$src1))),
3899       (i64 (A2_sxtw (i32 IntRegs:$src1)))>;
3900
3901 // Map cmple -> cmpgt.
3902 // rs <= rt -> !(rs > rt).
3903 def : Pat<(i1 (setle (i32 IntRegs:$src1), s10ExtPred:$src2)),
3904       (i1 (C2_not (C2_cmpgti (i32 IntRegs:$src1), s10ExtPred:$src2)))>;
3905
3906 // rs <= rt -> !(rs > rt).
3907 def : Pat<(i1 (setle (i32 IntRegs:$src1), (i32 IntRegs:$src2))),
3908       (i1 (C2_not (C2_cmpgt (i32 IntRegs:$src1), (i32 IntRegs:$src2))))>;
3909
3910 // Rss <= Rtt -> !(Rss > Rtt).
3911 def : Pat<(i1 (setle (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2))),
3912       (i1 (C2_not (C2_cmpgtp (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2))))>;
3913
3914 // Map cmpne -> cmpeq.
3915 // Hexagon_TODO: We should improve on this.
3916 // rs != rt -> !(rs == rt).
3917 def : Pat <(i1 (setne (i32 IntRegs:$src1), s10ExtPred:$src2)),
3918       (i1 (C2_not(i1 (C2_cmpeqi (i32 IntRegs:$src1), s10ExtPred:$src2))))>;
3919
3920 // Map cmpne(Rs) -> !cmpeqe(Rs).
3921 // rs != rt -> !(rs == rt).
3922 def : Pat <(i1 (setne (i32 IntRegs:$src1), (i32 IntRegs:$src2))),
3923       (i1 (C2_not (i1 (C2_cmpeq (i32 IntRegs:$src1), (i32 IntRegs:$src2)))))>;
3924
3925 // Convert setne back to xor for hexagon since we compute w/ pred registers.
3926 def : Pat <(i1 (setne (i1 PredRegs:$src1), (i1 PredRegs:$src2))),
3927       (i1 (C2_xor (i1 PredRegs:$src1), (i1 PredRegs:$src2)))>;
3928
3929 // Map cmpne(Rss) -> !cmpew(Rss).
3930 // rs != rt -> !(rs == rt).
3931 def : Pat <(i1 (setne (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2))),
3932       (i1 (C2_not (i1 (C2_cmpeqp (i64 DoubleRegs:$src1),
3933                                      (i64 DoubleRegs:$src2)))))>;
3934
3935 // Map cmpge(Rs, Rt) -> !(cmpgt(Rs, Rt).
3936 // rs >= rt -> !(rt > rs).
3937 def : Pat <(i1 (setge (i32 IntRegs:$src1), (i32 IntRegs:$src2))),
3938       (i1 (C2_not (i1 (C2_cmpgt (i32 IntRegs:$src2), (i32 IntRegs:$src1)))))>;
3939
3940 // cmpge(Rs, Imm) -> cmpgt(Rs, Imm-1)
3941 def : Pat <(i1 (setge (i32 IntRegs:$src1), s8ExtPred:$src2)),
3942       (i1 (C2_cmpgti (i32 IntRegs:$src1), (DEC_CONST_SIGNED s8ExtPred:$src2)))>;
3943
3944 // Map cmpge(Rss, Rtt) -> !cmpgt(Rtt, Rss).
3945 // rss >= rtt -> !(rtt > rss).
3946 def : Pat <(i1 (setge (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2))),
3947       (i1 (C2_not (i1 (C2_cmpgtp (i64 DoubleRegs:$src2),
3948                                 (i64 DoubleRegs:$src1)))))>;
3949
3950 // Map cmplt(Rs, Imm) -> !cmpge(Rs, Imm).
3951 // !cmpge(Rs, Imm) -> !cmpgt(Rs, Imm-1).
3952 // rs < rt -> !(rs >= rt).
3953 def : Pat <(i1 (setlt (i32 IntRegs:$src1), s8ExtPred:$src2)),
3954       (i1 (C2_not (C2_cmpgti (i32 IntRegs:$src1), (DEC_CONST_SIGNED s8ExtPred:$src2))))>;
3955
3956 // Map cmplt(Rs, Rt) -> cmpgt(Rt, Rs).
3957 // rs < rt -> rt > rs.
3958 // We can let assembler map it, or we can do in the compiler itself.
3959 def : Pat <(i1 (setlt (i32 IntRegs:$src1), (i32 IntRegs:$src2))),
3960       (i1 (C2_cmpgt (i32 IntRegs:$src2), (i32 IntRegs:$src1)))>;
3961
3962 // Map cmplt(Rss, Rtt) -> cmpgt(Rtt, Rss).
3963 // rss < rtt -> (rtt > rss).
3964 def : Pat <(i1 (setlt (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2))),
3965       (i1 (C2_cmpgtp (i64 DoubleRegs:$src2), (i64 DoubleRegs:$src1)))>;
3966
3967 // Map from cmpltu(Rs, Rd) -> cmpgtu(Rd, Rs)
3968 // rs < rt -> rt > rs.
3969 // We can let assembler map it, or we can do in the compiler itself.
3970 def : Pat <(i1 (setult (i32 IntRegs:$src1), (i32 IntRegs:$src2))),
3971       (i1 (C2_cmpgtu (i32 IntRegs:$src2), (i32 IntRegs:$src1)))>;
3972
3973 // Map from cmpltu(Rss, Rdd) -> cmpgtu(Rdd, Rss).
3974 // rs < rt -> rt > rs.
3975 def : Pat <(i1 (setult (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2))),
3976       (i1 (C2_cmpgtup (i64 DoubleRegs:$src2), (i64 DoubleRegs:$src1)))>;
3977
3978 // Generate cmpgeu(Rs, #0) -> cmpeq(Rs, Rs)
3979 def : Pat <(i1 (setuge (i32 IntRegs:$src1), 0)),
3980       (i1 (C2_cmpeq (i32 IntRegs:$src1), (i32 IntRegs:$src1)))>;
3981
3982 // Generate cmpgeu(Rs, #u8) -> cmpgtu(Rs, #u8 -1)
3983 def : Pat <(i1 (setuge (i32 IntRegs:$src1), u8ExtPred:$src2)),
3984       (i1 (C2_cmpgtui (i32 IntRegs:$src1), (DEC_CONST_UNSIGNED u8ExtPred:$src2)))>;
3985
3986 // Generate cmpgtu(Rs, #u9)
3987 def : Pat <(i1 (setugt (i32 IntRegs:$src1), u9ExtPred:$src2)),
3988       (i1 (C2_cmpgtui (i32 IntRegs:$src1), u9ExtPred:$src2))>;
3989
3990 // Map from Rs >= Rt -> !(Rt > Rs).
3991 // rs >= rt -> !(rt > rs).
3992 def : Pat <(i1 (setuge (i32 IntRegs:$src1), (i32 IntRegs:$src2))),
3993       (i1 (C2_not (C2_cmpgtu (i32 IntRegs:$src2), (i32 IntRegs:$src1))))>;
3994
3995 // Map from Rs >= Rt -> !(Rt > Rs).
3996 // rs >= rt -> !(rt > rs).
3997 def : Pat <(i1 (setuge (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2))),
3998       (i1 (C2_not (C2_cmpgtup (i64 DoubleRegs:$src2), (i64 DoubleRegs:$src1))))>;
3999
4000 // Map from cmpleu(Rs, Rt) -> !cmpgtu(Rs, Rt).
4001 // Map from (Rs <= Rt) -> !(Rs > Rt).
4002 def : Pat <(i1 (setule (i32 IntRegs:$src1), (i32 IntRegs:$src2))),
4003       (i1 (C2_not (C2_cmpgtu (i32 IntRegs:$src1), (i32 IntRegs:$src2))))>;
4004
4005 // Map from cmpleu(Rss, Rtt) -> !cmpgtu(Rss, Rtt-1).
4006 // Map from (Rs <= Rt) -> !(Rs > Rt).
4007 def : Pat <(i1 (setule (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2))),
4008       (i1 (C2_not (C2_cmpgtup (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2))))>;
4009
4010 // Sign extends.
4011 // i1 -> i32
4012 def : Pat <(i32 (sext (i1 PredRegs:$src1))),
4013       (i32 (C2_muxii (i1 PredRegs:$src1), -1, 0))>;
4014
4015 // i1 -> i64
4016 def : Pat <(i64 (sext (i1 PredRegs:$src1))),
4017       (i64 (A2_combinew (A2_tfrsi -1), (C2_muxii (i1 PredRegs:$src1), -1, 0)))>;
4018
4019 // Convert sign-extended load back to load and sign extend.
4020 // i8 -> i64
4021 def:  Pat <(i64 (sextloadi8 ADDRriS11_0:$src1)),
4022       (i64 (A2_sxtw (L2_loadrb_io AddrFI:$src1, 0)))>;
4023
4024 // Convert any-extended load back to load and sign extend.
4025 // i8 -> i64
4026 def:  Pat <(i64 (extloadi8 ADDRriS11_0:$src1)),
4027       (i64 (A2_sxtw (L2_loadrb_io AddrFI:$src1, 0)))>;
4028
4029 // Convert sign-extended load back to load and sign extend.
4030 // i16 -> i64
4031 def:  Pat <(i64 (sextloadi16 ADDRriS11_1:$src1)),
4032       (i64 (A2_sxtw (LDrih ADDRriS11_1:$src1)))>;
4033
4034 // Convert sign-extended load back to load and sign extend.
4035 // i32 -> i64
4036 def:  Pat <(i64 (sextloadi32 ADDRriS11_2:$src1)),
4037       (i64 (A2_sxtw (LDriw ADDRriS11_2:$src1)))>;
4038
4039
4040 // Zero extends.
4041 // i1 -> i32
4042 def : Pat <(i32 (zext (i1 PredRegs:$src1))),
4043       (i32 (C2_muxii (i1 PredRegs:$src1), 1, 0))>;
4044
4045 // i1 -> i64
4046 def : Pat <(i64 (zext (i1 PredRegs:$src1))),
4047       (i64 (A2_combinew (A2_tfrsi 0), (C2_muxii (i1 PredRegs:$src1), 1, 0)))>,
4048       Requires<[NoV4T]>;
4049
4050 // i32 -> i64
4051 def : Pat <(i64 (zext (i32 IntRegs:$src1))),
4052       (i64 (A2_combinew (A2_tfrsi 0), (i32 IntRegs:$src1)))>,
4053       Requires<[NoV4T]>;
4054
4055 // i8 -> i64
4056 def:  Pat <(i64 (zextloadi8 ADDRriS11_0:$src1)),
4057       (i64 (A2_combinew (A2_tfrsi 0), (L2_loadrub_io AddrFI:$src1, 0)))>,
4058       Requires<[NoV4T]>;
4059
4060 let AddedComplexity = 20 in
4061 def:  Pat <(i64 (zextloadi8 (add (i32 IntRegs:$src1),
4062                                 s11_0ExtPred:$offset))),
4063       (i64 (A2_combinew (A2_tfrsi 0), (L2_loadrub_io IntRegs:$src1,
4064                                   s11_0ExtPred:$offset)))>,
4065       Requires<[NoV4T]>;
4066
4067 // i1 -> i64
4068 def:  Pat <(i64 (zextloadi1 ADDRriS11_0:$src1)),
4069       (i64 (A2_combinew (A2_tfrsi 0), (L2_loadrub_io AddrFI:$src1, 0)))>,
4070       Requires<[NoV4T]>;
4071
4072 let AddedComplexity = 20 in
4073 def:  Pat <(i64 (zextloadi1 (add (i32 IntRegs:$src1),
4074                                 s11_0ExtPred:$offset))),
4075       (i64 (A2_combinew (A2_tfrsi 0), (L2_loadrub_io IntRegs:$src1,
4076                                   s11_0ExtPred:$offset)))>,
4077       Requires<[NoV4T]>;
4078
4079 // i16 -> i64
4080 def:  Pat <(i64 (zextloadi16 ADDRriS11_1:$src1)),
4081       (i64 (A2_combinew (A2_tfrsi 0), (LDriuh ADDRriS11_1:$src1)))>,
4082       Requires<[NoV4T]>;
4083
4084 let AddedComplexity = 20 in
4085 def:  Pat <(i64 (zextloadi16 (add (i32 IntRegs:$src1),
4086                                   s11_1ExtPred:$offset))),
4087       (i64 (A2_combinew (A2_tfrsi 0), (LDriuh_indexed IntRegs:$src1,
4088                                   s11_1ExtPred:$offset)))>,
4089       Requires<[NoV4T]>;
4090
4091 // i32 -> i64
4092 def:  Pat <(i64 (zextloadi32 ADDRriS11_2:$src1)),
4093       (i64 (A2_combinew (A2_tfrsi 0), (LDriw ADDRriS11_2:$src1)))>,
4094       Requires<[NoV4T]>;
4095
4096 let AddedComplexity = 100 in
4097 def:  Pat <(i64 (zextloadi32 (i32 (add IntRegs:$src1, s11_2ExtPred:$offset)))),
4098       (i64 (A2_combinew (A2_tfrsi 0), (LDriw_indexed IntRegs:$src1,
4099                                   s11_2ExtPred:$offset)))>,
4100       Requires<[NoV4T]>;
4101
4102 let AddedComplexity = 10 in
4103 def:  Pat <(i32 (zextloadi1 ADDRriS11_0:$src1)),
4104       (i32 (LDriw ADDRriS11_0:$src1))>;
4105
4106 // Map from Rs = Pd to Pd = mux(Pd, #1, #0)
4107 def : Pat <(i32 (zext (i1 PredRegs:$src1))),
4108       (i32 (C2_muxii (i1 PredRegs:$src1), 1, 0))>;
4109
4110 // Map from Rs = Pd to Pd = mux(Pd, #1, #0)
4111 def : Pat <(i32 (anyext (i1 PredRegs:$src1))),
4112       (i32 (C2_muxii (i1 PredRegs:$src1), 1, 0))>;
4113
4114 // Map from Rss = Pd to Rdd = A2_sxtw (mux(Pd, #1, #0))
4115 def : Pat <(i64 (anyext (i1 PredRegs:$src1))),
4116       (i64 (A2_sxtw (i32 (C2_muxii (i1 PredRegs:$src1), 1, 0))))>;
4117
4118
4119 let AddedComplexity = 100 in
4120 def: Pat<(i64 (or (i64 (shl (i64 DoubleRegs:$srcHigh),
4121                            (i32 32))),
4122                (i64 (zextloadi32 (i32 (add IntRegs:$src2,
4123                                          s11_2ExtPred:$offset2)))))),
4124         (i64 (A2_combinew (EXTRACT_SUBREG (i64 DoubleRegs:$srcHigh), subreg_loreg),
4125                         (LDriw_indexed IntRegs:$src2,
4126                                        s11_2ExtPred:$offset2)))>;
4127
4128 def: Pat<(i64 (or (i64 (shl (i64 DoubleRegs:$srcHigh),
4129                            (i32 32))),
4130                (i64 (zextloadi32 ADDRriS11_2:$srcLow)))),
4131         (i64 (A2_combinew (EXTRACT_SUBREG (i64 DoubleRegs:$srcHigh), subreg_loreg),
4132                         (LDriw ADDRriS11_2:$srcLow)))>;
4133
4134 def: Pat<(i64 (or (i64 (shl (i64 DoubleRegs:$srcHigh),
4135                            (i32 32))),
4136                (i64 (zext (i32 IntRegs:$srcLow))))),
4137         (i64 (A2_combinew (EXTRACT_SUBREG (i64 DoubleRegs:$srcHigh), subreg_loreg),
4138                         IntRegs:$srcLow))>;
4139
4140 let AddedComplexity = 100 in
4141 def: Pat<(i64 (or (i64 (shl (i64 DoubleRegs:$srcHigh),
4142                            (i32 32))),
4143                (i64 (zextloadi32 (i32 (add IntRegs:$src2,
4144                                          s11_2ExtPred:$offset2)))))),
4145         (i64 (A2_combinew (EXTRACT_SUBREG (i64 DoubleRegs:$srcHigh), subreg_loreg),
4146                         (LDriw_indexed IntRegs:$src2,
4147                                        s11_2ExtPred:$offset2)))>;
4148
4149 def: Pat<(i64 (or (i64 (shl (i64 DoubleRegs:$srcHigh),
4150                            (i32 32))),
4151                (i64 (zextloadi32 ADDRriS11_2:$srcLow)))),
4152         (i64 (A2_combinew (EXTRACT_SUBREG (i64 DoubleRegs:$srcHigh), subreg_loreg),
4153                         (LDriw ADDRriS11_2:$srcLow)))>;
4154
4155 def: Pat<(i64 (or (i64 (shl (i64 DoubleRegs:$srcHigh),
4156                            (i32 32))),
4157                (i64 (zext (i32 IntRegs:$srcLow))))),
4158         (i64 (A2_combinew (EXTRACT_SUBREG (i64 DoubleRegs:$srcHigh), subreg_loreg),
4159                         IntRegs:$srcLow))>;
4160
4161 // Any extended 64-bit load.
4162 // anyext i32 -> i64
4163 def:  Pat <(i64 (extloadi32 ADDRriS11_2:$src1)),
4164       (i64 (A2_combinew (A2_tfrsi 0), (LDriw ADDRriS11_2:$src1)))>,
4165       Requires<[NoV4T]>;
4166
4167 // When there is an offset we should prefer the pattern below over the pattern above.
4168 // The complexity of the above is 13 (gleaned from HexagonGenDAGIsel.inc)
4169 // So this complexity below is comfortably higher to allow for choosing the below.
4170 // If this is not done then we generate addresses such as
4171 // ********************************************
4172 //        r1 = add (r0, #4)
4173 //        r1 = memw(r1 + #0)
4174 //  instead of
4175 //        r1 = memw(r0 + #4)
4176 // ********************************************
4177 let AddedComplexity = 100 in
4178 def:  Pat <(i64 (extloadi32 (i32 (add IntRegs:$src1, s11_2ExtPred:$offset)))),
4179       (i64 (A2_combinew (A2_tfrsi 0), (LDriw_indexed IntRegs:$src1,
4180                                   s11_2ExtPred:$offset)))>,
4181       Requires<[NoV4T]>;
4182
4183 // anyext i16 -> i64.
4184 def:  Pat <(i64 (extloadi16 ADDRriS11_2:$src1)),
4185       (i64 (A2_combinew (A2_tfrsi 0), (LDrih ADDRriS11_2:$src1)))>,
4186       Requires<[NoV4T]>;
4187
4188 let AddedComplexity = 20 in
4189 def:  Pat <(i64 (extloadi16 (add (i32 IntRegs:$src1),
4190                                   s11_1ExtPred:$offset))),
4191       (i64 (A2_combinew (A2_tfrsi 0), (LDrih_indexed IntRegs:$src1,
4192                                   s11_1ExtPred:$offset)))>,
4193       Requires<[NoV4T]>;
4194
4195 // Map from Rdd = zxtw(Rs) -> Rdd = combine(0, Rs).
4196 def : Pat<(i64 (zext (i32 IntRegs:$src1))),
4197       (i64 (A2_combinew (A2_tfrsi 0), (i32 IntRegs:$src1)))>,
4198       Requires<[NoV4T]>;
4199
4200 // Multiply 64-bit unsigned and use upper result.
4201 def : Pat <(mulhu (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2)),
4202       (i64
4203        (M2_dpmpyuu_acc_s0
4204         (i64
4205          (A2_combinew
4206           (A2_tfrsi 0),
4207            (i32
4208             (EXTRACT_SUBREG
4209              (i64
4210               (S2_lsr_i_p
4211                (i64
4212                 (M2_dpmpyuu_acc_s0
4213                  (i64
4214                   (M2_dpmpyuu_acc_s0
4215                    (i64
4216                     (A2_combinew (A2_tfrsi 0),
4217                      (i32
4218                       (EXTRACT_SUBREG
4219                        (i64
4220                         (S2_lsr_i_p
4221                          (i64
4222                           (M2_dpmpyuu_s0
4223                             (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src1),
4224                                                        subreg_loreg)),
4225                                   (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src2),
4226                                                        subreg_loreg)))), 32)),
4227                        subreg_loreg)))),
4228                   (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src1), subreg_hireg)),
4229                   (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src2), subreg_loreg)))),
4230                  (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src1), subreg_loreg)),
4231                  (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src2), subreg_hireg)))),
4232                32)), subreg_loreg)))),
4233         (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src1), subreg_hireg)),
4234         (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src2), subreg_hireg))))>;
4235
4236 // Multiply 64-bit signed and use upper result.
4237 def : Pat <(mulhs (i64 DoubleRegs:$src1), (i64 DoubleRegs:$src2)),
4238       (i64
4239        (M2_dpmpyss_acc_s0
4240         (i64
4241          (A2_combinew (A2_tfrsi 0),
4242           (i32
4243            (EXTRACT_SUBREG
4244             (i64
4245              (S2_lsr_i_p
4246               (i64
4247                (M2_dpmpyss_acc_s0
4248                 (i64
4249                  (M2_dpmpyss_acc_s0
4250                   (i64
4251                    (A2_combinew (A2_tfrsi 0),
4252                     (i32
4253                      (EXTRACT_SUBREG
4254                       (i64
4255                        (S2_lsr_i_p
4256                         (i64
4257                          (M2_dpmpyuu_s0
4258                            (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src1),
4259                                                       subreg_loreg)),
4260                                  (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src2),
4261                                                       subreg_loreg)))), 32)),
4262                       subreg_loreg)))),
4263                   (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src1), subreg_hireg)),
4264                   (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src2), subreg_loreg)))),
4265                 (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src1), subreg_loreg)),
4266                 (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src2), subreg_hireg)))),
4267               32)), subreg_loreg)))),
4268         (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src1), subreg_hireg)),
4269         (i32 (EXTRACT_SUBREG (i64 DoubleRegs:$src2), subreg_hireg))))>;
4270
4271 // Hexagon specific ISD nodes.
4272 //def SDTHexagonADJDYNALLOC : SDTypeProfile<1, 2, [SDTCisSameAs<0, 1>]>;
4273 def SDTHexagonADJDYNALLOC : SDTypeProfile<1, 2,
4274                                   [SDTCisVT<0, i32>, SDTCisVT<1, i32>]>;
4275 def Hexagon_ADJDYNALLOC : SDNode<"HexagonISD::ADJDYNALLOC",
4276                                   SDTHexagonADJDYNALLOC>;
4277 // Needed to tag these instructions for stack layout.
4278 let usesCustomInserter = 1 in
4279 def ADJDYNALLOC : ALU32_ri<(outs IntRegs:$dst), (ins IntRegs:$src1,
4280                                                      s16Imm:$src2),
4281                   "$dst = add($src1, #$src2)",
4282                   [(set (i32 IntRegs:$dst),
4283                         (Hexagon_ADJDYNALLOC (i32 IntRegs:$src1),
4284                                              s16ImmPred:$src2))]>;
4285
4286 def SDTHexagonARGEXTEND : SDTypeProfile<1, 1, [SDTCisVT<0, i32>]>;
4287 def Hexagon_ARGEXTEND : SDNode<"HexagonISD::ARGEXTEND", SDTHexagonARGEXTEND>;
4288 def ARGEXTEND : ALU32_rr <(outs IntRegs:$dst), (ins IntRegs:$src1),
4289                 "$dst = $src1",
4290                 [(set (i32 IntRegs:$dst),
4291                       (Hexagon_ARGEXTEND (i32 IntRegs:$src1)))]>;
4292
4293 let AddedComplexity = 100 in
4294 def : Pat<(i32 (sext_inreg (Hexagon_ARGEXTEND (i32 IntRegs:$src1)), i16)),
4295       (COPY (i32 IntRegs:$src1))>;
4296
4297 def HexagonWrapperJT: SDNode<"HexagonISD::WrapperJT", SDTIntUnaryOp>;
4298
4299 def : Pat<(HexagonWrapperJT tjumptable:$dst),
4300           (i32 (CONST32_set_jt tjumptable:$dst))>;
4301
4302 // XTYPE/SHIFT
4303 //
4304 //===----------------------------------------------------------------------===//
4305 // Template Class
4306 // Shift by immediate/register and accumulate/logical
4307 //===----------------------------------------------------------------------===//
4308
4309 // Rx[+-&|]=asr(Rs,#u5)
4310 // Rx[+-&|^]=lsr(Rs,#u5)
4311 // Rx[+-&|^]=asl(Rs,#u5)
4312
4313 let hasNewValue = 1, opNewValue = 0 in
4314 class T_shift_imm_acc_r <string opc1, string opc2, SDNode OpNode1,
4315                          SDNode OpNode2, bits<3> majOp, bits<2> minOp>
4316   : SInst_acc<(outs IntRegs:$Rx),
4317               (ins IntRegs:$src1, IntRegs:$Rs, u5Imm:$u5),
4318   "$Rx "#opc2#opc1#"($Rs, #$u5)",
4319   [(set (i32 IntRegs:$Rx),
4320          (OpNode2 (i32 IntRegs:$src1),
4321                   (OpNode1 (i32 IntRegs:$Rs), u5ImmPred:$u5)))],
4322   "$src1 = $Rx", S_2op_tc_2_SLOT23> {
4323     bits<5> Rx;
4324     bits<5> Rs;
4325     bits<5> u5;
4326
4327     let IClass = 0b1000;
4328
4329     let Inst{27-24} = 0b1110;
4330     let Inst{23-22} = majOp{2-1};
4331     let Inst{13} = 0b0;
4332     let Inst{7} = majOp{0};
4333     let Inst{6-5} = minOp;
4334     let Inst{4-0} = Rx;
4335     let Inst{20-16} = Rs;
4336     let Inst{12-8} = u5;
4337   }
4338
4339 // Rx[+-&|]=asr(Rs,Rt)
4340 // Rx[+-&|^]=lsr(Rs,Rt)
4341 // Rx[+-&|^]=asl(Rs,Rt)
4342
4343 let hasNewValue = 1, opNewValue = 0 in
4344 class T_shift_reg_acc_r <string opc1, string opc2, SDNode OpNode1,
4345                          SDNode OpNode2, bits<2> majOp, bits<2> minOp>
4346   : SInst_acc<(outs IntRegs:$Rx),
4347               (ins IntRegs:$src1, IntRegs:$Rs, IntRegs:$Rt),
4348   "$Rx "#opc2#opc1#"($Rs, $Rt)",
4349   [(set (i32 IntRegs:$Rx),
4350          (OpNode2 (i32 IntRegs:$src1),
4351                   (OpNode1 (i32 IntRegs:$Rs), (i32 IntRegs:$Rt))))],
4352   "$src1 = $Rx", S_3op_tc_2_SLOT23 > {
4353     bits<5> Rx;
4354     bits<5> Rs;
4355     bits<5> Rt;
4356
4357     let IClass = 0b1100;
4358
4359     let Inst{27-24} = 0b1100;
4360     let Inst{23-22} = majOp;
4361     let Inst{7-6} = minOp;
4362     let Inst{4-0} = Rx;
4363     let Inst{20-16} = Rs;
4364     let Inst{12-8} = Rt;
4365   }
4366
4367 // Rxx[+-&|]=asr(Rss,#u6)
4368 // Rxx[+-&|^]=lsr(Rss,#u6)
4369 // Rxx[+-&|^]=asl(Rss,#u6)
4370
4371 class T_shift_imm_acc_p <string opc1, string opc2, SDNode OpNode1,
4372                          SDNode OpNode2, bits<3> majOp, bits<2> minOp>
4373   : SInst_acc<(outs DoubleRegs:$Rxx),
4374               (ins DoubleRegs:$src1, DoubleRegs:$Rss, u6Imm:$u6),
4375   "$Rxx "#opc2#opc1#"($Rss, #$u6)",
4376   [(set (i64 DoubleRegs:$Rxx),
4377         (OpNode2 (i64 DoubleRegs:$src1),
4378                  (OpNode1 (i64 DoubleRegs:$Rss), u6ImmPred:$u6)))],
4379   "$src1 = $Rxx", S_2op_tc_2_SLOT23> {
4380     bits<5> Rxx;
4381     bits<5> Rss;
4382     bits<6> u6;
4383
4384     let IClass = 0b1000;
4385
4386     let Inst{27-24} = 0b0010;
4387     let Inst{23-22} = majOp{2-1};
4388     let Inst{7} = majOp{0};
4389     let Inst{6-5} = minOp;
4390     let Inst{4-0} = Rxx;
4391     let Inst{20-16} = Rss;
4392     let Inst{13-8} = u6;
4393   }
4394
4395
4396 // Rxx[+-&|]=asr(Rss,Rt)
4397 // Rxx[+-&|^]=lsr(Rss,Rt)
4398 // Rxx[+-&|^]=asl(Rss,Rt)
4399 // Rxx[+-&|^]=lsl(Rss,Rt)
4400
4401 class T_shift_reg_acc_p <string opc1, string opc2, SDNode OpNode1,
4402                          SDNode OpNode2, bits<3> majOp, bits<2> minOp>
4403   : SInst_acc<(outs DoubleRegs:$Rxx),
4404               (ins DoubleRegs:$src1, DoubleRegs:$Rss, IntRegs:$Rt),
4405   "$Rxx "#opc2#opc1#"($Rss, $Rt)",
4406   [(set (i64 DoubleRegs:$Rxx),
4407         (OpNode2 (i64 DoubleRegs:$src1),
4408                  (OpNode1 (i64 DoubleRegs:$Rss), (i32 IntRegs:$Rt))))],
4409   "$src1 = $Rxx", S_3op_tc_2_SLOT23> {
4410     bits<5> Rxx;
4411     bits<5> Rss;
4412     bits<5> Rt;
4413
4414     let IClass = 0b1100;
4415
4416     let Inst{27-24} = 0b1011;
4417     let Inst{23-21} = majOp;
4418     let Inst{20-16} = Rss;
4419     let Inst{12-8} = Rt;
4420     let Inst{7-6} = minOp;
4421     let Inst{4-0} = Rxx;
4422   }
4423
4424 //===----------------------------------------------------------------------===//
4425 // Multi-class for the shift instructions with logical/arithmetic operators.
4426 //===----------------------------------------------------------------------===//
4427
4428 multiclass xtype_imm_base<string OpcStr1, string OpcStr2, SDNode OpNode1,
4429                          SDNode OpNode2, bits<3> majOp, bits<2> minOp > {
4430   def _i_r#NAME : T_shift_imm_acc_r< OpcStr1, OpcStr2, OpNode1,
4431                                      OpNode2, majOp, minOp >;
4432   def _i_p#NAME : T_shift_imm_acc_p< OpcStr1, OpcStr2, OpNode1,
4433                                      OpNode2, majOp, minOp >;
4434 }
4435
4436 multiclass xtype_imm_acc<string opc1, SDNode OpNode, bits<2>minOp> {
4437   let AddedComplexity = 100 in
4438   defm _acc  : xtype_imm_base< opc1, "+= ", OpNode, add, 0b001, minOp>;
4439
4440   defm _nac  : xtype_imm_base< opc1, "-= ", OpNode, sub, 0b000, minOp>;
4441   defm _and  : xtype_imm_base< opc1, "&= ", OpNode, and, 0b010, minOp>;
4442   defm _or   : xtype_imm_base< opc1, "|= ", OpNode,  or, 0b011, minOp>;
4443 }
4444
4445 multiclass xtype_xor_imm_acc<string opc1, SDNode OpNode, bits<2>minOp> {
4446 let AddedComplexity = 100 in
4447   defm _xacc  : xtype_imm_base< opc1, "^= ", OpNode, xor, 0b100, minOp>;
4448 }
4449
4450 let isCodeGenOnly = 0 in {
4451 defm S2_asr : xtype_imm_acc<"asr", sra, 0b00>;
4452
4453 defm S2_lsr : xtype_imm_acc<"lsr", srl, 0b01>,
4454               xtype_xor_imm_acc<"lsr", srl, 0b01>;
4455
4456 defm S2_asl : xtype_imm_acc<"asl", shl, 0b10>,
4457               xtype_xor_imm_acc<"asl", shl, 0b10>;
4458 }
4459
4460 multiclass xtype_reg_acc_r<string opc1, SDNode OpNode, bits<2>minOp> {
4461   let AddedComplexity = 100 in
4462   def _acc : T_shift_reg_acc_r <opc1, "+= ", OpNode, add, 0b11, minOp>;
4463
4464   def _nac : T_shift_reg_acc_r <opc1, "-= ", OpNode, sub, 0b10, minOp>;
4465   def _and : T_shift_reg_acc_r <opc1, "&= ", OpNode, and, 0b01, minOp>;
4466   def _or  : T_shift_reg_acc_r <opc1, "|= ", OpNode,  or, 0b00, minOp>;
4467 }
4468
4469 multiclass xtype_reg_acc_p<string opc1, SDNode OpNode, bits<2>minOp> {
4470   let AddedComplexity = 100 in
4471   def _acc : T_shift_reg_acc_p <opc1, "+= ", OpNode, add, 0b110, minOp>;
4472
4473   def _nac : T_shift_reg_acc_p <opc1, "-= ", OpNode, sub, 0b100, minOp>;
4474   def _and : T_shift_reg_acc_p <opc1, "&= ", OpNode, and, 0b010, minOp>;
4475   def _or  : T_shift_reg_acc_p <opc1, "|= ", OpNode,  or, 0b000, minOp>;
4476   def _xor : T_shift_reg_acc_p <opc1, "^= ", OpNode, xor, 0b011, minOp>;
4477 }
4478
4479 multiclass xtype_reg_acc<string OpcStr, SDNode OpNode, bits<2> minOp > {
4480   defm _r_r : xtype_reg_acc_r <OpcStr, OpNode, minOp>;
4481   defm _r_p : xtype_reg_acc_p <OpcStr, OpNode, minOp>;
4482 }
4483
4484 let isCodeGenOnly = 0 in {
4485 defm S2_asl : xtype_reg_acc<"asl", shl, 0b10>;
4486 defm S2_asr : xtype_reg_acc<"asr", sra, 0b00>;
4487 defm S2_lsr : xtype_reg_acc<"lsr", srl, 0b01>;
4488 defm S2_lsl : xtype_reg_acc<"lsl", shl, 0b11>;
4489 }
4490
4491 //===----------------------------------------------------------------------===//
4492 let hasSideEffects = 0 in
4493 class T_S3op_1 <string mnemonic, RegisterClass RC, bits<2> MajOp, bits<3> MinOp,
4494                 bit SwapOps, bit isSat = 0, bit isRnd = 0, bit hasShift = 0>
4495   : SInst <(outs RC:$dst),
4496            (ins DoubleRegs:$src1, DoubleRegs:$src2),
4497   "$dst = "#mnemonic#"($src1, $src2)"#!if(isRnd, ":rnd", "")
4498                                      #!if(hasShift,":>>1","")
4499                                      #!if(isSat, ":sat", ""),
4500   [], "", S_3op_tc_2_SLOT23 > {
4501     bits<5> dst;
4502     bits<5> src1;
4503     bits<5> src2;
4504
4505     let IClass = 0b1100;
4506
4507     let Inst{27-24} = 0b0001;
4508     let Inst{23-22} = MajOp;
4509     let Inst{20-16} = !if (SwapOps, src2, src1);
4510     let Inst{12-8}  = !if (SwapOps, src1, src2);
4511     let Inst{7-5}   = MinOp;
4512     let Inst{4-0}   = dst;
4513   }
4514
4515 class T_S3op_64 <string mnemonic, bits<2> MajOp, bits<3> MinOp, bit SwapOps,
4516                  bit isSat = 0, bit isRnd = 0, bit hasShift = 0 >
4517   : T_S3op_1 <mnemonic, DoubleRegs, MajOp, MinOp, SwapOps,
4518               isSat, isRnd, hasShift>;
4519
4520 let isCodeGenOnly = 0 in
4521 def S2_lfsp : T_S3op_64 < "lfs", 0b10, 0b110, 0>;
4522
4523 //===----------------------------------------------------------------------===//
4524 // Template class used by vector shift, vector rotate, vector neg,
4525 // 32-bit shift, 64-bit shifts, etc.
4526 //===----------------------------------------------------------------------===//
4527
4528 let hasSideEffects = 0 in
4529 class T_S3op_3 <string mnemonic, RegisterClass RC, bits<2> MajOp,
4530                  bits<2> MinOp, bit isSat = 0, list<dag> pattern = [] >
4531   : SInst <(outs RC:$dst),
4532            (ins RC:$src1, IntRegs:$src2),
4533   "$dst = "#mnemonic#"($src1, $src2)"#!if(isSat, ":sat", ""),
4534   pattern, "", S_3op_tc_1_SLOT23> {
4535     bits<5> dst;
4536     bits<5> src1;
4537     bits<5> src2;
4538
4539     let IClass = 0b1100;
4540
4541     let Inst{27-24} = !if(!eq(!cast<string>(RC), "IntRegs"), 0b0110, 0b0011);
4542     let Inst{23-22} = MajOp;
4543     let Inst{20-16} = src1;
4544     let Inst{12-8} = src2;
4545     let Inst{7-6} = MinOp;
4546     let Inst{4-0} = dst;
4547   }
4548
4549 let hasNewValue = 1 in
4550 class T_S3op_shift32 <string mnemonic, SDNode OpNode, bits<2> MinOp>
4551   : T_S3op_3 <mnemonic, IntRegs, 0b01, MinOp, 0,
4552     [(set (i32 IntRegs:$dst), (OpNode (i32 IntRegs:$src1),
4553                                       (i32 IntRegs:$src2)))]>;
4554
4555 let hasNewValue = 1, Itinerary = S_3op_tc_2_SLOT23 in
4556 class T_S3op_shift32_Sat <string mnemonic, bits<2> MinOp>
4557   : T_S3op_3 <mnemonic, IntRegs, 0b00, MinOp, 1, []>;
4558
4559
4560 class T_S3op_shift64 <string mnemonic, SDNode OpNode, bits<2> MinOp>
4561   : T_S3op_3 <mnemonic, DoubleRegs, 0b10, MinOp, 0,
4562     [(set (i64 DoubleRegs:$dst), (OpNode (i64 DoubleRegs:$src1),
4563                                          (i32 IntRegs:$src2)))]>;
4564
4565
4566 class T_S3op_shiftVect <string mnemonic, bits<2> MajOp, bits<2> MinOp>
4567   : T_S3op_3 <mnemonic, DoubleRegs, MajOp, MinOp, 0, []>;
4568
4569
4570 // Shift by register
4571 // Rdd=[asr|lsr|asl|lsl](Rss,Rt)
4572
4573 let isCodeGenOnly = 0 in {
4574 def S2_asr_r_p : T_S3op_shift64 < "asr", sra, 0b00>;
4575 def S2_lsr_r_p : T_S3op_shift64 < "lsr", srl, 0b01>;
4576 def S2_asl_r_p : T_S3op_shift64 < "asl", shl, 0b10>;
4577 def S2_lsl_r_p : T_S3op_shift64 < "lsl", shl, 0b11>;
4578 }
4579
4580 // Rd=[asr|lsr|asl|lsl](Rs,Rt)
4581
4582 let isCodeGenOnly = 0 in {
4583 def S2_asr_r_r : T_S3op_shift32<"asr", sra, 0b00>;
4584 def S2_lsr_r_r : T_S3op_shift32<"lsr", srl, 0b01>;
4585 def S2_asl_r_r : T_S3op_shift32<"asl", shl, 0b10>;
4586 def S2_lsl_r_r : T_S3op_shift32<"lsl", shl, 0b11>;
4587 }
4588
4589 // Shift by register with saturation
4590 // Rd=asr(Rs,Rt):sat
4591 // Rd=asl(Rs,Rt):sat
4592
4593 let Defs = [USR_OVF], isCodeGenOnly = 0 in {
4594   def S2_asr_r_r_sat : T_S3op_shift32_Sat<"asr", 0b00>;
4595   def S2_asl_r_r_sat : T_S3op_shift32_Sat<"asl", 0b10>;
4596 }
4597
4598 //===----------------------------------------------------------------------===//
4599 // Template class for 'insert bitfield' instructions
4600 //===----------------------------------------------------------------------===//
4601 let hasSideEffects = 0 in
4602 class T_S3op_insert <string mnemonic, RegisterClass RC>
4603   : SInst <(outs RC:$dst),
4604            (ins RC:$src1, RC:$src2, DoubleRegs:$src3),
4605   "$dst = "#mnemonic#"($src2, $src3)" ,
4606   [], "$src1 = $dst", S_3op_tc_1_SLOT23 > {
4607     bits<5> dst;
4608     bits<5> src2;
4609     bits<5> src3;
4610
4611     let IClass = 0b1100;
4612
4613     let Inst{27-26} = 0b10;
4614     let Inst{25-24} = !if(!eq(!cast<string>(RC), "IntRegs"), 0b00, 0b10);
4615     let Inst{23}    = 0b0;
4616     let Inst{20-16} = src2;
4617     let Inst{12-8}  = src3;
4618     let Inst{4-0}   = dst;
4619   }
4620
4621 let hasSideEffects = 0 in
4622 class T_S2op_insert <bits<4> RegTyBits, RegisterClass RC, Operand ImmOp>
4623   : SInst <(outs RC:$dst), (ins RC:$dst2, RC:$src1, ImmOp:$src2, ImmOp:$src3),
4624   "$dst = insert($src1, #$src2, #$src3)",
4625   [], "$dst2 = $dst", S_2op_tc_2_SLOT23> {
4626     bits<5> dst;
4627     bits<5> src1;
4628     bits<6> src2;
4629     bits<6> src3;
4630     bit bit23;
4631     bit bit13;
4632     string ImmOpStr = !cast<string>(ImmOp);
4633
4634     let bit23 = !if (!eq(ImmOpStr, "u6Imm"), src3{5}, 0);
4635     let bit13 = !if (!eq(ImmOpStr, "u6Imm"), src2{5}, 0);
4636
4637     let IClass = 0b1000;
4638
4639     let Inst{27-24} = RegTyBits;
4640     let Inst{23}    = bit23;
4641     let Inst{22-21} = src3{4-3};
4642     let Inst{20-16} = src1;
4643     let Inst{13}    = bit13;
4644     let Inst{12-8}  = src2{4-0};
4645     let Inst{7-5}   = src3{2-0};
4646     let Inst{4-0}   = dst;
4647   }
4648
4649 // Rx=insert(Rs,Rtt)
4650 // Rx=insert(Rs,#u5,#U5)
4651 let hasNewValue = 1, isCodeGenOnly = 0 in {
4652   def S2_insert_rp : T_S3op_insert <"insert", IntRegs>;
4653   def S2_insert    : T_S2op_insert <0b1111, IntRegs, u5Imm>;
4654 }
4655
4656 // Rxx=insert(Rss,Rtt)
4657 // Rxx=insert(Rss,#u6,#U6)
4658 let isCodeGenOnly = 0 in {
4659 def S2_insertp_rp : T_S3op_insert<"insert", DoubleRegs>;
4660 def S2_insertp    : T_S2op_insert <0b0011, DoubleRegs, u6Imm>;
4661 }
4662
4663 //===----------------------------------------------------------------------===//
4664 // Template class for 'extract bitfield' instructions
4665 //===----------------------------------------------------------------------===//
4666 let hasNewValue = 1, hasSideEffects = 0 in
4667 class T_S3op_extract <string mnemonic, bits<2> MinOp>
4668   : SInst <(outs IntRegs:$Rd), (ins IntRegs:$Rs, DoubleRegs:$Rtt),
4669   "$Rd = "#mnemonic#"($Rs, $Rtt)",
4670   [], "", S_3op_tc_2_SLOT23 > {
4671     bits<5> Rd;
4672     bits<5> Rs;
4673     bits<5> Rtt;
4674
4675     let IClass = 0b1100;
4676
4677     let Inst{27-22} = 0b100100;
4678     let Inst{20-16} = Rs;
4679     let Inst{12-8}  = Rtt;
4680     let Inst{7-6}   = MinOp;
4681     let Inst{4-0}   = Rd;
4682   }
4683
4684 let hasSideEffects = 0 in
4685 class T_S2op_extract <string mnemonic, bits<4> RegTyBits,
4686                       RegisterClass RC, Operand ImmOp>
4687   : SInst <(outs RC:$dst), (ins RC:$src1, ImmOp:$src2, ImmOp:$src3),
4688   "$dst = "#mnemonic#"($src1, #$src2, #$src3)",
4689   [], "", S_2op_tc_2_SLOT23> {
4690     bits<5> dst;
4691     bits<5> src1;
4692     bits<6> src2;
4693     bits<6> src3;
4694     bit bit23;
4695     bit bit13;
4696     string ImmOpStr = !cast<string>(ImmOp);
4697
4698     let bit23 = !if (!eq(ImmOpStr, "u6Imm"), src3{5},
4699                 !if (!eq(mnemonic, "extractu"), 0, 1));
4700
4701     let bit13 = !if (!eq(ImmOpStr, "u6Imm"), src2{5}, 0);
4702
4703     let IClass = 0b1000;
4704
4705     let Inst{27-24} = RegTyBits;
4706     let Inst{23}    = bit23;
4707     let Inst{22-21} = src3{4-3};
4708     let Inst{20-16} = src1;
4709     let Inst{13}    = bit13;
4710     let Inst{12-8}  = src2{4-0};
4711     let Inst{7-5}   = src3{2-0};
4712     let Inst{4-0}   = dst;
4713   }
4714
4715 // Extract bitfield
4716
4717 // Rdd=extractu(Rss,Rtt)
4718 // Rdd=extractu(Rss,#u6,#U6)
4719 let isCodeGenOnly = 0 in {
4720 def S2_extractup_rp : T_S3op_64 < "extractu", 0b00, 0b000, 0>;
4721 def S2_extractup    : T_S2op_extract <"extractu", 0b0001, DoubleRegs, u6Imm>;
4722 }
4723
4724 // Rd=extractu(Rs,Rtt)
4725 // Rd=extractu(Rs,#u5,#U5)
4726 let hasNewValue = 1, isCodeGenOnly = 0 in {
4727   def S2_extractu_rp : T_S3op_extract<"extractu", 0b00>;
4728   def S2_extractu    : T_S2op_extract <"extractu", 0b1101, IntRegs, u5Imm>;
4729 }
4730
4731 //===----------------------------------------------------------------------===//
4732 // :raw for of tableindx[bdhw] insns
4733 //===----------------------------------------------------------------------===//
4734
4735 let hasSideEffects = 0, hasNewValue = 1, opNewValue = 0 in
4736 class tableidxRaw<string OpStr, bits<2>MinOp>
4737   : SInst <(outs IntRegs:$Rx),
4738            (ins IntRegs:$_dst_, IntRegs:$Rs, u4Imm:$u4, s6Imm:$S6),
4739            "$Rx = "#OpStr#"($Rs, #$u4, #$S6):raw",
4740     [], "$Rx = $_dst_" > {
4741     bits<5> Rx;
4742     bits<5> Rs;
4743     bits<4> u4;
4744     bits<6> S6;
4745
4746     let IClass = 0b1000;
4747
4748     let Inst{27-24} = 0b0111;
4749     let Inst{23-22} = MinOp;
4750     let Inst{21}    = u4{3};
4751     let Inst{20-16} = Rs;
4752     let Inst{13-8}  = S6;
4753     let Inst{7-5}   = u4{2-0};
4754     let Inst{4-0}   = Rx;
4755   }
4756
4757 let isCodeGenOnly = 0 in {
4758 def S2_tableidxb : tableidxRaw<"tableidxb", 0b00>;
4759 def S2_tableidxh : tableidxRaw<"tableidxh", 0b01>;
4760 def S2_tableidxw : tableidxRaw<"tableidxw", 0b10>;
4761 def S2_tableidxd : tableidxRaw<"tableidxd", 0b11>;
4762 }
4763
4764 // Change the sign of the immediate for Rd=-mpyi(Rs,#u8)
4765 def : Pat <(mul (i32 IntRegs:$src1), (ineg n8ImmPred:$src2)),
4766       (i32 (M2_mpysin (i32 IntRegs:$src1), u8ImmPred:$src2))>;
4767
4768 //===----------------------------------------------------------------------===//
4769 // V3 Instructions +
4770 //===----------------------------------------------------------------------===//
4771
4772 include "HexagonInstrInfoV3.td"
4773
4774 //===----------------------------------------------------------------------===//
4775 // V3 Instructions -
4776 //===----------------------------------------------------------------------===//
4777
4778 //===----------------------------------------------------------------------===//
4779 // V4 Instructions +
4780 //===----------------------------------------------------------------------===//
4781
4782 include "HexagonInstrInfoV4.td"
4783
4784 //===----------------------------------------------------------------------===//
4785 // V4 Instructions -
4786 //===----------------------------------------------------------------------===//
4787
4788 //===----------------------------------------------------------------------===//
4789 // V5 Instructions +
4790 //===----------------------------------------------------------------------===//
4791
4792 include "HexagonInstrInfoV5.td"
4793
4794 //===----------------------------------------------------------------------===//
4795 // V5 Instructions -
4796 //===----------------------------------------------------------------------===//