lib/AsmParser/Lexer.l.cvs

   1 /*===-- Lexer.l - Scanner for llvm assembly files --------------*- C++ -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 //  This file implements the flex scanner for LLVM assembly languages files.
  11 //
  12 //===----------------------------------------------------------------------===*/
  13
  14 %option prefix="llvmAsm"
  15 %option yylineno
  16 %option nostdinit
  17 %option never-interactive
  18 %option batch
  19 %option noyywrap
  20 %option nodefault
  21 %option 8bit
  22 %option outfile="Lexer.cpp"
  23 %option ecs
  24 %option noreject
  25 %option noyymore
  26
  27 %{
  28 #include "ParserInternals.h"
  29 #include "llvm/Module.h"
  30 #include <list>
  31 #include "llvmAsmParser.h"
  32 #include <cctype>
  33 #include <cstdlib>
  34
  35 void set_scan_file(FILE * F){
  36   yy_switch_to_buffer(yy_create_buffer( F, YY_BUF_SIZE ) );
  37 }
  38 void set_scan_string (const char * str) {
  39   yy_scan_string (str);
  40 }
  41
  42 // Construct a token value for a non-obsolete token
  43 #define RET_TOK(type, Enum, sym) \
  44   llvmAsmlval.type = Instruction::Enum; \
  45   return sym
  46
  47 // Construct a token value for an obsolete token
  48 #define RET_TY(CTYPE, SYM) \
  49   llvmAsmlval.PrimType = CTYPE;\
  50   return SYM
  51
  52 namespace llvm {
  53
  54 // TODO: All of the static identifiers are figured out by the lexer,
  55 // these should be hashed to reduce the lexer size
  56
  57
  58 // atoull - Convert an ascii string of decimal digits into the unsigned long
  59 // long representation... this does not have to do input error checking,
  60 // because we know that the input will be matched by a suitable regex...
  61 //
  62 static uint64_t atoull(const char *Buffer) {
  63   uint64_t Result = 0;
  64   for (; *Buffer; Buffer++) {
  65     uint64_t OldRes = Result;
  66     Result *= 10;
  67     Result += *Buffer-'0';
  68     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  69       GenerateError("constant bigger than 64 bits detected!");
  70   }
  71   return Result;
  72 }
  73
  74 static uint64_t HexIntToVal(const char *Buffer) {
  75   uint64_t Result = 0;
  76   for (; *Buffer; ++Buffer) {
  77     uint64_t OldRes = Result;
  78     Result *= 16;
  79     char C = *Buffer;
  80     if (C >= '0' && C <= '9')
  81       Result += C-'0';
  82     else if (C >= 'A' && C <= 'F')
  83       Result += C-'A'+10;
  84     else if (C >= 'a' && C <= 'f')
  85       Result += C-'a'+10;
  86
  87     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  88       GenerateError("constant bigger than 64 bits detected!");
  89   }
  90   return Result;
  91 }
  92
  93
  94 // HexToFP - Convert the ascii string in hexidecimal format to the floating
  95 // point representation of it.
  96 //
  97 static double HexToFP(const char *Buffer) {
  98   // Behave nicely in the face of C TBAA rules... see:
  99   // http://www.nullstone.com/htmls/category/aliastyp.htm
 100   union {
 101     uint64_t UI;
 102     double FP;
 103   } UIntToFP;
 104   UIntToFP.UI = HexIntToVal(Buffer);
 105
 106   assert(sizeof(double) == sizeof(uint64_t) &&
 107          "Data sizes incompatible on this target!");
 108   return UIntToFP.FP;   // Cast Hex constant to double
 109 }
 110
 111
 112 // UnEscapeLexed - Run through the specified buffer and change \xx codes to the
 113 // appropriate character.  If AllowNull is set to false, a \00 value will cause
 114 // an exception to be thrown.
 115 //
 116 // If AllowNull is set to true, the return value of the function points to the
 117 // last character of the string in memory.
 118 //
 119 char *UnEscapeLexed(char *Buffer, bool AllowNull) {
 120   char *BOut = Buffer;
 121   for (char *BIn = Buffer; *BIn; ) {
 122     if (BIn[0] == '\\' && isxdigit(BIn[1]) && isxdigit(BIn[2])) {
 123       char Tmp = BIn[3]; BIn[3] = 0;     // Terminate string
 124       *BOut = (char)strtol(BIn+1, 0, 16);  // Convert to number
 125       if (!AllowNull && !*BOut)
 126         GenerateError("String literal cannot accept \\00 escape!");
 127
 128       BIn[3] = Tmp;                  // Restore character
 129       BIn += 3;                      // Skip over handled chars
 130       ++BOut;
 131     } else {
 132       *BOut++ = *BIn++;
 133     }
 134   }
 135
 136   return BOut;
 137 }
 138
 139 } // End llvm namespace
 140
 141 using namespace llvm;
 142
 143 #define YY_NEVER_INTERACTIVE 1
 144 %}
 145
 146
 147
 148 /* Comments start with a ; and go till end of line */
 149 Comment    ;.*
 150
 151 /* Local Values and Type identifiers start with a % sign */
 152 LocalVarName       %[-a-zA-Z$._][-a-zA-Z$._0-9]*
 153
 154 /* Global Value identifiers start with an @ sign */
 155 GlobalVarName       @[-a-zA-Z$._][-a-zA-Z$._0-9]*
 156
 157 /* Label identifiers end with a colon */
 158 Label       [-a-zA-Z$._0-9]+:
 159 QuoteLabel \"[^\"]+\":
 160
 161 /* Quoted names can contain any character except " and \ */
 162 StringConstant \"[^\"]*\"
 163 AtStringConstant @\"[^\"]*\"
 164
 165 /* LocalVarID/GlobalVarID: match an unnamed local variable slot ID. */
 166 LocalVarID     %[0-9]+
 167 GlobalVarID    @[0-9]+
 168
 169 /* Integer types are specified with i and a bitwidth */
 170 IntegerType i[0-9]+
 171
 172 /* E[PN]Integer: match positive and negative literal integer values. */
 173 PInteger   [0-9]+
 174 NInteger  -[0-9]+
 175
 176 /* FPConstant - A Floating point constant.
 177  */
 178 FPConstant [-+]?[0-9]+[.][0-9]*([eE][-+]?[0-9]+)?
 179
 180 /* HexFPConstant - Floating point constant represented in IEEE format as a
 181  *  hexadecimal number for when exponential notation is not precise enough.
 182  */
 183 HexFPConstant 0x[0-9A-Fa-f]+
 184
 185 /* HexIntConstant - Hexadecimal constant generated by the CFE to avoid forcing
 186  * it to deal with 64 bit numbers.
 187  */
 188 HexIntConstant [us]0x[0-9A-Fa-f]+
 189
 190 %%
 191
 192 {Comment}       { /* Ignore comments for now */ }
 193
 194 begin           { return BEGINTOK; }
 195 end             { return ENDTOK; }
 196 true            { return TRUETOK;  }
 197 false           { return FALSETOK; }
 198 declare         { return DECLARE; }
 199 define          { return DEFINE; }
 200 global          { return GLOBAL; }
 201 constant        { return CONSTANT; }
 202 internal        { return INTERNAL; }
 203 linkonce        { return LINKONCE; }
 204 weak            { return WEAK; }
 205 appending       { return APPENDING; }
 206 dllimport       { return DLLIMPORT; }
 207 dllexport       { return DLLEXPORT; }
 208 hidden          { return HIDDEN; }
 209 extern_weak     { return EXTERN_WEAK; }
 210 external        { return EXTERNAL; }
 211 implementation  { return IMPLEMENTATION; }
 212 zeroinitializer { return ZEROINITIALIZER; }
 213 \.\.\.          { return DOTDOTDOT; }
 214 undef           { return UNDEF; }
 215 null            { return NULL_TOK; }
 216 to              { return TO; }
 217 tail            { return TAIL; }
 218 target          { return TARGET; }
 219 triple          { return TRIPLE; }
 220 deplibs         { return DEPLIBS; }
 221 datalayout      { return DATALAYOUT; }
 222 volatile        { return VOLATILE; }
 223 align           { return ALIGN;  }
 224 section         { return SECTION; }
 225 module          { return MODULE; }
 226 asm             { return ASM_TOK; }
 227 sideeffect      { return SIDEEFFECT; }
 228
 229 cc              { return CC_TOK; }
 230 ccc             { return CCC_TOK; }
 231 fastcc          { return FASTCC_TOK; }
 232 coldcc          { return COLDCC_TOK; }
 233 x86_stdcallcc   { return X86_STDCALLCC_TOK; }
 234 x86_fastcallcc  { return X86_FASTCALLCC_TOK; }
 235
 236 inreg           { return INREG; }
 237 sret            { return SRET;  }
 238
 239 void            { RET_TY(Type::VoidTy,  VOID);  }
 240 float           { RET_TY(Type::FloatTy, FLOAT); }
 241 double          { RET_TY(Type::DoubleTy,DOUBLE);}
 242 label           { RET_TY(Type::LabelTy, LABEL); }
 243 type            { return TYPE;   }
 244 opaque          { return OPAQUE; }
 245 {IntegerType}   { uint64_t NumBits = atoull(yytext+1);
 246                   if (NumBits < IntegerType::MIN_INT_BITS ||
 247                       NumBits > IntegerType::MAX_INT_BITS)
 248                     GenerateError("Bitwidth for integer type out of range!");
 249                   const Type* Ty = IntegerType::get(NumBits);
 250                   RET_TY(Ty, INTTYPE);
 251                 }
 252
 253 add             { RET_TOK(BinaryOpVal, Add, ADD); }
 254 sub             { RET_TOK(BinaryOpVal, Sub, SUB); }
 255 mul             { RET_TOK(BinaryOpVal, Mul, MUL); }
 256 udiv            { RET_TOK(BinaryOpVal, UDiv, UDIV); }
 257 sdiv            { RET_TOK(BinaryOpVal, SDiv, SDIV); }
 258 fdiv            { RET_TOK(BinaryOpVal, FDiv, FDIV); }
 259 urem            { RET_TOK(BinaryOpVal, URem, UREM); }
 260 srem            { RET_TOK(BinaryOpVal, SRem, SREM); }
 261 frem            { RET_TOK(BinaryOpVal, FRem, FREM); }
 262 shl             { RET_TOK(BinaryOpVal, Shl, SHL); }
 263 lshr            { RET_TOK(BinaryOpVal, LShr, LSHR); }
 264 ashr            { RET_TOK(BinaryOpVal, AShr, ASHR); }
 265 and             { RET_TOK(BinaryOpVal, And, AND); }
 266 or              { RET_TOK(BinaryOpVal, Or , OR ); }
 267 xor             { RET_TOK(BinaryOpVal, Xor, XOR); }
 268 icmp            { RET_TOK(OtherOpVal,  ICmp,  ICMP); }
 269 fcmp            { RET_TOK(OtherOpVal,  FCmp,  FCMP); }
 270
 271 eq              { return EQ;  }
 272 ne              { return NE;  }
 273 slt             { return SLT; }
 274 sgt             { return SGT; }
 275 sle             { return SLE; }
 276 sge             { return SGE; }
 277 ult             { return ULT; }
 278 ugt             { return UGT; }
 279 ule             { return ULE; }
 280 uge             { return UGE; }
 281 oeq             { return OEQ; }
 282 one             { return ONE; }
 283 olt             { return OLT; }
 284 ogt             { return OGT; }
 285 ole             { return OLE; }
 286 oge             { return OGE; }
 287 ord             { return ORD; }
 288 uno             { return UNO; }
 289 ueq             { return UEQ; }
 290 une             { return UNE; }
 291
 292 phi             { RET_TOK(OtherOpVal, PHI, PHI_TOK); }
 293 call            { RET_TOK(OtherOpVal, Call, CALL); }
 294 trunc           { RET_TOK(CastOpVal, Trunc, TRUNC); }
 295 zext            { RET_TOK(CastOpVal, ZExt, ZEXT); }
 296 sext            { RET_TOK(CastOpVal, SExt, SEXT); }
 297 fptrunc         { RET_TOK(CastOpVal, FPTrunc, FPTRUNC); }
 298 fpext           { RET_TOK(CastOpVal, FPExt, FPEXT); }
 299 uitofp          { RET_TOK(CastOpVal, UIToFP, UITOFP); }
 300 sitofp          { RET_TOK(CastOpVal, SIToFP, SITOFP); }
 301 fptoui          { RET_TOK(CastOpVal, FPToUI, FPTOUI); }
 302 fptosi          { RET_TOK(CastOpVal, FPToSI, FPTOSI); }
 303 inttoptr        { RET_TOK(CastOpVal, IntToPtr, INTTOPTR); }
 304 ptrtoint        { RET_TOK(CastOpVal, PtrToInt, PTRTOINT); }
 305 bitcast         { RET_TOK(CastOpVal, BitCast, BITCAST); }
 306 select          { RET_TOK(OtherOpVal, Select, SELECT); }
 307 va_arg          { RET_TOK(OtherOpVal, VAArg , VAARG); }
 308 ret             { RET_TOK(TermOpVal, Ret, RET); }
 309 br              { RET_TOK(TermOpVal, Br, BR); }
 310 switch          { RET_TOK(TermOpVal, Switch, SWITCH); }
 311 invoke          { RET_TOK(TermOpVal, Invoke, INVOKE); }
 312 unwind          { RET_TOK(TermOpVal, Unwind, UNWIND); }
 313 unreachable     { RET_TOK(TermOpVal, Unreachable, UNREACHABLE); }
 314
 315 malloc          { RET_TOK(MemOpVal, Malloc, MALLOC); }
 316 alloca          { RET_TOK(MemOpVal, Alloca, ALLOCA); }
 317 free            { RET_TOK(MemOpVal, Free, FREE); }
 318 load            { RET_TOK(MemOpVal, Load, LOAD); }
 319 store           { RET_TOK(MemOpVal, Store, STORE); }
 320 getelementptr   { RET_TOK(MemOpVal, GetElementPtr, GETELEMENTPTR); }
 321
 322 extractelement  { RET_TOK(OtherOpVal, ExtractElement, EXTRACTELEMENT); }
 323 insertelement   { RET_TOK(OtherOpVal, InsertElement, INSERTELEMENT); }
 324 shufflevector   { RET_TOK(OtherOpVal, ShuffleVector, SHUFFLEVECTOR); }
 325
 326
 327 {LocalVarName}  {
 328                   UnEscapeLexed(yytext+1);
 329                   llvmAsmlval.StrVal = strdup(yytext+1);             // Skip %
 330                   return LOCALVAR;
 331                 }
 332 {GlobalVarName} {
 333                   UnEscapeLexed(yytext+1);
 334                   llvmAsmlval.StrVal = strdup(yytext+1);             // Skip @
 335                   return GLOBALVAR;
 336                 }
 337 {Label}         {
 338                   yytext[strlen(yytext)-1] = 0;  // nuke colon
 339                   UnEscapeLexed(yytext);
 340                   llvmAsmlval.StrVal = strdup(yytext);
 341                   return LABELSTR;
 342                 }
 343 {QuoteLabel}    {
 344                   yytext[strlen(yytext)-2] = 0;  // nuke colon, end quote
 345                   UnEscapeLexed(yytext+1);
 346                   llvmAsmlval.StrVal = strdup(yytext+1);
 347                   return LABELSTR;
 348                 }
 349
 350 {StringConstant} { // Note that we cannot unescape a string constant here!  The
 351                    // string constant might contain a \00 which would not be
 352                    // understood by the string stuff.  It is valid to make a
 353                    // [sbyte] c"Hello World\00" constant, for example.
 354                    //
 355                    yytext[strlen(yytext)-1] = 0;           // nuke end quote
 356                    llvmAsmlval.StrVal = strdup(yytext+1);  // Nuke start quote
 357                    return STRINGCONSTANT;
 358                  }
 359 {AtStringConstant} {
 360                      yytext[strlen(yytext)-1] = 0;           // nuke end quote
 361                      llvmAsmlval.StrVal = strdup(yytext+2);  // Nuke @, quote
 362                      return ATSTRINGCONSTANT;
 363                    }
 364
 365 {PInteger}      { int len = strlen(yytext);
 366                   uint32_t numBits = ((len * 64) / 19) + 1;
 367                   APInt Tmp(numBits, yytext, len, 10);
 368                   uint32_t activeBits = Tmp.getActiveBits();
 369                   if (activeBits > 0 && activeBits < numBits)
 370                     Tmp.trunc(activeBits);
 371                   if (Tmp.getBitWidth() > 64) {
 372                     llvmAsmlval.APIntVal = new APInt(Tmp);
 373                     return EUAPINTVAL;
 374                   } else {
 375                     llvmAsmlval.UInt64Val = Tmp.getZExtValue();
 376                     return EUINT64VAL;
 377                   }
 378                 }
 379 {NInteger}      { int len = strlen(yytext);
 380                   uint32_t numBits = (((len-1) * 64) / 19) + 1;
 381                   APInt Tmp(numBits, yytext, len, 10);
 382                   uint32_t minBits = Tmp.getMinSignedBits();
 383                   if (minBits > 0 && minBits < numBits)
 384                     Tmp.trunc(minBits);
 385                   if (Tmp.getBitWidth() > 64) {
 386                     llvmAsmlval.APIntVal = new APInt(Tmp);
 387                     return ESAPINTVAL;
 388                   } else {
 389                     llvmAsmlval.SInt64Val = Tmp.getSExtValue();
 390                     return ESINT64VAL;
 391                   }
 392                 }
 393
 394 {HexIntConstant} { int len = strlen(yytext+3) - 3;
 395                    uint32_t bits = len * 4;
 396                    APInt Tmp(bits, yytext+3, len, 16);
 397                    uint32_t activeBits = Tmp.getActiveBits();
 398                    if (activeBits > 0 && activeBits < bits)
 399                      Tmp.trunc(activeBits);
 400                    if (Tmp.getBitWidth() > 64) {
 401                      llvmAsmlval.APIntVal = new APInt(Tmp);
 402                      return yytext[0] == 's' ? ESAPINTVAL : EUAPINTVAL;
 403                    } else if (yytext[0] == 's') {
 404                      llvmAsmlval.SInt64Val = Tmp.getSExtValue();
 405                      return ESINT64VAL;
 406                    } else {
 407                      llvmAsmlval.UInt64Val = Tmp.getZExtValue();
 408                      return EUINT64VAL;
 409                    }
 410                  }
 411
 412 {LocalVarID}     {
 413                   uint64_t Val = atoull(yytext+1);
 414                   if ((unsigned)Val != Val)
 415                     GenerateError("Invalid value number (too large)!");
 416                   llvmAsmlval.UIntVal = unsigned(Val);
 417                   return LOCALVAL_ID;
 418                 }
 419 {GlobalVarID}   {
 420                   uint64_t Val = atoull(yytext+1);
 421                   if ((unsigned)Val != Val)
 422                     GenerateError("Invalid value number (too large)!");
 423                   llvmAsmlval.UIntVal = unsigned(Val);
 424                   return GLOBALVAL_ID;
 425                 }
 426
 427 {FPConstant}    { llvmAsmlval.FPVal = atof(yytext); return FPVAL; }
 428 {HexFPConstant} { llvmAsmlval.FPVal = HexToFP(yytext); return FPVAL; }
 429
 430 <<EOF>>         {
 431                   /* Make sure to free the internal buffers for flex when we are
 432                    * done reading our input!
 433                    */
 434                   yy_delete_buffer(YY_CURRENT_BUFFER);
 435                   return EOF;
 436                 }
 437
 438 [ \r\t\n]       { /* Ignore whitespace */ }
 439 .               { return yytext[0]; }
 440
 441 %%