include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under the
   6 // University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def IntrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 //===----------------------------------------------------------------------===//
  52 // Types used by intrinsics.
  53 //===----------------------------------------------------------------------===//
  54
  55 class LLVMType<ValueType vt, string typeval> {
  56   ValueType VT = vt;
  57   string TypeVal = typeval;
  58 }
  59
  60 class LLVMPackedType<ValueType VT, int numelts, LLVMType elty>
  61   : LLVMType<VT, "Type::PackedTyID">{
  62   int NumElts = numelts;
  63   LLVMType ElTy = elty;
  64 }
  65
  66 def llvm_void_ty       : LLVMType<isVoid, "Type::VoidTyID">;
  67 def llvm_bool_ty       : LLVMType<i1 , "Type::BoolTyID">;
  68 def llvm_i8_ty         : LLVMType<i8 , "Type::Int8TyID">;
  69 def llvm_i16_ty        : LLVMType<i16, "Type::Int16TyID">;
  70 def llvm_i32_ty        : LLVMType<i32, "Type::Int32TyID">;
  71 def llvm_i64_ty        : LLVMType<i64, "Type::Int64TyID">;
  72 def llvm_float_ty      : LLVMType<f32, "Type::FloatTyID">;
  73 def llvm_double_ty     : LLVMType<f64, "Type::DoubleTyID">;
  74 def llvm_ptr_ty        : LLVMType<iPTR, "Type::PointerTyID">;     // sbyte*
  75 def llvm_ptrptr_ty     : LLVMType<iPTR, "Type::PointerTyID">;     // sbyte**
  76 def llvm_descriptor_ty : LLVMType<iPTR, "Type::PointerTyID">;     // global*
  77
  78 def llvm_v16i8_ty      : LLVMPackedType<v16i8,16, llvm_i8_ty>;  // 16 x sbyte
  79 def llvm_v8i16_ty      : LLVMPackedType<v8i16, 8, llvm_i16_ty>;  // 8 x short
  80
  81 def llvm_v2i64_ty      : LLVMPackedType<v2i64, 2, llvm_i64_ty>;   // 2 x long
  82 def llvm_v2i32_ty      : LLVMPackedType<v2i32, 2, llvm_i32_ty>;    // 2 x int
  83 def llvm_v4i32_ty      : LLVMPackedType<v4i32, 4, llvm_i32_ty>;    // 4 x int
  84 def llvm_v4f32_ty      : LLVMPackedType<v4f32, 4, llvm_float_ty>;  // 4 x float
  85 def llvm_v2f64_ty      : LLVMPackedType<v2f64, 2, llvm_double_ty>; // 2 x double
  86
  87 //===----------------------------------------------------------------------===//
  88 // Intrinsic Definitions.
  89 //===----------------------------------------------------------------------===//
  90
  91 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
  92 // intrinsic definition should start with "int_", then match the LLVM intrinsic
  93 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
  94 // example, llvm.bswap.i16 -> int_bswap_i16.
  95 //
  96 //  * Types is a list containing the return type and the argument types
  97 //    expected for the intrinsic.
  98 //  * Properties can be set to describe the behavior of the intrinsic.
  99 //
 100 class Intrinsic<list<LLVMType> types,
 101                 list<IntrinsicProperty> properties = [],
 102                 string name = ""> {
 103   string LLVMName = name;
 104   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 105   list<LLVMType> Types = types;
 106   list<IntrinsicProperty> Properties = properties;
 107 }
 108
 109 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 110 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 111 /// support.
 112 class GCCBuiltin<string name> {
 113   string GCCBuiltinName = name;
 114 }
 115
 116
 117 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 118 //
 119
 120 def int_vastart : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty], [], "llvm.va_start">;
 121 def int_vacopy  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptrptr_ty], [],
 122                             "llvm.va_copy">;
 123 def int_vaend   : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty], [], "llvm.va_end">;
 124
 125 //===------------------- Garbage Collection Intrinsics --------------------===//
 126 //
 127 def int_gcroot  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptr_ty]>;
 128 def int_gcread  : Intrinsic<[llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 129                             [IntrReadArgMem]>;
 130 def int_gcwrite : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 131                              llvm_ptrptr_ty], [IntrWriteArgMem]>;
 132
 133 //===--------------------- Code Generator Intrinsics ----------------------===//
 134 //
 135 def int_returnaddress : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 136 def int_frameaddress  : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 137 def int_stacksave     : Intrinsic<[llvm_ptr_ty], [IntrReadMem]>;
 138 def int_stackrestore  : Intrinsic<[llvm_void_ty, llvm_ptr_ty]>;
 139 def int_prefetch      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 140                                    llvm_i32_ty, llvm_i32_ty]>;
 141 def int_pcmarker      : Intrinsic<[llvm_void_ty, llvm_i32_ty]>;
 142
 143 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 144
 145 //===------------------- Standard C Library Intrinsics --------------------===//
 146 //
 147
 148 let Properties = [IntrWriteArgMem] in {
 149   def int_memcpy_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 150                                    llvm_i32_ty, llvm_i32_ty]>;
 151   def int_memcpy_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 152                                    llvm_i64_ty, llvm_i32_ty]>;
 153   def int_memmove_i32 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 154                                    llvm_i32_ty, llvm_i32_ty]>;
 155   def int_memmove_i64 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 156                                    llvm_i64_ty, llvm_i32_ty]>;
 157   def int_memset_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 158                                    llvm_i32_ty, llvm_i32_ty]>;
 159   def int_memset_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 160                                    llvm_i64_ty, llvm_i32_ty]>;
 161 }
 162
 163 let Properties = [IntrNoMem] in {
 164   def int_isunordered_f32 : Intrinsic<[llvm_bool_ty,
 165                                        llvm_float_ty,  llvm_float_ty]>;
 166   def int_isunordered_f64 : Intrinsic<[llvm_bool_ty,
 167                                        llvm_double_ty, llvm_double_ty]>;
 168   def int_sqrt_f32 : Intrinsic<[llvm_float_ty , llvm_float_ty]>;
 169   def int_sqrt_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty]>;
 170
 171   def int_powi_f32 : Intrinsic<[llvm_float_ty , llvm_float_ty, llvm_i32_ty]>;
 172   def int_powi_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty, llvm_i32_ty]>;
 173 }
 174
 175 // NOTE: these are internal interfaces.
 176 def int_setjmp     : Intrinsic<[llvm_i32_ty , llvm_ptr_ty]>;
 177 def int_longjmp    : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 178 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty , llvm_ptr_ty, llvm_i32_ty]>;
 179 def int_siglongjmp : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 180
 181 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 182 //
 183
 184 // None of these intrinsics accesses memory at all.
 185 let Properties = [IntrNoMem] in {
 186   def int_bswap_i16 : Intrinsic<[llvm_i16_ty, llvm_i16_ty]>;
 187   def int_bswap_i32 : Intrinsic<[llvm_i32_ty,   llvm_i32_ty]>;
 188   def int_bswap_i64 : Intrinsic<[llvm_i64_ty,  llvm_i64_ty]>;
 189
 190   def int_ctpop_i8  : Intrinsic<[llvm_i8_ty,  llvm_i8_ty]>;
 191   def int_ctpop_i16 : Intrinsic<[llvm_i16_ty, llvm_i16_ty]>;
 192   def int_ctpop_i32 : Intrinsic<[llvm_i32_ty,   llvm_i32_ty]>;
 193   def int_ctpop_i64 : Intrinsic<[llvm_i64_ty,  llvm_i64_ty]>;
 194
 195   def int_ctlz_i8  : Intrinsic<[llvm_i8_ty,  llvm_i8_ty]>;
 196   def int_ctlz_i16 : Intrinsic<[llvm_i16_ty, llvm_i16_ty]>;
 197   def int_ctlz_i32 : Intrinsic<[llvm_i32_ty,   llvm_i32_ty]>;
 198   def int_ctlz_i64 : Intrinsic<[llvm_i64_ty,  llvm_i64_ty]>;
 199
 200   def int_cttz_i8  : Intrinsic<[llvm_i8_ty,  llvm_i8_ty]>;
 201   def int_cttz_i16 : Intrinsic<[llvm_i16_ty, llvm_i16_ty]>;
 202   def int_cttz_i32 : Intrinsic<[llvm_i32_ty,   llvm_i32_ty]>;
 203   def int_cttz_i64 : Intrinsic<[llvm_i64_ty,  llvm_i64_ty]>;
 204 }
 205
 206 //===------------------------ Debugger Intrinsics -------------------------===//
 207 //
 208
 209 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty,
 210                                       llvm_i32_ty, llvm_i32_ty,
 211                                       llvm_descriptor_ty]>;
 212 def int_dbg_region_start : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 213 def int_dbg_region_end   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 214 def int_dbg_func_start   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 215 def int_dbg_declare      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 216                                                     llvm_descriptor_ty]>;
 217
 218 //===----------------------------------------------------------------------===//
 219 // Target-specific intrinsics
 220 //===----------------------------------------------------------------------===//
 221
 222 include "llvm/IntrinsicsPowerPC.td"
 223 include "llvm/IntrinsicsX86.td"