include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def IntrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  52 def Commutative : IntrinsicProperty;
  53
  54 //===----------------------------------------------------------------------===//
  55 // Types used by intrinsics.
  56 //===----------------------------------------------------------------------===//
  57
  58 class LLVMType<ValueType vt> {
  59   ValueType VT = vt;
  60 }
  61
  62 class LLVMPointerType<LLVMType elty>
  63   : LLVMType<iPTR>{
  64   LLVMType ElTy = elty;
  65 }
  66
  67 class LLVMAnyPointerType<LLVMType elty>
  68   : LLVMType<iPTRAny>{
  69   LLVMType ElTy = elty;
  70 }
  71
  72 class LLVMMatchType<int num>
  73   : LLVMType<OtherVT>{
  74   int Number = num;
  75 }
  76
  77 def llvm_void_ty       : LLVMType<isVoid>;
  78 def llvm_anyint_ty     : LLVMType<iAny>;
  79 def llvm_anyfloat_ty   : LLVMType<fAny>;
  80 def llvm_i1_ty         : LLVMType<i1>;
  81 def llvm_i8_ty         : LLVMType<i8>;
  82 def llvm_i16_ty        : LLVMType<i16>;
  83 def llvm_i32_ty        : LLVMType<i32>;
  84 def llvm_i64_ty        : LLVMType<i64>;
  85 def llvm_float_ty      : LLVMType<f32>;
  86 def llvm_double_ty     : LLVMType<f64>;
  87 def llvm_f80_ty        : LLVMType<f80>;
  88 def llvm_f128_ty       : LLVMType<f128>;
  89 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
  90 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
  91 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
  92 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
  93 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
  94 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
  95
  96 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
  97 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
  98 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
  99 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 100 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 101 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 102 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 103 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 104
 105 // MMX Vector Types
 106 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 107 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 108
 109 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 110
 111 //===----------------------------------------------------------------------===//
 112 // Intrinsic Definitions.
 113 //===----------------------------------------------------------------------===//
 114
 115 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 116 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 117 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 118 // example, llvm.bswap.i16 -> int_bswap_i16.
 119 //
 120 //  * RetTypes is a list containing the return types expected for the
 121 //    intrinsic.
 122 //  * ParamTypes is a list containing the parameter types expected for the
 123 //    intrinsic.
 124 //  * Properties can be set to describe the behavior of the intrinsic.
 125 //
 126 class Intrinsic<list<LLVMType> ret_types,
 127                 list<LLVMType> param_types = [],
 128                 list<IntrinsicProperty> properties = [],
 129                 string name = ""> {
 130   string LLVMName = name;
 131   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 132   list<LLVMType> RetTypes = ret_types;
 133   list<LLVMType> ParamTypes = param_types;
 134   list<IntrinsicProperty> Properties = properties;
 135 }
 136
 137 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 138 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 139 /// support.
 140 class GCCBuiltin<string name> {
 141   string GCCBuiltinName = name;
 142 }
 143
 144
 145 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 146 //
 147
 148 def int_vastart : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_start">;
 149 def int_vacopy  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_ptr_ty], [],
 150                             "llvm.va_copy">;
 151 def int_vaend   : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_end">;
 152
 153 //===------------------- Garbage Collection Intrinsics --------------------===//
 154 //
 155 def int_gcroot  : Intrinsic<[llvm_void_ty],
 156                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 157 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 158                             [llvm_ptr_ty, llvm_ptrptr_ty],
 159                             [IntrReadArgMem]>;
 160 def int_gcwrite : Intrinsic<[llvm_void_ty],
 161                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 162                             [IntrWriteArgMem]>;
 163
 164 //===--------------------- Code Generator Intrinsics ----------------------===//
 165 //
 166 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 167 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 168
 169 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 170 // model their dependencies on allocas.
 171 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 172                         GCCBuiltin<"__builtin_stack_save">;
 173 def int_stackrestore  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty]>,
 174                         GCCBuiltin<"__builtin_stack_restore">;
 175
 176 // IntrWriteArgMem is more pessimistic than strictly necessary for prefetch,
 177 // however it does conveniently prevent the prefetch from being reordered
 178 // with respect to nearby accesses to the same memory.
 179 def int_prefetch      : Intrinsic<[llvm_void_ty],
 180                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty],
 181                                   [IntrWriteArgMem]>;
 182 def int_pcmarker      : Intrinsic<[llvm_void_ty], [llvm_i32_ty]>;
 183
 184 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 185
 186 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 187 // guard to the correct place on the stack frame.
 188 def int_stackprotector : Intrinsic<[llvm_void_ty],
 189                                    [llvm_ptr_ty, llvm_ptrptr_ty],
 190                                    [IntrWriteMem]>;
 191
 192 //===------------------- Standard C Library Intrinsics --------------------===//
 193 //
 194
 195 let Properties = [IntrWriteArgMem] in {
 196   def int_memcpy_i16  : Intrinsic<[llvm_void_ty],
 197                                   [llvm_ptr_ty, llvm_ptr_ty,
 198                                    llvm_i16_ty, llvm_i16_ty]>;
 199   def int_memcpy_i32  : Intrinsic<[llvm_void_ty],
 200                                   [llvm_ptr_ty, llvm_ptr_ty,
 201                                    llvm_i32_ty, llvm_i32_ty]>;
 202   def int_memcpy_i64  : Intrinsic<[llvm_void_ty],
 203                                   [llvm_ptr_ty, llvm_ptr_ty,
 204                                    llvm_i64_ty, llvm_i32_ty]>;
 205   def int_memmove_i16 : Intrinsic<[llvm_void_ty],
 206                                   [llvm_ptr_ty, llvm_ptr_ty,
 207                                    llvm_i16_ty, llvm_i16_ty]>;
 208   def int_memmove_i32 : Intrinsic<[llvm_void_ty],
 209                                   [llvm_ptr_ty, llvm_ptr_ty,
 210                                    llvm_i32_ty, llvm_i32_ty]>;
 211   def int_memmove_i64 : Intrinsic<[llvm_void_ty],
 212                                   [llvm_ptr_ty, llvm_ptr_ty,
 213                                    llvm_i64_ty, llvm_i32_ty]>;
 214   def int_memset_i16  : Intrinsic<[llvm_void_ty],
 215                                   [llvm_ptr_ty, llvm_i8_ty,
 216                                    llvm_i16_ty, llvm_i16_ty]>;
 217   def int_memset_i32  : Intrinsic<[llvm_void_ty],
 218                                   [llvm_ptr_ty, llvm_i8_ty,
 219                                    llvm_i32_ty, llvm_i32_ty]>;
 220   def int_memset_i64  : Intrinsic<[llvm_void_ty],
 221                                   [llvm_ptr_ty, llvm_i8_ty,
 222                                    llvm_i64_ty, llvm_i32_ty]>;
 223 }
 224
 225 // These functions do not actually read memory, but they are sensitive to the
 226 // rounding mode.  This needs to be modelled separately; in the meantime
 227 // declaring them as reading memory is conservatively correct.
 228 let Properties = [IntrReadMem] in {
 229   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 230   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 231   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 232   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 233   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 234                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 235   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 236   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 237   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 238   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 239   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 240 }
 241
 242 // NOTE: these are internal interfaces.
 243 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 244 def int_longjmp    : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 245 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 246 def int_siglongjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 247
 248 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 249 //
 250
 251 // None of these intrinsics accesses memory at all.
 252 let Properties = [IntrNoMem] in {
 253   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 254   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 255   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 256   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 257   def int_part_select : Intrinsic<[llvm_anyint_ty],
 258                                   [LLVMMatchType<0>, llvm_i32_ty, llvm_i32_ty]>;
 259   def int_part_set : Intrinsic<[llvm_anyint_ty],
 260                                [LLVMMatchType<0>, llvm_anyint_ty,
 261                                 llvm_i32_ty, llvm_i32_ty]>;
 262 }
 263
 264 //===------------------------ Debugger Intrinsics -------------------------===//
 265 //
 266
 267 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty],
 268                                      [llvm_i32_ty, llvm_i32_ty,
 269                                       llvm_descriptor_ty]>;
 270 def int_dbg_region_start : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 271 def int_dbg_region_end   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 272 def int_dbg_func_start   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 273 def int_dbg_declare      : Intrinsic<[llvm_void_ty],
 274                                      [llvm_descriptor_ty, llvm_descriptor_ty]>;
 275
 276 //===------------------ Exception Handling Intrinsics----------------------===//
 277 //
 278 def int_eh_exception    : Intrinsic<[llvm_ptr_ty]>;
 279 def int_eh_selector_i32 : Intrinsic<[llvm_i32_ty],
 280                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 281 def int_eh_selector_i64 : Intrinsic<[llvm_i64_ty],
 282                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 283
 284 def int_eh_typeid_for_i32 : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 285 def int_eh_typeid_for_i64 : Intrinsic<[llvm_i64_ty], [llvm_ptr_ty]>;
 286
 287 def int_eh_return_i32 : Intrinsic<[llvm_void_ty], [llvm_i32_ty, llvm_ptr_ty]>;
 288 def int_eh_return_i64 : Intrinsic<[llvm_void_ty], [llvm_i64_ty, llvm_ptr_ty]>;
 289
 290 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 291                         GCCBuiltin<"__builtin_unwind_init">;
 292
 293 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 294
 295 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 296 //
 297 def int_var_annotation : Intrinsic<[llvm_void_ty],
 298                                    [llvm_ptr_ty, llvm_ptr_ty,
 299                                     llvm_ptr_ty, llvm_i32_ty],
 300                                    [], "llvm.var.annotation">;
 301 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 302                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 303                                     llvm_i32_ty],
 304                                    [], "llvm.ptr.annotation">;
 305 def int_annotation : Intrinsic<[llvm_anyint_ty],
 306                                [LLVMMatchType<0>, llvm_ptr_ty,
 307                                 llvm_ptr_ty, llvm_i32_ty],
 308                                [], "llvm.annotation">;
 309
 310 //===------------------------ Trampoline Intrinsics -----------------------===//
 311 //
 312 def int_init_trampoline : Intrinsic<[llvm_ptr_ty],
 313                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 314                                     []>,
 315                           GCCBuiltin<"__builtin_init_trampoline">;
 316
 317 //===------------------------ Overflow Intrinsics -------------------------===//
 318 //
 319
 320 // Expose the carry flag from add operations on two integrals.
 321 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 322                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 323 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 324                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 325
 326 //===------------------------- Atomic Intrinsics --------------------------===//
 327 //
 328 def int_memory_barrier : Intrinsic<[llvm_void_ty],
 329                                    [llvm_i1_ty, llvm_i1_ty,
 330                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 331                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 332
 333 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 334                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 335                                      LLVMMatchType<0>, LLVMMatchType<0>],
 336                                     [IntrWriteArgMem]>,
 337                            GCCBuiltin<"__sync_val_compare_and_swap">;
 338 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 339                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 340                                      LLVMMatchType<0>],
 341                                     [IntrWriteArgMem]>,
 342                            GCCBuiltin<"__sync_fetch_and_add">;
 343 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 344                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 345                                      LLVMMatchType<0>],
 346                                     [IntrWriteArgMem]>,
 347                            GCCBuiltin<"__sync_lock_test_and_set">;
 348 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 349                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 350                                      LLVMMatchType<0>],
 351                                     [IntrWriteArgMem]>,
 352                            GCCBuiltin<"__sync_fetch_and_sub">;
 353 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 354                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 355                                      LLVMMatchType<0>],
 356                                     [IntrWriteArgMem]>,
 357                            GCCBuiltin<"__sync_fetch_and_and">;
 358 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 359                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 360                                       LLVMMatchType<0>],
 361                                      [IntrWriteArgMem]>,
 362                            GCCBuiltin<"__sync_fetch_and_or">;
 363 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 364                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 365                                      LLVMMatchType<0>],
 366                                     [IntrWriteArgMem]>,
 367                            GCCBuiltin<"__sync_fetch_and_xor">;
 368 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 369                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 370                                       LLVMMatchType<0>],
 371                                      [IntrWriteArgMem]>,
 372                            GCCBuiltin<"__sync_fetch_and_nand">;
 373 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 374                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 375                                       LLVMMatchType<0>],
 376                                      [IntrWriteArgMem]>,
 377                            GCCBuiltin<"__sync_fetch_and_min">;
 378 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 379                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 380                                       LLVMMatchType<0>],
 381                                      [IntrWriteArgMem]>,
 382                            GCCBuiltin<"__sync_fetch_and_max">;
 383 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 384                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 385                                       LLVMMatchType<0>],
 386                                      [IntrWriteArgMem]>,
 387                            GCCBuiltin<"__sync_fetch_and_umin">;
 388 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 389                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 390                                       LLVMMatchType<0>],
 391                                      [IntrWriteArgMem]>,
 392                            GCCBuiltin<"__sync_fetch_and_umax">;
 393
 394 //===-------------------------- Other Intrinsics --------------------------===//
 395 //
 396 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 397                      GCCBuiltin<"__builtin_flt_rounds">;
 398 def int_trap : Intrinsic<[llvm_void_ty]>,
 399                GCCBuiltin<"__builtin_trap">;
 400
 401 // These convert intrinsics are to support various conversions between
 402 // various types with rounding and saturation. NOTE: avoid using these
 403 // intrinsics as they might be removed sometime in the future and
 404 // most targets don't support them.
 405 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 406                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 407 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 408                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 409 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 410                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 411 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 412                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 413 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 414                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 415 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 416                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 417 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 418                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 419 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 420                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 421 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 422                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 423
 424 //===----------------------------------------------------------------------===//
 425 // Target-specific intrinsics
 426 //===----------------------------------------------------------------------===//
 427
 428 include "llvm/IntrinsicsPowerPC.td"
 429 include "llvm/IntrinsicsX86.td"
 430 include "llvm/IntrinsicsARM.td"
 431 include "llvm/IntrinsicsCellSPU.td"
 432 include "llvm/IntrinsicsAlpha.td"
 433 include "llvm/IntrinsicsXCore.td"