include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 def IntrNoReturn : IntrinsicProperty;
  59
  60 //===----------------------------------------------------------------------===//
  61 // Types used by intrinsics.
  62 //===----------------------------------------------------------------------===//
  63
  64 class LLVMType<ValueType vt> {
  65   ValueType VT = vt;
  66 }
  67
  68 class LLVMQualPointerType<LLVMType elty, int addrspace>
  69   : LLVMType<iPTR>{
  70   LLVMType ElTy = elty;
  71   int AddrSpace = addrspace;
  72 }
  73
  74 class LLVMPointerType<LLVMType elty>
  75   : LLVMQualPointerType<elty, 0>;
  76
  77 class LLVMAnyPointerType<LLVMType elty>
  78   : LLVMType<iPTRAny>{
  79   LLVMType ElTy = elty;
  80 }
  81
  82 // Match the type of another intrinsic parameter.  Number is an index into the
  83 // list of overloaded types for the intrinsic, excluding all the fixed types.
  84 // The Number value must refer to a previously listed type.  For example:
  85 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  86 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  87 // refers to the first overloaded type, which is the 2nd argument.
  88 class LLVMMatchType<int num>
  89   : LLVMType<OtherVT>{
  90   int Number = num;
  91 }
  92
  93 // Match the type of another intrinsic parameter that is expected to be
  94 // an integral vector type, but change the element size to be twice as wide
  95 // or half as wide as the other type.  This is only useful when the intrinsic
  96 // is overloaded, so the matched type should be declared as iAny.
  97 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  98 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  99
 100 def llvm_void_ty       : LLVMType<isVoid>;
 101 def llvm_anyint_ty     : LLVMType<iAny>;
 102 def llvm_anyfloat_ty   : LLVMType<fAny>;
 103 def llvm_anyvector_ty  : LLVMType<vAny>;
 104 def llvm_i1_ty         : LLVMType<i1>;
 105 def llvm_i8_ty         : LLVMType<i8>;
 106 def llvm_i16_ty        : LLVMType<i16>;
 107 def llvm_i32_ty        : LLVMType<i32>;
 108 def llvm_i64_ty        : LLVMType<i64>;
 109 def llvm_float_ty      : LLVMType<f32>;
 110 def llvm_double_ty     : LLVMType<f64>;
 111 def llvm_f80_ty        : LLVMType<f80>;
 112 def llvm_f128_ty       : LLVMType<f128>;
 113 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 114 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 115 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 116 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 117 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 118 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 119 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 120
 121 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 122 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 123
 124 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 125 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 126 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 127 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 128 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 129 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 130 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 131 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 132 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 133 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 134 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 135 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 136 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 137 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 138 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 139 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 140 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 141 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 142
 143 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 144 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 145 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 146 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 147 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 148
 149 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 150
 151
 152 //===----------------------------------------------------------------------===//
 153 // Intrinsic Definitions.
 154 //===----------------------------------------------------------------------===//
 155
 156 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 157 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 158 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 159 // example, llvm.bswap.i16 -> int_bswap_i16.
 160 //
 161 //  * RetTypes is a list containing the return types expected for the
 162 //    intrinsic.
 163 //  * ParamTypes is a list containing the parameter types expected for the
 164 //    intrinsic.
 165 //  * Properties can be set to describe the behavior of the intrinsic.
 166 //
 167 class SDPatternOperator;
 168 class Intrinsic<list<LLVMType> ret_types,
 169                 list<LLVMType> param_types = [],
 170                 list<IntrinsicProperty> properties = [],
 171                 string name = ""> : SDPatternOperator {
 172   string LLVMName = name;
 173   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 174   list<LLVMType> RetTypes = ret_types;
 175   list<LLVMType> ParamTypes = param_types;
 176   list<IntrinsicProperty> Properties = properties;
 177
 178   bit isTarget = 0;
 179 }
 180
 181 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 182 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 183 /// support.
 184 class GCCBuiltin<string name> {
 185   string GCCBuiltinName = name;
 186 }
 187
 188
 189 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 190 //
 191
 192 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 193 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 194                             "llvm.va_copy">;
 195 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 196
 197 //===------------------- Garbage Collection Intrinsics --------------------===//
 198 //
 199 def int_gcroot  : Intrinsic<[],
 200                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 201 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 202                             [llvm_ptr_ty, llvm_ptrptr_ty],
 203                             [IntrReadArgMem]>;
 204 def int_gcwrite : Intrinsic<[],
 205                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 206                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 207
 208 //===--------------------- Code Generator Intrinsics ----------------------===//
 209 //
 210 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 211 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 212
 213 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 214 // model their dependencies on allocas.
 215 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 216                         GCCBuiltin<"__builtin_stack_save">;
 217 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 218                         GCCBuiltin<"__builtin_stack_restore">;
 219
 220 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 221 // however it does conveniently prevent the prefetch from being reordered
 222 // with respect to nearby accesses to the same memory.
 223 def int_prefetch      : Intrinsic<[],
 224                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 225                                    llvm_i32_ty],
 226                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 227 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 228
 229 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 230
 231 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 232 // guard to the correct place on the stack frame.
 233 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 234
 235 //===------------------- Standard C Library Intrinsics --------------------===//
 236 //
 237
 238 def int_memcpy  : Intrinsic<[],
 239                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 240                               llvm_i32_ty, llvm_i1_ty],
 241                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 242 def int_memmove : Intrinsic<[],
 243                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 244                              llvm_i32_ty, llvm_i1_ty],
 245                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 246 def int_memset  : Intrinsic<[],
 247                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 248                              llvm_i32_ty, llvm_i1_ty],
 249                             [IntrReadWriteArgMem, NoCapture<0>]>;
 250
 251 // These functions do not actually read memory, but they are sensitive to the
 252 // rounding mode.  This needs to be modelled separately; in the meantime
 253 // declaring them as reading memory is conservatively correct.
 254 let Properties = [IntrReadMem] in {
 255   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 256   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 257   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 258   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 259   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 260                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 261   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 262   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 263   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 264   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 265   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 266   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 267   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 268 }
 269
 270 let Properties = [IntrNoMem] in {
 271   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 272                          [LLVMMatchType<0>, LLVMMatchType<0>,
 273                           LLVMMatchType<0>]>;
 274
 275   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 276                               [LLVMMatchType<0>, LLVMMatchType<0>,
 277                                LLVMMatchType<0>]>;
 278 }
 279
 280 // NOTE: these are internal interfaces.
 281 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 282 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 283 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 284 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 285
 286 // Internal interface for object size checking
 287 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_ptr_ty, llvm_i1_ty],
 288                                [IntrNoMem]>,
 289                                GCCBuiltin<"__builtin_object_size">;
 290
 291 //===------------------------- Expect Intrinsics --------------------------===//
 292 //
 293 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 294                                               LLVMMatchType<0>], [IntrNoMem]>;
 295
 296 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 297 //
 298
 299 // None of these intrinsics accesses memory at all.
 300 let Properties = [IntrNoMem] in {
 301   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 302   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 303   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 304   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 305 }
 306
 307 //===------------------------ Debugger Intrinsics -------------------------===//
 308 //
 309
 310 // None of these intrinsics accesses memory at all...but that doesn't mean the
 311 // optimizers can change them aggressively.  Special handling needed in a few
 312 // places.
 313 let Properties = [IntrNoMem] in {
 314   def int_dbg_declare      : Intrinsic<[],
 315                                        [llvm_metadata_ty, llvm_metadata_ty]>;
 316   def int_dbg_value        : Intrinsic<[],
 317                                        [llvm_metadata_ty, llvm_i64_ty,
 318                                         llvm_metadata_ty]>;
 319 }
 320
 321 //===------------------ Exception Handling Intrinsics----------------------===//
 322 //
 323
 324 // The result of eh.typeid.for depends on the enclosing function, but inside a
 325 // given function it is 'const' and may be CSE'd etc.
 326 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 327
 328 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 329 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 330
 331 def int_eh_unwind_init: Intrinsic<[]>,
 332                         GCCBuiltin<"__builtin_unwind_init">;
 333
 334 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 335
 336 let Properties = [IntrNoMem] in {
 337   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 338   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 339 }
 340 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 341 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 342 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty]>;
 343
 344 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 345 //
 346 def int_var_annotation : Intrinsic<[],
 347                                    [llvm_ptr_ty, llvm_ptr_ty,
 348                                     llvm_ptr_ty, llvm_i32_ty],
 349                                    [], "llvm.var.annotation">;
 350 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 351                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 352                                     llvm_i32_ty],
 353                                    [], "llvm.ptr.annotation">;
 354 def int_annotation : Intrinsic<[llvm_anyint_ty],
 355                                [LLVMMatchType<0>, llvm_ptr_ty,
 356                                 llvm_ptr_ty, llvm_i32_ty],
 357                                [], "llvm.annotation">;
 358
 359 //===------------------------ Trampoline Intrinsics -----------------------===//
 360 //
 361 def int_init_trampoline : Intrinsic<[],
 362                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 363                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 364                                    GCCBuiltin<"__builtin_init_trampoline">;
 365
 366 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 367                                       [IntrReadArgMem]>,
 368                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 369
 370 //===------------------------ Overflow Intrinsics -------------------------===//
 371 //
 372
 373 // Expose the carry flag from add operations on two integrals.
 374 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 375                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 376                                        [IntrNoMem]>;
 377 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 378                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 379                                        [IntrNoMem]>;
 380
 381 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 382                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 383                                        [IntrNoMem]>;
 384 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 385                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 386                                        [IntrNoMem]>;
 387
 388 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 389                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 390                                        [IntrNoMem]>;
 391 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 392                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 393                                        [IntrNoMem]>;
 394
 395 //===------------------------- Memory Use Markers -------------------------===//
 396 //
 397 def int_lifetime_start  : Intrinsic<[],
 398                                     [llvm_i64_ty, llvm_ptr_ty],
 399                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 400 def int_lifetime_end    : Intrinsic<[],
 401                                     [llvm_i64_ty, llvm_ptr_ty],
 402                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 403 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 404                                     [llvm_i64_ty, llvm_ptr_ty],
 405                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 406 def int_invariant_end   : Intrinsic<[],
 407                                     [llvm_descriptor_ty, llvm_i64_ty,
 408                                      llvm_ptr_ty],
 409                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 410
 411 //===-------------------------- Other Intrinsics --------------------------===//
 412 //
 413 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 414                      GCCBuiltin<"__builtin_flt_rounds">;
 415 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 416                GCCBuiltin<"__builtin_trap">;
 417 def int_debugtrap : Intrinsic<[]>,
 418                     GCCBuiltin<"__builtin_debugtrap">;
 419
 420 // NOP: calls/invokes to this intrinsic are removed by codegen
 421 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 422
 423 // Intrisics to support half precision floating point format
 424 let Properties = [IntrNoMem] in {
 425 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_float_ty]>,
 426                             GCCBuiltin<"__gnu_f2h_ieee">;
 427 def int_convert_from_fp16 : Intrinsic<[llvm_float_ty], [llvm_i16_ty]>,
 428                             GCCBuiltin<"__gnu_h2f_ieee">;
 429 }
 430
 431 // These convert intrinsics are to support various conversions between
 432 // various types with rounding and saturation. NOTE: avoid using these
 433 // intrinsics as they might be removed sometime in the future and
 434 // most targets don't support them.
 435 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 436                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 437 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 438                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 439 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 440                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 441 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 442                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 443 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 444                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 445 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 446                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 447 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 448                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 449 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 450                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 451 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 452                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 453
 454 //===----------------------------------------------------------------------===//
 455 // Target-specific intrinsics
 456 //===----------------------------------------------------------------------===//
 457
 458 include "llvm/IntrinsicsPowerPC.td"
 459 include "llvm/IntrinsicsX86.td"
 460 include "llvm/IntrinsicsARM.td"
 461 include "llvm/IntrinsicsCellSPU.td"
 462 include "llvm/IntrinsicsXCore.td"
 463 include "llvm/IntrinsicsHexagon.td"
 464 include "llvm/IntrinsicsNVVM.td"
 465 include "llvm/IntrinsicsMips.td"