lib/Target/ARM/ARMInstrFormats.td

   1 //===- ARMInstrFormats.td - ARM Instruction Formats --*- tablegen -*---------=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 //
  12 // ARM Instruction Format Definitions.
  13 //
  14
  15 // Format specifies the encoding used by the instruction.  This is part of the
  16 // ad-hoc solution used to emit machine instruction encodings by our machine
  17 // code emitter.
  18 class Format<bits<6> val> {
  19   bits<6> Value = val;
  20 }
  21
  22 def Pseudo        : Format<0>;
  23 def MulFrm        : Format<1>;
  24 def BrFrm         : Format<2>;
  25 def BrMiscFrm     : Format<3>;
  26
  27 def DPFrm         : Format<4>;
  28 def DPSoRegFrm    : Format<5>;
  29
  30 def LdFrm         : Format<6>;
  31 def StFrm         : Format<7>;
  32 def LdMiscFrm     : Format<8>;
  33 def StMiscFrm     : Format<9>;
  34 def LdStMulFrm    : Format<10>;
  35
  36 def LdStExFrm     : Format<11>;
  37
  38 def ArithMiscFrm  : Format<12>;
  39 def SatFrm        : Format<13>;
  40 def ExtFrm        : Format<14>;
  41
  42 def VFPUnaryFrm   : Format<15>;
  43 def VFPBinaryFrm  : Format<16>;
  44 def VFPConv1Frm   : Format<17>;
  45 def VFPConv2Frm   : Format<18>;
  46 def VFPConv3Frm   : Format<19>;
  47 def VFPConv4Frm   : Format<20>;
  48 def VFPConv5Frm   : Format<21>;
  49 def VFPLdStFrm    : Format<22>;
  50 def VFPLdStMulFrm : Format<23>;
  51 def VFPMiscFrm    : Format<24>;
  52
  53 def ThumbFrm      : Format<25>;
  54 def MiscFrm       : Format<26>;
  55
  56 def NGetLnFrm     : Format<27>;
  57 def NSetLnFrm     : Format<28>;
  58 def NDupFrm       : Format<29>;
  59 def NLdStFrm      : Format<30>;
  60 def N1RegModImmFrm: Format<31>;
  61 def N2RegFrm      : Format<32>;
  62 def NVCVTFrm      : Format<33>;
  63 def NVDupLnFrm    : Format<34>;
  64 def N2RegVShLFrm  : Format<35>;
  65 def N2RegVShRFrm  : Format<36>;
  66 def N3RegFrm      : Format<37>;
  67 def N3RegVShFrm   : Format<38>;
  68 def NVExtFrm      : Format<39>;
  69 def NVMulSLFrm    : Format<40>;
  70 def NVTBLFrm      : Format<41>;
  71
  72 // Misc flags.
  73
  74 // the instruction has a Rn register operand.
  75 // UnaryDP - Indicates this is a unary data processing instruction, i.e.
  76 // it doesn't have a Rn operand.
  77 class UnaryDP    { bit isUnaryDataProc = 1; }
  78
  79 // Xform16Bit - Indicates this Thumb2 instruction may be transformed into
  80 // a 16-bit Thumb instruction if certain conditions are met.
  81 class Xform16Bit { bit canXformTo16Bit = 1; }
  82
  83 //===----------------------------------------------------------------------===//
  84 // ARM Instruction flags.  These need to match ARMBaseInstrInfo.h.
  85 //
  86
  87 // Addressing mode.
  88 class AddrMode<bits<5> val> {
  89   bits<5> Value = val;
  90 }
  91 def AddrModeNone    : AddrMode<0>;
  92 def AddrMode1       : AddrMode<1>;
  93 def AddrMode2       : AddrMode<2>;
  94 def AddrMode3       : AddrMode<3>;
  95 def AddrMode4       : AddrMode<4>;
  96 def AddrMode5       : AddrMode<5>;
  97 def AddrMode6       : AddrMode<6>;
  98 def AddrModeT1_1    : AddrMode<7>;
  99 def AddrModeT1_2    : AddrMode<8>;
 100 def AddrModeT1_4    : AddrMode<9>;
 101 def AddrModeT1_s    : AddrMode<10>;
 102 def AddrModeT2_i12  : AddrMode<11>;
 103 def AddrModeT2_i8   : AddrMode<12>;
 104 def AddrModeT2_so   : AddrMode<13>;
 105 def AddrModeT2_pc   : AddrMode<14>;
 106 def AddrModeT2_i8s4 : AddrMode<15>;
 107
 108 // Instruction size.
 109 class SizeFlagVal<bits<3> val> {
 110   bits<3> Value = val;
 111 }
 112 def SizeInvalid  : SizeFlagVal<0>;  // Unset.
 113 def SizeSpecial  : SizeFlagVal<1>;  // Pseudo or special.
 114 def Size8Bytes   : SizeFlagVal<2>;
 115 def Size4Bytes   : SizeFlagVal<3>;
 116 def Size2Bytes   : SizeFlagVal<4>;
 117
 118 // Load / store index mode.
 119 class IndexMode<bits<2> val> {
 120   bits<2> Value = val;
 121 }
 122 def IndexModeNone : IndexMode<0>;
 123 def IndexModePre  : IndexMode<1>;
 124 def IndexModePost : IndexMode<2>;
 125 def IndexModeUpd  : IndexMode<3>;
 126
 127 // Instruction execution domain.
 128 class Domain<bits<2> val> {
 129   bits<2> Value = val;
 130 }
 131 def GenericDomain : Domain<0>;
 132 def VFPDomain     : Domain<1>; // Instructions in VFP domain only
 133 def NeonDomain    : Domain<2>; // Instructions in Neon domain only
 134 def VFPNeonDomain : Domain<3>; // Instructions in both VFP & Neon domains
 135
 136 //===----------------------------------------------------------------------===//
 137
 138 // ARM special operands.
 139 //
 140
 141 def CondCodeOperand : AsmOperandClass {
 142   let Name = "CondCode";
 143   let SuperClasses = [];
 144 }
 145
 146 // ARM Predicate operand. Default to 14 = always (AL). Second part is CC
 147 // register whose default is 0 (no register).
 148 def pred : PredicateOperand<OtherVT, (ops i32imm, CCR),
 149                                      (ops (i32 14), (i32 zero_reg))> {
 150   let PrintMethod = "printPredicateOperand";
 151   let ParserMatchClass = CondCodeOperand;
 152 }
 153
 154 // Conditional code result for instructions whose 's' bit is set, e.g. subs.
 155 def cc_out : OptionalDefOperand<OtherVT, (ops CCR), (ops (i32 zero_reg))> {
 156   string EncoderMethod = "getCCOutOpValue";
 157   let PrintMethod = "printSBitModifierOperand";
 158 }
 159
 160 // Same as cc_out except it defaults to setting CPSR.
 161 def s_cc_out : OptionalDefOperand<OtherVT, (ops CCR), (ops (i32 CPSR))> {
 162   string EncoderMethod = "getCCOutOpValue";
 163   let PrintMethod = "printSBitModifierOperand";
 164 }
 165
 166 // ARM special operands for disassembly only.
 167 //
 168 def setend_op : Operand<i32> {
 169   let PrintMethod = "printSetendOperand";
 170 }
 171
 172 def cps_opt : Operand<i32> {
 173   let PrintMethod = "printCPSOptionOperand";
 174 }
 175
 176 def msr_mask : Operand<i32> {
 177   let PrintMethod = "printMSRMaskOperand";
 178 }
 179
 180 // A8.6.117, A8.6.118.  Different instructions are generated for #0 and #-0.
 181 // The neg_zero operand translates -0 to -1, -1 to -2, ..., etc.
 182 def neg_zero : Operand<i32> {
 183   let PrintMethod = "printNegZeroOperand";
 184 }
 185
 186 //===----------------------------------------------------------------------===//
 187
 188 // ARM Instruction templates.
 189 //
 190
 191 class InstTemplate<AddrMode am, SizeFlagVal sz, IndexMode im,
 192                    Format f, Domain d, string cstr, InstrItinClass itin>
 193   : Instruction {
 194   let Namespace = "ARM";
 195
 196   AddrMode AM = am;
 197   SizeFlagVal SZ = sz;
 198   IndexMode IM = im;
 199   bits<2> IndexModeBits = IM.Value;
 200   Format F = f;
 201   bits<6> Form = F.Value;
 202   Domain D = d;
 203   bit isUnaryDataProc = 0;
 204   bit canXformTo16Bit = 0;
 205
 206   // The layout of TSFlags should be kept in sync with ARMBaseInstrInfo.h.
 207   let TSFlags{4-0}   = AM.Value;
 208   let TSFlags{7-5}   = SZ.Value;
 209   let TSFlags{9-8}   = IndexModeBits;
 210   let TSFlags{15-10} = Form;
 211   let TSFlags{16}    = isUnaryDataProc;
 212   let TSFlags{17}    = canXformTo16Bit;
 213   let TSFlags{19-18} = D.Value;
 214
 215   let Constraints = cstr;
 216   let Itinerary = itin;
 217 }
 218
 219 class Encoding {
 220   field bits<32> Inst;
 221 }
 222
 223 class InstARM<AddrMode am, SizeFlagVal sz, IndexMode im,
 224               Format f, Domain d, string cstr, InstrItinClass itin>
 225   : InstTemplate<am, sz, im, f, d, cstr, itin>, Encoding;
 226
 227 // This Encoding-less class is used by Thumb1 to specify the encoding bits later
 228 // on by adding flavors to specific instructions.
 229 class InstThumb<AddrMode am, SizeFlagVal sz, IndexMode im,
 230                 Format f, Domain d, string cstr, InstrItinClass itin>
 231   : InstTemplate<am, sz, im, f, d, cstr, itin>;
 232
 233 class PseudoInst<dag oops, dag iops, InstrItinClass itin,
 234                  string asm, list<dag> pattern>
 235   : InstARM<AddrModeNone, SizeSpecial, IndexModeNone, Pseudo, GenericDomain,
 236             "", itin> {
 237   let OutOperandList = oops;
 238   let InOperandList = iops;
 239   let AsmString = asm;
 240   let Pattern = pattern;
 241 }
 242
 243 // Almost all ARM instructions are predicable.
 244 class I<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 245         IndexMode im, Format f, InstrItinClass itin,
 246         string opc, string asm, string cstr,
 247         list<dag> pattern>
 248   : InstARM<am, sz, im, f, GenericDomain, cstr, itin> {
 249   bits<4> p;
 250   let Inst{31-28} = p;
 251   let OutOperandList = oops;
 252   let InOperandList = !con(iops, (ins pred:$p));
 253   let AsmString = !strconcat(opc, "${p}", asm);
 254   let Pattern = pattern;
 255   list<Predicate> Predicates = [IsARM];
 256 }
 257
 258 // A few are not predicable
 259 class InoP<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 260            IndexMode im, Format f, InstrItinClass itin,
 261            string opc, string asm, string cstr,
 262            list<dag> pattern>
 263   : InstARM<am, sz, im, f, GenericDomain, cstr, itin> {
 264   let OutOperandList = oops;
 265   let InOperandList = iops;
 266   let AsmString = !strconcat(opc, asm);
 267   let Pattern = pattern;
 268   let isPredicable = 0;
 269   list<Predicate> Predicates = [IsARM];
 270 }
 271
 272 // Same as I except it can optionally modify CPSR. Note it's modeled as an input
 273 // operand since by default it's a zero register. It will become an implicit def
 274 // once it's "flipped".
 275 class sI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 276          IndexMode im, Format f, InstrItinClass itin,
 277          string opc, string asm, string cstr,
 278          list<dag> pattern>
 279   : InstARM<am, sz, im, f, GenericDomain, cstr, itin> {
 280   bits<4> p; // Predicate operand
 281   bits<1> s; // condition-code set flag ('1' if the insn should set the flags)
 282   let Inst{31-28} = p;
 283   let Inst{20} = s;
 284
 285   let OutOperandList = oops;
 286   let InOperandList = !con(iops, (ins pred:$p, cc_out:$s));
 287   let AsmString = !strconcat(opc, "${s}${p}", asm);
 288   let Pattern = pattern;
 289   list<Predicate> Predicates = [IsARM];
 290 }
 291
 292 // Special cases
 293 class XI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 294          IndexMode im, Format f, InstrItinClass itin,
 295          string asm, string cstr, list<dag> pattern>
 296   : InstARM<am, sz, im, f, GenericDomain, cstr, itin> {
 297   let OutOperandList = oops;
 298   let InOperandList = iops;
 299   let AsmString = asm;
 300   let Pattern = pattern;
 301   list<Predicate> Predicates = [IsARM];
 302 }
 303
 304 class AI<dag oops, dag iops, Format f, InstrItinClass itin,
 305          string opc, string asm, list<dag> pattern>
 306   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
 307       opc, asm, "", pattern>;
 308 class AsI<dag oops, dag iops, Format f, InstrItinClass itin,
 309           string opc, string asm, list<dag> pattern>
 310   : sI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
 311        opc, asm, "", pattern>;
 312 class AXI<dag oops, dag iops, Format f, InstrItinClass itin,
 313           string asm, list<dag> pattern>
 314   : XI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
 315        asm, "", pattern>;
 316 class AInoP<dag oops, dag iops, Format f, InstrItinClass itin,
 317             string opc, string asm, list<dag> pattern>
 318   : InoP<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
 319          opc, asm, "", pattern>;
 320
 321 // Ctrl flow instructions
 322 class ABI<bits<4> opcod, dag oops, dag iops, InstrItinClass itin,
 323           string opc, string asm, list<dag> pattern>
 324   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, BrFrm, itin,
 325       opc, asm, "", pattern> {
 326   let Inst{27-24} = opcod;
 327 }
 328 class ABXI<bits<4> opcod, dag oops, dag iops, InstrItinClass itin,
 329            string asm, list<dag> pattern>
 330   : XI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, BrFrm, itin,
 331        asm, "", pattern> {
 332   let Inst{27-24} = opcod;
 333 }
 334 class ABXIx2<dag oops, dag iops, InstrItinClass itin,
 335              string asm, list<dag> pattern>
 336   : XI<oops, iops, AddrModeNone, Size8Bytes, IndexModeNone, Pseudo, itin,
 337        asm, "", pattern>;
 338
 339 // BR_JT instructions
 340 class JTI<dag oops, dag iops, InstrItinClass itin,
 341           string asm, list<dag> pattern>
 342   : XI<oops, iops, AddrModeNone, SizeSpecial, IndexModeNone, BrMiscFrm, itin,
 343        asm, "", pattern>;
 344
 345 // Atomic load/store instructions
 346 class AIldrex<bits<2> opcod, dag oops, dag iops, InstrItinClass itin,
 347               string opc, string asm, list<dag> pattern>
 348   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, LdStExFrm, itin,
 349       opc, asm, "", pattern> {
 350   let Inst{27-23} = 0b00011;
 351   let Inst{22-21} = opcod;
 352   let Inst{20}    = 1;
 353   let Inst{11-0}  = 0b111110011111;
 354 }
 355 class AIstrex<bits<2> opcod, dag oops, dag iops, InstrItinClass itin,
 356               string opc, string asm, list<dag> pattern>
 357   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, LdStExFrm, itin,
 358       opc, asm, "", pattern> {
 359   let Inst{27-23} = 0b00011;
 360   let Inst{22-21} = opcod;
 361   let Inst{20}    = 0;
 362   let Inst{11-4}  = 0b11111001;
 363 }
 364
 365 // addrmode1 instructions
 366 class AI1<bits<4> opcod, dag oops, dag iops, Format f, InstrItinClass itin,
 367           string opc, string asm, list<dag> pattern>
 368   : I<oops, iops, AddrMode1, Size4Bytes, IndexModeNone, f, itin,
 369       opc, asm, "", pattern> {
 370   let Inst{24-21} = opcod;
 371   let Inst{27-26} = 0b00;
 372 }
 373 class AsI1<bits<4> opcod, dag oops, dag iops, Format f, InstrItinClass itin,
 374            string opc, string asm, list<dag> pattern>
 375   : sI<oops, iops, AddrMode1, Size4Bytes, IndexModeNone, f, itin,
 376        opc, asm, "", pattern> {
 377   let Inst{24-21} = opcod;
 378   let Inst{27-26} = 0b00;
 379 }
 380 class AXI1<bits<4> opcod, dag oops, dag iops, Format f, InstrItinClass itin,
 381            string asm, list<dag> pattern>
 382   : XI<oops, iops, AddrMode1, Size4Bytes, IndexModeNone, f, itin,
 383        asm, "", pattern> {
 384   let Inst{24-21} = opcod;
 385   let Inst{27-26} = 0b00;
 386 }
 387 class AI1x2<dag oops, dag iops, Format f, InstrItinClass itin,
 388             string opc, string asm, list<dag> pattern>
 389   : I<oops, iops, AddrMode1, Size8Bytes, IndexModeNone, f, itin,
 390       opc, asm, "", pattern>;
 391
 392
 393 // addrmode2 loads and stores
 394 class AI2<dag oops, dag iops, Format f, InstrItinClass itin,
 395           string opc, string asm, list<dag> pattern>
 396   : I<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 397       opc, asm, "", pattern> {
 398   let Inst{27-26} = 0b01;
 399 }
 400
 401 // loads
 402 class AI2ldw<dag oops, dag iops, Format f, InstrItinClass itin,
 403              string opc, string asm, list<dag> pattern>
 404   : I<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 405       opc, asm, "", pattern> {
 406   let Inst{20}    = 1; // L bit
 407   let Inst{21}    = 0; // W bit
 408   let Inst{22}    = 0; // B bit
 409   let Inst{24}    = 1; // P bit
 410   let Inst{27-26} = 0b01;
 411 }
 412 class AXI2ldw<dag oops, dag iops, Format f, InstrItinClass itin,
 413               string asm, list<dag> pattern>
 414   : XI<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 415        asm, "", pattern> {
 416   let Inst{20}    = 1; // L bit
 417   let Inst{21}    = 0; // W bit
 418   let Inst{22}    = 0; // B bit
 419   let Inst{24}    = 1; // P bit
 420   let Inst{27-26} = 0b01;
 421 }
 422 class AI2ldb<dag oops, dag iops, Format f, InstrItinClass itin,
 423              string opc, string asm, list<dag> pattern>
 424   : I<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 425       opc, asm, "", pattern> {
 426   let Inst{20}    = 1; // L bit
 427   let Inst{21}    = 0; // W bit
 428   let Inst{22}    = 1; // B bit
 429   let Inst{24}    = 1; // P bit
 430   let Inst{27-26} = 0b01;
 431 }
 432 class AXI2ldb<dag oops, dag iops, Format f, InstrItinClass itin,
 433               string asm, list<dag> pattern>
 434   : XI<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 435        asm, "", pattern> {
 436   let Inst{20}    = 1; // L bit
 437   let Inst{21}    = 0; // W bit
 438   let Inst{22}    = 1; // B bit
 439   let Inst{24}    = 1; // P bit
 440   let Inst{27-26} = 0b01;
 441 }
 442
 443 // stores
 444 class AI2stw<dag oops, dag iops, Format f, InstrItinClass itin,
 445              string opc, string asm, list<dag> pattern>
 446   : I<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 447       opc, asm, "", pattern> {
 448   let Inst{20}    = 0; // L bit
 449   let Inst{21}    = 0; // W bit
 450   let Inst{22}    = 0; // B bit
 451   let Inst{24}    = 1; // P bit
 452   let Inst{27-26} = 0b01;
 453 }
 454 class AXI2stw<dag oops, dag iops, Format f, InstrItinClass itin,
 455               string asm, list<dag> pattern>
 456   : XI<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 457        asm, "", pattern> {
 458   let Inst{20}    = 0; // L bit
 459   let Inst{21}    = 0; // W bit
 460   let Inst{22}    = 0; // B bit
 461   let Inst{24}    = 1; // P bit
 462   let Inst{27-26} = 0b01;
 463 }
 464 class AI2stb<dag oops, dag iops, Format f, InstrItinClass itin,
 465              string opc, string asm, list<dag> pattern>
 466   : I<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 467       opc, asm, "", pattern> {
 468   let Inst{20}    = 0; // L bit
 469   let Inst{21}    = 0; // W bit
 470   let Inst{22}    = 1; // B bit
 471   let Inst{24}    = 1; // P bit
 472   let Inst{27-26} = 0b01;
 473 }
 474 class AXI2stb<dag oops, dag iops, Format f, InstrItinClass itin,
 475               string asm, list<dag> pattern>
 476   : XI<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 477        asm, "", pattern> {
 478   let Inst{20}    = 0; // L bit
 479   let Inst{21}    = 0; // W bit
 480   let Inst{22}    = 1; // B bit
 481   let Inst{24}    = 1; // P bit
 482   let Inst{27-26} = 0b01;
 483 }
 484
 485 // Pre-indexed loads
 486 class AI2ldwpr<dag oops, dag iops, Format f, InstrItinClass itin,
 487                string opc, string asm, string cstr, list<dag> pattern>
 488   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePre, f, itin,
 489       opc, asm, cstr, pattern> {
 490   let Inst{20}    = 1; // L bit
 491   let Inst{21}    = 1; // W bit
 492   let Inst{22}    = 0; // B bit
 493   let Inst{24}    = 1; // P bit
 494   let Inst{27-26} = 0b01;
 495 }
 496 class AI2ldbpr<dag oops, dag iops, Format f, InstrItinClass itin,
 497                string opc, string asm, string cstr, list<dag> pattern>
 498   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePre, f, itin,
 499       opc, asm, cstr, pattern> {
 500   let Inst{20}    = 1; // L bit
 501   let Inst{21}    = 1; // W bit
 502   let Inst{22}    = 1; // B bit
 503   let Inst{24}    = 1; // P bit
 504   let Inst{27-26} = 0b01;
 505 }
 506
 507 // Pre-indexed stores
 508 class AI2stwpr<dag oops, dag iops, Format f, InstrItinClass itin,
 509                string opc, string asm, string cstr, list<dag> pattern>
 510   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePre, f, itin,
 511       opc, asm, cstr, pattern> {
 512   let Inst{20}    = 0; // L bit
 513   let Inst{21}    = 1; // W bit
 514   let Inst{22}    = 0; // B bit
 515   let Inst{24}    = 1; // P bit
 516   let Inst{27-26} = 0b01;
 517 }
 518 class AI2stbpr<dag oops, dag iops, Format f, InstrItinClass itin,
 519                string opc, string asm, string cstr, list<dag> pattern>
 520   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePre, f, itin,
 521       opc, asm, cstr, pattern> {
 522   let Inst{20}    = 0; // L bit
 523   let Inst{21}    = 1; // W bit
 524   let Inst{22}    = 1; // B bit
 525   let Inst{24}    = 1; // P bit
 526   let Inst{27-26} = 0b01;
 527 }
 528
 529 // Post-indexed loads
 530 class AI2ldwpo<dag oops, dag iops, Format f, InstrItinClass itin,
 531                string opc, string asm, string cstr, list<dag> pattern>
 532   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePost, f, itin,
 533       opc, asm, cstr,pattern> {
 534   let Inst{20}    = 1; // L bit
 535   let Inst{21}    = 0; // W bit
 536   let Inst{22}    = 0; // B bit
 537   let Inst{24}    = 0; // P bit
 538   let Inst{27-26} = 0b01;
 539 }
 540 class AI2ldbpo<dag oops, dag iops, Format f, InstrItinClass itin,
 541                string opc, string asm, string cstr, list<dag> pattern>
 542   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePost, f, itin,
 543       opc, asm, cstr,pattern> {
 544   let Inst{20}    = 1; // L bit
 545   let Inst{21}    = 0; // W bit
 546   let Inst{22}    = 1; // B bit
 547   let Inst{24}    = 0; // P bit
 548   let Inst{27-26} = 0b01;
 549 }
 550
 551 // Post-indexed stores
 552 class AI2stwpo<dag oops, dag iops, Format f, InstrItinClass itin,
 553                string opc, string asm, string cstr, list<dag> pattern>
 554   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePost, f, itin,
 555       opc, asm, cstr,pattern> {
 556   let Inst{20}    = 0; // L bit
 557   let Inst{21}    = 0; // W bit
 558   let Inst{22}    = 0; // B bit
 559   let Inst{24}    = 0; // P bit
 560   let Inst{27-26} = 0b01;
 561 }
 562 class AI2stbpo<dag oops, dag iops, Format f, InstrItinClass itin,
 563                string opc, string asm, string cstr, list<dag> pattern>
 564   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePost, f, itin,
 565       opc, asm, cstr,pattern> {
 566   let Inst{20}    = 0; // L bit
 567   let Inst{21}    = 0; // W bit
 568   let Inst{22}    = 1; // B bit
 569   let Inst{24}    = 0; // P bit
 570   let Inst{27-26} = 0b01;
 571 }
 572
 573 // addrmode3 instructions
 574 class AI3<dag oops, dag iops, Format f, InstrItinClass itin,
 575           string opc, string asm, list<dag> pattern>
 576   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 577       opc, asm, "", pattern>;
 578 class AXI3<dag oops, dag iops, Format f, InstrItinClass itin,
 579            string asm, list<dag> pattern>
 580   : XI<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 581        asm, "", pattern>;
 582
 583 // loads
 584 class AI3ldh<dag oops, dag iops, Format f, InstrItinClass itin,
 585              string opc, string asm, list<dag> pattern>
 586   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 587       opc, asm, "", pattern> {
 588   let Inst{4}     = 1;
 589   let Inst{5}     = 1; // H bit
 590   let Inst{6}     = 0; // S bit
 591   let Inst{7}     = 1;
 592   let Inst{20}    = 1; // L bit
 593   let Inst{21}    = 0; // W bit
 594   let Inst{24}    = 1; // P bit
 595   let Inst{27-25} = 0b000;
 596 }
 597 class AXI3ldh<dag oops, dag iops, Format f, InstrItinClass itin,
 598               string asm, list<dag> pattern>
 599   : XI<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 600        asm, "", pattern> {
 601   let Inst{4}     = 1;
 602   let Inst{5}     = 1; // H bit
 603   let Inst{6}     = 0; // S bit
 604   let Inst{7}     = 1;
 605   let Inst{20}    = 1; // L bit
 606   let Inst{21}    = 0; // W bit
 607   let Inst{24}    = 1; // P bit
 608 }
 609 class AI3ldsh<dag oops, dag iops, Format f, InstrItinClass itin,
 610               string opc, string asm, list<dag> pattern>
 611   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 612       opc, asm, "", pattern> {
 613   let Inst{4}     = 1;
 614   let Inst{5}     = 1; // H bit
 615   let Inst{6}     = 1; // S bit
 616   let Inst{7}     = 1;
 617   let Inst{20}    = 1; // L bit
 618   let Inst{21}    = 0; // W bit
 619   let Inst{24}    = 1; // P bit
 620   let Inst{27-25} = 0b000;
 621 }
 622 class AXI3ldsh<dag oops, dag iops, Format f, InstrItinClass itin,
 623                string asm, list<dag> pattern>
 624   : XI<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 625        asm, "", pattern> {
 626   let Inst{4}     = 1;
 627   let Inst{5}     = 1; // H bit
 628   let Inst{6}     = 1; // S bit
 629   let Inst{7}     = 1;
 630   let Inst{20}    = 1; // L bit
 631   let Inst{21}    = 0; // W bit
 632   let Inst{24}    = 1; // P bit
 633 }
 634 class AI3ldsb<dag oops, dag iops, Format f, InstrItinClass itin,
 635               string opc, string asm, list<dag> pattern>
 636   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 637       opc, asm, "", pattern> {
 638   let Inst{4}     = 1;
 639   let Inst{5}     = 0; // H bit
 640   let Inst{6}     = 1; // S bit
 641   let Inst{7}     = 1;
 642   let Inst{20}    = 1; // L bit
 643   let Inst{21}    = 0; // W bit
 644   let Inst{24}    = 1; // P bit
 645   let Inst{27-25} = 0b000;
 646 }
 647 class AXI3ldsb<dag oops, dag iops, Format f, InstrItinClass itin,
 648                string asm, list<dag> pattern>
 649   : XI<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 650        asm, "", pattern> {
 651   let Inst{4}     = 1;
 652   let Inst{5}     = 0; // H bit
 653   let Inst{6}     = 1; // S bit
 654   let Inst{7}     = 1;
 655   let Inst{20}    = 1; // L bit
 656   let Inst{21}    = 0; // W bit
 657   let Inst{24}    = 1; // P bit
 658 }
 659 class AI3ldd<dag oops, dag iops, Format f, InstrItinClass itin,
 660              string opc, string asm, list<dag> pattern>
 661   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 662       opc, asm, "", pattern> {
 663   let Inst{4}     = 1;
 664   let Inst{5}     = 0; // H bit
 665   let Inst{6}     = 1; // S bit
 666   let Inst{7}     = 1;
 667   let Inst{20}    = 0; // L bit
 668   let Inst{21}    = 0; // W bit
 669   let Inst{24}    = 1; // P bit
 670   let Inst{27-25} = 0b000;
 671 }
 672
 673 // stores
 674 class AI3sth<dag oops, dag iops, Format f, InstrItinClass itin,
 675              string opc, string asm, list<dag> pattern>
 676   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 677       opc, asm, "", pattern> {
 678   let Inst{4}     = 1;
 679   let Inst{5}     = 1; // H bit
 680   let Inst{6}     = 0; // S bit
 681   let Inst{7}     = 1;
 682   let Inst{20}    = 0; // L bit
 683   let Inst{21}    = 0; // W bit
 684   let Inst{24}    = 1; // P bit
 685   let Inst{27-25} = 0b000;
 686 }
 687 class AXI3sth<dag oops, dag iops, Format f, InstrItinClass itin,
 688               string asm, list<dag> pattern>
 689   : XI<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 690        asm, "", pattern> {
 691   let Inst{4}     = 1;
 692   let Inst{5}     = 1; // H bit
 693   let Inst{6}     = 0; // S bit
 694   let Inst{7}     = 1;
 695   let Inst{20}    = 0; // L bit
 696   let Inst{21}    = 0; // W bit
 697   let Inst{24}    = 1; // P bit
 698 }
 699 class AI3std<dag oops, dag iops, Format f, InstrItinClass itin,
 700              string opc, string asm, list<dag> pattern>
 701   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 702       opc, asm, "", pattern> {
 703   let Inst{4}     = 1;
 704   let Inst{5}     = 1; // H bit
 705   let Inst{6}     = 1; // S bit
 706   let Inst{7}     = 1;
 707   let Inst{20}    = 0; // L bit
 708   let Inst{21}    = 0; // W bit
 709   let Inst{24}    = 1; // P bit
 710   let Inst{27-25} = 0b000;
 711 }
 712
 713 // Pre-indexed loads
 714 class AI3ldhpr<dag oops, dag iops, Format f, InstrItinClass itin,
 715                string opc, string asm, string cstr, list<dag> pattern>
 716   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePre, f, itin,
 717       opc, asm, cstr, pattern> {
 718   let Inst{4}     = 1;
 719   let Inst{5}     = 1; // H bit
 720   let Inst{6}     = 0; // S bit
 721   let Inst{7}     = 1;
 722   let Inst{20}    = 1; // L bit
 723   let Inst{21}    = 1; // W bit
 724   let Inst{24}    = 1; // P bit
 725   let Inst{27-25} = 0b000;
 726 }
 727 class AI3ldshpr<dag oops, dag iops, Format f, InstrItinClass itin,
 728                 string opc, string asm, string cstr, list<dag> pattern>
 729   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePre, f, itin,
 730       opc, asm, cstr, pattern> {
 731   let Inst{4}     = 1;
 732   let Inst{5}     = 1; // H bit
 733   let Inst{6}     = 1; // S bit
 734   let Inst{7}     = 1;
 735   let Inst{20}    = 1; // L bit
 736   let Inst{21}    = 1; // W bit
 737   let Inst{24}    = 1; // P bit
 738   let Inst{27-25} = 0b000;
 739 }
 740 class AI3ldsbpr<dag oops, dag iops, Format f, InstrItinClass itin,
 741                 string opc, string asm, string cstr, list<dag> pattern>
 742   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePre, f, itin,
 743       opc, asm, cstr, pattern> {
 744   let Inst{4}     = 1;
 745   let Inst{5}     = 0; // H bit
 746   let Inst{6}     = 1; // S bit
 747   let Inst{7}     = 1;
 748   let Inst{20}    = 1; // L bit
 749   let Inst{21}    = 1; // W bit
 750   let Inst{24}    = 1; // P bit
 751   let Inst{27-25} = 0b000;
 752 }
 753 class AI3lddpr<dag oops, dag iops, Format f, InstrItinClass itin,
 754              string opc, string asm, string cstr, list<dag> pattern>
 755   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePre, f, itin,
 756       opc, asm, cstr, pattern> {
 757   let Inst{4}     = 1;
 758   let Inst{5}     = 0; // H bit
 759   let Inst{6}     = 1; // S bit
 760   let Inst{7}     = 1;
 761   let Inst{20}    = 0; // L bit
 762   let Inst{21}    = 1; // W bit
 763   let Inst{24}    = 1; // P bit
 764   let Inst{27-25} = 0b000;
 765 }
 766
 767
 768 // Pre-indexed stores
 769 class AI3sthpr<dag oops, dag iops, Format f, InstrItinClass itin,
 770                string opc, string asm, string cstr, list<dag> pattern>
 771   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePre, f, itin,
 772       opc, asm, cstr, pattern> {
 773   let Inst{4}     = 1;
 774   let Inst{5}     = 1; // H bit
 775   let Inst{6}     = 0; // S bit
 776   let Inst{7}     = 1;
 777   let Inst{20}    = 0; // L bit
 778   let Inst{21}    = 1; // W bit
 779   let Inst{24}    = 1; // P bit
 780   let Inst{27-25} = 0b000;
 781 }
 782 class AI3stdpr<dag oops, dag iops, Format f, InstrItinClass itin,
 783              string opc, string asm, string cstr, list<dag> pattern>
 784   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePre, f, itin,
 785       opc, asm, cstr, pattern> {
 786   let Inst{4}     = 1;
 787   let Inst{5}     = 1; // H bit
 788   let Inst{6}     = 1; // S bit
 789   let Inst{7}     = 1;
 790   let Inst{20}    = 0; // L bit
 791   let Inst{21}    = 1; // W bit
 792   let Inst{24}    = 1; // P bit
 793   let Inst{27-25} = 0b000;
 794 }
 795
 796 // Post-indexed loads
 797 class AI3ldhpo<dag oops, dag iops, Format f, InstrItinClass itin,
 798                string opc, string asm, string cstr, list<dag> pattern>
 799   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePost, f, itin,
 800       opc, asm, cstr,pattern> {
 801   let Inst{4}     = 1;
 802   let Inst{5}     = 1; // H bit
 803   let Inst{6}     = 0; // S bit
 804   let Inst{7}     = 1;
 805   let Inst{20}    = 1; // L bit
 806   let Inst{21}    = 0; // W bit
 807   let Inst{24}    = 0; // P bit
 808   let Inst{27-25} = 0b000;
 809 }
 810 class AI3ldshpo<dag oops, dag iops, Format f, InstrItinClass itin,
 811                 string opc, string asm, string cstr, list<dag> pattern>
 812   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePost, f, itin,
 813       opc, asm, cstr,pattern> {
 814   let Inst{4}     = 1;
 815   let Inst{5}     = 1; // H bit
 816   let Inst{6}     = 1; // S bit
 817   let Inst{7}     = 1;
 818   let Inst{20}    = 1; // L bit
 819   let Inst{21}    = 0; // W bit
 820   let Inst{24}    = 0; // P bit
 821   let Inst{27-25} = 0b000;
 822 }
 823 class AI3ldsbpo<dag oops, dag iops, Format f, InstrItinClass itin,
 824                 string opc, string asm, string cstr, list<dag> pattern>
 825   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePost, f, itin,
 826       opc, asm, cstr,pattern> {
 827   let Inst{4}     = 1;
 828   let Inst{5}     = 0; // H bit
 829   let Inst{6}     = 1; // S bit
 830   let Inst{7}     = 1;
 831   let Inst{20}    = 1; // L bit
 832   let Inst{21}    = 0; // W bit
 833   let Inst{24}    = 0; // P bit
 834   let Inst{27-25} = 0b000;
 835 }
 836 class AI3lddpo<dag oops, dag iops, Format f, InstrItinClass itin,
 837              string opc, string asm, string cstr, list<dag> pattern>
 838   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePost, f, itin,
 839       opc, asm, cstr, pattern> {
 840   let Inst{4}     = 1;
 841   let Inst{5}     = 0; // H bit
 842   let Inst{6}     = 1; // S bit
 843   let Inst{7}     = 1;
 844   let Inst{20}    = 0; // L bit
 845   let Inst{21}    = 0; // W bit
 846   let Inst{24}    = 0; // P bit
 847   let Inst{27-25} = 0b000;
 848 }
 849
 850 // Post-indexed stores
 851 class AI3sthpo<dag oops, dag iops, Format f, InstrItinClass itin,
 852                string opc, string asm, string cstr, list<dag> pattern>
 853   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePost, f, itin,
 854       opc, asm, cstr,pattern> {
 855   let Inst{4}     = 1;
 856   let Inst{5}     = 1; // H bit
 857   let Inst{6}     = 0; // S bit
 858   let Inst{7}     = 1;
 859   let Inst{20}    = 0; // L bit
 860   let Inst{21}    = 0; // W bit
 861   let Inst{24}    = 0; // P bit
 862   let Inst{27-25} = 0b000;
 863 }
 864 class AI3stdpo<dag oops, dag iops, Format f, InstrItinClass itin,
 865              string opc, string asm, string cstr, list<dag> pattern>
 866   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePost, f, itin,
 867       opc, asm, cstr, pattern> {
 868   let Inst{4}     = 1;
 869   let Inst{5}     = 1; // H bit
 870   let Inst{6}     = 1; // S bit
 871   let Inst{7}     = 1;
 872   let Inst{20}    = 0; // L bit
 873   let Inst{21}    = 0; // W bit
 874   let Inst{24}    = 0; // P bit
 875   let Inst{27-25} = 0b000;
 876 }
 877
 878 // addrmode4 instructions
 879 class AXI4ld<dag oops, dag iops, IndexMode im, Format f, InstrItinClass itin,
 880              string asm, string cstr, list<dag> pattern>
 881   : XI<oops, iops, AddrMode4, Size4Bytes, im, f, itin,
 882        asm, cstr, pattern> {
 883   let Inst{20}    = 1; // L bit
 884   let Inst{22}    = 0; // S bit
 885   let Inst{27-25} = 0b100;
 886 }
 887 class AXI4st<dag oops, dag iops, IndexMode im, Format f, InstrItinClass itin,
 888              string asm, string cstr, list<dag> pattern>
 889   : XI<oops, iops, AddrMode4, Size4Bytes, im, f, itin,
 890        asm, cstr, pattern> {
 891   let Inst{20}    = 0; // L bit
 892   let Inst{22}    = 0; // S bit
 893   let Inst{27-25} = 0b100;
 894 }
 895
 896 // Unsigned multiply, multiply-accumulate instructions.
 897 class AMul1I<bits<7> opcod, dag oops, dag iops, InstrItinClass itin,
 898              string opc, string asm, list<dag> pattern>
 899   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, MulFrm, itin,
 900       opc, asm, "", pattern> {
 901   let Inst{7-4}   = 0b1001;
 902   let Inst{20}    = 0; // S bit
 903   let Inst{27-21} = opcod;
 904 }
 905 class AsMul1I<bits<7> opcod, dag oops, dag iops, InstrItinClass itin,
 906               string opc, string asm, list<dag> pattern>
 907   : sI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, MulFrm, itin,
 908        opc, asm, "", pattern> {
 909   let Inst{7-4}   = 0b1001;
 910   let Inst{27-21} = opcod;
 911 }
 912
 913 // Most significant word multiply
 914 class AMul2I<bits<7> opcod, dag oops, dag iops, InstrItinClass itin,
 915              string opc, string asm, list<dag> pattern>
 916   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, MulFrm, itin,
 917       opc, asm, "", pattern> {
 918   let Inst{7-4}   = 0b1001;
 919   let Inst{20}    = 1;
 920   let Inst{27-21} = opcod;
 921 }
 922
 923 // SMUL<x><y> / SMULW<y> / SMLA<x><y> / SMLAW<x><y>
 924 class AMulxyI<bits<7> opcod, dag oops, dag iops, InstrItinClass itin,
 925               string opc, string asm, list<dag> pattern>
 926   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, MulFrm, itin,
 927       opc, asm, "", pattern> {
 928   let Inst{4}     = 0;
 929   let Inst{7}     = 1;
 930   let Inst{20}    = 0;
 931   let Inst{27-21} = opcod;
 932 }
 933
 934 // Extend instructions.
 935 class AExtI<bits<8> opcod, dag oops, dag iops, InstrItinClass itin,
 936             string opc, string asm, list<dag> pattern>
 937   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, ExtFrm, itin,
 938       opc, asm, "", pattern> {
 939   // All AExtI instructions have Rd and Rm register operands.
 940   bits<4> Rd;
 941   bits<4> Rm;
 942   let Inst{15-12} = Rd;
 943   let Inst{3-0}   = Rm;
 944   let Inst{7-4}   = 0b0111;
 945   let Inst{9-8}   = 0b00;
 946   let Inst{27-20} = opcod;
 947 }
 948
 949 // Misc Arithmetic instructions.
 950 class AMiscA1I<bits<8> opcod, dag oops, dag iops, InstrItinClass itin,
 951                string opc, string asm, list<dag> pattern>
 952   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, ArithMiscFrm, itin,
 953       opc, asm, "", pattern> {
 954   let Inst{27-20} = opcod;
 955 }
 956
 957 //===----------------------------------------------------------------------===//
 958
 959 // ARMPat - Same as Pat<>, but requires that the compiler be in ARM mode.
 960 class ARMPat<dag pattern, dag result> : Pat<pattern, result> {
 961   list<Predicate> Predicates = [IsARM];
 962 }
 963 class ARMV5TEPat<dag pattern, dag result> : Pat<pattern, result> {
 964   list<Predicate> Predicates = [IsARM, HasV5TE];
 965 }
 966 class ARMV6Pat<dag pattern, dag result> : Pat<pattern, result> {
 967   list<Predicate> Predicates = [IsARM, HasV6];
 968 }
 969
 970 //===----------------------------------------------------------------------===//
 971 //
 972 // Thumb Instruction Format Definitions.
 973 //
 974
 975 // TI - Thumb instruction.
 976
 977 class ThumbI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 978              InstrItinClass itin, string asm, string cstr, list<dag> pattern>
 979   : InstThumb<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
 980   let OutOperandList = oops;
 981   let InOperandList = iops;
 982   let AsmString = asm;
 983   let Pattern = pattern;
 984   list<Predicate> Predicates = [IsThumb];
 985 }
 986
 987 class TI<dag oops, dag iops, InstrItinClass itin, string asm, list<dag> pattern>
 988   : ThumbI<oops, iops, AddrModeNone, Size2Bytes, itin, asm, "", pattern>;
 989
 990 // Two-address instructions
 991 class TIt<dag oops, dag iops, InstrItinClass itin, string asm,
 992           list<dag> pattern>
 993   : ThumbI<oops, iops, AddrModeNone, Size2Bytes, itin, asm, "$lhs = $dst",
 994            pattern>;
 995
 996 // tBL, tBX 32-bit instructions
 997 class TIx2<bits<5> opcod1, bits<2> opcod2, bit opcod3,
 998            dag oops, dag iops, InstrItinClass itin, string asm,
 999            list<dag> pattern>
1000     : ThumbI<oops, iops, AddrModeNone, Size4Bytes, itin, asm, "", pattern>,
1001       Encoding {
1002   let Inst{31-27} = opcod1;
1003   let Inst{15-14} = opcod2;
1004   let Inst{12}    = opcod3;
1005 }
1006
1007 // BR_JT instructions
1008 class TJTI<dag oops, dag iops, InstrItinClass itin, string asm,
1009            list<dag> pattern>
1010   : ThumbI<oops, iops, AddrModeNone, SizeSpecial, itin, asm, "", pattern>;
1011
1012 // Thumb1 only
1013 class Thumb1I<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1014               InstrItinClass itin, string asm, string cstr, list<dag> pattern>
1015   : InstThumb<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1016   let OutOperandList = oops;
1017   let InOperandList = iops;
1018   let AsmString = asm;
1019   let Pattern = pattern;
1020   list<Predicate> Predicates = [IsThumb1Only];
1021 }
1022
1023 class T1I<dag oops, dag iops, InstrItinClass itin,
1024           string asm, list<dag> pattern>
1025   : Thumb1I<oops, iops, AddrModeNone, Size2Bytes, itin, asm, "", pattern>;
1026 class T1Ix2<dag oops, dag iops, InstrItinClass itin,
1027             string asm, list<dag> pattern>
1028   : Thumb1I<oops, iops, AddrModeNone, Size4Bytes, itin, asm, "", pattern>;
1029 class T1JTI<dag oops, dag iops, InstrItinClass itin,
1030             string asm, list<dag> pattern>
1031   : Thumb1I<oops, iops, AddrModeNone, SizeSpecial, itin, asm, "", pattern>;
1032
1033 // Two-address instructions
1034 class T1It<dag oops, dag iops, InstrItinClass itin,
1035            string asm, string cstr, list<dag> pattern>
1036   : Thumb1I<oops, iops, AddrModeNone, Size2Bytes, itin,
1037             asm, cstr, pattern>;
1038
1039 // Thumb1 instruction that can either be predicated or set CPSR.
1040 class Thumb1sI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1041                InstrItinClass itin,
1042                string opc, string asm, string cstr, list<dag> pattern>
1043   : InstThumb<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1044   let OutOperandList = !con(oops, (outs s_cc_out:$s));
1045   let InOperandList = !con(iops, (ins pred:$p));
1046   let AsmString = !strconcat(opc, "${s}${p}", asm);
1047   let Pattern = pattern;
1048   list<Predicate> Predicates = [IsThumb1Only];
1049 }
1050
1051 class T1sI<dag oops, dag iops, InstrItinClass itin,
1052            string opc, string asm, list<dag> pattern>
1053   : Thumb1sI<oops, iops, AddrModeNone, Size2Bytes, itin, opc, asm, "", pattern>;
1054
1055 // Two-address instructions
1056 class T1sIt<dag oops, dag iops, InstrItinClass itin,
1057             string opc, string asm, list<dag> pattern>
1058   : Thumb1sI<oops, iops, AddrModeNone, Size2Bytes, itin, opc, asm,
1059              "$lhs = $dst", pattern>;
1060
1061 // Thumb1 instruction that can be predicated.
1062 class Thumb1pI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1063                InstrItinClass itin,
1064                string opc, string asm, string cstr, list<dag> pattern>
1065   : InstThumb<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1066   let OutOperandList = oops;
1067   let InOperandList = !con(iops, (ins pred:$p));
1068   let AsmString = !strconcat(opc, "${p}", asm);
1069   let Pattern = pattern;
1070   list<Predicate> Predicates = [IsThumb1Only];
1071 }
1072
1073 class T1pI<dag oops, dag iops, InstrItinClass itin,
1074            string opc, string asm, list<dag> pattern>
1075   : Thumb1pI<oops, iops, AddrModeNone, Size2Bytes, itin, opc, asm, "", pattern>;
1076
1077 // Two-address instructions
1078 class T1pIt<dag oops, dag iops, InstrItinClass itin,
1079             string opc, string asm, list<dag> pattern>
1080   : Thumb1pI<oops, iops, AddrModeNone, Size2Bytes, itin, opc, asm,
1081              "$lhs = $dst", pattern>;
1082
1083 class T1pI1<dag oops, dag iops, InstrItinClass itin,
1084             string opc, string asm, list<dag> pattern>
1085   : Thumb1pI<oops, iops, AddrModeT1_1, Size2Bytes, itin, opc, asm, "", pattern>;
1086 class T1pI2<dag oops, dag iops, InstrItinClass itin,
1087             string opc, string asm, list<dag> pattern>
1088   : Thumb1pI<oops, iops, AddrModeT1_2, Size2Bytes, itin, opc, asm, "", pattern>;
1089 class T1pI4<dag oops, dag iops, InstrItinClass itin,
1090             string opc, string asm, list<dag> pattern>
1091   : Thumb1pI<oops, iops, AddrModeT1_4, Size2Bytes, itin, opc, asm, "", pattern>;
1092 class T1pIs<dag oops, dag iops,
1093             InstrItinClass itin, string opc, string asm, list<dag> pattern>
1094   : Thumb1pI<oops, iops, AddrModeT1_s, Size2Bytes, itin, opc, asm, "", pattern>;
1095
1096 class Encoding16 : Encoding {
1097   let Inst{31-16} = 0x0000;
1098 }
1099
1100 // A6.2 16-bit Thumb instruction encoding
1101 class T1Encoding<bits<6> opcode> : Encoding16 {
1102   let Inst{15-10} = opcode;
1103 }
1104
1105 // A6.2.1 Shift (immediate), add, subtract, move, and compare encoding.
1106 class T1General<bits<5> opcode> : Encoding16 {
1107   let Inst{15-14} = 0b00;
1108   let Inst{13-9} = opcode;
1109 }
1110
1111 // A6.2.2 Data-processing encoding.
1112 class T1DataProcessing<bits<4> opcode> : Encoding16 {
1113   let Inst{15-10} = 0b010000;
1114   let Inst{9-6} = opcode;
1115 }
1116
1117 // A6.2.3 Special data instructions and branch and exchange encoding.
1118 class T1Special<bits<4> opcode> : Encoding16 {
1119   let Inst{15-10} = 0b010001;
1120   let Inst{9-6} = opcode;
1121 }
1122
1123 // A6.2.4 Load/store single data item encoding.
1124 class T1LoadStore<bits<4> opA, bits<3> opB> : Encoding16 {
1125   let Inst{15-12} = opA;
1126   let Inst{11-9}  = opB;
1127 }
1128 class T1LdSt<bits<3> opB>     : T1LoadStore<0b0101, opB>;
1129 class T1LdSt4Imm<bits<3> opB> : T1LoadStore<0b0110, opB>; // Immediate, 4 bytes
1130 class T1LdSt1Imm<bits<3> opB> : T1LoadStore<0b0111, opB>; // Immediate, 1 byte
1131 class T1LdSt2Imm<bits<3> opB> : T1LoadStore<0b1000, opB>; // Immediate, 2 bytes
1132 class T1LdStSP<bits<3> opB>   : T1LoadStore<0b1001, opB>; // SP relative
1133
1134 // A6.2.5 Miscellaneous 16-bit instructions encoding.
1135 class T1Misc<bits<7> opcode> : Encoding16 {
1136   let Inst{15-12} = 0b1011;
1137   let Inst{11-5} = opcode;
1138 }
1139
1140 // Thumb2I - Thumb2 instruction. Almost all Thumb2 instructions are predicable.
1141 class Thumb2I<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1142               InstrItinClass itin,
1143               string opc, string asm, string cstr, list<dag> pattern>
1144   : InstARM<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1145   let OutOperandList = oops;
1146   let InOperandList = !con(iops, (ins pred:$p));
1147   let AsmString = !strconcat(opc, "${p}", asm);
1148   let Pattern = pattern;
1149   list<Predicate> Predicates = [IsThumb2];
1150 }
1151
1152 // Same as Thumb2I except it can optionally modify CPSR. Note it's modeled as an
1153 // input operand since by default it's a zero register. It will become an
1154 // implicit def once it's "flipped".
1155 //
1156 // FIXME: This uses unified syntax so {s} comes before {p}. We should make it
1157 // more consistent.
1158 class Thumb2sI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1159                InstrItinClass itin,
1160                string opc, string asm, string cstr, list<dag> pattern>
1161   : InstARM<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1162   let OutOperandList = oops;
1163   let InOperandList = !con(iops, (ins pred:$p, cc_out:$s));
1164   let AsmString = !strconcat(opc, "${s}${p}", asm);
1165   let Pattern = pattern;
1166   list<Predicate> Predicates = [IsThumb2];
1167 }
1168
1169 // Special cases
1170 class Thumb2XI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1171                InstrItinClass itin,
1172                string asm, string cstr, list<dag> pattern>
1173   : InstARM<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1174   let OutOperandList = oops;
1175   let InOperandList = iops;
1176   let AsmString = asm;
1177   let Pattern = pattern;
1178   list<Predicate> Predicates = [IsThumb2];
1179 }
1180
1181 class ThumbXI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1182               InstrItinClass itin,
1183               string asm, string cstr, list<dag> pattern>
1184   : InstARM<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1185   let OutOperandList = oops;
1186   let InOperandList = iops;
1187   let AsmString = asm;
1188   let Pattern = pattern;
1189   list<Predicate> Predicates = [IsThumb1Only];
1190 }
1191
1192 class T2I<dag oops, dag iops, InstrItinClass itin,
1193           string opc, string asm, list<dag> pattern>
1194   : Thumb2I<oops, iops, AddrModeNone, Size4Bytes, itin, opc, asm, "", pattern>;
1195 class T2Ii12<dag oops, dag iops, InstrItinClass itin,
1196              string opc, string asm, list<dag> pattern>
1197   : Thumb2I<oops, iops, AddrModeT2_i12, Size4Bytes, itin, opc, asm, "",pattern>;
1198 class T2Ii8<dag oops, dag iops, InstrItinClass itin,
1199             string opc, string asm, list<dag> pattern>
1200   : Thumb2I<oops, iops, AddrModeT2_i8, Size4Bytes, itin, opc, asm, "", pattern>;
1201 class T2Iso<dag oops, dag iops, InstrItinClass itin,
1202             string opc, string asm, list<dag> pattern>
1203   : Thumb2I<oops, iops, AddrModeT2_so, Size4Bytes, itin, opc, asm, "", pattern>;
1204 class T2Ipc<dag oops, dag iops, InstrItinClass itin,
1205             string opc, string asm, list<dag> pattern>
1206   : Thumb2I<oops, iops, AddrModeT2_pc, Size4Bytes, itin, opc, asm, "", pattern>;
1207 class T2Ii8s4<bit P, bit W, bit load, dag oops, dag iops, InstrItinClass itin,
1208               string opc, string asm, list<dag> pattern>
1209   : Thumb2I<oops, iops, AddrModeT2_i8s4, Size4Bytes, itin, opc, asm, "",
1210             pattern> {
1211   let Inst{31-27} = 0b11101;
1212   let Inst{26-25} = 0b00;
1213   let Inst{24}    = P;
1214   let Inst{23}    = ?; // The U bit.
1215   let Inst{22}    = 1;
1216   let Inst{21}    = W;
1217   let Inst{20}    = load;
1218 }
1219
1220 class T2sI<dag oops, dag iops, InstrItinClass itin,
1221            string opc, string asm, list<dag> pattern>
1222   : Thumb2sI<oops, iops, AddrModeNone, Size4Bytes, itin, opc, asm, "", pattern>;
1223
1224 class T2XI<dag oops, dag iops, InstrItinClass itin,
1225            string asm, list<dag> pattern>
1226   : Thumb2XI<oops, iops, AddrModeNone, Size4Bytes, itin, asm, "", pattern>;
1227 class T2JTI<dag oops, dag iops, InstrItinClass itin,
1228             string asm, list<dag> pattern>
1229   : Thumb2XI<oops, iops, AddrModeNone, SizeSpecial, itin, asm, "", pattern>;
1230
1231 class T2Ix2<dag oops, dag iops, InstrItinClass itin,
1232             string opc, string asm, list<dag> pattern>
1233   : Thumb2I<oops, iops, AddrModeNone, Size8Bytes, itin, opc, asm, "", pattern>;
1234
1235 // Two-address instructions
1236 class T2XIt<dag oops, dag iops, InstrItinClass itin,
1237             string asm, string cstr, list<dag> pattern>
1238   : Thumb2XI<oops, iops, AddrModeNone, Size4Bytes, itin, asm, cstr, pattern>;
1239
1240 // T2Iidxldst - Thumb2 indexed load / store instructions.
1241 class T2Iidxldst<bit signed, bits<2> opcod, bit load, bit pre,
1242                  dag oops, dag iops,
1243                  AddrMode am, IndexMode im, InstrItinClass itin,
1244                  string opc, string asm, string cstr, list<dag> pattern>
1245   : InstARM<am, Size4Bytes, im, ThumbFrm, GenericDomain, cstr, itin> {
1246   let OutOperandList = oops;
1247   let InOperandList = !con(iops, (ins pred:$p));
1248   let AsmString = !strconcat(opc, "${p}", asm);
1249   let Pattern = pattern;
1250   list<Predicate> Predicates = [IsThumb2];
1251   let Inst{31-27} = 0b11111;
1252   let Inst{26-25} = 0b00;
1253   let Inst{24}    = signed;
1254   let Inst{23}    = 0;
1255   let Inst{22-21} = opcod;
1256   let Inst{20}    = load;
1257   let Inst{11}    = 1;
1258   // (P, W) = (1, 1) Pre-indexed or (0, 1) Post-indexed
1259   let Inst{10}    = pre; // The P bit.
1260   let Inst{8}     = 1; // The W bit.
1261 }
1262
1263 // Helper class for disassembly only
1264 // A6.3.16 & A6.3.17
1265 // T2Imac - Thumb2 multiply [accumulate, and absolute difference] instructions.
1266 class T2I_mac<bit long, bits<3> op22_20, bits<4> op7_4, dag oops, dag iops,
1267              InstrItinClass itin, string opc, string asm, list<dag> pattern>
1268   : T2I<oops, iops, itin, opc, asm, pattern> {
1269   let Inst{31-27} = 0b11111;
1270   let Inst{26-24} = 0b011;
1271   let Inst{23}    = long;
1272   let Inst{22-20} = op22_20;
1273   let Inst{7-4}   = op7_4;
1274 }
1275
1276 // Tv5Pat - Same as Pat<>, but requires V5T Thumb mode.
1277 class Tv5Pat<dag pattern, dag result> : Pat<pattern, result> {
1278   list<Predicate> Predicates = [IsThumb1Only, HasV5T];
1279 }
1280
1281 // T1Pat - Same as Pat<>, but requires that the compiler be in Thumb1 mode.
1282 class T1Pat<dag pattern, dag result> : Pat<pattern, result> {
1283   list<Predicate> Predicates = [IsThumb1Only];
1284 }
1285
1286 // T2Pat - Same as Pat<>, but requires that the compiler be in Thumb2 mode.
1287 class T2Pat<dag pattern, dag result> : Pat<pattern, result> {
1288   list<Predicate> Predicates = [IsThumb2];
1289 }
1290
1291 //===----------------------------------------------------------------------===//
1292
1293 //===----------------------------------------------------------------------===//
1294 // ARM VFP Instruction templates.
1295 //
1296
1297 // Almost all VFP instructions are predicable.
1298 class VFPI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1299            IndexMode im, Format f, InstrItinClass itin,
1300            string opc, string asm, string cstr, list<dag> pattern>
1301   : InstARM<am, sz, im, f, VFPDomain, cstr, itin> {
1302   bits<4> p;
1303   let Inst{31-28} = p;
1304   let OutOperandList = oops;
1305   let InOperandList = !con(iops, (ins pred:$p));
1306   let AsmString = !strconcat(opc, "${p}", asm);
1307   let Pattern = pattern;
1308   list<Predicate> Predicates = [HasVFP2];
1309 }
1310
1311 // Special cases
1312 class VFPXI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1313             IndexMode im, Format f, InstrItinClass itin,
1314             string asm, string cstr, list<dag> pattern>
1315   : InstARM<am, sz, im, f, VFPDomain, cstr, itin> {
1316   let OutOperandList = oops;
1317   let InOperandList = iops;
1318   let AsmString = asm;
1319   let Pattern = pattern;
1320   list<Predicate> Predicates = [HasVFP2];
1321 }
1322
1323 class VFPAI<dag oops, dag iops, Format f, InstrItinClass itin,
1324             string opc, string asm, list<dag> pattern>
1325   : VFPI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
1326          opc, asm, "", pattern>;
1327
1328 // ARM VFP addrmode5 loads and stores
1329 class ADI5<bits<4> opcod1, bits<2> opcod2, dag oops, dag iops,
1330            InstrItinClass itin,
1331            string opc, string asm, list<dag> pattern>
1332   : VFPI<oops, iops, AddrMode5, Size4Bytes, IndexModeNone,
1333          VFPLdStFrm, itin, opc, asm, "", pattern> {
1334   // TODO: Mark the instructions with the appropriate subtarget info.
1335   let Inst{27-24} = opcod1;
1336   let Inst{21-20} = opcod2;
1337   let Inst{11-9}  = 0b101;
1338   let Inst{8}     = 1;          // Double precision
1339
1340   // 64-bit loads & stores operate on both NEON and VFP pipelines.
1341   let D = VFPNeonDomain;
1342 }
1343
1344 class ASI5<bits<4> opcod1, bits<2> opcod2, dag oops, dag iops,
1345            InstrItinClass itin,
1346            string opc, string asm, list<dag> pattern>
1347   : VFPI<oops, iops, AddrMode5, Size4Bytes, IndexModeNone,
1348          VFPLdStFrm, itin, opc, asm, "", pattern> {
1349   // TODO: Mark the instructions with the appropriate subtarget info.
1350   let Inst{27-24} = opcod1;
1351   let Inst{21-20} = opcod2;
1352   let Inst{11-9}  = 0b101;
1353   let Inst{8}     = 0;          // Single precision
1354 }
1355
1356 // VFP Load / store multiple pseudo instructions.
1357 class PseudoVFPLdStM<dag oops, dag iops, InstrItinClass itin, string cstr,
1358                      list<dag> pattern>
1359   : InstARM<AddrMode4, Size4Bytes, IndexModeNone, Pseudo, VFPNeonDomain,
1360             cstr, itin> {
1361   let OutOperandList = oops;
1362   let InOperandList = !con(iops, (ins pred:$p));
1363   let Pattern = pattern;
1364   list<Predicate> Predicates = [HasVFP2];
1365 }
1366
1367 // Load / store multiple
1368 class AXDI4<dag oops, dag iops, IndexMode im, InstrItinClass itin,
1369             string asm, string cstr, list<dag> pattern>
1370   : VFPXI<oops, iops, AddrMode4, Size4Bytes, im,
1371           VFPLdStMulFrm, itin, asm, cstr, pattern> {
1372   // TODO: Mark the instructions with the appropriate subtarget info.
1373   let Inst{27-25} = 0b110;
1374   let Inst{11-9}  = 0b101;
1375   let Inst{8}     = 1;          // Double precision
1376
1377   // 64-bit loads & stores operate on both NEON and VFP pipelines.
1378   let D = VFPNeonDomain;
1379 }
1380
1381 class AXSI4<dag oops, dag iops, IndexMode im, InstrItinClass itin,
1382             string asm, string cstr, list<dag> pattern>
1383   : VFPXI<oops, iops, AddrMode4, Size4Bytes, im,
1384           VFPLdStMulFrm, itin, asm, cstr, pattern> {
1385   // TODO: Mark the instructions with the appropriate subtarget info.
1386   let Inst{27-25} = 0b110;
1387   let Inst{11-9}  = 0b101;
1388   let Inst{8}     = 0;          // Single precision
1389 }
1390
1391 // Double precision, unary
1392 class ADuI<bits<5> opcod1, bits<2> opcod2, bits<4> opcod3, bits<2> opcod4,
1393            bit opcod5, dag oops, dag iops, InstrItinClass itin, string opc,
1394            string asm, list<dag> pattern>
1395   : VFPAI<oops, iops, VFPUnaryFrm, itin, opc, asm, pattern> {
1396   let Inst{27-23} = opcod1;
1397   let Inst{21-20} = opcod2;
1398   let Inst{19-16} = opcod3;
1399   let Inst{11-9}  = 0b101;
1400   let Inst{8}     = 1;          // Double precision
1401   let Inst{7-6}   = opcod4;
1402   let Inst{4}     = opcod5;
1403 }
1404
1405 // Double precision, binary
1406 class ADbI<bits<5> opcod1, bits<2> opcod2, bit op6, bit op4, dag oops,
1407            dag iops, InstrItinClass itin, string opc, string asm,
1408            list<dag> pattern>
1409   : VFPAI<oops, iops, VFPBinaryFrm, itin, opc, asm, pattern> {
1410   let Inst{27-23} = opcod1;
1411   let Inst{21-20} = opcod2;
1412   let Inst{11-9}  = 0b101;
1413   let Inst{8}     = 1;          // Double precision
1414   let Inst{6}     = op6;
1415   let Inst{4}     = op4;
1416 }
1417
1418 // Double precision, binary, VML[AS] (for additional predicate)
1419 class ADbI_vmlX<bits<5> opcod1, bits<2> opcod2, bit op6, bit op4, dag oops,
1420            dag iops, InstrItinClass itin, string opc, string asm,
1421            list<dag> pattern>
1422   : VFPAI<oops, iops, VFPBinaryFrm, itin, opc, asm, pattern> {
1423   let Inst{27-23} = opcod1;
1424   let Inst{21-20} = opcod2;
1425   let Inst{11-9}  = 0b101;
1426   let Inst{8}     = 1;          // Double precision
1427   let Inst{6}     = op6;
1428   let Inst{4}     = op4;
1429   list<Predicate> Predicates = [HasVFP2, UseVMLx];
1430 }
1431
1432 // Single precision, unary
1433 class ASuI<bits<5> opcod1, bits<2> opcod2, bits<4> opcod3, bits<2> opcod4,
1434            bit opcod5, dag oops, dag iops, InstrItinClass itin, string opc,
1435            string asm, list<dag> pattern>
1436   : VFPAI<oops, iops, VFPUnaryFrm, itin, opc, asm, pattern> {
1437   let Inst{27-23} = opcod1;
1438   let Inst{21-20} = opcod2;
1439   let Inst{19-16} = opcod3;
1440   let Inst{11-9}  = 0b101;
1441   let Inst{8}     = 0;          // Single precision
1442   let Inst{7-6}   = opcod4;
1443   let Inst{4}     = opcod5;
1444 }
1445
1446 // Single precision unary, if no NEON
1447 // Same as ASuI except not available if NEON is enabled
1448 class ASuIn<bits<5> opcod1, bits<2> opcod2, bits<4> opcod3, bits<2> opcod4,
1449             bit opcod5, dag oops, dag iops, InstrItinClass itin, string opc,
1450             string asm, list<dag> pattern>
1451   : ASuI<opcod1, opcod2, opcod3, opcod4, opcod5, oops, iops, itin, opc, asm,
1452          pattern> {
1453   list<Predicate> Predicates = [HasVFP2,DontUseNEONForFP];
1454 }
1455
1456 // Single precision, binary
1457 class ASbI<bits<5> opcod1, bits<2> opcod2, bit op6, bit op4, dag oops, dag iops,
1458            InstrItinClass itin, string opc, string asm, list<dag> pattern>
1459   : VFPAI<oops, iops, VFPBinaryFrm, itin, opc, asm, pattern> {
1460   let Inst{27-23} = opcod1;
1461   let Inst{21-20} = opcod2;
1462   let Inst{11-9}  = 0b101;
1463   let Inst{8}     = 0;          // Single precision
1464   let Inst{6}     = op6;
1465   let Inst{4}     = op4;
1466 }
1467
1468 // Single precision binary, if no NEON
1469 // Same as ASbI except not available if NEON is enabled
1470 class ASbIn<bits<5> opcod1, bits<2> opcod2, bit op6, bit op4, dag oops,
1471             dag iops, InstrItinClass itin, string opc, string asm,
1472             list<dag> pattern>
1473   : ASbI<opcod1, opcod2, op6, op4, oops, iops, itin, opc, asm, pattern> {
1474   list<Predicate> Predicates = [HasVFP2,DontUseNEONForFP];
1475 }
1476
1477 // VFP conversion instructions
1478 class AVConv1I<bits<5> opcod1, bits<2> opcod2, bits<4> opcod3, bits<4> opcod4,
1479                dag oops, dag iops, InstrItinClass itin, string opc, string asm,
1480                list<dag> pattern>
1481   : VFPAI<oops, iops, VFPConv1Frm, itin, opc, asm, pattern> {
1482   let Inst{27-23} = opcod1;
1483   let Inst{21-20} = opcod2;
1484   let Inst{19-16} = opcod3;
1485   let Inst{11-8}  = opcod4;
1486   let Inst{6}     = 1;
1487   let Inst{4}     = 0;
1488 }
1489
1490 // VFP conversion between floating-point and fixed-point
1491 class AVConv1XI<bits<5> op1, bits<2> op2, bits<4> op3, bits<4> op4, bit op5,
1492                 dag oops, dag iops, InstrItinClass itin, string opc, string asm,
1493                 list<dag> pattern>
1494   : AVConv1I<op1, op2, op3, op4, oops, iops, itin, opc, asm, pattern> {
1495   // size (fixed-point number): sx == 0 ? 16 : 32
1496   let Inst{7} = op5; // sx
1497 }
1498
1499 // VFP conversion instructions, if no NEON
1500 class AVConv1In<bits<5> opcod1, bits<2> opcod2, bits<4> opcod3, bits<4> opcod4,
1501                 dag oops, dag iops, InstrItinClass itin,
1502                 string opc, string asm, list<dag> pattern>
1503   : AVConv1I<opcod1, opcod2, opcod3, opcod4, oops, iops, itin, opc, asm,
1504              pattern> {
1505   list<Predicate> Predicates = [HasVFP2,DontUseNEONForFP];
1506 }
1507
1508 class AVConvXI<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops, Format f,
1509                InstrItinClass itin,
1510                string opc, string asm, list<dag> pattern>
1511   : VFPAI<oops, iops, f, itin, opc, asm, pattern> {
1512   let Inst{27-20} = opcod1;
1513   let Inst{11-8}  = opcod2;
1514   let Inst{4}     = 1;
1515 }
1516
1517 class AVConv2I<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops,
1518                InstrItinClass itin, string opc, string asm, list<dag> pattern>
1519   : AVConvXI<opcod1, opcod2, oops, iops, VFPConv2Frm, itin, opc, asm, pattern>;
1520
1521 class AVConv3I<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops,
1522                InstrItinClass itin, string opc, string asm, list<dag> pattern>
1523   : AVConvXI<opcod1, opcod2, oops, iops, VFPConv3Frm, itin, opc, asm, pattern>;
1524
1525 class AVConv4I<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops,
1526                InstrItinClass itin, string opc, string asm, list<dag> pattern>
1527   : AVConvXI<opcod1, opcod2, oops, iops, VFPConv4Frm, itin, opc, asm, pattern>;
1528
1529 class AVConv5I<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops,
1530                InstrItinClass itin, string opc, string asm, list<dag> pattern>
1531   : AVConvXI<opcod1, opcod2, oops, iops, VFPConv5Frm, itin, opc, asm, pattern>;
1532
1533 //===----------------------------------------------------------------------===//
1534
1535 //===----------------------------------------------------------------------===//
1536 // ARM NEON Instruction templates.
1537 //
1538
1539 class NeonI<dag oops, dag iops, AddrMode am, IndexMode im, Format f,
1540             InstrItinClass itin, string opc, string dt, string asm, string cstr,
1541             list<dag> pattern>
1542   : InstARM<am, Size4Bytes, im, f, NeonDomain, cstr, itin> {
1543   let OutOperandList = oops;
1544   let InOperandList = !con(iops, (ins pred:$p));
1545   let AsmString = !strconcat(opc, "${p}", ".", dt, "\t", asm);
1546   let Pattern = pattern;
1547   list<Predicate> Predicates = [HasNEON];
1548 }
1549
1550 // Same as NeonI except it does not have a "data type" specifier.
1551 class NeonXI<dag oops, dag iops, AddrMode am, IndexMode im, Format f,
1552              InstrItinClass itin, string opc, string asm, string cstr,
1553              list<dag> pattern>
1554   : InstARM<am, Size4Bytes, im, f, NeonDomain, cstr, itin> {
1555   let OutOperandList = oops;
1556   let InOperandList = !con(iops, (ins pred:$p));
1557   let AsmString = !strconcat(opc, "${p}", "\t", asm);
1558   let Pattern = pattern;
1559   list<Predicate> Predicates = [HasNEON];
1560 }
1561
1562 class NLdSt<bit op23, bits<2> op21_20, bits<4> op11_8, bits<4> op7_4,
1563             dag oops, dag iops, InstrItinClass itin,
1564             string opc, string dt, string asm, string cstr, list<dag> pattern>
1565   : NeonI<oops, iops, AddrMode6, IndexModeNone, NLdStFrm, itin, opc, dt, asm,
1566           cstr, pattern> {
1567   let Inst{31-24} = 0b11110100;
1568   let Inst{23}    = op23;
1569   let Inst{21-20} = op21_20;
1570   let Inst{11-8}  = op11_8;
1571   let Inst{7-4}   = op7_4;
1572 }
1573
1574 class PseudoNLdSt<dag oops, dag iops, InstrItinClass itin, string cstr>
1575   : InstARM<AddrMode6, Size4Bytes, IndexModeNone, Pseudo, NeonDomain, cstr,
1576             itin> {
1577   let OutOperandList = oops;
1578   let InOperandList = !con(iops, (ins pred:$p));
1579   list<Predicate> Predicates = [HasNEON];
1580 }
1581
1582 class PseudoNeonI<dag oops, dag iops, InstrItinClass itin, string cstr,
1583                   list<dag> pattern>
1584   : InstARM<AddrModeNone, Size4Bytes, IndexModeNone, Pseudo, NeonDomain, cstr,
1585             itin> {
1586   let OutOperandList = oops;
1587   let InOperandList = !con(iops, (ins pred:$p));
1588   let Pattern = pattern;
1589   list<Predicate> Predicates = [HasNEON];
1590 }
1591
1592 class NDataI<dag oops, dag iops, Format f, InstrItinClass itin,
1593              string opc, string dt, string asm, string cstr, list<dag> pattern>
1594   : NeonI<oops, iops, AddrModeNone, IndexModeNone, f, itin, opc, dt, asm, cstr,
1595           pattern> {
1596   let Inst{31-25} = 0b1111001;
1597 }
1598
1599 class NDataXI<dag oops, dag iops, Format f, InstrItinClass itin,
1600               string opc, string asm, string cstr, list<dag> pattern>
1601   : NeonXI<oops, iops, AddrModeNone, IndexModeNone, f, itin, opc, asm,
1602            cstr, pattern> {
1603   let Inst{31-25} = 0b1111001;
1604 }
1605
1606 // NEON "one register and a modified immediate" format.
1607 class N1ModImm<bit op23, bits<3> op21_19, bits<4> op11_8, bit op7, bit op6,
1608                bit op5, bit op4,
1609                dag oops, dag iops, InstrItinClass itin,
1610                string opc, string dt, string asm, string cstr,
1611                list<dag> pattern>
1612   : NDataI<oops, iops, N1RegModImmFrm, itin, opc, dt, asm, cstr, pattern> {
1613   let Inst{23}    = op23;
1614   let Inst{21-19} = op21_19;
1615   let Inst{11-8}  = op11_8;
1616   let Inst{7}     = op7;
1617   let Inst{6}     = op6;
1618   let Inst{5}     = op5;
1619   let Inst{4}     = op4;
1620 }
1621
1622 // NEON 2 vector register format.
1623 class N2V<bits<2> op24_23, bits<2> op21_20, bits<2> op19_18, bits<2> op17_16,
1624           bits<5> op11_7, bit op6, bit op4,
1625           dag oops, dag iops, InstrItinClass itin,
1626           string opc, string dt, string asm, string cstr, list<dag> pattern>
1627   : NDataI<oops, iops, N2RegFrm, itin, opc, dt, asm, cstr, pattern> {
1628   let Inst{24-23} = op24_23;
1629   let Inst{21-20} = op21_20;
1630   let Inst{19-18} = op19_18;
1631   let Inst{17-16} = op17_16;
1632   let Inst{11-7}  = op11_7;
1633   let Inst{6}     = op6;
1634   let Inst{4}     = op4;
1635 }
1636
1637 // Same as N2V except it doesn't have a datatype suffix.
1638 class N2VX<bits<2> op24_23, bits<2> op21_20, bits<2> op19_18, bits<2> op17_16,
1639            bits<5> op11_7, bit op6, bit op4,
1640            dag oops, dag iops, InstrItinClass itin,
1641            string opc, string asm, string cstr, list<dag> pattern>
1642   : NDataXI<oops, iops, N2RegFrm, itin, opc, asm, cstr, pattern> {
1643   let Inst{24-23} = op24_23;
1644   let Inst{21-20} = op21_20;
1645   let Inst{19-18} = op19_18;
1646   let Inst{17-16} = op17_16;
1647   let Inst{11-7}  = op11_7;
1648   let Inst{6}     = op6;
1649   let Inst{4}     = op4;
1650 }
1651
1652 // NEON 2 vector register with immediate.
1653 class N2VImm<bit op24, bit op23, bits<4> op11_8, bit op7, bit op6, bit op4,
1654              dag oops, dag iops, Format f, InstrItinClass itin,
1655              string opc, string dt, string asm, string cstr, list<dag> pattern>
1656   : NDataI<oops, iops, f, itin, opc, dt, asm, cstr, pattern> {
1657   let Inst{24}   = op24;
1658   let Inst{23}   = op23;
1659   let Inst{11-8} = op11_8;
1660   let Inst{7}    = op7;
1661   let Inst{6}    = op6;
1662   let Inst{4}    = op4;
1663 }
1664
1665 // NEON 3 vector register format.
1666 class N3V<bit op24, bit op23, bits<2> op21_20, bits<4> op11_8, bit op6, bit op4,
1667           dag oops, dag iops, Format f, InstrItinClass itin,
1668           string opc, string dt, string asm, string cstr, list<dag> pattern>
1669   : NDataI<oops, iops, f, itin, opc, dt, asm, cstr, pattern> {
1670   let Inst{24}    = op24;
1671   let Inst{23}    = op23;
1672   let Inst{21-20} = op21_20;
1673   let Inst{11-8}  = op11_8;
1674   let Inst{6}     = op6;
1675   let Inst{4}     = op4;
1676 }
1677
1678 // Same as N3V except it doesn't have a data type suffix.
1679 class N3VX<bit op24, bit op23, bits<2> op21_20, bits<4> op11_8, bit op6,
1680            bit op4,
1681            dag oops, dag iops, Format f, InstrItinClass itin,
1682            string opc, string asm, string cstr, list<dag> pattern>
1683   : NDataXI<oops, iops, f, itin, opc, asm, cstr, pattern> {
1684   let Inst{24}    = op24;
1685   let Inst{23}    = op23;
1686   let Inst{21-20} = op21_20;
1687   let Inst{11-8}  = op11_8;
1688   let Inst{6}     = op6;
1689   let Inst{4}     = op4;
1690 }
1691
1692 // NEON VMOVs between scalar and core registers.
1693 class NVLaneOp<bits<8> opcod1, bits<4> opcod2, bits<2> opcod3,
1694                dag oops, dag iops, Format f, InstrItinClass itin,
1695                string opc, string dt, string asm, list<dag> pattern>
1696   : InstARM<AddrModeNone, Size4Bytes, IndexModeNone, f, GenericDomain,
1697             "", itin> {
1698   let Inst{27-20} = opcod1;
1699   let Inst{11-8}  = opcod2;
1700   let Inst{6-5}   = opcod3;
1701   let Inst{4}     = 1;
1702
1703   let OutOperandList = oops;
1704   let InOperandList = !con(iops, (ins pred:$p));
1705   let AsmString = !strconcat(opc, "${p}", ".", dt, "\t", asm);
1706   let Pattern = pattern;
1707   list<Predicate> Predicates = [HasNEON];
1708 }
1709 class NVGetLane<bits<8> opcod1, bits<4> opcod2, bits<2> opcod3,
1710                 dag oops, dag iops, InstrItinClass itin,
1711                 string opc, string dt, string asm, list<dag> pattern>
1712   : NVLaneOp<opcod1, opcod2, opcod3, oops, iops, NGetLnFrm, itin,
1713              opc, dt, asm, pattern>;
1714 class NVSetLane<bits<8> opcod1, bits<4> opcod2, bits<2> opcod3,
1715                 dag oops, dag iops, InstrItinClass itin,
1716                 string opc, string dt, string asm, list<dag> pattern>
1717   : NVLaneOp<opcod1, opcod2, opcod3, oops, iops, NSetLnFrm, itin,
1718              opc, dt, asm, pattern>;
1719 class NVDup<bits<8> opcod1, bits<4> opcod2, bits<2> opcod3,
1720             dag oops, dag iops, InstrItinClass itin,
1721             string opc, string dt, string asm, list<dag> pattern>
1722   : NVLaneOp<opcod1, opcod2, opcod3, oops, iops, NDupFrm, itin,
1723              opc, dt, asm, pattern>;
1724
1725 // Vector Duplicate Lane (from scalar to all elements)
1726 class NVDupLane<bits<4> op19_16, bit op6, dag oops, dag iops,
1727                 InstrItinClass itin, string opc, string dt, string asm,
1728                 list<dag> pattern>
1729   : NDataI<oops, iops, NVDupLnFrm, itin, opc, dt, asm, "", pattern> {
1730   let Inst{24-23} = 0b11;
1731   let Inst{21-20} = 0b11;
1732   let Inst{19-16} = op19_16;
1733   let Inst{11-7}  = 0b11000;
1734   let Inst{6}     = op6;
1735   let Inst{4}     = 0;
1736 }
1737
1738 // NEONFPPat - Same as Pat<>, but requires that the compiler be using NEON
1739 // for single-precision FP.
1740 class NEONFPPat<dag pattern, dag result> : Pat<pattern, result> {
1741   list<Predicate> Predicates = [HasNEON,UseNEONForFP];
1742 }