include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def IntrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  52 def Commutative : IntrinsicProperty;
  53
  54 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  55 class NoCapture<int argNo> : IntrinsicProperty {
  56   int ArgNo = argNo;
  57 }
  58
  59 //===----------------------------------------------------------------------===//
  60 // Types used by intrinsics.
  61 //===----------------------------------------------------------------------===//
  62
  63 class LLVMType<ValueType vt> {
  64   ValueType VT = vt;
  65 }
  66
  67 class LLVMPointerType<LLVMType elty>
  68   : LLVMType<iPTR>{
  69   LLVMType ElTy = elty;
  70 }
  71
  72 class LLVMAnyPointerType<LLVMType elty>
  73   : LLVMType<iPTRAny>{
  74   LLVMType ElTy = elty;
  75 }
  76
  77 class LLVMMatchType<int num>
  78   : LLVMType<OtherVT>{
  79   int Number = num;
  80 }
  81
  82 // Match the type of another intrinsic parameter that is expected to be
  83 // an integral vector type, but change the element size to be twice as wide
  84 // or half as wide as the other type.  This is only useful when the intrinsic
  85 // is overloaded, so the matched type should be declared as iAny.
  86 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  87 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  88
  89 def llvm_void_ty       : LLVMType<isVoid>;
  90 def llvm_anyint_ty     : LLVMType<iAny>;
  91 def llvm_anyfloat_ty   : LLVMType<fAny>;
  92 def llvm_i1_ty         : LLVMType<i1>;
  93 def llvm_i8_ty         : LLVMType<i8>;
  94 def llvm_i16_ty        : LLVMType<i16>;
  95 def llvm_i32_ty        : LLVMType<i32>;
  96 def llvm_i64_ty        : LLVMType<i64>;
  97 def llvm_float_ty      : LLVMType<f32>;
  98 def llvm_double_ty     : LLVMType<f64>;
  99 def llvm_f80_ty        : LLVMType<f80>;
 100 def llvm_f128_ty       : LLVMType<f128>;
 101 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 102 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 103 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 104 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 105 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 106 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 107
 108 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 109 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 110 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 111 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 112 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 113 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 114 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 115 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 116
 117 // MMX Vector Types
 118 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 119 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 120
 121 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 122
 123 //===----------------------------------------------------------------------===//
 124 // Intrinsic Definitions.
 125 //===----------------------------------------------------------------------===//
 126
 127 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 128 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 129 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 130 // example, llvm.bswap.i16 -> int_bswap_i16.
 131 //
 132 //  * RetTypes is a list containing the return types expected for the
 133 //    intrinsic.
 134 //  * ParamTypes is a list containing the parameter types expected for the
 135 //    intrinsic.
 136 //  * Properties can be set to describe the behavior of the intrinsic.
 137 //
 138 class Intrinsic<list<LLVMType> ret_types,
 139                 list<LLVMType> param_types = [],
 140                 list<IntrinsicProperty> properties = [],
 141                 string name = ""> {
 142   string LLVMName = name;
 143   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 144   list<LLVMType> RetTypes = ret_types;
 145   list<LLVMType> ParamTypes = param_types;
 146   list<IntrinsicProperty> Properties = properties;
 147
 148   bit isTarget = 0;
 149 }
 150
 151 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 152 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 153 /// support.
 154 class GCCBuiltin<string name> {
 155   string GCCBuiltinName = name;
 156 }
 157
 158
 159 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 160 //
 161
 162 def int_vastart : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_start">;
 163 def int_vacopy  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_ptr_ty], [],
 164                             "llvm.va_copy">;
 165 def int_vaend   : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_end">;
 166
 167 //===------------------- Garbage Collection Intrinsics --------------------===//
 168 //
 169 def int_gcroot  : Intrinsic<[llvm_void_ty],
 170                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 171 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 172                             [llvm_ptr_ty, llvm_ptrptr_ty],
 173                             [IntrReadArgMem]>;
 174 def int_gcwrite : Intrinsic<[llvm_void_ty],
 175                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 176                             [IntrWriteArgMem]>;
 177
 178 //===--------------------- Code Generator Intrinsics ----------------------===//
 179 //
 180 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 181 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 182
 183 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 184 // model their dependencies on allocas.
 185 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 186                         GCCBuiltin<"__builtin_stack_save">;
 187 def int_stackrestore  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty]>,
 188                         GCCBuiltin<"__builtin_stack_restore">;
 189
 190 // IntrWriteArgMem is more pessimistic than strictly necessary for prefetch,
 191 // however it does conveniently prevent the prefetch from being reordered
 192 // with respect to nearby accesses to the same memory.
 193 def int_prefetch      : Intrinsic<[llvm_void_ty],
 194                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty],
 195                                   [IntrWriteArgMem]>;
 196 def int_pcmarker      : Intrinsic<[llvm_void_ty], [llvm_i32_ty]>;
 197
 198 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 199
 200 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 201 // guard to the correct place on the stack frame.
 202 def int_stackprotector : Intrinsic<[llvm_void_ty],
 203                                    [llvm_ptr_ty, llvm_ptrptr_ty],
 204                                    [IntrWriteMem]>;
 205
 206 //===------------------- Standard C Library Intrinsics --------------------===//
 207 //
 208
 209 def int_memcpy  : Intrinsic<[llvm_void_ty],
 210                              [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 211                               llvm_i32_ty],
 212                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 213 def int_memmove : Intrinsic<[llvm_void_ty],
 214                             [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 215                              llvm_i32_ty],
 216                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 217 def int_memset  : Intrinsic<[llvm_void_ty],
 218                             [llvm_ptr_ty, llvm_i8_ty, llvm_anyint_ty,
 219                              llvm_i32_ty],
 220                             [IntrWriteArgMem, NoCapture<0>]>;
 221
 222 // These functions do not actually read memory, but they are sensitive to the
 223 // rounding mode.  This needs to be modelled separately; in the meantime
 224 // declaring them as reading memory is conservatively correct.
 225 let Properties = [IntrReadMem] in {
 226   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 227   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 228   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 229   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 230   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 231                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 232   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 233   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 234   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 235   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 236   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 237 }
 238
 239 // NOTE: these are internal interfaces.
 240 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 241 def int_longjmp    : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 242 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 243 def int_siglongjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 244
 245 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 246 //
 247
 248 // None of these intrinsics accesses memory at all.
 249 let Properties = [IntrNoMem] in {
 250   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 251   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 252   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 253   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 254   def int_part_select : Intrinsic<[llvm_anyint_ty],
 255                                   [LLVMMatchType<0>, llvm_i32_ty, llvm_i32_ty]>;
 256   def int_part_set : Intrinsic<[llvm_anyint_ty],
 257                                [LLVMMatchType<0>, llvm_anyint_ty,
 258                                 llvm_i32_ty, llvm_i32_ty]>;
 259 }
 260
 261 //===------------------------ Debugger Intrinsics -------------------------===//
 262 //
 263
 264 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty],
 265                                      [llvm_i32_ty, llvm_i32_ty,
 266                                       llvm_descriptor_ty]>;
 267 def int_dbg_region_start : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 268 def int_dbg_region_end   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 269 def int_dbg_func_start   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 270 def int_dbg_declare      : Intrinsic<[llvm_void_ty],
 271                                      [llvm_descriptor_ty, llvm_descriptor_ty]>;
 272
 273 //===------------------ Exception Handling Intrinsics----------------------===//
 274 //
 275 def int_eh_exception    : Intrinsic<[llvm_ptr_ty]>;
 276 def int_eh_selector_i32 : Intrinsic<[llvm_i32_ty],
 277                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 278 def int_eh_selector_i64 : Intrinsic<[llvm_i64_ty],
 279                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 280
 281 def int_eh_typeid_for_i32 : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 282 def int_eh_typeid_for_i64 : Intrinsic<[llvm_i64_ty], [llvm_ptr_ty]>;
 283
 284 def int_eh_return_i32 : Intrinsic<[llvm_void_ty], [llvm_i32_ty, llvm_ptr_ty]>;
 285 def int_eh_return_i64 : Intrinsic<[llvm_void_ty], [llvm_i64_ty, llvm_ptr_ty]>;
 286
 287 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 288                         GCCBuiltin<"__builtin_unwind_init">;
 289
 290 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 291
 292 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 293 //
 294 def int_var_annotation : Intrinsic<[llvm_void_ty],
 295                                    [llvm_ptr_ty, llvm_ptr_ty,
 296                                     llvm_ptr_ty, llvm_i32_ty],
 297                                    [], "llvm.var.annotation">;
 298 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 299                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 300                                     llvm_i32_ty],
 301                                    [], "llvm.ptr.annotation">;
 302 def int_annotation : Intrinsic<[llvm_anyint_ty],
 303                                [LLVMMatchType<0>, llvm_ptr_ty,
 304                                 llvm_ptr_ty, llvm_i32_ty],
 305                                [], "llvm.annotation">;
 306
 307 //===------------------------ Trampoline Intrinsics -----------------------===//
 308 //
 309 def int_init_trampoline : Intrinsic<[llvm_ptr_ty],
 310                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 311                                     []>,
 312                           GCCBuiltin<"__builtin_init_trampoline">;
 313
 314 //===------------------------ Overflow Intrinsics -------------------------===//
 315 //
 316
 317 // Expose the carry flag from add operations on two integrals.
 318 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 319                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 320 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 321                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 322
 323 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 324                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 325 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 326                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 327
 328 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 329                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 330 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 331                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 332
 333 //===------------------------- Atomic Intrinsics --------------------------===//
 334 //
 335 def int_memory_barrier : Intrinsic<[llvm_void_ty],
 336                                    [llvm_i1_ty, llvm_i1_ty,
 337                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 338                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 339
 340 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 341                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 342                                      LLVMMatchType<0>, LLVMMatchType<0>],
 343                                     [IntrWriteArgMem]>,
 344                            GCCBuiltin<"__sync_val_compare_and_swap">;
 345 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 346                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 347                                      LLVMMatchType<0>],
 348                                     [IntrWriteArgMem]>,
 349                            GCCBuiltin<"__sync_fetch_and_add">;
 350 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 351                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 352                                      LLVMMatchType<0>],
 353                                     [IntrWriteArgMem]>,
 354                            GCCBuiltin<"__sync_lock_test_and_set">;
 355 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 356                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 357                                      LLVMMatchType<0>],
 358                                     [IntrWriteArgMem]>,
 359                            GCCBuiltin<"__sync_fetch_and_sub">;
 360 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 361                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 362                                      LLVMMatchType<0>],
 363                                     [IntrWriteArgMem]>,
 364                            GCCBuiltin<"__sync_fetch_and_and">;
 365 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 366                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 367                                       LLVMMatchType<0>],
 368                                      [IntrWriteArgMem]>,
 369                            GCCBuiltin<"__sync_fetch_and_or">;
 370 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 371                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 372                                      LLVMMatchType<0>],
 373                                     [IntrWriteArgMem]>,
 374                            GCCBuiltin<"__sync_fetch_and_xor">;
 375 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 376                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 377                                       LLVMMatchType<0>],
 378                                      [IntrWriteArgMem]>,
 379                            GCCBuiltin<"__sync_fetch_and_nand">;
 380 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 381                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 382                                       LLVMMatchType<0>],
 383                                      [IntrWriteArgMem]>,
 384                            GCCBuiltin<"__sync_fetch_and_min">;
 385 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 386                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 387                                       LLVMMatchType<0>],
 388                                      [IntrWriteArgMem]>,
 389                            GCCBuiltin<"__sync_fetch_and_max">;
 390 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 391                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 392                                       LLVMMatchType<0>],
 393                                      [IntrWriteArgMem]>,
 394                            GCCBuiltin<"__sync_fetch_and_umin">;
 395 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 396                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 397                                       LLVMMatchType<0>],
 398                                      [IntrWriteArgMem]>,
 399                            GCCBuiltin<"__sync_fetch_and_umax">;
 400
 401 //===-------------------------- Other Intrinsics --------------------------===//
 402 //
 403 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 404                      GCCBuiltin<"__builtin_flt_rounds">;
 405 def int_trap : Intrinsic<[llvm_void_ty]>,
 406                GCCBuiltin<"__builtin_trap">;
 407
 408 // These convert intrinsics are to support various conversions between
 409 // various types with rounding and saturation. NOTE: avoid using these
 410 // intrinsics as they might be removed sometime in the future and
 411 // most targets don't support them.
 412 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 413                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 414 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 415                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 416 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 417                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 418 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 419                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 420 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 421                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 422 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 423                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 424 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 425                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 426 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 427                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 428 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 429                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 430
 431 //===----------------------------------------------------------------------===//
 432 // Target-specific intrinsics
 433 //===----------------------------------------------------------------------===//
 434
 435 include "llvm/IntrinsicsPowerPC.td"
 436 include "llvm/IntrinsicsX86.td"
 437 include "llvm/IntrinsicsARM.td"
 438 include "llvm/IntrinsicsCellSPU.td"
 439 include "llvm/IntrinsicsAlpha.td"
 440 include "llvm/IntrinsicsXCore.td"