lib/AsmParser/Lexer.l

   1 /*===-- Lexer.l - Scanner for llvm assembly files --------------*- C++ -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 //  This file implements the flex scanner for LLVM assembly languages files.
  11 //
  12 //===----------------------------------------------------------------------===*/
  13
  14 %option prefix="llvmAsm"
  15 %option yylineno
  16 %option nostdinit
  17 %option never-interactive
  18 %option batch
  19 %option noyywrap
  20 %option nodefault
  21 %option 8bit
  22 %option outfile="Lexer.cpp"
  23 %option ecs
  24 %option noreject
  25 %option noyymore
  26
  27 %{
  28 #include "ParserInternals.h"
  29 #include "llvm/Module.h"
  30 #include "llvm/Support/MathExtras.h"
  31 #include <list>
  32 #include "llvmAsmParser.h"
  33 #include <cctype>
  34 #include <cstdlib>
  35
  36 void set_scan_file(FILE * F){
  37   yy_switch_to_buffer(yy_create_buffer( F, YY_BUF_SIZE ) );
  38 }
  39 void set_scan_string (const char * str) {
  40   yy_scan_string (str);
  41 }
  42
  43 // Construct a token value for a non-obsolete token
  44 #define RET_TOK(type, Enum, sym) \
  45   llvmAsmlval.type = Instruction::Enum; \
  46   return sym
  47
  48 // Construct a token value for an obsolete token
  49 #define RET_TY(CTYPE, SYM) \
  50   llvmAsmlval.PrimType = CTYPE;\
  51   return SYM
  52
  53 namespace llvm {
  54
  55 // TODO: All of the static identifiers are figured out by the lexer,
  56 // these should be hashed to reduce the lexer size
  57
  58
  59 // atoull - Convert an ascii string of decimal digits into the unsigned long
  60 // long representation... this does not have to do input error checking,
  61 // because we know that the input will be matched by a suitable regex...
  62 //
  63 static uint64_t atoull(const char *Buffer) {
  64   uint64_t Result = 0;
  65   for (; *Buffer; Buffer++) {
  66     uint64_t OldRes = Result;
  67     Result *= 10;
  68     Result += *Buffer-'0';
  69     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  70       GenerateError("constant bigger than 64 bits detected!");
  71   }
  72   return Result;
  73 }
  74
  75 static uint64_t HexIntToVal(const char *Buffer) {
  76   uint64_t Result = 0;
  77   for (; *Buffer; ++Buffer) {
  78     uint64_t OldRes = Result;
  79     Result *= 16;
  80     char C = *Buffer;
  81     if (C >= '0' && C <= '9')
  82       Result += C-'0';
  83     else if (C >= 'A' && C <= 'F')
  84       Result += C-'A'+10;
  85     else if (C >= 'a' && C <= 'f')
  86       Result += C-'a'+10;
  87
  88     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  89       GenerateError("constant bigger than 64 bits detected!");
  90   }
  91   return Result;
  92 }
  93
  94
  95 // HexToFP - Convert the ascii string in hexidecimal format to the floating
  96 // point representation of it.
  97 //
  98 static double HexToFP(const char *Buffer) {
  99   return BitsToDouble(HexIntToVal(Buffer));   // Cast Hex constant to double
 100 }
 101
 102
 103 // UnEscapeLexed - Run through the specified buffer and change \xx codes to the
 104 // appropriate character.
 105 char *UnEscapeLexed(char *Buffer, char* EndBuffer) {
 106   char *BOut = Buffer;
 107   for (char *BIn = Buffer; *BIn; ) {
 108     if (BIn[0] == '\\') {
 109       if (BIn < EndBuffer-1 && BIn[1] == '\\') {
 110         *BOut++ = '\\'; // Two \ becomes one
 111         BIn += 2;
 112       } else if (BIn < EndBuffer-2 && isxdigit(BIn[1]) && isxdigit(BIn[2])) {
 113         char Tmp = BIn[3]; BIn[3] = 0;      // Terminate string
 114         *BOut = (char)strtol(BIn+1, 0, 16); // Convert to number
 115         BIn[3] = Tmp;                       // Restore character
 116         BIn += 3;                           // Skip over handled chars
 117         ++BOut;
 118       } else {
 119         *BOut++ = *BIn++;
 120       }
 121     } else {
 122       *BOut++ = *BIn++;
 123     }
 124   }
 125   return BOut;
 126 }
 127
 128 } // End llvm namespace
 129
 130 using namespace llvm;
 131
 132 #define YY_NEVER_INTERACTIVE 1
 133 %}
 134
 135
 136
 137 /* Comments start with a ; and go till end of line */
 138 Comment    ;.*
 139
 140 /* Local Values and Type identifiers start with a % sign */
 141 LocalVarName       %[-a-zA-Z$._][-a-zA-Z$._0-9]*
 142
 143 /* Global Value identifiers start with an @ sign */
 144 GlobalVarName       @[-a-zA-Z$._][-a-zA-Z$._0-9]*
 145
 146 /* Label identifiers end with a colon */
 147 Label       [-a-zA-Z$._0-9]+:
 148 QuoteLabel \"[^\"]+\":
 149
 150 /* Quoted names can contain any character except " and \ */
 151 StringConstant \"[^\"]*\"
 152 AtStringConstant @\"[^\"]*\"
 153 PctStringConstant %\"[^\"]*\"
 154
 155 /* LocalVarID/GlobalVarID: match an unnamed local variable slot ID. */
 156 LocalVarID     %[0-9]+
 157 GlobalVarID    @[0-9]+
 158
 159 /* Integer types are specified with i and a bitwidth */
 160 IntegerType i[0-9]+
 161
 162 /* E[PN]Integer: match positive and negative literal integer values. */
 163 PInteger   [0-9]+
 164 NInteger  -[0-9]+
 165
 166 /* FPConstant - A Floating point constant.
 167  */
 168 FPConstant [-+]?[0-9]+[.][0-9]*([eE][-+]?[0-9]+)?
 169
 170 /* HexFPConstant - Floating point constant represented in IEEE format as a
 171  *  hexadecimal number for when exponential notation is not precise enough.
 172  */
 173 HexFPConstant 0x[0-9A-Fa-f]+
 174
 175 /* HexIntConstant - Hexadecimal constant generated by the CFE to avoid forcing
 176  * it to deal with 64 bit numbers.
 177  */
 178 HexIntConstant [us]0x[0-9A-Fa-f]+
 179
 180 %%
 181
 182 {Comment}       { /* Ignore comments for now */ }
 183
 184 begin           { return BEGINTOK; }
 185 end             { return ENDTOK; }
 186 true            { return TRUETOK;  }
 187 false           { return FALSETOK; }
 188 declare         { return DECLARE; }
 189 define          { return DEFINE; }
 190 global          { return GLOBAL; }
 191 constant        { return CONSTANT; }
 192 internal        { return INTERNAL; }
 193 linkonce        { return LINKONCE; }
 194 weak            { return WEAK; }
 195 appending       { return APPENDING; }
 196 dllimport       { return DLLIMPORT; }
 197 dllexport       { return DLLEXPORT; }
 198 hidden          { return HIDDEN; }
 199 protected       { return PROTECTED; }
 200 extern_weak     { return EXTERN_WEAK; }
 201 external        { return EXTERNAL; }
 202 thread_local    { return THREAD_LOCAL; }
 203 zeroinitializer { return ZEROINITIALIZER; }
 204 \.\.\.          { return DOTDOTDOT; }
 205 undef           { return UNDEF; }
 206 null            { return NULL_TOK; }
 207 to              { return TO; }
 208 tail            { return TAIL; }
 209 target          { return TARGET; }
 210 triple          { return TRIPLE; }
 211 deplibs         { return DEPLIBS; }
 212 datalayout      { return DATALAYOUT; }
 213 volatile        { return VOLATILE; }
 214 align           { return ALIGN;  }
 215 section         { return SECTION; }
 216 alias           { return ALIAS; }
 217 module          { return MODULE; }
 218 asm             { return ASM_TOK; }
 219 sideeffect      { return SIDEEFFECT; }
 220
 221 cc              { return CC_TOK; }
 222 ccc             { return CCC_TOK; }
 223 fastcc          { return FASTCC_TOK; }
 224 coldcc          { return COLDCC_TOK; }
 225 x86_stdcallcc   { return X86_STDCALLCC_TOK; }
 226 x86_fastcallcc  { return X86_FASTCALLCC_TOK; }
 227
 228 inreg           { return INREG; }
 229 sret            { return SRET;  }
 230 nounwind        { return NOUNWIND; }
 231 noreturn        { return NORETURN; }
 232 noalias         { return NOALIAS; }
 233
 234 void            { RET_TY(Type::VoidTy,  VOID);  }
 235 float           { RET_TY(Type::FloatTy, FLOAT); }
 236 double          { RET_TY(Type::DoubleTy,DOUBLE);}
 237 label           { RET_TY(Type::LabelTy, LABEL); }
 238 type            { return TYPE;   }
 239 opaque          { return OPAQUE; }
 240 {IntegerType}   { uint64_t NumBits = atoull(yytext+1);
 241                   if (NumBits < IntegerType::MIN_INT_BITS ||
 242                       NumBits > IntegerType::MAX_INT_BITS)
 243                     GenerateError("Bitwidth for integer type out of range!");
 244                   const Type* Ty = IntegerType::get(NumBits);
 245                   RET_TY(Ty, INTTYPE);
 246                 }
 247
 248 add             { RET_TOK(BinaryOpVal, Add, ADD); }
 249 sub             { RET_TOK(BinaryOpVal, Sub, SUB); }
 250 mul             { RET_TOK(BinaryOpVal, Mul, MUL); }
 251 udiv            { RET_TOK(BinaryOpVal, UDiv, UDIV); }
 252 sdiv            { RET_TOK(BinaryOpVal, SDiv, SDIV); }
 253 fdiv            { RET_TOK(BinaryOpVal, FDiv, FDIV); }
 254 urem            { RET_TOK(BinaryOpVal, URem, UREM); }
 255 srem            { RET_TOK(BinaryOpVal, SRem, SREM); }
 256 frem            { RET_TOK(BinaryOpVal, FRem, FREM); }
 257 shl             { RET_TOK(BinaryOpVal, Shl, SHL); }
 258 lshr            { RET_TOK(BinaryOpVal, LShr, LSHR); }
 259 ashr            { RET_TOK(BinaryOpVal, AShr, ASHR); }
 260 and             { RET_TOK(BinaryOpVal, And, AND); }
 261 or              { RET_TOK(BinaryOpVal, Or , OR ); }
 262 xor             { RET_TOK(BinaryOpVal, Xor, XOR); }
 263 icmp            { RET_TOK(OtherOpVal,  ICmp,  ICMP); }
 264 fcmp            { RET_TOK(OtherOpVal,  FCmp,  FCMP); }
 265
 266 eq              { return EQ;  }
 267 ne              { return NE;  }
 268 slt             { return SLT; }
 269 sgt             { return SGT; }
 270 sle             { return SLE; }
 271 sge             { return SGE; }
 272 ult             { return ULT; }
 273 ugt             { return UGT; }
 274 ule             { return ULE; }
 275 uge             { return UGE; }
 276 oeq             { return OEQ; }
 277 one             { return ONE; }
 278 olt             { return OLT; }
 279 ogt             { return OGT; }
 280 ole             { return OLE; }
 281 oge             { return OGE; }
 282 ord             { return ORD; }
 283 uno             { return UNO; }
 284 ueq             { return UEQ; }
 285 une             { return UNE; }
 286
 287 phi             { RET_TOK(OtherOpVal, PHI, PHI_TOK); }
 288 call            { RET_TOK(OtherOpVal, Call, CALL); }
 289 trunc           { RET_TOK(CastOpVal, Trunc, TRUNC); }
 290 zext            { RET_TOK(CastOpVal, ZExt, ZEXT); }
 291 sext            { RET_TOK(CastOpVal, SExt, SEXT); }
 292 fptrunc         { RET_TOK(CastOpVal, FPTrunc, FPTRUNC); }
 293 fpext           { RET_TOK(CastOpVal, FPExt, FPEXT); }
 294 uitofp          { RET_TOK(CastOpVal, UIToFP, UITOFP); }
 295 sitofp          { RET_TOK(CastOpVal, SIToFP, SITOFP); }
 296 fptoui          { RET_TOK(CastOpVal, FPToUI, FPTOUI); }
 297 fptosi          { RET_TOK(CastOpVal, FPToSI, FPTOSI); }
 298 inttoptr        { RET_TOK(CastOpVal, IntToPtr, INTTOPTR); }
 299 ptrtoint        { RET_TOK(CastOpVal, PtrToInt, PTRTOINT); }
 300 bitcast         { RET_TOK(CastOpVal, BitCast, BITCAST); }
 301 select          { RET_TOK(OtherOpVal, Select, SELECT); }
 302 va_arg          { RET_TOK(OtherOpVal, VAArg , VAARG); }
 303 ret             { RET_TOK(TermOpVal, Ret, RET); }
 304 br              { RET_TOK(TermOpVal, Br, BR); }
 305 switch          { RET_TOK(TermOpVal, Switch, SWITCH); }
 306 invoke          { RET_TOK(TermOpVal, Invoke, INVOKE); }
 307 unwind          { RET_TOK(TermOpVal, Unwind, UNWIND); }
 308 unreachable     { RET_TOK(TermOpVal, Unreachable, UNREACHABLE); }
 309
 310 malloc          { RET_TOK(MemOpVal, Malloc, MALLOC); }
 311 alloca          { RET_TOK(MemOpVal, Alloca, ALLOCA); }
 312 free            { RET_TOK(MemOpVal, Free, FREE); }
 313 load            { RET_TOK(MemOpVal, Load, LOAD); }
 314 store           { RET_TOK(MemOpVal, Store, STORE); }
 315 getelementptr   { RET_TOK(MemOpVal, GetElementPtr, GETELEMENTPTR); }
 316
 317 extractelement  { RET_TOK(OtherOpVal, ExtractElement, EXTRACTELEMENT); }
 318 insertelement   { RET_TOK(OtherOpVal, InsertElement, INSERTELEMENT); }
 319 shufflevector   { RET_TOK(OtherOpVal, ShuffleVector, SHUFFLEVECTOR); }
 320
 321
 322 {LocalVarName}  {
 323                   llvmAsmlval.StrVal = new std::string(yytext+1);   // Skip %
 324                   return LOCALVAR;
 325                 }
 326 {GlobalVarName} {
 327                   llvmAsmlval.StrVal = new std::string(yytext+1);   // Skip @
 328                   return GLOBALVAR;
 329                 }
 330 {Label}         {
 331                   yytext[yyleng-1] = 0;            // nuke colon
 332                   llvmAsmlval.StrVal = new std::string(yytext);
 333                   return LABELSTR;
 334                 }
 335 {QuoteLabel}    {
 336                   yytext[yyleng-2] = 0;  // nuke colon, end quote
 337                   const char* EndChar = UnEscapeLexed(yytext+1, yytext+yyleng);
 338                   llvmAsmlval.StrVal =
 339                     new std::string(yytext+1, EndChar - yytext - 1);
 340                   return LABELSTR;
 341                 }
 342
 343 {StringConstant} { yytext[yyleng-1] = 0;           // nuke end quote
 344                    const char* EndChar = UnEscapeLexed(yytext+1, yytext+yyleng);
 345                    llvmAsmlval.StrVal =
 346                      new std::string(yytext+1, EndChar - yytext - 1);
 347                    return STRINGCONSTANT;
 348                  }
 349 {AtStringConstant} {
 350                      yytext[yyleng-1] = 0;         // nuke end quote
 351                      const char* EndChar =
 352                        UnEscapeLexed(yytext+2, yytext+yyleng);
 353                      llvmAsmlval.StrVal =
 354                        new std::string(yytext+2, EndChar - yytext - 2);
 355                      return ATSTRINGCONSTANT;
 356                    }
 357 {PctStringConstant} {
 358                      yytext[yyleng-1] = 0;           // nuke end quote
 359                      const char* EndChar =
 360                        UnEscapeLexed(yytext+2, yytext+yyleng);
 361                      llvmAsmlval.StrVal =
 362                        new std::string(yytext+2, EndChar - yytext - 2);
 363                      return PCTSTRINGCONSTANT;
 364                    }
 365 {PInteger}      {
 366                   uint32_t numBits = ((yyleng * 64) / 19) + 1;
 367                   APInt Tmp(numBits, yytext, yyleng, 10);
 368                   uint32_t activeBits = Tmp.getActiveBits();
 369                   if (activeBits > 0 && activeBits < numBits)
 370                     Tmp.trunc(activeBits);
 371                   if (Tmp.getBitWidth() > 64) {
 372                     llvmAsmlval.APIntVal = new APInt(Tmp);
 373                     return EUAPINTVAL;
 374                   } else {
 375                     llvmAsmlval.UInt64Val = Tmp.getZExtValue();
 376                     return EUINT64VAL;
 377                   }
 378                 }
 379 {NInteger}      {
 380                   uint32_t numBits = (((yyleng-1) * 64) / 19) + 2;
 381                   APInt Tmp(numBits, yytext, yyleng, 10);
 382                   uint32_t minBits = Tmp.getMinSignedBits();
 383                   if (minBits > 0 && minBits < numBits)
 384                     Tmp.trunc(minBits);
 385                   if (Tmp.getBitWidth() > 64) {
 386                     llvmAsmlval.APIntVal = new APInt(Tmp);
 387                     return ESAPINTVAL;
 388                   } else {
 389                     llvmAsmlval.SInt64Val = Tmp.getSExtValue();
 390                     return ESINT64VAL;
 391                   }
 392                 }
 393
 394 {HexIntConstant} { int len = yyleng - 3;
 395                    uint32_t bits = len * 4;
 396                    APInt Tmp(bits, yytext+3, len, 16);
 397                    uint32_t activeBits = Tmp.getActiveBits();
 398                    if (activeBits > 0 && activeBits < bits)
 399                      Tmp.trunc(activeBits);
 400                    if (Tmp.getBitWidth() > 64) {
 401                      llvmAsmlval.APIntVal = new APInt(Tmp);
 402                      return yytext[0] == 's' ? ESAPINTVAL : EUAPINTVAL;
 403                    } else if (yytext[0] == 's') {
 404                      llvmAsmlval.SInt64Val = Tmp.getSExtValue();
 405                      return ESINT64VAL;
 406                    } else {
 407                      llvmAsmlval.UInt64Val = Tmp.getZExtValue();
 408                      return EUINT64VAL;
 409                    }
 410                  }
 411
 412 {LocalVarID}     {
 413                   uint64_t Val = atoull(yytext+1);
 414                   if ((unsigned)Val != Val)
 415                     GenerateError("Invalid value number (too large)!");
 416                   llvmAsmlval.UIntVal = unsigned(Val);
 417                   return LOCALVAL_ID;
 418                 }
 419 {GlobalVarID}   {
 420                   uint64_t Val = atoull(yytext+1);
 421                   if ((unsigned)Val != Val)
 422                     GenerateError("Invalid value number (too large)!");
 423                   llvmAsmlval.UIntVal = unsigned(Val);
 424                   return GLOBALVAL_ID;
 425                 }
 426
 427 {FPConstant}    { llvmAsmlval.FPVal = atof(yytext); return FPVAL; }
 428 {HexFPConstant} { llvmAsmlval.FPVal = HexToFP(yytext); return FPVAL; }
 429
 430 <<EOF>>         {
 431                   /* Make sure to free the internal buffers for flex when we are
 432                    * done reading our input!
 433                    */
 434                   yy_delete_buffer(YY_CURRENT_BUFFER);
 435                   return EOF;
 436                 }
 437
 438 [ \r\t\n]       { /* Ignore whitespace */ }
 439 .               { return yytext[0]; }
 440
 441 %%