include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def IntrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  52 def Commutative : IntrinsicProperty;
  53
  54 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  55 class NoCapture<int argNo> : IntrinsicProperty {
  56   int ArgNo = argNo;
  57 }
  58
  59 //===----------------------------------------------------------------------===//
  60 // Types used by intrinsics.
  61 //===----------------------------------------------------------------------===//
  62
  63 class LLVMType<ValueType vt> {
  64   ValueType VT = vt;
  65 }
  66
  67 class LLVMPointerType<LLVMType elty>
  68   : LLVMType<iPTR>{
  69   LLVMType ElTy = elty;
  70 }
  71
  72 class LLVMAnyPointerType<LLVMType elty>
  73   : LLVMType<iPTRAny>{
  74   LLVMType ElTy = elty;
  75 }
  76
  77 class LLVMMatchType<int num>
  78   : LLVMType<OtherVT>{
  79   int Number = num;
  80 }
  81
  82 // Match the type of another intrinsic parameter that is expected to be
  83 // an integral vector type, but change the element size to be twice as wide
  84 // or half as wide as the other type.  This is only useful when the intrinsic
  85 // is overloaded, so the matched type should be declared as iAny.
  86 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  87 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  88
  89 def llvm_void_ty       : LLVMType<isVoid>;
  90 def llvm_anyint_ty     : LLVMType<iAny>;
  91 def llvm_anyfloat_ty   : LLVMType<fAny>;
  92 def llvm_i1_ty         : LLVMType<i1>;
  93 def llvm_i8_ty         : LLVMType<i8>;
  94 def llvm_i16_ty        : LLVMType<i16>;
  95 def llvm_i32_ty        : LLVMType<i32>;
  96 def llvm_i64_ty        : LLVMType<i64>;
  97 def llvm_float_ty      : LLVMType<f32>;
  98 def llvm_double_ty     : LLVMType<f64>;
  99 def llvm_f80_ty        : LLVMType<f80>;
 100 def llvm_f128_ty       : LLVMType<f128>;
 101 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 102 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 103 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 104 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 105 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 106 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 107
 108 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 109 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 110 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 111 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 112 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 113 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 114 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 115 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 116
 117 // MMX Vector Types
 118 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 119 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 120
 121 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 122
 123 //===----------------------------------------------------------------------===//
 124 // Intrinsic Definitions.
 125 //===----------------------------------------------------------------------===//
 126
 127 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 128 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 129 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 130 // example, llvm.bswap.i16 -> int_bswap_i16.
 131 //
 132 //  * RetTypes is a list containing the return types expected for the
 133 //    intrinsic.
 134 //  * ParamTypes is a list containing the parameter types expected for the
 135 //    intrinsic.
 136 //  * Properties can be set to describe the behavior of the intrinsic.
 137 //
 138 class Intrinsic<list<LLVMType> ret_types,
 139                 list<LLVMType> param_types = [],
 140                 list<IntrinsicProperty> properties = [],
 141                 string name = ""> {
 142   string LLVMName = name;
 143   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 144   list<LLVMType> RetTypes = ret_types;
 145   list<LLVMType> ParamTypes = param_types;
 146   list<IntrinsicProperty> Properties = properties;
 147 }
 148
 149 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 150 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 151 /// support.
 152 class GCCBuiltin<string name> {
 153   string GCCBuiltinName = name;
 154 }
 155
 156
 157 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 158 //
 159
 160 def int_vastart : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_start">;
 161 def int_vacopy  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_ptr_ty], [],
 162                             "llvm.va_copy">;
 163 def int_vaend   : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_end">;
 164
 165 //===------------------- Garbage Collection Intrinsics --------------------===//
 166 //
 167 def int_gcroot  : Intrinsic<[llvm_void_ty],
 168                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 169 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 170                             [llvm_ptr_ty, llvm_ptrptr_ty],
 171                             [IntrReadArgMem]>;
 172 def int_gcwrite : Intrinsic<[llvm_void_ty],
 173                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 174                             [IntrWriteArgMem]>;
 175
 176 //===--------------------- Code Generator Intrinsics ----------------------===//
 177 //
 178 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 179 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 180
 181 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 182 // model their dependencies on allocas.
 183 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 184                         GCCBuiltin<"__builtin_stack_save">;
 185 def int_stackrestore  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty]>,
 186                         GCCBuiltin<"__builtin_stack_restore">;
 187
 188 // IntrWriteArgMem is more pessimistic than strictly necessary for prefetch,
 189 // however it does conveniently prevent the prefetch from being reordered
 190 // with respect to nearby accesses to the same memory.
 191 def int_prefetch      : Intrinsic<[llvm_void_ty],
 192                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty],
 193                                   [IntrWriteArgMem]>;
 194 def int_pcmarker      : Intrinsic<[llvm_void_ty], [llvm_i32_ty]>;
 195
 196 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 197
 198 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 199 // guard to the correct place on the stack frame.
 200 def int_stackprotector : Intrinsic<[llvm_void_ty],
 201                                    [llvm_ptr_ty, llvm_ptrptr_ty],
 202                                    [IntrWriteMem]>;
 203
 204 //===------------------- Standard C Library Intrinsics --------------------===//
 205 //
 206
 207 def int_memcpy  : Intrinsic<[llvm_void_ty],
 208                              [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 209                               llvm_i32_ty],
 210                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 211 def int_memmove : Intrinsic<[llvm_void_ty],
 212                             [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 213                              llvm_i32_ty],
 214                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 215 def int_memset  : Intrinsic<[llvm_void_ty],
 216                             [llvm_ptr_ty, llvm_i8_ty, llvm_anyint_ty,
 217                              llvm_i32_ty],
 218                             [IntrWriteArgMem, NoCapture<0>]>;
 219
 220 // These functions do not actually read memory, but they are sensitive to the
 221 // rounding mode.  This needs to be modelled separately; in the meantime
 222 // declaring them as reading memory is conservatively correct.
 223 let Properties = [IntrReadMem] in {
 224   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 225   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 226   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 227   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 228   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 229                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 230   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 231   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 232   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 233   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 234   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 235 }
 236
 237 // NOTE: these are internal interfaces.
 238 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 239 def int_longjmp    : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 240 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 241 def int_siglongjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 242
 243 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 244 //
 245
 246 // None of these intrinsics accesses memory at all.
 247 let Properties = [IntrNoMem] in {
 248   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 249   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 250   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 251   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 252   def int_part_select : Intrinsic<[llvm_anyint_ty],
 253                                   [LLVMMatchType<0>, llvm_i32_ty, llvm_i32_ty]>;
 254   def int_part_set : Intrinsic<[llvm_anyint_ty],
 255                                [LLVMMatchType<0>, llvm_anyint_ty,
 256                                 llvm_i32_ty, llvm_i32_ty]>;
 257 }
 258
 259 //===------------------------ Debugger Intrinsics -------------------------===//
 260 //
 261
 262 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty],
 263                                      [llvm_i32_ty, llvm_i32_ty,
 264                                       llvm_descriptor_ty]>;
 265 def int_dbg_region_start : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 266 def int_dbg_region_end   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 267 def int_dbg_func_start   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 268 def int_dbg_declare      : Intrinsic<[llvm_void_ty],
 269                                      [llvm_descriptor_ty, llvm_descriptor_ty]>;
 270
 271 //===------------------ Exception Handling Intrinsics----------------------===//
 272 //
 273 def int_eh_exception    : Intrinsic<[llvm_ptr_ty]>;
 274 def int_eh_selector_i32 : Intrinsic<[llvm_i32_ty],
 275                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 276 def int_eh_selector_i64 : Intrinsic<[llvm_i64_ty],
 277                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 278
 279 def int_eh_typeid_for_i32 : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 280 def int_eh_typeid_for_i64 : Intrinsic<[llvm_i64_ty], [llvm_ptr_ty]>;
 281
 282 def int_eh_return_i32 : Intrinsic<[llvm_void_ty], [llvm_i32_ty, llvm_ptr_ty]>;
 283 def int_eh_return_i64 : Intrinsic<[llvm_void_ty], [llvm_i64_ty, llvm_ptr_ty]>;
 284
 285 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 286                         GCCBuiltin<"__builtin_unwind_init">;
 287
 288 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 289
 290 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 291 //
 292 def int_var_annotation : Intrinsic<[llvm_void_ty],
 293                                    [llvm_ptr_ty, llvm_ptr_ty,
 294                                     llvm_ptr_ty, llvm_i32_ty],
 295                                    [], "llvm.var.annotation">;
 296 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 297                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 298                                     llvm_i32_ty],
 299                                    [], "llvm.ptr.annotation">;
 300 def int_annotation : Intrinsic<[llvm_anyint_ty],
 301                                [LLVMMatchType<0>, llvm_ptr_ty,
 302                                 llvm_ptr_ty, llvm_i32_ty],
 303                                [], "llvm.annotation">;
 304
 305 //===------------------------ Trampoline Intrinsics -----------------------===//
 306 //
 307 def int_init_trampoline : Intrinsic<[llvm_ptr_ty],
 308                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 309                                     []>,
 310                           GCCBuiltin<"__builtin_init_trampoline">;
 311
 312 //===------------------------ Overflow Intrinsics -------------------------===//
 313 //
 314
 315 // Expose the carry flag from add operations on two integrals.
 316 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 317                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 318 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 319                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 320
 321 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 322                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 323 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 324                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 325
 326 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 327                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 328 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 329                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 330
 331 //===------------------------- Atomic Intrinsics --------------------------===//
 332 //
 333 def int_memory_barrier : Intrinsic<[llvm_void_ty],
 334                                    [llvm_i1_ty, llvm_i1_ty,
 335                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 336                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 337
 338 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 339                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 340                                      LLVMMatchType<0>, LLVMMatchType<0>],
 341                                     [IntrWriteArgMem]>,
 342                            GCCBuiltin<"__sync_val_compare_and_swap">;
 343 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 344                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 345                                      LLVMMatchType<0>],
 346                                     [IntrWriteArgMem]>,
 347                            GCCBuiltin<"__sync_fetch_and_add">;
 348 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 349                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 350                                      LLVMMatchType<0>],
 351                                     [IntrWriteArgMem]>,
 352                            GCCBuiltin<"__sync_lock_test_and_set">;
 353 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 354                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 355                                      LLVMMatchType<0>],
 356                                     [IntrWriteArgMem]>,
 357                            GCCBuiltin<"__sync_fetch_and_sub">;
 358 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 359                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 360                                      LLVMMatchType<0>],
 361                                     [IntrWriteArgMem]>,
 362                            GCCBuiltin<"__sync_fetch_and_and">;
 363 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 364                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 365                                       LLVMMatchType<0>],
 366                                      [IntrWriteArgMem]>,
 367                            GCCBuiltin<"__sync_fetch_and_or">;
 368 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 369                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 370                                      LLVMMatchType<0>],
 371                                     [IntrWriteArgMem]>,
 372                            GCCBuiltin<"__sync_fetch_and_xor">;
 373 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 374                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 375                                       LLVMMatchType<0>],
 376                                      [IntrWriteArgMem]>,
 377                            GCCBuiltin<"__sync_fetch_and_nand">;
 378 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 379                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 380                                       LLVMMatchType<0>],
 381                                      [IntrWriteArgMem]>,
 382                            GCCBuiltin<"__sync_fetch_and_min">;
 383 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 384                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 385                                       LLVMMatchType<0>],
 386                                      [IntrWriteArgMem]>,
 387                            GCCBuiltin<"__sync_fetch_and_max">;
 388 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 389                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 390                                       LLVMMatchType<0>],
 391                                      [IntrWriteArgMem]>,
 392                            GCCBuiltin<"__sync_fetch_and_umin">;
 393 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 394                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 395                                       LLVMMatchType<0>],
 396                                      [IntrWriteArgMem]>,
 397                            GCCBuiltin<"__sync_fetch_and_umax">;
 398
 399 //===-------------------------- Other Intrinsics --------------------------===//
 400 //
 401 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 402                      GCCBuiltin<"__builtin_flt_rounds">;
 403 def int_trap : Intrinsic<[llvm_void_ty]>,
 404                GCCBuiltin<"__builtin_trap">;
 405
 406 // These convert intrinsics are to support various conversions between
 407 // various types with rounding and saturation. NOTE: avoid using these
 408 // intrinsics as they might be removed sometime in the future and
 409 // most targets don't support them.
 410 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 411                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 412 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 413                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 414 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 415                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 416 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 417                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 418 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 419                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 420 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 421                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 422 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 423                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 424 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 425                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 426 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 427                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 428
 429 //===----------------------------------------------------------------------===//
 430 // Target-specific intrinsics
 431 //===----------------------------------------------------------------------===//
 432
 433 include "llvm/IntrinsicsPowerPC.td"
 434 include "llvm/IntrinsicsX86.td"
 435 include "llvm/IntrinsicsARM.td"
 436 include "llvm/IntrinsicsCellSPU.td"
 437 include "llvm/IntrinsicsAlpha.td"
 438 include "llvm/IntrinsicsXCore.td"