lib/Target/ARM/ARMInstrThumb2.td

   1 //===- ARMInstrThumb2.td - Thumb2 support for ARM -------------------------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Thumb2 instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 // IT block predicate field
  15 def it_pred : Operand<i32> {
  16   let PrintMethod = "printMandatoryPredicateOperand";
  17 }
  18
  19 // IT block condition mask
  20 def it_mask : Operand<i32> {
  21   let PrintMethod = "printThumbITMask";
  22 }
  23
  24 // Shifted operands. No register controlled shifts for Thumb2.
  25 // Note: We do not support rrx shifted operands yet.
  26 def t2_so_reg : Operand<i32>,    // reg imm
  27                 ComplexPattern<i32, 2, "SelectT2ShifterOperandReg",
  28                                [shl,srl,sra,rotr]> {
  29   let EncoderMethod = "getT2SORegOpValue";
  30   let PrintMethod = "printT2SOOperand";
  31   let MIOperandInfo = (ops rGPR, i32imm);
  32 }
  33
  34 // t2_so_imm_not_XFORM - Return the complement of a t2_so_imm value
  35 def t2_so_imm_not_XFORM : SDNodeXForm<imm, [{
  36   return CurDAG->getTargetConstant(~((uint32_t)N->getZExtValue()), MVT::i32);
  37 }]>;
  38
  39 // t2_so_imm_neg_XFORM - Return the negation of a t2_so_imm value
  40 def t2_so_imm_neg_XFORM : SDNodeXForm<imm, [{
  41   return CurDAG->getTargetConstant(-((int)N->getZExtValue()), MVT::i32);
  42 }]>;
  43
  44 // t2_so_imm - Match a 32-bit immediate operand, which is an
  45 // 8-bit immediate rotated by an arbitrary number of bits, or an 8-bit
  46 // immediate splatted into multiple bytes of the word.
  47 def t2_so_imm_asmoperand : AsmOperandClass { let Name = "T2SOImm"; }
  48 def t2_so_imm : Operand<i32>, ImmLeaf<i32, [{
  49     return ARM_AM::getT2SOImmVal(Imm) != -1;
  50   }]> {
  51   let ParserMatchClass = t2_so_imm_asmoperand;
  52   let EncoderMethod = "getT2SOImmOpValue";
  53   let DecoderMethod = "DecodeT2SOImm";
  54 }
  55
  56 // t2_so_imm_not - Match an immediate that is a complement
  57 // of a t2_so_imm.
  58 def t2_so_imm_not : Operand<i32>,
  59                     PatLeaf<(imm), [{
  60   return ARM_AM::getT2SOImmVal(~((uint32_t)N->getZExtValue())) != -1;
  61 }], t2_so_imm_not_XFORM>;
  62
  63 // t2_so_imm_neg - Match an immediate that is a negation of a t2_so_imm.
  64 def t2_so_imm_neg : Operand<i32>,
  65                     PatLeaf<(imm), [{
  66   return ARM_AM::getT2SOImmVal(-((uint32_t)N->getZExtValue())) != -1;
  67 }], t2_so_imm_neg_XFORM>;
  68
  69 /// imm1_31 predicate - True if the 32-bit immediate is in the range [1,31].
  70 def imm1_31 : Operand<i32>, ImmLeaf<i32, [{
  71   return (int32_t)Imm >= 1 && (int32_t)Imm < 32;
  72 }]>;
  73
  74 /// imm0_4095 predicate - True if the 32-bit immediate is in the range [0.4095].
  75 def imm0_4095 : Operand<i32>,
  76                 ImmLeaf<i32, [{
  77   return Imm >= 0 && Imm < 4096;
  78 }]>;
  79
  80 def imm0_4095_neg : PatLeaf<(i32 imm), [{
  81  return (uint32_t)(-N->getZExtValue()) < 4096;
  82 }], imm_neg_XFORM>;
  83
  84 def imm0_255_neg : PatLeaf<(i32 imm), [{
  85   return (uint32_t)(-N->getZExtValue()) < 255;
  86 }], imm_neg_XFORM>;
  87
  88 def imm0_255_not : PatLeaf<(i32 imm), [{
  89   return (uint32_t)(~N->getZExtValue()) < 255;
  90 }], imm_comp_XFORM>;
  91
  92 def lo5AllOne : PatLeaf<(i32 imm), [{
  93   // Returns true if all low 5-bits are 1.
  94   return (((uint32_t)N->getZExtValue()) & 0x1FUL) == 0x1FUL;
  95 }]>;
  96
  97 // Define Thumb2 specific addressing modes.
  98
  99 // t2addrmode_imm12  := reg + imm12
 100 def t2addrmode_imm12 : Operand<i32>,
 101                        ComplexPattern<i32, 2, "SelectT2AddrModeImm12", []> {
 102   let PrintMethod = "printAddrModeImm12Operand";
 103   let EncoderMethod = "getAddrModeImm12OpValue";
 104   let DecoderMethod = "DecodeT2AddrModeImm12";
 105   let MIOperandInfo = (ops GPR:$base, i32imm:$offsimm);
 106 }
 107
 108 // t2ldrlabel  := imm12
 109 def t2ldrlabel : Operand<i32> {
 110   let EncoderMethod = "getAddrModeImm12OpValue";
 111 }
 112
 113
 114 // ADR instruction labels.
 115 def t2adrlabel : Operand<i32> {
 116   let EncoderMethod = "getT2AdrLabelOpValue";
 117 }
 118
 119
 120 // t2addrmode_imm8  := reg +/- imm8
 121 def MemImm8OffsetAsmOperand : AsmOperandClass { let Name = "MemImm8Offset"; }
 122 def t2addrmode_imm8 : Operand<i32>,
 123                       ComplexPattern<i32, 2, "SelectT2AddrModeImm8", []> {
 124   let PrintMethod = "printT2AddrModeImm8Operand";
 125   let EncoderMethod = "getT2AddrModeImm8OpValue";
 126   let DecoderMethod = "DecodeT2AddrModeImm8";
 127   let ParserMatchClass = MemImm8OffsetAsmOperand;
 128   let MIOperandInfo = (ops GPR:$base, i32imm:$offsimm);
 129 }
 130
 131 def t2am_imm8_offset : Operand<i32>,
 132                        ComplexPattern<i32, 1, "SelectT2AddrModeImm8Offset",
 133                                       [], [SDNPWantRoot]> {
 134   let PrintMethod = "printT2AddrModeImm8OffsetOperand";
 135   let EncoderMethod = "getT2AddrModeImm8OffsetOpValue";
 136   let DecoderMethod = "DecodeT2Imm8";
 137 }
 138
 139 // t2addrmode_imm8s4  := reg +/- (imm8 << 2)
 140 def t2addrmode_imm8s4 : Operand<i32> {
 141   let PrintMethod = "printT2AddrModeImm8s4Operand";
 142   let EncoderMethod = "getT2AddrModeImm8s4OpValue";
 143   let DecoderMethod = "DecodeT2AddrModeImm8s4";
 144   let MIOperandInfo = (ops GPR:$base, i32imm:$offsimm);
 145 }
 146
 147 def t2am_imm8s4_offset : Operand<i32> {
 148   let PrintMethod = "printT2AddrModeImm8s4OffsetOperand";
 149   let DecoderMethod = "DecodeT2Imm8S4";
 150 }
 151
 152 // t2addrmode_so_reg  := reg + (reg << imm2)
 153 def t2addrmode_so_reg : Operand<i32>,
 154                         ComplexPattern<i32, 3, "SelectT2AddrModeSoReg", []> {
 155   let PrintMethod = "printT2AddrModeSoRegOperand";
 156   let EncoderMethod = "getT2AddrModeSORegOpValue";
 157   let DecoderMethod = "DecodeT2AddrModeSOReg";
 158   let MIOperandInfo = (ops GPR:$base, rGPR:$offsreg, i32imm:$offsimm);
 159 }
 160
 161 // t2addrmode_reg := reg
 162 // Used by load/store exclusive instructions. Useful to enable right assembly
 163 // parsing and printing. Not used for any codegen matching.
 164 //
 165 def t2addrmode_reg : Operand<i32> {
 166   let PrintMethod = "printAddrMode7Operand";
 167   let DecoderMethod = "DecodeGPRRegisterClass";
 168   let MIOperandInfo = (ops GPR);
 169 }
 170
 171 //===----------------------------------------------------------------------===//
 172 // Multiclass helpers...
 173 //
 174
 175
 176 class T2OneRegImm<dag oops, dag iops, InstrItinClass itin,
 177            string opc, string asm, list<dag> pattern>
 178   : T2I<oops, iops, itin, opc, asm, pattern> {
 179   bits<4> Rd;
 180   bits<12> imm;
 181
 182   let Inst{11-8}  = Rd;
 183   let Inst{26}    = imm{11};
 184   let Inst{14-12} = imm{10-8};
 185   let Inst{7-0}   = imm{7-0};
 186 }
 187
 188
 189 class T2sOneRegImm<dag oops, dag iops, InstrItinClass itin,
 190            string opc, string asm, list<dag> pattern>
 191   : T2sI<oops, iops, itin, opc, asm, pattern> {
 192   bits<4> Rd;
 193   bits<4> Rn;
 194   bits<12> imm;
 195
 196   let Inst{11-8}  = Rd;
 197   let Inst{26}    = imm{11};
 198   let Inst{14-12} = imm{10-8};
 199   let Inst{7-0}   = imm{7-0};
 200 }
 201
 202 class T2OneRegCmpImm<dag oops, dag iops, InstrItinClass itin,
 203            string opc, string asm, list<dag> pattern>
 204   : T2I<oops, iops, itin, opc, asm, pattern> {
 205   bits<4> Rn;
 206   bits<12> imm;
 207
 208   let Inst{19-16}  = Rn;
 209   let Inst{26}    = imm{11};
 210   let Inst{14-12} = imm{10-8};
 211   let Inst{7-0}   = imm{7-0};
 212 }
 213
 214
 215 class T2OneRegShiftedReg<dag oops, dag iops, InstrItinClass itin,
 216            string opc, string asm, list<dag> pattern>
 217   : T2I<oops, iops, itin, opc, asm, pattern> {
 218   bits<4> Rd;
 219   bits<12> ShiftedRm;
 220
 221   let Inst{11-8}  = Rd;
 222   let Inst{3-0}   = ShiftedRm{3-0};
 223   let Inst{5-4}   = ShiftedRm{6-5};
 224   let Inst{14-12} = ShiftedRm{11-9};
 225   let Inst{7-6}   = ShiftedRm{8-7};
 226 }
 227
 228 class T2sOneRegShiftedReg<dag oops, dag iops, InstrItinClass itin,
 229            string opc, string asm, list<dag> pattern>
 230   : T2sI<oops, iops, itin, opc, asm, pattern> {
 231   bits<4> Rd;
 232   bits<12> ShiftedRm;
 233
 234   let Inst{11-8}  = Rd;
 235   let Inst{3-0}   = ShiftedRm{3-0};
 236   let Inst{5-4}   = ShiftedRm{6-5};
 237   let Inst{14-12} = ShiftedRm{11-9};
 238   let Inst{7-6}   = ShiftedRm{8-7};
 239 }
 240
 241 class T2OneRegCmpShiftedReg<dag oops, dag iops, InstrItinClass itin,
 242            string opc, string asm, list<dag> pattern>
 243   : T2I<oops, iops, itin, opc, asm, pattern> {
 244   bits<4> Rn;
 245   bits<12> ShiftedRm;
 246
 247   let Inst{19-16} = Rn;
 248   let Inst{3-0}   = ShiftedRm{3-0};
 249   let Inst{5-4}   = ShiftedRm{6-5};
 250   let Inst{14-12} = ShiftedRm{11-9};
 251   let Inst{7-6}   = ShiftedRm{8-7};
 252 }
 253
 254 class T2TwoReg<dag oops, dag iops, InstrItinClass itin,
 255            string opc, string asm, list<dag> pattern>
 256   : T2I<oops, iops, itin, opc, asm, pattern> {
 257   bits<4> Rd;
 258   bits<4> Rm;
 259
 260   let Inst{11-8}  = Rd;
 261   let Inst{3-0}   = Rm;
 262 }
 263
 264 class T2sTwoReg<dag oops, dag iops, InstrItinClass itin,
 265            string opc, string asm, list<dag> pattern>
 266   : T2sI<oops, iops, itin, opc, asm, pattern> {
 267   bits<4> Rd;
 268   bits<4> Rm;
 269
 270   let Inst{11-8}  = Rd;
 271   let Inst{3-0}   = Rm;
 272 }
 273
 274 class T2TwoRegCmp<dag oops, dag iops, InstrItinClass itin,
 275            string opc, string asm, list<dag> pattern>
 276   : T2I<oops, iops, itin, opc, asm, pattern> {
 277   bits<4> Rn;
 278   bits<4> Rm;
 279
 280   let Inst{19-16} = Rn;
 281   let Inst{3-0}   = Rm;
 282 }
 283
 284
 285 class T2TwoRegImm<dag oops, dag iops, InstrItinClass itin,
 286            string opc, string asm, list<dag> pattern>
 287   : T2I<oops, iops, itin, opc, asm, pattern> {
 288   bits<4> Rd;
 289   bits<4> Rn;
 290   bits<12> imm;
 291
 292   let Inst{11-8}  = Rd;
 293   let Inst{19-16} = Rn;
 294   let Inst{26}    = imm{11};
 295   let Inst{14-12} = imm{10-8};
 296   let Inst{7-0}   = imm{7-0};
 297 }
 298
 299 class T2sTwoRegImm<dag oops, dag iops, InstrItinClass itin,
 300            string opc, string asm, list<dag> pattern>
 301   : T2sI<oops, iops, itin, opc, asm, pattern> {
 302   bits<4> Rd;
 303   bits<4> Rn;
 304   bits<12> imm;
 305
 306   let Inst{11-8}  = Rd;
 307   let Inst{19-16} = Rn;
 308   let Inst{26}    = imm{11};
 309   let Inst{14-12} = imm{10-8};
 310   let Inst{7-0}   = imm{7-0};
 311 }
 312
 313 class T2TwoRegShiftImm<dag oops, dag iops, InstrItinClass itin,
 314            string opc, string asm, list<dag> pattern>
 315   : T2I<oops, iops, itin, opc, asm, pattern> {
 316   bits<4> Rd;
 317   bits<4> Rm;
 318   bits<5> imm;
 319
 320   let Inst{11-8}  = Rd;
 321   let Inst{3-0}   = Rm;
 322   let Inst{14-12} = imm{4-2};
 323   let Inst{7-6}   = imm{1-0};
 324 }
 325
 326 class T2sTwoRegShiftImm<dag oops, dag iops, InstrItinClass itin,
 327            string opc, string asm, list<dag> pattern>
 328   : T2sI<oops, iops, itin, opc, asm, pattern> {
 329   bits<4> Rd;
 330   bits<4> Rm;
 331   bits<5> imm;
 332
 333   let Inst{11-8}  = Rd;
 334   let Inst{3-0}   = Rm;
 335   let Inst{14-12} = imm{4-2};
 336   let Inst{7-6}   = imm{1-0};
 337 }
 338
 339 class T2ThreeReg<dag oops, dag iops, InstrItinClass itin,
 340            string opc, string asm, list<dag> pattern>
 341   : T2I<oops, iops, itin, opc, asm, pattern> {
 342   bits<4> Rd;
 343   bits<4> Rn;
 344   bits<4> Rm;
 345
 346   let Inst{11-8}  = Rd;
 347   let Inst{19-16} = Rn;
 348   let Inst{3-0}   = Rm;
 349 }
 350
 351 class T2sThreeReg<dag oops, dag iops, InstrItinClass itin,
 352            string opc, string asm, list<dag> pattern>
 353   : T2sI<oops, iops, itin, opc, asm, pattern> {
 354   bits<4> Rd;
 355   bits<4> Rn;
 356   bits<4> Rm;
 357
 358   let Inst{11-8}  = Rd;
 359   let Inst{19-16} = Rn;
 360   let Inst{3-0}   = Rm;
 361 }
 362
 363 class T2TwoRegShiftedReg<dag oops, dag iops, InstrItinClass itin,
 364            string opc, string asm, list<dag> pattern>
 365   : T2I<oops, iops, itin, opc, asm, pattern> {
 366   bits<4> Rd;
 367   bits<4> Rn;
 368   bits<12> ShiftedRm;
 369
 370   let Inst{11-8}  = Rd;
 371   let Inst{19-16} = Rn;
 372   let Inst{3-0}   = ShiftedRm{3-0};
 373   let Inst{5-4}   = ShiftedRm{6-5};
 374   let Inst{14-12} = ShiftedRm{11-9};
 375   let Inst{7-6}   = ShiftedRm{8-7};
 376 }
 377
 378 class T2sTwoRegShiftedReg<dag oops, dag iops, InstrItinClass itin,
 379            string opc, string asm, list<dag> pattern>
 380   : T2sI<oops, iops, itin, opc, asm, pattern> {
 381   bits<4> Rd;
 382   bits<4> Rn;
 383   bits<12> ShiftedRm;
 384
 385   let Inst{11-8}  = Rd;
 386   let Inst{19-16} = Rn;
 387   let Inst{3-0}   = ShiftedRm{3-0};
 388   let Inst{5-4}   = ShiftedRm{6-5};
 389   let Inst{14-12} = ShiftedRm{11-9};
 390   let Inst{7-6}   = ShiftedRm{8-7};
 391 }
 392
 393 class T2FourReg<dag oops, dag iops, InstrItinClass itin,
 394            string opc, string asm, list<dag> pattern>
 395   : T2I<oops, iops, itin, opc, asm, pattern> {
 396   bits<4> Rd;
 397   bits<4> Rn;
 398   bits<4> Rm;
 399   bits<4> Ra;
 400
 401   let Inst{19-16} = Rn;
 402   let Inst{15-12} = Ra;
 403   let Inst{11-8}  = Rd;
 404   let Inst{3-0}   = Rm;
 405 }
 406
 407 class T2MulLong<bits<3> opc22_20, bits<4> opc7_4,
 408                 dag oops, dag iops, InstrItinClass itin,
 409                 string opc, string asm, list<dag> pattern>
 410   : T2I<oops, iops, itin, opc, asm, pattern> {
 411   bits<4> RdLo;
 412   bits<4> RdHi;
 413   bits<4> Rn;
 414   bits<4> Rm;
 415
 416   let Inst{31-23} = 0b111110111;
 417   let Inst{22-20} = opc22_20;
 418   let Inst{19-16} = Rn;
 419   let Inst{15-12} = RdLo;
 420   let Inst{11-8}  = RdHi;
 421   let Inst{7-4}   = opc7_4;
 422   let Inst{3-0}   = Rm;
 423 }
 424
 425
 426 /// T2I_un_irs - Defines a set of (op reg, {so_imm|r|so_reg}) patterns for a
 427 /// unary operation that produces a value. These are predicable and can be
 428 /// changed to modify CPSR.
 429 multiclass T2I_un_irs<bits<4> opcod, string opc,
 430                      InstrItinClass iii, InstrItinClass iir, InstrItinClass iis,
 431                       PatFrag opnode, bit Cheap = 0, bit ReMat = 0> {
 432    // shifted imm
 433    def i : T2sOneRegImm<(outs rGPR:$Rd), (ins t2_so_imm:$imm), iii,
 434                 opc, "\t$Rd, $imm",
 435                 [(set rGPR:$Rd, (opnode t2_so_imm:$imm))]> {
 436      let isAsCheapAsAMove = Cheap;
 437      let isReMaterializable = ReMat;
 438      let Inst{31-27} = 0b11110;
 439      let Inst{25} = 0;
 440      let Inst{24-21} = opcod;
 441      let Inst{19-16} = 0b1111; // Rn
 442      let Inst{15} = 0;
 443    }
 444    // register
 445    def r : T2sTwoReg<(outs rGPR:$Rd), (ins rGPR:$Rm), iir,
 446                 opc, ".w\t$Rd, $Rm",
 447                 [(set rGPR:$Rd, (opnode rGPR:$Rm))]> {
 448      let Inst{31-27} = 0b11101;
 449      let Inst{26-25} = 0b01;
 450      let Inst{24-21} = opcod;
 451      let Inst{19-16} = 0b1111; // Rn
 452      let Inst{14-12} = 0b000; // imm3
 453      let Inst{7-6} = 0b00; // imm2
 454      let Inst{5-4} = 0b00; // type
 455    }
 456    // shifted register
 457    def s : T2sOneRegShiftedReg<(outs rGPR:$Rd), (ins t2_so_reg:$ShiftedRm), iis,
 458                 opc, ".w\t$Rd, $ShiftedRm",
 459                 [(set rGPR:$Rd, (opnode t2_so_reg:$ShiftedRm))]> {
 460      let Inst{31-27} = 0b11101;
 461      let Inst{26-25} = 0b01;
 462      let Inst{24-21} = opcod;
 463      let Inst{19-16} = 0b1111; // Rn
 464    }
 465 }
 466
 467 /// T2I_bin_irs - Defines a set of (op reg, {so_imm|r|so_reg}) patterns for a
 468 /// binary operation that produces a value. These are predicable and can be
 469 /// changed to modify CPSR.
 470 multiclass T2I_bin_irs<bits<4> opcod, string opc,
 471                      InstrItinClass iii, InstrItinClass iir, InstrItinClass iis,
 472                        PatFrag opnode, string baseOpc, bit Commutable = 0,
 473                        string wide = ""> {
 474    // shifted imm
 475    def ri : T2sTwoRegImm<
 476                 (outs rGPR:$Rd), (ins rGPR:$Rn, t2_so_imm:$imm), iii,
 477                  opc, "\t$Rd, $Rn, $imm",
 478                  [(set rGPR:$Rd, (opnode rGPR:$Rn, t2_so_imm:$imm))]> {
 479      let Inst{31-27} = 0b11110;
 480      let Inst{25} = 0;
 481      let Inst{24-21} = opcod;
 482      let Inst{15} = 0;
 483    }
 484    // register
 485    def rr : T2sThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), iir,
 486                  opc, !strconcat(wide, "\t$Rd, $Rn, $Rm"),
 487                  [(set rGPR:$Rd, (opnode rGPR:$Rn, rGPR:$Rm))]> {
 488      let isCommutable = Commutable;
 489      let Inst{31-27} = 0b11101;
 490      let Inst{26-25} = 0b01;
 491      let Inst{24-21} = opcod;
 492      let Inst{14-12} = 0b000; // imm3
 493      let Inst{7-6} = 0b00; // imm2
 494      let Inst{5-4} = 0b00; // type
 495    }
 496    // shifted register
 497    def rs : T2sTwoRegShiftedReg<
 498                  (outs rGPR:$Rd), (ins rGPR:$Rn, t2_so_reg:$ShiftedRm), iis,
 499                  opc, !strconcat(wide, "\t$Rd, $Rn, $ShiftedRm"),
 500                  [(set rGPR:$Rd, (opnode rGPR:$Rn, t2_so_reg:$ShiftedRm))]> {
 501      let Inst{31-27} = 0b11101;
 502      let Inst{26-25} = 0b01;
 503      let Inst{24-21} = opcod;
 504    }
 505   // Assembly aliases for optional destination operand when it's the same
 506   // as the source operand.
 507   def : InstAlias<!strconcat(opc, "${s}${p} $Rdn, $imm"),
 508      (!cast<Instruction>(!strconcat(baseOpc, "ri")) rGPR:$Rdn, rGPR:$Rdn,
 509                                                     t2_so_imm:$imm, pred:$p,
 510                                                     cc_out:$s)>,
 511      Requires<[IsThumb2]>;
 512   def : InstAlias<!strconcat(opc, "${s}${p}", wide, " $Rdn, $Rm"),
 513      (!cast<Instruction>(!strconcat(baseOpc, "rr")) rGPR:$Rdn, rGPR:$Rdn,
 514                                                     rGPR:$Rm, pred:$p,
 515                                                     cc_out:$s)>,
 516      Requires<[IsThumb2]>;
 517   def : InstAlias<!strconcat(opc, "${s}${p}", wide, " $Rdn, $shift"),
 518      (!cast<Instruction>(!strconcat(baseOpc, "rs")) rGPR:$Rdn, rGPR:$Rdn,
 519                                                     t2_so_reg:$shift, pred:$p,
 520                                                     cc_out:$s)>,
 521      Requires<[IsThumb2]>;
 522 }
 523
 524 /// T2I_bin_w_irs - Same as T2I_bin_irs except these operations need
 525 //  the ".w" suffix to indicate that they are wide.
 526 multiclass T2I_bin_w_irs<bits<4> opcod, string opc,
 527                      InstrItinClass iii, InstrItinClass iir, InstrItinClass iis,
 528                          PatFrag opnode, string baseOpc, bit Commutable = 0> :
 529     T2I_bin_irs<opcod, opc, iii, iir, iis, opnode, baseOpc, Commutable, ".w">;
 530
 531 /// T2I_rbin_is - Same as T2I_bin_irs except the order of operands are
 532 /// reversed.  The 'rr' form is only defined for the disassembler; for codegen
 533 /// it is equivalent to the T2I_bin_irs counterpart.
 534 multiclass T2I_rbin_irs<bits<4> opcod, string opc, PatFrag opnode> {
 535    // shifted imm
 536    def ri : T2sTwoRegImm<
 537                  (outs rGPR:$Rd), (ins rGPR:$Rn, t2_so_imm:$imm), IIC_iALUi,
 538                  opc, ".w\t$Rd, $Rn, $imm",
 539                  [(set rGPR:$Rd, (opnode t2_so_imm:$imm, rGPR:$Rn))]> {
 540      let Inst{31-27} = 0b11110;
 541      let Inst{25} = 0;
 542      let Inst{24-21} = opcod;
 543      let Inst{15} = 0;
 544    }
 545    // register
 546    def rr : T2sThreeReg<
 547                  (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iALUr,
 548                  opc, "\t$Rd, $Rn, $Rm",
 549                  [/* For disassembly only; pattern left blank */]> {
 550      let Inst{31-27} = 0b11101;
 551      let Inst{26-25} = 0b01;
 552      let Inst{24-21} = opcod;
 553      let Inst{14-12} = 0b000; // imm3
 554      let Inst{7-6} = 0b00; // imm2
 555      let Inst{5-4} = 0b00; // type
 556    }
 557    // shifted register
 558    def rs : T2sTwoRegShiftedReg<
 559                  (outs rGPR:$Rd), (ins rGPR:$Rn, t2_so_reg:$ShiftedRm),
 560                  IIC_iALUsir, opc, "\t$Rd, $Rn, $ShiftedRm",
 561                  [(set rGPR:$Rd, (opnode t2_so_reg:$ShiftedRm, rGPR:$Rn))]> {
 562      let Inst{31-27} = 0b11101;
 563      let Inst{26-25} = 0b01;
 564      let Inst{24-21} = opcod;
 565    }
 566 }
 567
 568 /// T2I_bin_s_irs - Similar to T2I_bin_irs except it sets the 's' bit so the
 569 /// instruction modifies the CPSR register.
 570 let isCodeGenOnly = 1, Defs = [CPSR] in {
 571 multiclass T2I_bin_s_irs<bits<4> opcod, string opc,
 572                      InstrItinClass iii, InstrItinClass iir, InstrItinClass iis,
 573                          PatFrag opnode, bit Commutable = 0> {
 574    // shifted imm
 575    def ri : T2TwoRegImm<
 576                 (outs rGPR:$Rd), (ins GPR:$Rn, t2_so_imm:$imm), iii,
 577                 !strconcat(opc, "s"), ".w\t$Rd, $Rn, $imm",
 578                 [(set rGPR:$Rd, (opnode GPR:$Rn, t2_so_imm:$imm))]> {
 579      let Inst{31-27} = 0b11110;
 580      let Inst{25} = 0;
 581      let Inst{24-21} = opcod;
 582      let Inst{20} = 1; // The S bit.
 583      let Inst{15} = 0;
 584    }
 585    // register
 586    def rr : T2ThreeReg<
 587                 (outs rGPR:$Rd), (ins GPR:$Rn, rGPR:$Rm), iir,
 588                 !strconcat(opc, "s"), ".w\t$Rd, $Rn, $Rm",
 589                 [(set rGPR:$Rd, (opnode GPR:$Rn, rGPR:$Rm))]> {
 590      let isCommutable = Commutable;
 591      let Inst{31-27} = 0b11101;
 592      let Inst{26-25} = 0b01;
 593      let Inst{24-21} = opcod;
 594      let Inst{20} = 1; // The S bit.
 595      let Inst{14-12} = 0b000; // imm3
 596      let Inst{7-6} = 0b00; // imm2
 597      let Inst{5-4} = 0b00; // type
 598    }
 599    // shifted register
 600    def rs : T2TwoRegShiftedReg<
 601                 (outs rGPR:$Rd), (ins GPR:$Rn, t2_so_reg:$ShiftedRm), iis,
 602                 !strconcat(opc, "s"), ".w\t$Rd, $Rn, $ShiftedRm",
 603                 [(set rGPR:$Rd, (opnode GPR:$Rn, t2_so_reg:$ShiftedRm))]> {
 604      let Inst{31-27} = 0b11101;
 605      let Inst{26-25} = 0b01;
 606      let Inst{24-21} = opcod;
 607      let Inst{20} = 1; // The S bit.
 608    }
 609 }
 610 }
 611
 612 /// T2I_bin_ii12rs - Defines a set of (op reg, {so_imm|imm0_4095|r|so_reg})
 613 /// patterns for a binary operation that produces a value.
 614 multiclass T2I_bin_ii12rs<bits<3> op23_21, string opc, PatFrag opnode,
 615                           bit Commutable = 0> {
 616    // shifted imm
 617    // The register-immediate version is re-materializable. This is useful
 618    // in particular for taking the address of a local.
 619    let isReMaterializable = 1 in {
 620    def ri : T2sTwoRegImm<
 621                  (outs rGPR:$Rd), (ins GPR:$Rn, t2_so_imm:$imm), IIC_iALUi,
 622                  opc, ".w\t$Rd, $Rn, $imm",
 623                  [(set rGPR:$Rd, (opnode GPR:$Rn, t2_so_imm:$imm))]> {
 624      let Inst{31-27} = 0b11110;
 625      let Inst{25} = 0;
 626      let Inst{24} = 1;
 627      let Inst{23-21} = op23_21;
 628      let Inst{15} = 0;
 629    }
 630    }
 631    // 12-bit imm
 632    def ri12 : T2I<
 633                   (outs rGPR:$Rd), (ins GPR:$Rn, imm0_4095:$imm), IIC_iALUi,
 634                   !strconcat(opc, "w"), "\t$Rd, $Rn, $imm",
 635                   [(set rGPR:$Rd, (opnode GPR:$Rn, imm0_4095:$imm))]> {
 636      bits<4> Rd;
 637      bits<4> Rn;
 638      bits<12> imm;
 639      let Inst{31-27} = 0b11110;
 640      let Inst{26} = imm{11};
 641      let Inst{25-24} = 0b10;
 642      let Inst{23-21} = op23_21;
 643      let Inst{20} = 0; // The S bit.
 644      let Inst{19-16} = Rn;
 645      let Inst{15} = 0;
 646      let Inst{14-12} = imm{10-8};
 647      let Inst{11-8} = Rd;
 648      let Inst{7-0} = imm{7-0};
 649    }
 650    // register
 651    def rr : T2sThreeReg<(outs rGPR:$Rd), (ins GPR:$Rn, rGPR:$Rm), IIC_iALUr,
 652                  opc, ".w\t$Rd, $Rn, $Rm",
 653                  [(set rGPR:$Rd, (opnode GPR:$Rn, rGPR:$Rm))]> {
 654      let isCommutable = Commutable;
 655      let Inst{31-27} = 0b11101;
 656      let Inst{26-25} = 0b01;
 657      let Inst{24} = 1;
 658      let Inst{23-21} = op23_21;
 659      let Inst{14-12} = 0b000; // imm3
 660      let Inst{7-6} = 0b00; // imm2
 661      let Inst{5-4} = 0b00; // type
 662    }
 663    // shifted register
 664    def rs : T2sTwoRegShiftedReg<
 665                  (outs rGPR:$Rd), (ins GPR:$Rn, t2_so_reg:$ShiftedRm),
 666                  IIC_iALUsi, opc, ".w\t$Rd, $Rn, $ShiftedRm",
 667                  [(set rGPR:$Rd, (opnode GPR:$Rn, t2_so_reg:$ShiftedRm))]> {
 668      let Inst{31-27} = 0b11101;
 669      let Inst{26-25} = 0b01;
 670      let Inst{24} = 1;
 671      let Inst{23-21} = op23_21;
 672    }
 673 }
 674
 675 /// T2I_adde_sube_irs - Defines a set of (op reg, {so_imm|r|so_reg}) patterns
 676 /// for a binary operation that produces a value and use the carry
 677 /// bit. It's not predicable.
 678 let Uses = [CPSR] in {
 679 multiclass T2I_adde_sube_irs<bits<4> opcod, string opc, PatFrag opnode,
 680                              bit Commutable = 0> {
 681    // shifted imm
 682    def ri : T2sTwoRegImm<(outs rGPR:$Rd), (ins rGPR:$Rn, t2_so_imm:$imm),
 683                  IIC_iALUi, opc, "\t$Rd, $Rn, $imm",
 684                  [(set rGPR:$Rd, (opnode rGPR:$Rn, t2_so_imm:$imm))]>,
 685                  Requires<[IsThumb2]> {
 686      let Inst{31-27} = 0b11110;
 687      let Inst{25} = 0;
 688      let Inst{24-21} = opcod;
 689      let Inst{15} = 0;
 690    }
 691    // register
 692    def rr : T2sThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iALUr,
 693                  opc, ".w\t$Rd, $Rn, $Rm",
 694                  [(set rGPR:$Rd, (opnode rGPR:$Rn, rGPR:$Rm))]>,
 695                  Requires<[IsThumb2]> {
 696      let isCommutable = Commutable;
 697      let Inst{31-27} = 0b11101;
 698      let Inst{26-25} = 0b01;
 699      let Inst{24-21} = opcod;
 700      let Inst{14-12} = 0b000; // imm3
 701      let Inst{7-6} = 0b00; // imm2
 702      let Inst{5-4} = 0b00; // type
 703    }
 704    // shifted register
 705    def rs : T2sTwoRegShiftedReg<
 706                  (outs rGPR:$Rd), (ins rGPR:$Rn, t2_so_reg:$ShiftedRm),
 707                  IIC_iALUsi, opc, ".w\t$Rd, $Rn, $ShiftedRm",
 708                  [(set rGPR:$Rd, (opnode rGPR:$Rn, t2_so_reg:$ShiftedRm))]>,
 709                  Requires<[IsThumb2]> {
 710      let Inst{31-27} = 0b11101;
 711      let Inst{26-25} = 0b01;
 712      let Inst{24-21} = opcod;
 713    }
 714 }
 715 }
 716
 717 // Carry setting variants
 718 // NOTE: CPSR def omitted because it will be handled by the custom inserter.
 719 let usesCustomInserter = 1 in {
 720 multiclass T2I_adde_sube_s_irs<PatFrag opnode, bit Commutable = 0> {
 721    // shifted imm
 722    def ri : t2PseudoInst<(outs rGPR:$Rd), (ins rGPR:$Rn, t2_so_imm:$imm),
 723                 4, IIC_iALUi,
 724                 [(set rGPR:$Rd, (opnode rGPR:$Rn, t2_so_imm:$imm))]>;
 725    // register
 726    def rr : t2PseudoInst<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm),
 727                 4, IIC_iALUr,
 728                 [(set rGPR:$Rd, (opnode rGPR:$Rn, rGPR:$Rm))]> {
 729      let isCommutable = Commutable;
 730    }
 731    // shifted register
 732    def rs : t2PseudoInst<
 733                 (outs rGPR:$Rd), (ins rGPR:$Rn, t2_so_reg:$ShiftedRm),
 734                 4, IIC_iALUsi,
 735                 [(set rGPR:$Rd, (opnode rGPR:$Rn, t2_so_reg:$ShiftedRm))]>;
 736 }
 737 }
 738
 739 /// T2I_rbin_s_is - Same as T2I_rbin_irs except sets 's' bit and the register
 740 /// version is not needed since this is only for codegen.
 741 let isCodeGenOnly = 1, Defs = [CPSR] in {
 742 multiclass T2I_rbin_s_is<bits<4> opcod, string opc, PatFrag opnode> {
 743    // shifted imm
 744    def ri : T2TwoRegImm<
 745                 (outs rGPR:$Rd), (ins rGPR:$Rn, t2_so_imm:$imm), IIC_iALUi,
 746                 !strconcat(opc, "s"), ".w\t$Rd, $Rn, $imm",
 747                 [(set rGPR:$Rd, (opnode t2_so_imm:$imm, rGPR:$Rn))]> {
 748      let Inst{31-27} = 0b11110;
 749      let Inst{25} = 0;
 750      let Inst{24-21} = opcod;
 751      let Inst{20} = 1; // The S bit.
 752      let Inst{15} = 0;
 753    }
 754    // shifted register
 755    def rs : T2TwoRegShiftedReg<
 756                 (outs rGPR:$Rd), (ins rGPR:$Rn, t2_so_reg:$ShiftedRm),
 757                 IIC_iALUsi, !strconcat(opc, "s"), "\t$Rd, $Rn, $ShiftedRm",
 758                 [(set rGPR:$Rd, (opnode t2_so_reg:$ShiftedRm, rGPR:$Rn))]> {
 759      let Inst{31-27} = 0b11101;
 760      let Inst{26-25} = 0b01;
 761      let Inst{24-21} = opcod;
 762      let Inst{20} = 1; // The S bit.
 763    }
 764 }
 765 }
 766
 767 /// T2I_sh_ir - Defines a set of (op reg, {so_imm|r}) patterns for a shift /
 768 //  rotate operation that produces a value.
 769 multiclass T2I_sh_ir<bits<2> opcod, string opc, Operand ty, PatFrag opnode> {
 770    // 5-bit imm
 771    def ri : T2sTwoRegShiftImm<
 772                  (outs rGPR:$Rd), (ins rGPR:$Rm, ty:$imm), IIC_iMOVsi,
 773                  opc, ".w\t$Rd, $Rm, $imm",
 774                  [(set rGPR:$Rd, (opnode rGPR:$Rm, ty:$imm))]> {
 775      let Inst{31-27} = 0b11101;
 776      let Inst{26-21} = 0b010010;
 777      let Inst{19-16} = 0b1111; // Rn
 778      let Inst{5-4} = opcod;
 779    }
 780    // register
 781    def rr : T2sThreeReg<
 782                  (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iMOVsr,
 783                  opc, ".w\t$Rd, $Rn, $Rm",
 784                  [(set rGPR:$Rd, (opnode rGPR:$Rn, rGPR:$Rm))]> {
 785      let Inst{31-27} = 0b11111;
 786      let Inst{26-23} = 0b0100;
 787      let Inst{22-21} = opcod;
 788      let Inst{15-12} = 0b1111;
 789      let Inst{7-4} = 0b0000;
 790    }
 791 }
 792
 793 /// T2I_cmp_irs - Defines a set of (op r, {so_imm|r|so_reg}) cmp / test
 794 /// patterns. Similar to T2I_bin_irs except the instruction does not produce
 795 /// a explicit result, only implicitly set CPSR.
 796 let isCompare = 1, Defs = [CPSR] in {
 797 multiclass T2I_cmp_irs<bits<4> opcod, string opc,
 798                      InstrItinClass iii, InstrItinClass iir, InstrItinClass iis,
 799                        PatFrag opnode> {
 800    // shifted imm
 801    def ri : T2OneRegCmpImm<
 802                 (outs), (ins GPR:$Rn, t2_so_imm:$imm), iii,
 803                 opc, ".w\t$Rn, $imm",
 804                 [(opnode GPR:$Rn, t2_so_imm:$imm)]> {
 805      let Inst{31-27} = 0b11110;
 806      let Inst{25} = 0;
 807      let Inst{24-21} = opcod;
 808      let Inst{20} = 1; // The S bit.
 809      let Inst{15} = 0;
 810      let Inst{11-8} = 0b1111; // Rd
 811    }
 812    // register
 813    def rr : T2TwoRegCmp<
 814                 (outs), (ins GPR:$lhs, rGPR:$rhs), iir,
 815                 opc, ".w\t$lhs, $rhs",
 816                 [(opnode GPR:$lhs, rGPR:$rhs)]> {
 817      let Inst{31-27} = 0b11101;
 818      let Inst{26-25} = 0b01;
 819      let Inst{24-21} = opcod;
 820      let Inst{20} = 1; // The S bit.
 821      let Inst{14-12} = 0b000; // imm3
 822      let Inst{11-8} = 0b1111; // Rd
 823      let Inst{7-6} = 0b00; // imm2
 824      let Inst{5-4} = 0b00; // type
 825    }
 826    // shifted register
 827    def rs : T2OneRegCmpShiftedReg<
 828                 (outs), (ins GPR:$Rn, t2_so_reg:$ShiftedRm), iis,
 829                 opc, ".w\t$Rn, $ShiftedRm",
 830                 [(opnode GPR:$Rn, t2_so_reg:$ShiftedRm)]> {
 831      let Inst{31-27} = 0b11101;
 832      let Inst{26-25} = 0b01;
 833      let Inst{24-21} = opcod;
 834      let Inst{20} = 1; // The S bit.
 835      let Inst{11-8} = 0b1111; // Rd
 836    }
 837 }
 838 }
 839
 840 /// T2I_ld - Defines a set of (op r, {imm12|imm8|so_reg}) load patterns.
 841 multiclass T2I_ld<bit signed, bits<2> opcod, string opc,
 842                   InstrItinClass iii, InstrItinClass iis, PatFrag opnode> {
 843   def i12 : T2Ii12<(outs GPR:$Rt), (ins t2addrmode_imm12:$addr), iii,
 844                    opc, ".w\t$Rt, $addr",
 845                    [(set GPR:$Rt, (opnode t2addrmode_imm12:$addr))]> {
 846     let Inst{31-27} = 0b11111;
 847     let Inst{26-25} = 0b00;
 848     let Inst{24} = signed;
 849     let Inst{23} = 1;
 850     let Inst{22-21} = opcod;
 851     let Inst{20} = 1; // load
 852
 853     bits<4> Rt;
 854     let Inst{15-12} = Rt;
 855
 856     bits<17> addr;
 857     let addr{12}    = 1;           // add = TRUE
 858     let Inst{19-16} = addr{16-13}; // Rn
 859     let Inst{23}    = addr{12};    // U
 860     let Inst{11-0}  = addr{11-0};  // imm
 861   }
 862   def i8  : T2Ii8 <(outs GPR:$Rt), (ins t2addrmode_imm8:$addr), iii,
 863                    opc, "\t$Rt, $addr",
 864                    [(set GPR:$Rt, (opnode t2addrmode_imm8:$addr))]> {
 865     let Inst{31-27} = 0b11111;
 866     let Inst{26-25} = 0b00;
 867     let Inst{24} = signed;
 868     let Inst{23} = 0;
 869     let Inst{22-21} = opcod;
 870     let Inst{20} = 1; // load
 871     let Inst{11} = 1;
 872     // Offset: index==TRUE, wback==FALSE
 873     let Inst{10} = 1; // The P bit.
 874     let Inst{8} = 0; // The W bit.
 875
 876     bits<4> Rt;
 877     let Inst{15-12} = Rt;
 878
 879     bits<13> addr;
 880     let Inst{19-16} = addr{12-9}; // Rn
 881     let Inst{9}     = addr{8};    // U
 882     let Inst{7-0}   = addr{7-0};  // imm
 883   }
 884   def s   : T2Iso <(outs GPR:$Rt), (ins t2addrmode_so_reg:$addr), iis,
 885                    opc, ".w\t$Rt, $addr",
 886                    [(set GPR:$Rt, (opnode t2addrmode_so_reg:$addr))]> {
 887     let Inst{31-27} = 0b11111;
 888     let Inst{26-25} = 0b00;
 889     let Inst{24} = signed;
 890     let Inst{23} = 0;
 891     let Inst{22-21} = opcod;
 892     let Inst{20} = 1; // load
 893     let Inst{11-6} = 0b000000;
 894
 895     bits<4> Rt;
 896     let Inst{15-12} = Rt;
 897
 898     bits<10> addr;
 899     let Inst{19-16} = addr{9-6}; // Rn
 900     let Inst{3-0}   = addr{5-2}; // Rm
 901     let Inst{5-4}   = addr{1-0}; // imm
 902
 903     let DecoderMethod = "DecodeT2LoadShift";
 904   }
 905
 906   // FIXME: Is the pci variant actually needed?
 907   def pci : T2Ipc <(outs GPR:$Rt), (ins t2ldrlabel:$addr), iii,
 908                    opc, ".w\t$Rt, $addr",
 909                    [(set GPR:$Rt, (opnode (ARMWrapper tconstpool:$addr)))]> {
 910     let isReMaterializable = 1;
 911     let Inst{31-27} = 0b11111;
 912     let Inst{26-25} = 0b00;
 913     let Inst{24} = signed;
 914     let Inst{23} = ?; // add = (U == '1')
 915     let Inst{22-21} = opcod;
 916     let Inst{20} = 1; // load
 917     let Inst{19-16} = 0b1111; // Rn
 918     bits<4> Rt;
 919     bits<12> addr;
 920     let Inst{15-12} = Rt{3-0};
 921     let Inst{11-0}  = addr{11-0};
 922   }
 923 }
 924
 925 /// T2I_st - Defines a set of (op r, {imm12|imm8|so_reg}) store patterns.
 926 multiclass T2I_st<bits<2> opcod, string opc,
 927                   InstrItinClass iii, InstrItinClass iis, PatFrag opnode> {
 928   def i12 : T2Ii12<(outs), (ins GPR:$Rt, t2addrmode_imm12:$addr), iii,
 929                    opc, ".w\t$Rt, $addr",
 930                    [(opnode GPR:$Rt, t2addrmode_imm12:$addr)]> {
 931     let Inst{31-27} = 0b11111;
 932     let Inst{26-23} = 0b0001;
 933     let Inst{22-21} = opcod;
 934     let Inst{20} = 0; // !load
 935
 936     bits<4> Rt;
 937     let Inst{15-12} = Rt;
 938
 939     bits<17> addr;
 940     let addr{12}    = 1;           // add = TRUE
 941     let Inst{19-16} = addr{16-13}; // Rn
 942     let Inst{23}    = addr{12};    // U
 943     let Inst{11-0}  = addr{11-0};  // imm
 944   }
 945   def i8  : T2Ii8 <(outs), (ins GPR:$Rt, t2addrmode_imm8:$addr), iii,
 946                    opc, "\t$Rt, $addr",
 947                    [(opnode GPR:$Rt, t2addrmode_imm8:$addr)]> {
 948     let Inst{31-27} = 0b11111;
 949     let Inst{26-23} = 0b0000;
 950     let Inst{22-21} = opcod;
 951     let Inst{20} = 0; // !load
 952     let Inst{11} = 1;
 953     // Offset: index==TRUE, wback==FALSE
 954     let Inst{10} = 1; // The P bit.
 955     let Inst{8} = 0; // The W bit.
 956
 957     bits<4> Rt;
 958     let Inst{15-12} = Rt;
 959
 960     bits<13> addr;
 961     let Inst{19-16} = addr{12-9}; // Rn
 962     let Inst{9}     = addr{8};    // U
 963     let Inst{7-0}   = addr{7-0};  // imm
 964   }
 965   def s   : T2Iso <(outs), (ins GPR:$Rt, t2addrmode_so_reg:$addr), iis,
 966                    opc, ".w\t$Rt, $addr",
 967                    [(opnode GPR:$Rt, t2addrmode_so_reg:$addr)]> {
 968     let Inst{31-27} = 0b11111;
 969     let Inst{26-23} = 0b0000;
 970     let Inst{22-21} = opcod;
 971     let Inst{20} = 0; // !load
 972     let Inst{11-6} = 0b000000;
 973
 974     bits<4> Rt;
 975     let Inst{15-12} = Rt;
 976
 977     bits<10> addr;
 978     let Inst{19-16}   = addr{9-6}; // Rn
 979     let Inst{3-0} = addr{5-2}; // Rm
 980     let Inst{5-4}   = addr{1-0}; // imm
 981   }
 982 }
 983
 984 /// T2I_ext_rrot - A unary operation with two forms: one whose operand is a
 985 /// register and one whose operand is a register rotated by 8/16/24.
 986 class T2I_ext_rrot<bits<3> opcod, string opc, PatFrag opnode>
 987   : T2TwoReg<(outs rGPR:$Rd), (ins rGPR:$Rm, rot_imm:$rot), IIC_iEXTr,
 988              opc, ".w\t$Rd, $Rm$rot",
 989              [(set rGPR:$Rd, (opnode (rotr rGPR:$Rm, rot_imm:$rot)))]>,
 990              Requires<[IsThumb2]> {
 991    let Inst{31-27} = 0b11111;
 992    let Inst{26-23} = 0b0100;
 993    let Inst{22-20} = opcod;
 994    let Inst{19-16} = 0b1111; // Rn
 995    let Inst{15-12} = 0b1111;
 996    let Inst{7} = 1;
 997
 998    bits<2> rot;
 999    let Inst{5-4} = rot{1-0}; // rotate
1000 }
1001
1002 // UXTB16 - Requres T2ExtractPack, does not need the .w qualifier.
1003 class T2I_ext_rrot_uxtb16<bits<3> opcod, string opc, PatFrag opnode>
1004   : T2TwoReg<(outs rGPR:$dst), (ins rGPR:$Rm, rot_imm:$rot),
1005              IIC_iEXTr, opc, "\t$dst, $Rm$rot",
1006             [(set rGPR:$dst, (opnode (rotr rGPR:$Rm, rot_imm:$rot)))]>,
1007           Requires<[HasT2ExtractPack, IsThumb2]> {
1008   bits<2> rot;
1009   let Inst{31-27} = 0b11111;
1010   let Inst{26-23} = 0b0100;
1011   let Inst{22-20} = opcod;
1012   let Inst{19-16} = 0b1111; // Rn
1013   let Inst{15-12} = 0b1111;
1014   let Inst{7} = 1;
1015   let Inst{5-4} = rot;
1016 }
1017
1018 // SXTB16 - Requres T2ExtractPack, does not need the .w qualifier, no pattern
1019 // supported yet.
1020 class T2I_ext_rrot_sxtb16<bits<3> opcod, string opc>
1021   : T2TwoReg<(outs rGPR:$Rd), (ins rGPR:$Rm, rot_imm:$rot), IIC_iEXTr,
1022              opc, "\t$Rd, $Rm$rot", []>,
1023           Requires<[IsThumb2, HasT2ExtractPack]> {
1024   bits<2> rot;
1025   let Inst{31-27} = 0b11111;
1026   let Inst{26-23} = 0b0100;
1027   let Inst{22-20} = opcod;
1028   let Inst{19-16} = 0b1111; // Rn
1029   let Inst{15-12} = 0b1111;
1030   let Inst{7} = 1;
1031   let Inst{5-4} = rot;
1032 }
1033
1034 /// T2I_exta_rrot - A binary operation with two forms: one whose operand is a
1035 /// register and one whose operand is a register rotated by 8/16/24.
1036 class T2I_exta_rrot<bits<3> opcod, string opc, PatFrag opnode>
1037   : T2ThreeReg<(outs rGPR:$Rd),
1038                (ins rGPR:$Rn, rGPR:$Rm, rot_imm:$rot),
1039                IIC_iEXTAsr, opc, "\t$Rd, $Rn, $Rm$rot",
1040              [(set rGPR:$Rd, (opnode rGPR:$Rn, (rotr rGPR:$Rm,rot_imm:$rot)))]>,
1041            Requires<[HasT2ExtractPack, IsThumb2]> {
1042   bits<2> rot;
1043   let Inst{31-27} = 0b11111;
1044   let Inst{26-23} = 0b0100;
1045   let Inst{22-20} = opcod;
1046   let Inst{15-12} = 0b1111;
1047   let Inst{7} = 1;
1048   let Inst{5-4} = rot;
1049 }
1050
1051 class T2I_exta_rrot_np<bits<3> opcod, string opc>
1052   : T2ThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm,rot_imm:$rot),
1053                IIC_iEXTAsr, opc, "\t$Rd, $Rn, $Rm$rot", []> {
1054   bits<2> rot;
1055   let Inst{31-27} = 0b11111;
1056   let Inst{26-23} = 0b0100;
1057   let Inst{22-20} = opcod;
1058   let Inst{15-12} = 0b1111;
1059   let Inst{7} = 1;
1060   let Inst{5-4} = rot;
1061 }
1062
1063 //===----------------------------------------------------------------------===//
1064 // Instructions
1065 //===----------------------------------------------------------------------===//
1066
1067 //===----------------------------------------------------------------------===//
1068 //  Miscellaneous Instructions.
1069 //
1070
1071 class T2PCOneRegImm<dag oops, dag iops, InstrItinClass itin,
1072            string asm, list<dag> pattern>
1073   : T2XI<oops, iops, itin, asm, pattern> {
1074   bits<4> Rd;
1075   bits<12> label;
1076
1077   let Inst{11-8}  = Rd;
1078   let Inst{26}    = label{11};
1079   let Inst{14-12} = label{10-8};
1080   let Inst{7-0}   = label{7-0};
1081 }
1082
1083 // LEApcrel - Load a pc-relative address into a register without offending the
1084 // assembler.
1085 def t2ADR : T2PCOneRegImm<(outs rGPR:$Rd),
1086               (ins t2adrlabel:$addr, pred:$p),
1087               IIC_iALUi, "adr{$p}.w\t$Rd, #$addr", []> {
1088   let Inst{31-27} = 0b11110;
1089   let Inst{25-24} = 0b10;
1090   // Inst{23:21} = '11' (add = FALSE) or '00' (add = TRUE)
1091   let Inst{22} = 0;
1092   let Inst{20} = 0;
1093   let Inst{19-16} = 0b1111; // Rn
1094   let Inst{15} = 0;
1095
1096   bits<4> Rd;
1097   bits<13> addr;
1098   let Inst{11-8} = Rd;
1099   let Inst{23}    = addr{12};
1100   let Inst{21}    = addr{12};
1101   let Inst{26}    = addr{11};
1102   let Inst{14-12} = addr{10-8};
1103   let Inst{7-0}   = addr{7-0};
1104 }
1105
1106 let neverHasSideEffects = 1, isReMaterializable = 1 in
1107 def t2LEApcrel   : t2PseudoInst<(outs rGPR:$Rd), (ins i32imm:$label, pred:$p),
1108                                 4, IIC_iALUi, []>;
1109 def t2LEApcrelJT : t2PseudoInst<(outs rGPR:$Rd),
1110                                 (ins i32imm:$label, nohash_imm:$id, pred:$p),
1111                                 4, IIC_iALUi,
1112                                 []>;
1113
1114
1115 //===----------------------------------------------------------------------===//
1116 //  Load / store Instructions.
1117 //
1118
1119 // Load
1120 let canFoldAsLoad = 1, isReMaterializable = 1  in
1121 defm t2LDR   : T2I_ld<0, 0b10, "ldr", IIC_iLoad_i, IIC_iLoad_si,
1122                       UnOpFrag<(load node:$Src)>>;
1123
1124 // Loads with zero extension
1125 defm t2LDRH  : T2I_ld<0, 0b01, "ldrh", IIC_iLoad_bh_i, IIC_iLoad_bh_si,
1126                       UnOpFrag<(zextloadi16 node:$Src)>>;
1127 defm t2LDRB  : T2I_ld<0, 0b00, "ldrb", IIC_iLoad_bh_i, IIC_iLoad_bh_si,
1128                       UnOpFrag<(zextloadi8  node:$Src)>>;
1129
1130 // Loads with sign extension
1131 defm t2LDRSH : T2I_ld<1, 0b01, "ldrsh", IIC_iLoad_bh_i, IIC_iLoad_bh_si,
1132                       UnOpFrag<(sextloadi16 node:$Src)>>;
1133 defm t2LDRSB : T2I_ld<1, 0b00, "ldrsb", IIC_iLoad_bh_i, IIC_iLoad_bh_si,
1134                       UnOpFrag<(sextloadi8  node:$Src)>>;
1135
1136 let mayLoad = 1, neverHasSideEffects = 1, hasExtraDefRegAllocReq = 1 in {
1137 // Load doubleword
1138 def t2LDRDi8  : T2Ii8s4<1, 0, 1, (outs rGPR:$Rt, rGPR:$Rt2),
1139                         (ins t2addrmode_imm8s4:$addr),
1140                         IIC_iLoad_d_i, "ldrd", "\t$Rt, $Rt2, $addr", []>;
1141 } // mayLoad = 1, neverHasSideEffects = 1, hasExtraDefRegAllocReq = 1
1142
1143 // zextload i1 -> zextload i8
1144 def : T2Pat<(zextloadi1 t2addrmode_imm12:$addr),
1145             (t2LDRBi12  t2addrmode_imm12:$addr)>;
1146 def : T2Pat<(zextloadi1 t2addrmode_imm8:$addr),
1147             (t2LDRBi8   t2addrmode_imm8:$addr)>;
1148 def : T2Pat<(zextloadi1 t2addrmode_so_reg:$addr),
1149             (t2LDRBs    t2addrmode_so_reg:$addr)>;
1150 def : T2Pat<(zextloadi1 (ARMWrapper tconstpool:$addr)),
1151             (t2LDRBpci  tconstpool:$addr)>;
1152
1153 // extload -> zextload
1154 // FIXME: Reduce the number of patterns by legalizing extload to zextload
1155 // earlier?
1156 def : T2Pat<(extloadi1  t2addrmode_imm12:$addr),
1157             (t2LDRBi12  t2addrmode_imm12:$addr)>;
1158 def : T2Pat<(extloadi1  t2addrmode_imm8:$addr),
1159             (t2LDRBi8   t2addrmode_imm8:$addr)>;
1160 def : T2Pat<(extloadi1  t2addrmode_so_reg:$addr),
1161             (t2LDRBs    t2addrmode_so_reg:$addr)>;
1162 def : T2Pat<(extloadi1  (ARMWrapper tconstpool:$addr)),
1163             (t2LDRBpci  tconstpool:$addr)>;
1164
1165 def : T2Pat<(extloadi8  t2addrmode_imm12:$addr),
1166             (t2LDRBi12  t2addrmode_imm12:$addr)>;
1167 def : T2Pat<(extloadi8  t2addrmode_imm8:$addr),
1168             (t2LDRBi8   t2addrmode_imm8:$addr)>;
1169 def : T2Pat<(extloadi8  t2addrmode_so_reg:$addr),
1170             (t2LDRBs    t2addrmode_so_reg:$addr)>;
1171 def : T2Pat<(extloadi8  (ARMWrapper tconstpool:$addr)),
1172             (t2LDRBpci  tconstpool:$addr)>;
1173
1174 def : T2Pat<(extloadi16 t2addrmode_imm12:$addr),
1175             (t2LDRHi12  t2addrmode_imm12:$addr)>;
1176 def : T2Pat<(extloadi16 t2addrmode_imm8:$addr),
1177             (t2LDRHi8   t2addrmode_imm8:$addr)>;
1178 def : T2Pat<(extloadi16 t2addrmode_so_reg:$addr),
1179             (t2LDRHs    t2addrmode_so_reg:$addr)>;
1180 def : T2Pat<(extloadi16 (ARMWrapper tconstpool:$addr)),
1181             (t2LDRHpci  tconstpool:$addr)>;
1182
1183 // FIXME: The destination register of the loads and stores can't be PC, but
1184 //        can be SP. We need another regclass (similar to rGPR) to represent
1185 //        that. Not a pressing issue since these are selected manually,
1186 //        not via pattern.
1187
1188 // Indexed loads
1189
1190 let mayLoad = 1, neverHasSideEffects = 1 in {
1191 def t2LDR_PRE  : T2Iidxldst<0, 0b10, 1, 1, (outs GPR:$Rt, GPR:$Rn),
1192                             (ins t2addrmode_imm8:$addr),
1193                             AddrModeT2_i8, IndexModePre, IIC_iLoad_iu,
1194                             "ldr", "\t$Rt, $addr!", "$addr.base = $Rn",
1195                             []>;
1196
1197 def t2LDR_POST : T2Iidxldst<0, 0b10, 1, 0, (outs GPR:$Rt, GPR:$Rn),
1198                             (ins GPR:$base, t2am_imm8_offset:$addr),
1199                             AddrModeT2_i8, IndexModePost, IIC_iLoad_iu,
1200                           "ldr", "\t$Rt, [$Rn], $addr", "$base = $Rn",
1201                             []>;
1202
1203 def t2LDRB_PRE : T2Iidxldst<0, 0b00, 1, 1, (outs GPR:$Rt, GPR:$Rn),
1204                             (ins t2addrmode_imm8:$addr),
1205                             AddrModeT2_i8, IndexModePre, IIC_iLoad_bh_iu,
1206                             "ldrb", "\t$Rt, $addr!", "$addr.base = $Rn",
1207                             []>;
1208 def t2LDRB_POST : T2Iidxldst<0, 0b00, 1, 0, (outs GPR:$Rt, GPR:$Rn),
1209                             (ins GPR:$base, t2am_imm8_offset:$addr),
1210                             AddrModeT2_i8, IndexModePost, IIC_iLoad_bh_iu,
1211                          "ldrb", "\t$Rt, [$Rn], $addr", "$base = $Rn",
1212                             []>;
1213
1214 def t2LDRH_PRE : T2Iidxldst<0, 0b01, 1, 1, (outs GPR:$Rt, GPR:$Rn),
1215                             (ins t2addrmode_imm8:$addr),
1216                             AddrModeT2_i8, IndexModePre, IIC_iLoad_bh_iu,
1217                             "ldrh", "\t$Rt, $addr!", "$addr.base = $Rn",
1218                             []>;
1219 def t2LDRH_POST : T2Iidxldst<0, 0b01, 1, 0, (outs GPR:$Rt, GPR:$Rn),
1220                             (ins GPR:$base, t2am_imm8_offset:$addr),
1221                             AddrModeT2_i8, IndexModePost, IIC_iLoad_bh_iu,
1222                          "ldrh", "\t$Rt, [$Rn], $addr", "$base = $Rn",
1223                             []>;
1224
1225 def t2LDRSB_PRE : T2Iidxldst<1, 0b00, 1, 1, (outs GPR:$Rt, GPR:$Rn),
1226                             (ins t2addrmode_imm8:$addr),
1227                             AddrModeT2_i8, IndexModePre, IIC_iLoad_bh_iu,
1228                             "ldrsb", "\t$Rt, $addr!", "$addr.base = $Rn",
1229                             []>;
1230 def t2LDRSB_POST : T2Iidxldst<1, 0b00, 1, 0, (outs GPR:$Rt, GPR:$Rn),
1231                             (ins GPR:$base, t2am_imm8_offset:$addr),
1232                             AddrModeT2_i8, IndexModePost, IIC_iLoad_bh_iu,
1233                         "ldrsb", "\t$Rt, [$Rn], $addr", "$base = $Rn",
1234                             []>;
1235
1236 def t2LDRSH_PRE : T2Iidxldst<1, 0b01, 1, 1, (outs GPR:$Rt, GPR:$Rn),
1237                             (ins t2addrmode_imm8:$addr),
1238                             AddrModeT2_i8, IndexModePre, IIC_iLoad_bh_iu,
1239                             "ldrsh", "\t$Rt, $addr!", "$addr.base = $Rn",
1240                             []>;
1241 def t2LDRSH_POST : T2Iidxldst<1, 0b01, 1, 0, (outs GPR:$dst, GPR:$Rn),
1242                             (ins GPR:$base, t2am_imm8_offset:$addr),
1243                             AddrModeT2_i8, IndexModePost, IIC_iLoad_bh_iu,
1244                         "ldrsh", "\t$dst, [$Rn], $addr", "$base = $Rn",
1245                             []>;
1246 } // mayLoad = 1, neverHasSideEffects = 1
1247
1248 // LDRT, LDRBT, LDRHT, LDRSBT, LDRSHT all have offset mode (PUW=0b110) and are
1249 // for disassembly only.
1250 // Ref: A8.6.57 LDR (immediate, Thumb) Encoding T4
1251 class T2IldT<bit signed, bits<2> type, string opc, InstrItinClass ii>
1252   : T2Ii8<(outs rGPR:$Rt), (ins t2addrmode_imm8:$addr), ii, opc,
1253           "\t$Rt, $addr", []> {
1254   let Inst{31-27} = 0b11111;
1255   let Inst{26-25} = 0b00;
1256   let Inst{24} = signed;
1257   let Inst{23} = 0;
1258   let Inst{22-21} = type;
1259   let Inst{20} = 1; // load
1260   let Inst{11} = 1;
1261   let Inst{10-8} = 0b110; // PUW.
1262
1263   bits<4> Rt;
1264   bits<13> addr;
1265   let Inst{15-12} = Rt;
1266   let Inst{19-16} = addr{12-9};
1267   let Inst{7-0}   = addr{7-0};
1268 }
1269
1270 def t2LDRT   : T2IldT<0, 0b10, "ldrt", IIC_iLoad_i>;
1271 def t2LDRBT  : T2IldT<0, 0b00, "ldrbt", IIC_iLoad_bh_i>;
1272 def t2LDRHT  : T2IldT<0, 0b01, "ldrht", IIC_iLoad_bh_i>;
1273 def t2LDRSBT : T2IldT<1, 0b00, "ldrsbt", IIC_iLoad_bh_i>;
1274 def t2LDRSHT : T2IldT<1, 0b01, "ldrsht", IIC_iLoad_bh_i>;
1275
1276 // Store
1277 defm t2STR :T2I_st<0b10,"str", IIC_iStore_i, IIC_iStore_si,
1278                    BinOpFrag<(store node:$LHS, node:$RHS)>>;
1279 defm t2STRB:T2I_st<0b00,"strb", IIC_iStore_bh_i, IIC_iStore_bh_si,
1280                    BinOpFrag<(truncstorei8 node:$LHS, node:$RHS)>>;
1281 defm t2STRH:T2I_st<0b01,"strh", IIC_iStore_bh_i, IIC_iStore_bh_si,
1282                    BinOpFrag<(truncstorei16 node:$LHS, node:$RHS)>>;
1283
1284 // Store doubleword
1285 let mayLoad = 1, neverHasSideEffects = 1, hasExtraSrcRegAllocReq = 1 in
1286 def t2STRDi8 : T2Ii8s4<1, 0, 0, (outs),
1287                        (ins GPR:$Rt, GPR:$Rt2, t2addrmode_imm8s4:$addr),
1288                IIC_iStore_d_r, "strd", "\t$Rt, $Rt2, $addr", []>;
1289
1290 // Indexed stores
1291 def t2STR_PRE  : T2Iidxldst<0, 0b10, 0, 1, (outs GPR:$base_wb),
1292                             (ins GPR:$Rt, GPR:$Rn, t2am_imm8_offset:$addr),
1293                             AddrModeT2_i8, IndexModePre, IIC_iStore_iu,
1294                          "str", "\t$Rt, [$Rn, $addr]!",
1295                          "$Rn = $base_wb,@earlyclobber $base_wb",
1296              [(set GPR:$base_wb,
1297                    (pre_store GPR:$Rt, GPR:$Rn, t2am_imm8_offset:$addr))]>;
1298
1299 def t2STR_POST : T2Iidxldst<0, 0b10, 0, 0, (outs GPR:$base_wb),
1300                             (ins GPR:$Rt, GPR:$Rn, t2am_imm8_offset:$addr),
1301                             AddrModeT2_i8, IndexModePost, IIC_iStore_iu,
1302                           "str", "\t$Rt, [$Rn], $addr",
1303                           "$Rn = $base_wb,@earlyclobber $base_wb",
1304              [(set GPR:$base_wb,
1305                   (post_store GPR:$Rt, GPR:$Rn, t2am_imm8_offset:$addr))]>;
1306
1307 def t2STRH_PRE  : T2Iidxldst<0, 0b01, 0, 1, (outs GPR:$base_wb),
1308                             (ins GPR:$Rt, GPR:$Rn, t2am_imm8_offset:$addr),
1309                             AddrModeT2_i8, IndexModePre, IIC_iStore_iu,
1310                         "strh", "\t$Rt, [$Rn, $addr]!",
1311                         "$Rn = $base_wb,@earlyclobber $base_wb",
1312         [(set GPR:$base_wb,
1313               (pre_truncsti16 GPR:$Rt, GPR:$Rn, t2am_imm8_offset:$addr))]>;
1314
1315 def t2STRH_POST : T2Iidxldst<0, 0b01, 0, 0, (outs GPR:$base_wb),
1316                             (ins GPR:$Rt, GPR:$Rn, t2am_imm8_offset:$addr),
1317                             AddrModeT2_i8, IndexModePost, IIC_iStore_bh_iu,
1318                          "strh", "\t$Rt, [$Rn], $addr",
1319                          "$Rn = $base_wb,@earlyclobber $base_wb",
1320        [(set GPR:$base_wb,
1321              (post_truncsti16 GPR:$Rt, GPR:$Rn, t2am_imm8_offset:$addr))]>;
1322
1323 def t2STRB_PRE  : T2Iidxldst<0, 0b00, 0, 1, (outs GPR:$base_wb),
1324                             (ins GPR:$Rt, GPR:$Rn, t2am_imm8_offset:$addr),
1325                             AddrModeT2_i8, IndexModePre, IIC_iStore_bh_iu,
1326                         "strb", "\t$Rt, [$Rn, $addr]!",
1327                         "$Rn = $base_wb,@earlyclobber $base_wb",
1328          [(set GPR:$base_wb,
1329                (pre_truncsti8 GPR:$Rt, GPR:$Rn, t2am_imm8_offset:$addr))]>;
1330
1331 def t2STRB_POST : T2Iidxldst<0, 0b00, 0, 0, (outs GPR:$base_wb),
1332                             (ins GPR:$Rt, GPR:$Rn, t2am_imm8_offset:$addr),
1333                             AddrModeT2_i8, IndexModePost, IIC_iStore_bh_iu,
1334                          "strb", "\t$Rt, [$Rn], $addr",
1335                          "$Rn = $base_wb,@earlyclobber $base_wb",
1336         [(set GPR:$base_wb,
1337               (post_truncsti8 GPR:$Rt, GPR:$Rn, t2am_imm8_offset:$addr))]>;
1338
1339 // STRT, STRBT, STRHT all have offset mode (PUW=0b110) and are for disassembly
1340 // only.
1341 // Ref: A8.6.193 STR (immediate, Thumb) Encoding T4
1342 class T2IstT<bits<2> type, string opc, InstrItinClass ii>
1343   : T2Ii8<(outs rGPR:$Rt), (ins t2addrmode_imm8:$addr), ii, opc,
1344           "\t$Rt, $addr", []> {
1345   let Inst{31-27} = 0b11111;
1346   let Inst{26-25} = 0b00;
1347   let Inst{24} = 0; // not signed
1348   let Inst{23} = 0;
1349   let Inst{22-21} = type;
1350   let Inst{20} = 0; // store
1351   let Inst{11} = 1;
1352   let Inst{10-8} = 0b110; // PUW
1353
1354   bits<4> Rt;
1355   bits<13> addr;
1356   let Inst{15-12} = Rt;
1357   let Inst{19-16} = addr{12-9};
1358   let Inst{7-0}   = addr{7-0};
1359 }
1360
1361 def t2STRT   : T2IstT<0b10, "strt", IIC_iStore_i>;
1362 def t2STRBT  : T2IstT<0b00, "strbt", IIC_iStore_bh_i>;
1363 def t2STRHT  : T2IstT<0b01, "strht", IIC_iStore_bh_i>;
1364
1365 // ldrd / strd pre / post variants
1366 // For disassembly only.
1367
1368 def t2LDRD_PRE  : T2Ii8s4Tied<1, 1, 1,
1369                  (outs rGPR:$Rt, rGPR:$Rt2, GPR:$wb),
1370                  (ins GPR:$base, t2am_imm8s4_offset:$imm), IIC_iLoad_d_ru,
1371                  "ldrd", "\t$Rt, $Rt2, [$base, $imm]!", []>;
1372
1373 def t2LDRD_POST : T2Ii8s4Tied<0, 1, 1,
1374                  (outs rGPR:$Rt, rGPR:$Rt2, GPR:$wb),
1375                  (ins GPR:$base, t2am_imm8s4_offset:$imm), IIC_iLoad_d_ru,
1376                  "ldrd", "\t$Rt, $Rt2, [$base], $imm", []>;
1377
1378 def t2STRD_PRE  : T2Ii8s4Tied<1, 1, 0, (outs GPR:$wb),
1379                  (ins rGPR:$Rt, rGPR:$Rt2, GPR:$base, t2am_imm8s4_offset:$imm),
1380                  IIC_iStore_d_ru, "strd", "\t$Rt, $Rt2, [$base, $imm]!", []>;
1381
1382 def t2STRD_POST : T2Ii8s4Tied<0, 1, 0, (outs GPR:$wb),
1383                  (ins rGPR:$Rt, rGPR:$Rt2, GPR:$base, t2am_imm8s4_offset:$imm),
1384                  IIC_iStore_d_ru, "strd", "\t$Rt, $Rt2, [$base], $imm", []>;
1385
1386 // T2Ipl (Preload Data/Instruction) signals the memory system of possible future
1387 // data/instruction access.  These are for disassembly only.
1388 // instr_write is inverted for Thumb mode: (prefetch 3) -> (preload 0),
1389 // (prefetch 1) -> (preload 2),  (prefetch 2) -> (preload 1).
1390 multiclass T2Ipl<bits<1> write, bits<1> instr, string opc> {
1391
1392   def i12 : T2Ii12<(outs), (ins t2addrmode_imm12:$addr), IIC_Preload, opc,
1393                 "\t$addr",
1394               [(ARMPreload t2addrmode_imm12:$addr, (i32 write), (i32 instr))]> {
1395     let Inst{31-25} = 0b1111100;
1396     let Inst{24} = instr;
1397     let Inst{22} = 0;
1398     let Inst{21} = write;
1399     let Inst{20} = 1;
1400     let Inst{15-12} = 0b1111;
1401
1402     bits<17> addr;
1403     let addr{12}    = 1;           // add = TRUE
1404     let Inst{19-16} = addr{16-13}; // Rn
1405     let Inst{23}    = addr{12};    // U
1406     let Inst{11-0}  = addr{11-0};  // imm12
1407   }
1408
1409   def i8 : T2Ii8<(outs), (ins t2addrmode_imm8:$addr), IIC_Preload, opc,
1410                 "\t$addr",
1411                [(ARMPreload t2addrmode_imm8:$addr, (i32 write), (i32 instr))]> {
1412     let Inst{31-25} = 0b1111100;
1413     let Inst{24} = instr;
1414     let Inst{23} = 0; // U = 0
1415     let Inst{22} = 0;
1416     let Inst{21} = write;
1417     let Inst{20} = 1;
1418     let Inst{15-12} = 0b1111;
1419     let Inst{11-8} = 0b1100;
1420
1421     bits<13> addr;
1422     let Inst{19-16} = addr{12-9}; // Rn
1423     let Inst{7-0}   = addr{7-0};  // imm8
1424   }
1425
1426   def s : T2Iso<(outs), (ins t2addrmode_so_reg:$addr), IIC_Preload, opc,
1427                "\t$addr",
1428              [(ARMPreload t2addrmode_so_reg:$addr, (i32 write), (i32 instr))]> {
1429     let Inst{31-25} = 0b1111100;
1430     let Inst{24} = instr;
1431     let Inst{23} = 0; // add = TRUE for T1
1432     let Inst{22} = 0;
1433     let Inst{21} = write;
1434     let Inst{20} = 1;
1435     let Inst{15-12} = 0b1111;
1436     let Inst{11-6} = 0000000;
1437
1438     bits<10> addr;
1439     let Inst{19-16} = addr{9-6}; // Rn
1440     let Inst{3-0}   = addr{5-2}; // Rm
1441     let Inst{5-4}   = addr{1-0}; // imm2
1442
1443     let DecoderMethod = "DecodeT2LoadShift";
1444   }
1445 }
1446
1447 defm t2PLD  : T2Ipl<0, 0, "pld">,  Requires<[IsThumb2]>;
1448 defm t2PLDW : T2Ipl<1, 0, "pldw">, Requires<[IsThumb2,HasV7,HasMP]>;
1449 defm t2PLI  : T2Ipl<0, 1, "pli">,  Requires<[IsThumb2,HasV7]>;
1450
1451 //===----------------------------------------------------------------------===//
1452 //  Load / store multiple Instructions.
1453 //
1454
1455 multiclass thumb2_ldst_mult<string asm, InstrItinClass itin,
1456                             InstrItinClass itin_upd, bit L_bit> {
1457   def IA :
1458     T2XI<(outs), (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops),
1459          itin, !strconcat(asm, "ia${p}.w\t$Rn, $regs"), []> {
1460     bits<4>  Rn;
1461     bits<16> regs;
1462
1463     let Inst{31-27} = 0b11101;
1464     let Inst{26-25} = 0b00;
1465     let Inst{24-23} = 0b01;     // Increment After
1466     let Inst{22}    = 0;
1467     let Inst{21}    = 0;        // No writeback
1468     let Inst{20}    = L_bit;
1469     let Inst{19-16} = Rn;
1470     let Inst{15-0}  = regs;
1471   }
1472   def IA_UPD :
1473     T2XIt<(outs GPR:$wb), (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops),
1474           itin_upd, !strconcat(asm, "ia${p}.w\t$Rn!, $regs"), "$Rn = $wb", []> {
1475     bits<4>  Rn;
1476     bits<16> regs;
1477
1478     let Inst{31-27} = 0b11101;
1479     let Inst{26-25} = 0b00;
1480     let Inst{24-23} = 0b01;     // Increment After
1481     let Inst{22}    = 0;
1482     let Inst{21}    = 1;        // Writeback
1483     let Inst{20}    = L_bit;
1484     let Inst{19-16} = Rn;
1485     let Inst{15-0}  = regs;
1486   }
1487   def DB :
1488     T2XI<(outs), (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops),
1489          itin, !strconcat(asm, "db${p}.w\t$Rn, $regs"), []> {
1490     bits<4>  Rn;
1491     bits<16> regs;
1492
1493     let Inst{31-27} = 0b11101;
1494     let Inst{26-25} = 0b00;
1495     let Inst{24-23} = 0b10;     // Decrement Before
1496     let Inst{22}    = 0;
1497     let Inst{21}    = 0;        // No writeback
1498     let Inst{20}    = L_bit;
1499     let Inst{19-16} = Rn;
1500     let Inst{15-0}  = regs;
1501   }
1502   def DB_UPD :
1503     T2XIt<(outs GPR:$wb), (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops),
1504           itin_upd, !strconcat(asm, "db${p}.w\t$Rn, $regs"), "$Rn = $wb", []> {
1505     bits<4>  Rn;
1506     bits<16> regs;
1507
1508     let Inst{31-27} = 0b11101;
1509     let Inst{26-25} = 0b00;
1510     let Inst{24-23} = 0b10;     // Decrement Before
1511     let Inst{22}    = 0;
1512     let Inst{21}    = 1;        // Writeback
1513     let Inst{20}    = L_bit;
1514     let Inst{19-16} = Rn;
1515     let Inst{15-0}  = regs;
1516   }
1517 }
1518
1519 let neverHasSideEffects = 1 in {
1520
1521 let mayLoad = 1, hasExtraDefRegAllocReq = 1 in
1522 defm t2LDM : thumb2_ldst_mult<"ldm", IIC_iLoad_m, IIC_iLoad_mu, 1>;
1523
1524 let mayStore = 1, hasExtraSrcRegAllocReq = 1 in
1525 defm t2STM : thumb2_ldst_mult<"stm", IIC_iStore_m, IIC_iStore_mu, 0>;
1526
1527 } // neverHasSideEffects
1528
1529
1530 //===----------------------------------------------------------------------===//
1531 //  Move Instructions.
1532 //
1533
1534 let neverHasSideEffects = 1 in
1535 def t2MOVr : T2sTwoReg<(outs GPR:$Rd), (ins GPR:$Rm), IIC_iMOVr,
1536                    "mov", ".w\t$Rd, $Rm", []> {
1537   let Inst{31-27} = 0b11101;
1538   let Inst{26-25} = 0b01;
1539   let Inst{24-21} = 0b0010;
1540   let Inst{19-16} = 0b1111; // Rn
1541   let Inst{14-12} = 0b000;
1542   let Inst{7-4} = 0b0000;
1543 }
1544
1545 // AddedComplexity to ensure isel tries t2MOVi before t2MOVi16.
1546 let isReMaterializable = 1, isAsCheapAsAMove = 1, isMoveImm = 1,
1547     AddedComplexity = 1 in
1548 def t2MOVi : T2sOneRegImm<(outs rGPR:$Rd), (ins t2_so_imm:$imm), IIC_iMOVi,
1549                    "mov", ".w\t$Rd, $imm",
1550                    [(set rGPR:$Rd, t2_so_imm:$imm)]> {
1551   let Inst{31-27} = 0b11110;
1552   let Inst{25} = 0;
1553   let Inst{24-21} = 0b0010;
1554   let Inst{19-16} = 0b1111; // Rn
1555   let Inst{15} = 0;
1556 }
1557
1558 def : InstAlias<"mov${s}${p} $Rd, $imm", (t2MOVi rGPR:$Rd, t2_so_imm:$imm,
1559                                                  pred:$p, cc_out:$s)>,
1560                 Requires<[IsThumb2]>;
1561
1562 let isReMaterializable = 1, isAsCheapAsAMove = 1, isMoveImm = 1 in
1563 def t2MOVi16 : T2I<(outs rGPR:$Rd), (ins imm0_65535_expr:$imm), IIC_iMOVi,
1564                    "movw", "\t$Rd, $imm",
1565                    [(set rGPR:$Rd, imm0_65535:$imm)]> {
1566   let Inst{31-27} = 0b11110;
1567   let Inst{25} = 1;
1568   let Inst{24-21} = 0b0010;
1569   let Inst{20} = 0; // The S bit.
1570   let Inst{15} = 0;
1571
1572   bits<4> Rd;
1573   bits<16> imm;
1574
1575   let Inst{11-8}  = Rd;
1576   let Inst{19-16} = imm{15-12};
1577   let Inst{26}    = imm{11};
1578   let Inst{14-12} = imm{10-8};
1579   let Inst{7-0}   = imm{7-0};
1580 }
1581
1582 def t2MOVi16_ga_pcrel : PseudoInst<(outs rGPR:$Rd),
1583                                 (ins i32imm:$addr, pclabel:$id), IIC_iMOVi, []>;
1584
1585 let Constraints = "$src = $Rd" in {
1586 def t2MOVTi16 : T2I<(outs rGPR:$Rd),
1587                     (ins rGPR:$src, imm0_65535_expr:$imm), IIC_iMOVi,
1588                     "movt", "\t$Rd, $imm",
1589                     [(set rGPR:$Rd,
1590                           (or (and rGPR:$src, 0xffff), lo16AllZero:$imm))]> {
1591   let Inst{31-27} = 0b11110;
1592   let Inst{25} = 1;
1593   let Inst{24-21} = 0b0110;
1594   let Inst{20} = 0; // The S bit.
1595   let Inst{15} = 0;
1596
1597   bits<4> Rd;
1598   bits<16> imm;
1599
1600   let Inst{11-8}  = Rd;
1601   let Inst{19-16} = imm{15-12};
1602   let Inst{26}    = imm{11};
1603   let Inst{14-12} = imm{10-8};
1604   let Inst{7-0}   = imm{7-0};
1605 }
1606
1607 def t2MOVTi16_ga_pcrel : PseudoInst<(outs rGPR:$Rd),
1608                      (ins rGPR:$src, i32imm:$addr, pclabel:$id), IIC_iMOVi, []>;
1609 } // Constraints
1610
1611 def : T2Pat<(or rGPR:$src, 0xffff0000), (t2MOVTi16 rGPR:$src, 0xffff)>;
1612
1613 //===----------------------------------------------------------------------===//
1614 //  Extend Instructions.
1615 //
1616
1617 // Sign extenders
1618
1619 def t2SXTB  : T2I_ext_rrot<0b100, "sxtb",
1620                               UnOpFrag<(sext_inreg node:$Src, i8)>>;
1621 def t2SXTH  : T2I_ext_rrot<0b000, "sxth",
1622                               UnOpFrag<(sext_inreg node:$Src, i16)>>;
1623 def t2SXTB16 : T2I_ext_rrot_sxtb16<0b010, "sxtb16">;
1624
1625 def t2SXTAB : T2I_exta_rrot<0b100, "sxtab",
1626                         BinOpFrag<(add node:$LHS, (sext_inreg node:$RHS, i8))>>;
1627 def t2SXTAH : T2I_exta_rrot<0b000, "sxtah",
1628                         BinOpFrag<(add node:$LHS, (sext_inreg node:$RHS,i16))>>;
1629 def t2SXTAB16 : T2I_exta_rrot_np<0b010, "sxtab16">;
1630
1631 // TODO: SXT(A){B|H}16
1632
1633 // Zero extenders
1634
1635 let AddedComplexity = 16 in {
1636 def t2UXTB   : T2I_ext_rrot<0b101, "uxtb",
1637                                UnOpFrag<(and node:$Src, 0x000000FF)>>;
1638 def t2UXTH   : T2I_ext_rrot<0b001, "uxth",
1639                                UnOpFrag<(and node:$Src, 0x0000FFFF)>>;
1640 def t2UXTB16 : T2I_ext_rrot_uxtb16<0b011, "uxtb16",
1641                                UnOpFrag<(and node:$Src, 0x00FF00FF)>>;
1642
1643 // FIXME: This pattern incorrectly assumes the shl operator is a rotate.
1644 //        The transformation should probably be done as a combiner action
1645 //        instead so we can include a check for masking back in the upper
1646 //        eight bits of the source into the lower eight bits of the result.
1647 //def : T2Pat<(and (shl rGPR:$Src, (i32 8)), 0xFF00FF),
1648 //            (t2UXTB16 rGPR:$Src, 3)>,
1649 //          Requires<[HasT2ExtractPack, IsThumb2]>;
1650 def : T2Pat<(and (srl rGPR:$Src, (i32 8)), 0xFF00FF),
1651             (t2UXTB16 rGPR:$Src, 1)>,
1652         Requires<[HasT2ExtractPack, IsThumb2]>;
1653
1654 def t2UXTAB : T2I_exta_rrot<0b101, "uxtab",
1655                            BinOpFrag<(add node:$LHS, (and node:$RHS, 0x00FF))>>;
1656 def t2UXTAH : T2I_exta_rrot<0b001, "uxtah",
1657                            BinOpFrag<(add node:$LHS, (and node:$RHS, 0xFFFF))>>;
1658 def t2UXTAB16 : T2I_exta_rrot_np<0b011, "uxtab16">;
1659 }
1660
1661 //===----------------------------------------------------------------------===//
1662 //  Arithmetic Instructions.
1663 //
1664
1665 defm t2ADD  : T2I_bin_ii12rs<0b000, "add",
1666                              BinOpFrag<(add  node:$LHS, node:$RHS)>, 1>;
1667 defm t2SUB  : T2I_bin_ii12rs<0b101, "sub",
1668                              BinOpFrag<(sub  node:$LHS, node:$RHS)>>;
1669
1670 // ADD and SUB with 's' bit set. No 12-bit immediate (T4) variants.
1671 defm t2ADDS : T2I_bin_s_irs <0b1000, "add",
1672                              IIC_iALUi, IIC_iALUr, IIC_iALUsi,
1673                              BinOpFrag<(addc node:$LHS, node:$RHS)>, 1>;
1674 defm t2SUBS : T2I_bin_s_irs <0b1101, "sub",
1675                              IIC_iALUi, IIC_iALUr, IIC_iALUsi,
1676                              BinOpFrag<(subc node:$LHS, node:$RHS)>>;
1677
1678 defm t2ADC  : T2I_adde_sube_irs<0b1010, "adc",
1679                           BinOpFrag<(adde_dead_carry node:$LHS, node:$RHS)>, 1>;
1680 defm t2SBC  : T2I_adde_sube_irs<0b1011, "sbc",
1681                           BinOpFrag<(sube_dead_carry node:$LHS, node:$RHS)>>;
1682 defm t2ADCS : T2I_adde_sube_s_irs<BinOpFrag<(adde_live_carry node:$LHS,
1683                                                              node:$RHS)>, 1>;
1684 defm t2SBCS : T2I_adde_sube_s_irs<BinOpFrag<(sube_live_carry node:$LHS,
1685                                                              node:$RHS)>>;
1686
1687 // RSB
1688 defm t2RSB  : T2I_rbin_irs  <0b1110, "rsb",
1689                              BinOpFrag<(sub  node:$LHS, node:$RHS)>>;
1690 defm t2RSBS : T2I_rbin_s_is <0b1110, "rsb",
1691                              BinOpFrag<(subc node:$LHS, node:$RHS)>>;
1692
1693 // (sub X, imm) gets canonicalized to (add X, -imm).  Match this form.
1694 // The assume-no-carry-in form uses the negation of the input since add/sub
1695 // assume opposite meanings of the carry flag (i.e., carry == !borrow).
1696 // See the definition of AddWithCarry() in the ARM ARM A2.2.1 for the gory
1697 // details.
1698 // The AddedComplexity preferences the first variant over the others since
1699 // it can be shrunk to a 16-bit wide encoding, while the others cannot.
1700 let AddedComplexity = 1 in
1701 def : T2Pat<(add        GPR:$src, imm0_255_neg:$imm),
1702             (t2SUBri    GPR:$src, imm0_255_neg:$imm)>;
1703 def : T2Pat<(add        GPR:$src, t2_so_imm_neg:$imm),
1704             (t2SUBri    GPR:$src, t2_so_imm_neg:$imm)>;
1705 def : T2Pat<(add        GPR:$src, imm0_4095_neg:$imm),
1706             (t2SUBri12  GPR:$src, imm0_4095_neg:$imm)>;
1707 let AddedComplexity = 1 in
1708 def : T2Pat<(addc       rGPR:$src, imm0_255_neg:$imm),
1709             (t2SUBSri   rGPR:$src, imm0_255_neg:$imm)>;
1710 def : T2Pat<(addc       rGPR:$src, t2_so_imm_neg:$imm),
1711             (t2SUBSri   rGPR:$src, t2_so_imm_neg:$imm)>;
1712 // The with-carry-in form matches bitwise not instead of the negation.
1713 // Effectively, the inverse interpretation of the carry flag already accounts
1714 // for part of the negation.
1715 let AddedComplexity = 1 in
1716 def : T2Pat<(adde_dead_carry       rGPR:$src, imm0_255_not:$imm),
1717             (t2SBCri    rGPR:$src, imm0_255_not:$imm)>;
1718 def : T2Pat<(adde_dead_carry       rGPR:$src, t2_so_imm_not:$imm),
1719             (t2SBCri    rGPR:$src, t2_so_imm_not:$imm)>;
1720 let AddedComplexity = 1 in
1721 def : T2Pat<(adde_live_carry       rGPR:$src, imm0_255_not:$imm),
1722             (t2SBCSri   rGPR:$src, imm0_255_not:$imm)>;
1723 def : T2Pat<(adde_live_carry       rGPR:$src, t2_so_imm_not:$imm),
1724             (t2SBCSri   rGPR:$src, t2_so_imm_not:$imm)>;
1725
1726 // Select Bytes -- for disassembly only
1727
1728 def t2SEL : T2ThreeReg<(outs GPR:$Rd), (ins GPR:$Rn, GPR:$Rm),
1729                 NoItinerary, "sel", "\t$Rd, $Rn, $Rm", []>,
1730           Requires<[IsThumb2, HasThumb2DSP]> {
1731   let Inst{31-27} = 0b11111;
1732   let Inst{26-24} = 0b010;
1733   let Inst{23} = 0b1;
1734   let Inst{22-20} = 0b010;
1735   let Inst{15-12} = 0b1111;
1736   let Inst{7} = 0b1;
1737   let Inst{6-4} = 0b000;
1738 }
1739
1740 // A6.3.13, A6.3.14, A6.3.15 Parallel addition and subtraction (signed/unsigned)
1741 // And Miscellaneous operations -- for disassembly only
1742 class T2I_pam<bits<3> op22_20, bits<4> op7_4, string opc,
1743               list<dag> pat = [/* For disassembly only; pattern left blank */],
1744               dag iops = (ins rGPR:$Rn, rGPR:$Rm),
1745               string asm = "\t$Rd, $Rn, $Rm">
1746   : T2I<(outs rGPR:$Rd), iops, NoItinerary, opc, asm, pat>,
1747     Requires<[IsThumb2, HasThumb2DSP]> {
1748   let Inst{31-27} = 0b11111;
1749   let Inst{26-23} = 0b0101;
1750   let Inst{22-20} = op22_20;
1751   let Inst{15-12} = 0b1111;
1752   let Inst{7-4} = op7_4;
1753
1754   bits<4> Rd;
1755   bits<4> Rn;
1756   bits<4> Rm;
1757
1758   let Inst{11-8}  = Rd;
1759   let Inst{19-16} = Rn;
1760   let Inst{3-0}   = Rm;
1761 }
1762
1763 // Saturating add/subtract -- for disassembly only
1764
1765 def t2QADD    : T2I_pam<0b000, 0b1000, "qadd",
1766                         [(set rGPR:$Rd, (int_arm_qadd rGPR:$Rn, rGPR:$Rm))],
1767                         (ins rGPR:$Rm, rGPR:$Rn), "\t$Rd, $Rm, $Rn">;
1768 def t2QADD16  : T2I_pam<0b001, 0b0001, "qadd16">;
1769 def t2QADD8   : T2I_pam<0b000, 0b0001, "qadd8">;
1770 def t2QASX    : T2I_pam<0b010, 0b0001, "qasx">;
1771 def t2QDADD   : T2I_pam<0b000, 0b1001, "qdadd", [],
1772                         (ins rGPR:$Rm, rGPR:$Rn), "\t$Rd, $Rm, $Rn">;
1773 def t2QDSUB   : T2I_pam<0b000, 0b1011, "qdsub", [],
1774                         (ins rGPR:$Rm, rGPR:$Rn), "\t$Rd, $Rm, $Rn">;
1775 def t2QSAX    : T2I_pam<0b110, 0b0001, "qsax">;
1776 def t2QSUB    : T2I_pam<0b000, 0b1010, "qsub",
1777                         [(set rGPR:$Rd, (int_arm_qsub rGPR:$Rn, rGPR:$Rm))],
1778                         (ins rGPR:$Rm, rGPR:$Rn), "\t$Rd, $Rm, $Rn">;
1779 def t2QSUB16  : T2I_pam<0b101, 0b0001, "qsub16">;
1780 def t2QSUB8   : T2I_pam<0b100, 0b0001, "qsub8">;
1781 def t2UQADD16 : T2I_pam<0b001, 0b0101, "uqadd16">;
1782 def t2UQADD8  : T2I_pam<0b000, 0b0101, "uqadd8">;
1783 def t2UQASX   : T2I_pam<0b010, 0b0101, "uqasx">;
1784 def t2UQSAX   : T2I_pam<0b110, 0b0101, "uqsax">;
1785 def t2UQSUB16 : T2I_pam<0b101, 0b0101, "uqsub16">;
1786 def t2UQSUB8  : T2I_pam<0b100, 0b0101, "uqsub8">;
1787
1788 // Signed/Unsigned add/subtract -- for disassembly only
1789
1790 def t2SASX    : T2I_pam<0b010, 0b0000, "sasx">;
1791 def t2SADD16  : T2I_pam<0b001, 0b0000, "sadd16">;
1792 def t2SADD8   : T2I_pam<0b000, 0b0000, "sadd8">;
1793 def t2SSAX    : T2I_pam<0b110, 0b0000, "ssax">;
1794 def t2SSUB16  : T2I_pam<0b101, 0b0000, "ssub16">;
1795 def t2SSUB8   : T2I_pam<0b100, 0b0000, "ssub8">;
1796 def t2UASX    : T2I_pam<0b010, 0b0100, "uasx">;
1797 def t2UADD16  : T2I_pam<0b001, 0b0100, "uadd16">;
1798 def t2UADD8   : T2I_pam<0b000, 0b0100, "uadd8">;
1799 def t2USAX    : T2I_pam<0b110, 0b0100, "usax">;
1800 def t2USUB16  : T2I_pam<0b101, 0b0100, "usub16">;
1801 def t2USUB8   : T2I_pam<0b100, 0b0100, "usub8">;
1802
1803 // Signed/Unsigned halving add/subtract -- for disassembly only
1804
1805 def t2SHASX   : T2I_pam<0b010, 0b0010, "shasx">;
1806 def t2SHADD16 : T2I_pam<0b001, 0b0010, "shadd16">;
1807 def t2SHADD8  : T2I_pam<0b000, 0b0010, "shadd8">;
1808 def t2SHSAX   : T2I_pam<0b110, 0b0010, "shsax">;
1809 def t2SHSUB16 : T2I_pam<0b101, 0b0010, "shsub16">;
1810 def t2SHSUB8  : T2I_pam<0b100, 0b0010, "shsub8">;
1811 def t2UHASX   : T2I_pam<0b010, 0b0110, "uhasx">;
1812 def t2UHADD16 : T2I_pam<0b001, 0b0110, "uhadd16">;
1813 def t2UHADD8  : T2I_pam<0b000, 0b0110, "uhadd8">;
1814 def t2UHSAX   : T2I_pam<0b110, 0b0110, "uhsax">;
1815 def t2UHSUB16 : T2I_pam<0b101, 0b0110, "uhsub16">;
1816 def t2UHSUB8  : T2I_pam<0b100, 0b0110, "uhsub8">;
1817
1818 // Helper class for disassembly only
1819 // A6.3.16 & A6.3.17
1820 // T2Imac - Thumb2 multiply [accumulate, and absolute difference] instructions.
1821 class T2ThreeReg_mac<bit long, bits<3> op22_20, bits<4> op7_4, dag oops,
1822   dag iops, InstrItinClass itin, string opc, string asm, list<dag> pattern>
1823   : T2ThreeReg<oops, iops, itin, opc, asm, pattern> {
1824   let Inst{31-27} = 0b11111;
1825   let Inst{26-24} = 0b011;
1826   let Inst{23}    = long;
1827   let Inst{22-20} = op22_20;
1828   let Inst{7-4}   = op7_4;
1829 }
1830
1831 class T2FourReg_mac<bit long, bits<3> op22_20, bits<4> op7_4, dag oops,
1832   dag iops, InstrItinClass itin, string opc, string asm, list<dag> pattern>
1833   : T2FourReg<oops, iops, itin, opc, asm, pattern> {
1834   let Inst{31-27} = 0b11111;
1835   let Inst{26-24} = 0b011;
1836   let Inst{23}    = long;
1837   let Inst{22-20} = op22_20;
1838   let Inst{7-4}   = op7_4;
1839 }
1840
1841 // Unsigned Sum of Absolute Differences [and Accumulate] -- for disassembly only
1842
1843 def t2USAD8   : T2ThreeReg_mac<0, 0b111, 0b0000, (outs rGPR:$Rd),
1844                                            (ins rGPR:$Rn, rGPR:$Rm),
1845                         NoItinerary, "usad8", "\t$Rd, $Rn, $Rm", []>,
1846           Requires<[IsThumb2, HasThumb2DSP]> {
1847   let Inst{15-12} = 0b1111;
1848 }
1849 def t2USADA8  : T2FourReg_mac<0, 0b111, 0b0000, (outs rGPR:$Rd),
1850                        (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), NoItinerary,
1851                         "usada8", "\t$Rd, $Rn, $Rm, $Ra", []>,
1852           Requires<[IsThumb2, HasThumb2DSP]>;
1853
1854 // Signed/Unsigned saturate -- for disassembly only
1855
1856 class T2SatI<dag oops, dag iops, InstrItinClass itin,
1857            string opc, string asm, list<dag> pattern>
1858   : T2I<oops, iops, itin, opc, asm, pattern> {
1859   bits<4> Rd;
1860   bits<4> Rn;
1861   bits<5> sat_imm;
1862   bits<7> sh;
1863
1864   let Inst{11-8}  = Rd;
1865   let Inst{19-16} = Rn;
1866   let Inst{4-0}   = sat_imm;
1867   let Inst{21}    = sh{5};
1868   let Inst{14-12} = sh{4-2};
1869   let Inst{7-6}   = sh{1-0};
1870 }
1871
1872 def t2SSAT: T2SatI<
1873               (outs rGPR:$Rd), (ins imm1_32:$sat_imm, rGPR:$Rn, shift_imm:$sh),
1874               NoItinerary, "ssat", "\t$Rd, $sat_imm, $Rn$sh",
1875               [/* For disassembly only; pattern left blank */]> {
1876   let Inst{31-27} = 0b11110;
1877   let Inst{25-22} = 0b1100;
1878   let Inst{20} = 0;
1879   let Inst{15} = 0;
1880 }
1881
1882 def t2SSAT16: T2SatI<
1883                 (outs rGPR:$Rd), (ins imm1_16:$sat_imm, rGPR:$Rn), NoItinerary,
1884                 "ssat16", "\t$Rd, $sat_imm, $Rn",
1885                 [/* For disassembly only; pattern left blank */]>,
1886           Requires<[IsThumb2, HasThumb2DSP]> {
1887   let Inst{31-27} = 0b11110;
1888   let Inst{25-22} = 0b1100;
1889   let Inst{20} = 0;
1890   let Inst{15} = 0;
1891   let Inst{21} = 1;        // sh = '1'
1892   let Inst{14-12} = 0b000; // imm3 = '000'
1893   let Inst{7-6} = 0b00;    // imm2 = '00'
1894 }
1895
1896 def t2USAT: T2SatI<
1897                 (outs rGPR:$Rd), (ins i32imm:$sat_imm, rGPR:$Rn, shift_imm:$sh),
1898                 NoItinerary, "usat", "\t$Rd, $sat_imm, $Rn$sh",
1899                 [/* For disassembly only; pattern left blank */]> {
1900   let Inst{31-27} = 0b11110;
1901   let Inst{25-22} = 0b1110;
1902   let Inst{20} = 0;
1903   let Inst{15} = 0;
1904 }
1905
1906 def t2USAT16: T2SatI<(outs rGPR:$dst), (ins i32imm:$sat_imm, rGPR:$Rn),
1907                      NoItinerary,
1908                      "usat16", "\t$dst, $sat_imm, $Rn",
1909                      [/* For disassembly only; pattern left blank */]>,
1910           Requires<[IsThumb2, HasThumb2DSP]> {
1911   let Inst{31-27} = 0b11110;
1912   let Inst{25-22} = 0b1110;
1913   let Inst{20} = 0;
1914   let Inst{15} = 0;
1915   let Inst{21} = 1;        // sh = '1'
1916   let Inst{14-12} = 0b000; // imm3 = '000'
1917   let Inst{7-6} = 0b00;    // imm2 = '00'
1918 }
1919
1920 def : T2Pat<(int_arm_ssat GPR:$a, imm:$pos), (t2SSAT imm:$pos, GPR:$a, 0)>;
1921 def : T2Pat<(int_arm_usat GPR:$a, imm:$pos), (t2USAT imm:$pos, GPR:$a, 0)>;
1922
1923 //===----------------------------------------------------------------------===//
1924 //  Shift and rotate Instructions.
1925 //
1926
1927 defm t2LSL  : T2I_sh_ir<0b00, "lsl", imm1_31, BinOpFrag<(shl  node:$LHS, node:$RHS)>>;
1928 defm t2LSR  : T2I_sh_ir<0b01, "lsr", imm_sr, BinOpFrag<(srl  node:$LHS, node:$RHS)>>;
1929 defm t2ASR  : T2I_sh_ir<0b10, "asr", imm_sr, BinOpFrag<(sra  node:$LHS, node:$RHS)>>;
1930 defm t2ROR  : T2I_sh_ir<0b11, "ror", imm1_31, BinOpFrag<(rotr node:$LHS, node:$RHS)>>;
1931
1932 // (rotr x, (and y, 0x...1f)) ==> (ROR x, y)
1933 def : Pat<(rotr rGPR:$lhs, (and rGPR:$rhs, lo5AllOne)),
1934           (t2RORrr rGPR:$lhs, rGPR:$rhs)>;
1935
1936 let Uses = [CPSR] in {
1937 def t2RRX : T2sTwoReg<(outs rGPR:$Rd), (ins rGPR:$Rm), IIC_iMOVsi,
1938                    "rrx", "\t$Rd, $Rm",
1939                    [(set rGPR:$Rd, (ARMrrx rGPR:$Rm))]> {
1940   let Inst{31-27} = 0b11101;
1941   let Inst{26-25} = 0b01;
1942   let Inst{24-21} = 0b0010;
1943   let Inst{19-16} = 0b1111; // Rn
1944   let Inst{14-12} = 0b000;
1945   let Inst{7-4} = 0b0011;
1946 }
1947 }
1948
1949 let isCodeGenOnly = 1, Defs = [CPSR] in {
1950 def t2MOVsrl_flag : T2TwoRegShiftImm<
1951                         (outs rGPR:$Rd), (ins rGPR:$Rm), IIC_iMOVsi,
1952                         "lsrs", ".w\t$Rd, $Rm, #1",
1953                         [(set rGPR:$Rd, (ARMsrl_flag rGPR:$Rm))]> {
1954   let Inst{31-27} = 0b11101;
1955   let Inst{26-25} = 0b01;
1956   let Inst{24-21} = 0b0010;
1957   let Inst{20} = 1; // The S bit.
1958   let Inst{19-16} = 0b1111; // Rn
1959   let Inst{5-4} = 0b01; // Shift type.
1960   // Shift amount = Inst{14-12:7-6} = 1.
1961   let Inst{14-12} = 0b000;
1962   let Inst{7-6} = 0b01;
1963 }
1964 def t2MOVsra_flag : T2TwoRegShiftImm<
1965                         (outs rGPR:$Rd), (ins rGPR:$Rm), IIC_iMOVsi,
1966                         "asrs", ".w\t$Rd, $Rm, #1",
1967                         [(set rGPR:$Rd, (ARMsra_flag rGPR:$Rm))]> {
1968   let Inst{31-27} = 0b11101;
1969   let Inst{26-25} = 0b01;
1970   let Inst{24-21} = 0b0010;
1971   let Inst{20} = 1; // The S bit.
1972   let Inst{19-16} = 0b1111; // Rn
1973   let Inst{5-4} = 0b10; // Shift type.
1974   // Shift amount = Inst{14-12:7-6} = 1.
1975   let Inst{14-12} = 0b000;
1976   let Inst{7-6} = 0b01;
1977 }
1978 }
1979
1980 //===----------------------------------------------------------------------===//
1981 //  Bitwise Instructions.
1982 //
1983
1984 defm t2AND  : T2I_bin_w_irs<0b0000, "and",
1985                             IIC_iBITi, IIC_iBITr, IIC_iBITsi,
1986                             BinOpFrag<(and node:$LHS, node:$RHS)>, "t2AND", 1>;
1987 defm t2ORR  : T2I_bin_w_irs<0b0010, "orr",
1988                             IIC_iBITi, IIC_iBITr, IIC_iBITsi,
1989                             BinOpFrag<(or  node:$LHS, node:$RHS)>, "t2ORR", 1>;
1990 defm t2EOR  : T2I_bin_w_irs<0b0100, "eor",
1991                             IIC_iBITi, IIC_iBITr, IIC_iBITsi,
1992                             BinOpFrag<(xor node:$LHS, node:$RHS)>, "t2EOR", 1>;
1993
1994 defm t2BIC  : T2I_bin_w_irs<0b0001, "bic",
1995                             IIC_iBITi, IIC_iBITr, IIC_iBITsi,
1996                             BinOpFrag<(and node:$LHS, (not node:$RHS))>,
1997                             "t2BIC">;
1998
1999 class T2BitFI<dag oops, dag iops, InstrItinClass itin,
2000               string opc, string asm, list<dag> pattern>
2001     : T2I<oops, iops, itin, opc, asm, pattern> {
2002   bits<4> Rd;
2003   bits<5> msb;
2004   bits<5> lsb;
2005
2006   let Inst{11-8}  = Rd;
2007   let Inst{4-0}   = msb{4-0};
2008   let Inst{14-12} = lsb{4-2};
2009   let Inst{7-6}   = lsb{1-0};
2010 }
2011
2012 class T2TwoRegBitFI<dag oops, dag iops, InstrItinClass itin,
2013               string opc, string asm, list<dag> pattern>
2014     : T2BitFI<oops, iops, itin, opc, asm, pattern> {
2015   bits<4> Rn;
2016
2017   let Inst{19-16} = Rn;
2018 }
2019
2020 let Constraints = "$src = $Rd" in
2021 def t2BFC : T2BitFI<(outs rGPR:$Rd), (ins rGPR:$src, bf_inv_mask_imm:$imm),
2022                 IIC_iUNAsi, "bfc", "\t$Rd, $imm",
2023                 [(set rGPR:$Rd, (and rGPR:$src, bf_inv_mask_imm:$imm))]> {
2024   let Inst{31-27} = 0b11110;
2025   let Inst{26} = 0; // should be 0.
2026   let Inst{25} = 1;
2027   let Inst{24-20} = 0b10110;
2028   let Inst{19-16} = 0b1111; // Rn
2029   let Inst{15} = 0;
2030   let Inst{5} = 0; // should be 0.
2031
2032   bits<10> imm;
2033   let msb{4-0} = imm{9-5};
2034   let lsb{4-0} = imm{4-0};
2035 }
2036
2037 def t2SBFX: T2TwoRegBitFI<
2038                 (outs rGPR:$Rd), (ins rGPR:$Rn, imm0_31:$lsb, imm1_32:$msb),
2039                  IIC_iUNAsi, "sbfx", "\t$Rd, $Rn, $lsb, $msb", []> {
2040   let Inst{31-27} = 0b11110;
2041   let Inst{25} = 1;
2042   let Inst{24-20} = 0b10100;
2043   let Inst{15} = 0;
2044 }
2045
2046 def t2UBFX: T2TwoRegBitFI<
2047                 (outs rGPR:$Rd), (ins rGPR:$Rn, imm0_31:$lsb, imm1_32:$msb),
2048                  IIC_iUNAsi, "ubfx", "\t$Rd, $Rn, $lsb, $msb", []> {
2049   let Inst{31-27} = 0b11110;
2050   let Inst{25} = 1;
2051   let Inst{24-20} = 0b11100;
2052   let Inst{15} = 0;
2053 }
2054
2055 // A8.6.18  BFI - Bitfield insert (Encoding T1)
2056 let Constraints = "$src = $Rd" in {
2057   def t2BFI : T2TwoRegBitFI<(outs rGPR:$Rd),
2058                   (ins rGPR:$src, rGPR:$Rn, bf_inv_mask_imm:$imm),
2059                   IIC_iBITi, "bfi", "\t$Rd, $Rn, $imm",
2060                   [(set rGPR:$Rd, (ARMbfi rGPR:$src, rGPR:$Rn,
2061                                    bf_inv_mask_imm:$imm))]> {
2062     let Inst{31-27} = 0b11110;
2063     let Inst{26} = 0; // should be 0.
2064     let Inst{25} = 1;
2065     let Inst{24-20} = 0b10110;
2066     let Inst{15} = 0;
2067     let Inst{5} = 0; // should be 0.
2068
2069     bits<10> imm;
2070     let msb{4-0} = imm{9-5};
2071     let lsb{4-0} = imm{4-0};
2072   }
2073
2074   // GNU as only supports this form of bfi (w/ 4 arguments)
2075   let isAsmParserOnly = 1 in
2076   def t2BFI4p : T2TwoRegBitFI<(outs rGPR:$Rd),
2077                   (ins rGPR:$src, rGPR:$Rn, lsb_pos_imm:$lsbit,
2078                        width_imm:$width),
2079                   IIC_iBITi, "bfi", "\t$Rd, $Rn, $lsbit, $width",
2080                   []> {
2081     let Inst{31-27} = 0b11110;
2082     let Inst{26} = 0; // should be 0.
2083     let Inst{25} = 1;
2084     let Inst{24-20} = 0b10110;
2085     let Inst{15} = 0;
2086     let Inst{5} = 0; // should be 0.
2087
2088     bits<5> lsbit;
2089     bits<5> width;
2090     let msb{4-0} = width; // Custom encoder => lsb+width-1
2091     let lsb{4-0} = lsbit;
2092   }
2093 }
2094
2095 defm t2ORN  : T2I_bin_irs<0b0011, "orn",
2096                           IIC_iBITi, IIC_iBITr, IIC_iBITsi,
2097                           BinOpFrag<(or  node:$LHS, (not node:$RHS))>,
2098                           "t2ORN", 0, "">;
2099
2100 // Prefer over of t2EORri ra, rb, -1 because mvn has 16-bit version
2101 let AddedComplexity = 1 in
2102 defm t2MVN  : T2I_un_irs <0b0011, "mvn",
2103                           IIC_iMVNi, IIC_iMVNr, IIC_iMVNsi,
2104                           UnOpFrag<(not node:$Src)>, 1, 1>;
2105
2106
2107 let AddedComplexity = 1 in
2108 def : T2Pat<(and     rGPR:$src, t2_so_imm_not:$imm),
2109             (t2BICri rGPR:$src, t2_so_imm_not:$imm)>;
2110
2111 // FIXME: Disable this pattern on Darwin to workaround an assembler bug.
2112 def : T2Pat<(or      rGPR:$src, t2_so_imm_not:$imm),
2113             (t2ORNri rGPR:$src, t2_so_imm_not:$imm)>,
2114             Requires<[IsThumb2]>;
2115
2116 def : T2Pat<(t2_so_imm_not:$src),
2117             (t2MVNi t2_so_imm_not:$src)>;
2118
2119 //===----------------------------------------------------------------------===//
2120 //  Multiply Instructions.
2121 //
2122 let isCommutable = 1 in
2123 def t2MUL: T2ThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iMUL32,
2124                 "mul", "\t$Rd, $Rn, $Rm",
2125                 [(set rGPR:$Rd, (mul rGPR:$Rn, rGPR:$Rm))]> {
2126   let Inst{31-27} = 0b11111;
2127   let Inst{26-23} = 0b0110;
2128   let Inst{22-20} = 0b000;
2129   let Inst{15-12} = 0b1111; // Ra = 0b1111 (no accumulate)
2130   let Inst{7-4} = 0b0000; // Multiply
2131 }
2132
2133 def t2MLA: T2FourReg<
2134                 (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC32,
2135                 "mla", "\t$Rd, $Rn, $Rm, $Ra",
2136                 [(set rGPR:$Rd, (add (mul rGPR:$Rn, rGPR:$Rm), rGPR:$Ra))]> {
2137   let Inst{31-27} = 0b11111;
2138   let Inst{26-23} = 0b0110;
2139   let Inst{22-20} = 0b000;
2140   let Inst{7-4} = 0b0000; // Multiply
2141 }
2142
2143 def t2MLS: T2FourReg<
2144                 (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC32,
2145                 "mls", "\t$Rd, $Rn, $Rm, $Ra",
2146                 [(set rGPR:$Rd, (sub rGPR:$Ra, (mul rGPR:$Rn, rGPR:$Rm)))]> {
2147   let Inst{31-27} = 0b11111;
2148   let Inst{26-23} = 0b0110;
2149   let Inst{22-20} = 0b000;
2150   let Inst{7-4} = 0b0001; // Multiply and Subtract
2151 }
2152
2153 // Extra precision multiplies with low / high results
2154 let neverHasSideEffects = 1 in {
2155 let isCommutable = 1 in {
2156 def t2SMULL : T2MulLong<0b000, 0b0000,
2157                   (outs rGPR:$Rd, rGPR:$Ra),
2158                   (ins rGPR:$Rn, rGPR:$Rm), IIC_iMUL64,
2159                    "smull", "\t$Rd, $Ra, $Rn, $Rm", []>;
2160
2161 def t2UMULL : T2MulLong<0b010, 0b0000,
2162                   (outs rGPR:$RdLo, rGPR:$RdHi),
2163                   (ins rGPR:$Rn, rGPR:$Rm), IIC_iMUL64,
2164                    "umull", "\t$RdLo, $RdHi, $Rn, $Rm", []>;
2165 } // isCommutable
2166
2167 // Multiply + accumulate
2168 def t2SMLAL : T2MulLong<0b100, 0b0000,
2169                   (outs rGPR:$RdLo, rGPR:$RdHi),
2170                   (ins rGPR:$Rn, rGPR:$Rm), IIC_iMAC64,
2171                   "smlal", "\t$RdLo, $RdHi, $Rn, $Rm", []>;
2172
2173 def t2UMLAL : T2MulLong<0b110, 0b0000,
2174                   (outs rGPR:$RdLo, rGPR:$RdHi),
2175                   (ins rGPR:$Rn, rGPR:$Rm), IIC_iMAC64,
2176                   "umlal", "\t$RdLo, $RdHi, $Rn, $Rm", []>;
2177
2178 def t2UMAAL : T2MulLong<0b110, 0b0110,
2179                   (outs rGPR:$RdLo, rGPR:$RdHi),
2180                   (ins rGPR:$Rn, rGPR:$Rm), IIC_iMAC64,
2181                   "umaal", "\t$RdLo, $RdHi, $Rn, $Rm", []>,
2182           Requires<[IsThumb2, HasThumb2DSP]>;
2183 } // neverHasSideEffects
2184
2185 // Rounding variants of the below included for disassembly only
2186
2187 // Most significant word multiply
2188 def t2SMMUL : T2ThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iMUL32,
2189                   "smmul", "\t$Rd, $Rn, $Rm",
2190                   [(set rGPR:$Rd, (mulhs rGPR:$Rn, rGPR:$Rm))]>,
2191           Requires<[IsThumb2, HasThumb2DSP]> {
2192   let Inst{31-27} = 0b11111;
2193   let Inst{26-23} = 0b0110;
2194   let Inst{22-20} = 0b101;
2195   let Inst{15-12} = 0b1111; // Ra = 0b1111 (no accumulate)
2196   let Inst{7-4} = 0b0000; // No Rounding (Inst{4} = 0)
2197 }
2198
2199 def t2SMMULR : T2ThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iMUL32,
2200                   "smmulr", "\t$Rd, $Rn, $Rm", []>,
2201           Requires<[IsThumb2, HasThumb2DSP]> {
2202   let Inst{31-27} = 0b11111;
2203   let Inst{26-23} = 0b0110;
2204   let Inst{22-20} = 0b101;
2205   let Inst{15-12} = 0b1111; // Ra = 0b1111 (no accumulate)
2206   let Inst{7-4} = 0b0001; // Rounding (Inst{4} = 1)
2207 }
2208
2209 def t2SMMLA : T2FourReg<
2210         (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC32,
2211                 "smmla", "\t$Rd, $Rn, $Rm, $Ra",
2212                 [(set rGPR:$Rd, (add (mulhs rGPR:$Rm, rGPR:$Rn), rGPR:$Ra))]>,
2213           Requires<[IsThumb2, HasThumb2DSP]> {
2214   let Inst{31-27} = 0b11111;
2215   let Inst{26-23} = 0b0110;
2216   let Inst{22-20} = 0b101;
2217   let Inst{7-4} = 0b0000; // No Rounding (Inst{4} = 0)
2218 }
2219
2220 def t2SMMLAR: T2FourReg<
2221         (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC32,
2222                   "smmlar", "\t$Rd, $Rn, $Rm, $Ra", []>,
2223           Requires<[IsThumb2, HasThumb2DSP]> {
2224   let Inst{31-27} = 0b11111;
2225   let Inst{26-23} = 0b0110;
2226   let Inst{22-20} = 0b101;
2227   let Inst{7-4} = 0b0001; // Rounding (Inst{4} = 1)
2228 }
2229
2230 def t2SMMLS: T2FourReg<
2231         (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC32,
2232                 "smmls", "\t$Rd, $Rn, $Rm, $Ra",
2233                 [(set rGPR:$Rd, (sub rGPR:$Ra, (mulhs rGPR:$Rn, rGPR:$Rm)))]>,
2234           Requires<[IsThumb2, HasThumb2DSP]> {
2235   let Inst{31-27} = 0b11111;
2236   let Inst{26-23} = 0b0110;
2237   let Inst{22-20} = 0b110;
2238   let Inst{7-4} = 0b0000; // No Rounding (Inst{4} = 0)
2239 }
2240
2241 def t2SMMLSR:T2FourReg<
2242         (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC32,
2243                 "smmlsr", "\t$Rd, $Rn, $Rm, $Ra", []>,
2244           Requires<[IsThumb2, HasThumb2DSP]> {
2245   let Inst{31-27} = 0b11111;
2246   let Inst{26-23} = 0b0110;
2247   let Inst{22-20} = 0b110;
2248   let Inst{7-4} = 0b0001; // Rounding (Inst{4} = 1)
2249 }
2250
2251 multiclass T2I_smul<string opc, PatFrag opnode> {
2252   def BB : T2ThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iMUL16,
2253               !strconcat(opc, "bb"), "\t$Rd, $Rn, $Rm",
2254               [(set rGPR:$Rd, (opnode (sext_inreg rGPR:$Rn, i16),
2255                                       (sext_inreg rGPR:$Rm, i16)))]>,
2256           Requires<[IsThumb2, HasThumb2DSP]> {
2257     let Inst{31-27} = 0b11111;
2258     let Inst{26-23} = 0b0110;
2259     let Inst{22-20} = 0b001;
2260     let Inst{15-12} = 0b1111; // Ra = 0b1111 (no accumulate)
2261     let Inst{7-6} = 0b00;
2262     let Inst{5-4} = 0b00;
2263   }
2264
2265   def BT : T2ThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iMUL16,
2266               !strconcat(opc, "bt"), "\t$Rd, $Rn, $Rm",
2267               [(set rGPR:$Rd, (opnode (sext_inreg rGPR:$Rn, i16),
2268                                       (sra rGPR:$Rm, (i32 16))))]>,
2269           Requires<[IsThumb2, HasThumb2DSP]> {
2270     let Inst{31-27} = 0b11111;
2271     let Inst{26-23} = 0b0110;
2272     let Inst{22-20} = 0b001;
2273     let Inst{15-12} = 0b1111; // Ra = 0b1111 (no accumulate)
2274     let Inst{7-6} = 0b00;
2275     let Inst{5-4} = 0b01;
2276   }
2277
2278   def TB : T2ThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iMUL16,
2279               !strconcat(opc, "tb"), "\t$Rd, $Rn, $Rm",
2280               [(set rGPR:$Rd, (opnode (sra rGPR:$Rn, (i32 16)),
2281                                       (sext_inreg rGPR:$Rm, i16)))]>,
2282           Requires<[IsThumb2, HasThumb2DSP]> {
2283     let Inst{31-27} = 0b11111;
2284     let Inst{26-23} = 0b0110;
2285     let Inst{22-20} = 0b001;
2286     let Inst{15-12} = 0b1111; // Ra = 0b1111 (no accumulate)
2287     let Inst{7-6} = 0b00;
2288     let Inst{5-4} = 0b10;
2289   }
2290
2291   def TT : T2ThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iMUL16,
2292               !strconcat(opc, "tt"), "\t$Rd, $Rn, $Rm",
2293               [(set rGPR:$Rd, (opnode (sra rGPR:$Rn, (i32 16)),
2294                                       (sra rGPR:$Rm, (i32 16))))]>,
2295           Requires<[IsThumb2, HasThumb2DSP]> {
2296     let Inst{31-27} = 0b11111;
2297     let Inst{26-23} = 0b0110;
2298     let Inst{22-20} = 0b001;
2299     let Inst{15-12} = 0b1111; // Ra = 0b1111 (no accumulate)
2300     let Inst{7-6} = 0b00;
2301     let Inst{5-4} = 0b11;
2302   }
2303
2304   def WB : T2ThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iMUL16,
2305               !strconcat(opc, "wb"), "\t$Rd, $Rn, $Rm",
2306               [(set rGPR:$Rd, (sra (opnode rGPR:$Rn,
2307                                     (sext_inreg rGPR:$Rm, i16)), (i32 16)))]>,
2308           Requires<[IsThumb2, HasThumb2DSP]> {
2309     let Inst{31-27} = 0b11111;
2310     let Inst{26-23} = 0b0110;
2311     let Inst{22-20} = 0b011;
2312     let Inst{15-12} = 0b1111; // Ra = 0b1111 (no accumulate)
2313     let Inst{7-6} = 0b00;
2314     let Inst{5-4} = 0b00;
2315   }
2316
2317   def WT : T2ThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iMUL16,
2318               !strconcat(opc, "wt"), "\t$Rd, $Rn, $Rm",
2319               [(set rGPR:$Rd, (sra (opnode rGPR:$Rn,
2320                                     (sra rGPR:$Rm, (i32 16))), (i32 16)))]>,
2321           Requires<[IsThumb2, HasThumb2DSP]> {
2322     let Inst{31-27} = 0b11111;
2323     let Inst{26-23} = 0b0110;
2324     let Inst{22-20} = 0b011;
2325     let Inst{15-12} = 0b1111; // Ra = 0b1111 (no accumulate)
2326     let Inst{7-6} = 0b00;
2327     let Inst{5-4} = 0b01;
2328   }
2329 }
2330
2331
2332 multiclass T2I_smla<string opc, PatFrag opnode> {
2333   def BB : T2FourReg<
2334         (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC16,
2335               !strconcat(opc, "bb"), "\t$Rd, $Rn, $Rm, $Ra",
2336               [(set rGPR:$Rd, (add rGPR:$Ra,
2337                                (opnode (sext_inreg rGPR:$Rn, i16),
2338                                        (sext_inreg rGPR:$Rm, i16))))]>,
2339           Requires<[IsThumb2, HasThumb2DSP]> {
2340     let Inst{31-27} = 0b11111;
2341     let Inst{26-23} = 0b0110;
2342     let Inst{22-20} = 0b001;
2343     let Inst{7-6} = 0b00;
2344     let Inst{5-4} = 0b00;
2345   }
2346
2347   def BT : T2FourReg<
2348        (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC16,
2349              !strconcat(opc, "bt"), "\t$Rd, $Rn, $Rm, $Ra",
2350              [(set rGPR:$Rd, (add rGPR:$Ra, (opnode (sext_inreg rGPR:$Rn, i16),
2351                                                  (sra rGPR:$Rm, (i32 16)))))]>,
2352           Requires<[IsThumb2, HasThumb2DSP]> {
2353     let Inst{31-27} = 0b11111;
2354     let Inst{26-23} = 0b0110;
2355     let Inst{22-20} = 0b001;
2356     let Inst{7-6} = 0b00;
2357     let Inst{5-4} = 0b01;
2358   }
2359
2360   def TB : T2FourReg<
2361         (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC16,
2362               !strconcat(opc, "tb"), "\t$Rd, $Rn, $Rm, $Ra",
2363               [(set rGPR:$Rd, (add rGPR:$Ra, (opnode (sra rGPR:$Rn, (i32 16)),
2364                                                (sext_inreg rGPR:$Rm, i16))))]>,
2365           Requires<[IsThumb2, HasThumb2DSP]> {
2366     let Inst{31-27} = 0b11111;
2367     let Inst{26-23} = 0b0110;
2368     let Inst{22-20} = 0b001;
2369     let Inst{7-6} = 0b00;
2370     let Inst{5-4} = 0b10;
2371   }
2372
2373   def TT : T2FourReg<
2374         (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC16,
2375               !strconcat(opc, "tt"), "\t$Rd, $Rn, $Rm, $Ra",
2376              [(set rGPR:$Rd, (add rGPR:$Ra, (opnode (sra rGPR:$Rn, (i32 16)),
2377                                                  (sra rGPR:$Rm, (i32 16)))))]>,
2378           Requires<[IsThumb2, HasThumb2DSP]> {
2379     let Inst{31-27} = 0b11111;
2380     let Inst{26-23} = 0b0110;
2381     let Inst{22-20} = 0b001;
2382     let Inst{7-6} = 0b00;
2383     let Inst{5-4} = 0b11;
2384   }
2385
2386   def WB : T2FourReg<
2387         (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC16,
2388               !strconcat(opc, "wb"), "\t$Rd, $Rn, $Rm, $Ra",
2389               [(set rGPR:$Rd, (add rGPR:$Ra, (sra (opnode rGPR:$Rn,
2390                                     (sext_inreg rGPR:$Rm, i16)), (i32 16))))]>,
2391           Requires<[IsThumb2, HasThumb2DSP]> {
2392     let Inst{31-27} = 0b11111;
2393     let Inst{26-23} = 0b0110;
2394     let Inst{22-20} = 0b011;
2395     let Inst{7-6} = 0b00;
2396     let Inst{5-4} = 0b00;
2397   }
2398
2399   def WT : T2FourReg<
2400         (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC16,
2401               !strconcat(opc, "wt"), "\t$Rd, $Rn, $Rm, $Ra",
2402               [(set rGPR:$Rd, (add rGPR:$Ra, (sra (opnode rGPR:$Rn,
2403                                       (sra rGPR:$Rm, (i32 16))), (i32 16))))]>,
2404           Requires<[IsThumb2, HasThumb2DSP]> {
2405     let Inst{31-27} = 0b11111;
2406     let Inst{26-23} = 0b0110;
2407     let Inst{22-20} = 0b011;
2408     let Inst{7-6} = 0b00;
2409     let Inst{5-4} = 0b01;
2410   }
2411 }
2412
2413 defm t2SMUL : T2I_smul<"smul", BinOpFrag<(mul node:$LHS, node:$RHS)>>;
2414 defm t2SMLA : T2I_smla<"smla", BinOpFrag<(mul node:$LHS, node:$RHS)>>;
2415
2416 // Halfword multiple accumulate long: SMLAL<x><y> -- for disassembly only
2417 def t2SMLALBB : T2FourReg_mac<1, 0b100, 0b1000, (outs rGPR:$Ra,rGPR:$Rd),
2418          (ins rGPR:$Rn,rGPR:$Rm), IIC_iMAC64, "smlalbb", "\t$Ra, $Rd, $Rn, $Rm",
2419            [/* For disassembly only; pattern left blank */]>,
2420           Requires<[IsThumb2, HasThumb2DSP]>;
2421 def t2SMLALBT : T2FourReg_mac<1, 0b100, 0b1001, (outs rGPR:$Ra,rGPR:$Rd),
2422          (ins rGPR:$Rn,rGPR:$Rm), IIC_iMAC64, "smlalbt", "\t$Ra, $Rd, $Rn, $Rm",
2423            [/* For disassembly only; pattern left blank */]>,
2424           Requires<[IsThumb2, HasThumb2DSP]>;
2425 def t2SMLALTB : T2FourReg_mac<1, 0b100, 0b1010, (outs rGPR:$Ra,rGPR:$Rd),
2426          (ins rGPR:$Rn,rGPR:$Rm), IIC_iMAC64, "smlaltb", "\t$Ra, $Rd, $Rn, $Rm",
2427            [/* For disassembly only; pattern left blank */]>,
2428           Requires<[IsThumb2, HasThumb2DSP]>;
2429 def t2SMLALTT : T2FourReg_mac<1, 0b100, 0b1011, (outs rGPR:$Ra,rGPR:$Rd),
2430          (ins rGPR:$Rn,rGPR:$Rm), IIC_iMAC64, "smlaltt", "\t$Ra, $Rd, $Rn, $Rm",
2431            [/* For disassembly only; pattern left blank */]>,
2432           Requires<[IsThumb2, HasThumb2DSP]>;
2433
2434 // Dual halfword multiple: SMUAD, SMUSD, SMLAD, SMLSD, SMLALD, SMLSLD
2435 // These are for disassembly only.
2436
2437 def t2SMUAD: T2ThreeReg_mac<
2438             0, 0b010, 0b0000, (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm),
2439             IIC_iMAC32, "smuad", "\t$Rd, $Rn, $Rm", []>,
2440           Requires<[IsThumb2, HasThumb2DSP]> {
2441   let Inst{15-12} = 0b1111;
2442 }
2443 def t2SMUADX:T2ThreeReg_mac<
2444             0, 0b010, 0b0001, (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm),
2445             IIC_iMAC32, "smuadx", "\t$Rd, $Rn, $Rm", []>,
2446           Requires<[IsThumb2, HasThumb2DSP]> {
2447   let Inst{15-12} = 0b1111;
2448 }
2449 def t2SMUSD: T2ThreeReg_mac<
2450             0, 0b100, 0b0000, (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm),
2451             IIC_iMAC32, "smusd", "\t$Rd, $Rn, $Rm", []>,
2452           Requires<[IsThumb2, HasThumb2DSP]> {
2453   let Inst{15-12} = 0b1111;
2454 }
2455 def t2SMUSDX:T2ThreeReg_mac<
2456             0, 0b100, 0b0001, (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm),
2457             IIC_iMAC32, "smusdx", "\t$Rd, $Rn, $Rm", []>,
2458           Requires<[IsThumb2, HasThumb2DSP]> {
2459   let Inst{15-12} = 0b1111;
2460 }
2461 def t2SMLAD   : T2ThreeReg_mac<
2462             0, 0b010, 0b0000, (outs rGPR:$Rd),
2463             (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC32, "smlad",
2464             "\t$Rd, $Rn, $Rm, $Ra", []>,
2465           Requires<[IsThumb2, HasThumb2DSP]>;
2466 def t2SMLADX  : T2FourReg_mac<
2467             0, 0b010, 0b0001, (outs rGPR:$Rd),
2468             (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC32, "smladx",
2469             "\t$Rd, $Rn, $Rm, $Ra", []>,
2470           Requires<[IsThumb2, HasThumb2DSP]>;
2471 def t2SMLSD   : T2FourReg_mac<0, 0b100, 0b0000, (outs rGPR:$Rd),
2472             (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC32, "smlsd",
2473             "\t$Rd, $Rn, $Rm, $Ra", []>,
2474           Requires<[IsThumb2, HasThumb2DSP]>;
2475 def t2SMLSDX  : T2FourReg_mac<0, 0b100, 0b0001, (outs rGPR:$Rd),
2476             (ins rGPR:$Rn, rGPR:$Rm, rGPR:$Ra), IIC_iMAC32, "smlsdx",
2477             "\t$Rd, $Rn, $Rm, $Ra", []>,
2478           Requires<[IsThumb2, HasThumb2DSP]>;
2479 def t2SMLALD  : T2FourReg_mac<1, 0b100, 0b1100, (outs rGPR:$Ra,rGPR:$Rd),
2480                         (ins rGPR:$Rm, rGPR:$Rn), IIC_iMAC64, "smlald",
2481                         "\t$Ra, $Rd, $Rm, $Rn", []>,
2482           Requires<[IsThumb2, HasThumb2DSP]>;
2483 def t2SMLALDX : T2FourReg_mac<1, 0b100, 0b1101, (outs rGPR:$Ra,rGPR:$Rd),
2484                         (ins rGPR:$Rm,rGPR:$Rn), IIC_iMAC64, "smlaldx",
2485                         "\t$Ra, $Rd, $Rm, $Rn", []>,
2486           Requires<[IsThumb2, HasThumb2DSP]>;
2487 def t2SMLSLD  : T2FourReg_mac<1, 0b101, 0b1100, (outs rGPR:$Ra,rGPR:$Rd),
2488                         (ins rGPR:$Rm,rGPR:$Rn), IIC_iMAC64, "smlsld",
2489                         "\t$Ra, $Rd, $Rm, $Rn", []>,
2490           Requires<[IsThumb2, HasThumb2DSP]>;
2491 def t2SMLSLDX : T2FourReg_mac<1, 0b101, 0b1101, (outs rGPR:$Ra,rGPR:$Rd),
2492                         (ins rGPR:$Rm,rGPR:$Rn), IIC_iMAC64, "smlsldx",
2493                         "\t$Ra, $Rd, $Rm, $Rn", []>,
2494           Requires<[IsThumb2, HasThumb2DSP]>;
2495
2496 //===----------------------------------------------------------------------===//
2497 //  Division Instructions.
2498 //  Signed and unsigned division on v7-M
2499 //
2500 def t2SDIV : T2ThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iALUi,
2501                  "sdiv", "\t$Rd, $Rn, $Rm",
2502                  [(set rGPR:$Rd, (sdiv rGPR:$Rn, rGPR:$Rm))]>,
2503                  Requires<[HasDivide, IsThumb2]> {
2504   let Inst{31-27} = 0b11111;
2505   let Inst{26-21} = 0b011100;
2506   let Inst{20} = 0b1;
2507   let Inst{15-12} = 0b1111;
2508   let Inst{7-4} = 0b1111;
2509 }
2510
2511 def t2UDIV : T2ThreeReg<(outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm), IIC_iALUi,
2512                  "udiv", "\t$Rd, $Rn, $Rm",
2513                  [(set rGPR:$Rd, (udiv rGPR:$Rn, rGPR:$Rm))]>,
2514                  Requires<[HasDivide, IsThumb2]> {
2515   let Inst{31-27} = 0b11111;
2516   let Inst{26-21} = 0b011101;
2517   let Inst{20} = 0b1;
2518   let Inst{15-12} = 0b1111;
2519   let Inst{7-4} = 0b1111;
2520 }
2521
2522 //===----------------------------------------------------------------------===//
2523 //  Misc. Arithmetic Instructions.
2524 //
2525
2526 class T2I_misc<bits<2> op1, bits<2> op2, dag oops, dag iops,
2527       InstrItinClass itin, string opc, string asm, list<dag> pattern>
2528   : T2ThreeReg<oops, iops, itin, opc, asm, pattern> {
2529   let Inst{31-27} = 0b11111;
2530   let Inst{26-22} = 0b01010;
2531   let Inst{21-20} = op1;
2532   let Inst{15-12} = 0b1111;
2533   let Inst{7-6} = 0b10;
2534   let Inst{5-4} = op2;
2535   let Rn{3-0} = Rm;
2536 }
2537
2538 def t2CLZ : T2I_misc<0b11, 0b00, (outs rGPR:$Rd), (ins rGPR:$Rm), IIC_iUNAr,
2539                     "clz", "\t$Rd, $Rm", [(set rGPR:$Rd, (ctlz rGPR:$Rm))]>;
2540
2541 def t2RBIT : T2I_misc<0b01, 0b10, (outs rGPR:$Rd), (ins rGPR:$Rm), IIC_iUNAr,
2542                       "rbit", "\t$Rd, $Rm",
2543                       [(set rGPR:$Rd, (ARMrbit rGPR:$Rm))]>;
2544
2545 def t2REV : T2I_misc<0b01, 0b00, (outs rGPR:$Rd), (ins rGPR:$Rm), IIC_iUNAr,
2546                  "rev", ".w\t$Rd, $Rm", [(set rGPR:$Rd, (bswap rGPR:$Rm))]>;
2547
2548 def t2REV16 : T2I_misc<0b01, 0b01, (outs rGPR:$Rd), (ins rGPR:$Rm), IIC_iUNAr,
2549                        "rev16", ".w\t$Rd, $Rm",
2550                 [(set rGPR:$Rd, (rotr (bswap rGPR:$Rm), (i32 16)))]>;
2551
2552 def t2REVSH : T2I_misc<0b01, 0b11, (outs rGPR:$Rd), (ins rGPR:$Rm), IIC_iUNAr,
2553                        "revsh", ".w\t$Rd, $Rm",
2554                  [(set rGPR:$Rd, (sra (bswap rGPR:$Rm), (i32 16)))]>;
2555
2556 def : T2Pat<(or (sra (shl rGPR:$Rm, (i32 24)), (i32 16)),
2557                 (and (srl rGPR:$Rm, (i32 8)), 0xFF)),
2558             (t2REVSH rGPR:$Rm)>;
2559
2560 def t2PKHBT : T2ThreeReg<
2561             (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, i32imm:$sh),
2562                   IIC_iBITsi, "pkhbt", "\t$Rd, $Rn, $Rm, lsl $sh",
2563                   [(set rGPR:$Rd, (or (and rGPR:$Rn, 0xFFFF),
2564                                       (and (shl rGPR:$Rm, pkh_lsl_amt:$sh),
2565                                            0xFFFF0000)))]>,
2566                   Requires<[HasT2ExtractPack, IsThumb2]> {
2567   let Inst{31-27} = 0b11101;
2568   let Inst{26-25} = 0b01;
2569   let Inst{24-20} = 0b01100;
2570   let Inst{5} = 0; // BT form
2571   let Inst{4} = 0;
2572
2573   bits<5> sh;
2574   let Inst{14-12} = sh{4-2};
2575   let Inst{7-6}   = sh{1-0};
2576 }
2577
2578 // Alternate cases for PKHBT where identities eliminate some nodes.
2579 def : T2Pat<(or (and rGPR:$src1, 0xFFFF), (and rGPR:$src2, 0xFFFF0000)),
2580             (t2PKHBT rGPR:$src1, rGPR:$src2, 0)>,
2581             Requires<[HasT2ExtractPack, IsThumb2]>;
2582 def : T2Pat<(or (and rGPR:$src1, 0xFFFF), (shl rGPR:$src2, imm16_31:$sh)),
2583             (t2PKHBT rGPR:$src1, rGPR:$src2, imm16_31:$sh)>,
2584             Requires<[HasT2ExtractPack, IsThumb2]>;
2585
2586 // Note: Shifts of 1-15 bits will be transformed to srl instead of sra and
2587 // will match the pattern below.
2588 def t2PKHTB : T2ThreeReg<
2589                   (outs rGPR:$Rd), (ins rGPR:$Rn, rGPR:$Rm, i32imm:$sh),
2590                   IIC_iBITsi, "pkhtb", "\t$Rd, $Rn, $Rm, asr $sh",
2591                   [(set rGPR:$Rd, (or (and rGPR:$Rn, 0xFFFF0000),
2592                                        (and (sra rGPR:$Rm, pkh_asr_amt:$sh),
2593                                             0xFFFF)))]>,
2594                   Requires<[HasT2ExtractPack, IsThumb2]> {
2595   let Inst{31-27} = 0b11101;
2596   let Inst{26-25} = 0b01;
2597   let Inst{24-20} = 0b01100;
2598   let Inst{5} = 1; // TB form
2599   let Inst{4} = 0;
2600
2601   bits<5> sh;
2602   let Inst{14-12} = sh{4-2};
2603   let Inst{7-6}   = sh{1-0};
2604 }
2605
2606 // Alternate cases for PKHTB where identities eliminate some nodes.  Note that
2607 // a shift amount of 0 is *not legal* here, it is PKHBT instead.
2608 def : T2Pat<(or (and rGPR:$src1, 0xFFFF0000), (srl rGPR:$src2, imm16_31:$sh)),
2609             (t2PKHTB rGPR:$src1, rGPR:$src2, imm16_31:$sh)>,
2610             Requires<[HasT2ExtractPack, IsThumb2]>;
2611 def : T2Pat<(or (and rGPR:$src1, 0xFFFF0000),
2612                 (and (srl rGPR:$src2, imm1_15:$sh), 0xFFFF)),
2613             (t2PKHTB rGPR:$src1, rGPR:$src2, imm1_15:$sh)>,
2614             Requires<[HasT2ExtractPack, IsThumb2]>;
2615
2616 //===----------------------------------------------------------------------===//
2617 //  Comparison Instructions...
2618 //
2619 defm t2CMP  : T2I_cmp_irs<0b1101, "cmp",
2620                           IIC_iCMPi, IIC_iCMPr, IIC_iCMPsi,
2621                           BinOpFrag<(ARMcmp node:$LHS, node:$RHS)>>;
2622
2623 def : T2Pat<(ARMcmpZ  GPR:$lhs, t2_so_imm:$imm),
2624             (t2CMPri  GPR:$lhs, t2_so_imm:$imm)>;
2625 def : T2Pat<(ARMcmpZ  GPR:$lhs, rGPR:$rhs),
2626             (t2CMPrr  GPR:$lhs, rGPR:$rhs)>;
2627 def : T2Pat<(ARMcmpZ  GPR:$lhs, t2_so_reg:$rhs),
2628             (t2CMPrs  GPR:$lhs, t2_so_reg:$rhs)>;
2629
2630 //FIXME: Disable CMN, as CCodes are backwards from compare expectations
2631 //       Compare-to-zero still works out, just not the relationals
2632 //defm t2CMN  : T2I_cmp_irs<0b1000, "cmn",
2633 //                          BinOpFrag<(ARMcmp node:$LHS,(ineg node:$RHS))>>;
2634 defm t2CMNz : T2I_cmp_irs<0b1000, "cmn",
2635                           IIC_iCMPi, IIC_iCMPr, IIC_iCMPsi,
2636                           BinOpFrag<(ARMcmpZ node:$LHS,(ineg node:$RHS))>>;
2637
2638 //def : T2Pat<(ARMcmp  GPR:$src, t2_so_imm_neg:$imm),
2639 //            (t2CMNri GPR:$src, t2_so_imm_neg:$imm)>;
2640
2641 def : T2Pat<(ARMcmpZ  GPR:$src, t2_so_imm_neg:$imm),
2642             (t2CMNzri GPR:$src, t2_so_imm_neg:$imm)>;
2643
2644 defm t2TST  : T2I_cmp_irs<0b0000, "tst",
2645                           IIC_iTSTi, IIC_iTSTr, IIC_iTSTsi,
2646                          BinOpFrag<(ARMcmpZ (and_su node:$LHS, node:$RHS), 0)>>;
2647 defm t2TEQ  : T2I_cmp_irs<0b0100, "teq",
2648                           IIC_iTSTi, IIC_iTSTr, IIC_iTSTsi,
2649                          BinOpFrag<(ARMcmpZ (xor_su node:$LHS, node:$RHS), 0)>>;
2650
2651 // Conditional moves
2652 // FIXME: should be able to write a pattern for ARMcmov, but can't use
2653 // a two-value operand where a dag node expects two operands. :(
2654 let neverHasSideEffects = 1 in {
2655 def t2MOVCCr : t2PseudoInst<(outs rGPR:$Rd),
2656                             (ins rGPR:$false, rGPR:$Rm, pred:$p),
2657                             4, IIC_iCMOVr,
2658    [/*(set rGPR:$Rd, (ARMcmov rGPR:$false, rGPR:$Rm, imm:$cc, CCR:$ccr))*/]>,
2659                 RegConstraint<"$false = $Rd">;
2660
2661 let isMoveImm = 1 in
2662 def t2MOVCCi : t2PseudoInst<(outs rGPR:$Rd),
2663                             (ins rGPR:$false, t2_so_imm:$imm, pred:$p),
2664                    4, IIC_iCMOVi,
2665 [/*(set rGPR:$Rd,(ARMcmov rGPR:$false,t2_so_imm:$imm, imm:$cc, CCR:$ccr))*/]>,
2666                    RegConstraint<"$false = $Rd">;
2667
2668 // FIXME: Pseudo-ize these. For now, just mark codegen only.
2669 let isCodeGenOnly = 1 in {
2670 let isMoveImm = 1 in
2671 def t2MOVCCi16 : T2I<(outs rGPR:$Rd), (ins rGPR:$false, imm0_65535_expr:$imm),
2672                       IIC_iCMOVi,
2673                       "movw", "\t$Rd, $imm", []>,
2674                       RegConstraint<"$false = $Rd"> {
2675   let Inst{31-27} = 0b11110;
2676   let Inst{25} = 1;
2677   let Inst{24-21} = 0b0010;
2678   let Inst{20} = 0; // The S bit.
2679   let Inst{15} = 0;
2680
2681   bits<4> Rd;
2682   bits<16> imm;
2683
2684   let Inst{11-8}  = Rd;
2685   let Inst{19-16} = imm{15-12};
2686   let Inst{26}    = imm{11};
2687   let Inst{14-12} = imm{10-8};
2688   let Inst{7-0}   = imm{7-0};
2689 }
2690
2691 let isMoveImm = 1 in
2692 def t2MOVCCi32imm : PseudoInst<(outs rGPR:$dst),
2693                                (ins rGPR:$false, i32imm:$src, pred:$p),
2694                     IIC_iCMOVix2, []>, RegConstraint<"$false = $dst">;
2695
2696 let isMoveImm = 1 in
2697 def t2MVNCCi : T2OneRegImm<(outs rGPR:$Rd), (ins rGPR:$false, t2_so_imm:$imm),
2698                    IIC_iCMOVi, "mvn", ".w\t$Rd, $imm",
2699 [/*(set rGPR:$Rd,(ARMcmov rGPR:$false,t2_so_imm_not:$imm,
2700                    imm:$cc, CCR:$ccr))*/]>,
2701                    RegConstraint<"$false = $Rd"> {
2702   let Inst{31-27} = 0b11110;
2703   let Inst{25} = 0;
2704   let Inst{24-21} = 0b0011;
2705   let Inst{20} = 0; // The S bit.
2706   let Inst{19-16} = 0b1111; // Rn
2707   let Inst{15} = 0;
2708 }
2709
2710 class T2I_movcc_sh<bits<2> opcod, dag oops, dag iops, InstrItinClass itin,
2711                    string opc, string asm, list<dag> pattern>
2712   : T2TwoRegShiftImm<oops, iops, itin, opc, asm, pattern> {
2713   let Inst{31-27} = 0b11101;
2714   let Inst{26-25} = 0b01;
2715   let Inst{24-21} = 0b0010;
2716   let Inst{20} = 0; // The S bit.
2717   let Inst{19-16} = 0b1111; // Rn
2718   let Inst{5-4} = opcod; // Shift type.
2719 }
2720 def t2MOVCClsl : T2I_movcc_sh<0b00, (outs rGPR:$Rd),
2721                              (ins rGPR:$false, rGPR:$Rm, i32imm:$imm),
2722                              IIC_iCMOVsi, "lsl", ".w\t$Rd, $Rm, $imm", []>,
2723                  RegConstraint<"$false = $Rd">;
2724 def t2MOVCClsr : T2I_movcc_sh<0b01, (outs rGPR:$Rd),
2725                              (ins rGPR:$false, rGPR:$Rm, i32imm:$imm),
2726                              IIC_iCMOVsi, "lsr", ".w\t$Rd, $Rm, $imm", []>,
2727                  RegConstraint<"$false = $Rd">;
2728 def t2MOVCCasr : T2I_movcc_sh<0b10, (outs rGPR:$Rd),
2729                              (ins rGPR:$false, rGPR:$Rm, i32imm:$imm),
2730                              IIC_iCMOVsi, "asr", ".w\t$Rd, $Rm, $imm", []>,
2731                  RegConstraint<"$false = $Rd">;
2732 def t2MOVCCror : T2I_movcc_sh<0b11, (outs rGPR:$Rd),
2733                              (ins rGPR:$false, rGPR:$Rm, i32imm:$imm),
2734                              IIC_iCMOVsi, "ror", ".w\t$Rd, $Rm, $imm", []>,
2735                  RegConstraint<"$false = $Rd">;
2736 } // isCodeGenOnly = 1
2737 } // neverHasSideEffects
2738
2739 //===----------------------------------------------------------------------===//
2740 // Atomic operations intrinsics
2741 //
2742
2743 // memory barriers protect the atomic sequences
2744 let hasSideEffects = 1 in {
2745 def t2DMB : AInoP<(outs), (ins memb_opt:$opt), ThumbFrm, NoItinerary,
2746                   "dmb", "\t$opt", [(ARMMemBarrier (i32 imm:$opt))]>,
2747                   Requires<[IsThumb, HasDB]> {
2748   bits<4> opt;
2749   let Inst{31-4} = 0xf3bf8f5;
2750   let Inst{3-0} = opt;
2751 }
2752 }
2753
2754 def t2DSB : AInoP<(outs), (ins memb_opt:$opt), ThumbFrm, NoItinerary,
2755                   "dsb", "\t$opt",
2756                   [/* For disassembly only; pattern left blank */]>,
2757                   Requires<[IsThumb, HasDB]> {
2758   bits<4> opt;
2759   let Inst{31-4} = 0xf3bf8f4;
2760   let Inst{3-0} = opt;
2761 }
2762
2763 // ISB has only full system option -- for disassembly only
2764 def t2ISB : AInoP<(outs), (ins), ThumbFrm, NoItinerary, "isb", "",
2765                   [/* For disassembly only; pattern left blank */]>,
2766                   Requires<[IsThumb2, HasV7]> {
2767   let Inst{31-4} = 0xf3bf8f6;
2768   let Inst{3-0} = 0b1111;
2769 }
2770
2771 class T2I_ldrex<bits<2> opcod, dag oops, dag iops, AddrMode am, int sz,
2772                 InstrItinClass itin, string opc, string asm, string cstr,
2773                 list<dag> pattern, bits<4> rt2 = 0b1111>
2774   : Thumb2I<oops, iops, am, sz, itin, opc, asm, cstr, pattern> {
2775   let Inst{31-27} = 0b11101;
2776   let Inst{26-20} = 0b0001101;
2777   let Inst{11-8} = rt2;
2778   let Inst{7-6} = 0b01;
2779   let Inst{5-4} = opcod;
2780   let Inst{3-0} = 0b1111;
2781
2782   bits<4> addr;
2783   bits<4> Rt;
2784   let Inst{19-16} = addr;
2785   let Inst{15-12} = Rt;
2786 }
2787 class T2I_strex<bits<2> opcod, dag oops, dag iops, AddrMode am, int sz,
2788                 InstrItinClass itin, string opc, string asm, string cstr,
2789                 list<dag> pattern, bits<4> rt2 = 0b1111>
2790   : Thumb2I<oops, iops, am, sz, itin, opc, asm, cstr, pattern> {
2791   let Inst{31-27} = 0b11101;
2792   let Inst{26-20} = 0b0001100;
2793   let Inst{11-8} = rt2;
2794   let Inst{7-6} = 0b01;
2795   let Inst{5-4} = opcod;
2796
2797   bits<4> Rd;
2798   bits<4> addr;
2799   bits<4> Rt;
2800   let Inst{3-0}  = Rd;
2801   let Inst{19-16} = addr;
2802   let Inst{15-12} = Rt;
2803 }
2804
2805 let mayLoad = 1 in {
2806 def t2LDREXB : T2I_ldrex<0b00, (outs rGPR:$Rt), (ins t2addrmode_reg:$addr),
2807                          AddrModeNone, 4, NoItinerary,
2808                          "ldrexb", "\t$Rt, $addr", "", []>;
2809 def t2LDREXH : T2I_ldrex<0b01, (outs rGPR:$Rt), (ins t2addrmode_reg:$addr),
2810                          AddrModeNone, 4, NoItinerary,
2811                          "ldrexh", "\t$Rt, $addr", "", []>;
2812 def t2LDREX  : Thumb2I<(outs rGPR:$Rt), (ins t2addrmode_reg:$addr),
2813                        AddrModeNone, 4, NoItinerary,
2814                        "ldrex", "\t$Rt, $addr", "", []> {
2815   let Inst{31-27} = 0b11101;
2816   let Inst{26-20} = 0b0000101;
2817   let Inst{11-8} = 0b1111;
2818   let Inst{7-0} = 0b00000000; // imm8 = 0
2819
2820   bits<4> Rt;
2821   bits<4> addr;
2822   let Inst{19-16} = addr;
2823   let Inst{15-12} = Rt;
2824 }
2825 let hasExtraDefRegAllocReq = 1 in
2826 def t2LDREXD : T2I_ldrex<0b11, (outs rGPR:$Rt, rGPR:$Rt2),
2827                          (ins t2addrmode_reg:$addr),
2828                          AddrModeNone, 4, NoItinerary,
2829                          "ldrexd", "\t$Rt, $Rt2, $addr", "",
2830                          [], {?, ?, ?, ?}> {
2831   bits<4> Rt2;
2832   let Inst{11-8} = Rt2;
2833 }
2834 }
2835
2836 let mayStore = 1, Constraints = "@earlyclobber $Rd" in {
2837 def t2STREXB : T2I_strex<0b00, (outs rGPR:$Rd),
2838                          (ins rGPR:$Rt, t2addrmode_reg:$addr),
2839                          AddrModeNone, 4, NoItinerary,
2840                          "strexb", "\t$Rd, $Rt, $addr", "", []>;
2841 def t2STREXH : T2I_strex<0b01, (outs rGPR:$Rd),
2842                          (ins rGPR:$Rt, t2addrmode_reg:$addr),
2843                          AddrModeNone, 4, NoItinerary,
2844                          "strexh", "\t$Rd, $Rt, $addr", "", []>;
2845 def t2STREX  : Thumb2I<(outs rGPR:$Rd), (ins rGPR:$Rt, t2addrmode_reg:$addr),
2846                   AddrModeNone, 4, NoItinerary,
2847                   "strex", "\t$Rd, $Rt, $addr", "",
2848                   []> {
2849   let Inst{31-27} = 0b11101;
2850   let Inst{26-20} = 0b0000100;
2851   let Inst{7-0} = 0b00000000; // imm8 = 0
2852
2853   bits<4> Rd;
2854   bits<4> addr;
2855   bits<4> Rt;
2856   let Inst{11-8}  = Rd;
2857   let Inst{19-16} = addr;
2858   let Inst{15-12} = Rt;
2859 }
2860 }
2861
2862 let hasExtraSrcRegAllocReq = 1, Constraints = "@earlyclobber $Rd" in
2863 def t2STREXD : T2I_strex<0b11, (outs rGPR:$Rd),
2864                          (ins rGPR:$Rt, rGPR:$Rt2, t2addrmode_reg:$addr),
2865                          AddrModeNone, 4, NoItinerary,
2866                          "strexd", "\t$Rd, $Rt, $Rt2, $addr", "", [],
2867                          {?, ?, ?, ?}> {
2868   bits<4> Rt2;
2869   let Inst{11-8} = Rt2;
2870 }
2871
2872 // Clear-Exclusive is for disassembly only.
2873 def t2CLREX : T2XI<(outs), (ins), NoItinerary, "clrex",
2874                    [/* For disassembly only; pattern left blank */]>,
2875             Requires<[IsThumb2, HasV7]>  {
2876   let Inst{31-16} = 0xf3bf;
2877   let Inst{15-14} = 0b10;
2878   let Inst{13} = 0;
2879   let Inst{12} = 0;
2880   let Inst{11-8} = 0b1111;
2881   let Inst{7-4} = 0b0010;
2882   let Inst{3-0} = 0b1111;
2883 }
2884
2885 //===----------------------------------------------------------------------===//
2886 // SJLJ Exception handling intrinsics
2887 //   eh_sjlj_setjmp() is an instruction sequence to store the return
2888 //   address and save #0 in R0 for the non-longjmp case.
2889 //   Since by its nature we may be coming from some other function to get
2890 //   here, and we're using the stack frame for the containing function to
2891 //   save/restore registers, we can't keep anything live in regs across
2892 //   the eh_sjlj_setjmp(), else it will almost certainly have been tromped upon
2893 //   when we get here from a longjmp(). We force everything out of registers
2894 //   except for our own input by listing the relevant registers in Defs. By
2895 //   doing so, we also cause the prologue/epilogue code to actively preserve
2896 //   all of the callee-saved resgisters, which is exactly what we want.
2897 //   $val is a scratch register for our use.
2898 let Defs =
2899   [ R0,  R1,  R2,  R3,  R4,  R5,  R6,  R7,  R8,  R9,  R10, R11, R12, LR, CPSR,
2900     QQQQ0, QQQQ1, QQQQ2, QQQQ3 ],
2901   hasSideEffects = 1, isBarrier = 1, isCodeGenOnly = 1 in {
2902   def t2Int_eh_sjlj_setjmp : Thumb2XI<(outs), (ins tGPR:$src, tGPR:$val),
2903                                AddrModeNone, 0, NoItinerary, "", "",
2904                           [(set R0, (ARMeh_sjlj_setjmp tGPR:$src, tGPR:$val))]>,
2905                              Requires<[IsThumb2, HasVFP2]>;
2906 }
2907
2908 let Defs =
2909   [ R0,  R1,  R2,  R3,  R4,  R5,  R6,  R7,  R8,  R9,  R10, R11, R12, LR, CPSR ],
2910   hasSideEffects = 1, isBarrier = 1, isCodeGenOnly = 1 in {
2911   def t2Int_eh_sjlj_setjmp_nofp : Thumb2XI<(outs), (ins tGPR:$src, tGPR:$val),
2912                                AddrModeNone, 0, NoItinerary, "", "",
2913                           [(set R0, (ARMeh_sjlj_setjmp tGPR:$src, tGPR:$val))]>,
2914                                   Requires<[IsThumb2, NoVFP]>;
2915 }
2916
2917
2918 //===----------------------------------------------------------------------===//
2919 // Control-Flow Instructions
2920 //
2921
2922 // FIXME: remove when we have a way to marking a MI with these properties.
2923 // FIXME: Should pc be an implicit operand like PICADD, etc?
2924 let isReturn = 1, isTerminator = 1, isBarrier = 1, mayLoad = 1,
2925     hasExtraDefRegAllocReq = 1, isCodeGenOnly = 1 in
2926 def t2LDMIA_RET: t2PseudoExpand<(outs GPR:$wb), (ins GPR:$Rn, pred:$p,
2927                                                    reglist:$regs, variable_ops),
2928                               4, IIC_iLoad_mBr, [],
2929             (t2LDMIA_UPD GPR:$wb, GPR:$Rn, pred:$p, reglist:$regs)>,
2930                          RegConstraint<"$Rn = $wb">;
2931
2932 let isBranch = 1, isTerminator = 1, isBarrier = 1 in {
2933 let isPredicable = 1 in
2934 def t2B   : T2XI<(outs), (ins uncondbrtarget:$target), IIC_Br,
2935                  "b.w\t$target",
2936                  [(br bb:$target)]> {
2937   let Inst{31-27} = 0b11110;
2938   let Inst{15-14} = 0b10;
2939   let Inst{12} = 1;
2940
2941   bits<20> target;
2942   let Inst{26} = target{19};
2943   let Inst{11} = target{18};
2944   let Inst{13} = target{17};
2945   let Inst{21-16} = target{16-11};
2946   let Inst{10-0} = target{10-0};
2947 }
2948
2949 let isNotDuplicable = 1, isIndirectBranch = 1 in {
2950 def t2BR_JT : t2PseudoInst<(outs),
2951           (ins GPR:$target, GPR:$index, i32imm:$jt, i32imm:$id),
2952            0, IIC_Br,
2953           [(ARMbr2jt GPR:$target, GPR:$index, tjumptable:$jt, imm:$id)]>;
2954
2955 // FIXME: Add a non-pc based case that can be predicated.
2956 def t2TBB_JT : t2PseudoInst<(outs),
2957         (ins GPR:$index, i32imm:$jt, i32imm:$id),
2958          0, IIC_Br, []>;
2959
2960 def t2TBH_JT : t2PseudoInst<(outs),
2961         (ins GPR:$index, i32imm:$jt, i32imm:$id),
2962          0, IIC_Br, []>;
2963
2964 def t2TBB : T2I<(outs), (ins GPR:$Rn, GPR:$Rm), IIC_Br,
2965                     "tbb", "\t[$Rn, $Rm]", []> {
2966   bits<4> Rn;
2967   bits<4> Rm;
2968   let Inst{31-20} = 0b111010001101;
2969   let Inst{19-16} = Rn;
2970   let Inst{15-5} = 0b11110000000;
2971   let Inst{4} = 0; // B form
2972   let Inst{3-0} = Rm;
2973 }
2974
2975 def t2TBH : T2I<(outs), (ins GPR:$Rn, GPR:$Rm), IIC_Br,
2976                    "tbh", "\t[$Rn, $Rm, lsl #1]", []> {
2977   bits<4> Rn;
2978   bits<4> Rm;
2979   let Inst{31-20} = 0b111010001101;
2980   let Inst{19-16} = Rn;
2981   let Inst{15-5} = 0b11110000000;
2982   let Inst{4} = 1; // H form
2983   let Inst{3-0} = Rm;
2984 }
2985 } // isNotDuplicable, isIndirectBranch
2986
2987 } // isBranch, isTerminator, isBarrier
2988
2989 // FIXME: should be able to write a pattern for ARMBrcond, but can't use
2990 // a two-value operand where a dag node expects two operands. :(
2991 let isBranch = 1, isTerminator = 1 in
2992 def t2Bcc : T2I<(outs), (ins brtarget:$target), IIC_Br,
2993                 "b", ".w\t$target",
2994                 [/*(ARMbrcond bb:$target, imm:$cc)*/]> {
2995   let Inst{31-27} = 0b11110;
2996   let Inst{15-14} = 0b10;
2997   let Inst{12} = 0;
2998
2999   bits<4> p;
3000   let Inst{25-22} = p;
3001
3002   bits<21> target;
3003   let Inst{26} = target{20};
3004   let Inst{11} = target{19};
3005   let Inst{13} = target{18};
3006   let Inst{21-16} = target{17-12};
3007   let Inst{10-0} = target{11-1};
3008
3009   let DecoderMethod = "DecodeThumb2BCCInstruction";
3010 }
3011
3012 // Tail calls. The Darwin version of thumb tail calls uses a t2 branch, so
3013 // it goes here.
3014 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1 in {
3015   // Darwin version.
3016   let Defs = [R0, R1, R2, R3, R9, R12, QQQQ0, QQQQ2, QQQQ3, PC],
3017       Uses = [SP] in
3018   def tTAILJMPd: tPseudoExpand<(outs), (ins uncondbrtarget:$dst, variable_ops),
3019                    4, IIC_Br, [],
3020                    (t2B uncondbrtarget:$dst)>,
3021                  Requires<[IsThumb2, IsDarwin]>;
3022 }
3023
3024 // IT block
3025 let Defs = [ITSTATE] in
3026 def t2IT : Thumb2XI<(outs), (ins it_pred:$cc, it_mask:$mask),
3027                     AddrModeNone, 2,  IIC_iALUx,
3028                     "it$mask\t$cc", "", []> {
3029   // 16-bit instruction.
3030   let Inst{31-16} = 0x0000;
3031   let Inst{15-8} = 0b10111111;
3032
3033   bits<4> cc;
3034   bits<4> mask;
3035   let Inst{7-4} = cc;
3036   let Inst{3-0} = mask;
3037 }
3038
3039 // Branch and Exchange Jazelle -- for disassembly only
3040 // Rm = Inst{19-16}
3041 def t2BXJ : T2I<(outs), (ins rGPR:$func), NoItinerary, "bxj", "\t$func",
3042               [/* For disassembly only; pattern left blank */]> {
3043   let Inst{31-27} = 0b11110;
3044   let Inst{26} = 0;
3045   let Inst{25-20} = 0b111100;
3046   let Inst{15-14} = 0b10;
3047   let Inst{12} = 0;
3048
3049   bits<4> func;
3050   let Inst{19-16} = func;
3051 }
3052
3053 // Change Processor State is a system instruction -- for disassembly and
3054 // parsing only.
3055 // FIXME: Since the asm parser has currently no clean way to handle optional
3056 // operands, create 3 versions of the same instruction. Once there's a clean
3057 // framework to represent optional operands, change this behavior.
3058 class t2CPS<dag iops, string asm_op> : T2XI<(outs), iops, NoItinerary,
3059             !strconcat("cps", asm_op),
3060             [/* For disassembly only; pattern left blank */]> {
3061   bits<2> imod;
3062   bits<3> iflags;
3063   bits<5> mode;
3064   bit M;
3065
3066   let Inst{31-27} = 0b11110;
3067   let Inst{26}    = 0;
3068   let Inst{25-20} = 0b111010;
3069   let Inst{19-16} = 0b1111;
3070   let Inst{15-14} = 0b10;
3071   let Inst{12}    = 0;
3072   let Inst{10-9}  = imod;
3073   let Inst{8}     = M;
3074   let Inst{7-5}   = iflags;
3075   let Inst{4-0}   = mode;
3076 }
3077
3078 let M = 1 in
3079   def t2CPS3p : t2CPS<(ins imod_op:$imod, iflags_op:$iflags, i32imm:$mode),
3080                       "$imod.w\t$iflags, $mode">;
3081 let mode = 0, M = 0 in
3082   def t2CPS2p : t2CPS<(ins imod_op:$imod, iflags_op:$iflags),
3083                       "$imod.w\t$iflags">;
3084 let imod = 0, iflags = 0, M = 1 in
3085   def t2CPS1p : t2CPS<(ins i32imm:$mode), "\t$mode">;
3086
3087 // A6.3.4 Branches and miscellaneous control
3088 // Table A6-14 Change Processor State, and hint instructions
3089 // Helper class for disassembly only.
3090 class T2I_hint<bits<8> op7_0, string opc, string asm>
3091   : T2I<(outs), (ins), NoItinerary, opc, asm,
3092         [/* For disassembly only; pattern left blank */]> {
3093   let Inst{31-20} = 0xf3a;
3094   let Inst{19-16} = 0b1111;
3095   let Inst{15-14} = 0b10;
3096   let Inst{12} = 0;
3097   let Inst{10-8} = 0b000;
3098   let Inst{7-0} = op7_0;
3099 }
3100
3101 def t2NOP   : T2I_hint<0b00000000, "nop",   ".w">;
3102 def t2YIELD : T2I_hint<0b00000001, "yield", ".w">;
3103 def t2WFE   : T2I_hint<0b00000010, "wfe",   ".w">;
3104 def t2WFI   : T2I_hint<0b00000011, "wfi",   ".w">;
3105 def t2SEV   : T2I_hint<0b00000100, "sev",   ".w">;
3106
3107 def t2DBG : T2I<(outs), (ins imm0_15:$opt), NoItinerary, "dbg", "\t$opt", []> {
3108   let Inst{31-20} = 0xf3a;
3109   let Inst{15-14} = 0b10;
3110   let Inst{12} = 0;
3111   let Inst{10-8} = 0b000;
3112   let Inst{7-4} = 0b1111;
3113
3114   bits<4> opt;
3115   let Inst{3-0} = opt;
3116 }
3117
3118 // Secure Monitor Call is a system instruction -- for disassembly only
3119 // Option = Inst{19-16}
3120 def t2SMC : T2I<(outs), (ins imm0_15:$opt), NoItinerary, "smc", "\t$opt",
3121                 [/* For disassembly only; pattern left blank */]> {
3122   let Inst{31-27} = 0b11110;
3123   let Inst{26-20} = 0b1111111;
3124   let Inst{15-12} = 0b1000;
3125
3126   bits<4> opt;
3127   let Inst{19-16} = opt;
3128 }
3129
3130 class T2SRS<bits<12> op31_20,
3131            dag oops, dag iops, InstrItinClass itin,
3132           string opc, string asm, list<dag> pattern>
3133   : T2I<oops, iops, itin, opc, asm, pattern> {
3134   let Inst{31-20} = op31_20{11-0};
3135
3136   bits<5> mode;
3137   let Inst{4-0} = mode{4-0};
3138 }
3139
3140 // Store Return State is a system instruction -- for disassembly only
3141 def t2SRSDBW : T2SRS<0b111010000010,
3142                    (outs),(ins i32imm:$mode),NoItinerary,"srsdb","\tsp!, $mode",
3143                    [/* For disassembly only; pattern left blank */]>;
3144 def t2SRSDB  : T2SRS<0b111010000000,
3145                    (outs),(ins i32imm:$mode),NoItinerary,"srsdb","\tsp, $mode",
3146                    [/* For disassembly only; pattern left blank */]>;
3147 def t2SRSIAW : T2SRS<0b111010011010,
3148                    (outs),(ins i32imm:$mode),NoItinerary,"srsia","\tsp!, $mode",
3149                    [/* For disassembly only; pattern left blank */]>;
3150 def t2SRSIA  : T2SRS<0b111010011000,
3151                    (outs), (ins i32imm:$mode),NoItinerary,"srsia","\tsp, $mode",
3152                    [/* For disassembly only; pattern left blank */]>;
3153
3154 // Return From Exception is a system instruction -- for disassembly only
3155
3156 class T2RFE<bits<12> op31_20, dag oops, dag iops, InstrItinClass itin,
3157           string opc, string asm, list<dag> pattern>
3158   : T2I<oops, iops, itin, opc, asm, pattern> {
3159   let Inst{31-20} = op31_20{11-0};
3160
3161   bits<4> Rn;
3162   let Inst{19-16} = Rn;
3163   let Inst{15-0} = 0xc000;
3164 }
3165
3166 def t2RFEDBW : T2RFE<0b111010000011,
3167                    (outs), (ins GPR:$Rn), NoItinerary, "rfedb", "\t$Rn!",
3168                    [/* For disassembly only; pattern left blank */]>;
3169 def t2RFEDB  : T2RFE<0b111010000001,
3170                    (outs), (ins GPR:$Rn), NoItinerary, "rfedb", "\t$Rn",
3171                    [/* For disassembly only; pattern left blank */]>;
3172 def t2RFEIAW : T2RFE<0b111010011011,
3173                    (outs), (ins GPR:$Rn), NoItinerary, "rfeia", "\t$Rn!",
3174                    [/* For disassembly only; pattern left blank */]>;
3175 def t2RFEIA  : T2RFE<0b111010011001,
3176                    (outs), (ins GPR:$Rn), NoItinerary, "rfeia", "\t$Rn",
3177                    [/* For disassembly only; pattern left blank */]>;
3178
3179 //===----------------------------------------------------------------------===//
3180 // Non-Instruction Patterns
3181 //
3182
3183 // 32-bit immediate using movw + movt.
3184 // This is a single pseudo instruction to make it re-materializable.
3185 // FIXME: Remove this when we can do generalized remat.
3186 let isReMaterializable = 1, isMoveImm = 1 in
3187 def t2MOVi32imm : PseudoInst<(outs rGPR:$dst), (ins i32imm:$src), IIC_iMOVix2,
3188                             [(set rGPR:$dst, (i32 imm:$src))]>,
3189                             Requires<[IsThumb, HasV6T2]>;
3190
3191 // Pseudo instruction that combines movw + movt + add pc (if pic).
3192 // It also makes it possible to rematerialize the instructions.
3193 // FIXME: Remove this when we can do generalized remat and when machine licm
3194 // can properly the instructions.
3195 let isReMaterializable = 1 in {
3196 def t2MOV_ga_pcrel : PseudoInst<(outs rGPR:$dst), (ins i32imm:$addr),
3197                                 IIC_iMOVix2addpc,
3198                           [(set rGPR:$dst, (ARMWrapperPIC tglobaladdr:$addr))]>,
3199                           Requires<[IsThumb2, UseMovt]>;
3200
3201 def t2MOV_ga_dyn : PseudoInst<(outs rGPR:$dst), (ins i32imm:$addr),
3202                               IIC_iMOVix2,
3203                           [(set rGPR:$dst, (ARMWrapperDYN tglobaladdr:$addr))]>,
3204                           Requires<[IsThumb2, UseMovt]>;
3205 }
3206
3207 // ConstantPool, GlobalAddress, and JumpTable
3208 def : T2Pat<(ARMWrapper  tglobaladdr :$dst), (t2LEApcrel tglobaladdr :$dst)>,
3209            Requires<[IsThumb2, DontUseMovt]>;
3210 def : T2Pat<(ARMWrapper  tconstpool  :$dst), (t2LEApcrel tconstpool  :$dst)>;
3211 def : T2Pat<(ARMWrapper  tglobaladdr :$dst), (t2MOVi32imm tglobaladdr :$dst)>,
3212            Requires<[IsThumb2, UseMovt]>;
3213
3214 def : T2Pat<(ARMWrapperJT tjumptable:$dst, imm:$id),
3215             (t2LEApcrelJT tjumptable:$dst, imm:$id)>;
3216
3217 // Pseudo instruction that combines ldr from constpool and add pc. This should
3218 // be expanded into two instructions late to allow if-conversion and
3219 // scheduling.
3220 let canFoldAsLoad = 1, isReMaterializable = 1 in
3221 def t2LDRpci_pic : PseudoInst<(outs rGPR:$dst), (ins i32imm:$addr, pclabel:$cp),
3222                    IIC_iLoadiALU,
3223               [(set rGPR:$dst, (ARMpic_add (load (ARMWrapper tconstpool:$addr)),
3224                                            imm:$cp))]>,
3225                Requires<[IsThumb2]>;
3226
3227 //===----------------------------------------------------------------------===//
3228 // Move between special register and ARM core register -- for disassembly only
3229 //
3230
3231 class T2SpecialReg<bits<12> op31_20, bits<2> op15_14, bits<1> op12,
3232           dag oops, dag iops, InstrItinClass itin,
3233           string opc, string asm, list<dag> pattern>
3234   : T2I<oops, iops, itin, opc, asm, pattern> {
3235   let Inst{31-20} = op31_20{11-0};
3236   let Inst{15-14} = op15_14{1-0};
3237   let Inst{12} = op12{0};
3238 }
3239
3240 class T2MRS<bits<12> op31_20, bits<2> op15_14, bits<1> op12,
3241           dag oops, dag iops, InstrItinClass itin,
3242           string opc, string asm, list<dag> pattern>
3243   : T2SpecialReg<op31_20, op15_14, op12, oops, iops, itin, opc, asm, pattern> {
3244   bits<4> Rd;
3245   let Inst{11-8} = Rd;
3246   let Inst{19-16} = 0b1111;
3247 }
3248
3249 def t2MRS : T2MRS<0b111100111110, 0b10, 0,
3250                 (outs rGPR:$Rd), (ins), NoItinerary, "mrs", "\t$Rd, cpsr",
3251                 [/* For disassembly only; pattern left blank */]>;
3252 def t2MRSsys : T2MRS<0b111100111111, 0b10, 0,
3253                    (outs rGPR:$Rd), (ins), NoItinerary, "mrs", "\t$Rd, spsr",
3254                    [/* For disassembly only; pattern left blank */]>;
3255
3256 // Move from ARM core register to Special Register
3257 //
3258 // No need to have both system and application versions, the encodings are the
3259 // same and the assembly parser has no way to distinguish between them. The mask
3260 // operand contains the special register (R Bit) in bit 4 and bits 3-0 contains
3261 // the mask with the fields to be accessed in the special register.
3262 def t2MSR : T2SpecialReg<0b111100111000 /* op31-20 */, 0b10 /* op15-14 */,
3263                          0 /* op12 */, (outs), (ins msr_mask:$mask, rGPR:$Rn),
3264                          NoItinerary, "msr", "\t$mask, $Rn",
3265                          [/* For disassembly only; pattern left blank */]> {
3266   bits<5> mask;
3267   bits<4> Rn;
3268   let Inst{19-16} = Rn;
3269   let Inst{20}    = mask{4}; // R Bit
3270   let Inst{13}    = 0b0;
3271   let Inst{11-8}  = mask{3-0};
3272 }
3273
3274 //===----------------------------------------------------------------------===//
3275 // Move between coprocessor and ARM core register
3276 //
3277
3278 class t2MovRCopro<bits<4> Op, string opc, bit direction, dag oops, dag iops,
3279                   list<dag> pattern>
3280   : T2Cop<Op, oops, iops,
3281           !strconcat(opc, "\t$cop, $opc1, $Rt, $CRn, $CRm, $opc2"),
3282           pattern> {
3283   let Inst{27-24} = 0b1110;
3284   let Inst{20} = direction;
3285   let Inst{4} = 1;
3286
3287   bits<4> Rt;
3288   bits<4> cop;
3289   bits<3> opc1;
3290   bits<3> opc2;
3291   bits<4> CRm;
3292   bits<4> CRn;
3293
3294   let Inst{15-12} = Rt;
3295   let Inst{11-8}  = cop;
3296   let Inst{23-21} = opc1;
3297   let Inst{7-5}   = opc2;
3298   let Inst{3-0}   = CRm;
3299   let Inst{19-16} = CRn;
3300 }
3301
3302 class t2MovRRCopro<bits<4> Op, string opc, bit direction,
3303                    list<dag> pattern = []>
3304   : T2Cop<Op, (outs),
3305           (ins p_imm:$cop, imm0_15:$opc1, GPR:$Rt, GPR:$Rt2, c_imm:$CRm),
3306           !strconcat(opc, "\t$cop, $opc1, $Rt, $Rt2, $CRm"), pattern> {
3307   let Inst{27-24} = 0b1100;
3308   let Inst{23-21} = 0b010;
3309   let Inst{20} = direction;
3310
3311   bits<4> Rt;
3312   bits<4> Rt2;
3313   bits<4> cop;
3314   bits<4> opc1;
3315   bits<4> CRm;
3316
3317   let Inst{15-12} = Rt;
3318   let Inst{19-16} = Rt2;
3319   let Inst{11-8}  = cop;
3320   let Inst{7-4}   = opc1;
3321   let Inst{3-0}   = CRm;
3322 }
3323
3324 /* from ARM core register to coprocessor */
3325 def t2MCR : t2MovRCopro<0b1110, "mcr", 0,
3326            (outs),
3327            (ins p_imm:$cop, imm0_7:$opc1, GPR:$Rt, c_imm:$CRn,
3328                 c_imm:$CRm, imm0_7:$opc2),
3329            [(int_arm_mcr imm:$cop, imm:$opc1, GPR:$Rt, imm:$CRn,
3330                          imm:$CRm, imm:$opc2)]>;
3331 def t2MCR2 : t2MovRCopro<0b1111, "mcr2", 0,
3332              (outs), (ins p_imm:$cop, imm0_7:$opc1, GPR:$Rt, c_imm:$CRn,
3333                           c_imm:$CRm, imm0_7:$opc2),
3334              [(int_arm_mcr2 imm:$cop, imm:$opc1, GPR:$Rt, imm:$CRn,
3335                             imm:$CRm, imm:$opc2)]>;
3336
3337 /* from coprocessor to ARM core register */
3338 def t2MRC : t2MovRCopro<0b1110, "mrc", 1,
3339              (outs GPR:$Rt), (ins p_imm:$cop, imm0_7:$opc1, c_imm:$CRn,
3340                                   c_imm:$CRm, imm0_7:$opc2), []>;
3341
3342 def t2MRC2 : t2MovRCopro<0b1111, "mrc2", 1,
3343              (outs GPR:$Rt), (ins p_imm:$cop, imm0_7:$opc1, c_imm:$CRn,
3344                                   c_imm:$CRm, imm0_7:$opc2), []>;
3345
3346 def : T2v6Pat<(int_arm_mrc  imm:$cop, imm:$opc1, imm:$CRn, imm:$CRm, imm:$opc2),
3347               (t2MRC imm:$cop, imm:$opc1, imm:$CRn, imm:$CRm, imm:$opc2)>;
3348
3349 def : T2v6Pat<(int_arm_mrc2 imm:$cop, imm:$opc1, imm:$CRn, imm:$CRm, imm:$opc2),
3350               (t2MRC2 imm:$cop, imm:$opc1, imm:$CRn, imm:$CRm, imm:$opc2)>;
3351
3352
3353 /* from ARM core register to coprocessor */
3354 def t2MCRR : t2MovRRCopro<0b1110, "mcrr", 0,
3355                         [(int_arm_mcrr imm:$cop, imm:$opc1, GPR:$Rt, GPR:$Rt2,
3356                                        imm:$CRm)]>;
3357 def t2MCRR2 : t2MovRRCopro<0b1111, "mcrr2", 0,
3358                            [(int_arm_mcrr2 imm:$cop, imm:$opc1, GPR:$Rt,
3359                                            GPR:$Rt2, imm:$CRm)]>;
3360 /* from coprocessor to ARM core register */
3361 def t2MRRC : t2MovRRCopro<0b1110, "mrrc", 1>;
3362
3363 def t2MRRC2 : t2MovRRCopro<0b1111, "mrrc2", 1>;
3364
3365 //===----------------------------------------------------------------------===//
3366 // Other Coprocessor Instructions.
3367 //
3368
3369 def tCDP : T2Cop<0b1110, (outs), (ins p_imm:$cop, imm0_15:$opc1,
3370                  c_imm:$CRd, c_imm:$CRn, c_imm:$CRm, imm0_7:$opc2),
3371                  "cdp\t$cop, $opc1, $CRd, $CRn, $CRm, $opc2",
3372                  [(int_arm_cdp imm:$cop, imm:$opc1, imm:$CRd, imm:$CRn,
3373                                imm:$CRm, imm:$opc2)]> {
3374   let Inst{27-24} = 0b1110;
3375
3376   bits<4> opc1;
3377   bits<4> CRn;
3378   bits<4> CRd;
3379   bits<4> cop;
3380   bits<3> opc2;
3381   bits<4> CRm;
3382
3383   let Inst{3-0}   = CRm;
3384   let Inst{4}     = 0;
3385   let Inst{7-5}   = opc2;
3386   let Inst{11-8}  = cop;
3387   let Inst{15-12} = CRd;
3388   let Inst{19-16} = CRn;
3389   let Inst{23-20} = opc1;
3390 }
3391
3392 def t2CDP2 : T2Cop<0b1111, (outs), (ins p_imm:$cop, imm0_15:$opc1,
3393                    c_imm:$CRd, c_imm:$CRn, c_imm:$CRm, imm0_7:$opc2),
3394                    "cdp2\t$cop, $opc1, $CRd, $CRn, $CRm, $opc2",
3395                    [(int_arm_cdp2 imm:$cop, imm:$opc1, imm:$CRd, imm:$CRn,
3396                                   imm:$CRm, imm:$opc2)]> {
3397   let Inst{27-24} = 0b1110;
3398
3399   bits<4> opc1;
3400   bits<4> CRn;
3401   bits<4> CRd;
3402   bits<4> cop;
3403   bits<3> opc2;
3404   bits<4> CRm;
3405
3406   let Inst{3-0}   = CRm;
3407   let Inst{4}     = 0;
3408   let Inst{7-5}   = opc2;
3409   let Inst{11-8}  = cop;
3410   let Inst{15-12} = CRd;
3411   let Inst{19-16} = CRn;
3412   let Inst{23-20} = opc1;
3413 }
3414
3415
3416
3417 //===----------------------------------------------------------------------===//
3418 // Non-Instruction Patterns
3419 //
3420
3421 // SXT/UXT with no rotate
3422 let AddedComplexity = 16 in {
3423 def : T2Pat<(and rGPR:$Rm, 0x000000FF), (t2UXTB rGPR:$Rm, 0)>,
3424            Requires<[IsThumb2]>;
3425 def : T2Pat<(and rGPR:$Rm, 0x0000FFFF), (t2UXTH rGPR:$Rm, 0)>,
3426            Requires<[IsThumb2]>;
3427 def : T2Pat<(and rGPR:$Rm, 0x00FF00FF), (t2UXTB16 rGPR:$Rm, 0)>,
3428            Requires<[HasT2ExtractPack, IsThumb2]>;
3429 def : T2Pat<(add rGPR:$Rn, (and rGPR:$Rm, 0x00FF)),
3430             (t2UXTAB rGPR:$Rn, rGPR:$Rm, 0)>,
3431            Requires<[HasT2ExtractPack, IsThumb2]>;
3432 def : T2Pat<(add rGPR:$Rn, (and rGPR:$Rm, 0xFFFF)),
3433             (t2UXTAH rGPR:$Rn, rGPR:$Rm, 0)>,
3434            Requires<[HasT2ExtractPack, IsThumb2]>;
3435 }
3436
3437 def : T2Pat<(sext_inreg rGPR:$Src, i8),  (t2SXTB rGPR:$Src, 0)>,
3438            Requires<[IsThumb2]>;
3439 def : T2Pat<(sext_inreg rGPR:$Src, i16), (t2SXTH rGPR:$Src, 0)>,
3440            Requires<[IsThumb2]>;
3441 def : T2Pat<(add rGPR:$Rn, (sext_inreg rGPR:$Rm, i8)),
3442             (t2SXTAB rGPR:$Rn, rGPR:$Rm, 0)>,
3443            Requires<[HasT2ExtractPack, IsThumb2]>;
3444 def : T2Pat<(add rGPR:$Rn, (sext_inreg rGPR:$Rm, i16)),
3445             (t2SXTAH rGPR:$Rn, rGPR:$Rm, 0)>,
3446            Requires<[HasT2ExtractPack, IsThumb2]>;