include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  The reads
  42 // and writes may be volatile, but except for this it has no other side effects.
  43 def IntrWriteArgMem : IntrinsicProperty;
  44
  45 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  46 // other side effects.  It cannot be modified by the optimizer.  This is the
  47 // default if the intrinsic has no other Intr*Mem property.
  48 def IntrWriteMem : IntrinsicProperty;
  49
  50 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  51 def Commutative : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 //===----------------------------------------------------------------------===//
  59 // Types used by intrinsics.
  60 //===----------------------------------------------------------------------===//
  61
  62 class LLVMType<ValueType vt> {
  63   ValueType VT = vt;
  64 }
  65
  66 class LLVMPointerType<LLVMType elty>
  67   : LLVMType<iPTR>{
  68   LLVMType ElTy = elty;
  69 }
  70
  71 class LLVMAnyPointerType<LLVMType elty>
  72   : LLVMType<iPTRAny>{
  73   LLVMType ElTy = elty;
  74 }
  75
  76 class LLVMMatchType<int num>
  77   : LLVMType<OtherVT>{
  78   int Number = num;
  79 }
  80
  81 // Match the type of another intrinsic parameter that is expected to be
  82 // an integral vector type, but change the element size to be twice as wide
  83 // or half as wide as the other type.  This is only useful when the intrinsic
  84 // is overloaded, so the matched type should be declared as iAny.
  85 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  86 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  87
  88 def llvm_void_ty       : LLVMType<isVoid>;
  89 def llvm_anyint_ty     : LLVMType<iAny>;
  90 def llvm_anyfloat_ty   : LLVMType<fAny>;
  91 def llvm_i1_ty         : LLVMType<i1>;
  92 def llvm_i8_ty         : LLVMType<i8>;
  93 def llvm_i16_ty        : LLVMType<i16>;
  94 def llvm_i32_ty        : LLVMType<i32>;
  95 def llvm_i64_ty        : LLVMType<i64>;
  96 def llvm_float_ty      : LLVMType<f32>;
  97 def llvm_double_ty     : LLVMType<f64>;
  98 def llvm_f80_ty        : LLVMType<f80>;
  99 def llvm_f128_ty       : LLVMType<f128>;
 100 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 101 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 102 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 103 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 104 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 105 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 106
 107 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 108 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 109 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 110 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 111 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 112 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 113 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 114 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 115
 116 // MMX Vector Types
 117 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 118 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 119
 120 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 121
 122 //===----------------------------------------------------------------------===//
 123 // Intrinsic Definitions.
 124 //===----------------------------------------------------------------------===//
 125
 126 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 127 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 128 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 129 // example, llvm.bswap.i16 -> int_bswap_i16.
 130 //
 131 //  * RetTypes is a list containing the return types expected for the
 132 //    intrinsic.
 133 //  * ParamTypes is a list containing the parameter types expected for the
 134 //    intrinsic.
 135 //  * Properties can be set to describe the behavior of the intrinsic.
 136 //
 137 class Intrinsic<list<LLVMType> ret_types,
 138                 list<LLVMType> param_types = [],
 139                 list<IntrinsicProperty> properties = [],
 140                 string name = ""> {
 141   string LLVMName = name;
 142   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 143   list<LLVMType> RetTypes = ret_types;
 144   list<LLVMType> ParamTypes = param_types;
 145   list<IntrinsicProperty> Properties = properties;
 146
 147   bit isTarget = 0;
 148 }
 149
 150 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 151 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 152 /// support.
 153 class GCCBuiltin<string name> {
 154   string GCCBuiltinName = name;
 155 }
 156
 157
 158 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 159 //
 160
 161 def int_vastart : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_start">;
 162 def int_vacopy  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_ptr_ty], [],
 163                             "llvm.va_copy">;
 164 def int_vaend   : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_end">;
 165
 166 //===------------------- Garbage Collection Intrinsics --------------------===//
 167 //
 168 def int_gcroot  : Intrinsic<[llvm_void_ty],
 169                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 170 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 171                             [llvm_ptr_ty, llvm_ptrptr_ty],
 172                             [IntrReadArgMem]>;
 173 def int_gcwrite : Intrinsic<[llvm_void_ty],
 174                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 175                             [IntrWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 176
 177 //===--------------------- Code Generator Intrinsics ----------------------===//
 178 //
 179 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 180 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 181
 182 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 183 // model their dependencies on allocas.
 184 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 185                         GCCBuiltin<"__builtin_stack_save">;
 186 def int_stackrestore  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty]>,
 187                         GCCBuiltin<"__builtin_stack_restore">;
 188
 189 // IntrWriteArgMem is more pessimistic than strictly necessary for prefetch,
 190 // however it does conveniently prevent the prefetch from being reordered
 191 // with respect to nearby accesses to the same memory.
 192 def int_prefetch      : Intrinsic<[llvm_void_ty],
 193                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty],
 194                                   [IntrWriteArgMem, NoCapture<0>]>;
 195 def int_pcmarker      : Intrinsic<[llvm_void_ty], [llvm_i32_ty]>;
 196
 197 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 198
 199 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 200 // guard to the correct place on the stack frame.
 201 def int_stackprotector : Intrinsic<[llvm_void_ty],
 202                                    [llvm_ptr_ty, llvm_ptrptr_ty],
 203                                    [IntrWriteMem]>;
 204
 205 //===------------------- Standard C Library Intrinsics --------------------===//
 206 //
 207
 208 def int_memcpy  : Intrinsic<[llvm_void_ty],
 209                              [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 210                               llvm_i32_ty],
 211                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 212 def int_memmove : Intrinsic<[llvm_void_ty],
 213                             [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 214                              llvm_i32_ty],
 215                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 216 def int_memset  : Intrinsic<[llvm_void_ty],
 217                             [llvm_ptr_ty, llvm_i8_ty, llvm_anyint_ty,
 218                              llvm_i32_ty],
 219                             [IntrWriteArgMem, NoCapture<0>]>;
 220
 221 // These functions do not actually read memory, but they are sensitive to the
 222 // rounding mode.  This needs to be modelled separately; in the meantime
 223 // declaring them as reading memory is conservatively correct.
 224 let Properties = [IntrReadMem] in {
 225   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 226   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 227   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 228   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 229   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 230                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 231   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 232   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 233   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 234   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 235   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 236 }
 237
 238 // NOTE: these are internal interfaces.
 239 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 240 def int_longjmp    : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 241 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 242 def int_siglongjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 243
 244 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 245 //
 246
 247 // None of these intrinsics accesses memory at all.
 248 let Properties = [IntrNoMem] in {
 249   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 250   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 251   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 252   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 253   def int_part_select : Intrinsic<[llvm_anyint_ty],
 254                                   [LLVMMatchType<0>, llvm_i32_ty, llvm_i32_ty]>;
 255   def int_part_set : Intrinsic<[llvm_anyint_ty],
 256                                [LLVMMatchType<0>, llvm_anyint_ty,
 257                                 llvm_i32_ty, llvm_i32_ty]>;
 258 }
 259
 260 //===------------------------ Debugger Intrinsics -------------------------===//
 261 //
 262
 263 // None of these intrinsics accesses memory at all.
 264 let Properties = [IntrNoMem] in {
 265   def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty],
 266                                        [llvm_i32_ty, llvm_i32_ty,
 267                                         llvm_descriptor_ty]>;
 268   def int_dbg_region_start : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 269   def int_dbg_region_end   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 270   def int_dbg_func_start   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 271   def int_dbg_declare      : Intrinsic<[llvm_void_ty],
 272                                        [llvm_descriptor_ty, llvm_descriptor_ty]>;
 273 }
 274
 275 //===------------------ Exception Handling Intrinsics----------------------===//
 276 //
 277 def int_eh_exception    : Intrinsic<[llvm_ptr_ty]>;
 278 def int_eh_selector_i32 : Intrinsic<[llvm_i32_ty],
 279                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 280 def int_eh_selector_i64 : Intrinsic<[llvm_i64_ty],
 281                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 282
 283 def int_eh_typeid_for_i32 : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 284 def int_eh_typeid_for_i64 : Intrinsic<[llvm_i64_ty], [llvm_ptr_ty]>;
 285
 286 def int_eh_return_i32 : Intrinsic<[llvm_void_ty], [llvm_i32_ty, llvm_ptr_ty]>;
 287 def int_eh_return_i64 : Intrinsic<[llvm_void_ty], [llvm_i64_ty, llvm_ptr_ty]>;
 288
 289 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 290                         GCCBuiltin<"__builtin_unwind_init">;
 291
 292 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 293
 294 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 295 //
 296 def int_var_annotation : Intrinsic<[llvm_void_ty],
 297                                    [llvm_ptr_ty, llvm_ptr_ty,
 298                                     llvm_ptr_ty, llvm_i32_ty],
 299                                    [], "llvm.var.annotation">;
 300 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 301                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 302                                     llvm_i32_ty],
 303                                    [], "llvm.ptr.annotation">;
 304 def int_annotation : Intrinsic<[llvm_anyint_ty],
 305                                [LLVMMatchType<0>, llvm_ptr_ty,
 306                                 llvm_ptr_ty, llvm_i32_ty],
 307                                [], "llvm.annotation">;
 308
 309 //===------------------------ Trampoline Intrinsics -----------------------===//
 310 //
 311 def int_init_trampoline : Intrinsic<[llvm_ptr_ty],
 312                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 313                                     [IntrWriteArgMem]>,
 314                           GCCBuiltin<"__builtin_init_trampoline">;
 315
 316 //===------------------------ Overflow Intrinsics -------------------------===//
 317 //
 318
 319 // Expose the carry flag from add operations on two integrals.
 320 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 321                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 322 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 323                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 324
 325 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 326                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 327 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 328                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 329
 330 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 331                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 332 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 333                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 334
 335 //===------------------------- Atomic Intrinsics --------------------------===//
 336 //
 337 def int_memory_barrier : Intrinsic<[llvm_void_ty],
 338                                    [llvm_i1_ty, llvm_i1_ty,
 339                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 340                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 341
 342 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 343                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 344                                      LLVMMatchType<0>, LLVMMatchType<0>],
 345                                     [IntrWriteArgMem, NoCapture<0>]>,
 346                            GCCBuiltin<"__sync_val_compare_and_swap">;
 347 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 348                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 349                                      LLVMMatchType<0>],
 350                                     [IntrWriteArgMem, NoCapture<0>]>,
 351                            GCCBuiltin<"__sync_fetch_and_add">;
 352 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 353                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 354                                      LLVMMatchType<0>],
 355                                     [IntrWriteArgMem, NoCapture<0>]>,
 356                            GCCBuiltin<"__sync_lock_test_and_set">;
 357 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 358                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 359                                      LLVMMatchType<0>],
 360                                     [IntrWriteArgMem, NoCapture<0>]>,
 361                            GCCBuiltin<"__sync_fetch_and_sub">;
 362 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 363                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 364                                      LLVMMatchType<0>],
 365                                     [IntrWriteArgMem, NoCapture<0>]>,
 366                            GCCBuiltin<"__sync_fetch_and_and">;
 367 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 368                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 369                                       LLVMMatchType<0>],
 370                                      [IntrWriteArgMem, NoCapture<0>]>,
 371                            GCCBuiltin<"__sync_fetch_and_or">;
 372 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 373                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 374                                      LLVMMatchType<0>],
 375                                     [IntrWriteArgMem, NoCapture<0>]>,
 376                            GCCBuiltin<"__sync_fetch_and_xor">;
 377 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 378                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 379                                       LLVMMatchType<0>],
 380                                      [IntrWriteArgMem, NoCapture<0>]>,
 381                            GCCBuiltin<"__sync_fetch_and_nand">;
 382 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 383                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 384                                       LLVMMatchType<0>],
 385                                      [IntrWriteArgMem, NoCapture<0>]>,
 386                            GCCBuiltin<"__sync_fetch_and_min">;
 387 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 388                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 389                                       LLVMMatchType<0>],
 390                                      [IntrWriteArgMem, NoCapture<0>]>,
 391                            GCCBuiltin<"__sync_fetch_and_max">;
 392 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 393                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 394                                       LLVMMatchType<0>],
 395                                      [IntrWriteArgMem, NoCapture<0>]>,
 396                            GCCBuiltin<"__sync_fetch_and_umin">;
 397 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 398                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 399                                       LLVMMatchType<0>],
 400                                      [IntrWriteArgMem, NoCapture<0>]>,
 401                            GCCBuiltin<"__sync_fetch_and_umax">;
 402
 403 //===-------------------------- Other Intrinsics --------------------------===//
 404 //
 405 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 406                      GCCBuiltin<"__builtin_flt_rounds">;
 407 def int_trap : Intrinsic<[llvm_void_ty]>,
 408                GCCBuiltin<"__builtin_trap">;
 409
 410 // These convert intrinsics are to support various conversions between
 411 // various types with rounding and saturation. NOTE: avoid using these
 412 // intrinsics as they might be removed sometime in the future and
 413 // most targets don't support them.
 414 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 415                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 416 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 417                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 418 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 419                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 420 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 421                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 422 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 423                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 424 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 425                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 426 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 427                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 428 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 429                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 430 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 431                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 432
 433 //===----------------------------------------------------------------------===//
 434 // Target-specific intrinsics
 435 //===----------------------------------------------------------------------===//
 436
 437 include "llvm/IntrinsicsPowerPC.td"
 438 include "llvm/IntrinsicsX86.td"
 439 include "llvm/IntrinsicsARM.td"
 440 include "llvm/IntrinsicsCellSPU.td"
 441 include "llvm/IntrinsicsAlpha.td"
 442 include "llvm/IntrinsicsXCore.td"