lib/AsmParser/Lexer.l.cvs

   1 /*===-- Lexer.l - Scanner for llvm assembly files --------------*- C++ -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 //  This file implements the flex scanner for LLVM assembly languages files.
  11 //
  12 //===----------------------------------------------------------------------===*/
  13
  14 %option prefix="llvmAsm"
  15 %option yylineno
  16 %option nostdinit
  17 %option never-interactive
  18 %option batch
  19 %option noyywrap
  20 %option nodefault
  21 %option 8bit
  22 %option outfile="Lexer.cpp"
  23 %option ecs
  24 %option noreject
  25 %option noyymore
  26
  27 %{
  28 #include "ParserInternals.h"
  29 #include "llvm/Module.h"
  30 #include <list>
  31 #include "llvmAsmParser.h"
  32 #include <cctype>
  33 #include <cstdlib>
  34
  35 void set_scan_file(FILE * F){
  36   yy_switch_to_buffer(yy_create_buffer( F, YY_BUF_SIZE ) );
  37 }
  38 void set_scan_string (const char * str) {
  39   yy_scan_string (str);
  40 }
  41
  42 #define RET_TOK(type, Enum, sym) \
  43   llvmAsmlval.type = Instruction::Enum; return sym
  44
  45 namespace llvm {
  46
  47 // TODO: All of the static identifiers are figured out by the lexer,
  48 // these should be hashed to reduce the lexer size
  49
  50
  51 // atoull - Convert an ascii string of decimal digits into the unsigned long
  52 // long representation... this does not have to do input error checking,
  53 // because we know that the input will be matched by a suitable regex...
  54 //
  55 static uint64_t atoull(const char *Buffer) {
  56   uint64_t Result = 0;
  57   for (; *Buffer; Buffer++) {
  58     uint64_t OldRes = Result;
  59     Result *= 10;
  60     Result += *Buffer-'0';
  61     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  62       ThrowException("constant bigger than 64 bits detected!");
  63   }
  64   return Result;
  65 }
  66
  67 static uint64_t HexIntToVal(const char *Buffer) {
  68   uint64_t Result = 0;
  69   for (; *Buffer; ++Buffer) {
  70     uint64_t OldRes = Result;
  71     Result *= 16;
  72     char C = *Buffer;
  73     if (C >= '0' && C <= '9')
  74       Result += C-'0';
  75     else if (C >= 'A' && C <= 'F')
  76       Result += C-'A'+10;
  77     else if (C >= 'a' && C <= 'f')
  78       Result += C-'a'+10;
  79
  80     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  81       ThrowException("constant bigger than 64 bits detected!");
  82   }
  83   return Result;
  84 }
  85
  86
  87 // HexToFP - Convert the ascii string in hexidecimal format to the floating
  88 // point representation of it.
  89 //
  90 static double HexToFP(const char *Buffer) {
  91   // Behave nicely in the face of C TBAA rules... see:
  92   // http://www.nullstone.com/htmls/category/aliastyp.htm
  93   union {
  94     uint64_t UI;
  95     double FP;
  96   } UIntToFP;
  97   UIntToFP.UI = HexIntToVal(Buffer);
  98
  99   assert(sizeof(double) == sizeof(uint64_t) &&
 100          "Data sizes incompatible on this target!");
 101   return UIntToFP.FP;   // Cast Hex constant to double
 102 }
 103
 104
 105 // UnEscapeLexed - Run through the specified buffer and change \xx codes to the
 106 // appropriate character.  If AllowNull is set to false, a \00 value will cause
 107 // an exception to be thrown.
 108 //
 109 // If AllowNull is set to true, the return value of the function points to the
 110 // last character of the string in memory.
 111 //
 112 char *UnEscapeLexed(char *Buffer, bool AllowNull) {
 113   char *BOut = Buffer;
 114   for (char *BIn = Buffer; *BIn; ) {
 115     if (BIn[0] == '\\' && isxdigit(BIn[1]) && isxdigit(BIn[2])) {
 116       char Tmp = BIn[3]; BIn[3] = 0;     // Terminate string
 117       *BOut = (char)strtol(BIn+1, 0, 16);  // Convert to number
 118       if (!AllowNull && !*BOut)
 119         ThrowException("String literal cannot accept \\00 escape!");
 120
 121       BIn[3] = Tmp;                  // Restore character
 122       BIn += 3;                      // Skip over handled chars
 123       ++BOut;
 124     } else {
 125       *BOut++ = *BIn++;
 126     }
 127   }
 128
 129   return BOut;
 130 }
 131
 132 } // End llvm namespace
 133
 134 using namespace llvm;
 135
 136 #define YY_NEVER_INTERACTIVE 1
 137 %}
 138
 139
 140
 141 /* Comments start with a ; and go till end of line */
 142 Comment    ;.*
 143
 144 /* Variable(Value) identifiers start with a % sign */
 145 VarID       %[-a-zA-Z$._][-a-zA-Z$._0-9]*
 146
 147 /* Label identifiers end with a colon */
 148 Label       [-a-zA-Z$._0-9]+:
 149 QuoteLabel \"[^\"]+\":
 150
 151 /* Quoted names can contain any character except " and \ */
 152 StringConstant \"[^\"]*\"
 153
 154
 155 /* [PN]Integer: match positive and negative literal integer values that
 156  * are preceeded by a '%' character.  These represent unnamed variable slots.
 157  */
 158 EPInteger     %[0-9]+
 159 ENInteger    %-[0-9]+
 160
 161
 162 /* E[PN]Integer: match positive and negative literal integer values */
 163 PInteger   [0-9]+
 164 NInteger  -[0-9]+
 165
 166 /* FPConstant - A Floating point constant.
 167  */
 168 FPConstant [-+]?[0-9]+[.][0-9]*([eE][-+]?[0-9]+)?
 169
 170 /* HexFPConstant - Floating point constant represented in IEEE format as a
 171  *  hexadecimal number for when exponential notation is not precise enough.
 172  */
 173 HexFPConstant 0x[0-9A-Fa-f]+
 174
 175 /* HexIntConstant - Hexadecimal constant generated by the CFE to avoid forcing
 176  * it to deal with 64 bit numbers.
 177  */
 178 HexIntConstant [us]0x[0-9A-Fa-f]+
 179 %%
 180
 181 {Comment}       { /* Ignore comments for now */ }
 182
 183 begin           { return BEGINTOK; }
 184 end             { return ENDTOK; }
 185 true            { return TRUETOK;  }
 186 false           { return FALSETOK; }
 187 declare         { return DECLARE; }
 188 global          { return GLOBAL; }
 189 constant        { return CONSTANT; }
 190 internal        { return INTERNAL; }
 191 linkonce        { return LINKONCE; }
 192 weak            { return WEAK; }
 193 appending       { return APPENDING; }
 194 uninitialized   { return EXTERNAL; }    /* Deprecated, turn into external */
 195 external        { return EXTERNAL; }
 196 implementation  { return IMPLEMENTATION; }
 197 zeroinitializer { return ZEROINITIALIZER; }
 198 \.\.\.          { return DOTDOTDOT; }
 199 undef           { return UNDEF; }
 200 null            { return NULL_TOK; }
 201 to              { return TO; }
 202 except          { RET_TOK(TermOpVal, Unwind, UNWIND); }
 203 not             { return NOT; }  /* Deprecated, turned into XOR */
 204 tail            { return TAIL; }
 205 target          { return TARGET; }
 206 triple          { return TRIPLE; }
 207 deplibs         { return DEPLIBS; }
 208 endian          { return ENDIAN; }
 209 pointersize     { return POINTERSIZE; }
 210 little          { return LITTLE; }
 211 big             { return BIG; }
 212 volatile        { return VOLATILE; }
 213 align           { return ALIGN;  }
 214 section         { return SECTION; }
 215 module          { return MODULE; }
 216 asm             { return ASM_TOK; }
 217 sideeffect      { return SIDEEFFECT; }
 218
 219 cc              { return CC_TOK; }
 220 ccc             { return CCC_TOK; }
 221 fastcc          { return FASTCC_TOK; }
 222 coldcc          { return COLDCC_TOK; }
 223
 224 void            { llvmAsmlval.PrimType = Type::VoidTy  ; return VOID;   }
 225 bool            { llvmAsmlval.PrimType = Type::BoolTy  ; return BOOL;   }
 226 sbyte           { llvmAsmlval.PrimType = Type::SByteTy ; return SBYTE;  }
 227 ubyte           { llvmAsmlval.PrimType = Type::UByteTy ; return UBYTE;  }
 228 short           { llvmAsmlval.PrimType = Type::ShortTy ; return SHORT;  }
 229 ushort          { llvmAsmlval.PrimType = Type::UShortTy; return USHORT; }
 230 int             { llvmAsmlval.PrimType = Type::IntTy   ; return INT;    }
 231 uint            { llvmAsmlval.PrimType = Type::UIntTy  ; return UINT;   }
 232 long            { llvmAsmlval.PrimType = Type::LongTy  ; return LONG;   }
 233 ulong           { llvmAsmlval.PrimType = Type::ULongTy ; return ULONG;  }
 234 float           { llvmAsmlval.PrimType = Type::FloatTy ; return FLOAT;  }
 235 double          { llvmAsmlval.PrimType = Type::DoubleTy; return DOUBLE; }
 236 label           { llvmAsmlval.PrimType = Type::LabelTy ; return LABEL;  }
 237 type            { return TYPE;   }
 238 opaque          { return OPAQUE; }
 239
 240 add             { RET_TOK(BinaryOpVal, Add, ADD); }
 241 sub             { RET_TOK(BinaryOpVal, Sub, SUB); }
 242 mul             { RET_TOK(BinaryOpVal, Mul, MUL); }
 243 div             { RET_TOK(BinaryOpVal, Div, DIV); }
 244 rem             { RET_TOK(BinaryOpVal, Rem, REM); }
 245 and             { RET_TOK(BinaryOpVal, And, AND); }
 246 or              { RET_TOK(BinaryOpVal, Or , OR ); }
 247 xor             { RET_TOK(BinaryOpVal, Xor, XOR); }
 248 setne           { RET_TOK(BinaryOpVal, SetNE, SETNE); }
 249 seteq           { RET_TOK(BinaryOpVal, SetEQ, SETEQ); }
 250 setlt           { RET_TOK(BinaryOpVal, SetLT, SETLT); }
 251 setgt           { RET_TOK(BinaryOpVal, SetGT, SETGT); }
 252 setle           { RET_TOK(BinaryOpVal, SetLE, SETLE); }
 253 setge           { RET_TOK(BinaryOpVal, SetGE, SETGE); }
 254
 255 phi             { RET_TOK(OtherOpVal, PHI, PHI_TOK); }
 256 call            { RET_TOK(OtherOpVal, Call, CALL); }
 257 cast            { RET_TOK(OtherOpVal, Cast, CAST); }
 258 select          { RET_TOK(OtherOpVal, Select, SELECT); }
 259 shl             { RET_TOK(OtherOpVal, Shl, SHL); }
 260 shr             { RET_TOK(OtherOpVal, Shr, SHR); }
 261 vanext          { return VANEXT_old; }
 262 vaarg           { return VAARG_old; }
 263 va_arg          { RET_TOK(OtherOpVal, VAArg , VAARG); }
 264 ret             { RET_TOK(TermOpVal, Ret, RET); }
 265 br              { RET_TOK(TermOpVal, Br, BR); }
 266 switch          { RET_TOK(TermOpVal, Switch, SWITCH); }
 267 invoke          { RET_TOK(TermOpVal, Invoke, INVOKE); }
 268 unwind          { RET_TOK(TermOpVal, Unwind, UNWIND); }
 269 unreachable     { RET_TOK(TermOpVal, Unreachable, UNREACHABLE); }
 270
 271 malloc          { RET_TOK(MemOpVal, Malloc, MALLOC); }
 272 alloca          { RET_TOK(MemOpVal, Alloca, ALLOCA); }
 273 free            { RET_TOK(MemOpVal, Free, FREE); }
 274 load            { RET_TOK(MemOpVal, Load, LOAD); }
 275 store           { RET_TOK(MemOpVal, Store, STORE); }
 276 getelementptr   { RET_TOK(MemOpVal, GetElementPtr, GETELEMENTPTR); }
 277
 278 extractelement  { RET_TOK(OtherOpVal, ExtractElement, EXTRACTELEMENT); }
 279 insertelement   { RET_TOK(OtherOpVal, InsertElement, INSERTELEMENT); }
 280 shufflevector   { RET_TOK(OtherOpVal, ShuffleVector, SHUFFLEVECTOR); }
 281
 282
 283 {VarID}         {
 284                   UnEscapeLexed(yytext+1);
 285                   llvmAsmlval.StrVal = strdup(yytext+1);             // Skip %
 286                   return VAR_ID;
 287                 }
 288 {Label}         {
 289                   yytext[strlen(yytext)-1] = 0;  // nuke colon
 290                   UnEscapeLexed(yytext);
 291                   llvmAsmlval.StrVal = strdup(yytext);
 292                   return LABELSTR;
 293                 }
 294 {QuoteLabel}    {
 295                   yytext[strlen(yytext)-2] = 0;  // nuke colon, end quote
 296                   UnEscapeLexed(yytext+1);
 297                   llvmAsmlval.StrVal = strdup(yytext+1);
 298                   return LABELSTR;
 299                 }
 300
 301 {StringConstant} { // Note that we cannot unescape a string constant here!  The
 302                    // string constant might contain a \00 which would not be
 303                    // understood by the string stuff.  It is valid to make a
 304                    // [sbyte] c"Hello World\00" constant, for example.
 305                    //
 306                    yytext[strlen(yytext)-1] = 0;           // nuke end quote
 307                    llvmAsmlval.StrVal = strdup(yytext+1);  // Nuke start quote
 308                    return STRINGCONSTANT;
 309                  }
 310
 311
 312 {PInteger}      { llvmAsmlval.UInt64Val = atoull(yytext); return EUINT64VAL; }
 313 {NInteger}      {
 314                   uint64_t Val = atoull(yytext+1);
 315                   // +1:  we have bigger negative range
 316                   if (Val > (uint64_t)INT64_MAX+1)
 317                     ThrowException("Constant too large for signed 64 bits!");
 318                   llvmAsmlval.SInt64Val = -Val;
 319                   return ESINT64VAL;
 320                 }
 321 {HexIntConstant} {
 322                    llvmAsmlval.UInt64Val = HexIntToVal(yytext+3);
 323                    return yytext[0] == 's' ? ESINT64VAL : EUINT64VAL;
 324                  }
 325
 326 {EPInteger}     {
 327                   uint64_t Val = atoull(yytext+1);
 328                   if ((unsigned)Val != Val)
 329                     ThrowException("Invalid value number (too large)!");
 330                   llvmAsmlval.UIntVal = unsigned(Val);
 331                   return UINTVAL;
 332                 }
 333 {ENInteger}     {
 334                   uint64_t Val = atoull(yytext+2);
 335                   // +1:  we have bigger negative range
 336                   if (Val > (uint64_t)INT32_MAX+1)
 337                     ThrowException("Constant too large for signed 32 bits!");
 338                   llvmAsmlval.SIntVal = (int)-Val;
 339                   return SINTVAL;
 340                 }
 341
 342 {FPConstant}    { llvmAsmlval.FPVal = atof(yytext); return FPVAL; }
 343 {HexFPConstant} { llvmAsmlval.FPVal = HexToFP(yytext); return FPVAL; }
 344
 345 <<EOF>>         {
 346                   /* Make sure to free the internal buffers for flex when we are
 347                    * done reading our input!
 348                    */
 349                   yy_delete_buffer(YY_CURRENT_BUFFER);
 350                   return EOF;
 351                 }
 352
 353 [ \r\t\n]       { /* Ignore whitespace */ }
 354 .               { return yytext[0]; }
 355
 356 %%
 357