include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under the
   6 // University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // InstrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def InstrNoMem : IntrinsicProperty;
  30
  31 // InstrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def InstrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // InstrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def InstrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 //===----------------------------------------------------------------------===//
  52 // Types used by intrinsics.
  53 //===----------------------------------------------------------------------===//
  54
  55 class LLVMType<ValueType vt, string typeval> {
  56   ValueType VT = vt;
  57   string TypeVal = typeval;
  58 }
  59
  60 class LLVMPackedType<ValueType VT, int numelts, LLVMType elty>
  61   : LLVMType<VT, "Type::PackedTyID">{
  62   int NumElts = numelts;
  63   LLVMType ElTy = elty;
  64 }
  65
  66 def llvm_void_ty       : LLVMType<isVoid, "Type::VoidTyID">;
  67 def llvm_bool_ty       : LLVMType<i1 , "Type::BoolTyID">;
  68 def llvm_sbyte_ty      : LLVMType<i8 , "Type::SByteTyID">;
  69 def llvm_short_ty      : LLVMType<i16, "Type::ShortTyID">;
  70 def llvm_int_ty        : LLVMType<i32, "Type::IntTyID">;
  71 def llvm_long_ty       : LLVMType<i64, "Type::LongTyID">;
  72 def llvm_ubyte_ty      : LLVMType<i8,  "Type::UByteTyID">;
  73 def llvm_ushort_ty     : LLVMType<i16, "Type::UShortTyID">;
  74 def llvm_uint_ty       : LLVMType<i32, "Type::UIntTyID">;
  75 def llvm_ulong_ty      : LLVMType<i64, "Type::ULongTyID">;
  76 def llvm_float_ty      : LLVMType<f32, "Type::FloatTyID">;
  77 def llvm_double_ty     : LLVMType<f64, "Type::DoubleTyID">;
  78 def llvm_ptr_ty        : LLVMType<OtherVT, "Type::PointerTyID">;     // sbyte*
  79 def llvm_ptrptr_ty     : LLVMType<OtherVT, "Type::PointerTyID">;     // sbyte**
  80 def llvm_descriptor_ty : LLVMType<OtherVT, "Type::PointerTyID">;     // global*
  81
  82 def llvm_v4i32_ty      : LLVMPackedType<v4i32, 4, llvm_int_ty>;    // 4 x int
  83 def llvm_v4f32_ty      : LLVMPackedType<v4f32, 4, llvm_float_ty>;  // 4 x float
  84 def llvm_v2f64_ty      : LLVMPackedType<v2f64, 2, llvm_double_ty>; // 2 x double
  85
  86 //===----------------------------------------------------------------------===//
  87 // Intrinsic Definitions.
  88 //===----------------------------------------------------------------------===//
  89
  90 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
  91 // intrinsic definition should start with "int_", then match the LLVM intrinsic
  92 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
  93 // example, llvm.bswap.i16 -> int_bswap_i16.
  94 //
  95 //  * Types is a list containing the return type and the argument types
  96 //    expected for the intrinsic.
  97 //  * Properties can be set to describe the behavior of the intrinsic.
  98 //
  99 class Intrinsic<list<LLVMType> types,
 100                 list<IntrinsicProperty> properties = [],
 101                 string name = ""> {
 102   string LLVMName = name;
 103   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 104   list<LLVMType> Types = types;
 105   list<IntrinsicProperty> Properties = properties;
 106 }
 107
 108 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 109 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 110 /// support.
 111 class GCCBuiltin<string name> {
 112   string GCCBuiltinName = name;
 113 }
 114
 115
 116 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 117 //
 118
 119 def int_vastart : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty], [], "llvm.va_start">;
 120 def int_vacopy  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptrptr_ty], [],
 121                             "llvm.va_copy">;
 122 def int_vaend   : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty], [], "llvm.va_end">;
 123
 124 //===------------------- Garbage Collection Intrinsics --------------------===//
 125 //
 126 def int_gcroot  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptr_ty]>;
 127 def int_gcread  : Intrinsic<[llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 128                             [InstrReadArgMem]>;
 129 def int_gcwrite : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 130                              llvm_ptrptr_ty], [InstrWriteArgMem]>;
 131
 132 //===--------------------- Code Generator Intrinsics ----------------------===//
 133 //
 134 def int_returnaddress : Intrinsic<[llvm_ptr_ty, llvm_uint_ty], [InstrNoMem]>;
 135 def int_frameaddress  : Intrinsic<[llvm_ptr_ty, llvm_uint_ty], [InstrNoMem]>;
 136 def int_stacksave     : Intrinsic<[llvm_ptr_ty], [IntrReadMem]>;
 137 def int_stackrestore  : Intrinsic<[llvm_void_ty, llvm_ptr_ty]>;
 138 def int_prefetch      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 139                                    llvm_uint_ty, llvm_uint_ty]>;
 140 def int_pcmarker      : Intrinsic<[llvm_void_ty, llvm_uint_ty]>;
 141
 142 def int_readcyclecounter : Intrinsic<[llvm_ulong_ty]>;
 143
 144 //===------------------- Standard C Library Intrinsics --------------------===//
 145 //
 146
 147 let Properties = [InstrWriteArgMem] in {
 148   def int_memcpy_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 149                                    llvm_uint_ty, llvm_uint_ty]>;
 150   def int_memcpy_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 151                                    llvm_ulong_ty, llvm_uint_ty]>;
 152   def int_memmove_i32 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 153                                    llvm_uint_ty, llvm_uint_ty]>;
 154   def int_memmove_i64 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 155                                    llvm_ulong_ty, llvm_uint_ty]>;
 156   def int_memset_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ubyte_ty,
 157                                    llvm_uint_ty, llvm_uint_ty]>;
 158   def int_memset_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ubyte_ty,
 159                                    llvm_ulong_ty, llvm_uint_ty]>;
 160 }
 161
 162 let Properties = [InstrNoMem] in {
 163   def int_isunordered_f32 : Intrinsic<[llvm_bool_ty,
 164                                        llvm_float_ty,  llvm_float_ty]>;
 165   def int_isunordered_f64 : Intrinsic<[llvm_bool_ty,
 166                                        llvm_double_ty, llvm_double_ty]>;
 167   def int_sqrt_f32 : Intrinsic<[llvm_float_ty , llvm_float_ty]>;
 168   def int_sqrt_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty]>;
 169 }
 170
 171 // NOTE: these are internal interfaces.
 172 def int_setjmp     : Intrinsic<[llvm_int_ty , llvm_ptr_ty]>;
 173 def int_longjmp    : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_int_ty]>;
 174 def int_sigsetjmp  : Intrinsic<[llvm_int_ty , llvm_ptr_ty]>;
 175 def int_siglongjmp : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_int_ty]>;
 176
 177 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 178 //
 179
 180 // None of these intrinsics accesses memory at all.
 181 let Properties = [InstrNoMem] in {
 182   def int_bswap_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 183   def int_bswap_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 184   def int_bswap_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 185
 186   def int_ctpop_i8  : Intrinsic<[llvm_ubyte_ty,  llvm_ubyte_ty]>;
 187   def int_ctpop_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 188   def int_ctpop_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 189   def int_ctpop_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 190
 191   def int_ctlz_i8  : Intrinsic<[llvm_ubyte_ty,  llvm_ubyte_ty]>;
 192   def int_ctlz_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 193   def int_ctlz_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 194   def int_ctlz_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 195
 196   def int_cttz_i8  : Intrinsic<[llvm_ubyte_ty,  llvm_ubyte_ty]>;
 197   def int_cttz_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 198   def int_cttz_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 199   def int_cttz_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 200 }
 201
 202 //===------------------------ Debugger Intrinsics -------------------------===//
 203 //
 204
 205 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty,
 206                                       llvm_uint_ty, llvm_uint_ty,
 207                                       llvm_descriptor_ty]>;
 208 def int_dbg_region_start : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 209 def int_dbg_region_end   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 210 def int_dbg_func_start   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 211 def int_dbg_declare      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 212                                                     llvm_descriptor_ty]>;
 213
 214 //===----------------------------------------------------------------------===//
 215 // Target-specific intrinsics
 216 //===----------------------------------------------------------------------===//
 217
 218 //===----------------------------------------------------------------------===//
 219 // PowerPC Intrinsics
 220 //
 221 let TargetPrefix = "ppc" in {  // All intrinsics start with "llvm.ppc.".
 222   def int_ppc_altivec_lvx : GCCBuiltin<"__builtin_altivec_lvx">,
 223               Intrinsic<[llvm_v4i32_ty, llvm_int_ty, llvm_ptr_ty],
 224                         [IntrReadMem]>;
 225   def int_ppc_altivec_stvx : GCCBuiltin<"__builtin_altivec_stvx">,
 226               Intrinsic<[llvm_void_ty, llvm_v4i32_ty, llvm_int_ty, llvm_ptr_ty],
 227                         [IntrWriteMem]>;
 228
 229   def int_ppc_altivec_vmaddfp : GCCBuiltin<"__builtin_altivec_vmaddfp">,
 230               Intrinsic<[llvm_v4f32_ty, llvm_v4f32_ty,
 231                          llvm_v4f32_ty, llvm_v4f32_ty], [InstrNoMem]>;
 232   def int_ppc_altivec_vadduwm : GCCBuiltin<"__builtin_altivec_vadduwm">,
 233               Intrinsic<[llvm_v4i32_ty, llvm_v4i32_ty, llvm_v4i32_ty],
 234                         [InstrNoMem]>;
 235
 236 }
 237
 238
 239 //===----------------------------------------------------------------------===//
 240 // X86 Intrinsics
 241 //
 242
 243 // SSE1
 244
 245 let TargetPrefix = "x86" in {  // All intrinsics start with "llvm.x86.".
 246   def int_x86_sse_movmskps : GCCBuiltin<"__builtin_ia32_movmskps">,
 247               Intrinsic<[llvm_int_ty, llvm_v4f32_ty], [InstrNoMem]>;
 248 }
 249
 250 // SSE2
 251 let TargetPrefix = "x86" in {  // All intrinsics start with "llvm.x86.".
 252   def int_x86_sse2_movmskpd : GCCBuiltin<"__builtin_ia32_movmskpd">,
 253               Intrinsic<[llvm_int_ty, llvm_v2f64_ty], [InstrNoMem]>;
 254 }