include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under the
   6 // University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def IntrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 //===----------------------------------------------------------------------===//
  52 // Types used by intrinsics.
  53 //===----------------------------------------------------------------------===//
  54
  55 class LLVMType<ValueType vt, string typeval> {
  56   ValueType VT = vt;
  57   string TypeVal = typeval;
  58 }
  59
  60 class LLVMIntegerType<ValueType VT, int width>
  61   : LLVMType<VT, "Type::IntegerTyID"> {
  62   int Width = width;
  63 }
  64
  65 class LLVMVectorType<ValueType VT, int numelts, LLVMType elty>
  66   : LLVMType<VT, "Type::VectorTyID">{
  67   int NumElts = numelts;
  68   LLVMType ElTy = elty;
  69 }
  70
  71 class LLVMPointerType<LLVMType elty>
  72   : LLVMType<iPTR, "Type::PointerTyID">{
  73   LLVMType ElTy = elty;
  74 }
  75
  76 class LLVMEmptyStructType
  77   : LLVMType<OtherVT, "Type::StructTyID">{
  78 }
  79
  80 def llvm_void_ty       : LLVMType<isVoid, "Type::VoidTyID">;
  81 def llvm_int_ty        : LLVMIntegerType<iAny, 0>;
  82 def llvm_i1_ty         : LLVMIntegerType<i1 , 1>;
  83 def llvm_i8_ty         : LLVMIntegerType<i8 , 8>;
  84 def llvm_i16_ty        : LLVMIntegerType<i16, 16>;
  85 def llvm_i32_ty        : LLVMIntegerType<i32, 32>;
  86 def llvm_i64_ty        : LLVMIntegerType<i64, 64>;
  87 def llvm_float_ty      : LLVMType<f32, "Type::FloatTyID">;
  88 def llvm_double_ty     : LLVMType<f64, "Type::DoubleTyID">;
  89 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
  90 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
  91 def llvm_empty_ty      : LLVMEmptyStructType;                     // { }
  92 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
  93
  94 def llvm_v16i8_ty      : LLVMVectorType<v16i8,16, llvm_i8_ty>;    // 16 x i8
  95 def llvm_v8i16_ty      : LLVMVectorType<v8i16, 8, llvm_i16_ty>;   //  8 x i16
  96 def llvm_v2i64_ty      : LLVMVectorType<v2i64, 2, llvm_i64_ty>;   //  2 x i64
  97 def llvm_v2i32_ty      : LLVMVectorType<v2i32, 2, llvm_i32_ty>;   //  2 x i32
  98 def llvm_v1i64_ty      : LLVMVectorType<v1i64, 1, llvm_i64_ty>;   //  1 x i64
  99 def llvm_v4i32_ty      : LLVMVectorType<v4i32, 4, llvm_i32_ty>;   //  4 x i32
 100 def llvm_v4f32_ty      : LLVMVectorType<v4f32, 4, llvm_float_ty>; //  4 x float
 101 def llvm_v2f64_ty      : LLVMVectorType<v2f64, 2, llvm_double_ty>;//  2 x double
 102
 103 // MMX Vector Types
 104 def llvm_v8i8_ty       : LLVMVectorType<v8i8,  8, llvm_i8_ty>;    //  8 x i8
 105 def llvm_v4i16_ty      : LLVMVectorType<v4i16, 4, llvm_i16_ty>;   //  4 x i16
 106
 107 def llvm_vararg_ty     : LLVMType<isVoid, "...">; // vararg
 108
 109 //===----------------------------------------------------------------------===//
 110 // Intrinsic Definitions.
 111 //===----------------------------------------------------------------------===//
 112
 113 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 114 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 115 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 116 // example, llvm.bswap.i16 -> int_bswap_i16.
 117 //
 118 //  * Types is a list containing the return type and the argument types
 119 //    expected for the intrinsic.
 120 //  * Properties can be set to describe the behavior of the intrinsic.
 121 //
 122 class Intrinsic<list<LLVMType> types,
 123                 list<IntrinsicProperty> properties = [],
 124                 string name = ""> {
 125   string LLVMName = name;
 126   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 127   list<LLVMType> Types = types;
 128   list<IntrinsicProperty> Properties = properties;
 129 }
 130
 131 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 132 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 133 /// support.
 134 class GCCBuiltin<string name> {
 135   string GCCBuiltinName = name;
 136 }
 137
 138
 139 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 140 //
 141
 142 def int_vastart : Intrinsic<[llvm_void_ty, llvm_ptr_ty], [], "llvm.va_start">;
 143 def int_vacopy  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty], [],
 144                             "llvm.va_copy">;
 145 def int_vaend   : Intrinsic<[llvm_void_ty, llvm_ptr_ty], [], "llvm.va_end">;
 146
 147 //===------------------- Garbage Collection Intrinsics --------------------===//
 148 //
 149 def int_gcroot  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptr_ty]>;
 150 def int_gcread  : Intrinsic<[llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 151                             [IntrReadArgMem]>;
 152 def int_gcwrite : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 153                              llvm_ptrptr_ty], [IntrWriteArgMem]>;
 154
 155 //===--------------------- Code Generator Intrinsics ----------------------===//
 156 //
 157 def int_returnaddress : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 158 def int_frameaddress  : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 159 def int_stacksave     : Intrinsic<[llvm_ptr_ty], [IntrReadMem]>,
 160                         GCCBuiltin<"__builtin_stack_save">;
 161 def int_stackrestore  : Intrinsic<[llvm_void_ty, llvm_ptr_ty]>,
 162                         GCCBuiltin<"__builtin_stack_restore">;
 163 def int_prefetch      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 164                                    llvm_i32_ty, llvm_i32_ty]>;
 165 def int_pcmarker      : Intrinsic<[llvm_void_ty, llvm_i32_ty]>;
 166
 167 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 168
 169 //===------------------- Standard C Library Intrinsics --------------------===//
 170 //
 171
 172 let Properties = [IntrWriteArgMem] in {
 173   def int_memcpy_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 174                                    llvm_i32_ty, llvm_i32_ty]>;
 175   def int_memcpy_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 176                                    llvm_i64_ty, llvm_i32_ty]>;
 177   def int_memmove_i32 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 178                                    llvm_i32_ty, llvm_i32_ty]>;
 179   def int_memmove_i64 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 180                                    llvm_i64_ty, llvm_i32_ty]>;
 181   def int_memset_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 182                                    llvm_i32_ty, llvm_i32_ty]>;
 183   def int_memset_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 184                                    llvm_i64_ty, llvm_i32_ty]>;
 185 }
 186
 187 let Properties = [IntrNoMem] in {
 188   def int_sqrt_f32 : Intrinsic<[llvm_float_ty , llvm_float_ty]>;
 189   def int_sqrt_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty]>;
 190
 191   def int_powi_f32 : Intrinsic<[llvm_float_ty , llvm_float_ty, llvm_i32_ty]>;
 192   def int_powi_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty, llvm_i32_ty]>;
 193 }
 194
 195 // NOTE: these are internal interfaces.
 196 def int_setjmp     : Intrinsic<[llvm_i32_ty , llvm_ptr_ty]>;
 197 def int_longjmp    : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 198 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty , llvm_ptr_ty, llvm_i32_ty]>;
 199 def int_siglongjmp : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 200
 201 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 202 //
 203
 204 // None of these intrinsics accesses memory at all.
 205 let Properties = [IntrNoMem] in {
 206   def int_bswap: Intrinsic<[llvm_int_ty, llvm_int_ty]>;
 207   def int_ctpop: Intrinsic<[llvm_i32_ty, llvm_int_ty]>;
 208   def int_ctlz : Intrinsic<[llvm_i32_ty, llvm_int_ty]>;
 209   def int_cttz : Intrinsic<[llvm_i32_ty, llvm_int_ty]>;
 210   def int_part_select :
 211      Intrinsic<[llvm_int_ty, llvm_int_ty, llvm_i32_ty, llvm_i32_ty]>;
 212   def int_part_set :
 213      Intrinsic<[llvm_int_ty, llvm_int_ty, llvm_int_ty, llvm_i32_ty,
 214                 llvm_i32_ty]>;
 215 }
 216
 217 //===------------------------ Debugger Intrinsics -------------------------===//
 218 //
 219
 220 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty,
 221                                       llvm_i32_ty, llvm_i32_ty,
 222                                       llvm_descriptor_ty]>;
 223 def int_dbg_region_start : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 224 def int_dbg_region_end   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 225 def int_dbg_func_start   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 226 def int_dbg_declare      : Intrinsic<[llvm_void_ty, llvm_descriptor_ty,
 227                                                     llvm_descriptor_ty]>;
 228
 229 //===------------------ Exception Handling Intrinsics----------------------===//
 230 //
 231 def int_eh_exception  : Intrinsic<[llvm_ptr_ty]>;
 232 def int_eh_selector   : Intrinsic<[llvm_i32_ty, llvm_ptr_ty, llvm_ptr_ty,
 233                                                 llvm_vararg_ty]>;
 234 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty, llvm_ptr_ty]>;
 235
 236 def int_eh_return     : Intrinsic<[llvm_void_ty, llvm_i32_ty, llvm_ptr_ty]>,
 237                         GCCBuiltin<"__builtin_eh_return">;
 238
 239 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 240                         GCCBuiltin<"__builtin_unwind_init">;
 241
 242 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty, llvm_i32_ty]>;
 243
 244 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 245 //
 246 def int_var_annotation : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 247                                     llvm_ptr_ty, llvm_i32_ty],
 248                                     [], "llvm.var.annotation">;
 249
 250 //===----------------------------------------------------------------------===//
 251 // Target-specific intrinsics
 252 //===----------------------------------------------------------------------===//
 253
 254 include "llvm/IntrinsicsPowerPC.td"
 255 include "llvm/IntrinsicsX86.td"