include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  The reads
  42 // and writes may be volatile, but except for this it has no other side effects.
  43 def IntrWriteArgMem : IntrinsicProperty;
  44
  45 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  46 // other side effects.  It cannot be modified by the optimizer.  This is the
  47 // default if the intrinsic has no other Intr*Mem property.
  48 def IntrWriteMem : IntrinsicProperty;
  49
  50 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  51 def Commutative : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 //===----------------------------------------------------------------------===//
  59 // Types used by intrinsics.
  60 //===----------------------------------------------------------------------===//
  61
  62 class LLVMType<ValueType vt> {
  63   ValueType VT = vt;
  64 }
  65
  66 class LLVMPointerType<LLVMType elty>
  67   : LLVMType<iPTR>{
  68   LLVMType ElTy = elty;
  69 }
  70
  71 class LLVMAnyPointerType<LLVMType elty>
  72   : LLVMType<iPTRAny>{
  73   LLVMType ElTy = elty;
  74 }
  75
  76 // Match the type of another intrinsic parameter.  Number is an index into the
  77 // list of overloaded types for the intrinsic, excluding all the fixed types.
  78 // The Number value must refer to a previously listed type.  For example:
  79 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  80 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  81 // refers to the first overloaded type, which is the 2nd argument.
  82 class LLVMMatchType<int num>
  83   : LLVMType<OtherVT>{
  84   int Number = num;
  85 }
  86
  87 // Match the type of another intrinsic parameter that is expected to be
  88 // an integral vector type, but change the element size to be twice as wide
  89 // or half as wide as the other type.  This is only useful when the intrinsic
  90 // is overloaded, so the matched type should be declared as iAny.
  91 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  92 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  93
  94 def llvm_void_ty       : LLVMType<isVoid>;
  95 def llvm_anyint_ty     : LLVMType<iAny>;
  96 def llvm_anyfloat_ty   : LLVMType<fAny>;
  97 def llvm_i1_ty         : LLVMType<i1>;
  98 def llvm_i8_ty         : LLVMType<i8>;
  99 def llvm_i16_ty        : LLVMType<i16>;
 100 def llvm_i32_ty        : LLVMType<i32>;
 101 def llvm_i64_ty        : LLVMType<i64>;
 102 def llvm_float_ty      : LLVMType<f32>;
 103 def llvm_double_ty     : LLVMType<f64>;
 104 def llvm_f80_ty        : LLVMType<f80>;
 105 def llvm_f128_ty       : LLVMType<f128>;
 106 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 107 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 108 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 109 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 110 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 111 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 112
 113 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 114 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 115 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 116 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 117 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 118 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  4 x i16
 119 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 120 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 121 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 122 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 123 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 124 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 125 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 126 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 127 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 128
 129 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 130 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 131 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 132 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 133 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 134
 135 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 136
 137
 138 //===----------------------------------------------------------------------===//
 139 // Intrinsic Definitions.
 140 //===----------------------------------------------------------------------===//
 141
 142 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 143 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 144 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 145 // example, llvm.bswap.i16 -> int_bswap_i16.
 146 //
 147 //  * RetTypes is a list containing the return types expected for the
 148 //    intrinsic.
 149 //  * ParamTypes is a list containing the parameter types expected for the
 150 //    intrinsic.
 151 //  * Properties can be set to describe the behavior of the intrinsic.
 152 //
 153 class Intrinsic<list<LLVMType> ret_types,
 154                 list<LLVMType> param_types = [],
 155                 list<IntrinsicProperty> properties = [],
 156                 string name = ""> {
 157   string LLVMName = name;
 158   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 159   list<LLVMType> RetTypes = ret_types;
 160   list<LLVMType> ParamTypes = param_types;
 161   list<IntrinsicProperty> Properties = properties;
 162
 163   bit isTarget = 0;
 164 }
 165
 166 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 167 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 168 /// support.
 169 class GCCBuiltin<string name> {
 170   string GCCBuiltinName = name;
 171 }
 172
 173
 174 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 175 //
 176
 177 def int_vastart : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_start">;
 178 def int_vacopy  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_ptr_ty], [],
 179                             "llvm.va_copy">;
 180 def int_vaend   : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_end">;
 181
 182 //===------------------- Garbage Collection Intrinsics --------------------===//
 183 //
 184 def int_gcroot  : Intrinsic<[llvm_void_ty],
 185                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 186 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 187                             [llvm_ptr_ty, llvm_ptrptr_ty],
 188                             [IntrReadArgMem]>;
 189 def int_gcwrite : Intrinsic<[llvm_void_ty],
 190                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 191                             [IntrWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 192
 193 //===--------------------- Code Generator Intrinsics ----------------------===//
 194 //
 195 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 196 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 197
 198 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 199 // model their dependencies on allocas.
 200 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 201                         GCCBuiltin<"__builtin_stack_save">;
 202 def int_stackrestore  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty]>,
 203                         GCCBuiltin<"__builtin_stack_restore">;
 204
 205 // IntrWriteArgMem is more pessimistic than strictly necessary for prefetch,
 206 // however it does conveniently prevent the prefetch from being reordered
 207 // with respect to nearby accesses to the same memory.
 208 def int_prefetch      : Intrinsic<[llvm_void_ty],
 209                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty],
 210                                   [IntrWriteArgMem, NoCapture<0>]>;
 211 def int_pcmarker      : Intrinsic<[llvm_void_ty], [llvm_i32_ty]>;
 212
 213 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 214
 215 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 216 // guard to the correct place on the stack frame.
 217 def int_stackprotector : Intrinsic<[llvm_void_ty],
 218                                    [llvm_ptr_ty, llvm_ptrptr_ty],
 219                                    [IntrWriteMem]>;
 220
 221 //===------------------- Standard C Library Intrinsics --------------------===//
 222 //
 223
 224 def int_memcpy  : Intrinsic<[llvm_void_ty],
 225                              [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 226                               llvm_i32_ty],
 227                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 228 def int_memmove : Intrinsic<[llvm_void_ty],
 229                             [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 230                              llvm_i32_ty],
 231                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 232 def int_memset  : Intrinsic<[llvm_void_ty],
 233                             [llvm_ptr_ty, llvm_i8_ty, llvm_anyint_ty,
 234                              llvm_i32_ty],
 235                             [IntrWriteArgMem, NoCapture<0>]>;
 236
 237 // These functions do not actually read memory, but they are sensitive to the
 238 // rounding mode.  This needs to be modelled separately; in the meantime
 239 // declaring them as reading memory is conservatively correct.
 240 let Properties = [IntrReadMem] in {
 241   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 242   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 243   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 244   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 245   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 246                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 247   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 248   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 249   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 250   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 251   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 252 }
 253
 254 // NOTE: these are internal interfaces.
 255 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 256 def int_longjmp    : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 257 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 258 def int_siglongjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 259
 260 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 261 //
 262
 263 // None of these intrinsics accesses memory at all.
 264 let Properties = [IntrNoMem] in {
 265   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 266   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 267   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 268   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 269 }
 270
 271 //===------------------------ Debugger Intrinsics -------------------------===//
 272 //
 273
 274 // None of these intrinsics accesses memory at all...but that doesn't mean the
 275 // optimizers can change them aggressively.  Special handling needed in a few
 276 // places.
 277 let Properties = [IntrNoMem] in {
 278   def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty],
 279                                        [llvm_i32_ty, llvm_i32_ty,
 280                                         llvm_descriptor_ty]>;
 281   def int_dbg_region_start : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 282   def int_dbg_region_end   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 283   def int_dbg_func_start   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 284   def int_dbg_declare      : Intrinsic<[llvm_void_ty],
 285                                        [llvm_descriptor_ty, llvm_descriptor_ty]>;
 286 }
 287
 288 //===------------------ Exception Handling Intrinsics----------------------===//
 289 //
 290 def int_eh_exception    : Intrinsic<[llvm_ptr_ty]>;
 291 def int_eh_selector_i32 : Intrinsic<[llvm_i32_ty],
 292                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 293 def int_eh_selector_i64 : Intrinsic<[llvm_i64_ty],
 294                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 295
 296 def int_eh_typeid_for_i32 : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 297 def int_eh_typeid_for_i64 : Intrinsic<[llvm_i64_ty], [llvm_ptr_ty]>;
 298
 299 def int_eh_return_i32 : Intrinsic<[llvm_void_ty], [llvm_i32_ty, llvm_ptr_ty]>;
 300 def int_eh_return_i64 : Intrinsic<[llvm_void_ty], [llvm_i64_ty, llvm_ptr_ty]>;
 301
 302 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 303                         GCCBuiltin<"__builtin_unwind_init">;
 304
 305 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 306
 307 let Properties = [IntrNoMem] in {
 308 def int_eh_sjlj_setjmp  : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 309 def int_eh_sjlj_longjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 310 }
 311
 312 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 313 //
 314 def int_var_annotation : Intrinsic<[llvm_void_ty],
 315                                    [llvm_ptr_ty, llvm_ptr_ty,
 316                                     llvm_ptr_ty, llvm_i32_ty],
 317                                    [], "llvm.var.annotation">;
 318 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 319                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 320                                     llvm_i32_ty],
 321                                    [], "llvm.ptr.annotation">;
 322 def int_annotation : Intrinsic<[llvm_anyint_ty],
 323                                [LLVMMatchType<0>, llvm_ptr_ty,
 324                                 llvm_ptr_ty, llvm_i32_ty],
 325                                [], "llvm.annotation">;
 326
 327 //===------------------------ Trampoline Intrinsics -----------------------===//
 328 //
 329 def int_init_trampoline : Intrinsic<[llvm_ptr_ty],
 330                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 331                                     [IntrWriteArgMem]>,
 332                           GCCBuiltin<"__builtin_init_trampoline">;
 333
 334 //===------------------------ Overflow Intrinsics -------------------------===//
 335 //
 336
 337 // Expose the carry flag from add operations on two integrals.
 338 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 339                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 340 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 341                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 342
 343 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 344                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 345 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 346                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 347
 348 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 349                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 350 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 351                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 352
 353 //===------------------------- Atomic Intrinsics --------------------------===//
 354 //
 355 def int_memory_barrier : Intrinsic<[llvm_void_ty],
 356                                    [llvm_i1_ty, llvm_i1_ty,
 357                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 358                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 359
 360 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 361                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 362                                      LLVMMatchType<0>, LLVMMatchType<0>],
 363                                     [IntrWriteArgMem, NoCapture<0>]>,
 364                            GCCBuiltin<"__sync_val_compare_and_swap">;
 365 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 366                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 367                                      LLVMMatchType<0>],
 368                                     [IntrWriteArgMem, NoCapture<0>]>,
 369                            GCCBuiltin<"__sync_fetch_and_add">;
 370 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 371                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 372                                      LLVMMatchType<0>],
 373                                     [IntrWriteArgMem, NoCapture<0>]>,
 374                            GCCBuiltin<"__sync_lock_test_and_set">;
 375 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 376                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 377                                      LLVMMatchType<0>],
 378                                     [IntrWriteArgMem, NoCapture<0>]>,
 379                            GCCBuiltin<"__sync_fetch_and_sub">;
 380 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 381                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 382                                      LLVMMatchType<0>],
 383                                     [IntrWriteArgMem, NoCapture<0>]>,
 384                            GCCBuiltin<"__sync_fetch_and_and">;
 385 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 386                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 387                                       LLVMMatchType<0>],
 388                                      [IntrWriteArgMem, NoCapture<0>]>,
 389                            GCCBuiltin<"__sync_fetch_and_or">;
 390 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 391                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 392                                      LLVMMatchType<0>],
 393                                     [IntrWriteArgMem, NoCapture<0>]>,
 394                            GCCBuiltin<"__sync_fetch_and_xor">;
 395 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 396                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 397                                       LLVMMatchType<0>],
 398                                      [IntrWriteArgMem, NoCapture<0>]>,
 399                            GCCBuiltin<"__sync_fetch_and_nand">;
 400 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 401                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 402                                       LLVMMatchType<0>],
 403                                      [IntrWriteArgMem, NoCapture<0>]>,
 404                            GCCBuiltin<"__sync_fetch_and_min">;
 405 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 406                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 407                                       LLVMMatchType<0>],
 408                                      [IntrWriteArgMem, NoCapture<0>]>,
 409                            GCCBuiltin<"__sync_fetch_and_max">;
 410 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 411                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 412                                       LLVMMatchType<0>],
 413                                      [IntrWriteArgMem, NoCapture<0>]>,
 414                            GCCBuiltin<"__sync_fetch_and_umin">;
 415 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 416                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 417                                       LLVMMatchType<0>],
 418                                      [IntrWriteArgMem, NoCapture<0>]>,
 419                            GCCBuiltin<"__sync_fetch_and_umax">;
 420
 421 //===-------------------------- Other Intrinsics --------------------------===//
 422 //
 423 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 424                      GCCBuiltin<"__builtin_flt_rounds">;
 425 def int_trap : Intrinsic<[llvm_void_ty]>,
 426                GCCBuiltin<"__builtin_trap">;
 427
 428 // These convert intrinsics are to support various conversions between
 429 // various types with rounding and saturation. NOTE: avoid using these
 430 // intrinsics as they might be removed sometime in the future and
 431 // most targets don't support them.
 432 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 433                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 434 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 435                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 436 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 437                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 438 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 439                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 440 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 441                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 442 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 443                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 444 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 445                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 446 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 447                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 448 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 449                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 450
 451 //===----------------------------------------------------------------------===//
 452 // Target-specific intrinsics
 453 //===----------------------------------------------------------------------===//
 454
 455 include "llvm/IntrinsicsPowerPC.td"
 456 include "llvm/IntrinsicsX86.td"
 457 include "llvm/IntrinsicsARM.td"
 458 include "llvm/IntrinsicsCellSPU.td"
 459 include "llvm/IntrinsicsAlpha.td"
 460 include "llvm/IntrinsicsXCore.td"
 461 include "llvm/IntrinsicsBlackfin.td"