lib/AsmParser/Lexer.l

   1 /*===-- Lexer.l - Scanner for llvm assembly files ----------------*- C++ -*--=//
   2 //
   3 //  This file implements the flex scanner for LLVM assembly languages files.
   4 //
   5 //===------------------------------------------------------------------------=*/
   6
   7 %option prefix="llvmAsm"
   8 %option yylineno
   9 %option nostdinit
  10 %option never-interactive
  11 %option batch
  12 %option noyywrap
  13 %option nodefault
  14 %option 8bit
  15 %option outfile="Lexer.cpp"
  16 %option ecs
  17 %option noreject
  18 %option noyymore
  19
  20 %{
  21 #include "ParserInternals.h"
  22 #include "llvm/BasicBlock.h"
  23 #include "llvm/Method.h"
  24 #include "llvm/Module.h"
  25 #include <list>
  26 #include "llvmAsmParser.h"
  27 #include <ctype.h>
  28 #include <stdlib.h>
  29
  30 #define RET_TOK(type, Enum, sym) \
  31   llvmAsmlval.type = Instruction::Enum; return sym
  32
  33
  34 // TODO: All of the static identifiers are figured out by the lexer,
  35 // these should be hashed to reduce the lexer size
  36
  37
  38 // atoull - Convert an ascii string of decimal digits into the unsigned long
  39 // long representation... this does not have to do input error checking,
  40 // because we know that the input will be matched by a suitable regex...
  41 //
  42 uint64_t atoull(const char *Buffer) {
  43   uint64_t Result = 0;
  44   for (; *Buffer; Buffer++) {
  45     uint64_t OldRes = Result;
  46     Result *= 10;
  47     Result += *Buffer-'0';
  48     if (Result < OldRes) {  // Uh, oh, overflow detected!!!
  49       ThrowException("constant bigger than 64 bits detected!");
  50     }
  51   }
  52   return Result;
  53 }
  54
  55
  56 // UnEscapeLexed - Run through the specified buffer and change \xx codes to the
  57 // appropriate character.  If AllowNull is set to false, a \00 value will cause
  58 // an exception to be thrown.
  59 //
  60 // If AllowNull is set to true, the return value of the function points to the
  61 // last character of the string in memory.
  62 //
  63 char *UnEscapeLexed(char *Buffer, bool AllowNull = false) {
  64   char *BOut = Buffer;
  65   for (char *BIn = Buffer; *BIn; ) {
  66     if (BIn[0] == '\\' && isxdigit(BIn[1]) && isxdigit(BIn[2])) {
  67       char Tmp = BIn[3]; BIn[3] = 0;     // Terminate string
  68       *BOut = strtol(BIn+1, 0, 16);  // Convert to number
  69       if (!AllowNull && !*BOut)
  70         ThrowException("String literal cannot accept \\00 escape!");
  71
  72       BIn[3] = Tmp;                  // Restore character
  73       BIn += 3;                      // Skip over handled chars
  74       ++BOut;
  75     } else {
  76       *BOut++ = *BIn++;
  77     }
  78   }
  79
  80   return BOut;
  81 }
  82
  83 #define YY_NEVER_INTERACTIVE 1
  84 %}
  85
  86
  87
  88 /* Comments start with a ; and go till end of line */
  89 Comment    ;.*
  90
  91 /* Variable(Value) identifiers start with a % sign */
  92 VarID       %[a-zA-Z$._][a-zA-Z$._0-9]*
  93
  94 /* Label identifiers end with a colon */
  95 Label       [a-zA-Z$._0-9]+:
  96
  97 /* Quoted names can contain any character except " and \ */
  98 StringConstant \"[^\"]+\"
  99
 100
 101 /* [PN]Integer: match positive and negative literal integer values that
 102  * are preceeded by a '%' character.  These represent unnamed variable slots.
 103  */
 104 EPInteger     %[0-9]+
 105 ENInteger    %-[0-9]+
 106
 107
 108 /* E[PN]Integer: match positive and negative literal integer values */
 109 PInteger   [0-9]+
 110 NInteger  -[0-9]+
 111
 112 /* FPConstant - A Floating point constant.
 113    TODO: Expand lexer to support 10e50 FP constant notation */
 114 FPConstant [-+]?[0-9]+[.][0-9]*([eE][-+]?[0-9]+)?
 115
 116 %%
 117
 118 {Comment}       { /* Ignore comments for now */ }
 119
 120 begin           { return BEGINTOK; }
 121 end             { return END; }
 122 true            { return TRUE;  }
 123 false           { return FALSE; }
 124 declare         { return DECLARE; }
 125 global          { return GLOBAL; }
 126 constant        { return CONSTANT; }
 127 const           { return CONST; }
 128 uninitialized   { return UNINIT; }
 129 implementation  { return IMPLEMENTATION; }
 130 \.\.\.          { return DOTDOTDOT; }
 131 string          { return STRING; }
 132 null            { return NULL_TOK; }
 133 to              { return TO; }
 134 except          { return EXCEPT; }
 135
 136 void            { llvmAsmlval.PrimType = Type::VoidTy  ; return VOID;   }
 137 bool            { llvmAsmlval.PrimType = Type::BoolTy  ; return BOOL;   }
 138 sbyte           { llvmAsmlval.PrimType = Type::SByteTy ; return SBYTE;  }
 139 ubyte           { llvmAsmlval.PrimType = Type::UByteTy ; return UBYTE;  }
 140 short           { llvmAsmlval.PrimType = Type::ShortTy ; return SHORT;  }
 141 ushort          { llvmAsmlval.PrimType = Type::UShortTy; return USHORT; }
 142 int             { llvmAsmlval.PrimType = Type::IntTy   ; return INT;    }
 143 uint            { llvmAsmlval.PrimType = Type::UIntTy  ; return UINT;   }
 144 long            { llvmAsmlval.PrimType = Type::LongTy  ; return LONG;   }
 145 ulong           { llvmAsmlval.PrimType = Type::ULongTy ; return ULONG;  }
 146 float           { llvmAsmlval.PrimType = Type::FloatTy ; return FLOAT;  }
 147 double          { llvmAsmlval.PrimType = Type::DoubleTy; return DOUBLE; }
 148
 149 type            { llvmAsmlval.PrimType = Type::TypeTy  ; return TYPE;   }
 150
 151 label           { llvmAsmlval.PrimType = Type::LabelTy ; return LABEL;  }
 152 opaque          { llvmAsmlval.TypeVal =
 153                     new PATypeHolder<Type>(OpaqueType::get());
 154                   return OPAQUE;
 155                 }
 156
 157
 158 not             { RET_TOK(UnaryOpVal, Not, NOT); }
 159
 160 add             { RET_TOK(BinaryOpVal, Add, ADD); }
 161 sub             { RET_TOK(BinaryOpVal, Sub, SUB); }
 162 mul             { RET_TOK(BinaryOpVal, Mul, MUL); }
 163 div             { RET_TOK(BinaryOpVal, Div, DIV); }
 164 rem             { RET_TOK(BinaryOpVal, Rem, REM); }
 165 and             { RET_TOK(BinaryOpVal, And, AND); }
 166 or              { RET_TOK(BinaryOpVal, Or , OR ); }
 167 xor             { RET_TOK(BinaryOpVal, Xor, XOR); }
 168 setne           { RET_TOK(BinaryOpVal, SetNE, SETNE); }
 169 seteq           { RET_TOK(BinaryOpVal, SetEQ, SETEQ); }
 170 setlt           { RET_TOK(BinaryOpVal, SetLT, SETLT); }
 171 setgt           { RET_TOK(BinaryOpVal, SetGT, SETGT); }
 172 setle           { RET_TOK(BinaryOpVal, SetLE, SETLE); }
 173 setge           { RET_TOK(BinaryOpVal, SetGE, SETGE); }
 174
 175 phi             { RET_TOK(OtherOpVal, PHINode, PHI); }
 176 call            { RET_TOK(OtherOpVal, Call, CALL); }
 177 cast            { RET_TOK(OtherOpVal, Cast, CAST); }
 178 shl             { RET_TOK(OtherOpVal, Shl, SHL); }
 179 shr             { RET_TOK(OtherOpVal, Shr, SHR); }
 180
 181 ret             { RET_TOK(TermOpVal, Ret, RET); }
 182 br              { RET_TOK(TermOpVal, Br, BR); }
 183 switch          { RET_TOK(TermOpVal, Switch, SWITCH); }
 184 invoke          { RET_TOK(TermOpVal, Invoke, INVOKE); }
 185
 186
 187 malloc          { RET_TOK(MemOpVal, Malloc, MALLOC); }
 188 alloca          { RET_TOK(MemOpVal, Alloca, ALLOCA); }
 189 free            { RET_TOK(MemOpVal, Free, FREE); }
 190 load            { RET_TOK(MemOpVal, Load, LOAD); }
 191 store           { RET_TOK(MemOpVal, Store, STORE); }
 192 getelementptr   { RET_TOK(MemOpVal, GetElementPtr, GETELEMENTPTR); }
 193
 194
 195 {VarID}         {
 196                   UnEscapeLexed(yytext+1);
 197                   llvmAsmlval.StrVal = strdup(yytext+1);             // Skip %
 198                   return VAR_ID;
 199                 }
 200 {Label}         {
 201                   yytext[strlen(yytext)-1] = 0;  // nuke colon
 202                   UnEscapeLexed(yytext);
 203                   llvmAsmlval.StrVal = strdup(yytext);
 204                   return LABELSTR;
 205                 }
 206
 207 {StringConstant} { // Note that we cannot unescape a string constant here!  The
 208                    // string constant might contain a \00 which would not be
 209                    // understood by the string stuff.  It is valid to make a
 210                    // [sbyte] c"Hello World\00" constant, for example.
 211                    //
 212                   yytext[strlen(yytext)-1] = 0;           // nuke end quote
 213                   llvmAsmlval.StrVal = strdup(yytext+1);  // Nuke start quote
 214                   return STRINGCONSTANT;
 215                  }
 216
 217
 218 {PInteger}      { llvmAsmlval.UInt64Val = atoull(yytext); return EUINT64VAL; }
 219 {NInteger}      {
 220                   uint64_t Val = atoull(yytext+1);
 221                   // +1:  we have bigger negative range
 222                   if (Val > (uint64_t)INT64_MAX+1)
 223                     ThrowException("Constant too large for signed 64 bits!");
 224                   llvmAsmlval.SInt64Val = -Val;
 225                   return ESINT64VAL;
 226                 }
 227
 228
 229 {EPInteger}     { llvmAsmlval.UIntVal = atoull(yytext+1); return UINTVAL; }
 230 {ENInteger}     {
 231                   uint64_t Val = atoull(yytext+2);
 232                   // +1:  we have bigger negative range
 233                   if (Val > (uint64_t)INT32_MAX+1)
 234                     ThrowException("Constant too large for signed 32 bits!");
 235                   llvmAsmlval.SIntVal = -Val;
 236                   return SINTVAL;
 237                 }
 238
 239 {FPConstant}    { llvmAsmlval.FPVal = atof(yytext); return FPVAL; }
 240
 241 [ \t\n]         { /* Ignore whitespace */ }
 242 .               { return yytext[0]; }
 243
 244 %%