lib/Target/ARM/ARMInstrInfo.td

   1 //===- ARMInstrInfo.td - Target Description for ARM Target -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the ARM instructions in TableGen format.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // ARM specific DAG Nodes.
  16 //
  17
  18 // Type profiles.
  19 def SDT_ARMCallSeqStart : SDCallSeqStart<[ SDTCisVT<0, i32> ]>;
  20 def SDT_ARMCallSeqEnd   : SDCallSeqEnd<[ SDTCisVT<0, i32>, SDTCisVT<1, i32> ]>;
  21
  22 def SDT_ARMSaveCallPC : SDTypeProfile<0, 1, []>;
  23
  24 def SDT_ARMcall    : SDTypeProfile<0, -1, [SDTCisInt<0>]>;
  25
  26 def SDT_ARMCMov    : SDTypeProfile<1, 3,
  27                                    [SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>,
  28                                     SDTCisVT<3, i32>]>;
  29
  30 def SDT_ARMBrcond  : SDTypeProfile<0, 2,
  31                                    [SDTCisVT<0, OtherVT>, SDTCisVT<1, i32>]>;
  32
  33 def SDT_ARMBrJT    : SDTypeProfile<0, 3,
  34                                   [SDTCisPtrTy<0>, SDTCisVT<1, i32>,
  35                                    SDTCisVT<2, i32>]>;
  36
  37 def SDT_ARMBr2JT   : SDTypeProfile<0, 4,
  38                                   [SDTCisPtrTy<0>, SDTCisVT<1, i32>,
  39                                    SDTCisVT<2, i32>, SDTCisVT<3, i32>]>;
  40
  41 def SDT_ARMCmp     : SDTypeProfile<0, 2, [SDTCisSameAs<0, 1>]>;
  42
  43 def SDT_ARMPICAdd  : SDTypeProfile<1, 2, [SDTCisSameAs<0, 1>,
  44                                           SDTCisPtrTy<1>, SDTCisVT<2, i32>]>;
  45
  46 def SDT_ARMThreadPointer : SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;
  47 def SDT_ARMEH_SJLJ_Setjmp : SDTypeProfile<1, 1, [SDTCisInt<0>, SDTCisPtrTy<1>]>;
  48
  49 // Node definitions.
  50 def ARMWrapper       : SDNode<"ARMISD::Wrapper",     SDTIntUnaryOp>;
  51 def ARMWrapperJT     : SDNode<"ARMISD::WrapperJT",   SDTIntBinOp>;
  52
  53 def ARMcallseq_start : SDNode<"ISD::CALLSEQ_START", SDT_ARMCallSeqStart,
  54                               [SDNPHasChain, SDNPOutFlag]>;
  55 def ARMcallseq_end   : SDNode<"ISD::CALLSEQ_END",   SDT_ARMCallSeqEnd,
  56                               [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  57
  58 def ARMcall          : SDNode<"ARMISD::CALL", SDT_ARMcall,
  59                               [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  60 def ARMcall_pred    : SDNode<"ARMISD::CALL_PRED", SDT_ARMcall,
  61                               [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  62 def ARMcall_nolink   : SDNode<"ARMISD::CALL_NOLINK", SDT_ARMcall,
  63                               [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  64
  65 def ARMretflag       : SDNode<"ARMISD::RET_FLAG", SDTNone,
  66                               [SDNPHasChain, SDNPOptInFlag]>;
  67
  68 def ARMcmov          : SDNode<"ARMISD::CMOV", SDT_ARMCMov,
  69                               [SDNPInFlag]>;
  70 def ARMcneg          : SDNode<"ARMISD::CNEG", SDT_ARMCMov,
  71                               [SDNPInFlag]>;
  72
  73 def ARMbrcond        : SDNode<"ARMISD::BRCOND", SDT_ARMBrcond,
  74                               [SDNPHasChain, SDNPInFlag, SDNPOutFlag]>;
  75
  76 def ARMbrjt          : SDNode<"ARMISD::BR_JT", SDT_ARMBrJT,
  77                               [SDNPHasChain]>;
  78 def ARMbr2jt         : SDNode<"ARMISD::BR2_JT", SDT_ARMBr2JT,
  79                               [SDNPHasChain]>;
  80
  81 def ARMcmp           : SDNode<"ARMISD::CMP", SDT_ARMCmp,
  82                               [SDNPOutFlag]>;
  83
  84 def ARMcmpZ          : SDNode<"ARMISD::CMPZ", SDT_ARMCmp,
  85                               [SDNPOutFlag,SDNPCommutative]>;
  86
  87 def ARMpic_add       : SDNode<"ARMISD::PIC_ADD", SDT_ARMPICAdd>;
  88
  89 def ARMsrl_flag      : SDNode<"ARMISD::SRL_FLAG", SDTIntUnaryOp, [SDNPOutFlag]>;
  90 def ARMsra_flag      : SDNode<"ARMISD::SRA_FLAG", SDTIntUnaryOp, [SDNPOutFlag]>;
  91 def ARMrrx           : SDNode<"ARMISD::RRX"     , SDTIntUnaryOp, [SDNPInFlag ]>;
  92
  93 def ARMthread_pointer: SDNode<"ARMISD::THREAD_POINTER", SDT_ARMThreadPointer>;
  94 def ARMeh_sjlj_setjmp: SDNode<"ARMISD::EH_SJLJ_SETJMP", SDT_ARMEH_SJLJ_Setjmp>;
  95
  96 //===----------------------------------------------------------------------===//
  97 // ARM Instruction Predicate Definitions.
  98 //
  99 def HasV5T    : Predicate<"Subtarget->hasV5TOps()">;
 100 def HasV5TE   : Predicate<"Subtarget->hasV5TEOps()">;
 101 def HasV6     : Predicate<"Subtarget->hasV6Ops()">;
 102 def HasV6T2   : Predicate<"Subtarget->hasV6T2Ops()">;
 103 def HasV7     : Predicate<"Subtarget->hasV7Ops()">;
 104 def HasVFP2   : Predicate<"Subtarget->hasVFP2()">;
 105 def HasVFP3   : Predicate<"Subtarget->hasVFP3()">;
 106 def HasNEON   : Predicate<"Subtarget->hasNEON()">;
 107 def UseNEONForFP : Predicate<"Subtarget->useNEONForSinglePrecisionFP()">;
 108 def DontUseNEONForFP : Predicate<"!Subtarget->useNEONForSinglePrecisionFP()">;
 109 def IsThumb   : Predicate<"Subtarget->isThumb()">;
 110 def IsThumb1Only : Predicate<"Subtarget->isThumb1Only()">;
 111 def IsThumb2  : Predicate<"Subtarget->isThumb2()">;
 112 def IsARM     : Predicate<"!Subtarget->isThumb()">;
 113 def IsDarwin    : Predicate<"Subtarget->isTargetDarwin()">;
 114 def IsNotDarwin : Predicate<"!Subtarget->isTargetDarwin()">;
 115 def CarryDefIsUnused : Predicate<"!N.getNode()->hasAnyUseOfValue(1)">;
 116 def CarryDefIsUsed   : Predicate<"N.getNode()->hasAnyUseOfValue(1)">;
 117
 118 //===----------------------------------------------------------------------===//
 119 // ARM Flag Definitions.
 120
 121 class RegConstraint<string C> {
 122   string Constraints = C;
 123 }
 124
 125 //===----------------------------------------------------------------------===//
 126 //  ARM specific transformation functions and pattern fragments.
 127 //
 128
 129 // so_imm_neg_XFORM - Return a so_imm value packed into the format described for
 130 // so_imm_neg def below.
 131 def so_imm_neg_XFORM : SDNodeXForm<imm, [{
 132   return CurDAG->getTargetConstant(-(int)N->getZExtValue(), MVT::i32);
 133 }]>;
 134
 135 // so_imm_not_XFORM - Return a so_imm value packed into the format described for
 136 // so_imm_not def below.
 137 def so_imm_not_XFORM : SDNodeXForm<imm, [{
 138   return CurDAG->getTargetConstant(~(int)N->getZExtValue(), MVT::i32);
 139 }]>;
 140
 141 // rot_imm predicate - True if the 32-bit immediate is equal to 8, 16, or 24.
 142 def rot_imm : PatLeaf<(i32 imm), [{
 143   int32_t v = (int32_t)N->getZExtValue();
 144   return v == 8 || v == 16 || v == 24;
 145 }]>;
 146
 147 /// imm1_15 predicate - True if the 32-bit immediate is in the range [1,15].
 148 def imm1_15 : PatLeaf<(i32 imm), [{
 149   return (int32_t)N->getZExtValue() >= 1 && (int32_t)N->getZExtValue() < 16;
 150 }]>;
 151
 152 /// imm16_31 predicate - True if the 32-bit immediate is in the range [16,31].
 153 def imm16_31 : PatLeaf<(i32 imm), [{
 154   return (int32_t)N->getZExtValue() >= 16 && (int32_t)N->getZExtValue() < 32;
 155 }]>;
 156
 157 def so_imm_neg :
 158   PatLeaf<(imm), [{
 159     return ARM_AM::getSOImmVal(-(int)N->getZExtValue()) != -1;
 160   }], so_imm_neg_XFORM>;
 161
 162 def so_imm_not :
 163   PatLeaf<(imm), [{
 164     return ARM_AM::getSOImmVal(~(int)N->getZExtValue()) != -1;
 165   }], so_imm_not_XFORM>;
 166
 167 // sext_16_node predicate - True if the SDNode is sign-extended 16 or more bits.
 168 def sext_16_node : PatLeaf<(i32 GPR:$a), [{
 169   return CurDAG->ComputeNumSignBits(SDValue(N,0)) >= 17;
 170 }]>;
 171
 172 /// bf_inv_mask_imm predicate - An AND mask to clear an arbitrary width bitfield
 173 /// e.g., 0xf000ffff
 174 def bf_inv_mask_imm : Operand<i32>,
 175                       PatLeaf<(imm), [{
 176   uint32_t v = (uint32_t)N->getZExtValue();
 177   if (v == 0xffffffff)
 178     return 0;
 179   // there can be 1's on either or both "outsides", all the "inside"
 180   // bits must be 0's
 181   unsigned int lsb = 0, msb = 31;
 182   while (v & (1 << msb)) --msb;
 183   while (v & (1 << lsb)) ++lsb;
 184   for (unsigned int i = lsb; i <= msb; ++i) {
 185     if (v & (1 << i))
 186       return 0;
 187   }
 188   return 1;
 189 }] > {
 190   let PrintMethod = "printBitfieldInvMaskImmOperand";
 191 }
 192
 193 class BinOpFrag<dag res> : PatFrag<(ops node:$LHS, node:$RHS), res>;
 194 class UnOpFrag <dag res> : PatFrag<(ops node:$Src), res>;
 195
 196 //===----------------------------------------------------------------------===//
 197 // Operand Definitions.
 198 //
 199
 200 // Branch target.
 201 def brtarget : Operand<OtherVT>;
 202
 203 // A list of registers separated by comma. Used by load/store multiple.
 204 def reglist : Operand<i32> {
 205   let PrintMethod = "printRegisterList";
 206 }
 207
 208 // An operand for the CONSTPOOL_ENTRY pseudo-instruction.
 209 def cpinst_operand : Operand<i32> {
 210   let PrintMethod = "printCPInstOperand";
 211 }
 212
 213 def jtblock_operand : Operand<i32> {
 214   let PrintMethod = "printJTBlockOperand";
 215 }
 216 def jt2block_operand : Operand<i32> {
 217   let PrintMethod = "printJT2BlockOperand";
 218 }
 219
 220 // Local PC labels.
 221 def pclabel : Operand<i32> {
 222   let PrintMethod = "printPCLabel";
 223 }
 224
 225 // shifter_operand operands: so_reg and so_imm.
 226 def so_reg : Operand<i32>,    // reg reg imm
 227             ComplexPattern<i32, 3, "SelectShifterOperandReg",
 228                             [shl,srl,sra,rotr]> {
 229   let PrintMethod = "printSORegOperand";
 230   let MIOperandInfo = (ops GPR, GPR, i32imm);
 231 }
 232
 233 // so_imm - Match a 32-bit shifter_operand immediate operand, which is an
 234 // 8-bit immediate rotated by an arbitrary number of bits.  so_imm values are
 235 // represented in the imm field in the same 12-bit form that they are encoded
 236 // into so_imm instructions: the 8-bit immediate is the least significant bits
 237 // [bits 0-7], the 4-bit shift amount is the next 4 bits [bits 8-11].
 238 def so_imm : Operand<i32>,
 239              PatLeaf<(imm), [{
 240       return ARM_AM::getSOImmVal(N->getZExtValue()) != -1;
 241     }]> {
 242   let PrintMethod = "printSOImmOperand";
 243 }
 244
 245 // Break so_imm's up into two pieces.  This handles immediates with up to 16
 246 // bits set in them.  This uses so_imm2part to match and so_imm2part_[12] to
 247 // get the first/second pieces.
 248 def so_imm2part : Operand<i32>,
 249                   PatLeaf<(imm), [{
 250       return ARM_AM::isSOImmTwoPartVal((unsigned)N->getZExtValue());
 251     }]> {
 252   let PrintMethod = "printSOImm2PartOperand";
 253 }
 254
 255 def so_imm2part_1 : SDNodeXForm<imm, [{
 256   unsigned V = ARM_AM::getSOImmTwoPartFirst((unsigned)N->getZExtValue());
 257   return CurDAG->getTargetConstant(V, MVT::i32);
 258 }]>;
 259
 260 def so_imm2part_2 : SDNodeXForm<imm, [{
 261   unsigned V = ARM_AM::getSOImmTwoPartSecond((unsigned)N->getZExtValue());
 262   return CurDAG->getTargetConstant(V, MVT::i32);
 263 }]>;
 264
 265
 266 // Define ARM specific addressing modes.
 267
 268 // addrmode2 := reg +/- reg shop imm
 269 // addrmode2 := reg +/- imm12
 270 //
 271 def addrmode2 : Operand<i32>,
 272                 ComplexPattern<i32, 3, "SelectAddrMode2", []> {
 273   let PrintMethod = "printAddrMode2Operand";
 274   let MIOperandInfo = (ops GPR:$base, GPR:$offsreg, i32imm:$offsimm);
 275 }
 276
 277 def am2offset : Operand<i32>,
 278                 ComplexPattern<i32, 2, "SelectAddrMode2Offset", []> {
 279   let PrintMethod = "printAddrMode2OffsetOperand";
 280   let MIOperandInfo = (ops GPR, i32imm);
 281 }
 282
 283 // addrmode3 := reg +/- reg
 284 // addrmode3 := reg +/- imm8
 285 //
 286 def addrmode3 : Operand<i32>,
 287                 ComplexPattern<i32, 3, "SelectAddrMode3", []> {
 288   let PrintMethod = "printAddrMode3Operand";
 289   let MIOperandInfo = (ops GPR:$base, GPR:$offsreg, i32imm:$offsimm);
 290 }
 291
 292 def am3offset : Operand<i32>,
 293                 ComplexPattern<i32, 2, "SelectAddrMode3Offset", []> {
 294   let PrintMethod = "printAddrMode3OffsetOperand";
 295   let MIOperandInfo = (ops GPR, i32imm);
 296 }
 297
 298 // addrmode4 := reg, <mode|W>
 299 //
 300 def addrmode4 : Operand<i32>,
 301                 ComplexPattern<i32, 2, "SelectAddrMode4", []> {
 302   let PrintMethod = "printAddrMode4Operand";
 303   let MIOperandInfo = (ops GPR, i32imm);
 304 }
 305
 306 // addrmode5 := reg +/- imm8*4
 307 //
 308 def addrmode5 : Operand<i32>,
 309                 ComplexPattern<i32, 2, "SelectAddrMode5", []> {
 310   let PrintMethod = "printAddrMode5Operand";
 311   let MIOperandInfo = (ops GPR, i32imm);
 312 }
 313
 314 // addrmode6 := reg with optional writeback
 315 //
 316 def addrmode6 : Operand<i32>,
 317                 ComplexPattern<i32, 3, "SelectAddrMode6", []> {
 318   let PrintMethod = "printAddrMode6Operand";
 319   let MIOperandInfo = (ops GPR:$addr, GPR:$upd, i32imm);
 320 }
 321
 322 // addrmodepc := pc + reg
 323 //
 324 def addrmodepc : Operand<i32>,
 325                  ComplexPattern<i32, 2, "SelectAddrModePC", []> {
 326   let PrintMethod = "printAddrModePCOperand";
 327   let MIOperandInfo = (ops GPR, i32imm);
 328 }
 329
 330 def nohash_imm : Operand<i32> {
 331   let PrintMethod = "printNoHashImmediate";
 332 }
 333
 334 //===----------------------------------------------------------------------===//
 335
 336 include "ARMInstrFormats.td"
 337
 338 //===----------------------------------------------------------------------===//
 339 // Multiclass helpers...
 340 //
 341
 342 /// AsI1_bin_irs - Defines a set of (op r, {so_imm|r|so_reg}) patterns for a
 343 /// binop that produces a value.
 344 multiclass AsI1_bin_irs<bits<4> opcod, string opc, PatFrag opnode,
 345                         bit Commutable = 0> {
 346   def ri : AsI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_imm:$b), DPFrm,
 347                IIC_iALUi, opc, " $dst, $a, $b",
 348                [(set GPR:$dst, (opnode GPR:$a, so_imm:$b))]> {
 349     let Inst{25} = 1;
 350   }
 351   def rr : AsI1<opcod, (outs GPR:$dst), (ins GPR:$a, GPR:$b), DPFrm,
 352                IIC_iALUr, opc, " $dst, $a, $b",
 353                [(set GPR:$dst, (opnode GPR:$a, GPR:$b))]> {
 354     let Inst{25} = 0;
 355     let isCommutable = Commutable;
 356   }
 357   def rs : AsI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_reg:$b), DPSoRegFrm,
 358                IIC_iALUsr, opc, " $dst, $a, $b",
 359                [(set GPR:$dst, (opnode GPR:$a, so_reg:$b))]> {
 360     let Inst{25} = 0;
 361   }
 362 }
 363
 364 /// AI1_bin_s_irs - Similar to AsI1_bin_irs except it sets the 's' bit so the
 365 /// instruction modifies the CSPR register.
 366 let Defs = [CPSR] in {
 367 multiclass AI1_bin_s_irs<bits<4> opcod, string opc, PatFrag opnode,
 368                          bit Commutable = 0> {
 369   def ri : AI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_imm:$b), DPFrm,
 370                IIC_iALUi, opc, "s $dst, $a, $b",
 371                [(set GPR:$dst, (opnode GPR:$a, so_imm:$b))]> {
 372     let Inst{25} = 1;
 373   }
 374   def rr : AI1<opcod, (outs GPR:$dst), (ins GPR:$a, GPR:$b), DPFrm,
 375                IIC_iALUr, opc, "s $dst, $a, $b",
 376                [(set GPR:$dst, (opnode GPR:$a, GPR:$b))]> {
 377     let isCommutable = Commutable;
 378         let Inst{25} = 0;
 379   }
 380   def rs : AI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_reg:$b), DPSoRegFrm,
 381                IIC_iALUsr, opc, "s $dst, $a, $b",
 382                [(set GPR:$dst, (opnode GPR:$a, so_reg:$b))]> {
 383     let Inst{25} = 0;
 384   }
 385 }
 386 }
 387
 388 /// AI1_cmp_irs - Defines a set of (op r, {so_imm|r|so_reg}) cmp / test
 389 /// patterns. Similar to AsI1_bin_irs except the instruction does not produce
 390 /// a explicit result, only implicitly set CPSR.
 391 let Defs = [CPSR] in {
 392 multiclass AI1_cmp_irs<bits<4> opcod, string opc, PatFrag opnode,
 393                        bit Commutable = 0> {
 394   def ri : AI1<opcod, (outs), (ins GPR:$a, so_imm:$b), DPFrm, IIC_iCMPi,
 395                opc, " $a, $b",
 396                [(opnode GPR:$a, so_imm:$b)]> {
 397     let Inst{25} = 1;
 398   }
 399   def rr : AI1<opcod, (outs), (ins GPR:$a, GPR:$b), DPFrm, IIC_iCMPr,
 400                opc, " $a, $b",
 401                [(opnode GPR:$a, GPR:$b)]> {
 402     let Inst{25} = 0;
 403     let isCommutable = Commutable;
 404   }
 405   def rs : AI1<opcod, (outs), (ins GPR:$a, so_reg:$b), DPSoRegFrm, IIC_iCMPsr,
 406                opc, " $a, $b",
 407                [(opnode GPR:$a, so_reg:$b)]> {
 408     let Inst{25} = 0;
 409   }
 410 }
 411 }
 412
 413 /// AI_unary_rrot - A unary operation with two forms: one whose operand is a
 414 /// register and one whose operand is a register rotated by 8/16/24.
 415 /// FIXME: Remove the 'r' variant. Its rot_imm is zero.
 416 multiclass AI_unary_rrot<bits<8> opcod, string opc, PatFrag opnode> {
 417   def r     : AExtI<opcod, (outs GPR:$dst), (ins GPR:$src),
 418                  IIC_iUNAr, opc, " $dst, $src",
 419                  [(set GPR:$dst, (opnode GPR:$src))]>,
 420               Requires<[IsARM, HasV6]> {
 421                 let Inst{19-16} = 0b1111;
 422               }
 423   def r_rot : AExtI<opcod, (outs GPR:$dst), (ins GPR:$src, i32imm:$rot),
 424                  IIC_iUNAsi, opc, " $dst, $src, ror $rot",
 425                  [(set GPR:$dst, (opnode (rotr GPR:$src, rot_imm:$rot)))]>,
 426               Requires<[IsARM, HasV6]> {
 427                 let Inst{19-16} = 0b1111;
 428               }
 429 }
 430
 431 /// AI_bin_rrot - A binary operation with two forms: one whose operand is a
 432 /// register and one whose operand is a register rotated by 8/16/24.
 433 multiclass AI_bin_rrot<bits<8> opcod, string opc, PatFrag opnode> {
 434   def rr     : AExtI<opcod, (outs GPR:$dst), (ins GPR:$LHS, GPR:$RHS),
 435                   IIC_iALUr, opc, " $dst, $LHS, $RHS",
 436                   [(set GPR:$dst, (opnode GPR:$LHS, GPR:$RHS))]>,
 437                   Requires<[IsARM, HasV6]>;
 438   def rr_rot : AExtI<opcod, (outs GPR:$dst), (ins GPR:$LHS, GPR:$RHS, i32imm:$rot),
 439                   IIC_iALUsi, opc, " $dst, $LHS, $RHS, ror $rot",
 440                   [(set GPR:$dst, (opnode GPR:$LHS,
 441                                           (rotr GPR:$RHS, rot_imm:$rot)))]>,
 442                   Requires<[IsARM, HasV6]>;
 443 }
 444
 445 /// AI1_adde_sube_irs - Define instructions and patterns for adde and sube.
 446 let Uses = [CPSR] in {
 447 multiclass AI1_adde_sube_irs<bits<4> opcod, string opc, PatFrag opnode,
 448                              bit Commutable = 0> {
 449   def ri : AsI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_imm:$b),
 450                 DPFrm, IIC_iALUi, opc, " $dst, $a, $b",
 451                [(set GPR:$dst, (opnode GPR:$a, so_imm:$b))]>,
 452                Requires<[IsARM, CarryDefIsUnused]> {
 453     let Inst{25} = 1;
 454   }
 455   def rr : AsI1<opcod, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
 456                 DPFrm, IIC_iALUr, opc, " $dst, $a, $b",
 457                [(set GPR:$dst, (opnode GPR:$a, GPR:$b))]>,
 458                Requires<[IsARM, CarryDefIsUnused]> {
 459     let isCommutable = Commutable;
 460     let Inst{25} = 0;
 461   }
 462   def rs : AsI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_reg:$b),
 463                 DPSoRegFrm, IIC_iALUsr, opc, " $dst, $a, $b",
 464                [(set GPR:$dst, (opnode GPR:$a, so_reg:$b))]>,
 465                Requires<[IsARM, CarryDefIsUnused]> {
 466     let Inst{25} = 0;
 467   }
 468   // Carry setting variants
 469   def Sri : AXI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_imm:$b),
 470                 DPFrm, IIC_iALUi, !strconcat(opc, "s $dst, $a, $b"),
 471                [(set GPR:$dst, (opnode GPR:$a, so_imm:$b))]>,
 472                Requires<[IsARM, CarryDefIsUsed]> {
 473     let Defs = [CPSR];
 474     let Inst{25} = 1;
 475   }
 476   def Srr : AXI1<opcod, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
 477                 DPFrm, IIC_iALUr, !strconcat(opc, "s $dst, $a, $b"),
 478                [(set GPR:$dst, (opnode GPR:$a, GPR:$b))]>,
 479                Requires<[IsARM, CarryDefIsUsed]> {
 480     let Defs = [CPSR];
 481     let Inst{25} = 0;
 482   }
 483   def Srs : AXI1<opcod, (outs GPR:$dst), (ins GPR:$a, so_reg:$b),
 484                 DPSoRegFrm, IIC_iALUsr, !strconcat(opc, "s $dst, $a, $b"),
 485                [(set GPR:$dst, (opnode GPR:$a, so_reg:$b))]>,
 486                Requires<[IsARM, CarryDefIsUsed]> {
 487     let Defs = [CPSR];
 488     let Inst{25} = 0;
 489   }
 490 }
 491 }
 492
 493 //===----------------------------------------------------------------------===//
 494 // Instructions
 495 //===----------------------------------------------------------------------===//
 496
 497 //===----------------------------------------------------------------------===//
 498 //  Miscellaneous Instructions.
 499 //
 500
 501 /// CONSTPOOL_ENTRY - This instruction represents a floating constant pool in
 502 /// the function.  The first operand is the ID# for this instruction, the second
 503 /// is the index into the MachineConstantPool that this is, the third is the
 504 /// size in bytes of this constant pool entry.
 505 let neverHasSideEffects = 1, isNotDuplicable = 1 in
 506 def CONSTPOOL_ENTRY :
 507 PseudoInst<(outs), (ins cpinst_operand:$instid, cpinst_operand:$cpidx,
 508                     i32imm:$size), NoItinerary,
 509            "${instid:label} ${cpidx:cpentry}", []>;
 510
 511 let Defs = [SP], Uses = [SP] in {
 512 def ADJCALLSTACKUP :
 513 PseudoInst<(outs), (ins i32imm:$amt1, i32imm:$amt2, pred:$p), NoItinerary,
 514            "@ ADJCALLSTACKUP $amt1",
 515            [(ARMcallseq_end timm:$amt1, timm:$amt2)]>;
 516
 517 def ADJCALLSTACKDOWN :
 518 PseudoInst<(outs), (ins i32imm:$amt, pred:$p), NoItinerary,
 519            "@ ADJCALLSTACKDOWN $amt",
 520            [(ARMcallseq_start timm:$amt)]>;
 521 }
 522
 523 def DWARF_LOC :
 524 PseudoInst<(outs), (ins i32imm:$line, i32imm:$col, i32imm:$file), NoItinerary,
 525            ".loc $file, $line, $col",
 526            [(dwarf_loc (i32 imm:$line), (i32 imm:$col), (i32 imm:$file))]>;
 527
 528
 529 // Address computation and loads and stores in PIC mode.
 530 let isNotDuplicable = 1 in {
 531 def PICADD : AXI1<0b0100, (outs GPR:$dst), (ins GPR:$a, pclabel:$cp, pred:$p),
 532                   Pseudo, IIC_iALUr, "\n$cp:\n\tadd$p $dst, pc, $a",
 533                    [(set GPR:$dst, (ARMpic_add GPR:$a, imm:$cp))]>;
 534
 535 let AddedComplexity = 10 in {
 536 let canFoldAsLoad = 1 in
 537 def PICLDR  : AXI2ldw<(outs GPR:$dst), (ins addrmodepc:$addr, pred:$p),
 538                   Pseudo, IIC_iLoadr, "\n${addr:label}:\n\tldr$p $dst, $addr",
 539                   [(set GPR:$dst, (load addrmodepc:$addr))]>;
 540
 541 def PICLDRH : AXI3ldh<(outs GPR:$dst), (ins addrmodepc:$addr, pred:$p),
 542                  Pseudo, IIC_iLoadr, "\n${addr:label}:\n\tldr${p}h $dst, $addr",
 543                   [(set GPR:$dst, (zextloadi16 addrmodepc:$addr))]>;
 544
 545 def PICLDRB : AXI2ldb<(outs GPR:$dst), (ins addrmodepc:$addr, pred:$p),
 546                  Pseudo, IIC_iLoadr, "\n${addr:label}:\n\tldr${p}b $dst, $addr",
 547                   [(set GPR:$dst, (zextloadi8 addrmodepc:$addr))]>;
 548
 549 def PICLDRSH : AXI3ldsh<(outs GPR:$dst), (ins addrmodepc:$addr, pred:$p),
 550                 Pseudo, IIC_iLoadr, "\n${addr:label}:\n\tldr${p}sh $dst, $addr",
 551                   [(set GPR:$dst, (sextloadi16 addrmodepc:$addr))]>;
 552
 553 def PICLDRSB : AXI3ldsb<(outs GPR:$dst), (ins addrmodepc:$addr, pred:$p),
 554                 Pseudo, IIC_iLoadr, "\n${addr:label}:\n\tldr${p}sb $dst, $addr",
 555                   [(set GPR:$dst, (sextloadi8 addrmodepc:$addr))]>;
 556 }
 557 let AddedComplexity = 10 in {
 558 def PICSTR  : AXI2stw<(outs), (ins GPR:$src, addrmodepc:$addr, pred:$p),
 559                Pseudo, IIC_iStorer, "\n${addr:label}:\n\tstr$p $src, $addr",
 560                [(store GPR:$src, addrmodepc:$addr)]>;
 561
 562 def PICSTRH : AXI3sth<(outs), (ins GPR:$src, addrmodepc:$addr, pred:$p),
 563                Pseudo, IIC_iStorer, "\n${addr:label}:\n\tstr${p}h $src, $addr",
 564                [(truncstorei16 GPR:$src, addrmodepc:$addr)]>;
 565
 566 def PICSTRB : AXI2stb<(outs), (ins GPR:$src, addrmodepc:$addr, pred:$p),
 567                Pseudo, IIC_iStorer, "\n${addr:label}:\n\tstr${p}b $src, $addr",
 568                [(truncstorei8 GPR:$src, addrmodepc:$addr)]>;
 569 }
 570 } // isNotDuplicable = 1
 571
 572
 573 // LEApcrel - Load a pc-relative address into a register without offending the
 574 // assembler.
 575 def LEApcrel : AXI1<0x0, (outs GPR:$dst), (ins i32imm:$label, pred:$p),
 576                     Pseudo, IIC_iALUi,
 577             !strconcat(!strconcat(".set ${:private}PCRELV${:uid}, ($label-(",
 578                                   "${:private}PCRELL${:uid}+8))\n"),
 579                        !strconcat("${:private}PCRELL${:uid}:\n\t",
 580                                   "add$p $dst, pc, #${:private}PCRELV${:uid}")),
 581                    []>;
 582
 583 def LEApcrelJT : AXI1<0x0, (outs GPR:$dst),
 584                            (ins i32imm:$label, nohash_imm:$id, pred:$p),
 585           Pseudo, IIC_iALUi,
 586    !strconcat(!strconcat(".set ${:private}PCRELV${:uid}, "
 587                          "(${label}_${id}-(",
 588                                   "${:private}PCRELL${:uid}+8))\n"),
 589                        !strconcat("${:private}PCRELL${:uid}:\n\t",
 590                                   "add$p $dst, pc, #${:private}PCRELV${:uid}")),
 591                    []> {
 592     let Inst{25} = 1;
 593 }
 594
 595 //===----------------------------------------------------------------------===//
 596 //  Control Flow Instructions.
 597 //
 598
 599 let isReturn = 1, isTerminator = 1 in
 600   def BX_RET : AI<(outs), (ins), BrMiscFrm, IIC_Br,
 601                   "bx", " lr", [(ARMretflag)]> {
 602   let Inst{7-4}   = 0b0001;
 603   let Inst{19-8}  = 0b111111111111;
 604   let Inst{27-20} = 0b00010010;
 605 }
 606
 607 // FIXME: remove when we have a way to marking a MI with these properties.
 608 // FIXME: $dst1 should be a def. But the extra ops must be in the end of the
 609 // operand list.
 610 // FIXME: Should pc be an implicit operand like PICADD, etc?
 611 let isReturn = 1, isTerminator = 1, mayLoad = 1 in
 612   def LDM_RET : AXI4ld<(outs),
 613                     (ins addrmode4:$addr, pred:$p, reglist:$dst1, variable_ops),
 614                     LdStMulFrm, IIC_Br, "ldm${p}${addr:submode} $addr, $dst1",
 615                     []>;
 616
 617 // On non-Darwin platforms R9 is callee-saved.
 618 let isCall = 1,
 619   Defs = [R0,  R1,  R2,  R3,  R12, LR,
 620           D0,  D1,  D2,  D3,  D4,  D5,  D6,  D7,
 621           D16, D17, D18, D19, D20, D21, D22, D23,
 622           D24, D25, D26, D27, D28, D29, D30, D31, CPSR] in {
 623   def BL  : ABXI<0b1011, (outs), (ins i32imm:$func, variable_ops),
 624                 IIC_Br, "bl ${func:call}",
 625                 [(ARMcall tglobaladdr:$func)]>,
 626             Requires<[IsARM, IsNotDarwin]>;
 627
 628   def BL_pred : ABI<0b1011, (outs), (ins i32imm:$func, variable_ops),
 629                    IIC_Br, "bl", " ${func:call}",
 630                    [(ARMcall_pred tglobaladdr:$func)]>,
 631                 Requires<[IsARM, IsNotDarwin]>;
 632
 633   // ARMv5T and above
 634   def BLX : AXI<(outs), (ins GPR:$func, variable_ops), BrMiscFrm,
 635                 IIC_Br, "blx $func",
 636                 [(ARMcall GPR:$func)]>,
 637             Requires<[IsARM, HasV5T, IsNotDarwin]> {
 638     let Inst{7-4}   = 0b0011;
 639     let Inst{19-8}  = 0b111111111111;
 640     let Inst{27-20} = 0b00010010;
 641   }
 642
 643   // ARMv4T
 644   def BX : ABXIx2<(outs), (ins GPR:$func, variable_ops),
 645                   IIC_Br, "mov lr, pc\n\tbx $func",
 646                   [(ARMcall_nolink GPR:$func)]>,
 647            Requires<[IsARM, IsNotDarwin]> {
 648     let Inst{7-4}   = 0b0001;
 649     let Inst{19-8}  = 0b111111111111;
 650     let Inst{27-20} = 0b00010010;
 651   }
 652 }
 653
 654 // On Darwin R9 is call-clobbered.
 655 let isCall = 1,
 656   Defs = [R0,  R1,  R2,  R3,  R9,  R12, LR,
 657           D0,  D1,  D2,  D3,  D4,  D5,  D6,  D7,
 658           D16, D17, D18, D19, D20, D21, D22, D23,
 659           D24, D25, D26, D27, D28, D29, D30, D31, CPSR] in {
 660   def BLr9  : ABXI<0b1011, (outs), (ins i32imm:$func, variable_ops),
 661                 IIC_Br, "bl ${func:call}",
 662                 [(ARMcall tglobaladdr:$func)]>, Requires<[IsARM, IsDarwin]>;
 663
 664   def BLr9_pred : ABI<0b1011, (outs), (ins i32imm:$func, variable_ops),
 665                    IIC_Br, "bl", " ${func:call}",
 666                    [(ARMcall_pred tglobaladdr:$func)]>,
 667                   Requires<[IsARM, IsDarwin]>;
 668
 669   // ARMv5T and above
 670   def BLXr9 : AXI<(outs), (ins GPR:$func, variable_ops), BrMiscFrm,
 671                 IIC_Br, "blx $func",
 672                 [(ARMcall GPR:$func)]>, Requires<[IsARM, HasV5T, IsDarwin]> {
 673     let Inst{7-4}   = 0b0011;
 674     let Inst{19-8}  = 0b111111111111;
 675     let Inst{27-20} = 0b00010010;
 676   }
 677
 678   // ARMv4T
 679   def BXr9 : ABXIx2<(outs), (ins GPR:$func, variable_ops),
 680                   IIC_Br, "mov lr, pc\n\tbx $func",
 681                   [(ARMcall_nolink GPR:$func)]>, Requires<[IsARM, IsDarwin]> {
 682     let Inst{7-4}   = 0b0001;
 683     let Inst{19-8}  = 0b111111111111;
 684     let Inst{27-20} = 0b00010010;
 685   }
 686 }
 687
 688 let isBranch = 1, isTerminator = 1 in {
 689   // B is "predicable" since it can be xformed into a Bcc.
 690   let isBarrier = 1 in {
 691     let isPredicable = 1 in
 692     def B : ABXI<0b1010, (outs), (ins brtarget:$target), IIC_Br,
 693                 "b $target", [(br bb:$target)]>;
 694
 695   let isNotDuplicable = 1, isIndirectBranch = 1 in {
 696   def BR_JTr : JTI<(outs), (ins GPR:$target, jtblock_operand:$jt, i32imm:$id),
 697                     IIC_Br, "mov pc, $target \n$jt",
 698                     [(ARMbrjt GPR:$target, tjumptable:$jt, imm:$id)]> {
 699     let Inst{20}    = 0; // S Bit
 700     let Inst{24-21} = 0b1101;
 701     let Inst{27-25} = 0b000;
 702   }
 703   def BR_JTm : JTI<(outs),
 704                    (ins addrmode2:$target, jtblock_operand:$jt, i32imm:$id),
 705                    IIC_Br, "ldr pc, $target \n$jt",
 706                    [(ARMbrjt (i32 (load addrmode2:$target)), tjumptable:$jt,
 707                      imm:$id)]> {
 708     let Inst{20}    = 1; // L bit
 709     let Inst{21}    = 0; // W bit
 710     let Inst{22}    = 0; // B bit
 711     let Inst{24}    = 1; // P bit
 712     let Inst{27-25} = 0b011;
 713   }
 714   def BR_JTadd : JTI<(outs),
 715                    (ins GPR:$target, GPR:$idx, jtblock_operand:$jt, i32imm:$id),
 716                     IIC_Br, "add pc, $target, $idx \n$jt",
 717                     [(ARMbrjt (add GPR:$target, GPR:$idx), tjumptable:$jt,
 718                       imm:$id)]> {
 719     let Inst{20}    = 0; // S bit
 720     let Inst{24-21} = 0b0100;
 721     let Inst{27-25} = 0b000;
 722   }
 723   } // isNotDuplicable = 1, isIndirectBranch = 1
 724   } // isBarrier = 1
 725
 726   // FIXME: should be able to write a pattern for ARMBrcond, but can't use
 727   // a two-value operand where a dag node expects two operands. :(
 728   def Bcc : ABI<0b1010, (outs), (ins brtarget:$target),
 729                IIC_Br, "b", " $target",
 730                [/*(ARMbrcond bb:$target, imm:$cc, CCR:$ccr)*/]>;
 731 }
 732
 733 //===----------------------------------------------------------------------===//
 734 //  Load / store Instructions.
 735 //
 736
 737 // Load
 738 let canFoldAsLoad = 1 in
 739 def LDR  : AI2ldw<(outs GPR:$dst), (ins addrmode2:$addr), LdFrm, IIC_iLoadr,
 740                "ldr", " $dst, $addr",
 741                [(set GPR:$dst, (load addrmode2:$addr))]>;
 742
 743 // Special LDR for loads from non-pc-relative constpools.
 744 let canFoldAsLoad = 1, mayLoad = 1, isReMaterializable = 1 in
 745 def LDRcp : AI2ldw<(outs GPR:$dst), (ins addrmode2:$addr), LdFrm, IIC_iLoadr,
 746                  "ldr", " $dst, $addr", []>;
 747
 748 // Loads with zero extension
 749 def LDRH  : AI3ldh<(outs GPR:$dst), (ins addrmode3:$addr), LdMiscFrm,
 750                   IIC_iLoadr, "ldr", "h $dst, $addr",
 751                   [(set GPR:$dst, (zextloadi16 addrmode3:$addr))]>;
 752
 753 def LDRB  : AI2ldb<(outs GPR:$dst), (ins addrmode2:$addr), LdFrm,
 754                   IIC_iLoadr, "ldr", "b $dst, $addr",
 755                   [(set GPR:$dst, (zextloadi8 addrmode2:$addr))]>;
 756
 757 // Loads with sign extension
 758 def LDRSH : AI3ldsh<(outs GPR:$dst), (ins addrmode3:$addr), LdMiscFrm,
 759                    IIC_iLoadr, "ldr", "sh $dst, $addr",
 760                    [(set GPR:$dst, (sextloadi16 addrmode3:$addr))]>;
 761
 762 def LDRSB : AI3ldsb<(outs GPR:$dst), (ins addrmode3:$addr), LdMiscFrm,
 763                    IIC_iLoadr, "ldr", "sb $dst, $addr",
 764                    [(set GPR:$dst, (sextloadi8 addrmode3:$addr))]>;
 765
 766 let mayLoad = 1 in {
 767 // Load doubleword
 768 def LDRD : AI3ldd<(outs GPR:$dst1, GPR:$dst2), (ins addrmode3:$addr), LdMiscFrm,
 769                  IIC_iLoadr, "ldr", "d $dst1, $addr",
 770                  []>, Requires<[IsARM, HasV5TE]>;
 771
 772 // Indexed loads
 773 def LDR_PRE  : AI2ldwpr<(outs GPR:$dst, GPR:$base_wb),
 774                      (ins addrmode2:$addr), LdFrm, IIC_iLoadru,
 775                      "ldr", " $dst, $addr!", "$addr.base = $base_wb", []>;
 776
 777 def LDR_POST : AI2ldwpo<(outs GPR:$dst, GPR:$base_wb),
 778                      (ins GPR:$base, am2offset:$offset), LdFrm, IIC_iLoadru,
 779                      "ldr", " $dst, [$base], $offset", "$base = $base_wb", []>;
 780
 781 def LDRH_PRE  : AI3ldhpr<(outs GPR:$dst, GPR:$base_wb),
 782                      (ins addrmode3:$addr), LdMiscFrm, IIC_iLoadru,
 783                      "ldr", "h $dst, $addr!", "$addr.base = $base_wb", []>;
 784
 785 def LDRH_POST : AI3ldhpo<(outs GPR:$dst, GPR:$base_wb),
 786                      (ins GPR:$base,am3offset:$offset), LdMiscFrm, IIC_iLoadru,
 787                      "ldr", "h $dst, [$base], $offset", "$base = $base_wb", []>;
 788
 789 def LDRB_PRE  : AI2ldbpr<(outs GPR:$dst, GPR:$base_wb),
 790                      (ins addrmode2:$addr), LdFrm, IIC_iLoadru,
 791                      "ldr", "b $dst, $addr!", "$addr.base = $base_wb", []>;
 792
 793 def LDRB_POST : AI2ldbpo<(outs GPR:$dst, GPR:$base_wb),
 794                      (ins GPR:$base,am2offset:$offset), LdFrm, IIC_iLoadru,
 795                      "ldr", "b $dst, [$base], $offset", "$base = $base_wb", []>;
 796
 797 def LDRSH_PRE : AI3ldshpr<(outs GPR:$dst, GPR:$base_wb),
 798                       (ins addrmode3:$addr), LdMiscFrm, IIC_iLoadru,
 799                       "ldr", "sh $dst, $addr!", "$addr.base = $base_wb", []>;
 800
 801 def LDRSH_POST: AI3ldshpo<(outs GPR:$dst, GPR:$base_wb),
 802                       (ins GPR:$base,am3offset:$offset), LdMiscFrm, IIC_iLoadru,
 803                     "ldr", "sh $dst, [$base], $offset", "$base = $base_wb", []>;
 804
 805 def LDRSB_PRE : AI3ldsbpr<(outs GPR:$dst, GPR:$base_wb),
 806                       (ins addrmode3:$addr), LdMiscFrm, IIC_iLoadru,
 807                       "ldr", "sb $dst, $addr!", "$addr.base = $base_wb", []>;
 808
 809 def LDRSB_POST: AI3ldsbpo<(outs GPR:$dst, GPR:$base_wb),
 810                       (ins GPR:$base,am3offset:$offset), LdMiscFrm, IIC_iLoadru,
 811                     "ldr", "sb $dst, [$base], $offset", "$base = $base_wb", []>;
 812 }
 813
 814 // Store
 815 def STR  : AI2stw<(outs), (ins GPR:$src, addrmode2:$addr), StFrm, IIC_iStorer,
 816                "str", " $src, $addr",
 817                [(store GPR:$src, addrmode2:$addr)]>;
 818
 819 // Stores with truncate
 820 def STRH : AI3sth<(outs), (ins GPR:$src, addrmode3:$addr), StMiscFrm, IIC_iStorer,
 821                "str", "h $src, $addr",
 822                [(truncstorei16 GPR:$src, addrmode3:$addr)]>;
 823
 824 def STRB : AI2stb<(outs), (ins GPR:$src, addrmode2:$addr), StFrm, IIC_iStorer,
 825                "str", "b $src, $addr",
 826                [(truncstorei8 GPR:$src, addrmode2:$addr)]>;
 827
 828 // Store doubleword
 829 let mayStore = 1 in
 830 def STRD : AI3std<(outs), (ins GPR:$src1, GPR:$src2, addrmode3:$addr),
 831                StMiscFrm, IIC_iStorer,
 832                "str", "d $src1, $addr", []>, Requires<[IsARM, HasV5TE]>;
 833
 834 // Indexed stores
 835 def STR_PRE  : AI2stwpr<(outs GPR:$base_wb),
 836                      (ins GPR:$src, GPR:$base, am2offset:$offset),
 837                      StFrm, IIC_iStoreru,
 838                     "str", " $src, [$base, $offset]!", "$base = $base_wb",
 839                     [(set GPR:$base_wb,
 840                       (pre_store GPR:$src, GPR:$base, am2offset:$offset))]>;
 841
 842 def STR_POST : AI2stwpo<(outs GPR:$base_wb),
 843                      (ins GPR:$src, GPR:$base,am2offset:$offset),
 844                      StFrm, IIC_iStoreru,
 845                     "str", " $src, [$base], $offset", "$base = $base_wb",
 846                     [(set GPR:$base_wb,
 847                       (post_store GPR:$src, GPR:$base, am2offset:$offset))]>;
 848
 849 def STRH_PRE : AI3sthpr<(outs GPR:$base_wb),
 850                      (ins GPR:$src, GPR:$base,am3offset:$offset),
 851                      StMiscFrm, IIC_iStoreru,
 852                      "str", "h $src, [$base, $offset]!", "$base = $base_wb",
 853                     [(set GPR:$base_wb,
 854                       (pre_truncsti16 GPR:$src, GPR:$base,am3offset:$offset))]>;
 855
 856 def STRH_POST: AI3sthpo<(outs GPR:$base_wb),
 857                      (ins GPR:$src, GPR:$base,am3offset:$offset),
 858                      StMiscFrm, IIC_iStoreru,
 859                      "str", "h $src, [$base], $offset", "$base = $base_wb",
 860                     [(set GPR:$base_wb, (post_truncsti16 GPR:$src,
 861                                          GPR:$base, am3offset:$offset))]>;
 862
 863 def STRB_PRE : AI2stbpr<(outs GPR:$base_wb),
 864                      (ins GPR:$src, GPR:$base,am2offset:$offset),
 865                      StFrm, IIC_iStoreru,
 866                      "str", "b $src, [$base, $offset]!", "$base = $base_wb",
 867                     [(set GPR:$base_wb, (pre_truncsti8 GPR:$src,
 868                                          GPR:$base, am2offset:$offset))]>;
 869
 870 def STRB_POST: AI2stbpo<(outs GPR:$base_wb),
 871                      (ins GPR:$src, GPR:$base,am2offset:$offset),
 872                      StFrm, IIC_iStoreru,
 873                      "str", "b $src, [$base], $offset", "$base = $base_wb",
 874                     [(set GPR:$base_wb, (post_truncsti8 GPR:$src,
 875                                          GPR:$base, am2offset:$offset))]>;
 876
 877 //===----------------------------------------------------------------------===//
 878 //  Load / store multiple Instructions.
 879 //
 880
 881 // FIXME: $dst1 should be a def.
 882 let mayLoad = 1 in
 883 def LDM : AXI4ld<(outs),
 884                (ins addrmode4:$addr, pred:$p, reglist:$dst1, variable_ops),
 885                LdStMulFrm, IIC_iLoadm, "ldm${p}${addr:submode} $addr, $dst1",
 886                []>;
 887
 888 let mayStore = 1 in
 889 def STM : AXI4st<(outs),
 890                (ins addrmode4:$addr, pred:$p, reglist:$src1, variable_ops),
 891                LdStMulFrm, IIC_iStorem, "stm${p}${addr:submode} $addr, $src1",
 892                []>;
 893
 894 //===----------------------------------------------------------------------===//
 895 //  Move Instructions.
 896 //
 897
 898 let neverHasSideEffects = 1 in
 899 def MOVr : AsI1<0b1101, (outs GPR:$dst), (ins GPR:$src), DPFrm, IIC_iMOVr,
 900                  "mov", " $dst, $src", []>, UnaryDP;
 901 def MOVs : AsI1<0b1101, (outs GPR:$dst), (ins so_reg:$src),
 902                  DPSoRegFrm, IIC_iMOVsr,
 903                  "mov", " $dst, $src", [(set GPR:$dst, so_reg:$src)]>, UnaryDP;
 904
 905 let isReMaterializable = 1, isAsCheapAsAMove = 1 in
 906 def MOVi : AsI1<0b1101, (outs GPR:$dst), (ins so_imm:$src), DPFrm, IIC_iMOVi,
 907                  "mov", " $dst, $src", [(set GPR:$dst, so_imm:$src)]>, UnaryDP;
 908
 909 let Uses = [CPSR] in
 910 def MOVrx : AsI1<0b1101, (outs GPR:$dst), (ins GPR:$src), Pseudo, IIC_iMOVsi,
 911                  "mov", " $dst, $src, rrx",
 912                  [(set GPR:$dst, (ARMrrx GPR:$src))]>, UnaryDP;
 913
 914 // These aren't really mov instructions, but we have to define them this way
 915 // due to flag operands.
 916
 917 let Defs = [CPSR] in {
 918 def MOVsrl_flag : AI1<0b1101, (outs GPR:$dst), (ins GPR:$src), Pseudo,
 919                       IIC_iMOVsi, "mov", "s $dst, $src, lsr #1",
 920                       [(set GPR:$dst, (ARMsrl_flag GPR:$src))]>, UnaryDP;
 921 def MOVsra_flag : AI1<0b1101, (outs GPR:$dst), (ins GPR:$src), Pseudo,
 922                       IIC_iMOVsi, "mov", "s $dst, $src, asr #1",
 923                       [(set GPR:$dst, (ARMsra_flag GPR:$src))]>, UnaryDP;
 924 }
 925
 926 //===----------------------------------------------------------------------===//
 927 //  Extend Instructions.
 928 //
 929
 930 // Sign extenders
 931
 932 defm SXTB  : AI_unary_rrot<0b01101010,
 933                            "sxtb", UnOpFrag<(sext_inreg node:$Src, i8)>>;
 934 defm SXTH  : AI_unary_rrot<0b01101011,
 935                            "sxth", UnOpFrag<(sext_inreg node:$Src, i16)>>;
 936
 937 defm SXTAB : AI_bin_rrot<0b01101010,
 938                "sxtab", BinOpFrag<(add node:$LHS, (sext_inreg node:$RHS, i8))>>;
 939 defm SXTAH : AI_bin_rrot<0b01101011,
 940                "sxtah", BinOpFrag<(add node:$LHS, (sext_inreg node:$RHS,i16))>>;
 941
 942 // TODO: SXT(A){B|H}16
 943
 944 // Zero extenders
 945
 946 let AddedComplexity = 16 in {
 947 defm UXTB   : AI_unary_rrot<0b01101110,
 948                             "uxtb"  , UnOpFrag<(and node:$Src, 0x000000FF)>>;
 949 defm UXTH   : AI_unary_rrot<0b01101111,
 950                             "uxth"  , UnOpFrag<(and node:$Src, 0x0000FFFF)>>;
 951 defm UXTB16 : AI_unary_rrot<0b01101100,
 952                             "uxtb16", UnOpFrag<(and node:$Src, 0x00FF00FF)>>;
 953
 954 def : ARMV6Pat<(and (shl GPR:$Src, (i32 8)), 0xFF00FF),
 955                (UXTB16r_rot GPR:$Src, 24)>;
 956 def : ARMV6Pat<(and (srl GPR:$Src, (i32 8)), 0xFF00FF),
 957                (UXTB16r_rot GPR:$Src, 8)>;
 958
 959 defm UXTAB : AI_bin_rrot<0b01101110, "uxtab",
 960                         BinOpFrag<(add node:$LHS, (and node:$RHS, 0x00FF))>>;
 961 defm UXTAH : AI_bin_rrot<0b01101111, "uxtah",
 962                         BinOpFrag<(add node:$LHS, (and node:$RHS, 0xFFFF))>>;
 963 }
 964
 965 // This isn't safe in general, the add is two 16-bit units, not a 32-bit add.
 966 //defm UXTAB16 : xxx<"uxtab16", 0xff00ff>;
 967
 968 // TODO: UXT(A){B|H}16
 969
 970 //===----------------------------------------------------------------------===//
 971 //  Arithmetic Instructions.
 972 //
 973
 974 defm ADD  : AsI1_bin_irs<0b0100, "add",
 975                          BinOpFrag<(add  node:$LHS, node:$RHS)>, 1>;
 976 defm SUB  : AsI1_bin_irs<0b0010, "sub",
 977                          BinOpFrag<(sub  node:$LHS, node:$RHS)>>;
 978
 979 // ADD and SUB with 's' bit set.
 980 defm ADDS : AI1_bin_s_irs<0b0100, "add",
 981                           BinOpFrag<(addc node:$LHS, node:$RHS)>>;
 982 defm SUBS : AI1_bin_s_irs<0b0010, "sub",
 983                           BinOpFrag<(subc node:$LHS, node:$RHS)>>;
 984
 985 defm ADC : AI1_adde_sube_irs<0b0101, "adc",
 986                              BinOpFrag<(adde node:$LHS, node:$RHS)>, 1>;
 987 defm SBC : AI1_adde_sube_irs<0b0110, "sbc",
 988                              BinOpFrag<(sube node:$LHS, node:$RHS)>>;
 989
 990 // These don't define reg/reg forms, because they are handled above.
 991 def RSBri : AsI1<0b0011, (outs GPR:$dst), (ins GPR:$a, so_imm:$b), DPFrm,
 992                   IIC_iALUi, "rsb", " $dst, $a, $b",
 993                   [(set GPR:$dst, (sub so_imm:$b, GPR:$a))]>;
 994
 995 def RSBrs : AsI1<0b0011, (outs GPR:$dst), (ins GPR:$a, so_reg:$b), DPSoRegFrm,
 996                   IIC_iALUsr, "rsb", " $dst, $a, $b",
 997                   [(set GPR:$dst, (sub so_reg:$b, GPR:$a))]>;
 998
 999 // RSB with 's' bit set.
1000 let Defs = [CPSR] in {
1001 def RSBSri : AI1<0b0011, (outs GPR:$dst), (ins GPR:$a, so_imm:$b), DPFrm,
1002                  IIC_iALUi, "rsb", "s $dst, $a, $b",
1003                  [(set GPR:$dst, (subc so_imm:$b, GPR:$a))]>;
1004 def RSBSrs : AI1<0b0011, (outs GPR:$dst), (ins GPR:$a, so_reg:$b), DPSoRegFrm,
1005                  IIC_iALUsr, "rsb", "s $dst, $a, $b",
1006                  [(set GPR:$dst, (subc so_reg:$b, GPR:$a))]>;
1007 }
1008
1009 let Uses = [CPSR] in {
1010 def RSCri : AsI1<0b0111, (outs GPR:$dst), (ins GPR:$a, so_imm:$b),
1011                  DPFrm, IIC_iALUi, "rsc", " $dst, $a, $b",
1012                  [(set GPR:$dst, (sube so_imm:$b, GPR:$a))]>,
1013                  Requires<[IsARM, CarryDefIsUnused]>;
1014 def RSCrs : AsI1<0b0111, (outs GPR:$dst), (ins GPR:$a, so_reg:$b),
1015                  DPSoRegFrm, IIC_iALUsr, "rsc", " $dst, $a, $b",
1016                  [(set GPR:$dst, (sube so_reg:$b, GPR:$a))]>,
1017                  Requires<[IsARM, CarryDefIsUnused]>;
1018 }
1019
1020 // FIXME: Allow these to be predicated.
1021 let Defs = [CPSR], Uses = [CPSR] in {
1022 def RSCSri : AXI1<0b0111, (outs GPR:$dst), (ins GPR:$a, so_imm:$b),
1023                   DPFrm, IIC_iALUi, "rscs $dst, $a, $b",
1024                   [(set GPR:$dst, (sube so_imm:$b, GPR:$a))]>,
1025                   Requires<[IsARM, CarryDefIsUnused]>;
1026 def RSCSrs : AXI1<0b0111, (outs GPR:$dst), (ins GPR:$a, so_reg:$b),
1027                   DPSoRegFrm, IIC_iALUsr, "rscs $dst, $a, $b",
1028                   [(set GPR:$dst, (sube so_reg:$b, GPR:$a))]>,
1029                   Requires<[IsARM, CarryDefIsUnused]>;
1030 }
1031
1032 // (sub X, imm) gets canonicalized to (add X, -imm).  Match this form.
1033 def : ARMPat<(add    GPR:$src, so_imm_neg:$imm),
1034              (SUBri  GPR:$src, so_imm_neg:$imm)>;
1035
1036 //def : ARMPat<(addc   GPR:$src, so_imm_neg:$imm),
1037 //             (SUBSri GPR:$src, so_imm_neg:$imm)>;
1038 //def : ARMPat<(adde   GPR:$src, so_imm_neg:$imm),
1039 //             (SBCri  GPR:$src, so_imm_neg:$imm)>;
1040
1041 // Note: These are implemented in C++ code, because they have to generate
1042 // ADD/SUBrs instructions, which use a complex pattern that a xform function
1043 // cannot produce.
1044 // (mul X, 2^n+1) -> (add (X << n), X)
1045 // (mul X, 2^n-1) -> (rsb X, (X << n))
1046
1047
1048 //===----------------------------------------------------------------------===//
1049 //  Bitwise Instructions.
1050 //
1051
1052 defm AND   : AsI1_bin_irs<0b0000, "and",
1053                           BinOpFrag<(and node:$LHS, node:$RHS)>, 1>;
1054 defm ORR   : AsI1_bin_irs<0b1100, "orr",
1055                           BinOpFrag<(or  node:$LHS, node:$RHS)>, 1>;
1056 defm EOR   : AsI1_bin_irs<0b0001, "eor",
1057                           BinOpFrag<(xor node:$LHS, node:$RHS)>, 1>;
1058 defm BIC   : AsI1_bin_irs<0b1110, "bic",
1059                           BinOpFrag<(and node:$LHS, (not node:$RHS))>>;
1060
1061 def BFC    : I<(outs GPR:$dst), (ins GPR:$src, bf_inv_mask_imm:$imm),
1062                AddrMode1, Size4Bytes, IndexModeNone, DPFrm, IIC_iALUi,
1063                "bfc", " $dst, $imm", "$src = $dst",
1064                [(set GPR:$dst, (and GPR:$src, bf_inv_mask_imm:$imm))]>,
1065                Requires<[IsARM, HasV6T2]> {
1066   let Inst{27-21} = 0b0111110;
1067   let Inst{6-0}   = 0b0011111;
1068 }
1069
1070 def  MVNr  : AsI1<0b1111, (outs GPR:$dst), (ins GPR:$src), DPFrm, IIC_iMOVr,
1071                   "mvn", " $dst, $src",
1072                   [(set GPR:$dst, (not GPR:$src))]>, UnaryDP;
1073 def  MVNs  : AsI1<0b1111, (outs GPR:$dst), (ins so_reg:$src), DPSoRegFrm,
1074                   IIC_iMOVsr, "mvn", " $dst, $src",
1075                   [(set GPR:$dst, (not so_reg:$src))]>, UnaryDP;
1076 let isReMaterializable = 1, isAsCheapAsAMove = 1 in
1077 def  MVNi  : AsI1<0b1111, (outs GPR:$dst), (ins so_imm:$imm), DPFrm,
1078                   IIC_iMOVi, "mvn", " $dst, $imm",
1079                   [(set GPR:$dst, so_imm_not:$imm)]>,UnaryDP;
1080
1081 def : ARMPat<(and   GPR:$src, so_imm_not:$imm),
1082              (BICri GPR:$src, so_imm_not:$imm)>;
1083
1084 //===----------------------------------------------------------------------===//
1085 //  Multiply Instructions.
1086 //
1087
1088 let isCommutable = 1 in
1089 def MUL   : AsMul1I<0b0000000, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
1090                    IIC_iMUL32, "mul", " $dst, $a, $b",
1091                    [(set GPR:$dst, (mul GPR:$a, GPR:$b))]>;
1092
1093 def MLA   : AsMul1I<0b0000001, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
1094                     IIC_iMAC32, "mla", " $dst, $a, $b, $c",
1095                    [(set GPR:$dst, (add (mul GPR:$a, GPR:$b), GPR:$c))]>;
1096
1097 def MLS   : AMul1I<0b0000011, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
1098                    IIC_iMAC32, "mls", " $dst, $a, $b, $c",
1099                    [(set GPR:$dst, (sub GPR:$c, (mul GPR:$a, GPR:$b)))]>,
1100                    Requires<[IsARM, HasV6T2]>;
1101
1102 // Extra precision multiplies with low / high results
1103 let neverHasSideEffects = 1 in {
1104 let isCommutable = 1 in {
1105 def SMULL : AsMul1I<0b0000110, (outs GPR:$ldst, GPR:$hdst),
1106                                (ins GPR:$a, GPR:$b), IIC_iMUL64,
1107                     "smull", " $ldst, $hdst, $a, $b", []>;
1108
1109 def UMULL : AsMul1I<0b0000100, (outs GPR:$ldst, GPR:$hdst),
1110                                (ins GPR:$a, GPR:$b), IIC_iMUL64,
1111                     "umull", " $ldst, $hdst, $a, $b", []>;
1112 }
1113
1114 // Multiply + accumulate
1115 def SMLAL : AsMul1I<0b0000111, (outs GPR:$ldst, GPR:$hdst),
1116                                (ins GPR:$a, GPR:$b), IIC_iMAC64,
1117                     "smlal", " $ldst, $hdst, $a, $b", []>;
1118
1119 def UMLAL : AsMul1I<0b0000101, (outs GPR:$ldst, GPR:$hdst),
1120                                (ins GPR:$a, GPR:$b), IIC_iMAC64,
1121                     "umlal", " $ldst, $hdst, $a, $b", []>;
1122
1123 def UMAAL : AMul1I <0b0000010, (outs GPR:$ldst, GPR:$hdst),
1124                                (ins GPR:$a, GPR:$b), IIC_iMAC64,
1125                     "umaal", " $ldst, $hdst, $a, $b", []>,
1126                     Requires<[IsARM, HasV6]>;
1127 } // neverHasSideEffects
1128
1129 // Most significant word multiply
1130 def SMMUL : AMul2I <0b0111010, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
1131                IIC_iMUL32, "smmul", " $dst, $a, $b",
1132                [(set GPR:$dst, (mulhs GPR:$a, GPR:$b))]>,
1133             Requires<[IsARM, HasV6]> {
1134   let Inst{7-4}   = 0b0001;
1135   let Inst{15-12} = 0b1111;
1136 }
1137
1138 def SMMLA : AMul2I <0b0111010, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
1139                IIC_iMAC32, "smmla", " $dst, $a, $b, $c",
1140                [(set GPR:$dst, (add (mulhs GPR:$a, GPR:$b), GPR:$c))]>,
1141             Requires<[IsARM, HasV6]> {
1142   let Inst{7-4}   = 0b0001;
1143 }
1144
1145
1146 def SMMLS : AMul2I <0b0111010, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
1147                IIC_iMAC32, "smmls", " $dst, $a, $b, $c",
1148                [(set GPR:$dst, (sub GPR:$c, (mulhs GPR:$a, GPR:$b)))]>,
1149             Requires<[IsARM, HasV6]> {
1150   let Inst{7-4}   = 0b1101;
1151 }
1152
1153 multiclass AI_smul<string opc, PatFrag opnode> {
1154   def BB : AMulxyI<0b0001011, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
1155               IIC_iMUL32, !strconcat(opc, "bb"), " $dst, $a, $b",
1156               [(set GPR:$dst, (opnode (sext_inreg GPR:$a, i16),
1157                                       (sext_inreg GPR:$b, i16)))]>,
1158            Requires<[IsARM, HasV5TE]> {
1159              let Inst{5} = 0;
1160              let Inst{6} = 0;
1161            }
1162
1163   def BT : AMulxyI<0b0001011, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
1164               IIC_iMUL32, !strconcat(opc, "bt"), " $dst, $a, $b",
1165               [(set GPR:$dst, (opnode (sext_inreg GPR:$a, i16),
1166                                       (sra GPR:$b, (i32 16))))]>,
1167            Requires<[IsARM, HasV5TE]> {
1168              let Inst{5} = 0;
1169              let Inst{6} = 1;
1170            }
1171
1172   def TB : AMulxyI<0b0001011, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
1173               IIC_iMUL32, !strconcat(opc, "tb"), " $dst, $a, $b",
1174               [(set GPR:$dst, (opnode (sra GPR:$a, (i32 16)),
1175                                       (sext_inreg GPR:$b, i16)))]>,
1176            Requires<[IsARM, HasV5TE]> {
1177              let Inst{5} = 1;
1178              let Inst{6} = 0;
1179            }
1180
1181   def TT : AMulxyI<0b0001011, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
1182               IIC_iMUL32, !strconcat(opc, "tt"), " $dst, $a, $b",
1183               [(set GPR:$dst, (opnode (sra GPR:$a, (i32 16)),
1184                                       (sra GPR:$b, (i32 16))))]>,
1185             Requires<[IsARM, HasV5TE]> {
1186              let Inst{5} = 1;
1187              let Inst{6} = 1;
1188            }
1189
1190   def WB : AMulxyI<0b0001001, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
1191               IIC_iMUL16, !strconcat(opc, "wb"), " $dst, $a, $b",
1192               [(set GPR:$dst, (sra (opnode GPR:$a,
1193                                     (sext_inreg GPR:$b, i16)), (i32 16)))]>,
1194            Requires<[IsARM, HasV5TE]> {
1195              let Inst{5} = 1;
1196              let Inst{6} = 0;
1197            }
1198
1199   def WT : AMulxyI<0b0001001, (outs GPR:$dst), (ins GPR:$a, GPR:$b),
1200               IIC_iMUL16, !strconcat(opc, "wt"), " $dst, $a, $b",
1201               [(set GPR:$dst, (sra (opnode GPR:$a,
1202                                     (sra GPR:$b, (i32 16))), (i32 16)))]>,
1203             Requires<[IsARM, HasV5TE]> {
1204              let Inst{5} = 1;
1205              let Inst{6} = 1;
1206            }
1207 }
1208
1209
1210 multiclass AI_smla<string opc, PatFrag opnode> {
1211   def BB : AMulxyI<0b0001000, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
1212               IIC_iMAC16, !strconcat(opc, "bb"), " $dst, $a, $b, $acc",
1213               [(set GPR:$dst, (add GPR:$acc,
1214                                (opnode (sext_inreg GPR:$a, i16),
1215                                        (sext_inreg GPR:$b, i16))))]>,
1216            Requires<[IsARM, HasV5TE]> {
1217              let Inst{5} = 0;
1218              let Inst{6} = 0;
1219            }
1220
1221   def BT : AMulxyI<0b0001000, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
1222               IIC_iMAC16, !strconcat(opc, "bt"), " $dst, $a, $b, $acc",
1223               [(set GPR:$dst, (add GPR:$acc, (opnode (sext_inreg GPR:$a, i16),
1224                                                      (sra GPR:$b, (i32 16)))))]>,
1225            Requires<[IsARM, HasV5TE]> {
1226              let Inst{5} = 0;
1227              let Inst{6} = 1;
1228            }
1229
1230   def TB : AMulxyI<0b0001000, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
1231               IIC_iMAC16, !strconcat(opc, "tb"), " $dst, $a, $b, $acc",
1232               [(set GPR:$dst, (add GPR:$acc, (opnode (sra GPR:$a, (i32 16)),
1233                                                  (sext_inreg GPR:$b, i16))))]>,
1234            Requires<[IsARM, HasV5TE]> {
1235              let Inst{5} = 1;
1236              let Inst{6} = 0;
1237            }
1238
1239   def TT : AMulxyI<0b0001000, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
1240               IIC_iMAC16, !strconcat(opc, "tt"), " $dst, $a, $b, $acc",
1241               [(set GPR:$dst, (add GPR:$acc, (opnode (sra GPR:$a, (i32 16)),
1242                                                      (sra GPR:$b, (i32 16)))))]>,
1243             Requires<[IsARM, HasV5TE]> {
1244              let Inst{5} = 1;
1245              let Inst{6} = 1;
1246            }
1247
1248   def WB : AMulxyI<0b0001001, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
1249               IIC_iMAC16, !strconcat(opc, "wb"), " $dst, $a, $b, $acc",
1250               [(set GPR:$dst, (add GPR:$acc, (sra (opnode GPR:$a,
1251                                        (sext_inreg GPR:$b, i16)), (i32 16))))]>,
1252            Requires<[IsARM, HasV5TE]> {
1253              let Inst{5} = 0;
1254              let Inst{6} = 0;
1255            }
1256
1257   def WT : AMulxyI<0b0001001, (outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
1258               IIC_iMAC16, !strconcat(opc, "wt"), " $dst, $a, $b, $acc",
1259               [(set GPR:$dst, (add GPR:$acc, (sra (opnode GPR:$a,
1260                                          (sra GPR:$b, (i32 16))), (i32 16))))]>,
1261             Requires<[IsARM, HasV5TE]> {
1262              let Inst{5} = 0;
1263              let Inst{6} = 1;
1264            }
1265 }
1266
1267 defm SMUL : AI_smul<"smul", BinOpFrag<(mul node:$LHS, node:$RHS)>>;
1268 defm SMLA : AI_smla<"smla", BinOpFrag<(mul node:$LHS, node:$RHS)>>;
1269
1270 // TODO: Halfword multiple accumulate long: SMLAL<x><y>
1271 // TODO: Dual halfword multiple: SMUAD, SMUSD, SMLAD, SMLSD, SMLALD, SMLSLD
1272
1273 //===----------------------------------------------------------------------===//
1274 //  Misc. Arithmetic Instructions.
1275 //
1276
1277 def CLZ  : AMiscA1I<0b000010110, (outs GPR:$dst), (ins GPR:$src), IIC_iUNAr,
1278               "clz", " $dst, $src",
1279               [(set GPR:$dst, (ctlz GPR:$src))]>, Requires<[IsARM, HasV5T]> {
1280   let Inst{7-4}   = 0b0001;
1281   let Inst{11-8}  = 0b1111;
1282   let Inst{19-16} = 0b1111;
1283 }
1284
1285 def REV  : AMiscA1I<0b01101011, (outs GPR:$dst), (ins GPR:$src), IIC_iUNAr,
1286               "rev", " $dst, $src",
1287               [(set GPR:$dst, (bswap GPR:$src))]>, Requires<[IsARM, HasV6]> {
1288   let Inst{7-4}   = 0b0011;
1289   let Inst{11-8}  = 0b1111;
1290   let Inst{19-16} = 0b1111;
1291 }
1292
1293 def REV16 : AMiscA1I<0b01101011, (outs GPR:$dst), (ins GPR:$src), IIC_iUNAr,
1294                "rev16", " $dst, $src",
1295                [(set GPR:$dst,
1296                    (or (and (srl GPR:$src, (i32 8)), 0xFF),
1297                        (or (and (shl GPR:$src, (i32 8)), 0xFF00),
1298                            (or (and (srl GPR:$src, (i32 8)), 0xFF0000),
1299                                (and (shl GPR:$src, (i32 8)), 0xFF000000)))))]>,
1300                Requires<[IsARM, HasV6]> {
1301   let Inst{7-4}   = 0b1011;
1302   let Inst{11-8}  = 0b1111;
1303   let Inst{19-16} = 0b1111;
1304 }
1305
1306 def REVSH : AMiscA1I<0b01101111, (outs GPR:$dst), (ins GPR:$src), IIC_iUNAr,
1307                "revsh", " $dst, $src",
1308                [(set GPR:$dst,
1309                   (sext_inreg
1310                     (or (srl (and GPR:$src, 0xFF00), (i32 8)),
1311                         (shl GPR:$src, (i32 8))), i16))]>,
1312                Requires<[IsARM, HasV6]> {
1313   let Inst{7-4}   = 0b1011;
1314   let Inst{11-8}  = 0b1111;
1315   let Inst{19-16} = 0b1111;
1316 }
1317
1318 def PKHBT : AMiscA1I<0b01101000, (outs GPR:$dst),
1319                                  (ins GPR:$src1, GPR:$src2, i32imm:$shamt),
1320                IIC_iALUsi, "pkhbt", " $dst, $src1, $src2, LSL $shamt",
1321                [(set GPR:$dst, (or (and GPR:$src1, 0xFFFF),
1322                                    (and (shl GPR:$src2, (i32 imm:$shamt)),
1323                                         0xFFFF0000)))]>,
1324                Requires<[IsARM, HasV6]> {
1325   let Inst{6-4} = 0b001;
1326 }
1327
1328 // Alternate cases for PKHBT where identities eliminate some nodes.
1329 def : ARMV6Pat<(or (and GPR:$src1, 0xFFFF), (and GPR:$src2, 0xFFFF0000)),
1330                (PKHBT GPR:$src1, GPR:$src2, 0)>;
1331 def : ARMV6Pat<(or (and GPR:$src1, 0xFFFF), (shl GPR:$src2, imm16_31:$shamt)),
1332                (PKHBT GPR:$src1, GPR:$src2, imm16_31:$shamt)>;
1333
1334
1335 def PKHTB : AMiscA1I<0b01101000, (outs GPR:$dst),
1336                                  (ins GPR:$src1, GPR:$src2, i32imm:$shamt),
1337                IIC_iALUsi, "pkhtb", " $dst, $src1, $src2, ASR $shamt",
1338                [(set GPR:$dst, (or (and GPR:$src1, 0xFFFF0000),
1339                                    (and (sra GPR:$src2, imm16_31:$shamt),
1340                                         0xFFFF)))]>, Requires<[IsARM, HasV6]> {
1341   let Inst{6-4} = 0b101;
1342 }
1343
1344 // Alternate cases for PKHTB where identities eliminate some nodes.  Note that
1345 // a shift amount of 0 is *not legal* here, it is PKHBT instead.
1346 def : ARMV6Pat<(or (and GPR:$src1, 0xFFFF0000), (srl GPR:$src2, (i32 16))),
1347                (PKHTB GPR:$src1, GPR:$src2, 16)>;
1348 def : ARMV6Pat<(or (and GPR:$src1, 0xFFFF0000),
1349                    (and (srl GPR:$src2, imm1_15:$shamt), 0xFFFF)),
1350                (PKHTB GPR:$src1, GPR:$src2, imm1_15:$shamt)>;
1351
1352 //===----------------------------------------------------------------------===//
1353 //  Comparison Instructions...
1354 //
1355
1356 defm CMP  : AI1_cmp_irs<0b1010, "cmp",
1357                         BinOpFrag<(ARMcmp node:$LHS, node:$RHS)>>;
1358 defm CMN  : AI1_cmp_irs<0b1011, "cmn",
1359                         BinOpFrag<(ARMcmp node:$LHS,(ineg node:$RHS))>>;
1360
1361 // Note that TST/TEQ don't set all the same flags that CMP does!
1362 defm TST  : AI1_cmp_irs<0b1000, "tst",
1363                         BinOpFrag<(ARMcmpZ (and node:$LHS, node:$RHS), 0)>, 1>;
1364 defm TEQ  : AI1_cmp_irs<0b1001, "teq",
1365                         BinOpFrag<(ARMcmpZ (xor node:$LHS, node:$RHS), 0)>, 1>;
1366
1367 defm CMPz  : AI1_cmp_irs<0b1010, "cmp",
1368                          BinOpFrag<(ARMcmpZ node:$LHS, node:$RHS)>>;
1369 defm CMNz  : AI1_cmp_irs<0b1011, "cmn",
1370                          BinOpFrag<(ARMcmpZ node:$LHS,(ineg node:$RHS))>>;
1371
1372 def : ARMPat<(ARMcmp GPR:$src, so_imm_neg:$imm),
1373              (CMNri  GPR:$src, so_imm_neg:$imm)>;
1374
1375 def : ARMPat<(ARMcmpZ GPR:$src, so_imm_neg:$imm),
1376              (CMNri  GPR:$src, so_imm_neg:$imm)>;
1377
1378
1379 // Conditional moves
1380 // FIXME: should be able to write a pattern for ARMcmov, but can't use
1381 // a two-value operand where a dag node expects two operands. :(
1382 def MOVCCr : AI1<0b1101, (outs GPR:$dst), (ins GPR:$false, GPR:$true), DPFrm,
1383                 IIC_iCMOVr, "mov", " $dst, $true",
1384       [/*(set GPR:$dst, (ARMcmov GPR:$false, GPR:$true, imm:$cc, CCR:$ccr))*/]>,
1385                 RegConstraint<"$false = $dst">, UnaryDP;
1386
1387 def MOVCCs : AI1<0b1101, (outs GPR:$dst),
1388                         (ins GPR:$false, so_reg:$true), DPSoRegFrm, IIC_iCMOVsr,
1389                 "mov", " $dst, $true",
1390    [/*(set GPR:$dst, (ARMcmov GPR:$false, so_reg:$true, imm:$cc, CCR:$ccr))*/]>,
1391                 RegConstraint<"$false = $dst">, UnaryDP;
1392
1393 def MOVCCi : AI1<0b1101, (outs GPR:$dst),
1394                         (ins GPR:$false, so_imm:$true), DPFrm, IIC_iCMOVi,
1395                 "mov", " $dst, $true",
1396    [/*(set GPR:$dst, (ARMcmov GPR:$false, so_imm:$true, imm:$cc, CCR:$ccr))*/]>,
1397                 RegConstraint<"$false = $dst">, UnaryDP;
1398
1399
1400 //===----------------------------------------------------------------------===//
1401 // TLS Instructions
1402 //
1403
1404 // __aeabi_read_tp preserves the registers r1-r3.
1405 let isCall = 1,
1406   Defs = [R0, R12, LR, CPSR] in {
1407   def TPsoft : ABXI<0b1011, (outs), (ins), IIC_Br,
1408                "bl __aeabi_read_tp",
1409                [(set R0, ARMthread_pointer)]>;
1410 }
1411
1412 //===----------------------------------------------------------------------===//
1413 // SJLJ Exception handling intrinsics
1414 //   eh_sjlj_setjmp() is an instruction sequence to store the return
1415 //   address and save #0 in R0 for the non-longjmp case.
1416 //   Since by its nature we may be coming from some other function to get
1417 //   here, and we're using the stack frame for the containing function to
1418 //   save/restore registers, we can't keep anything live in regs across
1419 //   the eh_sjlj_setjmp(), else it will almost certainly have been tromped upon
1420 //   when we get here from a longjmp(). We force everthing out of registers
1421 //   except for our own input by listing the relevant registers in Defs. By
1422 //   doing so, we also cause the prologue/epilogue code to actively preserve
1423 //   all of the callee-saved resgisters, which is exactly what we want.
1424 let Defs =
1425   [ R0,  R1,  R2,  R3,  R4,  R5,  R6,  R7,  R8,  R9,  R10, R11, R12, LR,  D0,
1426     D1,  D2,  D3,  D4,  D5,  D6,  D7,  D8,  D9,  D10, D11, D12, D13, D14, D15,
1427     D16, D17, D18, D19, D20, D21, D22, D23, D24, D25, D26, D27, D28, D29, D30,
1428     D31 ] in {
1429   def Int_eh_sjlj_setjmp : XI<(outs), (ins GPR:$src),
1430                                AddrModeNone, SizeSpecial, IndexModeNone,
1431                                Pseudo, NoItinerary,
1432                                "str sp, [$src, #+8] @ eh_setjmp begin\n\t"
1433                                "add r12, pc, #8\n\t"
1434                                "str r12, [$src, #+4]\n\t"
1435                                "mov r0, #0\n\t"
1436                                "add pc, pc, #0\n\t"
1437                                "mov r0, #1 @ eh_setjmp end", "",
1438                                [(set R0, (ARMeh_sjlj_setjmp GPR:$src))]>;
1439 }
1440
1441 //===----------------------------------------------------------------------===//
1442 // Non-Instruction Patterns
1443 //
1444
1445 // ConstantPool, GlobalAddress, and JumpTable
1446 def : ARMPat<(ARMWrapper  tglobaladdr :$dst), (LEApcrel tglobaladdr :$dst)>;
1447 def : ARMPat<(ARMWrapper  tconstpool  :$dst), (LEApcrel tconstpool  :$dst)>;
1448 def : ARMPat<(ARMWrapperJT tjumptable:$dst, imm:$id),
1449              (LEApcrelJT tjumptable:$dst, imm:$id)>;
1450
1451 // Large immediate handling.
1452
1453 // Two piece so_imms.
1454 let isReMaterializable = 1 in
1455 def MOVi2pieces : AI1x2<(outs GPR:$dst), (ins so_imm2part:$src),
1456                          Pseudo, IIC_iMOVi,
1457                          "mov", " $dst, $src",
1458                          [(set GPR:$dst, so_imm2part:$src)]>;
1459
1460 def : ARMPat<(or GPR:$LHS, so_imm2part:$RHS),
1461              (ORRri (ORRri GPR:$LHS, (so_imm2part_1 imm:$RHS)),
1462                     (so_imm2part_2 imm:$RHS))>;
1463 def : ARMPat<(xor GPR:$LHS, so_imm2part:$RHS),
1464              (EORri (EORri GPR:$LHS, (so_imm2part_1 imm:$RHS)),
1465                     (so_imm2part_2 imm:$RHS))>;
1466
1467 // TODO: add,sub,and, 3-instr forms?
1468
1469
1470 // Direct calls
1471 def : ARMPat<(ARMcall texternalsym:$func), (BL texternalsym:$func)>,
1472       Requires<[IsARM, IsNotDarwin]>;
1473 def : ARMPat<(ARMcall texternalsym:$func), (BLr9 texternalsym:$func)>,
1474       Requires<[IsARM, IsDarwin]>;
1475
1476 // zextload i1 -> zextload i8
1477 def : ARMPat<(zextloadi1 addrmode2:$addr),  (LDRB addrmode2:$addr)>;
1478
1479 // extload -> zextload
1480 def : ARMPat<(extloadi1  addrmode2:$addr),  (LDRB addrmode2:$addr)>;
1481 def : ARMPat<(extloadi8  addrmode2:$addr),  (LDRB addrmode2:$addr)>;
1482 def : ARMPat<(extloadi16 addrmode3:$addr),  (LDRH addrmode3:$addr)>;
1483
1484 def : ARMPat<(extloadi8  addrmodepc:$addr), (PICLDRB addrmodepc:$addr)>;
1485 def : ARMPat<(extloadi16 addrmodepc:$addr), (PICLDRH addrmodepc:$addr)>;
1486
1487 // smul* and smla*
1488 def : ARMV5TEPat<(mul (sra (shl GPR:$a, (i32 16)), (i32 16)),
1489                       (sra (shl GPR:$b, (i32 16)), (i32 16))),
1490                  (SMULBB GPR:$a, GPR:$b)>;
1491 def : ARMV5TEPat<(mul sext_16_node:$a, sext_16_node:$b),
1492                  (SMULBB GPR:$a, GPR:$b)>;
1493 def : ARMV5TEPat<(mul (sra (shl GPR:$a, (i32 16)), (i32 16)),
1494                       (sra GPR:$b, (i32 16))),
1495                  (SMULBT GPR:$a, GPR:$b)>;
1496 def : ARMV5TEPat<(mul sext_16_node:$a, (sra GPR:$b, (i32 16))),
1497                  (SMULBT GPR:$a, GPR:$b)>;
1498 def : ARMV5TEPat<(mul (sra GPR:$a, (i32 16)),
1499                       (sra (shl GPR:$b, (i32 16)), (i32 16))),
1500                  (SMULTB GPR:$a, GPR:$b)>;
1501 def : ARMV5TEPat<(mul (sra GPR:$a, (i32 16)), sext_16_node:$b),
1502                 (SMULTB GPR:$a, GPR:$b)>;
1503 def : ARMV5TEPat<(sra (mul GPR:$a, (sra (shl GPR:$b, (i32 16)), (i32 16))),
1504                       (i32 16)),
1505                  (SMULWB GPR:$a, GPR:$b)>;
1506 def : ARMV5TEPat<(sra (mul GPR:$a, sext_16_node:$b), (i32 16)),
1507                  (SMULWB GPR:$a, GPR:$b)>;
1508
1509 def : ARMV5TEPat<(add GPR:$acc,
1510                       (mul (sra (shl GPR:$a, (i32 16)), (i32 16)),
1511                            (sra (shl GPR:$b, (i32 16)), (i32 16)))),
1512                  (SMLABB GPR:$a, GPR:$b, GPR:$acc)>;
1513 def : ARMV5TEPat<(add GPR:$acc,
1514                       (mul sext_16_node:$a, sext_16_node:$b)),
1515                  (SMLABB GPR:$a, GPR:$b, GPR:$acc)>;
1516 def : ARMV5TEPat<(add GPR:$acc,
1517                       (mul (sra (shl GPR:$a, (i32 16)), (i32 16)),
1518                            (sra GPR:$b, (i32 16)))),
1519                  (SMLABT GPR:$a, GPR:$b, GPR:$acc)>;
1520 def : ARMV5TEPat<(add GPR:$acc,
1521                       (mul sext_16_node:$a, (sra GPR:$b, (i32 16)))),
1522                  (SMLABT GPR:$a, GPR:$b, GPR:$acc)>;
1523 def : ARMV5TEPat<(add GPR:$acc,
1524                       (mul (sra GPR:$a, (i32 16)),
1525                            (sra (shl GPR:$b, (i32 16)), (i32 16)))),
1526                  (SMLATB GPR:$a, GPR:$b, GPR:$acc)>;
1527 def : ARMV5TEPat<(add GPR:$acc,
1528                       (mul (sra GPR:$a, (i32 16)), sext_16_node:$b)),
1529                  (SMLATB GPR:$a, GPR:$b, GPR:$acc)>;
1530 def : ARMV5TEPat<(add GPR:$acc,
1531                       (sra (mul GPR:$a, (sra (shl GPR:$b, (i32 16)), (i32 16))),
1532                            (i32 16))),
1533                  (SMLAWB GPR:$a, GPR:$b, GPR:$acc)>;
1534 def : ARMV5TEPat<(add GPR:$acc,
1535                       (sra (mul GPR:$a, sext_16_node:$b), (i32 16))),
1536                  (SMLAWB GPR:$a, GPR:$b, GPR:$acc)>;
1537
1538 //===----------------------------------------------------------------------===//
1539 // Thumb Support
1540 //
1541
1542 include "ARMInstrThumb.td"
1543
1544 //===----------------------------------------------------------------------===//
1545 // Thumb2 Support
1546 //
1547
1548 include "ARMInstrThumb2.td"
1549
1550 //===----------------------------------------------------------------------===//
1551 // Floating Point Support
1552 //
1553
1554 include "ARMInstrVFP.td"
1555
1556 //===----------------------------------------------------------------------===//
1557 // Advanced SIMD (NEON) Support
1558 //
1559
1560 include "ARMInstrNEON.td"