include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def IntrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  52 def Commutative : IntrinsicProperty;
  53
  54 //===----------------------------------------------------------------------===//
  55 // Types used by intrinsics.
  56 //===----------------------------------------------------------------------===//
  57
  58 class LLVMType<ValueType vt> {
  59   ValueType VT = vt;
  60 }
  61
  62 class LLVMPointerType<LLVMType elty>
  63   : LLVMType<iPTR>{
  64   LLVMType ElTy = elty;
  65 }
  66
  67 class LLVMAnyPointerType<LLVMType elty>
  68   : LLVMType<iPTRAny>{
  69   LLVMType ElTy = elty;
  70 }
  71
  72 class LLVMMatchType<int num>
  73   : LLVMType<OtherVT>{
  74   int Number = num;
  75 }
  76
  77 // Match the type of another intrinsic parameter that is expected to be
  78 // an integral vector type, but change the element size to be twice as wide
  79 // or half as wide as the other type.  This is only useful when the intrinsic
  80 // is overloaded, so the matched type should be declared as iAny.
  81 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  82 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  83
  84 def llvm_void_ty       : LLVMType<isVoid>;
  85 def llvm_anyint_ty     : LLVMType<iAny>;
  86 def llvm_anyfloat_ty   : LLVMType<fAny>;
  87 def llvm_i1_ty         : LLVMType<i1>;
  88 def llvm_i8_ty         : LLVMType<i8>;
  89 def llvm_i16_ty        : LLVMType<i16>;
  90 def llvm_i32_ty        : LLVMType<i32>;
  91 def llvm_i64_ty        : LLVMType<i64>;
  92 def llvm_float_ty      : LLVMType<f32>;
  93 def llvm_double_ty     : LLVMType<f64>;
  94 def llvm_f80_ty        : LLVMType<f80>;
  95 def llvm_f128_ty       : LLVMType<f128>;
  96 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
  97 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
  98 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
  99 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 100 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 101 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 102
 103 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 104 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 105 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 106 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 107 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 108 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 109 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 110 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 111
 112 // MMX Vector Types
 113 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 114 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 115
 116 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 117
 118 //===----------------------------------------------------------------------===//
 119 // Intrinsic Definitions.
 120 //===----------------------------------------------------------------------===//
 121
 122 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 123 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 124 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 125 // example, llvm.bswap.i16 -> int_bswap_i16.
 126 //
 127 //  * RetTypes is a list containing the return types expected for the
 128 //    intrinsic.
 129 //  * ParamTypes is a list containing the parameter types expected for the
 130 //    intrinsic.
 131 //  * Properties can be set to describe the behavior of the intrinsic.
 132 //
 133 class Intrinsic<list<LLVMType> ret_types,
 134                 list<LLVMType> param_types = [],
 135                 list<IntrinsicProperty> properties = [],
 136                 string name = ""> {
 137   string LLVMName = name;
 138   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 139   list<LLVMType> RetTypes = ret_types;
 140   list<LLVMType> ParamTypes = param_types;
 141   list<IntrinsicProperty> Properties = properties;
 142 }
 143
 144 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 145 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 146 /// support.
 147 class GCCBuiltin<string name> {
 148   string GCCBuiltinName = name;
 149 }
 150
 151
 152 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 153 //
 154
 155 def int_vastart : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_start">;
 156 def int_vacopy  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_ptr_ty], [],
 157                             "llvm.va_copy">;
 158 def int_vaend   : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_end">;
 159
 160 //===------------------- Garbage Collection Intrinsics --------------------===//
 161 //
 162 def int_gcroot  : Intrinsic<[llvm_void_ty],
 163                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 164 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 165                             [llvm_ptr_ty, llvm_ptrptr_ty],
 166                             [IntrReadArgMem]>;
 167 def int_gcwrite : Intrinsic<[llvm_void_ty],
 168                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 169                             [IntrWriteArgMem]>;
 170
 171 //===--------------------- Code Generator Intrinsics ----------------------===//
 172 //
 173 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 174 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 175
 176 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 177 // model their dependencies on allocas.
 178 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 179                         GCCBuiltin<"__builtin_stack_save">;
 180 def int_stackrestore  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty]>,
 181                         GCCBuiltin<"__builtin_stack_restore">;
 182
 183 // IntrWriteArgMem is more pessimistic than strictly necessary for prefetch,
 184 // however it does conveniently prevent the prefetch from being reordered
 185 // with respect to nearby accesses to the same memory.
 186 def int_prefetch      : Intrinsic<[llvm_void_ty],
 187                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty],
 188                                   [IntrWriteArgMem]>;
 189 def int_pcmarker      : Intrinsic<[llvm_void_ty], [llvm_i32_ty]>;
 190
 191 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 192
 193 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 194 // guard to the correct place on the stack frame.
 195 def int_stackprotector : Intrinsic<[llvm_void_ty],
 196                                    [llvm_ptr_ty, llvm_ptrptr_ty],
 197                                    [IntrWriteMem]>;
 198
 199 //===------------------- Standard C Library Intrinsics --------------------===//
 200 //
 201
 202 let Properties = [IntrWriteArgMem] in {
 203   def int_memcpy  : Intrinsic<[llvm_void_ty],
 204                                [llvm_ptr_ty, llvm_ptr_ty,
 205                                 llvm_anyint_ty, llvm_i32_ty]>;
 206   def int_memmove : Intrinsic<[llvm_void_ty],
 207                                   [llvm_ptr_ty, llvm_ptr_ty,
 208                                    llvm_anyint_ty, llvm_i32_ty]>;
 209   def int_memset  : Intrinsic<[llvm_void_ty],
 210                                [llvm_ptr_ty, llvm_i8_ty,
 211                                 llvm_anyint_ty, llvm_i32_ty]>;
 212 }
 213
 214 // These functions do not actually read memory, but they are sensitive to the
 215 // rounding mode.  This needs to be modelled separately; in the meantime
 216 // declaring them as reading memory is conservatively correct.
 217 let Properties = [IntrReadMem] in {
 218   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 219   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 220   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 221   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 222   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 223                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 224   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 225   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 226   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 227   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 228   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 229 }
 230
 231 // NOTE: these are internal interfaces.
 232 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 233 def int_longjmp    : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 234 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 235 def int_siglongjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 236
 237 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 238 //
 239
 240 // None of these intrinsics accesses memory at all.
 241 let Properties = [IntrNoMem] in {
 242   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 243   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 244   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 245   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 246   def int_part_select : Intrinsic<[llvm_anyint_ty],
 247                                   [LLVMMatchType<0>, llvm_i32_ty, llvm_i32_ty]>;
 248   def int_part_set : Intrinsic<[llvm_anyint_ty],
 249                                [LLVMMatchType<0>, llvm_anyint_ty,
 250                                 llvm_i32_ty, llvm_i32_ty]>;
 251 }
 252
 253 //===------------------------ Debugger Intrinsics -------------------------===//
 254 //
 255
 256 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty],
 257                                      [llvm_i32_ty, llvm_i32_ty,
 258                                       llvm_descriptor_ty]>;
 259 def int_dbg_region_start : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 260 def int_dbg_region_end   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 261 def int_dbg_func_start   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 262 def int_dbg_declare      : Intrinsic<[llvm_void_ty],
 263                                      [llvm_descriptor_ty, llvm_descriptor_ty]>;
 264
 265 //===------------------ Exception Handling Intrinsics----------------------===//
 266 //
 267 def int_eh_exception    : Intrinsic<[llvm_ptr_ty]>;
 268 def int_eh_selector_i32 : Intrinsic<[llvm_i32_ty],
 269                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 270 def int_eh_selector_i64 : Intrinsic<[llvm_i64_ty],
 271                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 272
 273 def int_eh_typeid_for_i32 : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 274 def int_eh_typeid_for_i64 : Intrinsic<[llvm_i64_ty], [llvm_ptr_ty]>;
 275
 276 def int_eh_return_i32 : Intrinsic<[llvm_void_ty], [llvm_i32_ty, llvm_ptr_ty]>;
 277 def int_eh_return_i64 : Intrinsic<[llvm_void_ty], [llvm_i64_ty, llvm_ptr_ty]>;
 278
 279 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 280                         GCCBuiltin<"__builtin_unwind_init">;
 281
 282 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 283
 284 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 285 //
 286 def int_var_annotation : Intrinsic<[llvm_void_ty],
 287                                    [llvm_ptr_ty, llvm_ptr_ty,
 288                                     llvm_ptr_ty, llvm_i32_ty],
 289                                    [], "llvm.var.annotation">;
 290 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 291                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 292                                     llvm_i32_ty],
 293                                    [], "llvm.ptr.annotation">;
 294 def int_annotation : Intrinsic<[llvm_anyint_ty],
 295                                [LLVMMatchType<0>, llvm_ptr_ty,
 296                                 llvm_ptr_ty, llvm_i32_ty],
 297                                [], "llvm.annotation">;
 298
 299 //===------------------------ Trampoline Intrinsics -----------------------===//
 300 //
 301 def int_init_trampoline : Intrinsic<[llvm_ptr_ty],
 302                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 303                                     []>,
 304                           GCCBuiltin<"__builtin_init_trampoline">;
 305
 306 //===------------------------ Overflow Intrinsics -------------------------===//
 307 //
 308
 309 // Expose the carry flag from add operations on two integrals.
 310 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 311                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 312 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 313                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 314
 315 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 316                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 317 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 318                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 319
 320 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 321                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 322 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 323                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 324
 325 //===------------------------- Atomic Intrinsics --------------------------===//
 326 //
 327 def int_memory_barrier : Intrinsic<[llvm_void_ty],
 328                                    [llvm_i1_ty, llvm_i1_ty,
 329                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 330                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 331
 332 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 333                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 334                                      LLVMMatchType<0>, LLVMMatchType<0>],
 335                                     [IntrWriteArgMem]>,
 336                            GCCBuiltin<"__sync_val_compare_and_swap">;
 337 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 338                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 339                                      LLVMMatchType<0>],
 340                                     [IntrWriteArgMem]>,
 341                            GCCBuiltin<"__sync_fetch_and_add">;
 342 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 343                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 344                                      LLVMMatchType<0>],
 345                                     [IntrWriteArgMem]>,
 346                            GCCBuiltin<"__sync_lock_test_and_set">;
 347 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 348                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 349                                      LLVMMatchType<0>],
 350                                     [IntrWriteArgMem]>,
 351                            GCCBuiltin<"__sync_fetch_and_sub">;
 352 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 353                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 354                                      LLVMMatchType<0>],
 355                                     [IntrWriteArgMem]>,
 356                            GCCBuiltin<"__sync_fetch_and_and">;
 357 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 358                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 359                                       LLVMMatchType<0>],
 360                                      [IntrWriteArgMem]>,
 361                            GCCBuiltin<"__sync_fetch_and_or">;
 362 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 363                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 364                                      LLVMMatchType<0>],
 365                                     [IntrWriteArgMem]>,
 366                            GCCBuiltin<"__sync_fetch_and_xor">;
 367 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 368                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 369                                       LLVMMatchType<0>],
 370                                      [IntrWriteArgMem]>,
 371                            GCCBuiltin<"__sync_fetch_and_nand">;
 372 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 373                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 374                                       LLVMMatchType<0>],
 375                                      [IntrWriteArgMem]>,
 376                            GCCBuiltin<"__sync_fetch_and_min">;
 377 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 378                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 379                                       LLVMMatchType<0>],
 380                                      [IntrWriteArgMem]>,
 381                            GCCBuiltin<"__sync_fetch_and_max">;
 382 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 383                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 384                                       LLVMMatchType<0>],
 385                                      [IntrWriteArgMem]>,
 386                            GCCBuiltin<"__sync_fetch_and_umin">;
 387 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 388                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 389                                       LLVMMatchType<0>],
 390                                      [IntrWriteArgMem]>,
 391                            GCCBuiltin<"__sync_fetch_and_umax">;
 392
 393 //===-------------------------- Other Intrinsics --------------------------===//
 394 //
 395 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 396                      GCCBuiltin<"__builtin_flt_rounds">;
 397 def int_trap : Intrinsic<[llvm_void_ty]>,
 398                GCCBuiltin<"__builtin_trap">;
 399
 400 // These convert intrinsics are to support various conversions between
 401 // various types with rounding and saturation. NOTE: avoid using these
 402 // intrinsics as they might be removed sometime in the future and
 403 // most targets don't support them.
 404 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 405                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 406 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 407                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 408 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 409                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 410 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 411                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 412 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 413                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 414 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 415                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 416 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 417                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 418 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 419                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 420 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 421                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 422
 423 //===----------------------------------------------------------------------===//
 424 // Target-specific intrinsics
 425 //===----------------------------------------------------------------------===//
 426
 427 include "llvm/IntrinsicsPowerPC.td"
 428 include "llvm/IntrinsicsX86.td"
 429 include "llvm/IntrinsicsARM.td"
 430 include "llvm/IntrinsicsCellSPU.td"
 431 include "llvm/IntrinsicsAlpha.td"
 432 include "llvm/IntrinsicsXCore.td"